003e5091a9443fc0f7cf77c90ba945f239eba5f3
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2015 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [12])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.21
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.6.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.1
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.2.0
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=0.91
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_adns=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 card_support=yes
114 use_ccid_driver=auto
115 dirmngr_auto_start=yes
116 use_tls_library=no
117 large_secmem=no
118 show_tor_support=no
119
120
121 GNUPG_BUILD_PROGRAM(gpg, yes)
122 GNUPG_BUILD_PROGRAM(gpgsm, yes)
123 # The agent is a required part and can't be disabled anymore.
124 build_agent=yes
125 GNUPG_BUILD_PROGRAM(scdaemon, yes)
126 GNUPG_BUILD_PROGRAM(g13, no)
127 GNUPG_BUILD_PROGRAM(dirmngr, yes)
128 GNUPG_BUILD_PROGRAM(tools, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132
133 AC_SUBST(PACKAGE)
134 AC_SUBST(PACKAGE_GT)
135 AC_SUBST(VERSION)
136 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
137 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
138                                 [Name of this package for gettext])
139 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
141                                         [Bug report address])
142 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
143                                        [Required version of Libgcrypt])
144 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
145                                        [Required version of Libksba])
146 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
147                                        [Required version of NTBTLS])
148
149
150
151 # The default is to use the modules from this package and the few
152 # other packages in a standard place; i.e where this package gets
153 # installed.  With these options it is possible to override these
154 # ${prefix} depended values with fixed paths, which can't be replaced
155 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
156 AC_ARG_WITH(agent-pgm,
157     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
158           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
159 AC_SUBST(GNUPG_AGENT_PGM)
160 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
161 show_gnupg_agent_pgm="(default)"
162 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
163
164 AC_ARG_WITH(pinentry-pgm,
165     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
166           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
167 AC_SUBST(GNUPG_PINENTRY_PGM)
168 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
169 show_gnupg_pinentry_pgm="(default)"
170 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
171
172
173 AC_ARG_WITH(scdaemon-pgm,
174     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
175           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
176 AC_SUBST(GNUPG_SCDAEMON_PGM)
177 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
178 show_gnupg_scdaemon_pgm="(default)"
179 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
180
181
182 AC_ARG_WITH(dirmngr-pgm,
183     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
184           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
185 AC_SUBST(GNUPG_DIRMNGR_PGM)
186 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
187 show_gnupg_dirmngr_pgm="(default)"
188 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
189
190 AC_ARG_WITH(protect-tool-pgm,
191     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
192           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
193 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
194 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
195 show_gnupg_protect_tool_pgm="(default)"
196 test -n "$GNUPG_PROTECT_TOOL_PGM" \
197       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
198
199 AC_ARG_WITH(dirmngr-ldap-pgm,
200     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
201           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
202 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
203 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
204 show_gnupg_dirmngr_ldap_pgm="(default)"
205 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
206       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
207
208 #
209 # On some platforms gpg2 is usually installed as gpg without using a
210 # symlink.  For correct operation of gpgconf it needs to know the
211 # installed name of gpg.  This option sets "gpg2"'s installed name to
212 # just "gpg".  Note that it might be required to rename gpg2 to gpg
213 # manually after the build process.
214 #
215 AC_ARG_ENABLE(gpg2-is-gpg,
216     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
217     gpg2_is_gpg=$enableval)
218 if test "$gpg2_is_gpg" = "yes"; then
219    name_of_installed_gpg=gpg
220 else
221    name_of_installed_gpg=gpg2
222 fi
223 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
224                    [The name of the installed GPG tool])
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=yes)
267 AC_MSG_RESULT($use_tofu)
268
269
270
271 #
272 # Options to disable algorithm
273 #
274
275 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
276 # Elgamal is a MUST algorithm
277 # DSA is a MUST algorithm
278 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
279 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
280 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
281
282 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
283 # 3DES is a MUST algorithm
284 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
285 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
286 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
287 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
288 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
289 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
290 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
291 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
292 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
293
294 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
295 # SHA1 is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
297 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
298 # SHA256 is a MUST algorithm for GnuPG.
299 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
300 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
301
302
303 # Allow disabling of zip support.
304 # This is in general not a good idea because according to rfc4880 OpenPGP
305 # implementations SHOULD support ZLIB.
306 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
307 AC_ARG_ENABLE(zip,
308    AC_HELP_STRING([--disable-zip],
309                   [disable the ZIP and ZLIB compression algorithm]),
310    use_zip=$enableval)
311 AC_MSG_RESULT($use_zip)
312
313 # Allow disabling of bzib2 support.
314 # It is defined only after we confirm the library is available later
315 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
316 AC_ARG_ENABLE(bzip2,
317    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
318    use_bzip2=$enableval)
319 AC_MSG_RESULT($use_bzip2)
320
321 # Configure option to allow or disallow execution of external
322 # programs, like a photo viewer.
323 AC_MSG_CHECKING([whether to enable external program execution])
324 AC_ARG_ENABLE(exec,
325     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
326     use_exec=$enableval)
327 AC_MSG_RESULT($use_exec)
328 if test "$use_exec" = no ; then
329     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
330 fi
331
332 if test "$use_exec" = yes ; then
333   AC_MSG_CHECKING([whether to enable photo ID viewing])
334   AC_ARG_ENABLE(photo-viewers,
335       [  --disable-photo-viewers disable photo ID viewers],
336       [if test "$enableval" = no ; then
337          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
338       fi],enableval=yes)
339   gnupg_cv_enable_photo_viewers=$enableval
340   AC_MSG_RESULT($enableval)
341
342   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
343     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
344     AC_ARG_WITH(photo-viewer,
345         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
346         [if test "$withval" = yes ; then
347            withval=no
348         elif test "$withval" != no ; then
349            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
350                             [if set, restrict photo-viewer to this])
351         fi],withval=no)
352     AC_MSG_RESULT($withval)
353   fi
354 fi
355
356
357 #
358 # Check for the key/uid cache size.  This can't be zero, but can be
359 # pretty small on embedded systems.  This is used for the gpg part.
360 #
361 AC_MSG_CHECKING([for the size of the key and uid cache])
362 AC_ARG_ENABLE(key-cache,
363         AC_HELP_STRING([--enable-key-cache=SIZE],
364                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
365 if test "$enableval" = "no"; then
366    enableval=5
367 elif test "$enableval" = "yes" || test "$enableval" = ""; then
368    enableval=4096
369 fi
370 changequote(,)dnl
371 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
372 changequote([,])dnl
373 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
374    AC_MSG_ERROR([invalid key-cache size])
375 fi
376 AC_MSG_RESULT($key_cache_size)
377 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
378                   [Size of the key and UID caches])
379
380
381
382 #
383 # Check whether we want to use Linux capabilities
384 #
385 AC_MSG_CHECKING([whether use of capabilities is requested])
386 AC_ARG_WITH(capabilities,
387     [  --with-capabilities     use linux capabilities [default=no]],
388 [use_capabilities="$withval"],[use_capabilities=no])
389 AC_MSG_RESULT($use_capabilities)
390
391 #
392 # Check whether to disable the card support
393 AC_MSG_CHECKING([whether smartcard support is requested])
394 AC_ARG_ENABLE(card-support,
395               AC_HELP_STRING([--disable-card-support],
396                              [disable smartcard support]),
397               card_support=$enableval)
398 AC_MSG_RESULT($card_support)
399 if test "$card_support" = yes ; then
400   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
401 else
402   build_scdaemon=no
403 fi
404
405 #
406 # Allow disabling of internal CCID support.
407 # It is defined only after we confirm the library is available later
408 #
409 AC_MSG_CHECKING([whether to enable the internal CCID driver])
410 AC_ARG_ENABLE(ccid-driver,
411               AC_HELP_STRING([--disable-ccid-driver],
412                              [disable the internal CCID driver]),
413               use_ccid_driver=$enableval)
414 AC_MSG_RESULT($use_ccid_driver)
415
416 AC_MSG_CHECKING([whether to auto start dirmngr])
417 AC_ARG_ENABLE(dirmngr-auto-start,
418               AC_HELP_STRING([--disable-dirmngr-auto-start],
419                              [disable auto starting of the dirmngr]),
420               dirmngr_auto_start=$enableval)
421 AC_MSG_RESULT($dirmngr_auto_start)
422 if test "$dirmngr_auto_start" = yes ; then
423     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
424               [Define to enable auto starting of the dirmngr])
425 fi
426
427
428 #
429 # To avoid double inclusion of config.h which might happen at some
430 # places, we add the usual double inclusion protection at the top of
431 # config.h.
432 #
433 AH_TOP([
434 #ifndef GNUPG_CONFIG_H_INCLUDED
435 #define GNUPG_CONFIG_H_INCLUDED
436 ])
437
438 #
439 # Stuff which goes at the bottom of config.h.
440 #
441 AH_BOTTOM([
442 /* This is the major version number of GnuPG so that
443    source included files can test for this.  Note, that
444    we use 2 here even for GnuPG 1.9.x. */
445 #define GNUPG_MAJOR_VERSION 2
446
447 /* Now to separate file name parts.
448    Please note that the string version must not contain more
449    than one character because the code assumes strlen()==1 */
450 #ifdef HAVE_DOSISH_SYSTEM
451 #define DIRSEP_C '\\'
452 #define DIRSEP_S "\\"
453 #define EXTSEP_C '.'
454 #define EXTSEP_S "."
455 #define PATHSEP_C ';'
456 #define PATHSEP_S ";"
457 #define EXEEXT_S ".exe"
458 #else
459 #define DIRSEP_C '/'
460 #define DIRSEP_S "/"
461 #define EXTSEP_C '.'
462 #define EXTSEP_S "."
463 #define PATHSEP_C ':'
464 #define PATHSEP_S ":"
465 #define EXEEXT_S ""
466 #endif
467
468 /* This is the same as VERSION, but should be overridden if the
469    platform cannot handle things like dots '.' in filenames. Set
470    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
471    uses for dots and dashes. */
472 #define SAFE_VERSION VERSION
473 #define SAFE_VERSION_DOT  '.'
474 #define SAFE_VERSION_DASH '-'
475
476 /* Some global constants. */
477 #ifdef HAVE_DOSISH_SYSTEM
478 # ifdef HAVE_DRIVE_LETTERS
479 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
480 # else
481 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
482 # endif
483 #elif defined(__VMS)
484 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
485 #else
486 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
487 #endif
488 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
489 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
490
491 /* For some systems (DOS currently), we hardcode the path here.  For
492    POSIX systems the values are constructed by the Makefiles, so that
493    the values may be overridden by the make invocations; this is to
494    comply with the GNU coding standards.  Note that these values are
495    only defaults.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_BINDIR      "c:\\gnupg"
499 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
500 #  define GNUPG_LIBDIR      "c:\\gnupg"
501 #  define GNUPG_DATADIR     "c:\\gnupg"
502 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
503 # else
504 #  define GNUPG_BINDIR      "\\gnupg"
505 #  define GNUPG_LIBEXECDIR  "\\gnupg"
506 #  define GNUPG_LIBDIR      "\\gnupg"
507 #  define GNUPG_DATADIR     "\\gnupg"
508 #  define GNUPG_SYSCONFDIR  "\\gnupg"
509 # endif
510 #endif
511
512 /* Derive some other constants. */
513 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
514 #define EXEC_TEMPFILE_ONLY
515 #endif
516
517
518 /* We didn't define endianness above, so get it from OS macros.  This
519    is intended for making fat binary builds on OS X. */
520 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
521 #if defined(__BIG_ENDIAN__)
522 #define BIG_ENDIAN_HOST 1
523 #elif defined(__LITTLE_ENDIAN__)
524 #define LITTLE_ENDIAN_HOST 1
525 #else
526 #error "No endianness found"
527 #endif
528 #endif
529
530
531 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
532    ldap_start_tls_s because that is the actual symbol used in the
533    library.  winldap.h redefines it to our commonly used value,
534    thus we define our usual macro here.  */
535 #ifdef HAVE_LDAP_START_TLS_SA
536 # ifndef HAVE_LDAP_START_TLS_S
537 #  define HAVE_LDAP_START_TLS_S 1
538 # endif
539 #endif
540
541 /* Provide the es_ macro for estream.  */
542 #define GPGRT_ENABLE_ES_MACROS 1
543
544 /* Tell libgcrypt not to use its own libgpg-error implementation. */
545 #define USE_LIBGPG_ERROR 1
546
547 /* Tell Libgcrypt not to include deprecated definitions.  */
548 #define GCRYPT_NO_DEPRECATED 1
549
550 /* Our HTTP code is used in estream mode.  */
551 #define HTTP_USE_ESTREAM 1
552
553 /* Under W32 we do an explicit socket initialization, thus we need to
554    avoid the on-demand initialization which would also install an atexit
555    handler.  */
556 #define HTTP_NO_WSASTARTUP
557
558 /* Under Windows we use the gettext code from libgpg-error.  */
559 #define GPG_ERR_ENABLE_GETTEXT_MACROS
560
561 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
562 #define GPG_ERR_ENABLE_ERRNO_MACROS
563
564 #endif /*GNUPG_CONFIG_H_INCLUDED*/
565 ])
566
567
568 AM_MAINTAINER_MODE
569 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
570
571 # Checks for programs.
572 AC_MSG_NOTICE([checking for programs])
573 AC_PROG_MAKE_SET
574 AM_SANITY_CHECK
575 missing_dir=`cd $ac_aux_dir && pwd`
576 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
577 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
578 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
579 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
580 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
581 AM_SILENT_RULES
582 AC_PROG_AWK
583 AC_PROG_CC
584 AC_PROG_CPP
585 AM_PROG_CC_C_O
586 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
587   AC_MSG_ERROR([[No C-89 compiler found]])
588 fi
589 AC_PROG_INSTALL
590 AC_PROG_LN_S
591 AC_PROG_RANLIB
592 AC_CHECK_TOOL(AR, ar, :)
593 AC_PATH_PROG(PERL,"perl")
594 AC_CHECK_TOOL(WINDRES, windres, :)
595 AC_ISC_POSIX
596 AC_SYS_LARGEFILE
597 GNUPG_CHECK_USTAR
598
599
600 # We need to compile and run a program on the build machine.  A
601 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
602 # the AC archive is broken for autoconf 2.57.  Given that there is no
603 # newer version of that macro, we assume that it is also broken for
604 # autoconf 2.61 and thus we use a simple but usually sufficient
605 # approach.
606 AC_MSG_CHECKING(for cc for build)
607 if test "$cross_compiling" = "yes"; then
608   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
609 else
610   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
611 fi
612 AC_MSG_RESULT($CC_FOR_BUILD)
613 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
614
615 # We need to call this macro because other pkg-config macros are
616 # not always used.
617 PKG_PROG_PKG_CONFIG
618
619
620 try_gettext=yes
621 require_iconv=yes
622 have_dosish_system=no
623 have_w32_system=no
624 have_w32ce_system=no
625 have_android_system=no
626 run_tests=yes
627 use_simple_gettext=no
628 use_ldapwrapper=yes
629 mmap_needed=yes
630 case "${host}" in
631     *-mingw32*)
632         # special stuff for Windoze NT
633         ac_cv_have_dev_random=no
634         AC_DEFINE(USE_ONLY_8DOT3,1,
635                   [Set this to limit filenames to the 8.3 format])
636         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
637                   [Because the Unix gettext has too much overhead on
638                    MingW32 systems and these systems lack Posix functions,
639                    we use a simplified version of gettext])
640         have_dosish_system=yes
641         have_w32_system=yes
642         run_tests=no
643         use_ldapwrapper=no  # Fixme: Do this only for CE.
644         case "${host}" in
645           *-mingw32ce*)
646             have_w32ce_system=yes
647             ;;
648           *)
649             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
650                       [Defined if the OS supports drive letters.])
651             ;;
652         esac
653         try_gettext="no"
654         use_simple_gettext=yes
655         mmap_needed=no
656         ;;
657     i?86-emx-os2 | i?86-*-os2*emx )
658         # OS/2 with the EMX environment
659         ac_cv_have_dev_random=no
660         AC_DEFINE(HAVE_DRIVE_LETTERS)
661         have_dosish_system=yes
662         try_gettext="no"
663         ;;
664
665     i?86-*-msdosdjgpp*)
666         # DOS with the DJGPP environment
667         ac_cv_have_dev_random=no
668         AC_DEFINE(HAVE_DRIVE_LETTERS)
669         have_dosish_system=yes
670         try_gettext="no"
671         ;;
672
673     *-*-hpux*)
674         if test -z "$GCC" ; then
675             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
676         fi
677         ;;
678     *-dec-osf4*)
679         if test -z "$GCC" ; then
680             # Suppress all warnings
681             # to get rid of the unsigned/signed char mismatch warnings.
682             CFLAGS="-w $CFLAGS"
683         fi
684         ;;
685     *-dec-osf5*)
686         if test -z "$GCC" ; then
687             # Use the newer compiler `-msg_disable ptrmismatch1' to
688             # get rid of the unsigned/signed char mismatch warnings.
689             # Using this may hide other pointer mismatch warnings, but
690             # it at least lets other warning classes through
691             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
692         fi
693         ;;
694     m68k-atari-mint)
695         ;;
696     *-linux-androideabi)
697         have_android_system=yes
698         # Android is fully utf-8 and we do not want to use iconv to
699         # keeps things simple
700         require_iconv=no
701         run_tests=no
702         ;;
703     *)
704        ;;
705 esac
706
707 if test "$have_dosish_system" = yes; then
708    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
709              [Defined if we run on some of the PCDOS like systems
710               (DOS, Windoze. OS/2) with special properties like
711               no file modes, case insensitive file names and preferred
712               use of backslashes as directory name separators.])
713 fi
714 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
715
716 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
717
718 if test "$have_w32_system" = yes; then
719    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
720    if test "$have_w32ce_system" = yes; then
721       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
722    fi
723 fi
724 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
725 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
726
727 if test "$have_android_system" = yes; then
728    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
729 fi
730 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
731
732 if test "$run_tests" = yes; then
733    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
734 fi
735 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
736
737
738 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
739 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
740
741
742 #
743 # Checks for libraries.
744 #
745 AC_MSG_NOTICE([checking for libraries])
746
747
748 #
749 # libgpg-error is a library with error codes shared between GnuPG
750 # related projects.
751 #
752 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
753                   have_gpg_error=yes,have_gpg_error=no)
754
755
756 #
757 # Libgcrypt is our generic crypto library
758 #
759 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
760         have_libgcrypt=yes,have_libgcrypt=no)
761
762
763 #
764 # libassuan is used for IPC
765 #
766 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
767                   have_libassuan=yes,have_libassuan=no)
768 if test "$have_libassuan" = "yes"; then
769   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
770                      [version of the libassuan library])
771   show_tor_support="only .onion"
772 fi
773
774
775 #
776 # libksba is our X.509 support library
777 #
778 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
779
780
781 #
782 # libusb allows us to use the integrated CCID smartcard reader driver.
783 #
784 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
785 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
786    case "${host}" in
787      *-mingw32*)
788        LIBUSB_LIBS=
789        LIBUSB_CPPFLAGS=
790        ;;
791      *-*-darwin*)
792        LIBUSB_LIBS="-lusb-1.0 -Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
793        ;;
794      *-*-freebsd*)
795        # FreeBSD has a native 1.0 compatible library by -lusb.
796        LIBUSB_LIBS="-lusb"
797        ;;
798      *)
799        LIBUSB_LIBS="-lusb-1.0"
800        ;;
801    esac
802 fi
803 if test x"$LIBUSB_LIBS" != x ; then
804    AC_CHECK_LIB(usb-1.0, libusb_init,
805                 [ LIBUSB_LIBS="$LIBUSB_LIBS"
806                   have_libusb=yes ])
807    AC_MSG_CHECKING([libusb include dir])
808    usb_incdir_found="no"
809    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
810      _libusb_save_cppflags=$CPPFLAGS
811      if test -n "${_incdir}"; then
812        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
813      fi
814      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
815      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
816      CPPFLAGS=${_libusb_save_cppflags}
817      if test "$usb_incdir_found" = "yes"; then
818        break
819      fi
820    done
821    if test "$usb_incdir_found" = "yes"; then
822      AC_MSG_RESULT([${usb_incdir}])
823    else
824      AC_MSG_RESULT([not found])
825      usb_incdir=""
826      have_libusb=no
827      if test "$use_ccid_driver" != yes; then
828        use_ccid_driver=no
829      fi
830      LIBUSB_LIBS=""
831    fi
832
833    if test "$have_libusb" = yes; then
834      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
835    fi
836    if test x"$usb_incdir" = x; then
837      LIBUSB_CPPFLAGS=""
838    else
839      LIBUSB_CPPFLAGS="-I${usb_incdir}"
840    fi
841 fi
842 AC_SUBST(LIBUSB_LIBS)
843 AC_SUBST(LIBUSB_CPPFLAGS)
844
845 #
846 # Check wether it is necessary to link against libdl.
847 # (For example to load libpcsclite)
848 #
849 gnupg_dlopen_save_libs="$LIBS"
850 LIBS=""
851 AC_SEARCH_LIBS(dlopen, c dl,,,)
852 DL_LIBS=$LIBS
853 AC_SUBST(DL_LIBS)
854 LIBS="$gnupg_dlopen_save_libs"
855
856
857 # Checks for g10
858
859 AC_ARG_ENABLE(sqlite,
860                 AC_HELP_STRING([--disable-sqlite],
861                                [disable the use of SQLITE]),
862               try_sqlite=$enableval, try_sqlite=yes)
863
864 if test x"$use_tofu" = xyes ; then
865   if test x"$try_sqlite" = xyes ; then
866     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
867                                  [have_sqlite=yes],
868                                  [have_sqlite=no])
869   fi
870   if test "$have_sqlite" = "yes"; then
871     :
872     AC_SUBST([SQLITE3_CFLAGS])
873     AC_SUBST([SQLITE3_LIBS])
874   else
875     use_tofu=no
876     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
877     AC_MSG_WARN([[
878 ***
879 *** Building without SQLite support - TOFU disabled
880 ***
881 *** $tmp]])
882   fi
883 fi
884
885 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
886
887 if test x"$use_tofu" = xyes ; then
888     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
889 fi
890
891
892 # Checks for g13
893
894 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
895 AC_DEFINE_UNQUOTED(ENCFS,
896         "${ENCFS}", [defines the filename of the encfs program])
897
898 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
899 AC_DEFINE_UNQUOTED(FUSERMOUNT,
900         "${FUSERMOUNT}", [defines the filename of the fusermount program])
901
902
903 # Checks for dirmngr
904
905
906 #
907 # Checks for symcryptrun:
908 #
909
910 # libutil has openpty() and login_tty().
911 AC_CHECK_LIB(util, openpty,
912               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
913                 AC_DEFINE(HAVE_LIBUTIL,1,
914                          [defined if libutil is available])
915              ])
916 AC_SUBST(LIBUTIL_LIBS)
917
918 # shred is used to clean temporary plain text files.
919 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
920 AC_DEFINE_UNQUOTED(SHRED,
921         "${SHRED}", [defines the filename of the shred program])
922
923
924 #
925 # Check whether the nPth library is available
926 #
927 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
928 if test "$have_npth" = "yes"; then
929   AC_DEFINE(HAVE_NPTH, 1,
930               [Defined if the New Portable Thread Library is available])
931   AC_DEFINE(USE_NPTH, 1,
932               [Defined if support for nPth is requested and nPth is available])
933 else
934   AC_MSG_WARN([[
935 ***
936 *** To support concurrent access for example in gpg-agent and the SCdaemon
937 *** we need the support of the New Portable Threads Library.
938 ***]])
939 fi
940
941
942 #
943 # NTBTLS is our TLS library.  If it is not available fallback to
944 # GNUTLS.
945 #
946 AC_ARG_ENABLE(ntbtls,
947               AC_HELP_STRING([--disable-ntbtls],
948                              [disable the use of NTBTLS as TLS library]),
949               try_ntbtls=$enableval, try_ntbtls=yes)
950 if test x"$try_ntbtls" = xyes ; then
951   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
952                  [have_ntbtls=yes],[have_ntbtls=no])
953 fi
954 if test "$have_ntbtls" = yes ; then
955    use_tls_library=ntbtls
956    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
957 else
958   AC_ARG_ENABLE(gnutls,
959                 AC_HELP_STRING([--disable-gnutls],
960                                [disable GNUTLS as fallback TLS library]),
961                 try_gnutls=$enableval, try_gnutls=yes)
962   if test x"$try_gnutls" = xyes ; then
963     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
964                                    [have_gnutls=yes],
965                                    [have_gnutls=no])
966   fi
967   if test "$have_gnutls" = "yes"; then
968     AC_SUBST([LIBGNUTLS_CFLAGS])
969     AC_SUBST([LIBGNUTLS_LIBS])
970     use_tls_library=gnutls
971     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
972   else
973     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
974     AC_MSG_WARN([[
975 ***
976 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
977 ***
978 *** $tmp]])
979   fi
980 fi
981
982
983 AC_MSG_NOTICE([checking for networking options])
984
985 #
986 # Must check for network library requirements before doing link tests
987 # for ldap, for example. If ldap libs are static (or dynamic and without
988 # ELF runtime link paths), then link will fail and LDAP support won't
989 # be detected.
990 #
991 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
992         [NETLIBS="-lnsl $NETLIBS"]))
993 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
994         [NETLIBS="-lsocket $NETLIBS"]))
995
996
997 #
998 # Check for ADNS.
999 #
1000 _cppflags="${CPPFLAGS}"
1001 _ldflags="${LDFLAGS}"
1002 AC_ARG_WITH(adns,
1003             AC_HELP_STRING([--with-adns=DIR],
1004                            [look for the adns library in DIR]),
1005             [if test -d "$withval"; then
1006                CPPFLAGS="${CPPFLAGS} -I$withval/include"
1007                LDFLAGS="${LDFLAGS} -L$withval/lib"
1008              fi])
1009 if test "$with_adns" != "no"; then
1010   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
1011   AC_CHECK_FUNCS(adns_free)
1012   AC_MSG_CHECKING([if adns supports adns_if_tormode])
1013   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1014     #include <adns.h>
1015     adns_initflags flags = adns_if_tormode;
1016   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
1017   AC_MSG_RESULT($adns_if_tormode)
1018   if test x"$adns_if_tormode" = xyes; then
1019     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
1020     if test "$show_tor_support" != "no"; then
1021       show_tor_support=yes
1022     fi
1023   fi
1024 fi
1025 CPPFLAGS=${_cppflags}
1026 LDFLAGS=${_ldflags}
1027 if test "$have_adns" = "yes"; then
1028   ADNSLIBS="-ladns"
1029 fi
1030
1031
1032 #
1033 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
1034 #
1035 AC_ARG_ENABLE(dns-srv,
1036               AC_HELP_STRING([--disable-dns-srv],
1037                              [disable the use of DNS SRV in HKP and HTTP]),
1038               use_dns_srv=$enableval,use_dns_srv=yes)
1039
1040 AC_ARG_ENABLE(dns-cert,
1041    AC_HELP_STRING([--disable-dns-cert],
1042         [disable the use of CERT records in DNS]),
1043    use_dns_cert=$enableval,use_dns_cert=yes)
1044
1045 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
1046   _dns_save_libs=$LIBS
1047   LIBS=""
1048
1049   if test x"$have_adns" = xyes ; then
1050     # We prefer ADNS.
1051     DNSLIBS="$ADNSLIBS"
1052     AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1053
1054     if test x"$use_dns_srv" = xyes ; then
1055         AC_DEFINE(USE_DNS_SRV,1)
1056     fi
1057
1058     if test x"$use_dns_cert" = xyes ; then
1059         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1060     fi
1061   else
1062     # With no ADNS find the system resolver.
1063
1064     # the double underscore thing is a glibc-ism?
1065     AC_SEARCH_LIBS(res_query,resolv bind,,
1066                    AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1067     AC_SEARCH_LIBS(dn_expand,resolv bind,,
1068                    AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1069     AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1070                    AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
1071
1072     if test x"$have_resolver" != xno ; then
1073
1074       # Make sure that the BIND 4 resolver interface is workable before
1075       # enabling any code that calls it.  At some point I'll rewrite the
1076       # code to use the BIND 8 resolver API.
1077       # We might also want to use adns instead.  Problem with ADNS is that
1078       # it does not support v6.
1079
1080       AC_MSG_CHECKING([whether the resolver is usable])
1081       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1082 #include <netinet/in.h>
1083 #include <arpa/nameser.h>
1084 #include <resolv.h>]],
1085 [[unsigned char answer[PACKETSZ];
1086   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1087   dn_skipname(0,0);
1088   dn_expand(0,0,0,0,0);
1089 ]])],have_resolver=yes,have_resolver=no)
1090       AC_MSG_RESULT($have_resolver)
1091
1092       # This is Apple-specific and somewhat bizarre as they changed the
1093       # define in bind 8 for some reason.
1094
1095       if test x"$have_resolver" != xyes ; then
1096          AC_MSG_CHECKING(
1097              [whether I can make the resolver usable with BIND_8_COMPAT])
1098         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1099 #include <sys/types.h>
1100 #include <netinet/in.h>
1101 #include <arpa/nameser.h>
1102 #include <resolv.h>]],
1103 [[unsigned char answer[PACKETSZ];
1104   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1105   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1106 ]])],[have_resolver=yes ; need_compat=yes])
1107          AC_MSG_RESULT($have_resolver)
1108       fi
1109     fi
1110
1111     if test x"$have_resolver" = xyes ; then
1112       DNSLIBS=$LIBS
1113
1114       if test x"$use_dns_srv" = xyes ; then
1115          AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
1116       fi
1117
1118       if test x"$use_dns_cert" = xyes ; then
1119         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1120       fi
1121
1122       if test x"$need_compat" = xyes ; then
1123         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1124       fi
1125     else
1126       use_dns_srv=no
1127       use_dns_cert=no
1128     fi
1129   fi
1130
1131   LIBS=$_dns_save_libs
1132 fi
1133
1134 AC_SUBST(DNSLIBS)
1135
1136 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1137
1138
1139 #
1140 # Check for LDAP
1141 #
1142 # Note that running the check changes the variable
1143 # gnupg_have_ldap from "n/a" to "no" or "yes".
1144
1145 AC_ARG_ENABLE(ldap,
1146     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1147     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1148
1149 if test "$gnupg_have_ldap" != "no" ; then
1150   if test "$build_dirmngr" = "yes" ; then
1151      GNUPG_CHECK_LDAP($NETLIBS)
1152      AC_CHECK_LIB(lber, ber_free,
1153                   [ LBER_LIBS="$LBER_LIBS -llber"
1154                     AC_DEFINE(HAVE_LBER,1,
1155                              [defined if liblber is available])
1156                     have_lber=yes
1157                  ])
1158   fi
1159 fi
1160 AC_SUBST(LBER_LIBS)
1161 if test "$gnupg_have_ldap" = "no"; then
1162     AC_MSG_WARN([[
1163 ***
1164 *** Building without LDAP support.
1165 *** No CRL access or X.509 certificate search available.
1166 ***]])
1167 fi
1168
1169 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1170 if test "$gnupg_have_ldap" = yes ; then
1171   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1172 else
1173  use_ldapwrapper=no
1174 fi
1175
1176 if test "$use_ldapwrapper" = yes; then
1177    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1178 fi
1179 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1180
1181
1182
1183
1184 #
1185 # Check for sendmail
1186 #
1187 # This isn't necessarily sendmail itself, but anything that gives a
1188 # sendmail-ish interface to the outside world.  That includes Exim,
1189 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1190 AC_ARG_WITH(mailprog,
1191       AC_HELP_STRING([--with-mailprog=NAME],
1192                      [use "NAME -t" for mail transport]),
1193              ,with_mailprog=yes)
1194 if test x"$with_mailprog" = xyes ; then
1195     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1196 elif test x"$with_mailprog" != xno ; then
1197     AC_MSG_CHECKING([for a mail transport program])
1198     AC_SUBST(SENDMAIL,$with_mailprog)
1199     AC_MSG_RESULT($with_mailprog)
1200 fi
1201
1202
1203 #
1204 # Construct a printable name of the OS
1205 #
1206 case "${host}" in
1207     *-mingw32ce*)
1208         PRINTABLE_OS_NAME="W32CE"
1209         ;;
1210     *-mingw32*)
1211         PRINTABLE_OS_NAME="MingW32"
1212         ;;
1213     *-*-cygwin*)
1214         PRINTABLE_OS_NAME="Cygwin"
1215         ;;
1216     i?86-emx-os2 | i?86-*-os2*emx )
1217         PRINTABLE_OS_NAME="OS/2"
1218         ;;
1219     i?86-*-msdosdjgpp*)
1220         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1221         try_dynload=no
1222         ;;
1223     *-linux*)
1224         PRINTABLE_OS_NAME="GNU/Linux"
1225         ;;
1226     *)
1227         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1228         ;;
1229 esac
1230 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1231                    [A human readable text with the name of the OS])
1232
1233
1234 #
1235 # Checking for iconv
1236 #
1237 if test "$require_iconv" = yes; then
1238   AM_ICONV
1239 else
1240   LIBICONV=
1241   LTLIBICONV=
1242   AC_SUBST(LIBICONV)
1243   AC_SUBST(LTLIBICONV)
1244 fi
1245
1246
1247 #
1248 # Check for gettext
1249 #
1250 # This is "GNU gnupg" - The project-id script from gettext
1251 #                       needs this string
1252 #
1253 AC_MSG_NOTICE([checking for gettext])
1254 AM_PO_SUBDIRS
1255 AM_GNU_GETTEXT_VERSION([0.17])
1256 if test "$try_gettext" = yes; then
1257   AM_GNU_GETTEXT([external],[need-ngettext])
1258
1259   # gettext requires some extra checks.  These really should be part of
1260   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1261   # function checks to here.
1262
1263   AC_CHECK_FUNCS(strchr)
1264 else
1265   USE_NLS=no
1266   USE_INCLUDED_LIBINTL=no
1267   BUILD_INCLUDED_LIBINTL=no
1268   POSUB=po
1269   AC_SUBST(USE_NLS)
1270   AC_SUBST(USE_INCLUDED_LIBINTL)
1271   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1272   AC_SUBST(POSUB)
1273 fi
1274
1275 # We use HAVE_LANGINFO_CODESET in a couple of places.
1276 AM_LANGINFO_CODESET
1277
1278 # Checks required for our use of locales
1279 gt_LC_MESSAGES
1280
1281
1282 #
1283 # SELinux support
1284 #
1285 if test "$selinux_support" = yes ; then
1286   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1287 fi
1288
1289
1290 #
1291 # Checks for header files.
1292 #
1293 AC_MSG_NOTICE([checking for header files])
1294 AC_HEADER_STDC
1295 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1296                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1297                   signal.h])
1298 AC_HEADER_TIME
1299
1300
1301 #
1302 # Checks for typedefs, structures, and compiler characteristics.
1303 #
1304 AC_MSG_NOTICE([checking for system characteristics])
1305 AC_C_CONST
1306 AC_C_INLINE
1307 AC_C_VOLATILE
1308 AC_TYPE_SIZE_T
1309 AC_TYPE_MODE_T
1310 AC_TYPE_SIGNAL
1311 AC_DECL_SYS_SIGLIST
1312
1313 gl_HEADER_SYS_SOCKET
1314 gl_TYPE_SOCKLEN_T
1315
1316 AC_SEARCH_LIBS([inet_addr], [nsl])
1317
1318 AC_ARG_ENABLE(endian-check,
1319               AC_HELP_STRING([--disable-endian-check],
1320               [disable the endian check and trust the OS provided macros]),
1321               endiancheck=$enableval,endiancheck=yes)
1322
1323 if test x"$endiancheck" = xyes ; then
1324   GNUPG_CHECK_ENDIAN
1325 fi
1326
1327 # fixme: we should get rid of the byte type
1328 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1329 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1330 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1331 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1332 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1333
1334 AC_CHECK_SIZEOF(unsigned short)
1335 AC_CHECK_SIZEOF(unsigned int)
1336 AC_CHECK_SIZEOF(unsigned long)
1337 AC_CHECK_SIZEOF(unsigned long long)
1338 AC_HEADER_TIME
1339 AC_CHECK_SIZEOF(time_t,,[[
1340 #include <stdio.h>
1341 #if TIME_WITH_SYS_TIME
1342 # include <sys/time.h>
1343 # include <time.h>
1344 #else
1345 # if HAVE_SYS_TIME_H
1346 #  include <sys/time.h>
1347 # else
1348 #  include <time.h>
1349 # endif
1350 #endif
1351 ]])
1352 GNUPG_TIME_T_UNSIGNED
1353
1354
1355 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1356    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1357    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1358     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1359 fi
1360
1361
1362 #
1363 # Checks for library functions.
1364 #
1365 AC_MSG_NOTICE([checking for library functions])
1366 AC_CHECK_DECLS(getpagesize)
1367 AC_FUNC_FSEEKO
1368 AC_FUNC_VPRINTF
1369 AC_FUNC_FORK
1370 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1371 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1372 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1373 AC_CHECK_FUNCS([canonicalize_file_name])
1374 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1375 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1376 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1377 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1378 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1379                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1380                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1381                 getenv inet_pton strpbrk])
1382
1383 if test "$have_android_system" = yes; then
1384    # On Android ttyname is a stub but prints an error message.
1385    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1386              [Defined if ttyname does not work properly])
1387 fi
1388
1389 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1390
1391 # Dirmngr requires mmap on Unix systems.
1392 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1393   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1394 fi
1395
1396 #
1397 # W32 specific test
1398 #
1399 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1400
1401 #
1402 # Sanity check regex.  Tests adapted from mutt.
1403 #
1404 AC_MSG_CHECKING([whether regular expression support is requested])
1405 AC_ARG_ENABLE(regex,
1406   AC_HELP_STRING([--disable-regex],
1407     [do not handle regular expressions in trust signatures]),
1408   use_regex=$enableval, use_regex=yes)
1409 AC_MSG_RESULT($use_regex)
1410
1411 if test "$use_regex" = yes ; then
1412   _cppflags="${CPPFLAGS}"
1413   _ldflags="${LDFLAGS}"
1414   AC_ARG_WITH(regex,
1415      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1416       [
1417       if test -d "$withval" ; then
1418         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1419         LDFLAGS="${LDFLAGS} -L$withval/lib"
1420       fi
1421       ],withval="")
1422
1423   # Does the system have regex functions at all?
1424   AC_SEARCH_LIBS([regcomp], [regex])
1425   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1426
1427   if test $gnupg_cv_have_regex = no; then
1428     use_regex=no
1429   else
1430     if test x"$cross_compiling" = xyes; then
1431       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1432     else
1433       AC_CACHE_CHECK([whether your system's regexp library is broken],
1434        [gnupg_cv_regex_broken],
1435        AC_TRY_RUN([
1436 #include <unistd.h>
1437 #include <regex.h>
1438 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1439        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1440
1441       if test $gnupg_cv_regex_broken = yes; then
1442         AC_MSG_WARN([your regex is broken - disabling regex use])
1443         use_regex=no
1444       fi
1445     fi
1446   fi
1447   CPPFLAGS="${_cppflags}"
1448   LDFLAGS="${_ldflags}"
1449 fi
1450
1451 if test "$use_regex" != yes ; then
1452   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1453 fi
1454 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1455
1456
1457
1458 #
1459 # Do we have zlib? Must do it here because Solaris failed
1460 # when compiling a conftest (due to the "-lz" from LIBS).
1461 # Note that we combine zlib and bzlib2 in ZLIBS.
1462 #
1463 if test "$use_zip" = yes ; then
1464   _cppflags="${CPPFLAGS}"
1465   _ldflags="${LDFLAGS}"
1466   AC_ARG_WITH(zlib,
1467     [  --with-zlib=DIR         use libz in DIR],[
1468       if test -d "$withval"; then
1469         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1470         LDFLAGS="${LDFLAGS} -L$withval/lib"
1471       fi
1472     ])
1473
1474   AC_CHECK_HEADER(zlib.h,
1475      AC_CHECK_LIB(z, deflateInit2_,
1476        [
1477        ZLIBS="-lz"
1478        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1479        ],
1480        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1481        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1482 fi
1483
1484
1485 #
1486 # Check whether we can support bzip2
1487 #
1488 if test "$use_bzip2" = yes ; then
1489   _cppflags="${CPPFLAGS}"
1490   _ldflags="${LDFLAGS}"
1491   AC_ARG_WITH(bzip2,
1492      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1493       [
1494       if test -d "$withval" ; then
1495         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1496         LDFLAGS="${LDFLAGS} -L$withval/lib"
1497       fi
1498       ],withval="")
1499
1500   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1501   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1502   # woefully out of date.
1503   if test "$withval" != no ; then
1504      AC_CHECK_HEADER(bzlib.h,
1505         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1506           [
1507           have_bz2=yes
1508           ZLIBS="$ZLIBS -lbz2"
1509           AC_DEFINE(HAVE_BZIP2,1,
1510                   [Defined if the bz2 compression library is available])
1511           ],
1512           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1513           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1514   fi
1515 fi
1516 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1517 AC_SUBST(ZLIBS)
1518
1519
1520 # Check for readline support
1521 GNUPG_CHECK_READLINE
1522
1523
1524 if test "$development_version" = yes; then
1525     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1526             [Defined if this is not a regular release])
1527 fi
1528
1529 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1530
1531 GNUPG_CHECK_GNUMAKE
1532
1533 # Add some extra libs here so that previous tests don't fail for
1534 # mysterious reasons - the final link step should bail out.
1535 # W32SOCKLIBS is also defined so that if can be used for tools not
1536 # requiring any network stuff but linking to code in libcommon which
1537 # tracks in winsock stuff (e.g. init_common_subsystems).
1538 if test "$have_w32_system" = yes; then
1539    if test "$have_w32ce_system" = yes; then
1540      W32SOCKLIBS="-lws2"
1541    else
1542      W32SOCKLIBS="-lws2_32"
1543    fi
1544    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1545 fi
1546
1547 AC_SUBST(NETLIBS)
1548 AC_SUBST(W32SOCKLIBS)
1549
1550 #
1551 # Setup gcc specific options
1552 #
1553 AC_MSG_NOTICE([checking for cc features])
1554 if test "$GCC" = yes; then
1555     mycflags=
1556     mycflags_save=$CFLAGS
1557
1558     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1559     # options.  This is the case for gcc >= 4.6
1560     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1561     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1562 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1563 #kickerror
1564 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1565     AC_MSG_RESULT($_gcc_silent_wno)
1566
1567     # Note that it is okay to use CFLAGS here because these are just
1568     # warning options and the user should have a chance of overriding
1569     # them.
1570     if test "$USE_MAINTAINER_MODE" = "yes"; then
1571         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1572         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1573         if test x"$_gcc_silent_wno" = xyes ; then
1574           _gcc_wopt=yes
1575         else
1576           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1577           CFLAGS="-Wno-missing-field-initializers"
1578           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1579                             [_gcc_wopt=yes],[_gcc_wopt=no])
1580           AC_MSG_RESULT($_gcc_wopt)
1581         fi
1582         if test x"$_gcc_wopt" = xyes ; then
1583           mycflags="$mycflags -W -Wno-sign-compare"
1584           mycflags="$mycflags -Wno-missing-field-initializers"
1585         fi
1586
1587         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1588         CFLAGS="-Wdeclaration-after-statement"
1589         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1590         AC_MSG_RESULT($_gcc_wopt)
1591         if test x"$_gcc_wopt" = xyes ; then
1592           mycflags="$mycflags -Wdeclaration-after-statement"
1593         fi
1594     else
1595         mycflags="$mycflags -Wall"
1596     fi
1597
1598     if test x"$_gcc_silent_wno" = xyes ; then
1599       _gcc_psign=yes
1600     else
1601       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1602       CFLAGS="-Wno-pointer-sign"
1603       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1604                         [_gcc_psign=yes],[_gcc_psign=no])
1605       AC_MSG_RESULT($_gcc_psign)
1606     fi
1607     if test x"$_gcc_psign" = xyes ; then
1608        mycflags="$mycflags -Wno-pointer-sign"
1609     fi
1610
1611     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1612     CFLAGS="-Wpointer-arith"
1613     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1614     AC_MSG_RESULT($_gcc_psign)
1615     if test x"$_gcc_psign" = xyes ; then
1616        mycflags="$mycflags -Wpointer-arith"
1617     fi
1618
1619     CFLAGS="$mycflags $mycflags_save"
1620 fi
1621
1622
1623 #
1624 # This is handy for debugging so the compiler doesn't rearrange
1625 # things and eliminate variables.
1626 #
1627 AC_ARG_ENABLE(optimization,
1628    AC_HELP_STRING([--disable-optimization],
1629                   [disable compiler optimization]),
1630                   [if test $enableval = no ; then
1631                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1632                    fi])
1633
1634 #
1635 # Add user CFLAGS.
1636 #
1637 CFLAGS="$CFLAGS $CFLAGS_orig"
1638
1639 #
1640 # Decide what to build
1641 #
1642
1643 build_scdaemon_extra=""
1644 if test "$build_scdaemon" = "yes"; then
1645   if test $have_libusb = no; then
1646      build_scdaemon_extra="without internal CCID driver"
1647   fi
1648   if test -n "$build_scdaemon_extra"; then
1649      build_scdaemon_extra="(${build_scdaemon_extra})"
1650   fi
1651 fi
1652
1653
1654 #
1655 # Set variables for use by automake makefiles.
1656 #
1657 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1658 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1659 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1660 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1661 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1662 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1663 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1664 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1665 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1666 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1667
1668 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1669 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1670 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1671
1672 AM_CONDITIONAL(RUN_GPG_TESTS,
1673                test x$cross_compiling = xno -a "$build_gpg" = yes )
1674
1675 #
1676 # Set some defines for use gpgconf.
1677 #
1678 if test "$build_gpg" = yes ; then
1679     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1680 fi
1681 if test "$build_gpgsm" = yes ; then
1682     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1683 fi
1684 if test "$build_agent" = yes ; then
1685     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1686 fi
1687 if test "$build_scdaemon" = yes ; then
1688     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1689 fi
1690 if test "$build_dirmngr" = yes ; then
1691     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1692 fi
1693 if test "$build_g13" = yes ; then
1694     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1695 fi
1696
1697
1698 #
1699 # Define Name strings
1700 #
1701 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1702
1703 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1704 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1705
1706 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1707 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1708
1709 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1710 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1711                                         [The displayed name of gpg-agent])
1712
1713 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1714 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1715                                        [The displayed name of scdaemon])
1716
1717 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1718 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1719                                       [The displayed name of dirmngr])
1720
1721 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1722 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1723
1724 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1725 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1726                                       [The displayed name of gpgconf])
1727
1728 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1729
1730 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1731                    [The name of the agent socket])
1732 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1733                    [The name of the agent socket for ssh])
1734 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1735                    [The name of the dirmngr info envvar])
1736 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1737                    [The name of the SCdaemon socket])
1738 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1739                    [The name of the dirmngr socket])
1740
1741 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1742
1743 if test "$have_w32_system" = yes; then
1744   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1745                      [The directory part of the W32 registry keys])
1746 fi
1747
1748
1749 #
1750 # Provide information about the build.
1751 #
1752 BUILD_REVISION="mym4_revision"
1753 AC_SUBST(BUILD_REVISION)
1754 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1755                    [GIT commit id revision used to build this package])
1756
1757 changequote(,)dnl
1758 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1759 changequote([,])dnl
1760 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1761 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1762 AC_SUBST(BUILD_VERSION)
1763 AC_SUBST(BUILD_FILEVERSION)
1764
1765 AC_ARG_ENABLE([build-timestamp],
1766   AC_HELP_STRING([--enable-build-timestamp],
1767                  [set an explicit build timestamp for reproducibility.
1768                   (default is the current time in ISO-8601 format)]),
1769      [if test "$enableval" = "yes"; then
1770         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1771       else
1772         BUILD_TIMESTAMP="$enableval"
1773       fi],
1774      [BUILD_TIMESTAMP="<none>"])
1775 AC_SUBST(BUILD_TIMESTAMP)
1776 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1777                    [The time this package was configured for a build])
1778 BUILD_HOSTNAME="$ac_hostname"
1779 AC_SUBST(BUILD_HOSTNAME)
1780
1781
1782 #
1783 # Print errors here so that they are visible all
1784 # together and the user can acquire them all together.
1785 #
1786 die=no
1787 if test "$have_gpg_error" = "no"; then
1788    die=yes
1789    AC_MSG_NOTICE([[
1790 ***
1791 *** You need libgpg-error to build this program.
1792 **  This library is for example available at
1793 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1794 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1795 ***]])
1796 fi
1797 if test "$have_libgcrypt" = "no"; then
1798    die=yes
1799    AC_MSG_NOTICE([[
1800 ***
1801 *** You need libgcrypt to build this program.
1802 **  This library is for example available at
1803 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1804 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1805 ***]])
1806 fi
1807 if test "$have_libassuan" = "no"; then
1808    die=yes
1809    AC_MSG_NOTICE([[
1810 ***
1811 *** You need libassuan to build this program.
1812 *** This library is for example available at
1813 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1814 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1815 ***]])
1816 fi
1817 if test "$have_ksba" = "no"; then
1818     die=yes
1819     AC_MSG_NOTICE([[
1820 ***
1821 *** You need libksba to build this program.
1822 *** This library is for example available at
1823 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1824 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1825 ***]])
1826 fi
1827 if test "$gnupg_have_ldap" = yes; then
1828   if test "$have_w32ce_system" = yes; then
1829     AC_MSG_NOTICE([[
1830 *** Note that CeGCC might be broken, a package fixing this is:
1831 ***    http://files.kolab.org/local/windows-ce/
1832 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1833 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1834 ***]])
1835    fi
1836 fi
1837 if test "$have_npth" = "no"; then
1838     die=yes
1839     AC_MSG_NOTICE([[
1840 ***
1841 *** It is now required to build with support for the
1842 *** New Portable Threads Library (nPth). Please install this
1843 *** library first.  The library is for example available at
1844 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1845 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1846 ***]])
1847 fi
1848
1849 if test "$require_iconv" = yes; then
1850   if test "$am_func_iconv" != yes; then
1851     die=yes
1852     AC_MSG_NOTICE([[
1853 ***
1854 *** The system does not provide a working iconv function.  Please
1855 *** install a suitable library; for example GNU Libiconv which is
1856 *** available at:
1857 ***   http://ftp.gnu.org/gnu/libiconv/
1858 ***]])
1859   fi
1860 fi
1861
1862 if test "$use_ccid_driver" = yes; then
1863   if test "$have_libusb" != yes; then
1864     die=yes
1865     AC_MSG_NOTICE([[
1866 ***
1867 *** You need libusb to build the internal ccid driver.  Please
1868 *** install a libusb suitable for your system.
1869 ***]])
1870   fi
1871 fi
1872
1873 if test "$die" = "yes"; then
1874     AC_MSG_ERROR([[
1875 ***
1876 *** Required libraries not found. Please consult the above messages
1877 *** and install them before running configure again.
1878 ***]])
1879 fi
1880
1881
1882
1883 AC_CONFIG_FILES([ m4/Makefile
1884 Makefile
1885 po/Makefile.in
1886 common/Makefile
1887 common/w32info-rc.h
1888 kbx/Makefile
1889 g10/Makefile
1890 sm/Makefile
1891 agent/Makefile
1892 scd/Makefile
1893 g13/Makefile
1894 dirmngr/Makefile
1895 tools/gpg-zip
1896 tools/Makefile
1897 doc/Makefile
1898 tests/Makefile
1899 tests/openpgp/Makefile
1900 tests/pkits/Makefile
1901 g10/gpg.w32-manifest
1902 ])
1903
1904
1905 AC_OUTPUT
1906
1907
1908 echo "
1909         GnuPG v${VERSION} has been configured as follows:
1910
1911         Revision:  mym4_revision  (mym4_revision_dec)
1912         Platform:  $PRINTABLE_OS_NAME ($host)
1913
1914         OpenPGP:   $build_gpg
1915         S/MIME:    $build_gpgsm
1916         Agent:     $build_agent
1917         Smartcard: $build_scdaemon $build_scdaemon_extra
1918         G13:       $build_g13
1919         Dirmngr:   $build_dirmngr
1920         Gpgtar:    $build_gpgtar
1921
1922         Protect tool:      $show_gnupg_protect_tool_pgm
1923         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1924         Default agent:     $show_gnupg_agent_pgm
1925         Default pinentry:  $show_gnupg_pinentry_pgm
1926         Default scdaemon:  $show_gnupg_scdaemon_pgm
1927         Default dirmngr:   $show_gnupg_dirmngr_pgm
1928
1929         Dirmngr auto start:  $dirmngr_auto_start
1930         Readline support:    $gnupg_cv_have_readline
1931         LDAP support:        $gnupg_have_ldap
1932         DNS SRV support:     $use_dns_srv
1933         TLS support:         $use_tls_library
1934         TOFU support:        $use_tofu
1935         Tor support:         $show_tor_support
1936 "
1937 if test x"$use_regex" != xyes ; then
1938 echo "
1939         Warning: No regular expression support available.
1940                  OpenPGP trust signatures won't work.
1941                  gpg-check-pattern will not be built.
1942 "
1943 fi
1944 if test "x${gpg_config_script_warn}" != x; then
1945 cat <<G10EOF
1946         Warning: Mismatches between the target platform and the
1947                  to be used libraries have been detected for:
1948                   ${gpg_config_script_warn}
1949                  Please check above for more warning messages.
1950
1951 G10EOF
1952 fi