gpg: Remove PGP6 compliance mode.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2018 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2018 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg24", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.24
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.5.0
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119 # gpg is a required part and can't be disabled anymore.
120 build_gpg=yes
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
248 AC_ARG_WITH(agent-s2k-calibration,
249               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
250                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
251               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
252 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
253 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
254                    [Agent s2k calibration time (ms)])
255
256 AC_MSG_CHECKING([whether to enable trust models])
257 AC_ARG_ENABLE(trust-models,
258               AC_HELP_STRING([--disable-trust-models],
259                              [disable all trust models except "always"]),
260               use_trust_models=$enableval)
261 AC_MSG_RESULT($use_trust_models)
262 if test "$use_trust_models" = no ; then
263     AC_DEFINE(NO_TRUST_MODELS, 1,
264              [Define to include only trust-model always])
265 fi
266
267 AC_MSG_CHECKING([whether to enable TOFU])
268 AC_ARG_ENABLE(tofu,
269                 AC_HELP_STRING([--disable-tofu],
270                                [disable the TOFU trust model]),
271               use_tofu=$enableval, use_tofu=$use_trust_models)
272 AC_MSG_RESULT($use_tofu)
273 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
274     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
275 fi
276
277 AC_MSG_CHECKING([whether to enable libdns])
278 AC_ARG_ENABLE(libdns,
279                 AC_HELP_STRING([--disable-libdns],
280                                [do not build with libdns support]),
281               use_libdns=$enableval, use_libdns=yes)
282 AC_MSG_RESULT($use_libdns)
283 if test x"$use_libdns" = xyes ; then
284     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
285 fi
286 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
287
288
289 #
290 # Options to disable algorithm
291 #
292
293 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
294 # Elgamal is a MUST algorithm
295 # DSA is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
297 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
298 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
299
300 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
301 # 3DES is a MUST algorithm
302 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
303 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
307 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
309 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
310 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
311
312 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
313 # SHA1 is a MUST algorithm
314 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
315 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
316 # SHA256 is a MUST algorithm for GnuPG.
317 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
318 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
319
320
321 # Allow disabling of zip support.
322 # This is in general not a good idea because according to rfc4880 OpenPGP
323 # implementations SHOULD support ZLIB.
324 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
325 AC_ARG_ENABLE(zip,
326    AC_HELP_STRING([--disable-zip],
327                   [disable the ZIP and ZLIB compression algorithm]),
328    use_zip=$enableval)
329 AC_MSG_RESULT($use_zip)
330
331 # Allow disabling of bzib2 support.
332 # It is defined only after we confirm the library is available later
333 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
334 AC_ARG_ENABLE(bzip2,
335    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
336    use_bzip2=$enableval)
337 AC_MSG_RESULT($use_bzip2)
338
339 # Configure option to allow or disallow execution of external
340 # programs, like a photo viewer.
341 AC_MSG_CHECKING([whether to enable external program execution])
342 AC_ARG_ENABLE(exec,
343     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
344     use_exec=$enableval)
345 AC_MSG_RESULT($use_exec)
346 if test "$use_exec" = no ; then
347     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
348 fi
349
350 if test "$use_exec" = yes ; then
351   AC_MSG_CHECKING([whether to enable photo ID viewing])
352   AC_ARG_ENABLE(photo-viewers,
353       [  --disable-photo-viewers disable photo ID viewers],
354       [if test "$enableval" = no ; then
355          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
356       fi],enableval=yes)
357   gnupg_cv_enable_photo_viewers=$enableval
358   AC_MSG_RESULT($enableval)
359
360   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
361     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
362     AC_ARG_WITH(photo-viewer,
363         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
364         [if test "$withval" = yes ; then
365            withval=no
366         elif test "$withval" != no ; then
367            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
368                             [if set, restrict photo-viewer to this])
369         fi],withval=no)
370     AC_MSG_RESULT($withval)
371   fi
372 fi
373
374
375 #
376 # Check for the key/uid cache size.  This can't be zero, but can be
377 # pretty small on embedded systems.  This is used for the gpg part.
378 #
379 AC_MSG_CHECKING([for the size of the key and uid cache])
380 AC_ARG_ENABLE(key-cache,
381         AC_HELP_STRING([--enable-key-cache=SIZE],
382                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
383 if test "$enableval" = "no"; then
384    enableval=5
385 elif test "$enableval" = "yes" || test "$enableval" = ""; then
386    enableval=4096
387 fi
388 changequote(,)dnl
389 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
390 changequote([,])dnl
391 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
392    AC_MSG_ERROR([invalid key-cache size])
393 fi
394 AC_MSG_RESULT($key_cache_size)
395 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
396                   [Size of the key and UID caches])
397
398
399
400 #
401 # Check whether we want to use Linux capabilities
402 #
403 AC_MSG_CHECKING([whether use of capabilities is requested])
404 AC_ARG_WITH(capabilities,
405     [  --with-capabilities     use linux capabilities [default=no]],
406 [use_capabilities="$withval"],[use_capabilities=no])
407 AC_MSG_RESULT($use_capabilities)
408
409 #
410 # Check whether to disable the card support
411 AC_MSG_CHECKING([whether smartcard support is requested])
412 AC_ARG_ENABLE(card-support,
413               AC_HELP_STRING([--disable-card-support],
414                              [disable smartcard support]),
415               card_support=$enableval)
416 AC_MSG_RESULT($card_support)
417 if test "$card_support" = yes ; then
418   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
419 else
420   build_scdaemon=no
421 fi
422
423 #
424 # Allow disabling of internal CCID support.
425 # It is defined only after we confirm the library is available later
426 #
427 AC_MSG_CHECKING([whether to enable the internal CCID driver])
428 AC_ARG_ENABLE(ccid-driver,
429               AC_HELP_STRING([--disable-ccid-driver],
430                              [disable the internal CCID driver]),
431               use_ccid_driver=$enableval)
432 AC_MSG_RESULT($use_ccid_driver)
433
434 AC_MSG_CHECKING([whether to auto start dirmngr])
435 AC_ARG_ENABLE(dirmngr-auto-start,
436               AC_HELP_STRING([--disable-dirmngr-auto-start],
437                              [disable auto starting of the dirmngr]),
438               dirmngr_auto_start=$enableval)
439 AC_MSG_RESULT($dirmngr_auto_start)
440 if test "$dirmngr_auto_start" = yes ; then
441     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
442               [Define to enable auto starting of the dirmngr])
443 fi
444
445
446 #
447 # To avoid double inclusion of config.h which might happen at some
448 # places, we add the usual double inclusion protection at the top of
449 # config.h.
450 #
451 AH_TOP([
452 #ifndef GNUPG_CONFIG_H_INCLUDED
453 #define GNUPG_CONFIG_H_INCLUDED
454 ])
455
456 #
457 # Stuff which goes at the bottom of config.h.
458 #
459 AH_BOTTOM([
460 /* This is the major version number of GnuPG so that
461    source included files can test for this.  Note, that
462    we use 2 here even for GnuPG 1.9.x. */
463 #define GNUPG_MAJOR_VERSION 2
464
465 /* Now to separate file name parts.
466    Please note that the string version must not contain more
467    than one character because the code assumes strlen()==1 */
468 #ifdef HAVE_DOSISH_SYSTEM
469 #define DIRSEP_C '\\'
470 #define DIRSEP_S "\\"
471 #define EXTSEP_C '.'
472 #define EXTSEP_S "."
473 #define PATHSEP_C ';'
474 #define PATHSEP_S ";"
475 #define EXEEXT_S ".exe"
476 #else
477 #define DIRSEP_C '/'
478 #define DIRSEP_S "/"
479 #define EXTSEP_C '.'
480 #define EXTSEP_S "."
481 #define PATHSEP_C ':'
482 #define PATHSEP_S ":"
483 #define EXEEXT_S ""
484 #endif
485
486 /* This is the same as VERSION, but should be overridden if the
487    platform cannot handle things like dots '.' in filenames. Set
488    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
489    uses for dots and dashes. */
490 #define SAFE_VERSION VERSION
491 #define SAFE_VERSION_DOT  '.'
492 #define SAFE_VERSION_DASH '-'
493
494 /* Some global constants.
495  * Note that the homedir must not end in a slash.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
499 # else
500 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
501 # endif
502 #elif defined(__VMS)
503 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
504 #else
505 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
506 #endif
507 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
508 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
509
510 /* For some systems (DOS currently), we hardcode the path here.  For
511    POSIX systems the values are constructed by the Makefiles, so that
512    the values may be overridden by the make invocations; this is to
513    comply with the GNU coding standards.  Note that these values are
514    only defaults.  */
515 #ifdef HAVE_DOSISH_SYSTEM
516 # ifdef HAVE_DRIVE_LETTERS
517 #  define GNUPG_BINDIR      "c:\\gnupg"
518 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
519 #  define GNUPG_LIBDIR      "c:\\gnupg"
520 #  define GNUPG_DATADIR     "c:\\gnupg"
521 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
522 # else
523 #  define GNUPG_BINDIR      "\\gnupg"
524 #  define GNUPG_LIBEXECDIR  "\\gnupg"
525 #  define GNUPG_LIBDIR      "\\gnupg"
526 #  define GNUPG_DATADIR     "\\gnupg"
527 #  define GNUPG_SYSCONFDIR  "\\gnupg"
528 # endif
529 #endif
530
531 /* Derive some other constants. */
532 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
533 #define EXEC_TEMPFILE_ONLY
534 #endif
535
536
537 /* We didn't define endianness above, so get it from OS macros.  This
538    is intended for making fat binary builds on OS X. */
539 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
540 #if defined(__BIG_ENDIAN__)
541 #define BIG_ENDIAN_HOST 1
542 #elif defined(__LITTLE_ENDIAN__)
543 #define LITTLE_ENDIAN_HOST 1
544 #else
545 #error "No endianness found"
546 #endif
547 #endif
548
549
550 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
551    ldap_start_tls_s because that is the actual symbol used in the
552    library.  winldap.h redefines it to our commonly used value,
553    thus we define our usual macro here.  */
554 #ifdef HAVE_LDAP_START_TLS_SA
555 # ifndef HAVE_LDAP_START_TLS_S
556 #  define HAVE_LDAP_START_TLS_S 1
557 # endif
558 #endif
559
560 /* Enable the es_ macros from gpgrt.  */
561 #define GPGRT_ENABLE_ES_MACROS 1
562
563 /* Enable the log_ macros from gpgrt.  */
564 #define GPGRT_ENABLE_LOG_MACROS 1
565
566 /* Tell libgcrypt not to use its own libgpg-error implementation. */
567 #define USE_LIBGPG_ERROR 1
568
569 /* Tell Libgcrypt not to include deprecated definitions.  */
570 #define GCRYPT_NO_DEPRECATED 1
571
572 /* Our HTTP code is used in estream mode.  */
573 #define HTTP_USE_ESTREAM 1
574
575 /* Under W32 we do an explicit socket initialization, thus we need to
576    avoid the on-demand initialization which would also install an atexit
577    handler.  */
578 #define HTTP_NO_WSASTARTUP
579
580 /* Under Windows we use the gettext code from libgpg-error.  */
581 #define GPG_ERR_ENABLE_GETTEXT_MACROS
582
583 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
584 #define GPG_ERR_ENABLE_ERRNO_MACROS
585
586 #endif /*GNUPG_CONFIG_H_INCLUDED*/
587 ])
588
589
590 AM_MAINTAINER_MODE
591 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
592
593 # Checks for programs.
594 AC_MSG_NOTICE([checking for programs])
595 AC_PROG_MAKE_SET
596 AM_SANITY_CHECK
597 missing_dir=`cd $ac_aux_dir && pwd`
598 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
599 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
600 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
601 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
602 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
603 AM_SILENT_RULES
604 AC_PROG_AWK
605 AC_PROG_CC
606 AC_PROG_CPP
607 AM_PROG_CC_C_O
608 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
609   AC_MSG_ERROR([[No C-89 compiler found]])
610 fi
611 AC_PROG_INSTALL
612 AC_PROG_LN_S
613 AC_PROG_RANLIB
614 AC_CHECK_TOOL(AR, ar, :)
615 AC_PATH_PROG(PERL,"perl")
616 AC_CHECK_TOOL(WINDRES, windres, :)
617 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
618 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
619 AM_CONDITIONAL(HAVE_YAT2M, test -n "$ac_cv_path_YAT2M")
620 AC_ISC_POSIX
621 AC_SYS_LARGEFILE
622 GNUPG_CHECK_USTAR
623
624
625 # We need to compile and run a program on the build machine.  A
626 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
627 # the AC archive is broken for autoconf 2.57.  Given that there is no
628 # newer version of that macro, we assume that it is also broken for
629 # autoconf 2.61 and thus we use a simple but usually sufficient
630 # approach.
631 AC_MSG_CHECKING(for cc for build)
632 if test "$cross_compiling" = "yes"; then
633   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
634 else
635   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
636 fi
637 AC_MSG_RESULT($CC_FOR_BUILD)
638 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
639
640 # We need to call this macro because other pkg-config macros are
641 # not always used.
642 PKG_PROG_PKG_CONFIG
643
644
645 try_gettext=yes
646 require_iconv=yes
647 have_dosish_system=no
648 have_w32_system=no
649 have_w32ce_system=no
650 have_android_system=no
651 use_simple_gettext=no
652 use_ldapwrapper=yes
653 mmap_needed=yes
654 require_pipe_to_unblock_pselect=yes
655 case "${host}" in
656     *-mingw32*)
657         # special stuff for Windoze NT
658         ac_cv_have_dev_random=no
659         AC_DEFINE(USE_ONLY_8DOT3,1,
660                   [Set this to limit filenames to the 8.3 format])
661         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
662                   [Because the Unix gettext has too much overhead on
663                    MingW32 systems and these systems lack Posix functions,
664                    we use a simplified version of gettext])
665         have_dosish_system=yes
666         have_w32_system=yes
667         require_iconv=no
668         require_pipe_to_unblock_pselect=no
669         case "${host}" in
670           *-mingw32ce*)
671             have_w32ce_system=yes
672             ;;
673           *)
674             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
675                       [Defined if the OS supports drive letters.])
676             ;;
677         esac
678         try_gettext="no"
679         use_simple_gettext=yes
680         mmap_needed=no
681         ;;
682     i?86-emx-os2 | i?86-*-os2*emx )
683         # OS/2 with the EMX environment
684         ac_cv_have_dev_random=no
685         AC_DEFINE(HAVE_DRIVE_LETTERS)
686         have_dosish_system=yes
687         try_gettext="no"
688         ;;
689
690     i?86-*-msdosdjgpp*)
691         # DOS with the DJGPP environment
692         ac_cv_have_dev_random=no
693         AC_DEFINE(HAVE_DRIVE_LETTERS)
694         have_dosish_system=yes
695         try_gettext="no"
696         ;;
697
698     *-*-hpux*)
699         if test -z "$GCC" ; then
700             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
701         fi
702         ;;
703     *-dec-osf4*)
704         if test -z "$GCC" ; then
705             # Suppress all warnings
706             # to get rid of the unsigned/signed char mismatch warnings.
707             CFLAGS="-w $CFLAGS"
708         fi
709         ;;
710     *-dec-osf5*)
711         if test -z "$GCC" ; then
712             # Use the newer compiler `-msg_disable ptrmismatch1' to
713             # get rid of the unsigned/signed char mismatch warnings.
714             # Using this may hide other pointer mismatch warnings, but
715             # it at least lets other warning classes through
716             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
717         fi
718         ;;
719     m68k-atari-mint)
720         ;;
721     *-linux-android*)
722         have_android_system=yes
723         # Android is fully utf-8 and we do not want to use iconv to
724         # keeps things simple
725         require_iconv=no
726         ;;
727     *-apple-darwin*)
728         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
729                   Expose all libc features (__DARWIN_C_FULL).)
730         ;;
731     *-*-netbsd*)
732         require_pipe_to_unblock_pselect=yes
733         ;;
734     *)
735         ;;
736 esac
737
738 if test "$require_pipe_to_unblock_pselect" = yes; then
739    AC_DEFINE(HAVE_PSELECT_NO_EINTR, 1,
740              [Defined if we run on systems like NetBSD, where
741               pselect cannot be unblocked by signal from a thread
742               within the same process.  We use pipe in this case, instead.])
743 fi
744
745 if test "$have_dosish_system" = yes; then
746    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
747              [Defined if we run on some of the PCDOS like systems
748               (DOS, Windoze. OS/2) with special properties like
749               no file modes, case insensitive file names and preferred
750               use of backslashes as directory name separators.])
751 fi
752 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
753
754 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
755
756 if test "$have_w32_system" = yes; then
757    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
758    if test "$have_w32ce_system" = yes; then
759       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
760    fi
761 fi
762 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
763 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
764
765 if test "$have_android_system" = yes; then
766    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
767 fi
768 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
769
770
771 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
772 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
773
774
775 #
776 # Checks for libraries.
777 #
778 AC_MSG_NOTICE([checking for libraries])
779
780
781 #
782 # libgpg-error is a library with error codes shared between GnuPG
783 # related projects.
784 #
785 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
786                   have_gpg_error=yes,have_gpg_error=no)
787
788
789 #
790 # Libgcrypt is our generic crypto library
791 #
792 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
793         have_libgcrypt=yes,have_libgcrypt=no)
794
795
796 #
797 # libassuan is used for IPC
798 #
799 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
800                   have_libassuan=yes,have_libassuan=no)
801 if test "$have_libassuan" = "yes"; then
802   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
803                      [version of the libassuan library])
804   show_tor_support="only .onion"
805 fi
806
807
808 #
809 # libksba is our X.509 support library
810 #
811 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
812
813
814 #
815 # libusb allows us to use the integrated CCID smartcard reader driver.
816 #
817 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
818 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
819    case "${host}" in
820      *-mingw32*)
821        LIBUSB_NAME=
822        LIBUSB_LIBS=
823        LIBUSB_CPPFLAGS=
824        ;;
825      *-*-darwin*)
826        LIBUSB_NAME=usb-1.0
827        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
828        ;;
829      *-*-freebsd*)
830        # FreeBSD has a native 1.0 compatible library by -lusb.
831        LIBUSB_NAME=usb
832        LIBUSB_LIBS=
833        ;;
834      *)
835        LIBUSB_NAME=usb-1.0
836        LIBUSB_LIBS=
837        ;;
838    esac
839 fi
840 if test x"$LIBUSB_NAME" != x ; then
841    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
842                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
843                   have_libusb=yes ])
844    AC_MSG_CHECKING([libusb include dir])
845    usb_incdir_found="no"
846    for _incdir in "" "/usr/include/libusb-1.0" \
847        "/usr/local/include/libusb-1.0" "/usr/pkg/include/libusb-1.0"; do
848      _libusb_save_cppflags=$CPPFLAGS
849      if test -n "${_incdir}"; then
850        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
851      fi
852      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
853      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
854      CPPFLAGS=${_libusb_save_cppflags}
855      if test "$usb_incdir_found" = "yes"; then
856        break
857      fi
858    done
859    if test "$usb_incdir_found" = "yes"; then
860      AC_MSG_RESULT([${usb_incdir}])
861    else
862      AC_MSG_RESULT([not found])
863      usb_incdir=""
864      have_libusb=no
865      if test "$use_ccid_driver" != yes; then
866        use_ccid_driver=no
867      fi
868      LIBUSB_LIBS=""
869    fi
870
871    if test "$have_libusb" = yes; then
872      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
873    fi
874    if test x"$usb_incdir" = x; then
875      LIBUSB_CPPFLAGS=""
876    else
877      LIBUSB_CPPFLAGS="-I${usb_incdir}"
878    fi
879 fi
880 AC_SUBST(LIBUSB_LIBS)
881 AC_SUBST(LIBUSB_CPPFLAGS)
882
883 #
884 # Check whether it is necessary to link against libdl.
885 # (For example to load libpcsclite)
886 #
887 gnupg_dlopen_save_libs="$LIBS"
888 LIBS=""
889 AC_SEARCH_LIBS(dlopen, c dl,,,)
890 DL_LIBS=$LIBS
891 AC_SUBST(DL_LIBS)
892 LIBS="$gnupg_dlopen_save_libs"
893
894
895 # Checks for g10
896
897 AC_ARG_ENABLE(sqlite,
898                 AC_HELP_STRING([--disable-sqlite],
899                                [disable the use of SQLITE]),
900               try_sqlite=$enableval, try_sqlite=yes)
901
902 if test x"$use_tofu" = xyes ; then
903   if test x"$try_sqlite" = xyes ; then
904     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
905                                  [have_sqlite=yes],
906                                  [have_sqlite=no])
907   fi
908   if test "$have_sqlite" = "yes"; then
909     :
910     AC_SUBST([SQLITE3_CFLAGS])
911     AC_SUBST([SQLITE3_LIBS])
912   else
913     use_tofu=no
914     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
915     AC_MSG_WARN([[
916 ***
917 *** Building without SQLite support - TOFU disabled
918 ***
919 *** $tmp]])
920   fi
921 fi
922
923 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
924
925 if test x"$use_tofu" = xyes ; then
926     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
927 fi
928
929
930 # Checks for g13
931
932 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
933 AC_DEFINE_UNQUOTED(ENCFS,
934         "${ENCFS}", [defines the filename of the encfs program])
935
936 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
937 AC_DEFINE_UNQUOTED(FUSERMOUNT,
938         "${FUSERMOUNT}", [defines the filename of the fusermount program])
939
940
941 # Checks for dirmngr
942
943
944 #
945 # Checks for symcryptrun:
946 #
947
948 # libutil has openpty() and login_tty().
949 AC_CHECK_LIB(util, openpty,
950               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
951                 AC_DEFINE(HAVE_LIBUTIL,1,
952                          [defined if libutil is available])
953              ])
954 AC_SUBST(LIBUTIL_LIBS)
955
956 # shred is used to clean temporary plain text files.
957 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
958 AC_DEFINE_UNQUOTED(SHRED,
959         "${SHRED}", [defines the filename of the shred program])
960
961
962 #
963 # Check whether the nPth library is available
964 #
965 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
966 if test "$have_npth" = "yes"; then
967   AC_DEFINE(HAVE_NPTH, 1,
968               [Defined if the New Portable Thread Library is available])
969   AC_DEFINE(USE_NPTH, 1,
970               [Defined if support for nPth is requested and nPth is available])
971 else
972   AC_MSG_WARN([[
973 ***
974 *** To support concurrent access for example in gpg-agent and the SCdaemon
975 *** we need the support of the New Portable Threads Library.
976 ***]])
977 fi
978 #
979 # Enable debugging of nPth
980 #
981 AC_ARG_ENABLE(npth-debug,
982    AC_HELP_STRING([--enable-npth-debug],
983                   [build with debug version of npth]),
984                   [if test $enableval = yes ; then
985                      AC_DEFINE(NPTH_ENABLE_DEBUG,1,
986                               [Build with debug version of nPth])
987                   fi])
988
989
990
991 #
992 # NTBTLS is our TLS library.  If it is not available fallback to
993 # GNUTLS.
994 #
995 AC_ARG_ENABLE(ntbtls,
996               AC_HELP_STRING([--disable-ntbtls],
997                              [disable the use of NTBTLS as TLS library]),
998               try_ntbtls=$enableval, try_ntbtls=yes)
999 if test x"$try_ntbtls" = xyes ; then
1000   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
1001                  [have_ntbtls=yes],[have_ntbtls=no])
1002 fi
1003 if test "$have_ntbtls" = yes ; then
1004    use_tls_library=ntbtls
1005    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
1006 else
1007   AC_ARG_ENABLE(gnutls,
1008                 AC_HELP_STRING([--disable-gnutls],
1009                                [disable GNUTLS as fallback TLS library]),
1010                 try_gnutls=$enableval, try_gnutls=yes)
1011   if test x"$try_gnutls" = xyes ; then
1012     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
1013                                    [have_gnutls=yes],
1014                                    [have_gnutls=no])
1015   fi
1016   if test "$have_gnutls" = "yes"; then
1017     AC_SUBST([LIBGNUTLS_CFLAGS])
1018     AC_SUBST([LIBGNUTLS_LIBS])
1019     use_tls_library=gnutls
1020     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
1021   else
1022     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1023     AC_MSG_WARN([[
1024 ***
1025 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1026 ***
1027 *** $tmp]])
1028   fi
1029 fi
1030
1031 #
1032 # Allow to set a fixed trust store file for system provided certificates.
1033 #
1034 AC_ARG_WITH([default-trust-store-file],
1035             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1036                             [Use FILE as system trust store])],
1037             default_trust_store_file="$withval",
1038             default_trust_store_file="")
1039 if test x"$default_trust_store_file" = xno;then
1040   default_trust_store_file=""
1041 fi
1042 if test x"$default_trust_store_file" != x ; then
1043   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1044     ["$default_trust_store_file"], [Use as default system trust store file])
1045 fi
1046
1047
1048 AC_MSG_NOTICE([checking for networking options])
1049
1050 #
1051 # Must check for network library requirements before doing link tests
1052 # for ldap, for example. If ldap libs are static (or dynamic and without
1053 # ELF runtime link paths), then link will fail and LDAP support won't
1054 # be detected.
1055 #
1056 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1057         [NETLIBS="-lnsl $NETLIBS"]))
1058 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1059         [NETLIBS="-lsocket $NETLIBS"]))
1060
1061
1062 #
1063 # Check standard resolver functions.
1064 #
1065 if test "$build_dirmngr" = "yes"; then
1066   _dns_save_libs=$LIBS
1067   LIBS=""
1068
1069   # Find the system resolver which can always be enabled with
1070   # the dirmngr option --standard-resolver.
1071
1072   # the double underscore thing is a glibc-ism?
1073   AC_SEARCH_LIBS(res_query,resolv bind,,
1074                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1075   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1076                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1077
1078   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1079   # and for some reason fools us into believing we don't need
1080   # -lresolv even if we do.  Since the test program checking for the
1081   # symbol does not include <resolv.h>, we need to check for the
1082   # renamed symbol explicitly.
1083   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1084       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1085           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1086
1087   if test x"$have_resolver" != xno ; then
1088
1089       # Make sure that the BIND 4 resolver interface is workable before
1090       # enabling any code that calls it.  At some point I'll rewrite the
1091       # code to use the BIND 8 resolver API.
1092       # We might also want to use libdns instead.
1093
1094     AC_MSG_CHECKING([whether the resolver is usable])
1095     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1096 #include <netinet/in.h>
1097 #include <arpa/nameser.h>
1098 #include <resolv.h>]],
1099 [[unsigned char answer[PACKETSZ];
1100   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1101   dn_skipname(0,0);
1102   dn_expand(0,0,0,0,0);
1103 ]])],have_resolver=yes,have_resolver=no)
1104     AC_MSG_RESULT($have_resolver)
1105
1106     # This is Apple-specific and somewhat bizarre as they changed the
1107     # define in bind 8 for some reason.
1108
1109     if test x"$have_resolver" != xyes ; then
1110       AC_MSG_CHECKING(
1111            [whether I can make the resolver usable with BIND_8_COMPAT])
1112       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1113 #include <sys/types.h>
1114 #include <netinet/in.h>
1115 #include <arpa/nameser.h>
1116 #include <resolv.h>]],
1117 [[unsigned char answer[PACKETSZ];
1118   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1119   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1120 ]])],[have_resolver=yes ; need_compat=yes])
1121       AC_MSG_RESULT($have_resolver)
1122     fi
1123   fi
1124
1125   if test x"$have_resolver" = xyes ; then
1126     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1127     DNSLIBS="$DNSLIBS $LIBS"
1128     if test x"$need_compat" = xyes ; then
1129       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1130     fi
1131     if test "$use_libdns" = yes; then
1132      show_tor_support=yes
1133     fi
1134   elif test "$use_libdns" = yes; then
1135     show_tor_support=yes
1136   else
1137     AC_MSG_WARN([[
1138 ***
1139 *** The system's DNS resolver is not usable.
1140 *** Dirmngr functionality is limited.
1141 ***]])
1142     show_tor_support="${show_tor_support} (no system resolver)"
1143   fi
1144
1145   if test "$have_w32_system" = yes; then
1146     if test "$use_libdns" = yes; then
1147       DNSLIBS="$DNSLIBS -liphlpapi"
1148     fi
1149   fi
1150
1151   LIBS=$_dns_save_libs
1152 fi
1153
1154 AC_SUBST(DNSLIBS)
1155
1156
1157 #
1158 # Check for LDAP
1159 #
1160 # Note that running the check changes the variable
1161 # gnupg_have_ldap from "n/a" to "no" or "yes".
1162
1163 AC_ARG_ENABLE(ldap,
1164     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1165     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1166
1167 if test "$gnupg_have_ldap" != "no" ; then
1168   if test "$build_dirmngr" = "yes" ; then
1169      GNUPG_CHECK_LDAP($NETLIBS)
1170      AC_CHECK_LIB(lber, ber_free,
1171                   [ LBER_LIBS="$LBER_LIBS -llber"
1172                     AC_DEFINE(HAVE_LBER,1,
1173                              [defined if liblber is available])
1174                     have_lber=yes
1175                  ])
1176   fi
1177 fi
1178 AC_SUBST(LBER_LIBS)
1179 if test "$gnupg_have_ldap" = "no"; then
1180     AC_MSG_WARN([[
1181 ***
1182 *** Building without LDAP support.
1183 *** No CRL access or X.509 certificate search available.
1184 ***]])
1185 fi
1186
1187 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1188 if test "$gnupg_have_ldap" = yes ; then
1189   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1190 else
1191  use_ldapwrapper=no
1192 fi
1193
1194 if test "$use_ldapwrapper" = yes; then
1195    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1196 fi
1197 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1198
1199
1200
1201
1202 #
1203 # Check for sendmail
1204 #
1205 # This isn't necessarily sendmail itself, but anything that gives a
1206 # sendmail-ish interface to the outside world.  That includes Exim,
1207 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1208 AC_ARG_WITH(mailprog,
1209       AC_HELP_STRING([--with-mailprog=NAME],
1210                      [use "NAME -t" for mail transport]),
1211              ,with_mailprog=yes)
1212 if test x"$with_mailprog" = xyes ; then
1213     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1214 elif test x"$with_mailprog" != xno ; then
1215     AC_MSG_CHECKING([for a mail transport program])
1216     AC_SUBST(SENDMAIL,$with_mailprog)
1217     AC_MSG_RESULT($with_mailprog)
1218 fi
1219
1220
1221 #
1222 # Construct a printable name of the OS
1223 #
1224 case "${host}" in
1225     *-mingw32ce*)
1226         PRINTABLE_OS_NAME="W32CE"
1227         ;;
1228     *-mingw32*)
1229         PRINTABLE_OS_NAME="MingW32"
1230         ;;
1231     *-*-cygwin*)
1232         PRINTABLE_OS_NAME="Cygwin"
1233         ;;
1234     i?86-emx-os2 | i?86-*-os2*emx )
1235         PRINTABLE_OS_NAME="OS/2"
1236         ;;
1237     i?86-*-msdosdjgpp*)
1238         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1239         try_dynload=no
1240         ;;
1241     *-linux*)
1242         PRINTABLE_OS_NAME="GNU/Linux"
1243         ;;
1244     *)
1245         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1246         ;;
1247 esac
1248 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1249                    [A human readable text with the name of the OS])
1250
1251
1252 #
1253 # Checking for iconv
1254 #
1255 if test "$require_iconv" = yes; then
1256   AM_ICONV
1257 else
1258   LIBICONV=
1259   LTLIBICONV=
1260   AC_SUBST(LIBICONV)
1261   AC_SUBST(LTLIBICONV)
1262 fi
1263
1264
1265 #
1266 # Check for gettext
1267 #
1268 # This is "GNU gnupg" - The project-id script from gettext
1269 #                       needs this string
1270 #
1271 AC_MSG_NOTICE([checking for gettext])
1272 AM_PO_SUBDIRS
1273 AM_GNU_GETTEXT_VERSION([0.17])
1274 if test "$try_gettext" = yes; then
1275   AM_GNU_GETTEXT([external],[need-ngettext])
1276
1277   # gettext requires some extra checks.  These really should be part of
1278   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1279   # function checks to here.
1280
1281   AC_CHECK_FUNCS(strchr)
1282 else
1283   USE_NLS=no
1284   USE_INCLUDED_LIBINTL=no
1285   BUILD_INCLUDED_LIBINTL=no
1286   POSUB=po
1287   AC_SUBST(USE_NLS)
1288   AC_SUBST(USE_INCLUDED_LIBINTL)
1289   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1290   AC_SUBST(POSUB)
1291 fi
1292
1293 # We use HAVE_LANGINFO_CODESET in a couple of places.
1294 AM_LANGINFO_CODESET
1295
1296 # Checks required for our use of locales
1297 gt_LC_MESSAGES
1298
1299
1300 #
1301 # SELinux support
1302 #
1303 if test "$selinux_support" = yes ; then
1304   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1305 fi
1306
1307
1308 #
1309 # Checks for header files.
1310 #
1311 AC_MSG_NOTICE([checking for header files])
1312 AC_HEADER_STDC
1313 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1314                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1315                   stdint.h signal.h util.h libutil.h termios.h \
1316                   ucred.h sys/ucred.h sys/sysmacros.h sys/mkdev.h])
1317
1318 AC_HEADER_TIME
1319
1320
1321 #
1322 # Checks for typedefs, structures, and compiler characteristics.
1323 #
1324 AC_MSG_NOTICE([checking for system characteristics])
1325 AC_C_CONST
1326 AC_C_INLINE
1327 AC_C_VOLATILE
1328 AC_TYPE_SIZE_T
1329 AC_TYPE_MODE_T
1330 AC_TYPE_SIGNAL
1331 AC_DECL_SYS_SIGLIST
1332
1333 gl_HEADER_SYS_SOCKET
1334 gl_TYPE_SOCKLEN_T
1335
1336 AC_SEARCH_LIBS([inet_addr], [nsl])
1337
1338 AC_ARG_ENABLE(endian-check,
1339               AC_HELP_STRING([--disable-endian-check],
1340               [disable the endian check and trust the OS provided macros]),
1341               endiancheck=$enableval,endiancheck=yes)
1342
1343 if test x"$endiancheck" = xyes ; then
1344   GNUPG_CHECK_ENDIAN
1345 fi
1346
1347 # fixme: we should get rid of the byte type
1348 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1349 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1350 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1351 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1352 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1353
1354 AC_CHECK_SIZEOF(unsigned short)
1355 AC_CHECK_SIZEOF(unsigned int)
1356 AC_CHECK_SIZEOF(unsigned long)
1357 AC_CHECK_SIZEOF(unsigned long long)
1358 AC_HEADER_TIME
1359 AC_CHECK_SIZEOF(time_t,,[[
1360 #include <stdio.h>
1361 #if TIME_WITH_SYS_TIME
1362 # include <sys/time.h>
1363 # include <time.h>
1364 #else
1365 # if HAVE_SYS_TIME_H
1366 #  include <sys/time.h>
1367 # else
1368 #  include <time.h>
1369 # endif
1370 #endif
1371 ]])
1372 GNUPG_TIME_T_UNSIGNED
1373
1374
1375 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1376    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1377    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1378     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1379 fi
1380
1381
1382 #
1383 # Checks for library functions.
1384 #
1385 AC_MSG_NOTICE([checking for library functions])
1386 AC_CHECK_DECLS(getpagesize)
1387 AC_FUNC_FSEEKO
1388 AC_FUNC_VPRINTF
1389 AC_FUNC_FORK
1390 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1391 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1392 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1393 AC_CHECK_FUNCS([canonicalize_file_name])
1394 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1395 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1396 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1397 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1398 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1399                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1400                 flockfile funlockfile getpwnam getpwuid \
1401                 getenv inet_pton strpbrk])
1402
1403 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1404 # Given that we use nanosleep only as an optimization over a select
1405 # based wait function we want it only if it is available in libc.
1406 _save_libs="$LIBS"
1407 AC_SEARCH_LIBS([nanosleep], [],
1408                [AC_DEFINE(HAVE_NANOSLEEP,1,
1409                 [Define to 1 if you have the `nanosleep' function in libc.])])
1410 LIBS="$_save_libs"
1411
1412
1413 # See whether libc supports the Linux inotify interface
1414 case "${host}" in
1415     *-*-linux*)
1416         AC_CHECK_FUNCS([inotify_init])
1417         ;;
1418 esac
1419
1420
1421 if test "$have_android_system" = yes; then
1422    # On Android ttyname is a stub but prints an error message.
1423    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1424              [Defined if ttyname does not work properly])
1425 fi
1426
1427 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1428
1429 # Dirmngr requires mmap on Unix systems.
1430 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1431   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1432 fi
1433
1434
1435 #
1436 # Check for the getsockopt SO_PEERCRED, etc.
1437 #
1438 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1439 #include <sys/socket.h> ])
1440
1441 # (Open)Solaris
1442 AC_CHECK_FUNCS([getpeerucred])
1443
1444
1445 #
1446 # W32 specific test
1447 #
1448 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1449
1450 #
1451 # Sanity check regex.  Tests adapted from mutt.
1452 #
1453 AC_MSG_CHECKING([whether regular expression support is requested])
1454 AC_ARG_ENABLE(regex,
1455   AC_HELP_STRING([--disable-regex],
1456     [do not handle regular expressions in trust signatures]),
1457   use_regex=$enableval, use_regex=yes)
1458 AC_MSG_RESULT($use_regex)
1459
1460 if test "$use_regex" = yes ; then
1461   _cppflags="${CPPFLAGS}"
1462   _ldflags="${LDFLAGS}"
1463   AC_ARG_WITH(regex,
1464      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1465       [
1466       if test -d "$withval" ; then
1467         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1468         LDFLAGS="${LDFLAGS} -L$withval/lib"
1469       fi
1470       ],withval="")
1471
1472   # Does the system have regex functions at all?
1473   AC_SEARCH_LIBS([regcomp], [regex])
1474   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1475
1476   if test $gnupg_cv_have_regex = no; then
1477     use_regex=no
1478   else
1479     if test x"$cross_compiling" = xyes; then
1480       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1481     else
1482       AC_CACHE_CHECK([whether your system's regexp library is broken],
1483        [gnupg_cv_regex_broken],
1484        AC_TRY_RUN([
1485 #include <unistd.h>
1486 #include <regex.h>
1487 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1488        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1489
1490       if test $gnupg_cv_regex_broken = yes; then
1491         AC_MSG_WARN([your regex is broken - disabling regex use])
1492         use_regex=no
1493       fi
1494     fi
1495   fi
1496   CPPFLAGS="${_cppflags}"
1497   LDFLAGS="${_ldflags}"
1498 fi
1499
1500 if test "$use_regex" != yes ; then
1501   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1502 fi
1503 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1504
1505
1506
1507 #
1508 # Do we have zlib? Must do it here because Solaris failed
1509 # when compiling a conftest (due to the "-lz" from LIBS).
1510 # Note that we combine zlib and bzlib2 in ZLIBS.
1511 #
1512 if test "$use_zip" = yes ; then
1513   _cppflags="${CPPFLAGS}"
1514   _ldflags="${LDFLAGS}"
1515   AC_ARG_WITH(zlib,
1516     [  --with-zlib=DIR         use libz in DIR],[
1517       if test -d "$withval"; then
1518         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1519         LDFLAGS="${LDFLAGS} -L$withval/lib"
1520       fi
1521     ])
1522
1523   AC_CHECK_HEADER(zlib.h,
1524      AC_CHECK_LIB(z, deflateInit2_,
1525        [
1526        ZLIBS="-lz"
1527        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1528        ],
1529        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1530        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1531 fi
1532
1533
1534 #
1535 # Check whether we can support bzip2
1536 #
1537 if test "$use_bzip2" = yes ; then
1538   _cppflags="${CPPFLAGS}"
1539   _ldflags="${LDFLAGS}"
1540   AC_ARG_WITH(bzip2,
1541      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1542       [
1543       if test -d "$withval" ; then
1544         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1545         LDFLAGS="${LDFLAGS} -L$withval/lib"
1546       fi
1547       ],withval="")
1548
1549   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1550   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1551   # woefully out of date.
1552   if test "$withval" != no ; then
1553      AC_CHECK_HEADER(bzlib.h,
1554         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1555           [
1556           have_bz2=yes
1557           ZLIBS="$ZLIBS -lbz2"
1558           AC_DEFINE(HAVE_BZIP2,1,
1559                   [Defined if the bz2 compression library is available])
1560           ],
1561           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1562           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1563   fi
1564 fi
1565 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1566 AC_SUBST(ZLIBS)
1567
1568
1569 # Check for readline support
1570 GNUPG_CHECK_READLINE
1571
1572
1573 if test "$development_version" = yes; then
1574     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1575             [Defined if this is not a regular release])
1576 fi
1577
1578 if test "$USE_MAINTAINER_MODE" = "yes"; then
1579     AC_DEFINE(MAINTAINER_MODE,1,
1580             [Defined if this build is in maintainer mode])
1581 fi
1582
1583 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1584
1585 GNUPG_CHECK_GNUMAKE
1586
1587 # Add some extra libs here so that previous tests don't fail for
1588 # mysterious reasons - the final link step should bail out.
1589 # W32SOCKLIBS is also defined so that if can be used for tools not
1590 # requiring any network stuff but linking to code in libcommon which
1591 # tracks in winsock stuff (e.g. init_common_subsystems).
1592 if test "$have_w32_system" = yes; then
1593    if test "$have_w32ce_system" = yes; then
1594      W32SOCKLIBS="-lws2"
1595    else
1596      W32SOCKLIBS="-lws2_32"
1597    fi
1598    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1599 fi
1600
1601 AC_SUBST(NETLIBS)
1602 AC_SUBST(W32SOCKLIBS)
1603
1604 #
1605 # Setup gcc specific options
1606 #
1607 USE_C99_CFLAGS=
1608 AC_MSG_NOTICE([checking for cc features])
1609 if test "$GCC" = yes; then
1610     mycflags=
1611     mycflags_save=$CFLAGS
1612
1613     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1614     # options.  This is the case for gcc >= 4.6
1615     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1616     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1617 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1618 #kickerror
1619 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1620     AC_MSG_RESULT($_gcc_silent_wno)
1621
1622     # Note that it is okay to use CFLAGS here because these are just
1623     # warning options and the user should have a chance of overriding
1624     # them.
1625     if test "$USE_MAINTAINER_MODE" = "yes"; then
1626         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1627         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1628         if test x"$_gcc_silent_wno" = xyes ; then
1629           _gcc_wopt=yes
1630         else
1631           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1632           CFLAGS="-Wno-missing-field-initializers"
1633           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1634                             [_gcc_wopt=yes],[_gcc_wopt=no])
1635           AC_MSG_RESULT($_gcc_wopt)
1636         fi
1637         if test x"$_gcc_wopt" = xyes ; then
1638           mycflags="$mycflags -W -Wno-sign-compare -Wno-format-zero-length"
1639           mycflags="$mycflags -Wno-missing-field-initializers"
1640         fi
1641
1642         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1643         CFLAGS="-Wdeclaration-after-statement"
1644         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1645         AC_MSG_RESULT($_gcc_wopt)
1646         if test x"$_gcc_wopt" = xyes ; then
1647           mycflags="$mycflags -Wdeclaration-after-statement"
1648         fi
1649
1650         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1651         CFLAGS="-Wlogical-op -Werror"
1652         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1653         AC_MSG_RESULT($_gcc_wopt)
1654         if test x"$_gcc_wopt" = xyes ; then
1655           mycflags="$mycflags -Wlogical-op"
1656         fi
1657
1658         AC_MSG_CHECKING([if gcc supports -Wvla])
1659         CFLAGS="-Wvla"
1660         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1661         AC_MSG_RESULT($_gcc_wopt)
1662         if test x"$_gcc_wopt" = xyes ; then
1663           mycflags="$mycflags -Wvla"
1664         fi
1665
1666     else
1667         mycflags="$mycflags -Wall"
1668     fi
1669
1670     if test x"$_gcc_silent_wno" = xyes ; then
1671       _gcc_psign=yes
1672     else
1673       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1674       CFLAGS="-Wno-pointer-sign"
1675       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1676                         [_gcc_psign=yes],[_gcc_psign=no])
1677       AC_MSG_RESULT($_gcc_psign)
1678     fi
1679     if test x"$_gcc_psign" = xyes ; then
1680        mycflags="$mycflags -Wno-pointer-sign"
1681     fi
1682
1683     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1684     CFLAGS="-Wpointer-arith"
1685     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1686     AC_MSG_RESULT($_gcc_psign)
1687     if test x"$_gcc_psign" = xyes ; then
1688        mycflags="$mycflags -Wpointer-arith"
1689     fi
1690
1691     CFLAGS="$mycflags $mycflags_save"
1692     if test "$use_libdns" = yes; then
1693        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1694        USE_C99_CFLAGS="-std=gnu99"
1695     fi
1696 fi
1697
1698 AC_SUBST(USE_C99_CFLAGS)
1699
1700
1701 #
1702 # This is handy for debugging so the compiler doesn't rearrange
1703 # things and eliminate variables.
1704 #
1705 AC_ARG_ENABLE(optimization,
1706    AC_HELP_STRING([--disable-optimization],
1707                   [disable compiler optimization]),
1708                   [if test $enableval = no ; then
1709                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1710                    fi])
1711
1712 #
1713 # log_debug has certain requirements which might hamper portability.
1714 # Thus we use an option to enable it.
1715 #
1716 AC_MSG_CHECKING([whether to enable log_clock])
1717 AC_ARG_ENABLE(log_clock,
1718               AC_HELP_STRING([--enable-log-clock],
1719                              [enable log_clock timestamps]),
1720               enable_log_clock=$enableval, enable_log_clock=no)
1721 AC_MSG_RESULT($enable_log_clock)
1722 if test "$enable_log_clock" = yes ; then
1723   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1724 fi
1725
1726 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1727 # misbehaving autoconf tests in case the user supplied -Werror.
1728 #
1729 AC_ARG_ENABLE(werror,
1730    AC_HELP_STRING([--enable-werror],
1731                   [append -Werror to CFLAGS]),
1732                   [if test $enableval = yes ; then
1733                       CFLAGS="$CFLAGS -Werror"
1734                    fi])
1735
1736 #
1737 # Configure option --enable-all-tests
1738 #
1739 AC_MSG_CHECKING([whether "make check" shall run all tests])
1740 AC_ARG_ENABLE(all-tests,
1741               AC_HELP_STRING([--enable-all-tests],
1742                              [let "make check" run all tests]),
1743               run_all_tests=$enableval, run_all_tests=no)
1744 AC_MSG_RESULT($run_all_tests)
1745 if test "$run_all_tests" = "yes"; then
1746     AC_DEFINE(RUN_ALL_TESTS,1,
1747             [Defined if "make check" shall run all tests])
1748 fi
1749
1750 #
1751 # We do not want support for the GNUPG_BUILDDIR environment variable
1752 # in a released version.  However, our regression tests suite requires
1753 # this and thus we build with support for it during "make distcheck".
1754 # This configure option implements this along with the top Makefile's
1755 # AM_DISTCHECK_CONFIGURE_FLAGS.
1756 #
1757 gnupg_builddir_envvar=no
1758 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1759               gnupg_builddir_envvar=$enableval)
1760 if test x"$gnupg_builddir_envvar" = x"yes"; then
1761    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1762       [This is only used with "make distcheck"])
1763 fi
1764
1765
1766 #
1767 # To avoid problems with systemd cleaning up the /run/user directory,
1768 # this option will make GnuPG try to use /run/gnupg/user as socket dir
1769 # before /run/user
1770 #
1771 AC_ARG_ENABLE(run-gnupg-user-socket,
1772     AC_HELP_STRING([--enable-run-gnupg-user-socket],
1773                    [try /run/gnupg/user for sockets prior to /run/user]),
1774     use_run_gnupg_user_socket=$enableval)
1775 if test x"$use_run_gnupg_user_socket" = x"yes"; then
1776    AC_DEFINE(USE_RUN_GNUPG_USER_SOCKET, 1,
1777             [If defined try /run/gnupg/user before /run/user])
1778 fi
1779
1780
1781 #
1782 # Decide what to build
1783 #
1784
1785 build_scdaemon_extra=""
1786 if test "$build_scdaemon" = "yes"; then
1787   if test $have_libusb = no; then
1788      build_scdaemon_extra="without internal CCID driver"
1789   fi
1790   if test -n "$build_scdaemon_extra"; then
1791      build_scdaemon_extra="(${build_scdaemon_extra})"
1792   fi
1793 fi
1794
1795
1796 #
1797 # Set variables for use by automake makefiles.
1798 #
1799 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1800 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1801 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1802 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1803 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1804 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1805 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1806 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1807 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1808 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1809
1810 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1811 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1812 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1813
1814 #
1815 # Set some defines for use gpgconf.
1816 #
1817 if test "$build_gpg" = yes ; then
1818     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1819 fi
1820 if test "$build_gpgsm" = yes ; then
1821     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1822 fi
1823 if test "$build_agent" = yes ; then
1824     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1825 fi
1826 if test "$build_scdaemon" = yes ; then
1827     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1828 fi
1829 if test "$build_dirmngr" = yes ; then
1830     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1831 fi
1832 if test "$build_g13" = yes ; then
1833     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1834 fi
1835
1836
1837 #
1838 # Define Name strings
1839 #
1840 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1841
1842 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1843 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1844
1845 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1846 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1847
1848 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1849 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1850                                         [The displayed name of gpg-agent])
1851
1852 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1853 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1854                                        [The displayed name of scdaemon])
1855
1856 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1857 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1858                                       [The displayed name of dirmngr])
1859
1860 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1861 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1862
1863 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1864 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1865                                       [The displayed name of gpgconf])
1866
1867 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1868
1869 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1870                    [The name of the agent socket])
1871 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1872                    [The name of the agent socket for remote access])
1873 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1874                    [The name of the agent socket for browsers])
1875 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1876                    [The name of the agent socket for ssh])
1877 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1878                    [The name of the dirmngr info envvar])
1879 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1880                    [The name of the SCdaemon socket])
1881 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1882                    [The name of the dirmngr socket])
1883 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1884                    "hkps://hkps.pool.sks-keyservers.net",
1885       [The default keyserver for dirmngr to use, if none is explicitly given])
1886
1887 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1888
1889 if test "$have_w32_system" = yes; then
1890   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1891                      [The directory part of the W32 registry keys])
1892 fi
1893
1894
1895 #
1896 # Provide information about the build.
1897 #
1898 BUILD_REVISION="mym4_revision"
1899 AC_SUBST(BUILD_REVISION)
1900 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1901                    [GIT commit id revision used to build this package])
1902
1903 changequote(,)dnl
1904 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1905 changequote([,])dnl
1906 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1907 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1908 AC_SUBST(BUILD_VERSION)
1909 AC_SUBST(BUILD_FILEVERSION)
1910
1911 AC_ARG_ENABLE([build-timestamp],
1912   AC_HELP_STRING([--enable-build-timestamp],
1913                  [set an explicit build timestamp for reproducibility.
1914                   (default is the current time in ISO-8601 format)]),
1915      [if test "$enableval" = "yes"; then
1916         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1917       else
1918         BUILD_TIMESTAMP="$enableval"
1919       fi
1920       BUILD_HOSTNAME="$ac_hostname"],
1921      [BUILD_TIMESTAMP="<none>"
1922       BUILD_HOSTNAME="<anon>"])
1923 AC_SUBST(BUILD_TIMESTAMP)
1924 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1925                    [The time this package was configured for a build])
1926 AC_SUBST(BUILD_HOSTNAME)
1927
1928
1929 #
1930 # Print errors here so that they are visible all
1931 # together and the user can acquire them all together.
1932 #
1933 die=no
1934 if test "$have_gpg_error" = "no"; then
1935    die=yes
1936    AC_MSG_NOTICE([[
1937 ***
1938 *** You need libgpg-error to build this program.
1939 **  This library is for example available at
1940 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1941 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1942 ***]])
1943 fi
1944 if test "$have_libgcrypt" = "no"; then
1945    die=yes
1946    AC_MSG_NOTICE([[
1947 ***
1948 *** You need libgcrypt to build this program.
1949 **  This library is for example available at
1950 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1951 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1952 ***]])
1953 fi
1954 if test "$have_libassuan" = "no"; then
1955    die=yes
1956    AC_MSG_NOTICE([[
1957 ***
1958 *** You need libassuan to build this program.
1959 *** This library is for example available at
1960 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1961 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1962 ***]])
1963 fi
1964 if test "$have_ksba" = "no"; then
1965     die=yes
1966     AC_MSG_NOTICE([[
1967 ***
1968 *** You need libksba to build this program.
1969 *** This library is for example available at
1970 ***   https://gnupg.org/ftp/gcrypt/libksba/
1971 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1972 ***]])
1973 fi
1974 if test "$gnupg_have_ldap" = yes; then
1975   if test "$have_w32ce_system" = yes; then
1976     AC_MSG_NOTICE([[
1977 *** Note that CeGCC might be broken, a package fixing this is:
1978 ***    http://files.kolab.org/local/windows-ce/
1979 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1980 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1981 ***]])
1982    fi
1983 fi
1984 if test "$have_npth" = "no"; then
1985     die=yes
1986     AC_MSG_NOTICE([[
1987 ***
1988 *** It is now required to build with support for the
1989 *** New Portable Threads Library (nPth). Please install this
1990 *** library first.  The library is for example available at
1991 ***   https://gnupg.org/ftp/gcrypt/npth/
1992 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1993 ***]])
1994 fi
1995
1996 if test "$require_iconv" = yes; then
1997   if test "$am_func_iconv" != yes; then
1998     die=yes
1999     AC_MSG_NOTICE([[
2000 ***
2001 *** The system does not provide a working iconv function.  Please
2002 *** install a suitable library; for example GNU Libiconv which is
2003 *** available at:
2004 ***   https://ftp.gnu.org/gnu/libiconv/
2005 ***]])
2006   fi
2007 fi
2008
2009 if test "$use_ccid_driver" = yes; then
2010   if test "$have_libusb" != yes; then
2011     die=yes
2012     AC_MSG_NOTICE([[
2013 ***
2014 *** You need libusb to build the internal ccid driver.  Please
2015 *** install a libusb suitable for your system.
2016 ***]])
2017   fi
2018 fi
2019
2020 if test "$die" = "yes"; then
2021     AC_MSG_ERROR([[
2022 ***
2023 *** Required libraries not found. Please consult the above messages
2024 *** and install them before running configure again.
2025 ***]])
2026 fi
2027
2028
2029
2030 AC_CONFIG_FILES([ m4/Makefile
2031 Makefile
2032 po/Makefile.in
2033 common/Makefile
2034 common/w32info-rc.h
2035 kbx/Makefile
2036 g10/Makefile
2037 sm/Makefile
2038 agent/Makefile
2039 scd/Makefile
2040 g13/Makefile
2041 dirmngr/Makefile
2042 tools/gpg-zip
2043 tools/Makefile
2044 doc/Makefile
2045 tests/Makefile
2046 tests/gpgscm/Makefile
2047 tests/openpgp/Makefile
2048 tests/migrations/Makefile
2049 tests/gpgsm/Makefile
2050 tests/gpgme/Makefile
2051 tests/pkits/Makefile
2052 g10/gpg.w32-manifest
2053 ])
2054
2055
2056 AC_OUTPUT
2057
2058
2059 echo "
2060         GnuPG v${VERSION} has been configured as follows:
2061
2062         Revision:  mym4_revision  (mym4_revision_dec)
2063         Platform:  $PRINTABLE_OS_NAME ($host)
2064
2065         OpenPGP:   $build_gpg
2066         S/MIME:    $build_gpgsm
2067         Agent:     $build_agent
2068         Smartcard: $build_scdaemon $build_scdaemon_extra
2069         G13:       $build_g13
2070         Dirmngr:   $build_dirmngr
2071         Gpgtar:    $build_gpgtar
2072         WKS tools: $build_wks_tools
2073
2074         Protect tool:      $show_gnupg_protect_tool_pgm
2075         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2076         Default agent:     $show_gnupg_agent_pgm
2077         Default pinentry:  $show_gnupg_pinentry_pgm
2078         Default scdaemon:  $show_gnupg_scdaemon_pgm
2079         Default dirmngr:   $show_gnupg_dirmngr_pgm
2080
2081         Dirmngr auto start:  $dirmngr_auto_start
2082         Readline support:    $gnupg_cv_have_readline
2083         LDAP support:        $gnupg_have_ldap
2084         TLS support:         $use_tls_library
2085         TOFU support:        $use_tofu
2086         Tor support:         $show_tor_support
2087 "
2088 if test x"$use_regex" != xyes ; then
2089 echo "
2090         Warning: No regular expression support available.
2091                  OpenPGP trust signatures won't work.
2092                  gpg-check-pattern will not be built.
2093 "
2094 fi
2095 if test "x${gpg_config_script_warn}" != x; then
2096 cat <<G10EOF
2097         Warning: Mismatches between the target platform and the
2098                  to be used libraries have been detected for:
2099                   ${gpg_config_script_warn}
2100                  Please check above for more warning messages.
2101
2102 G10EOF
2103 fi