dirmngr: Change the Onion keyserver in the conf template.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2015 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [11])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [http://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.21
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.6.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.1
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.2.0
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=0.91
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_adns=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 card_support=yes
114 use_ccid_driver=yes
115 dirmngr_auto_start=yes
116 use_tls_library=no
117 large_secmem=no
118 show_tor_support=no
119
120
121 GNUPG_BUILD_PROGRAM(gpg, yes)
122 GNUPG_BUILD_PROGRAM(gpgsm, yes)
123 # The agent is a required part and can't be disabled anymore.
124 build_agent=yes
125 GNUPG_BUILD_PROGRAM(scdaemon, yes)
126 GNUPG_BUILD_PROGRAM(g13, no)
127 GNUPG_BUILD_PROGRAM(dirmngr, yes)
128 GNUPG_BUILD_PROGRAM(tools, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132
133 AC_SUBST(PACKAGE)
134 AC_SUBST(PACKAGE_GT)
135 AC_SUBST(VERSION)
136 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
137 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
138                                 [Name of this package for gettext])
139 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
141                                         [Bug report address])
142 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
143                                        [Required version of Libgcrypt])
144 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
145                                        [Required version of Libksba])
146 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
147                                        [Required version of NTBTLS])
148
149
150
151 # The default is to use the modules from this package and the few
152 # other packages in a standard place; i.e where this package gets
153 # installed.  With these options it is possible to override these
154 # ${prefix} depended values with fixed paths, which can't be replaced
155 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
156 AC_ARG_WITH(agent-pgm,
157     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
158           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
159 AC_SUBST(GNUPG_AGENT_PGM)
160 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
161 show_gnupg_agent_pgm="(default)"
162 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
163
164 AC_ARG_WITH(pinentry-pgm,
165     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
166           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
167 AC_SUBST(GNUPG_PINENTRY_PGM)
168 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
169 show_gnupg_pinentry_pgm="(default)"
170 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
171
172
173 AC_ARG_WITH(scdaemon-pgm,
174     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
175           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
176 AC_SUBST(GNUPG_SCDAEMON_PGM)
177 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
178 show_gnupg_scdaemon_pgm="(default)"
179 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
180
181
182 AC_ARG_WITH(dirmngr-pgm,
183     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
184           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
185 AC_SUBST(GNUPG_DIRMNGR_PGM)
186 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
187 show_gnupg_dirmngr_pgm="(default)"
188 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
189
190 AC_ARG_WITH(protect-tool-pgm,
191     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
192           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
193 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
194 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
195 show_gnupg_protect_tool_pgm="(default)"
196 test -n "$GNUPG_PROTECT_TOOL_PGM" \
197       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
198
199 AC_ARG_WITH(dirmngr-ldap-pgm,
200     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
201           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
202 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
203 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
204 show_gnupg_dirmngr_ldap_pgm="(default)"
205 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
206       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
207
208 #
209 # On some platforms gpg2 is usually installed as gpg without using a
210 # symlink.  For correct operation of gpgconf it needs to know the
211 # installed name of gpg.  This option sets "gpg2"'s installed name to
212 # just "gpg".  Note that it might be required to rename gpg2 to gpg
213 # manually after the build process.
214 #
215 AC_ARG_ENABLE(gpg2-is-gpg,
216     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
217     gpg2_is_gpg=$enableval)
218 if test "$gpg2_is_gpg" = "yes"; then
219    name_of_installed_gpg=gpg
220 else
221    name_of_installed_gpg=gpg2
222 fi
223 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
224                    [The name of the installed GPG tool])
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=yes)
267 AC_MSG_RESULT($use_tofu)
268
269
270
271 #
272 # Options to disable algorithm
273 #
274
275 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
276 # Elgamal is a MUST algorithm
277 # DSA is a MUST algorithm
278 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
279 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
280 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
281
282 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
283 # 3DES is a MUST algorithm
284 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
285 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
286 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
287 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
288 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
289 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
290 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
291 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
292 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
293
294 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
295 # SHA1 is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
297 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
298 # SHA256 is a MUST algorithm for GnuPG.
299 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
300 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
301
302
303 # Allow disabling of zip support.
304 # This is in general not a good idea because according to rfc4880 OpenPGP
305 # implementations SHOULD support ZLIB.
306 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
307 AC_ARG_ENABLE(zip,
308    AC_HELP_STRING([--disable-zip],
309                   [disable the ZIP and ZLIB compression algorithm]),
310    use_zip=$enableval)
311 AC_MSG_RESULT($use_zip)
312
313 # Allow disabling of bzib2 support.
314 # It is defined only after we confirm the library is available later
315 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
316 AC_ARG_ENABLE(bzip2,
317    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
318    use_bzip2=$enableval)
319 AC_MSG_RESULT($use_bzip2)
320
321 # Configure option to allow or disallow execution of external
322 # programs, like a photo viewer.
323 AC_MSG_CHECKING([whether to enable external program execution])
324 AC_ARG_ENABLE(exec,
325     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
326     use_exec=$enableval)
327 AC_MSG_RESULT($use_exec)
328 if test "$use_exec" = no ; then
329     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
330 fi
331
332 if test "$use_exec" = yes ; then
333   AC_MSG_CHECKING([whether to enable photo ID viewing])
334   AC_ARG_ENABLE(photo-viewers,
335       [  --disable-photo-viewers disable photo ID viewers],
336       [if test "$enableval" = no ; then
337          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
338       fi],enableval=yes)
339   gnupg_cv_enable_photo_viewers=$enableval
340   AC_MSG_RESULT($enableval)
341
342   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
343     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
344     AC_ARG_WITH(photo-viewer,
345         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
346         [if test "$withval" = yes ; then
347            withval=no
348         elif test "$withval" != no ; then
349            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
350                             [if set, restrict photo-viewer to this])
351         fi],withval=no)
352     AC_MSG_RESULT($withval)
353   fi
354 fi
355
356
357 #
358 # Check for the key/uid cache size.  This can't be zero, but can be
359 # pretty small on embedded systems.  This is used for the gpg part.
360 #
361 AC_MSG_CHECKING([for the size of the key and uid cache])
362 AC_ARG_ENABLE(key-cache,
363         AC_HELP_STRING([--enable-key-cache=SIZE],
364                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
365 if test "$enableval" = "no"; then
366    enableval=5
367 elif test "$enableval" = "yes" || test "$enableval" = ""; then
368    enableval=4096
369 fi
370 changequote(,)dnl
371 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
372 changequote([,])dnl
373 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
374    AC_MSG_ERROR([invalid key-cache size])
375 fi
376 AC_MSG_RESULT($key_cache_size)
377 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
378                   [Size of the key and UID caches])
379
380
381
382 #
383 # Check whether we want to use Linux capabilities
384 #
385 AC_MSG_CHECKING([whether use of capabilities is requested])
386 AC_ARG_WITH(capabilities,
387     [  --with-capabilities     use linux capabilities [default=no]],
388 [use_capabilities="$withval"],[use_capabilities=no])
389 AC_MSG_RESULT($use_capabilities)
390
391 #
392 # Check whether to disable the card support
393 AC_MSG_CHECKING([whether smartcard support is requested])
394 AC_ARG_ENABLE(card-support,
395               AC_HELP_STRING([--disable-card-support],
396                              [disable smartcard support]),
397               card_support=$enableval)
398 AC_MSG_RESULT($card_support)
399 if test "$card_support" = yes ; then
400   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
401 else
402   build_scdaemon=no
403 fi
404
405 #
406 # Allow disabling of internal CCID support.
407 # It is defined only after we confirm the library is available later
408 #
409 AC_MSG_CHECKING([whether to enable the internal CCID driver])
410 AC_ARG_ENABLE(ccid-driver,
411               AC_HELP_STRING([--disable-ccid-driver],
412                              [disable the internal CCID driver]),
413               use_ccid_driver=$enableval)
414 AC_MSG_RESULT($use_ccid_driver)
415
416 AC_MSG_CHECKING([whether to auto start dirmngr])
417 AC_ARG_ENABLE(dirmngr-auto-start,
418               AC_HELP_STRING([--disable-dirmngr-auto-start],
419                              [disable auto starting of the dirmngr]),
420               dirmngr_auto_start=$enableval)
421 AC_MSG_RESULT($dirmngr_auto_start)
422 if test "$dirmngr_auto_start" = yes ; then
423     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
424               [Define to enable auto starting of the dirmngr])
425 fi
426
427
428 #
429 # To avoid double inclusion of config.h which might happen at some
430 # places, we add the usual double inclusion protection at the top of
431 # config.h.
432 #
433 AH_TOP([
434 #ifndef GNUPG_CONFIG_H_INCLUDED
435 #define GNUPG_CONFIG_H_INCLUDED
436 ])
437
438 #
439 # Stuff which goes at the bottom of config.h.
440 #
441 AH_BOTTOM([
442 /* This is the major version number of GnuPG so that
443    source included files can test for this.  Note, that
444    we use 2 here even for GnuPG 1.9.x. */
445 #define GNUPG_MAJOR_VERSION 2
446
447 /* Now to separate file name parts.
448    Please note that the string version must not contain more
449    than one character because the code assumes strlen()==1 */
450 #ifdef HAVE_DOSISH_SYSTEM
451 #define DIRSEP_C '\\'
452 #define DIRSEP_S "\\"
453 #define EXTSEP_C '.'
454 #define EXTSEP_S "."
455 #define PATHSEP_C ';'
456 #define PATHSEP_S ";"
457 #define EXEEXT_S ".exe"
458 #else
459 #define DIRSEP_C '/'
460 #define DIRSEP_S "/"
461 #define EXTSEP_C '.'
462 #define EXTSEP_S "."
463 #define PATHSEP_C ':'
464 #define PATHSEP_S ":"
465 #define EXEEXT_S ""
466 #endif
467
468 /* This is the same as VERSION, but should be overridden if the
469    platform cannot handle things like dots '.' in filenames. Set
470    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
471    uses for dots and dashes. */
472 #define SAFE_VERSION VERSION
473 #define SAFE_VERSION_DOT  '.'
474 #define SAFE_VERSION_DASH '-'
475
476 /* Some global constants. */
477 #ifdef HAVE_DOSISH_SYSTEM
478 # ifdef HAVE_DRIVE_LETTERS
479 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
480 # else
481 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
482 # endif
483 #elif defined(__VMS)
484 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
485 #else
486 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
487 #endif
488 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
489 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
490
491 /* For some systems (DOS currently), we hardcode the path here.  For
492    POSIX systems the values are constructed by the Makefiles, so that
493    the values may be overridden by the make invocations; this is to
494    comply with the GNU coding standards.  Note that these values are
495    only defaults.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_BINDIR      "c:\\gnupg"
499 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
500 #  define GNUPG_LIBDIR      "c:\\gnupg"
501 #  define GNUPG_DATADIR     "c:\\gnupg"
502 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
503 # else
504 #  define GNUPG_BINDIR      "\\gnupg"
505 #  define GNUPG_LIBEXECDIR  "\\gnupg"
506 #  define GNUPG_LIBDIR      "\\gnupg"
507 #  define GNUPG_DATADIR     "\\gnupg"
508 #  define GNUPG_SYSCONFDIR  "\\gnupg"
509 # endif
510 #endif
511
512 /* Derive some other constants. */
513 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
514 #define EXEC_TEMPFILE_ONLY
515 #endif
516
517
518 /* We didn't define endianness above, so get it from OS macros.  This
519    is intended for making fat binary builds on OS X. */
520 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
521 #if defined(__BIG_ENDIAN__)
522 #define BIG_ENDIAN_HOST 1
523 #elif defined(__LITTLE_ENDIAN__)
524 #define LITTLE_ENDIAN_HOST 1
525 #else
526 #error "No endianness found"
527 #endif
528 #endif
529
530
531 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
532    ldap_start_tls_s because that is the actual symbol used in the
533    library.  winldap.h redefines it to our commonly used value,
534    thus we define our usual macro here.  */
535 #ifdef HAVE_LDAP_START_TLS_SA
536 # ifndef HAVE_LDAP_START_TLS_S
537 #  define HAVE_LDAP_START_TLS_S 1
538 # endif
539 #endif
540
541 /* Provide the es_ macro for estream.  */
542 #define GPGRT_ENABLE_ES_MACROS 1
543
544 /* Tell libgcrypt not to use its own libgpg-error implementation. */
545 #define USE_LIBGPG_ERROR 1
546
547 /* Tell Libgcrypt not to include deprecated definitions.  */
548 #define GCRYPT_NO_DEPRECATED 1
549
550 /* Our HTTP code is used in estream mode.  */
551 #define HTTP_USE_ESTREAM 1
552
553 /* Under W32 we do an explicit socket initialization, thus we need to
554    avoid the on-demand initialization which would also install an atexit
555    handler.  */
556 #define HTTP_NO_WSASTARTUP
557
558 /* Under Windows we use the gettext code from libgpg-error.  */
559 #define GPG_ERR_ENABLE_GETTEXT_MACROS
560
561 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
562 #define GPG_ERR_ENABLE_ERRNO_MACROS
563
564 #endif /*GNUPG_CONFIG_H_INCLUDED*/
565 ])
566
567
568 AM_MAINTAINER_MODE
569 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
570
571 # Checks for programs.
572 AC_MSG_NOTICE([checking for programs])
573 AC_PROG_MAKE_SET
574 AM_SANITY_CHECK
575 missing_dir=`cd $ac_aux_dir && pwd`
576 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
577 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
578 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
579 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
580 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
581 AM_SILENT_RULES
582 AC_PROG_AWK
583 AC_PROG_CC
584 AC_PROG_CPP
585 AM_PROG_CC_C_O
586 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
587   AC_MSG_ERROR([[No C-89 compiler found]])
588 fi
589 AC_PROG_INSTALL
590 AC_PROG_LN_S
591 AC_PROG_RANLIB
592 AC_CHECK_TOOL(AR, ar, :)
593 AC_PATH_PROG(PERL,"perl")
594 AC_CHECK_TOOL(WINDRES, windres, :)
595 AC_ISC_POSIX
596 AC_SYS_LARGEFILE
597 GNUPG_CHECK_USTAR
598
599
600 # We need to compile and run a program on the build machine.  A
601 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
602 # the AC archive is broken for autoconf 2.57.  Given that there is no
603 # newer version of that macro, we assume that it is also broken for
604 # autoconf 2.61 and thus we use a simple but usually sufficient
605 # approach.
606 AC_MSG_CHECKING(for cc for build)
607 if test "$cross_compiling" = "yes"; then
608   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
609 else
610   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
611 fi
612 AC_MSG_RESULT($CC_FOR_BUILD)
613 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
614
615 # We need to call this macro because other pkg-config macros are
616 # not always used.
617 PKG_PROG_PKG_CONFIG
618
619
620 try_gettext=yes
621 require_iconv=yes
622 have_dosish_system=no
623 have_w32_system=no
624 have_w32ce_system=no
625 have_android_system=no
626 run_tests=yes
627 use_simple_gettext=no
628 use_ldapwrapper=yes
629 mmap_needed=yes
630 case "${host}" in
631     *-mingw32*)
632         # special stuff for Windoze NT
633         ac_cv_have_dev_random=no
634         AC_DEFINE(USE_ONLY_8DOT3,1,
635                   [Set this to limit filenames to the 8.3 format])
636         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
637                   [Because the Unix gettext has too much overhead on
638                    MingW32 systems and these systems lack Posix functions,
639                    we use a simplified version of gettext])
640         have_dosish_system=yes
641         have_w32_system=yes
642         run_tests=no
643         use_ldapwrapper=no  # Fixme: Do this only for CE.
644         case "${host}" in
645           *-mingw32ce*)
646             have_w32ce_system=yes
647             ;;
648           *)
649             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
650                       [Defined if the OS supports drive letters.])
651             ;;
652         esac
653         try_gettext="no"
654         use_simple_gettext=yes
655         mmap_needed=no
656         ;;
657     i?86-emx-os2 | i?86-*-os2*emx )
658         # OS/2 with the EMX environment
659         ac_cv_have_dev_random=no
660         AC_DEFINE(HAVE_DRIVE_LETTERS)
661         have_dosish_system=yes
662         try_gettext="no"
663         ;;
664
665     i?86-*-msdosdjgpp*)
666         # DOS with the DJGPP environment
667         ac_cv_have_dev_random=no
668         AC_DEFINE(HAVE_DRIVE_LETTERS)
669         have_dosish_system=yes
670         try_gettext="no"
671         ;;
672
673     *-*-hpux*)
674         if test -z "$GCC" ; then
675             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
676         fi
677         ;;
678     *-dec-osf4*)
679         if test -z "$GCC" ; then
680             # Suppress all warnings
681             # to get rid of the unsigned/signed char mismatch warnings.
682             CFLAGS="-w $CFLAGS"
683         fi
684         ;;
685     *-dec-osf5*)
686         if test -z "$GCC" ; then
687             # Use the newer compiler `-msg_disable ptrmismatch1' to
688             # get rid of the unsigned/signed char mismatch warnings.
689             # Using this may hide other pointer mismatch warnings, but
690             # it at least lets other warning classes through
691             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
692         fi
693         ;;
694     m68k-atari-mint)
695         ;;
696     *-linux-androideabi)
697         have_android_system=yes
698         # Android is fully utf-8 and we do not want to use iconv to
699         # keeps things simple
700         require_iconv=no
701         run_tests=no
702         ;;
703     *)
704        ;;
705 esac
706
707 if test "$have_dosish_system" = yes; then
708    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
709              [Defined if we run on some of the PCDOS like systems
710               (DOS, Windoze. OS/2) with special properties like
711               no file modes, case insensitive file names and preferred
712               use of backslashes as directory name separators.])
713 fi
714 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
715
716 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
717
718 if test "$have_w32_system" = yes; then
719    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
720    if test "$have_w32ce_system" = yes; then
721       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
722    fi
723 fi
724 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
725 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
726
727 if test "$have_android_system" = yes; then
728    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
729 fi
730 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
731
732 if test "$run_tests" = yes; then
733    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
734 fi
735 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
736
737
738 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
739 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
740
741
742 #
743 # Checks for libraries.
744 #
745 AC_MSG_NOTICE([checking for libraries])
746
747
748 #
749 # libgpg-error is a library with error codes shared between GnuPG
750 # related projects.
751 #
752 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
753                   have_gpg_error=yes,have_gpg_error=no)
754
755
756 #
757 # Libgcrypt is our generic crypto library
758 #
759 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
760         have_libgcrypt=yes,have_libgcrypt=no)
761
762
763 #
764 # libassuan is used for IPC
765 #
766 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
767                   have_libassuan=yes,have_libassuan=no)
768 if test "$have_libassuan" = "yes"; then
769   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
770                      [version of the libassuan library])
771   show_tor_support="only .onion"
772 fi
773
774
775 #
776 # libksba is our X.509 support library
777 #
778 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
779
780
781 #
782 # libusb allows us to use the integrated CCID smartcard reader driver.
783 #
784 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
785 if test "$use_ccid_driver" = yes ; then
786   AC_CHECK_LIB(usb, usb_bulk_write,
787                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
788                   AC_DEFINE(HAVE_LIBUSB,1,
789                            [defined if libusb is available])
790                   have_libusb=yes
791                ])
792   AC_CHECK_FUNCS(usb_create_match)
793 fi
794 AC_SUBST(LIBUSB_LIBS)
795
796 #
797 # Check wether it is necessary to link against libdl.
798 # (For example to load libpcsclite)
799 #
800 gnupg_dlopen_save_libs="$LIBS"
801 LIBS=""
802 AC_SEARCH_LIBS(dlopen, c dl,,,)
803 DL_LIBS=$LIBS
804 AC_SUBST(DL_LIBS)
805 LIBS="$gnupg_dlopen_save_libs"
806
807
808 # Checks for g10
809
810 AC_ARG_ENABLE(sqlite,
811                 AC_HELP_STRING([--disable-sqlite],
812                                [disable the use of SQLITE]),
813               try_sqlite=$enableval, try_sqlite=yes)
814
815 if test x"$use_tofu" = xyes ; then
816   if test x"$try_sqlite" = xyes ; then
817     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
818                                  [have_sqlite=yes],
819                                  [have_sqlite=no])
820   fi
821   if test "$have_sqlite" = "yes"; then
822     :
823     AC_SUBST([SQLITE3_CFLAGS])
824     AC_SUBST([SQLITE3_LIBS])
825   else
826     use_tofu=no
827     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
828     AC_MSG_WARN([[
829 ***
830 *** Building without SQLite support - TOFU disabled
831 ***
832 *** $tmp]])
833   fi
834 fi
835
836 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
837
838 if test x"$use_tofu" = xyes ; then
839     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
840 fi
841
842
843 # Checks for g13
844
845 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
846 AC_DEFINE_UNQUOTED(ENCFS,
847         "${ENCFS}", [defines the filename of the encfs program])
848
849 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
850 AC_DEFINE_UNQUOTED(FUSERMOUNT,
851         "${FUSERMOUNT}", [defines the filename of the fusermount program])
852
853
854 # Checks for dirmngr
855
856
857 #
858 # Checks for symcryptrun:
859 #
860
861 # libutil has openpty() and login_tty().
862 AC_CHECK_LIB(util, openpty,
863               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
864                 AC_DEFINE(HAVE_LIBUTIL,1,
865                          [defined if libutil is available])
866              ])
867 AC_SUBST(LIBUTIL_LIBS)
868
869 # shred is used to clean temporary plain text files.
870 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
871 AC_DEFINE_UNQUOTED(SHRED,
872         "${SHRED}", [defines the filename of the shred program])
873
874
875 #
876 # Check whether the nPth library is available
877 #
878 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
879 if test "$have_npth" = "yes"; then
880   AC_DEFINE(HAVE_NPTH, 1,
881               [Defined if the New Portable Thread Library is available])
882   AC_DEFINE(USE_NPTH, 1,
883               [Defined if support for nPth is requested and nPth is available])
884 else
885   AC_MSG_WARN([[
886 ***
887 *** To support concurrent access for example in gpg-agent and the SCdaemon
888 *** we need the support of the New Portable Threads Library.
889 ***]])
890 fi
891
892
893 #
894 # NTBTLS is our TLS library.  If it is not available fallback to
895 # GNUTLS.
896 #
897 AC_ARG_ENABLE(ntbtls,
898               AC_HELP_STRING([--disable-ntbtls],
899                              [disable the use of NTBTLS as TLS library]),
900               try_ntbtls=$enableval, try_ntbtls=yes)
901 if test x"$try_ntbtls" = xyes ; then
902   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
903                  [have_ntbtls=yes],[have_ntbtls=no])
904 fi
905 if test "$have_ntbtls" = yes ; then
906    use_tls_library=ntbtls
907    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
908 else
909   AC_ARG_ENABLE(gnutls,
910                 AC_HELP_STRING([--disable-gnutls],
911                                [disable GNUTLS as fallback TLS library]),
912                 try_gnutls=$enableval, try_gnutls=yes)
913   if test x"$try_gnutls" = xyes ; then
914     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
915                                    [have_gnutls=yes],
916                                    [have_gnutls=no])
917   fi
918   if test "$have_gnutls" = "yes"; then
919     AC_SUBST([LIBGNUTLS_CFLAGS])
920     AC_SUBST([LIBGNUTLS_LIBS])
921     use_tls_library=gnutls
922     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
923   else
924     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
925     AC_MSG_WARN([[
926 ***
927 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
928 ***
929 *** $tmp]])
930   fi
931 fi
932
933
934 AC_MSG_NOTICE([checking for networking options])
935
936 #
937 # Must check for network library requirements before doing link tests
938 # for ldap, for example. If ldap libs are static (or dynamic and without
939 # ELF runtime link paths), then link will fail and LDAP support won't
940 # be detected.
941 #
942 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
943         [NETLIBS="-lnsl $NETLIBS"]))
944 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
945         [NETLIBS="-lsocket $NETLIBS"]))
946
947
948 #
949 # Check for ADNS.
950 #
951 _cppflags="${CPPFLAGS}"
952 _ldflags="${LDFLAGS}"
953 AC_ARG_WITH(adns,
954             AC_HELP_STRING([--with-adns=DIR],
955                            [look for the adns library in DIR]),
956             [if test -d "$withval"; then
957                CPPFLAGS="${CPPFLAGS} -I$withval/include"
958                LDFLAGS="${LDFLAGS} -L$withval/lib"
959              fi])
960 if test "$with_adns" != "no"; then
961   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
962   AC_CHECK_FUNCS(adns_free)
963   AC_MSG_CHECKING([if adns supports adns_if_tormode])
964   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
965     #include <adns.h>
966     adns_initflags flags = adns_if_tormode;
967   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
968   AC_MSG_RESULT($adns_if_tormode)
969   if test x"$adns_if_tormode" = xyes; then
970     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
971     if test "$show_tor_support" != "no"; then
972       show_tor_support=yes
973     fi
974   fi
975 fi
976 CPPFLAGS=${_cppflags}
977 LDFLAGS=${_ldflags}
978 if test "$have_adns" = "yes"; then
979   ADNSLIBS="-ladns"
980 fi
981
982
983 #
984 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
985 #
986 AC_ARG_ENABLE(dns-srv,
987               AC_HELP_STRING([--disable-dns-srv],
988                              [disable the use of DNS SRV in HKP and HTTP]),
989               use_dns_srv=$enableval,use_dns_srv=yes)
990
991 AC_ARG_ENABLE(dns-cert,
992    AC_HELP_STRING([--disable-dns-cert],
993         [disable the use of CERT records in DNS]),
994    use_dns_cert=$enableval,use_dns_cert=yes)
995
996 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
997   _dns_save_libs=$LIBS
998   LIBS=""
999
1000   if test x"$have_adns" = xyes ; then
1001     # We prefer ADNS.
1002     DNSLIBS="$ADNSLIBS"
1003     AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1004
1005     if test x"$use_dns_srv" = xyes ; then
1006         AC_DEFINE(USE_DNS_SRV,1)
1007     fi
1008
1009     if test x"$use_dns_cert" = xyes ; then
1010         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1011     fi
1012   else
1013     # With no ADNS find the system resolver.
1014
1015     # the double underscore thing is a glibc-ism?
1016     AC_SEARCH_LIBS(res_query,resolv bind,,
1017                    AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1018     AC_SEARCH_LIBS(dn_expand,resolv bind,,
1019                    AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1020     AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1021                    AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
1022
1023     if test x"$have_resolver" != xno ; then
1024
1025       # Make sure that the BIND 4 resolver interface is workable before
1026       # enabling any code that calls it.  At some point I'll rewrite the
1027       # code to use the BIND 8 resolver API.
1028       # We might also want to use adns instead.  Problem with ADNS is that
1029       # it does not support v6.
1030
1031       AC_MSG_CHECKING([whether the resolver is usable])
1032       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1033 #include <netinet/in.h>
1034 #include <arpa/nameser.h>
1035 #include <resolv.h>]],
1036 [[unsigned char answer[PACKETSZ];
1037   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1038   dn_skipname(0,0);
1039   dn_expand(0,0,0,0,0);
1040 ]])],have_resolver=yes,have_resolver=no)
1041       AC_MSG_RESULT($have_resolver)
1042
1043       # This is Apple-specific and somewhat bizarre as they changed the
1044       # define in bind 8 for some reason.
1045
1046       if test x"$have_resolver" != xyes ; then
1047          AC_MSG_CHECKING(
1048              [whether I can make the resolver usable with BIND_8_COMPAT])
1049         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1050 #include <sys/types.h>
1051 #include <netinet/in.h>
1052 #include <arpa/nameser.h>
1053 #include <resolv.h>]],
1054 [[unsigned char answer[PACKETSZ];
1055   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1056   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1057 ]])],[have_resolver=yes ; need_compat=yes])
1058          AC_MSG_RESULT($have_resolver)
1059       fi
1060     fi
1061
1062     if test x"$have_resolver" = xyes ; then
1063       DNSLIBS=$LIBS
1064
1065       if test x"$use_dns_srv" = xyes ; then
1066          AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
1067       fi
1068
1069       if test x"$use_dns_cert" = xyes ; then
1070         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1071       fi
1072
1073       if test x"$need_compat" = xyes ; then
1074         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1075       fi
1076     else
1077       use_dns_srv=no
1078       use_dns_cert=no
1079     fi
1080   fi
1081
1082   LIBS=$_dns_save_libs
1083 fi
1084
1085 AC_SUBST(DNSLIBS)
1086
1087 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1088
1089
1090 #
1091 # Check for LDAP
1092 #
1093 # Note that running the check changes the variable
1094 # gnupg_have_ldap from "n/a" to "no" or "yes".
1095
1096 AC_ARG_ENABLE(ldap,
1097     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1098     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1099
1100 if test "$gnupg_have_ldap" != "no" ; then
1101   if test "$build_dirmngr" = "yes" ; then
1102      GNUPG_CHECK_LDAP($NETLIBS)
1103      AC_CHECK_LIB(lber, ber_free,
1104                   [ LBER_LIBS="$LBER_LIBS -llber"
1105                     AC_DEFINE(HAVE_LBER,1,
1106                              [defined if liblber is available])
1107                     have_lber=yes
1108                  ])
1109   fi
1110 fi
1111 AC_SUBST(LBER_LIBS)
1112 if test "$gnupg_have_ldap" = "no"; then
1113     AC_MSG_WARN([[
1114 ***
1115 *** Building without LDAP support.
1116 *** No CRL access or X.509 certificate search available.
1117 ***]])
1118 fi
1119
1120 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1121 if test "$gnupg_have_ldap" = yes ; then
1122   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1123 else
1124  use_ldapwrapper=no
1125 fi
1126
1127 if test "$use_ldapwrapper" = yes; then
1128    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1129 fi
1130 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1131
1132
1133
1134
1135 #
1136 # Check for sendmail
1137 #
1138 # This isn't necessarily sendmail itself, but anything that gives a
1139 # sendmail-ish interface to the outside world.  That includes Exim,
1140 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1141 AC_ARG_WITH(mailprog,
1142       AC_HELP_STRING([--with-mailprog=NAME],
1143                      [use "NAME -t" for mail transport]),
1144              ,with_mailprog=yes)
1145 if test x"$with_mailprog" = xyes ; then
1146     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1147 elif test x"$with_mailprog" != xno ; then
1148     AC_MSG_CHECKING([for a mail transport program])
1149     AC_SUBST(SENDMAIL,$with_mailprog)
1150     AC_MSG_RESULT($with_mailprog)
1151 fi
1152
1153
1154 #
1155 # Construct a printable name of the OS
1156 #
1157 case "${host}" in
1158     *-mingw32ce*)
1159         PRINTABLE_OS_NAME="W32CE"
1160         ;;
1161     *-mingw32*)
1162         PRINTABLE_OS_NAME="MingW32"
1163         ;;
1164     *-*-cygwin*)
1165         PRINTABLE_OS_NAME="Cygwin"
1166         ;;
1167     i?86-emx-os2 | i?86-*-os2*emx )
1168         PRINTABLE_OS_NAME="OS/2"
1169         ;;
1170     i?86-*-msdosdjgpp*)
1171         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1172         try_dynload=no
1173         ;;
1174     *-linux*)
1175         PRINTABLE_OS_NAME="GNU/Linux"
1176         ;;
1177     *)
1178         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1179         ;;
1180 esac
1181 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1182                    [A human readable text with the name of the OS])
1183
1184
1185 #
1186 # Checking for iconv
1187 #
1188 if test "$require_iconv" = yes; then
1189   AM_ICONV
1190 else
1191   LIBICONV=
1192   LTLIBICONV=
1193   AC_SUBST(LIBICONV)
1194   AC_SUBST(LTLIBICONV)
1195 fi
1196
1197
1198 #
1199 # Check for gettext
1200 #
1201 # This is "GNU gnupg" - The project-id script from gettext
1202 #                       needs this string
1203 #
1204 AC_MSG_NOTICE([checking for gettext])
1205 AM_PO_SUBDIRS
1206 AM_GNU_GETTEXT_VERSION([0.17])
1207 if test "$try_gettext" = yes; then
1208   AM_GNU_GETTEXT([external],[need-ngettext])
1209
1210   # gettext requires some extra checks.  These really should be part of
1211   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1212   # function checks to here.
1213
1214   AC_CHECK_FUNCS(strchr)
1215 else
1216   USE_NLS=no
1217   USE_INCLUDED_LIBINTL=no
1218   BUILD_INCLUDED_LIBINTL=no
1219   POSUB=po
1220   AC_SUBST(USE_NLS)
1221   AC_SUBST(USE_INCLUDED_LIBINTL)
1222   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1223   AC_SUBST(POSUB)
1224 fi
1225
1226 # We use HAVE_LANGINFO_CODESET in a couple of places.
1227 AM_LANGINFO_CODESET
1228
1229 # Checks required for our use of locales
1230 gt_LC_MESSAGES
1231
1232
1233 #
1234 # SELinux support
1235 #
1236 if test "$selinux_support" = yes ; then
1237   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1238 fi
1239
1240
1241 #
1242 # Checks for header files.
1243 #
1244 AC_MSG_NOTICE([checking for header files])
1245 AC_HEADER_STDC
1246 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1247                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1248                   signal.h])
1249 AC_HEADER_TIME
1250
1251
1252 #
1253 # Checks for typedefs, structures, and compiler characteristics.
1254 #
1255 AC_MSG_NOTICE([checking for system characteristics])
1256 AC_C_CONST
1257 AC_C_INLINE
1258 AC_C_VOLATILE
1259 AC_TYPE_SIZE_T
1260 AC_TYPE_MODE_T
1261 AC_TYPE_SIGNAL
1262 AC_DECL_SYS_SIGLIST
1263
1264 gl_HEADER_SYS_SOCKET
1265 gl_TYPE_SOCKLEN_T
1266
1267 AC_SEARCH_LIBS([inet_addr], [nsl])
1268
1269 AC_ARG_ENABLE(endian-check,
1270               AC_HELP_STRING([--disable-endian-check],
1271               [disable the endian check and trust the OS provided macros]),
1272               endiancheck=$enableval,endiancheck=yes)
1273
1274 if test x"$endiancheck" = xyes ; then
1275   GNUPG_CHECK_ENDIAN
1276 fi
1277
1278 # fixme: we should get rid of the byte type
1279 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1280 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1281 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1282 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1283 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1284
1285 AC_CHECK_SIZEOF(unsigned short)
1286 AC_CHECK_SIZEOF(unsigned int)
1287 AC_CHECK_SIZEOF(unsigned long)
1288 AC_CHECK_SIZEOF(unsigned long long)
1289 AC_HEADER_TIME
1290 AC_CHECK_SIZEOF(time_t,,[[
1291 #include <stdio.h>
1292 #if TIME_WITH_SYS_TIME
1293 # include <sys/time.h>
1294 # include <time.h>
1295 #else
1296 # if HAVE_SYS_TIME_H
1297 #  include <sys/time.h>
1298 # else
1299 #  include <time.h>
1300 # endif
1301 #endif
1302 ]])
1303 GNUPG_TIME_T_UNSIGNED
1304
1305
1306 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1307    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1308    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1309     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1310 fi
1311
1312
1313 #
1314 # Checks for library functions.
1315 #
1316 AC_MSG_NOTICE([checking for library functions])
1317 AC_CHECK_DECLS(getpagesize)
1318 AC_FUNC_FSEEKO
1319 AC_FUNC_VPRINTF
1320 AC_FUNC_FORK
1321 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1322 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1323 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1324 AC_CHECK_FUNCS([canonicalize_file_name])
1325 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1326 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1327 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1328 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1329 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1330                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1331                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1332                 getenv inet_pton strpbrk])
1333
1334 if test "$have_android_system" = yes; then
1335    # On Android ttyname is a stub but prints an error message.
1336    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1337              [Defined if ttyname does not work properly])
1338 fi
1339
1340 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1341
1342 # Dirmngr requires mmap on Unix systems.
1343 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1344   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1345 fi
1346
1347 #
1348 # W32 specific test
1349 #
1350 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1351
1352 #
1353 # Sanity check regex.  Tests adapted from mutt.
1354 #
1355 AC_MSG_CHECKING([whether regular expression support is requested])
1356 AC_ARG_ENABLE(regex,
1357   AC_HELP_STRING([--disable-regex],
1358     [do not handle regular expressions in trust signatures]),
1359   use_regex=$enableval, use_regex=yes)
1360 AC_MSG_RESULT($use_regex)
1361
1362 if test "$use_regex" = yes ; then
1363   _cppflags="${CPPFLAGS}"
1364   _ldflags="${LDFLAGS}"
1365   AC_ARG_WITH(regex,
1366      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1367       [
1368       if test -d "$withval" ; then
1369         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1370         LDFLAGS="${LDFLAGS} -L$withval/lib"
1371       fi
1372       ],withval="")
1373
1374   # Does the system have regex functions at all?
1375   AC_SEARCH_LIBS([regcomp], [regex])
1376   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1377
1378   if test $gnupg_cv_have_regex = no; then
1379     use_regex=no
1380   else
1381     if test x"$cross_compiling" = xyes; then
1382       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1383     else
1384       AC_CACHE_CHECK([whether your system's regexp library is broken],
1385        [gnupg_cv_regex_broken],
1386        AC_TRY_RUN([
1387 #include <unistd.h>
1388 #include <regex.h>
1389 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1390        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1391
1392       if test $gnupg_cv_regex_broken = yes; then
1393         AC_MSG_WARN([your regex is broken - disabling regex use])
1394         use_regex=no
1395       fi
1396     fi
1397   fi
1398   CPPFLAGS="${_cppflags}"
1399   LDFLAGS="${_ldflags}"
1400 fi
1401
1402 if test "$use_regex" != yes ; then
1403   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1404 fi
1405 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1406
1407
1408
1409 #
1410 # Do we have zlib? Must do it here because Solaris failed
1411 # when compiling a conftest (due to the "-lz" from LIBS).
1412 # Note that we combine zlib and bzlib2 in ZLIBS.
1413 #
1414 if test "$use_zip" = yes ; then
1415   _cppflags="${CPPFLAGS}"
1416   _ldflags="${LDFLAGS}"
1417   AC_ARG_WITH(zlib,
1418     [  --with-zlib=DIR         use libz in DIR],[
1419       if test -d "$withval"; then
1420         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1421         LDFLAGS="${LDFLAGS} -L$withval/lib"
1422       fi
1423     ])
1424
1425   AC_CHECK_HEADER(zlib.h,
1426      AC_CHECK_LIB(z, deflateInit2_,
1427        [
1428        ZLIBS="-lz"
1429        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1430        ],
1431        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1432        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1433 fi
1434
1435
1436 #
1437 # Check whether we can support bzip2
1438 #
1439 if test "$use_bzip2" = yes ; then
1440   _cppflags="${CPPFLAGS}"
1441   _ldflags="${LDFLAGS}"
1442   AC_ARG_WITH(bzip2,
1443      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1444       [
1445       if test -d "$withval" ; then
1446         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1447         LDFLAGS="${LDFLAGS} -L$withval/lib"
1448       fi
1449       ],withval="")
1450
1451   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1452   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1453   # woefully out of date.
1454   if test "$withval" != no ; then
1455      AC_CHECK_HEADER(bzlib.h,
1456         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1457           [
1458           have_bz2=yes
1459           ZLIBS="$ZLIBS -lbz2"
1460           AC_DEFINE(HAVE_BZIP2,1,
1461                   [Defined if the bz2 compression library is available])
1462           ],
1463           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1464           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1465   fi
1466 fi
1467 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1468 AC_SUBST(ZLIBS)
1469
1470
1471 # Check for readline support
1472 GNUPG_CHECK_READLINE
1473
1474
1475 if test "$development_version" = yes; then
1476     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1477             [Defined if this is not a regular release])
1478 fi
1479
1480 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1481
1482 GNUPG_CHECK_GNUMAKE
1483
1484 # Add some extra libs here so that previous tests don't fail for
1485 # mysterious reasons - the final link step should bail out.
1486 # W32SOCKLIBS is also defined so that if can be used for tools not
1487 # requiring any network stuff but linking to code in libcommon which
1488 # tracks in winsock stuff (e.g. init_common_subsystems).
1489 if test "$have_w32_system" = yes; then
1490    if test "$have_w32ce_system" = yes; then
1491      W32SOCKLIBS="-lws2"
1492    else
1493      W32SOCKLIBS="-lws2_32"
1494    fi
1495    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1496 fi
1497
1498 AC_SUBST(NETLIBS)
1499 AC_SUBST(W32SOCKLIBS)
1500
1501 #
1502 # Setup gcc specific options
1503 #
1504 AC_MSG_NOTICE([checking for cc features])
1505 if test "$GCC" = yes; then
1506     mycflags=
1507     mycflags_save=$CFLAGS
1508
1509     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1510     # options.  This is the case for gcc >= 4.6
1511     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1512     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1513 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1514 #kickerror
1515 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1516     AC_MSG_RESULT($_gcc_silent_wno)
1517
1518     # Note that it is okay to use CFLAGS here because these are just
1519     # warning options and the user should have a chance of overriding
1520     # them.
1521     if test "$USE_MAINTAINER_MODE" = "yes"; then
1522         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1523         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1524         if test x"$_gcc_silent_wno" = xyes ; then
1525           _gcc_wopt=yes
1526         else
1527           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1528           CFLAGS="-Wno-missing-field-initializers"
1529           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1530                             [_gcc_wopt=yes],[_gcc_wopt=no])
1531           AC_MSG_RESULT($_gcc_wopt)
1532         fi
1533         if test x"$_gcc_wopt" = xyes ; then
1534           mycflags="$mycflags -W -Wno-sign-compare"
1535           mycflags="$mycflags -Wno-missing-field-initializers"
1536         fi
1537
1538         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1539         CFLAGS="-Wdeclaration-after-statement"
1540         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1541         AC_MSG_RESULT($_gcc_wopt)
1542         if test x"$_gcc_wopt" = xyes ; then
1543           mycflags="$mycflags -Wdeclaration-after-statement"
1544         fi
1545     else
1546         mycflags="$mycflags -Wall"
1547     fi
1548
1549     if test x"$_gcc_silent_wno" = xyes ; then
1550       _gcc_psign=yes
1551     else
1552       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1553       CFLAGS="-Wno-pointer-sign"
1554       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1555                         [_gcc_psign=yes],[_gcc_psign=no])
1556       AC_MSG_RESULT($_gcc_psign)
1557     fi
1558     if test x"$_gcc_psign" = xyes ; then
1559        mycflags="$mycflags -Wno-pointer-sign"
1560     fi
1561
1562     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1563     CFLAGS="-Wpointer-arith"
1564     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1565     AC_MSG_RESULT($_gcc_psign)
1566     if test x"$_gcc_psign" = xyes ; then
1567        mycflags="$mycflags -Wpointer-arith"
1568     fi
1569
1570     CFLAGS="$mycflags $mycflags_save"
1571 fi
1572
1573
1574 #
1575 # This is handy for debugging so the compiler doesn't rearrange
1576 # things and eliminate variables.
1577 #
1578 AC_ARG_ENABLE(optimization,
1579    AC_HELP_STRING([--disable-optimization],
1580                   [disable compiler optimization]),
1581                   [if test $enableval = no ; then
1582                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1583                    fi])
1584
1585 #
1586 # Add user CFLAGS.
1587 #
1588 CFLAGS="$CFLAGS $CFLAGS_orig"
1589
1590 #
1591 # Decide what to build
1592 #
1593
1594 build_scdaemon_extra=""
1595 if test "$build_scdaemon" = "yes"; then
1596   if test $have_libusb = no; then
1597      build_scdaemon_extra="without internal CCID driver"
1598   fi
1599   if test -n "$build_scdaemon_extra"; then
1600      build_scdaemon_extra="(${build_scdaemon_extra})"
1601   fi
1602 fi
1603
1604
1605 #
1606 # Set variables for use by automake makefiles.
1607 #
1608 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1609 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1610 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1611 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1612 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1613 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1614 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1615 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1616 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1617 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1618
1619 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1620 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1621 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1622
1623 AM_CONDITIONAL(RUN_GPG_TESTS,
1624                test x$cross_compiling = xno -a "$build_gpg" = yes )
1625
1626 #
1627 # Set some defines for use gpgconf.
1628 #
1629 if test "$build_gpg" = yes ; then
1630     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1631 fi
1632 if test "$build_gpgsm" = yes ; then
1633     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1634 fi
1635 if test "$build_agent" = yes ; then
1636     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1637 fi
1638 if test "$build_scdaemon" = yes ; then
1639     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1640 fi
1641 if test "$build_dirmngr" = yes ; then
1642     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1643 fi
1644 if test "$build_g13" = yes ; then
1645     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1646 fi
1647
1648
1649 #
1650 # Define Name strings
1651 #
1652 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1653
1654 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1655 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1656
1657 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1658 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1659
1660 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1661 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1662                                         [The displayed name of gpg-agent])
1663
1664 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1665 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1666                                        [The displayed name of scdaemon])
1667
1668 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1669 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1670                                       [The displayed name of dirmngr])
1671
1672 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1673 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1674
1675 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1676 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1677                                       [The displayed name of gpgconf])
1678
1679 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1680
1681 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1682                    [The name of the agent socket])
1683 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1684                    [The name of the agent socket for ssh])
1685 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1686                    [The name of the dirmngr info envvar])
1687 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1688                    [The name of the SCdaemon socket])
1689 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1690                    [The name of the dirmngr socket])
1691
1692 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1693
1694 if test "$have_w32_system" = yes; then
1695   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1696                      [The directory part of the W32 registry keys])
1697 fi
1698
1699
1700 #
1701 # Provide information about the build.
1702 #
1703 BUILD_REVISION="mym4_revision"
1704 AC_SUBST(BUILD_REVISION)
1705 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1706                    [GIT commit id revision used to build this package])
1707
1708 changequote(,)dnl
1709 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1710 changequote([,])dnl
1711 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1712 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1713 AC_SUBST(BUILD_VERSION)
1714 AC_SUBST(BUILD_FILEVERSION)
1715
1716 AC_ARG_ENABLE([build-timestamp],
1717   AC_HELP_STRING([--enable-build-timestamp],
1718                  [set an explicit build timestamp for reproducibility.
1719                   (default is the current time in ISO-8601 format)]),
1720      [if test "$enableval" = "yes"; then
1721         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1722       else
1723         BUILD_TIMESTAMP="$enableval"
1724       fi],
1725      [BUILD_TIMESTAMP="<none>"])
1726 AC_SUBST(BUILD_TIMESTAMP)
1727 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1728                    [The time this package was configured for a build])
1729 BUILD_HOSTNAME="$ac_hostname"
1730 AC_SUBST(BUILD_HOSTNAME)
1731
1732
1733 #
1734 # Print errors here so that they are visible all
1735 # together and the user can acquire them all together.
1736 #
1737 die=no
1738 if test "$have_gpg_error" = "no"; then
1739    die=yes
1740    AC_MSG_NOTICE([[
1741 ***
1742 *** You need libgpg-error to build this program.
1743 **  This library is for example available at
1744 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1745 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1746 ***]])
1747 fi
1748 if test "$have_libgcrypt" = "no"; then
1749    die=yes
1750    AC_MSG_NOTICE([[
1751 ***
1752 *** You need libgcrypt to build this program.
1753 **  This library is for example available at
1754 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1755 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1756 ***]])
1757 fi
1758 if test "$have_libassuan" = "no"; then
1759    die=yes
1760    AC_MSG_NOTICE([[
1761 ***
1762 *** You need libassuan to build this program.
1763 *** This library is for example available at
1764 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1765 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1766 ***]])
1767 fi
1768 if test "$have_ksba" = "no"; then
1769     die=yes
1770     AC_MSG_NOTICE([[
1771 ***
1772 *** You need libksba to build this program.
1773 *** This library is for example available at
1774 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1775 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1776 ***]])
1777 fi
1778 if test "$gnupg_have_ldap" = yes; then
1779   if test "$have_w32ce_system" = yes; then
1780     AC_MSG_NOTICE([[
1781 *** Note that CeGCC might be broken, a package fixing this is:
1782 ***    http://files.kolab.org/local/windows-ce/
1783 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1784 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1785 ***]])
1786    fi
1787 fi
1788 if test "$have_npth" = "no"; then
1789     die=yes
1790     AC_MSG_NOTICE([[
1791 ***
1792 *** It is now required to build with support for the
1793 *** New Portable Threads Library (nPth). Please install this
1794 *** library first.  The library is for example available at
1795 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1796 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1797 ***]])
1798 fi
1799
1800 if test "$require_iconv" = yes; then
1801   if test "$am_func_iconv" != yes; then
1802     die=yes
1803     AC_MSG_NOTICE([[
1804 ***
1805 *** The system does not provide a working iconv function.  Please
1806 *** install a suitable library; for example GNU Libiconv which is
1807 *** available at:
1808 ***   http://ftp.gnu.org/gnu/libiconv/
1809 ***]])
1810   fi
1811 fi
1812
1813 if test "$die" = "yes"; then
1814     AC_MSG_ERROR([[
1815 ***
1816 *** Required libraries not found. Please consult the above messages
1817 *** and install them before running configure again.
1818 ***]])
1819 fi
1820
1821
1822
1823 AC_CONFIG_FILES([ m4/Makefile
1824 Makefile
1825 po/Makefile.in
1826 common/Makefile
1827 common/w32info-rc.h
1828 kbx/Makefile
1829 g10/Makefile
1830 sm/Makefile
1831 agent/Makefile
1832 scd/Makefile
1833 g13/Makefile
1834 dirmngr/Makefile
1835 tools/gpg-zip
1836 tools/Makefile
1837 doc/Makefile
1838 tests/Makefile
1839 tests/openpgp/Makefile
1840 tests/pkits/Makefile
1841 g10/gpg.w32-manifest
1842 ])
1843
1844
1845 AC_OUTPUT
1846
1847
1848 echo "
1849         GnuPG v${VERSION} has been configured as follows:
1850
1851         Revision:  mym4_revision  (mym4_revision_dec)
1852         Platform:  $PRINTABLE_OS_NAME ($host)
1853
1854         OpenPGP:   $build_gpg
1855         S/MIME:    $build_gpgsm
1856         Agent:     $build_agent
1857         Smartcard: $build_scdaemon $build_scdaemon_extra
1858         G13:       $build_g13
1859         Dirmngr:   $build_dirmngr
1860         Gpgtar:    $build_gpgtar
1861
1862         Protect tool:      $show_gnupg_protect_tool_pgm
1863         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1864         Default agent:     $show_gnupg_agent_pgm
1865         Default pinentry:  $show_gnupg_pinentry_pgm
1866         Default scdaemon:  $show_gnupg_scdaemon_pgm
1867         Default dirmngr:   $show_gnupg_dirmngr_pgm
1868
1869         Dirmngr auto start:  $dirmngr_auto_start
1870         Readline support:    $gnupg_cv_have_readline
1871         LDAP support:        $gnupg_have_ldap
1872         DNS SRV support:     $use_dns_srv
1873         TLS support:         $use_tls_library
1874         TOFU support:        $use_tofu
1875         Tor support:         $show_tor_support
1876 "
1877 if test x"$use_regex" != xyes ; then
1878 echo "
1879         Warning: No regular expression support available.
1880                  OpenPGP trust signatures won't work.
1881                  gpg-check-pattern will not be built.
1882 "
1883 fi
1884 if test "x${gpg_config_script_warn}" != x; then
1885 cat <<G10EOF
1886         Warning: Mismatches between the target platform and the
1887                  to be used libraries have been detected for:
1888                   ${gpg_config_script_warn}
1889                  Please check above for more warning messages.
1890
1891 G10EOF
1892 fi