tools: Add experimental code for a pairing protocol
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2018 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2018 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg24", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.29
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.5.0
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119 # gpg is a required part and can't be disabled anymore.
120 build_gpg=yes
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
248 AC_ARG_WITH(agent-s2k-calibration,
249               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
250                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
251               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
252 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
253 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
254                    [Agent s2k calibration time (ms)])
255
256 AC_MSG_CHECKING([whether to enable trust models])
257 AC_ARG_ENABLE(trust-models,
258               AC_HELP_STRING([--disable-trust-models],
259                              [disable all trust models except "always"]),
260               use_trust_models=$enableval)
261 AC_MSG_RESULT($use_trust_models)
262 if test "$use_trust_models" = no ; then
263     AC_DEFINE(NO_TRUST_MODELS, 1,
264              [Define to include only trust-model always])
265 fi
266
267 AC_MSG_CHECKING([whether to enable TOFU])
268 AC_ARG_ENABLE(tofu,
269                 AC_HELP_STRING([--disable-tofu],
270                                [disable the TOFU trust model]),
271               use_tofu=$enableval, use_tofu=$use_trust_models)
272 AC_MSG_RESULT($use_tofu)
273 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
274     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
275 fi
276
277 AC_MSG_CHECKING([whether to enable libdns])
278 AC_ARG_ENABLE(libdns,
279                 AC_HELP_STRING([--disable-libdns],
280                                [do not build with libdns support]),
281               use_libdns=$enableval, use_libdns=yes)
282 AC_MSG_RESULT($use_libdns)
283 if test x"$use_libdns" = xyes ; then
284     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
285 fi
286 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
287
288
289 #
290 # Options to disable algorithm
291 #
292
293 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
294 # Elgamal is a MUST algorithm
295 # DSA is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
297 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
298 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
299
300 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
301 # 3DES is a MUST algorithm
302 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
303 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
307 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
309 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
310 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
311
312 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
313 # SHA1 is a MUST algorithm
314 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
315 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
316 # SHA256 is a MUST algorithm for GnuPG.
317 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
318 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
319
320
321 # Allow disabling of zip support.
322 # This is in general not a good idea because according to rfc4880 OpenPGP
323 # implementations SHOULD support ZLIB.
324 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
325 AC_ARG_ENABLE(zip,
326    AC_HELP_STRING([--disable-zip],
327                   [disable the ZIP and ZLIB compression algorithm]),
328    use_zip=$enableval)
329 AC_MSG_RESULT($use_zip)
330
331 # Allow disabling of bzib2 support.
332 # It is defined only after we confirm the library is available later
333 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
334 AC_ARG_ENABLE(bzip2,
335    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
336    use_bzip2=$enableval)
337 AC_MSG_RESULT($use_bzip2)
338
339 # Configure option to allow or disallow execution of external
340 # programs, like a photo viewer.
341 AC_MSG_CHECKING([whether to enable external program execution])
342 AC_ARG_ENABLE(exec,
343     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
344     use_exec=$enableval)
345 AC_MSG_RESULT($use_exec)
346 if test "$use_exec" = no ; then
347     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
348 fi
349
350 if test "$use_exec" = yes ; then
351   AC_MSG_CHECKING([whether to enable photo ID viewing])
352   AC_ARG_ENABLE(photo-viewers,
353       [  --disable-photo-viewers disable photo ID viewers],
354       [if test "$enableval" = no ; then
355          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
356       fi],enableval=yes)
357   gnupg_cv_enable_photo_viewers=$enableval
358   AC_MSG_RESULT($enableval)
359
360   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
361     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
362     AC_ARG_WITH(photo-viewer,
363         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
364         [if test "$withval" = yes ; then
365            withval=no
366         elif test "$withval" != no ; then
367            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
368                             [if set, restrict photo-viewer to this])
369         fi],withval=no)
370     AC_MSG_RESULT($withval)
371   fi
372 fi
373
374
375 #
376 # Check for the key/uid cache size.  This can't be zero, but can be
377 # pretty small on embedded systems.  This is used for the gpg part.
378 #
379 AC_MSG_CHECKING([for the size of the key and uid cache])
380 AC_ARG_ENABLE(key-cache,
381         AC_HELP_STRING([--enable-key-cache=SIZE],
382                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
383 if test "$enableval" = "no"; then
384    enableval=5
385 elif test "$enableval" = "yes" || test "$enableval" = ""; then
386    enableval=4096
387 fi
388 changequote(,)dnl
389 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
390 changequote([,])dnl
391 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
392    AC_MSG_ERROR([invalid key-cache size])
393 fi
394 AC_MSG_RESULT($key_cache_size)
395 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
396                   [Size of the key and UID caches])
397
398
399
400 #
401 # Check whether we want to use Linux capabilities
402 #
403 AC_MSG_CHECKING([whether use of capabilities is requested])
404 AC_ARG_WITH(capabilities,
405     [  --with-capabilities     use linux capabilities [default=no]],
406 [use_capabilities="$withval"],[use_capabilities=no])
407 AC_MSG_RESULT($use_capabilities)
408
409 #
410 # Check whether to disable the card support
411 AC_MSG_CHECKING([whether smartcard support is requested])
412 AC_ARG_ENABLE(card-support,
413               AC_HELP_STRING([--disable-card-support],
414                              [disable smartcard support]),
415               card_support=$enableval)
416 AC_MSG_RESULT($card_support)
417 if test "$card_support" = yes ; then
418   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
419 else
420   build_scdaemon=no
421 fi
422
423 #
424 # Allow disabling of internal CCID support.
425 # It is defined only after we confirm the library is available later
426 #
427 AC_MSG_CHECKING([whether to enable the internal CCID driver])
428 AC_ARG_ENABLE(ccid-driver,
429               AC_HELP_STRING([--disable-ccid-driver],
430                              [disable the internal CCID driver]),
431               use_ccid_driver=$enableval)
432 AC_MSG_RESULT($use_ccid_driver)
433
434 AC_MSG_CHECKING([whether to auto start dirmngr])
435 AC_ARG_ENABLE(dirmngr-auto-start,
436               AC_HELP_STRING([--disable-dirmngr-auto-start],
437                              [disable auto starting of the dirmngr]),
438               dirmngr_auto_start=$enableval)
439 AC_MSG_RESULT($dirmngr_auto_start)
440 if test "$dirmngr_auto_start" = yes ; then
441     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
442               [Define to enable auto starting of the dirmngr])
443 fi
444
445
446 #
447 # To avoid double inclusion of config.h which might happen at some
448 # places, we add the usual double inclusion protection at the top of
449 # config.h.
450 #
451 AH_TOP([
452 #ifndef GNUPG_CONFIG_H_INCLUDED
453 #define GNUPG_CONFIG_H_INCLUDED
454 ])
455
456 #
457 # Stuff which goes at the bottom of config.h.
458 #
459 AH_BOTTOM([
460 /* This is the major version number of GnuPG so that
461    source included files can test for this.  Note, that
462    we use 2 here even for GnuPG 1.9.x. */
463 #define GNUPG_MAJOR_VERSION 2
464
465 /* Now to separate file name parts.
466    Please note that the string version must not contain more
467    than one character because the code assumes strlen()==1 */
468 #ifdef HAVE_DOSISH_SYSTEM
469 #define DIRSEP_C '\\'
470 #define DIRSEP_S "\\"
471 #define EXTSEP_C '.'
472 #define EXTSEP_S "."
473 #define PATHSEP_C ';'
474 #define PATHSEP_S ";"
475 #define EXEEXT_S ".exe"
476 #else
477 #define DIRSEP_C '/'
478 #define DIRSEP_S "/"
479 #define EXTSEP_C '.'
480 #define EXTSEP_S "."
481 #define PATHSEP_C ':'
482 #define PATHSEP_S ":"
483 #define EXEEXT_S ""
484 #endif
485
486 /* This is the same as VERSION, but should be overridden if the
487    platform cannot handle things like dots '.' in filenames. Set
488    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
489    uses for dots and dashes. */
490 #define SAFE_VERSION VERSION
491 #define SAFE_VERSION_DOT  '.'
492 #define SAFE_VERSION_DASH '-'
493
494 /* Some global constants.
495  * Note that the homedir must not end in a slash.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
499 # else
500 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
501 # endif
502 #elif defined(__VMS)
503 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
504 #else
505 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
506 #endif
507 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
508 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
509 #define GNUPG_CACHE_DIR         "cache.d"
510
511 #define GNUPG_DEF_COPYRIGHT_LINE \
512         "Copyright (C) 2018 Free Software Foundation, Inc."
513
514 /* For some systems (DOS currently), we hardcode the path here.  For
515    POSIX systems the values are constructed by the Makefiles, so that
516    the values may be overridden by the make invocations; this is to
517    comply with the GNU coding standards.  Note that these values are
518    only defaults.  */
519 #ifdef HAVE_DOSISH_SYSTEM
520 # ifdef HAVE_DRIVE_LETTERS
521 #  define GNUPG_BINDIR      "c:\\gnupg"
522 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
523 #  define GNUPG_LIBDIR      "c:\\gnupg"
524 #  define GNUPG_DATADIR     "c:\\gnupg"
525 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
526 # else
527 #  define GNUPG_BINDIR      "\\gnupg"
528 #  define GNUPG_LIBEXECDIR  "\\gnupg"
529 #  define GNUPG_LIBDIR      "\\gnupg"
530 #  define GNUPG_DATADIR     "\\gnupg"
531 #  define GNUPG_SYSCONFDIR  "\\gnupg"
532 # endif
533 #endif
534
535 /* Derive some other constants. */
536 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
537 #define EXEC_TEMPFILE_ONLY
538 #endif
539
540
541 /* We didn't define endianness above, so get it from OS macros.  This
542    is intended for making fat binary builds on OS X. */
543 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
544 #if defined(__BIG_ENDIAN__)
545 #define BIG_ENDIAN_HOST 1
546 #elif defined(__LITTLE_ENDIAN__)
547 #define LITTLE_ENDIAN_HOST 1
548 #else
549 #error "No endianness found"
550 #endif
551 #endif
552
553
554 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
555    ldap_start_tls_s because that is the actual symbol used in the
556    library.  winldap.h redefines it to our commonly used value,
557    thus we define our usual macro here.  */
558 #ifdef HAVE_LDAP_START_TLS_SA
559 # ifndef HAVE_LDAP_START_TLS_S
560 #  define HAVE_LDAP_START_TLS_S 1
561 # endif
562 #endif
563
564 /* Enable the es_ macros from gpgrt.  */
565 #define GPGRT_ENABLE_ES_MACROS 1
566
567 /* Enable the log_ macros from gpgrt.  */
568 #define GPGRT_ENABLE_LOG_MACROS 1
569
570 /* Tell libgcrypt not to use its own libgpg-error implementation. */
571 #define USE_LIBGPG_ERROR 1
572
573 /* Tell Libgcrypt not to include deprecated definitions.  */
574 #define GCRYPT_NO_DEPRECATED 1
575
576 /* Our HTTP code is used in estream mode.  */
577 #define HTTP_USE_ESTREAM 1
578
579 /* Under W32 we do an explicit socket initialization, thus we need to
580    avoid the on-demand initialization which would also install an atexit
581    handler.  */
582 #define HTTP_NO_WSASTARTUP
583
584 /* Under Windows we use the gettext code from libgpg-error.  */
585 #define GPG_ERR_ENABLE_GETTEXT_MACROS
586
587 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
588 #define GPG_ERR_ENABLE_ERRNO_MACROS
589
590 #endif /*GNUPG_CONFIG_H_INCLUDED*/
591 ])
592
593
594 AM_MAINTAINER_MODE
595 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
596
597 # Checks for programs.
598 AC_MSG_NOTICE([checking for programs])
599 AC_PROG_MAKE_SET
600 AM_SANITY_CHECK
601 missing_dir=`cd $ac_aux_dir && pwd`
602 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
603 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
604 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
605 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
606 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
607 AM_SILENT_RULES
608 AC_PROG_AWK
609 AC_PROG_CC
610 AC_PROG_CPP
611 AM_PROG_CC_C_O
612 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
613   AC_MSG_ERROR([[No C-89 compiler found]])
614 fi
615 AC_PROG_INSTALL
616 AC_PROG_LN_S
617 AC_PROG_RANLIB
618 AC_CHECK_TOOL(AR, ar, :)
619 AC_PATH_PROG(PERL,"perl")
620 AC_CHECK_TOOL(WINDRES, windres, :)
621 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
622 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
623 AM_CONDITIONAL(HAVE_YAT2M, test -n "$ac_cv_path_YAT2M")
624 AC_ISC_POSIX
625 AC_SYS_LARGEFILE
626 GNUPG_CHECK_USTAR
627
628
629 # We need to compile and run a program on the build machine.  A
630 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
631 # the AC archive is broken for autoconf 2.57.  Given that there is no
632 # newer version of that macro, we assume that it is also broken for
633 # autoconf 2.61 and thus we use a simple but usually sufficient
634 # approach.
635 AC_MSG_CHECKING(for cc for build)
636 if test "$cross_compiling" = "yes"; then
637   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
638 else
639   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
640 fi
641 AC_MSG_RESULT($CC_FOR_BUILD)
642 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
643
644 # We need to call this macro because other pkg-config macros are
645 # not always used.
646 PKG_PROG_PKG_CONFIG
647
648
649 try_gettext=yes
650 require_iconv=yes
651 have_dosish_system=no
652 have_w32_system=no
653 have_w32ce_system=no
654 have_android_system=no
655 use_simple_gettext=no
656 use_ldapwrapper=yes
657 mmap_needed=yes
658 require_pipe_to_unblock_pselect=yes
659 case "${host}" in
660     *-mingw32*)
661         # special stuff for Windoze NT
662         ac_cv_have_dev_random=no
663         AC_DEFINE(USE_ONLY_8DOT3,1,
664                   [Set this to limit filenames to the 8.3 format])
665         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
666                   [Because the Unix gettext has too much overhead on
667                    MingW32 systems and these systems lack Posix functions,
668                    we use a simplified version of gettext])
669         have_dosish_system=yes
670         have_w32_system=yes
671         require_iconv=no
672         require_pipe_to_unblock_pselect=no
673         case "${host}" in
674           *-mingw32ce*)
675             have_w32ce_system=yes
676             ;;
677           *)
678             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
679                       [Defined if the OS supports drive letters.])
680             ;;
681         esac
682         try_gettext="no"
683         use_simple_gettext=yes
684         mmap_needed=no
685         ;;
686     i?86-emx-os2 | i?86-*-os2*emx )
687         # OS/2 with the EMX environment
688         ac_cv_have_dev_random=no
689         AC_DEFINE(HAVE_DRIVE_LETTERS)
690         have_dosish_system=yes
691         try_gettext="no"
692         ;;
693
694     i?86-*-msdosdjgpp*)
695         # DOS with the DJGPP environment
696         ac_cv_have_dev_random=no
697         AC_DEFINE(HAVE_DRIVE_LETTERS)
698         have_dosish_system=yes
699         try_gettext="no"
700         ;;
701
702     *-*-hpux*)
703         if test -z "$GCC" ; then
704             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
705         fi
706         ;;
707     *-dec-osf4*)
708         if test -z "$GCC" ; then
709             # Suppress all warnings
710             # to get rid of the unsigned/signed char mismatch warnings.
711             CFLAGS="-w $CFLAGS"
712         fi
713         ;;
714     *-dec-osf5*)
715         if test -z "$GCC" ; then
716             # Use the newer compiler `-msg_disable ptrmismatch1' to
717             # get rid of the unsigned/signed char mismatch warnings.
718             # Using this may hide other pointer mismatch warnings, but
719             # it at least lets other warning classes through
720             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
721         fi
722         ;;
723     m68k-atari-mint)
724         ;;
725     *-linux-android*)
726         have_android_system=yes
727         # Android is fully utf-8 and we do not want to use iconv to
728         # keeps things simple
729         require_iconv=no
730         ;;
731     *-apple-darwin*)
732         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
733                   Expose all libc features (__DARWIN_C_FULL).)
734         ;;
735     *-*-netbsd*)
736         require_pipe_to_unblock_pselect=yes
737         ;;
738     *)
739         ;;
740 esac
741
742 if test "$require_pipe_to_unblock_pselect" = yes; then
743    AC_DEFINE(HAVE_PSELECT_NO_EINTR, 1,
744              [Defined if we run on systems like NetBSD, where
745               pselect cannot be unblocked by signal from a thread
746               within the same process.  We use pipe in this case, instead.])
747 fi
748
749 if test "$have_dosish_system" = yes; then
750    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
751              [Defined if we run on some of the PCDOS like systems
752               (DOS, Windoze. OS/2) with special properties like
753               no file modes, case insensitive file names and preferred
754               use of backslashes as directory name separators.])
755 fi
756 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
757
758 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
759
760 if test "$have_w32_system" = yes; then
761    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
762    if test "$have_w32ce_system" = yes; then
763       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
764    fi
765 fi
766 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
767 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
768
769 if test "$have_android_system" = yes; then
770    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
771 fi
772 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
773
774
775 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
776 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
777
778
779 #
780 # Checks for libraries.
781 #
782 AC_MSG_NOTICE([checking for libraries])
783
784
785 #
786 # libgpg-error is a library with error codes shared between GnuPG
787 # related projects.
788 #
789 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
790                   have_gpg_error=yes,have_gpg_error=no)
791
792
793 #
794 # Libgcrypt is our generic crypto library
795 #
796 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
797         have_libgcrypt=yes,have_libgcrypt=no)
798
799
800 #
801 # libassuan is used for IPC
802 #
803 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
804                   have_libassuan=yes,have_libassuan=no)
805 if test "$have_libassuan" = "yes"; then
806   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
807                      [version of the libassuan library])
808   show_tor_support="only .onion"
809 fi
810
811
812 #
813 # libksba is our X.509 support library
814 #
815 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
816
817
818 #
819 # libusb allows us to use the integrated CCID smartcard reader driver.
820 #
821 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
822 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
823    case "${host}" in
824      *-mingw32*)
825        LIBUSB_NAME=
826        LIBUSB_LIBS=
827        LIBUSB_CPPFLAGS=
828        ;;
829      *-*-darwin*)
830        LIBUSB_NAME=usb-1.0
831        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
832        ;;
833      *-*-freebsd*)
834        # FreeBSD has a native 1.0 compatible library by -lusb.
835        LIBUSB_NAME=usb
836        LIBUSB_LIBS=
837        ;;
838      *)
839        LIBUSB_NAME=usb-1.0
840        LIBUSB_LIBS=
841        ;;
842    esac
843 fi
844 if test x"$LIBUSB_NAME" != x ; then
845    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
846                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
847                   have_libusb=yes ])
848    AC_MSG_CHECKING([libusb include dir])
849    usb_incdir_found="no"
850    for _incdir in "" "/usr/include/libusb-1.0" \
851        "/usr/local/include/libusb-1.0" "/usr/pkg/include/libusb-1.0"; do
852      _libusb_save_cppflags=$CPPFLAGS
853      if test -n "${_incdir}"; then
854        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
855      fi
856      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
857      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
858      CPPFLAGS=${_libusb_save_cppflags}
859      if test "$usb_incdir_found" = "yes"; then
860        break
861      fi
862    done
863    if test "$usb_incdir_found" = "yes"; then
864      AC_MSG_RESULT([${usb_incdir}])
865    else
866      AC_MSG_RESULT([not found])
867      usb_incdir=""
868      have_libusb=no
869      if test "$use_ccid_driver" != yes; then
870        use_ccid_driver=no
871      fi
872      LIBUSB_LIBS=""
873    fi
874
875    if test "$have_libusb" = yes; then
876      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
877    fi
878    if test x"$usb_incdir" = x; then
879      LIBUSB_CPPFLAGS=""
880    else
881      LIBUSB_CPPFLAGS="-I${usb_incdir}"
882    fi
883 fi
884 AC_SUBST(LIBUSB_LIBS)
885 AC_SUBST(LIBUSB_CPPFLAGS)
886
887 #
888 # Check whether it is necessary to link against libdl.
889 # (For example to load libpcsclite)
890 #
891 gnupg_dlopen_save_libs="$LIBS"
892 LIBS=""
893 AC_SEARCH_LIBS(dlopen, c dl,,,)
894 DL_LIBS=$LIBS
895 AC_SUBST(DL_LIBS)
896 LIBS="$gnupg_dlopen_save_libs"
897
898
899 # Checks for g10
900
901 AC_ARG_ENABLE(sqlite,
902                 AC_HELP_STRING([--disable-sqlite],
903                                [disable the use of SQLITE]),
904               try_sqlite=$enableval, try_sqlite=yes)
905
906 if test x"$use_tofu" = xyes ; then
907   if test x"$try_sqlite" = xyes ; then
908     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
909                                  [have_sqlite=yes],
910                                  [have_sqlite=no])
911   fi
912   if test "$have_sqlite" = "yes"; then
913     :
914     AC_SUBST([SQLITE3_CFLAGS])
915     AC_SUBST([SQLITE3_LIBS])
916   else
917     use_tofu=no
918     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
919     AC_MSG_WARN([[
920 ***
921 *** Building without SQLite support - TOFU disabled
922 ***
923 *** $tmp]])
924   fi
925 fi
926
927 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
928
929 if test x"$use_tofu" = xyes ; then
930     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
931 fi
932
933
934 # Checks for g13
935
936 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
937 AC_DEFINE_UNQUOTED(ENCFS,
938         "${ENCFS}", [defines the filename of the encfs program])
939
940 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
941 AC_DEFINE_UNQUOTED(FUSERMOUNT,
942         "${FUSERMOUNT}", [defines the filename of the fusermount program])
943
944
945 # Checks for dirmngr
946
947
948 #
949 # Checks for symcryptrun:
950 #
951
952 # libutil has openpty() and login_tty().
953 AC_CHECK_LIB(util, openpty,
954               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
955                 AC_DEFINE(HAVE_LIBUTIL,1,
956                          [defined if libutil is available])
957              ])
958 AC_SUBST(LIBUTIL_LIBS)
959
960 # shred is used to clean temporary plain text files.
961 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
962 AC_DEFINE_UNQUOTED(SHRED,
963         "${SHRED}", [defines the filename of the shred program])
964
965
966 #
967 # Check whether the nPth library is available
968 #
969 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
970 if test "$have_npth" = "yes"; then
971   AC_DEFINE(HAVE_NPTH, 1,
972               [Defined if the New Portable Thread Library is available])
973   AC_DEFINE(USE_NPTH, 1,
974               [Defined if support for nPth is requested and nPth is available])
975 else
976   AC_MSG_WARN([[
977 ***
978 *** To support concurrent access for example in gpg-agent and the SCdaemon
979 *** we need the support of the New Portable Threads Library.
980 ***]])
981 fi
982 #
983 # Enable debugging of nPth
984 #
985 AC_ARG_ENABLE(npth-debug,
986    AC_HELP_STRING([--enable-npth-debug],
987                   [build with debug version of npth]),
988                   [if test $enableval = yes ; then
989                      AC_DEFINE(NPTH_ENABLE_DEBUG,1,
990                               [Build with debug version of nPth])
991                   fi])
992
993
994
995 #
996 # NTBTLS is our TLS library.  If it is not available fallback to
997 # GNUTLS.
998 #
999 AC_ARG_ENABLE(ntbtls,
1000               AC_HELP_STRING([--disable-ntbtls],
1001                              [disable the use of NTBTLS as TLS library]),
1002               try_ntbtls=$enableval, try_ntbtls=yes)
1003 if test x"$try_ntbtls" = xyes ; then
1004   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
1005                  [have_ntbtls=yes],[have_ntbtls=no])
1006 fi
1007 if test "$have_ntbtls" = yes ; then
1008    use_tls_library=ntbtls
1009    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
1010 else
1011   AC_ARG_ENABLE(gnutls,
1012                 AC_HELP_STRING([--disable-gnutls],
1013                                [disable GNUTLS as fallback TLS library]),
1014                 try_gnutls=$enableval, try_gnutls=yes)
1015   if test x"$try_gnutls" = xyes ; then
1016     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
1017                                    [have_gnutls=yes],
1018                                    [have_gnutls=no])
1019   fi
1020   if test "$have_gnutls" = "yes"; then
1021     AC_SUBST([LIBGNUTLS_CFLAGS])
1022     AC_SUBST([LIBGNUTLS_LIBS])
1023     use_tls_library=gnutls
1024     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
1025   else
1026     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1027     AC_MSG_WARN([[
1028 ***
1029 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1030 ***
1031 *** $tmp]])
1032   fi
1033 fi
1034
1035 #
1036 # Allow to set a fixed trust store file for system provided certificates.
1037 #
1038 AC_ARG_WITH([default-trust-store-file],
1039             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1040                             [Use FILE as system trust store])],
1041             default_trust_store_file="$withval",
1042             default_trust_store_file="")
1043 if test x"$default_trust_store_file" = xno;then
1044   default_trust_store_file=""
1045 fi
1046 if test x"$default_trust_store_file" != x ; then
1047   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1048     ["$default_trust_store_file"], [Use as default system trust store file])
1049 fi
1050
1051
1052 AC_MSG_NOTICE([checking for networking options])
1053
1054 #
1055 # Must check for network library requirements before doing link tests
1056 # for ldap, for example. If ldap libs are static (or dynamic and without
1057 # ELF runtime link paths), then link will fail and LDAP support won't
1058 # be detected.
1059 #
1060 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1061         [NETLIBS="-lnsl $NETLIBS"]))
1062 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1063         [NETLIBS="-lsocket $NETLIBS"]))
1064
1065
1066 #
1067 # Check standard resolver functions.
1068 #
1069 if test "$build_dirmngr" = "yes"; then
1070   _dns_save_libs=$LIBS
1071   LIBS=""
1072
1073   # Find the system resolver which can always be enabled with
1074   # the dirmngr option --standard-resolver.
1075
1076   # the double underscore thing is a glibc-ism?
1077   AC_SEARCH_LIBS(res_query,resolv bind,,
1078                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1079   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1080                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1081
1082   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1083   # and for some reason fools us into believing we don't need
1084   # -lresolv even if we do.  Since the test program checking for the
1085   # symbol does not include <resolv.h>, we need to check for the
1086   # renamed symbol explicitly.
1087   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1088       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1089           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1090
1091   if test x"$have_resolver" != xno ; then
1092
1093       # Make sure that the BIND 4 resolver interface is workable before
1094       # enabling any code that calls it.  At some point I'll rewrite the
1095       # code to use the BIND 8 resolver API.
1096       # We might also want to use libdns instead.
1097
1098     AC_MSG_CHECKING([whether the resolver is usable])
1099     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1100 #include <netinet/in.h>
1101 #include <arpa/nameser.h>
1102 #include <resolv.h>]],
1103 [[unsigned char answer[PACKETSZ];
1104   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1105   dn_skipname(0,0);
1106   dn_expand(0,0,0,0,0);
1107 ]])],have_resolver=yes,have_resolver=no)
1108     AC_MSG_RESULT($have_resolver)
1109
1110     # This is Apple-specific and somewhat bizarre as they changed the
1111     # define in bind 8 for some reason.
1112
1113     if test x"$have_resolver" != xyes ; then
1114       AC_MSG_CHECKING(
1115            [whether I can make the resolver usable with BIND_8_COMPAT])
1116       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1117 #include <sys/types.h>
1118 #include <netinet/in.h>
1119 #include <arpa/nameser.h>
1120 #include <resolv.h>]],
1121 [[unsigned char answer[PACKETSZ];
1122   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1123   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1124 ]])],[have_resolver=yes ; need_compat=yes])
1125       AC_MSG_RESULT($have_resolver)
1126     fi
1127   fi
1128
1129   if test x"$have_resolver" = xyes ; then
1130     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1131     DNSLIBS="$DNSLIBS $LIBS"
1132     if test x"$need_compat" = xyes ; then
1133       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1134     fi
1135     if test "$use_libdns" = yes; then
1136      show_tor_support=yes
1137     fi
1138   elif test "$use_libdns" = yes; then
1139     show_tor_support=yes
1140   else
1141     AC_MSG_WARN([[
1142 ***
1143 *** The system's DNS resolver is not usable.
1144 *** Dirmngr functionality is limited.
1145 ***]])
1146     show_tor_support="${show_tor_support} (no system resolver)"
1147   fi
1148
1149   if test "$have_w32_system" = yes; then
1150     if test "$use_libdns" = yes; then
1151       DNSLIBS="$DNSLIBS -liphlpapi"
1152     fi
1153   fi
1154
1155   LIBS=$_dns_save_libs
1156 fi
1157
1158 AC_SUBST(DNSLIBS)
1159
1160
1161 #
1162 # Check for LDAP
1163 #
1164 # Note that running the check changes the variable
1165 # gnupg_have_ldap from "n/a" to "no" or "yes".
1166
1167 AC_ARG_ENABLE(ldap,
1168     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1169     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1170
1171 if test "$gnupg_have_ldap" != "no" ; then
1172   if test "$build_dirmngr" = "yes" ; then
1173      GNUPG_CHECK_LDAP($NETLIBS)
1174      AC_CHECK_LIB(lber, ber_free,
1175                   [ LBER_LIBS="$LBER_LIBS -llber"
1176                     AC_DEFINE(HAVE_LBER,1,
1177                              [defined if liblber is available])
1178                     have_lber=yes
1179                  ])
1180   fi
1181 fi
1182 AC_SUBST(LBER_LIBS)
1183 if test "$gnupg_have_ldap" = "no"; then
1184     AC_MSG_WARN([[
1185 ***
1186 *** Building without LDAP support.
1187 *** No CRL access or X.509 certificate search available.
1188 ***]])
1189 fi
1190
1191 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1192 if test "$gnupg_have_ldap" = yes ; then
1193   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1194 else
1195  use_ldapwrapper=no
1196 fi
1197
1198 if test "$use_ldapwrapper" = yes; then
1199    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1200 fi
1201 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1202
1203
1204
1205
1206 #
1207 # Check for sendmail
1208 #
1209 # This isn't necessarily sendmail itself, but anything that gives a
1210 # sendmail-ish interface to the outside world.  That includes Exim,
1211 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1212 AC_ARG_WITH(mailprog,
1213       AC_HELP_STRING([--with-mailprog=NAME],
1214                      [use "NAME -t" for mail transport]),
1215              ,with_mailprog=yes)
1216 if test x"$with_mailprog" = xyes ; then
1217     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1218 elif test x"$with_mailprog" != xno ; then
1219     AC_MSG_CHECKING([for a mail transport program])
1220     AC_SUBST(SENDMAIL,$with_mailprog)
1221     AC_MSG_RESULT($with_mailprog)
1222 fi
1223 AC_DEFINE_UNQUOTED(NAME_OF_SENDMAIL,"$SENDMAIL",
1224                    [Tool with sendmail -t interface])
1225
1226
1227 #
1228 # Construct a printable name of the OS
1229 #
1230 case "${host}" in
1231     *-mingw32ce*)
1232         PRINTABLE_OS_NAME="W32CE"
1233         ;;
1234     *-mingw32*)
1235         PRINTABLE_OS_NAME="MingW32"
1236         ;;
1237     *-*-cygwin*)
1238         PRINTABLE_OS_NAME="Cygwin"
1239         ;;
1240     i?86-emx-os2 | i?86-*-os2*emx )
1241         PRINTABLE_OS_NAME="OS/2"
1242         ;;
1243     i?86-*-msdosdjgpp*)
1244         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1245         try_dynload=no
1246         ;;
1247     *-linux*)
1248         PRINTABLE_OS_NAME="GNU/Linux"
1249         ;;
1250     *)
1251         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1252         ;;
1253 esac
1254 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1255                    [A human readable text with the name of the OS])
1256
1257
1258 #
1259 # Checking for iconv
1260 #
1261 if test "$require_iconv" = yes; then
1262   AM_ICONV
1263 else
1264   LIBICONV=
1265   LTLIBICONV=
1266   AC_SUBST(LIBICONV)
1267   AC_SUBST(LTLIBICONV)
1268 fi
1269
1270
1271 #
1272 # Check for gettext
1273 #
1274 # This is "GNU gnupg" - The project-id script from gettext
1275 #                       needs this string
1276 #
1277 AC_MSG_NOTICE([checking for gettext])
1278 AM_PO_SUBDIRS
1279 AM_GNU_GETTEXT_VERSION([0.17])
1280 if test "$try_gettext" = yes; then
1281   AM_GNU_GETTEXT([external],[need-ngettext])
1282
1283   # gettext requires some extra checks.  These really should be part of
1284   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1285   # function checks to here.
1286
1287   AC_CHECK_FUNCS(strchr)
1288 else
1289   USE_NLS=no
1290   USE_INCLUDED_LIBINTL=no
1291   BUILD_INCLUDED_LIBINTL=no
1292   POSUB=po
1293   AC_SUBST(USE_NLS)
1294   AC_SUBST(USE_INCLUDED_LIBINTL)
1295   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1296   AC_SUBST(POSUB)
1297 fi
1298
1299 # We use HAVE_LANGINFO_CODESET in a couple of places.
1300 AM_LANGINFO_CODESET
1301
1302 # Checks required for our use of locales
1303 gt_LC_MESSAGES
1304
1305
1306 #
1307 # SELinux support
1308 #
1309 if test "$selinux_support" = yes ; then
1310   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1311 fi
1312
1313
1314 #
1315 # Checks for header files.
1316 #
1317 AC_MSG_NOTICE([checking for header files])
1318 AC_HEADER_STDC
1319 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1320                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1321                   stdint.h signal.h util.h libutil.h termios.h \
1322                   ucred.h sys/ucred.h sys/sysmacros.h sys/mkdev.h])
1323
1324 AC_HEADER_TIME
1325
1326
1327 #
1328 # Checks for typedefs, structures, and compiler characteristics.
1329 #
1330 AC_MSG_NOTICE([checking for system characteristics])
1331 AC_C_CONST
1332 AC_C_INLINE
1333 AC_C_VOLATILE
1334 AC_TYPE_SIZE_T
1335 AC_TYPE_MODE_T
1336 AC_TYPE_SIGNAL
1337 AC_DECL_SYS_SIGLIST
1338
1339 gl_HEADER_SYS_SOCKET
1340 gl_TYPE_SOCKLEN_T
1341
1342 AC_SEARCH_LIBS([inet_addr], [nsl])
1343
1344 AC_ARG_ENABLE(endian-check,
1345               AC_HELP_STRING([--disable-endian-check],
1346               [disable the endian check and trust the OS provided macros]),
1347               endiancheck=$enableval,endiancheck=yes)
1348
1349 if test x"$endiancheck" = xyes ; then
1350   GNUPG_CHECK_ENDIAN
1351 fi
1352
1353 # fixme: we should get rid of the byte type
1354 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1355 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1356 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1357 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1358 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1359
1360 AC_CHECK_SIZEOF(unsigned short)
1361 AC_CHECK_SIZEOF(unsigned int)
1362 AC_CHECK_SIZEOF(unsigned long)
1363 AC_CHECK_SIZEOF(unsigned long long)
1364 AC_HEADER_TIME
1365 AC_CHECK_SIZEOF(time_t,,[[
1366 #include <stdio.h>
1367 #if TIME_WITH_SYS_TIME
1368 # include <sys/time.h>
1369 # include <time.h>
1370 #else
1371 # if HAVE_SYS_TIME_H
1372 #  include <sys/time.h>
1373 # else
1374 #  include <time.h>
1375 # endif
1376 #endif
1377 ]])
1378 GNUPG_TIME_T_UNSIGNED
1379
1380
1381 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1382    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1383    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1384     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1385 fi
1386
1387
1388 #
1389 # Checks for library functions.
1390 #
1391 AC_MSG_NOTICE([checking for library functions])
1392 AC_CHECK_DECLS(getpagesize)
1393 AC_FUNC_FSEEKO
1394 AC_FUNC_VPRINTF
1395 AC_FUNC_FORK
1396 AC_CHECK_FUNCS([atexit canonicalize_file_name clock_gettime ctermid  \
1397                 fcntl flockfile fsync ftello ftruncate funlockfile   \
1398                 getaddrinfo getenv getpagesize getpwnam getpwuid     \
1399                 getrlimit getrusage gettimeofday gmtime_r            \
1400                 inet_ntop inet_pton isascii lstat                    \
1401                 memicmp memmove memrchr mmap nl_langinfo pipe        \
1402                 raise rand setenv setlocale setrlimit sigaction      \
1403                 sigprocmask stat stpcpy strcasecmp strerror strftime \
1404                 stricmp strlwr strncasecmp strpbrk strsep            \
1405                 strtol strtoul strtoull tcgetattr timegm times       \
1406                 ttyname unsetenv wait4 waitpid ])
1407
1408 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1409 # Given that we use nanosleep only as an optimization over a select
1410 # based wait function we want it only if it is available in libc.
1411 _save_libs="$LIBS"
1412 AC_SEARCH_LIBS([nanosleep], [],
1413                [AC_DEFINE(HAVE_NANOSLEEP,1,
1414                 [Define to 1 if you have the `nanosleep' function in libc.])])
1415 LIBS="$_save_libs"
1416
1417
1418 # See whether libc supports the Linux inotify interface
1419 case "${host}" in
1420     *-*-linux*)
1421         AC_CHECK_FUNCS([inotify_init])
1422         ;;
1423 esac
1424
1425
1426 if test "$have_android_system" = yes; then
1427    # On Android ttyname is a stub but prints an error message.
1428    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1429              [Defined if ttyname does not work properly])
1430 fi
1431
1432 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1433
1434 # Dirmngr requires mmap on Unix systems.
1435 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1436   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1437 fi
1438
1439
1440 #
1441 # Check for the getsockopt SO_PEERCRED, etc.
1442 #
1443 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1444 #include <sys/socket.h> ])
1445
1446 # (Open)Solaris
1447 AC_CHECK_FUNCS([getpeerucred])
1448
1449
1450 #
1451 # W32 specific test
1452 #
1453 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1454
1455 #
1456 # Sanity check regex.  Tests adapted from mutt.
1457 #
1458 AC_MSG_CHECKING([whether regular expression support is requested])
1459 AC_ARG_ENABLE(regex,
1460   AC_HELP_STRING([--disable-regex],
1461     [do not handle regular expressions in trust signatures]),
1462   use_regex=$enableval, use_regex=yes)
1463 AC_MSG_RESULT($use_regex)
1464
1465 if test "$use_regex" = yes ; then
1466   _cppflags="${CPPFLAGS}"
1467   _ldflags="${LDFLAGS}"
1468   AC_ARG_WITH(regex,
1469      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1470       [
1471       if test -d "$withval" ; then
1472         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1473         LDFLAGS="${LDFLAGS} -L$withval/lib"
1474       fi
1475       ],withval="")
1476
1477   # Does the system have regex functions at all?
1478   AC_SEARCH_LIBS([regcomp], [regex])
1479   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1480
1481   if test $gnupg_cv_have_regex = no; then
1482     use_regex=no
1483   else
1484     if test x"$cross_compiling" = xyes; then
1485       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1486     else
1487       AC_CACHE_CHECK([whether your system's regexp library is broken],
1488        [gnupg_cv_regex_broken],
1489        AC_TRY_RUN([
1490 #include <unistd.h>
1491 #include <regex.h>
1492 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1493        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1494
1495       if test $gnupg_cv_regex_broken = yes; then
1496         AC_MSG_WARN([your regex is broken - disabling regex use])
1497         use_regex=no
1498       fi
1499     fi
1500   fi
1501   CPPFLAGS="${_cppflags}"
1502   LDFLAGS="${_ldflags}"
1503 fi
1504
1505 if test "$use_regex" != yes ; then
1506   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1507 fi
1508 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1509
1510
1511
1512 #
1513 # Do we have zlib? Must do it here because Solaris failed
1514 # when compiling a conftest (due to the "-lz" from LIBS).
1515 # Note that we combine zlib and bzlib2 in ZLIBS.
1516 #
1517 if test "$use_zip" = yes ; then
1518   _cppflags="${CPPFLAGS}"
1519   _ldflags="${LDFLAGS}"
1520   AC_ARG_WITH(zlib,
1521     [  --with-zlib=DIR         use libz in DIR],[
1522       if test -d "$withval"; then
1523         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1524         LDFLAGS="${LDFLAGS} -L$withval/lib"
1525       fi
1526     ])
1527
1528   AC_CHECK_HEADER(zlib.h,
1529      AC_CHECK_LIB(z, deflateInit2_,
1530        [
1531        ZLIBS="-lz"
1532        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1533        ],
1534        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1535        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1536 fi
1537
1538
1539 #
1540 # Check whether we can support bzip2
1541 #
1542 if test "$use_bzip2" = yes ; then
1543   _cppflags="${CPPFLAGS}"
1544   _ldflags="${LDFLAGS}"
1545   AC_ARG_WITH(bzip2,
1546      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1547       [
1548       if test -d "$withval" ; then
1549         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1550         LDFLAGS="${LDFLAGS} -L$withval/lib"
1551       fi
1552       ],withval="")
1553
1554   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1555   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1556   # woefully out of date.
1557   if test "$withval" != no ; then
1558      AC_CHECK_HEADER(bzlib.h,
1559         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1560           [
1561           have_bz2=yes
1562           ZLIBS="$ZLIBS -lbz2"
1563           AC_DEFINE(HAVE_BZIP2,1,
1564                   [Defined if the bz2 compression library is available])
1565           ],
1566           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1567           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1568   fi
1569 fi
1570 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1571 AC_SUBST(ZLIBS)
1572
1573
1574 # Check for readline support
1575 GNUPG_CHECK_READLINE
1576
1577
1578 if test "$development_version" = yes; then
1579     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1580             [Defined if this is not a regular release])
1581 fi
1582
1583 if test "$USE_MAINTAINER_MODE" = "yes"; then
1584     AC_DEFINE(MAINTAINER_MODE,1,
1585             [Defined if this build is in maintainer mode])
1586 fi
1587
1588 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1589
1590 GNUPG_CHECK_GNUMAKE
1591
1592 # Add some extra libs here so that previous tests don't fail for
1593 # mysterious reasons - the final link step should bail out.
1594 # W32SOCKLIBS is also defined so that if can be used for tools not
1595 # requiring any network stuff but linking to code in libcommon which
1596 # tracks in winsock stuff (e.g. init_common_subsystems).
1597 if test "$have_w32_system" = yes; then
1598    if test "$have_w32ce_system" = yes; then
1599      W32SOCKLIBS="-lws2"
1600    else
1601      W32SOCKLIBS="-lws2_32"
1602    fi
1603    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1604 fi
1605
1606 AC_SUBST(NETLIBS)
1607 AC_SUBST(W32SOCKLIBS)
1608
1609 #
1610 # Setup gcc specific options
1611 #
1612 USE_C99_CFLAGS=
1613 AC_MSG_NOTICE([checking for cc features])
1614 if test "$GCC" = yes; then
1615     mycflags=
1616     mycflags_save=$CFLAGS
1617
1618     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1619     # options.  This is the case for gcc >= 4.6
1620     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1621     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1622 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1623 #kickerror
1624 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1625     AC_MSG_RESULT($_gcc_silent_wno)
1626
1627     # Note that it is okay to use CFLAGS here because these are just
1628     # warning options and the user should have a chance of overriding
1629     # them.
1630     if test "$USE_MAINTAINER_MODE" = "yes"; then
1631         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1632         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1633         if test x"$_gcc_silent_wno" = xyes ; then
1634           _gcc_wopt=yes
1635         else
1636           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1637           CFLAGS="-Wno-missing-field-initializers"
1638           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1639                             [_gcc_wopt=yes],[_gcc_wopt=no])
1640           AC_MSG_RESULT($_gcc_wopt)
1641         fi
1642         if test x"$_gcc_wopt" = xyes ; then
1643           mycflags="$mycflags -W -Wno-sign-compare -Wno-format-zero-length"
1644           mycflags="$mycflags -Wno-missing-field-initializers"
1645         fi
1646
1647         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1648         CFLAGS="-Wdeclaration-after-statement"
1649         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1650         AC_MSG_RESULT($_gcc_wopt)
1651         if test x"$_gcc_wopt" = xyes ; then
1652           mycflags="$mycflags -Wdeclaration-after-statement"
1653         fi
1654
1655         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1656         CFLAGS="-Wlogical-op -Werror"
1657         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1658         AC_MSG_RESULT($_gcc_wopt)
1659         if test x"$_gcc_wopt" = xyes ; then
1660           mycflags="$mycflags -Wlogical-op"
1661         fi
1662
1663         AC_MSG_CHECKING([if gcc supports -Wvla])
1664         CFLAGS="-Wvla"
1665         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1666         AC_MSG_RESULT($_gcc_wopt)
1667         if test x"$_gcc_wopt" = xyes ; then
1668           mycflags="$mycflags -Wvla"
1669         fi
1670
1671     else
1672         mycflags="$mycflags -Wall"
1673     fi
1674
1675     if test x"$_gcc_silent_wno" = xyes ; then
1676       _gcc_psign=yes
1677     else
1678       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1679       CFLAGS="-Wno-pointer-sign"
1680       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1681                         [_gcc_psign=yes],[_gcc_psign=no])
1682       AC_MSG_RESULT($_gcc_psign)
1683     fi
1684     if test x"$_gcc_psign" = xyes ; then
1685        mycflags="$mycflags -Wno-pointer-sign"
1686     fi
1687
1688     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1689     CFLAGS="-Wpointer-arith"
1690     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1691     AC_MSG_RESULT($_gcc_psign)
1692     if test x"$_gcc_psign" = xyes ; then
1693        mycflags="$mycflags -Wpointer-arith"
1694     fi
1695
1696     CFLAGS="$mycflags $mycflags_save"
1697     if test "$use_libdns" = yes; then
1698        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1699        USE_C99_CFLAGS="-std=gnu99"
1700     fi
1701 fi
1702
1703 AC_SUBST(USE_C99_CFLAGS)
1704
1705
1706 #
1707 # This is handy for debugging so the compiler doesn't rearrange
1708 # things and eliminate variables.
1709 #
1710 AC_ARG_ENABLE(optimization,
1711    AC_HELP_STRING([--disable-optimization],
1712                   [disable compiler optimization]),
1713                   [if test $enableval = no ; then
1714                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1715                    fi])
1716
1717 #
1718 # log_debug has certain requirements which might hamper portability.
1719 # Thus we use an option to enable it.
1720 #
1721 AC_MSG_CHECKING([whether to enable log_clock])
1722 AC_ARG_ENABLE(log_clock,
1723               AC_HELP_STRING([--enable-log-clock],
1724                              [enable log_clock timestamps]),
1725               enable_log_clock=$enableval, enable_log_clock=no)
1726 AC_MSG_RESULT($enable_log_clock)
1727 if test "$enable_log_clock" = yes ; then
1728   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1729 fi
1730
1731 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1732 # misbehaving autoconf tests in case the user supplied -Werror.
1733 #
1734 AC_ARG_ENABLE(werror,
1735    AC_HELP_STRING([--enable-werror],
1736                   [append -Werror to CFLAGS]),
1737                   [if test $enableval = yes ; then
1738                       CFLAGS="$CFLAGS -Werror"
1739                    fi])
1740
1741 #
1742 # Configure option --enable-all-tests
1743 #
1744 AC_MSG_CHECKING([whether "make check" shall run all tests])
1745 AC_ARG_ENABLE(all-tests,
1746               AC_HELP_STRING([--enable-all-tests],
1747                              [let "make check" run all tests]),
1748               run_all_tests=$enableval, run_all_tests=no)
1749 AC_MSG_RESULT($run_all_tests)
1750 if test "$run_all_tests" = "yes"; then
1751     AC_DEFINE(RUN_ALL_TESTS,1,
1752             [Defined if "make check" shall run all tests])
1753 fi
1754
1755 #
1756 # We do not want support for the GNUPG_BUILDDIR environment variable
1757 # in a released version.  However, our regression tests suite requires
1758 # this and thus we build with support for it during "make distcheck".
1759 # This configure option implements this along with the top Makefile's
1760 # AM_DISTCHECK_CONFIGURE_FLAGS.
1761 #
1762 gnupg_builddir_envvar=no
1763 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1764               gnupg_builddir_envvar=$enableval)
1765 if test x"$gnupg_builddir_envvar" = x"yes"; then
1766    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1767       [This is only used with "make distcheck"])
1768 fi
1769
1770
1771 #
1772 # To avoid problems with systemd cleaning up the /run/user directory,
1773 # this option will make GnuPG try to use /run/gnupg/user as socket dir
1774 # before /run/user
1775 #
1776 AC_ARG_ENABLE(run-gnupg-user-socket,
1777     AC_HELP_STRING([--enable-run-gnupg-user-socket],
1778                    [try /run/gnupg/user for sockets prior to /run/user]),
1779     use_run_gnupg_user_socket=$enableval)
1780 if test x"$use_run_gnupg_user_socket" = x"yes"; then
1781    AC_DEFINE(USE_RUN_GNUPG_USER_SOCKET, 1,
1782             [If defined try /run/gnupg/user before /run/user])
1783 fi
1784
1785
1786 #
1787 # Decide what to build
1788 #
1789
1790 build_scdaemon_extra=""
1791 if test "$build_scdaemon" = "yes"; then
1792   if test $have_libusb = no; then
1793      build_scdaemon_extra="without internal CCID driver"
1794   fi
1795   if test -n "$build_scdaemon_extra"; then
1796      build_scdaemon_extra="(${build_scdaemon_extra})"
1797   fi
1798 fi
1799
1800
1801 #
1802 # Set variables for use by automake makefiles.
1803 #
1804 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1805 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1806 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1807 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1808 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1809 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1810 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1811 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1812 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1813 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1814
1815 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1816 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1817 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1818
1819 #
1820 # Set some defines for use gpgconf.
1821 #
1822 if test "$build_gpg" = yes ; then
1823     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1824 fi
1825 if test "$build_gpgsm" = yes ; then
1826     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1827 fi
1828 if test "$build_agent" = yes ; then
1829     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1830 fi
1831 if test "$build_scdaemon" = yes ; then
1832     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1833 fi
1834 if test "$build_dirmngr" = yes ; then
1835     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1836 fi
1837 if test "$build_g13" = yes ; then
1838     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1839 fi
1840
1841
1842 #
1843 # Define Name strings
1844 #
1845 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1846
1847 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1848 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1849
1850 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1851 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1852
1853 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1854 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1855                                         [The displayed name of gpg-agent])
1856
1857 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1858 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1859                                        [The displayed name of scdaemon])
1860
1861 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1862 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1863                                       [The displayed name of dirmngr])
1864
1865 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1866 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1867
1868 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1869 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1870                                       [The displayed name of gpgconf])
1871
1872 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1873
1874 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1875                    [The name of the agent socket])
1876 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1877                    [The name of the agent socket for remote access])
1878 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1879                    [The name of the agent socket for browsers])
1880 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1881                    [The name of the agent socket for ssh])
1882 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1883                    [The name of the dirmngr info envvar])
1884 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1885                    [The name of the SCdaemon socket])
1886 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1887                    [The name of the dirmngr socket])
1888 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1889                    "hkps://hkps.pool.sks-keyservers.net",
1890       [The default keyserver for dirmngr to use, if none is explicitly given])
1891
1892 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1893
1894 if test "$have_w32_system" = yes; then
1895   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1896                      [The directory part of the W32 registry keys])
1897 fi
1898
1899
1900 #
1901 # Provide information about the build.
1902 #
1903 BUILD_REVISION="mym4_revision"
1904 AC_SUBST(BUILD_REVISION)
1905 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1906                    [GIT commit id revision used to build this package])
1907
1908 changequote(,)dnl
1909 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1910 changequote([,])dnl
1911 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1912 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1913 AC_SUBST(BUILD_VERSION)
1914 AC_SUBST(BUILD_FILEVERSION)
1915
1916 AC_ARG_ENABLE([build-timestamp],
1917   AC_HELP_STRING([--enable-build-timestamp],
1918                  [set an explicit build timestamp for reproducibility.
1919                   (default is the current time in ISO-8601 format)]),
1920      [if test "$enableval" = "yes"; then
1921         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1922       else
1923         BUILD_TIMESTAMP="$enableval"
1924       fi
1925       BUILD_HOSTNAME="$ac_hostname"],
1926      [BUILD_TIMESTAMP="<none>"
1927       BUILD_HOSTNAME="<anon>"])
1928 AC_SUBST(BUILD_TIMESTAMP)
1929 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1930                    [The time this package was configured for a build])
1931 AC_SUBST(BUILD_HOSTNAME)
1932
1933
1934 #
1935 # Print errors here so that they are visible all
1936 # together and the user can acquire them all together.
1937 #
1938 die=no
1939 if test "$have_gpg_error" = "no"; then
1940    die=yes
1941    AC_MSG_NOTICE([[
1942 ***
1943 *** You need libgpg-error to build this program.
1944 **  This library is for example available at
1945 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1946 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1947 ***]])
1948 fi
1949 if test "$have_libgcrypt" = "no"; then
1950    die=yes
1951    AC_MSG_NOTICE([[
1952 ***
1953 *** You need libgcrypt to build this program.
1954 **  This library is for example available at
1955 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1956 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1957 ***]])
1958 fi
1959 if test "$have_libassuan" = "no"; then
1960    die=yes
1961    AC_MSG_NOTICE([[
1962 ***
1963 *** You need libassuan to build this program.
1964 *** This library is for example available at
1965 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1966 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1967 ***]])
1968 fi
1969 if test "$have_ksba" = "no"; then
1970     die=yes
1971     AC_MSG_NOTICE([[
1972 ***
1973 *** You need libksba to build this program.
1974 *** This library is for example available at
1975 ***   https://gnupg.org/ftp/gcrypt/libksba/
1976 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1977 ***]])
1978 fi
1979 if test "$gnupg_have_ldap" = yes; then
1980   if test "$have_w32ce_system" = yes; then
1981     AC_MSG_NOTICE([[
1982 *** Note that CeGCC might be broken, a package fixing this is:
1983 ***    http://files.kolab.org/local/windows-ce/
1984 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1985 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1986 ***]])
1987    fi
1988 fi
1989 if test "$have_npth" = "no"; then
1990     die=yes
1991     AC_MSG_NOTICE([[
1992 ***
1993 *** It is now required to build with support for the
1994 *** New Portable Threads Library (nPth). Please install this
1995 *** library first.  The library is for example available at
1996 ***   https://gnupg.org/ftp/gcrypt/npth/
1997 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1998 ***]])
1999 fi
2000
2001 if test "$require_iconv" = yes; then
2002   if test "$am_func_iconv" != yes; then
2003     die=yes
2004     AC_MSG_NOTICE([[
2005 ***
2006 *** The system does not provide a working iconv function.  Please
2007 *** install a suitable library; for example GNU Libiconv which is
2008 *** available at:
2009 ***   https://ftp.gnu.org/gnu/libiconv/
2010 ***]])
2011   fi
2012 fi
2013
2014 if test "$use_ccid_driver" = yes; then
2015   if test "$have_libusb" != yes; then
2016     die=yes
2017     AC_MSG_NOTICE([[
2018 ***
2019 *** You need libusb to build the internal ccid driver.  Please
2020 *** install a libusb suitable for your system.
2021 ***]])
2022   fi
2023 fi
2024
2025 if test "$die" = "yes"; then
2026     AC_MSG_ERROR([[
2027 ***
2028 *** Required libraries not found. Please consult the above messages
2029 *** and install them before running configure again.
2030 ***]])
2031 fi
2032
2033
2034
2035 AC_CONFIG_FILES([ m4/Makefile
2036 Makefile
2037 po/Makefile.in
2038 common/Makefile
2039 common/w32info-rc.h
2040 kbx/Makefile
2041 g10/Makefile
2042 sm/Makefile
2043 agent/Makefile
2044 scd/Makefile
2045 g13/Makefile
2046 dirmngr/Makefile
2047 tools/gpg-zip
2048 tools/Makefile
2049 doc/Makefile
2050 tests/Makefile
2051 tests/gpgscm/Makefile
2052 tests/openpgp/Makefile
2053 tests/migrations/Makefile
2054 tests/gpgsm/Makefile
2055 tests/gpgme/Makefile
2056 tests/pkits/Makefile
2057 g10/gpg.w32-manifest
2058 ])
2059
2060
2061 AC_OUTPUT
2062
2063
2064 echo "
2065         GnuPG v${VERSION} has been configured as follows:
2066
2067         Revision:  mym4_revision  (mym4_revision_dec)
2068         Platform:  $PRINTABLE_OS_NAME ($host)
2069
2070         OpenPGP:   $build_gpg
2071         S/MIME:    $build_gpgsm
2072         Agent:     $build_agent
2073         Smartcard: $build_scdaemon $build_scdaemon_extra
2074         G13:       $build_g13
2075         Dirmngr:   $build_dirmngr
2076         Gpgtar:    $build_gpgtar
2077         WKS tools: $build_wks_tools
2078
2079         Protect tool:      $show_gnupg_protect_tool_pgm
2080         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2081         Default agent:     $show_gnupg_agent_pgm
2082         Default pinentry:  $show_gnupg_pinentry_pgm
2083         Default scdaemon:  $show_gnupg_scdaemon_pgm
2084         Default dirmngr:   $show_gnupg_dirmngr_pgm
2085
2086         Dirmngr auto start:  $dirmngr_auto_start
2087         Readline support:    $gnupg_cv_have_readline
2088         LDAP support:        $gnupg_have_ldap
2089         TLS support:         $use_tls_library
2090         TOFU support:        $use_tofu
2091         Tor support:         $show_tor_support
2092 "
2093 if test x"$use_regex" != xyes ; then
2094 echo "
2095         Warning: No regular expression support available.
2096                  OpenPGP trust signatures won't work.
2097                  gpg-check-pattern will not be built.
2098 "
2099 fi
2100 if test "x${gpg_config_script_warn}" != x; then
2101 cat <<G10EOF
2102         Warning: Mismatches between the target platform and the
2103                  to be used libraries have been detected for:
2104                   ${gpg_config_script_warn}
2105                  Please check above for more warning messages.
2106
2107 G10EOF
2108 fi