10f45ee92d01349cad8ad131625517c3f8ebc44c
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.9.3"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.17-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=1.0
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.9
38
39 NEED_KSBA_VERSION=0.9.11
40
41 NEED_OPENSC_VERSION=0.8.0
42
43
44
45 PACKAGE=$PACKAGE_NAME
46 PACKAGE_GT=${PACKAGE_NAME}2
47 VERSION=$PACKAGE_VERSION
48
49 AC_CONFIG_AUX_DIR(scripts)
50 AC_CONFIG_SRCDIR(sm/gpgsm.c)
51 AM_CONFIG_HEADER(config.h)
52 AC_CANONICAL_TARGET()
53 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
54
55 AC_GNU_SOURCE
56
57 # Some status variables to give feedback at the end of a configure run
58 have_gpg_error=no
59 have_libgcrypt=no 
60 have_libassuan=no
61 have_ksba=no
62 have_opensc=no
63 have_pth=no
64
65 GNUPG_BUILD_PROGRAM(gpg, no)
66 GNUPG_BUILD_PROGRAM(gpgsm, yes)
67 GNUPG_BUILD_PROGRAM(agent, yes)
68 GNUPG_BUILD_PROGRAM(scdaemon, yes)
69 GNUPG_BUILD_PROGRAM(symcryptrun, no)
70
71
72 AC_SUBST(PACKAGE)
73 AC_SUBST(PACKAGE_GT)
74 AC_SUBST(VERSION)
75 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
76 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
77                                 [Name of this package for gettext])
78 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
79 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
80                                         [Bug report address])
81 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
82                                        [Required version of Libgcrypt])
83 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
84                                        [Required version of Libksba])
85
86
87
88 # The default is to use the modules from this package and the few
89 # other packages in a standard place; i.e where this package gets
90 # installed.  With these options it is possible to override these
91 # ${prefix} depended values with fixed paths, which can't be replaced
92 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
93 AC_ARG_WITH(agent-pgm,
94     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
95           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
96 AC_SUBST(GNUPG_AGENT_PGM)
97 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
98 show_gnupg_agent_pgm="(default)"
99 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
100
101 AC_ARG_WITH(pinentry-pgm,
102     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
103           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
104 AC_SUBST(GNUPG_PINENTRY_PGM)
105 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
106 show_gnupg_pinentry_pgm="(default)"
107 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
108
109
110 AC_ARG_WITH(scdaemon-pgm,
111     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
112           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
113 AC_SUBST(GNUPG_SCDAEMON_PGM)
114 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
115 show_gnupg_scdaemon_pgm="(default)"
116 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
117
118
119 AC_ARG_WITH(dirmngr-pgm,
120     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
121           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
122 AC_SUBST(GNUPG_DIRMNGR_PGM)
123 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
124 show_gnupg_dirmngr_pgm="(default)"
125 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
126
127 AC_ARG_WITH(protect-tool-pgm,
128     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
129           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
130 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
131 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
132 show_gnupg_protect_tool_pgm="(default)"
133 test -n "$GNUPG_PROTECT_TOOL_PGM" \
134       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
135
136
137
138 # Some folks want to use only the agent form this packet.  Make it
139 # easier for them by providing the configure option
140 # --enable-only-agent.
141 AC_ARG_ENABLE(agent-only,
142     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
143     build_agent_only=$enableval)
144
145
146 # Configure option to allow or disallow execution of external
147 # programs, like a photo viewer.
148 AC_MSG_CHECKING([whether to enable external program execution])
149 AC_ARG_ENABLE(exec,
150     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
151     use_exec=$enableval)
152 AC_MSG_RESULT($use_exec)
153 if test "$use_exec" = no ; then
154     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
155 fi
156
157 if test "$use_exec" = yes ; then
158   AC_MSG_CHECKING([whether to enable photo ID viewing])
159   AC_ARG_ENABLE(photo-viewers,
160       [  --disable-photo-viewers disable photo ID viewers],
161       [if test "$enableval" = no ; then
162          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
163       fi],enableval=yes)
164   gnupg_cv_enable_photo_viewers=$enableval
165   AC_MSG_RESULT($enableval)
166
167   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
168     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
169     AC_ARG_WITH(photo-viewer,
170         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
171         [if test "$withval" = yes ; then
172            withval=no
173         elif test "$withval" != no ; then
174            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
175                             [if set, restrict photo-viewer to this])
176         fi],withval=no)
177     AC_MSG_RESULT($withval)
178   fi
179
180   AC_MSG_CHECKING([whether to enable external keyserver helpers])
181   AC_ARG_ENABLE(keyserver-helpers,
182       [  --disable-keyserver-helpers  disable all external keyserver support],
183       [if test "$enableval" = no ; then
184          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
185                   [define to disable keyserver helpers])
186       fi],enableval=yes)
187   gnupg_cv_enable_keyserver_helpers=$enableval
188   AC_MSG_RESULT($enableval)
189
190   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
191     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
192     AC_ARG_ENABLE(ldap,
193     [  --disable-ldap          disable LDAP keyserver interface],
194         try_ldap=$enableval, try_ldap=yes)
195     AC_MSG_RESULT($try_ldap)
196
197     AC_MSG_CHECKING([whether HKP keyserver support is requested])
198     AC_ARG_ENABLE(hkp,
199     [  --disable-hkp           disable HKP keyserver interface],
200         try_hkp=$enableval, try_hkp=yes)
201     AC_MSG_RESULT($try_hkp)
202
203     if test "$try_hkp" = yes ; then
204       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
205     fi
206
207     AC_MSG_CHECKING([whether email keyserver support is requested])
208     AC_ARG_ENABLE(mailto,
209     [  --disable-mailto        disable email keyserver interface],
210         try_mailto=$enableval, try_mailto=yes)
211     AC_MSG_RESULT($try_mailto)
212     fi
213
214     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
215     AC_ARG_ENABLE(keyserver-path,
216         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
217         [if test "$enableval" = no ; then
218          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
219         fi],enableval=yes)
220     AC_MSG_RESULT($enableval)
221   fi
222
223 dnl
224 dnl Check whether we want to use Linux capabilities
225 dnl
226 AC_MSG_CHECKING([whether use of capabilities is requested])
227 AC_ARG_WITH(capabilities,
228     [  --with-capabilities     use linux capabilities [default=no]],
229 [use_capabilities="$withval"],[use_capabilities=no])
230 AC_MSG_RESULT($use_capabilities)
231
232
233 AH_BOTTOM([
234 /* Some global constants. */
235 #ifdef HAVE_DRIVE_LETTERS
236 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
237 #elif defined(__VMS)
238 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
239 #else
240 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
241 #endif 
242 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
243
244 /* Tell libgcrypt not to use its own libgpg-error implementation. */
245 #define USE_LIBGPG_ERROR 1
246
247 /* This is the major version number of GnuPG so that
248    source included files can test for this.  Note, that\
249    we use 2 here even for GnuPG 1.9.x. */
250 #define GNUPG_MAJOR_VERSION 2
251
252 /* Now to separate file name parts.
253    Please note that the string version must not contain more
254    than one character because the code assumes strlen()==1 */
255 #ifdef HAVE_DOSISH_SYSTEM
256 #define DIRSEP_C '\\'
257 #define DIRSEP_S "\\"
258 #define EXTSEP_C '.'
259 #define EXTSEP_S "."
260 #define PATHSEP_C ';'
261 #define PATHSEP_S ";"
262 #define EXEEXT_S ".exe"
263 #else
264 #define DIRSEP_C '/'
265 #define DIRSEP_S "/"
266 #define EXTSEP_C '.'
267 #define EXTSEP_S "."
268 #define PATHSEP_C ':'
269 #define PATHSEP_S ":"
270 #define EXEEXT_S ""
271 #endif
272
273 /* This is the same as VERSION, but should be overridden if the
274    platform cannot handle things like dots '.' in filenames. Set
275    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
276    uses for dots and dashes. */
277 #define SAFE_VERSION VERSION
278 #define SAFE_VERSION_DOT  '.'
279 #define SAFE_VERSION_DASH '-'
280
281 /* For some systems (DOS currently), we hardcode the path here.  For
282    POSIX systems the values are constructed by the Makefiles, so that
283    the values may be overridden by the make invocations; this is to
284    comply with the GNU coding standards. */
285 #ifdef HAVE_DRIVE_LETTERS
286 #define GNUPG_BINDIR      "c:\\gnupg"
287 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
288 #define GNUPG_LIBDIR      "c:\\gnupg"
289 #define GNUPG_DATADIR     "c:\\gnupg"
290 #endif
291
292 /* Setup the hardwired names of modules. */
293 #ifndef GNUPG_DEFAULT_AGENT
294 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
295 #endif
296 #ifndef GNUPG_DEFAULT_PINENTRY
297 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
298 #endif
299 #ifndef GNUPG_DEFAULT_SCDAEMON
300 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
301 #endif
302 #ifndef GNUPG_DEFAULT_DIRMNGR
303 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
304 #endif
305 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
306 #define GNUPG_DEFAULT_PROTECT_TOOL \
307                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
308 #endif
309
310
311 /* Derive some other constants. */
312 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
313 #define EXEC_TEMPFILE_ONLY
314 #endif
315
316 /* Temporary hacks to avoid requring a libgpg-error update. */
317 #if !HAVE_DECL_GPG_ERR_LOCKED
318 #define GPG_ERR_LOCKED  173
319 #endif
320
321 ])
322
323 AM_MAINTAINER_MODE
324
325 # Checks for programs.
326 AC_PROG_MAKE_SET
327 AM_SANITY_CHECK
328 missing_dir=`cd $ac_aux_dir && pwd`
329 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
330 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
331 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
332 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
333 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
334 AC_PROG_AWK
335 AC_PROG_CC
336 AC_PROG_CPP
337 AC_PROG_INSTALL
338 AC_PROG_LN_S
339 AC_PROG_MAKE_SET
340 AC_PROG_RANLIB
341 AC_CHECK_TOOL(AR, ar, :)
342 AC_PATH_PROG(PERL,"perl")
343 AC_ISC_POSIX
344 AC_SYS_LARGEFILE
345 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
346 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
347 GNUPG_CHECK_FAQPROG
348 GNUPG_CHECK_DOCBOOK_TO_TEXI
349
350
351 try_gettext=yes
352 have_dosish_system=no
353 have_w32_system=no
354 case "${host}" in
355     *-mingw32*)
356         # special stuff for Windoze NT
357         ac_cv_have_dev_random=no
358         AC_DEFINE(USE_ONLY_8DOT3,1,
359                   [set this to limit filenames to the 8.3 format])
360         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
361                   [defined if we must run on a stupid file system])
362         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
363                   [because the Unix gettext has too much overhead on
364                    MingW32 systems and these systems lack Posix functions,
365                    we use a simplified version of gettext])
366         have_dosish_system=yes
367         have_w32_system=yes
368         try_gettext="no"
369         ;;
370     i?86-emx-os2 | i?86-*-os2*emx )
371         # OS/2 with the EMX environment
372         ac_cv_have_dev_random=no
373         AC_DEFINE(HAVE_DRIVE_LETTERS)
374         have_dosish_system=yes
375         try_gettext="no"
376         ;;
377
378     i?86-*-msdosdjgpp*)
379         # DOS with the DJGPP environment
380         ac_cv_have_dev_random=no
381         AC_DEFINE(HAVE_DRIVE_LETTERS)
382         have_dosish_system=yes
383         try_gettext="no"
384         ;;
385
386     *-*-freebsd*)
387        # FreeBSD
388        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
389        LDFLAGS="$LDFLAGS -L/usr/local/lib"
390        ;;
391
392     *-*-hpux*)
393         if test -z "$GCC" ; then
394             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
395         fi
396         ;;
397     *-dec-osf4*)
398         if test -z "$GCC" ; then
399             # Suppress all warnings
400             # to get rid of the unsigned/signed char mismatch warnings.
401             CFLAGS="$CFLAGS -w"
402         fi
403         ;;
404     *-dec-osf5*)
405         if test -z "$GCC" ; then
406             # Use the newer compiler `-msg_disable ptrmismatch' to
407             # get rid of the unsigned/signed char mismatch warnings.
408             # Using this may hide other pointer mismatch warnings, but
409             # it at least lets other warning classes through
410             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
411         fi
412         ;;
413     m68k-atari-mint)
414         ;;
415     *)
416        ;;
417 esac
418
419 if test "$have_dosish_system" = yes; then
420    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
421              [Defined if we run on some of the PCDOS like systems 
422               (DOS, Windoze. OS/2) with special properties like
423               no file modes])
424 fi
425 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
426
427 if test "$have_w32_system" = yes; then
428    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
429 fi
430 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
431
432
433
434 #
435 # Checks for libraries.
436 #
437
438
439 #
440 # libgpg-error is a library with error codes shared between GnuPG
441 # related projects.
442 #
443 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
444                   have_gpg_error=yes,have_gpg_error=no)
445 _tmp_gpg_error_save_cflags="$CFLAGS"
446 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
447 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
448 CFLAGS="${_tmp_gpg_error_save_cflags}"
449
450
451 #
452 # Libgcrypt is our generic crypto library
453 #
454 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
455         have_libgcrypt=yes,have_libgcrypt=no)
456
457
458 #
459 # libassuan is used for IPC
460 #
461 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
462                   have_libassuan=yes,have_libassuan=no)
463
464
465 #
466 # libksba is our X.509 support library
467 #
468 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
469
470 #
471 # libusb allows us to use the integrated CCID smartcard reader driver.
472 #
473 AC_CHECK_LIB(usb, usb_bulk_write,
474               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
475                 AC_DEFINE(HAVE_LIBUSB,1,
476                          [defined if libusb is available])
477              ])
478 AC_SUBST(LIBUSB_LIBS)
479 AC_CHECK_FUNCS(usb_create_match)
480
481 #
482 # Check wether it is necessary to link against libdl.
483 #
484 LIBS=""
485 AC_SEARCH_LIBS(dlopen, c dl,,,)
486 DL_LIBS=$LIBS
487 AC_SUBST(DL_LIBS)
488
489 #
490 # Checks for symcryptrun:
491 #
492
493 # libutil has openpty() and login_tty().
494 AC_CHECK_LIB(util, openpty,
495               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
496                 AC_DEFINE(HAVE_LIBUTIL,1,
497                          [defined if libutil is available])
498              ])
499 AC_SUBST(LIBUTIL_LIBS)
500
501 # shred is used to clean temporary plain text files.
502 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
503 AC_DEFINE_UNQUOTED(SHRED,
504         "${SHRED}", [defines the filename of the shred program])
505
506 #
507 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
508 # build a limited SCdaemon
509 #
510 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
511 if test $have_opensc = yes; then
512   AC_DEFINE(HAVE_OPENSC,1,
513             [defined if the OpenSC library is available])
514 fi
515 AM_CONDITIONAL(HAVE_OPENSC, test "$have_opensc" = "yes")
516
517 #
518 # Check whether the (highly desirable) GNU Pth library is available
519 # Note, that we include a Pth emulation for W32.
520 #
521 AC_ARG_WITH(pth-prefix,
522             AC_HELP_STRING([--with-pth-prefix=PFX],
523                            [prefix where GNU Pth is installed (optional)]),
524      pth_config_prefix="$withval", pth_config_prefix="")
525 if test x$pth_config_prefix != x ; then
526    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
527 fi
528 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
529 if test "$have_w32_system" = no; then
530  if test "$PTH_CONFIG" = "no"; then
531     AC_MSG_WARN([[
532 ***
533 *** To support concurrent access to the gpg-agent and the SCdaemon
534 *** we need the support of the GNU Portable Threads Library.
535 *** Download it from ftp://ftp.gnu.org/gnu/pth/
536 *** On a Debian GNU/Linux system you might want to try 
537 ***   apt-get install libpth-dev
538 ***]])
539  else
540   GNUPG_PTH_VERSION_CHECK(1.3.7)
541   if test $have_pth = yes; then      
542      PTH_CFLAGS=`$PTH_CONFIG --cflags`
543      PTH_LIBS=`$PTH_CONFIG --ldflags`
544      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
545      AC_DEFINE(USE_GNU_PTH, 1,
546               [Defined if the GNU Portable Thread Library should be used])
547   fi
548  fi
549 else 
550  have_pth=yes
551  PTH_CFLAGS=""
552  PTH_LIBS=""
553  AC_DEFINE(USE_GNU_PTH, 1)
554 fi
555 AC_SUBST(PTH_CFLAGS)
556 AC_SUBST(PTH_LIBS)
557
558 AC_ARG_ENABLE(threads,
559     AC_HELP_STRING([--disable-threads],[allow building without Pth support])
560              )
561
562
563 dnl Must check for network library requirements before doing link tests
564 dnl for ldap, for example. If ldap libs are static (or dynamic and without
565 dnl ELF runtime link paths), then link will fail and LDAP support won't
566 dnl be detected.
567
568 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
569         [NETLIBS="-lnsl $NETLIBS"]))
570 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
571         [NETLIBS="-lsocket $NETLIBS"]))
572
573 dnl Now try for the resolver functions so we can use DNS SRV
574
575 AC_ARG_ENABLE(dns-srv,
576    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
577    use_dns_srv=$enableval,use_dns_srv=yes)
578
579 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
580   _srv_save_libs=$LIBS
581   LIBS=""
582   # the double underscore thing is a glibc-ism?
583   AC_SEARCH_LIBS(res_query,resolv bind,,
584                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
585   AC_SEARCH_LIBS(dn_expand,resolv bind,,
586                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
587   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
588                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
589
590   if test x"$use_dns_srv" = xyes ; then
591      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
592      SRVLIBS=$LIBS
593   else
594      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
595   fi
596   LIBS=$_srv_save_libs
597 fi
598
599 AC_SUBST(SRVLIBS)
600
601 # Try and link a LDAP test program to weed out unusable LDAP
602 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
603 # general is terrible with creating weird dependencies.  If all else
604 # fails, the user can play guess-the-dependency by using something
605 # like ./configure LDAPLIBS="-Lfoo -lbar"
606
607 if test "$try_ldap" = yes ; then
608   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
609     _ldap_save_libs=$LIBS
610     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
611
612     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
613     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
614                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
615     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
616
617     if test $gnupg_cv_func_ldap_init = no; then
618       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
619       AC_TRY_LINK([#include <lber.h>
620 #include <ldap.h>],[ldap_open("foobar",1234);],
621          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
622       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
623     fi
624
625     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
626        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
627     fi
628
629     if test "$gnupg_cv_func_ldap_init" = yes || \
630         test "$gnupg_cv_func_ldaplber_init" = yes ; then
631        LDAPLIBS=$MY_LDAPLIBS
632        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
633
634        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
635
636        if test "$gnupg_cv_func_ldap_init" = yes ; then
637           AC_TRY_LINK([#include <ldap.h>],
638              [ldap_get_option((void *)0,0,(void *)0);],
639              [gnupg_cv_func_ldap_get_option=yes],
640              [gnupg_cv_func_ldap_get_option=no])
641         else
642           AC_TRY_LINK([#include <lber.h>
643 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
644              [gnupg_cv_func_ldap_get_option=yes],
645              [gnupg_cv_func_ldap_get_option=no])
646        fi
647
648        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
649
650        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
651           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
652        else
653           AC_MSG_CHECKING([whether LDAP supports ld_errno])
654
655           if test "$gnupg_cv_func_ldap_init" = yes ; then
656             AC_TRY_COMPILE([#include <ldap.h>],
657                [LDAP *ldap; ldap->ld_errno;],
658                [gnupg_cv_func_ldap_ld_errno=yes],
659                [gnupg_cv_func_ldap_ld_errno=no])
660            else
661             AC_TRY_LINK([#include <lber.h>
662 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
663                [gnupg_cv_func_ldap_ld_errno=yes],
664                [gnupg_cv_func_ldap_ld_errno=no])
665           fi
666
667           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
668
669           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
670              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
671           fi
672        fi
673     fi
674
675     LIBS=$_ldap_save_libs
676
677     if test "$GPGKEYS_LDAP" != "" ; then break; fi
678   done
679 fi
680
681 AC_SUBST(GPGKEYS_LDAP)
682 AC_SUBST(LDAPLIBS)
683
684 dnl This isn't necessarily sendmail itself, but anything that gives a
685 dnl sendmail-ish interface to the outside world.  That includes qmail,
686 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
687
688 if test "$try_mailto" = yes ; then
689   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
690
691   if test "$with_mailprog" = yes ; then
692     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
693     if test "$ac_cv_path_SENDMAIL" ; then
694       GPGKEYS_MAILTO="gpgkeys_mailto"
695     fi
696   elif test "$with_mailprog" != no ; then
697     AC_MSG_CHECKING([for a mail transport program])
698     AC_SUBST(SENDMAIL,$with_mailprog)
699     AC_MSG_RESULT($with_mailprog)
700     GPGKEYS_MAILTO="gpgkeys_mailto"
701   fi
702 fi
703
704 AC_SUBST(GPGKEYS_MAILTO)
705
706 case "${host}" in
707     *-mingw32*)
708         PRINTABLE_OS_NAME="MingW32"
709         ;;
710     *-*-cygwin*)
711         PRINTABLE_OS_NAME="Cygwin"
712         ;;
713     i?86-emx-os2 | i?86-*-os2*emx )
714         PRINTABLE_OS_NAME="OS/2"
715         ;;
716     i?86-*-msdosdjgpp*)
717         PRINTABLE_OS_NAME="MSDOS/DJGPP"
718         try_dynload=no
719         ;;
720     *-linux*)
721         PRINTABLE_OS_NAME="GNU/Linux"
722         ;;
723     *)
724         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
725         ;;
726 esac
727 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
728                    [A human readable text with the name of the OS])
729
730
731 AM_GNU_GETTEXT_VERSION(0.14.1)
732 if test "$try_gettext" = yes; then
733   AM_GNU_GETTEXT(,[need-ngettext])
734
735   # gettext requires some extra checks.  These really should be part of
736   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
737   # function checks to here.
738
739   AC_CHECK_FUNCS(strchr)
740 else
741   USE_NLS=no
742   USE_INCLUDED_LIBINTL=no
743   BUILD_INCLUDED_LIBINTL=no
744   AC_SUBST(USE_NLS)
745   AC_SUBST(USE_INCLUDED_LIBINTL)
746   AC_SUBST(BUILD_INCLUDED_LIBINTL)
747 fi
748
749 # Checks for header files.
750 AC_HEADER_STDC
751 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
752
753 # Checks for typedefs, structures, and compiler characteristics.
754 AC_C_CONST
755 AC_C_INLINE
756 AC_TYPE_SIZE_T
757 AC_TYPE_SIGNAL
758 AC_DECL_SYS_SIGLIST
759
760 GNUPG_CHECK_ENDIAN
761
762 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
763 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
764 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
765 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
766 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
767
768 AC_CHECK_SIZEOF(unsigned short)
769 AC_CHECK_SIZEOF(unsigned int)
770 AC_CHECK_SIZEOF(unsigned long)
771 AC_CHECK_SIZEOF(unsigned long long)
772 # Ensure that we have UINT64_C before we bother to check for uint64_t
773 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
774 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
775    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
776 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
777 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
778    AC_CHECK_SIZEOF(uint64_t)
779 fi
780  
781
782
783
784 if test "$ac_cv_sizeof_unsigned_short" = "0" \
785    || test "$ac_cv_sizeof_unsigned_int" = "0" \
786    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
787     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
788 fi
789
790 dnl Do we have any 64-bit data types?
791 if test "$ac_cv_sizeof_unsigned_int" != "8" \
792    && test "$ac_cv_sizeof_unsigned_long" != "8" \
793    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
794    && test "$ac_cv_sizeof_uint64_t" != "8"; then
795     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
796 else
797   if test x"$use_sha512" = xyes ; then
798      AC_SUBST(SHA512_O,sha512.o)
799      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
800   fi
801 fi
802
803 # fixme: do we really need this - it should be encapsulated in libassuan
804 GNUPG_SYS_SO_PEERCRED
805
806 # Checks for library functions.
807 AC_FUNC_FSEEKO
808 AC_FUNC_VPRINTF
809 AC_FUNC_FORK
810 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
811 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
812 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
813 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
814 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
815
816 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
817
818 # These are needed by libjnlib - fixme: we should have macros for them
819 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
820 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
821 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
822
823 AC_REPLACE_FUNCS(vasprintf)
824 AC_REPLACE_FUNCS(mkdtemp)
825 AC_REPLACE_FUNCS(fseeko ftello)
826 AC_REPLACE_FUNCS(isascii)
827 AC_REPLACE_FUNCS(putc_unlocked)
828 AC_REPLACE_FUNCS(strsep)
829 AC_REPLACE_FUNCS(ttyname)
830
831
832
833 #
834 # check for gethrtime and run a testprogram to see whether
835 # it is broken.  It has been reported that some Solaris and HP UX systems 
836 # raise an SIGILL
837 #
838 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
839 #
840 AC_CACHE_CHECK([for gethrtime], 
841                [gnupg_cv_func_gethrtime],
842                [AC_TRY_LINK([#include <sys/times.h>],[
843                    hrtime_t tv;
844                    tv = gethrtime();
845                  ],
846                  [gnupg_cv_func_gethrtime=yes],
847                  [gnupg_cv_func_gethrtime=no])
848                ])
849 if test $gnupg_cv_func_gethrtime = yes; then
850      AC_DEFINE([HAVE_GETHRTIME], 1,
851                [Define if you have the `gethrtime(2)' function.])
852      AC_CACHE_CHECK([whether gethrtime is broken], 
853                [gnupg_cv_func_broken_gethrtime],
854                [AC_TRY_RUN([
855                    #include <sys/times.h>
856                    int main () {
857                    hrtime_t tv;
858                    tv = gethrtime(); 
859                  }
860                  ],
861                  [gnupg_cv_func_broken_gethrtime=no],
862                  [gnupg_cv_func_broken_gethrtime=yes],
863                  [gnupg_cv_func_broken_gethrtime=assume-no])
864                 ])
865     if test $gnupg_cv_func_broken_gethrtime = yes; then
866       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
867       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
868     fi
869 fi
870      
871
872 GNUPG_CHECK_MLOCK
873 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
874
875 dnl
876 dnl Check whether we can use Linux capabilities as requested
877 dnl
878 #  fixme: Still required?
879 #
880 if test "$use_capabilities" = "yes" ; then
881 use_capabilities=no
882 AC_CHECK_HEADERS(sys/capability.h)
883 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
884   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
885   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
886      AC_DEFINE(USE_CAPABILITIES,1,
887                [define if capabilities should be used])
888      AC_SUBST(CAPLIBS,"-lcap")
889      use_capabilities=yes
890   fi
891 fi
892 if test "$use_capabilities" = "no" ; then
893     AC_MSG_WARN([[
894 ***
895 *** The use of capabilities on this system is not possible.
896 *** You need a recent Linux kernel and some patches:
897 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
898 ***   fcap-module-990613.tar.gz     (kernel module)
899 ***   libcap-1.92.tar.gz            (user mode library and utilities)
900 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
901 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
902 ***]])
903 fi
904 fi
905
906
907 # Sanity check regex.  Tests adapted from mutt.
908
909 AC_MSG_CHECKING([whether regular expression support is requested])
910 AC_ARG_ENABLE(regex,
911 [  --disable-regex         do not handle regular expressions in trust sigs],
912      use_regex=$enableval, use_regex=yes)
913 AC_MSG_RESULT($use_regex)
914
915 if test "$use_regex" = yes ; then
916   AC_MSG_CHECKING([whether the included regex lib is requested])
917   AC_ARG_WITH(included-regex,
918       [  --with-included-regex   use the included GNU regex library],
919       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
920   AC_MSG_RESULT($gnupg_cv_included_regex)
921
922   if test $gnupg_cv_included_regex = no ; then
923      # Does the system have regex functions at all?
924      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
925                            gnupg_cv_included_regex=yes)
926   fi
927
928   if test $gnupg_cv_included_regex = no ; then
929      AC_CACHE_CHECK([whether your system's regexp library is broken],
930        [gnupg_cv_regex_broken],
931        AC_TRY_RUN([
932 #include <unistd.h>
933 #include <regex.h>
934 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
935        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
936
937      if test $gnupg_cv_regex_broken = yes ; then
938       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
939       gnupg_cv_included_regex=yes
940      fi
941   fi
942
943   if test $gnupg_cv_included_regex = yes; then
944      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
945      AC_SUBST(REGEX_O,regex.o)
946   fi
947 else
948
949   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
950 fi
951
952 dnl Do we have zlib? Must do it here because Solaris failed
953 dnl when compiling a conftest (due to the "-lz" from LIBS).
954 _cppflags="${CPPFLAGS}"
955 _ldflags="${LDFLAGS}"
956
957 AC_ARG_WITH(zlib,
958   [  --with-zlib=DIR         use libz in DIR],[
959     if test -d "$withval"; then
960       CPPFLAGS="${CPPFLAGS} -I$withval/include"
961       LDFLAGS="${LDFLAGS} -L$withval/lib"
962     fi
963   ])
964
965 AC_CHECK_HEADER(zlib.h,
966       AC_CHECK_LIB(z, deflateInit2_,
967        LIBS="$LIBS -lz",
968        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
969        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
970  
971
972
973 # See wether we want to run the long test suite.
974 AC_ARG_WITH(pkits-tests,
975     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
976     [run_pkits_tests=$withval], [run_pkits_tests=no])
977 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
978
979
980 # Allow users to append something to the version string without
981 # flagging it as development version.  The user version parts is
982 # considered everything after a dash. 
983 if test "$development_version" != yes; then
984   changequote(,)dnl
985   tmp_pat='[a-zA-Z]'
986   changequote([,])dnl
987   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
988     development_version=yes
989   fi
990 fi
991 if test "$development_version" = yes; then
992     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
993             [Defined if this is not a regular release])
994 fi
995
996 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
997
998 GNUPG_CHECK_GNUMAKE
999
1000 # Add some extra libs here so that previous tests don't fail for
1001 # mysterious reasons - the final link step should bail out. 
1002 if test "$have_w32_system" = yes; then
1003    W32LIBS="-lwsock32"
1004 fi
1005
1006
1007 if test "$GCC" = yes; then
1008     if test "$USE_MAINTAINER_MODE" = "yes"; then
1009         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1010         CFLAGS="$CFLAGS -Wformat-nonliteral"
1011     else
1012         CFLAGS="$CFLAGS -Wall"
1013     fi
1014 fi
1015
1016 AC_SUBST(NETLIBS)
1017 AC_SUBST(W32LIBS)
1018
1019
1020 # We use jnlib, so tell other modules about it
1021 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1022           [Defined if jnlib style logging functions are available])
1023
1024 # For W32 we need to use our Pth emulation code
1025 if test "$have_w32_system" = yes; then
1026   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1027 fi
1028
1029
1030 #
1031 # Decide what to build
1032 #
1033 missing_pth=no
1034 if test $have_ksba = no; then
1035   build_gpgsm=no
1036   build_scdaemon=no
1037 fi
1038
1039 build_agent_threaded=""
1040 if test "$build_agent" = "yes"; then
1041   if test $have_pth = no; then
1042      build_agent_threaded="(not multi-threaded)"
1043      missing_pth=yes
1044   fi
1045 fi
1046
1047 build_scdaemon_extra=""
1048 if test "$build_scdaemon" = "yes"; then
1049   tmp=""
1050   if test $have_pth = no; then
1051      build_scdaemon_extra="not multi-threaded"
1052      tmp=", "
1053      missing_pth=yes
1054   fi
1055   if test $have_opensc = no; then
1056      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
1057      tmp=", "
1058   fi      
1059   if test -n "$build_scdaemon_extra"; then
1060      build_scdaemon_extra="(${build_scdaemon_extra})"
1061   fi
1062 fi
1063
1064
1065 if test "$build_agent_only" = "yes" ; then
1066   build_gpg=no
1067   build_gpgsm=no
1068   build_scdaemon=no
1069 fi
1070
1071
1072 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1073 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1074 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1075 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1076 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1077
1078
1079
1080 #
1081 # Print errors here so that they are visible all
1082 # together and the user can acquire them all together.
1083 #
1084 die=no
1085 if test "$have_gpg_error" = "no"; then
1086    die=yes
1087    AC_MSG_NOTICE([[
1088 ***  
1089 *** You need libgpg-error to build this program.
1090 **  This library is for example available at
1091 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1092 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1093 ***]])
1094 fi
1095 if test "$have_libgcrypt" = "no"; then
1096    die=yes
1097    AC_MSG_NOTICE([[
1098 ***  
1099 *** You need libgcrypt to build this program.
1100 **  This library is for example available at
1101 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1102 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1103 ***]])
1104 fi
1105 if test "$have_libassuan" = "no"; then
1106    die=yes
1107    AC_MSG_NOTICE([[
1108 ***
1109 *** You need libassuan to build this program.
1110 *** This library is for example available at
1111 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1112 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1113 ***]])
1114 fi
1115 if test "$have_ksba" = "no"; then
1116     AC_MSG_NOTICE([[
1117 ***
1118 *** You need libksba to build this program.
1119 *** This library is for example available at
1120 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1121 *** (at least version $NEED_KSBA_VERSION is required).
1122 ***]])
1123 fi
1124 if test "$missing_pth" = "yes"; then
1125     AC_MSG_NOTICE([[
1126 ***
1127 *** It is strongly suggested to build with support for the
1128 *** GNU Portable Threads Library (Pth). Please install this
1129 *** library first or use --disable-threads to allow building
1130 *** anyway.  The library is for example available at
1131 ***   ftp://ftp.gnu.org/gnu/pth/
1132 *** On a Debian GNU/Linux system you can install it using 
1133 ***   apt-get install libpth-dev
1134 ***]])
1135   if test "$enable_threads" != "no"; then
1136      die=yes
1137   fi
1138 fi
1139
1140 if test "$die" = "yes"; then
1141     AC_MSG_ERROR([[
1142 ***
1143 *** Required libraries not found. Please consult the above messages
1144 *** and install them before running configure again.
1145 ***]])
1146 fi
1147
1148
1149
1150 AC_CONFIG_FILES([ m4/Makefile 
1151 Makefile
1152 po/Makefile.in
1153 intl/Makefile
1154 jnlib/Makefile
1155 common/Makefile
1156 kbx/Makefile
1157 g10/Makefile
1158 sm/Makefile
1159 agent/Makefile
1160 scd/Makefile
1161 tools/Makefile
1162 doc/Makefile
1163 tests/Makefile
1164 ])
1165 AC_OUTPUT
1166
1167 #tests/pkits/Makefile
1168
1169
1170
1171
1172 echo "
1173         GnuPG v${VERSION} has been configured as follows:
1174         
1175         Platform:  $PRINTABLE_OS_NAME ($host)
1176
1177         OpenPGP:   $build_gpg
1178         S/MIME:    $build_gpgsm
1179         Agent:     $build_agent $build_agent_threaded
1180         Smartcard: $build_scdaemon $build_scdaemon_extra
1181
1182         Protect tool:      $show_gnupg_protect_tool_pgm
1183         Default agent:     $show_gnupg_agent_pgm
1184         Default pinentry:  $show_gnupg_pinentry_pgm
1185         Default scdaemon:  $show_gnupg_scdaemon_pgm
1186         Default dirmngr:   $show_gnupg_dirmngr_pgm
1187
1188         PKITS based tests: $run_pkits_tests
1189 "
1190