Merge branch 'STABLE-BRANCH-2-2' into master
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2018 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2018 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg24", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.24
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.5.0
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119 # gpg is a required part and can't be disabled anymore.
120 build_gpg=yes
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
248 AC_ARG_WITH(agent-s2k-calibration,
249               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
250                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
251               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
252 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
253 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
254                    [Agent s2k calibration time (ms)])
255
256 AC_MSG_CHECKING([whether to enable trust models])
257 AC_ARG_ENABLE(trust-models,
258               AC_HELP_STRING([--disable-trust-models],
259                              [disable all trust models except "always"]),
260               use_trust_models=$enableval)
261 AC_MSG_RESULT($use_trust_models)
262 if test "$use_trust_models" = no ; then
263     AC_DEFINE(NO_TRUST_MODELS, 1,
264              [Define to include only trust-model always])
265 fi
266
267 AC_MSG_CHECKING([whether to enable TOFU])
268 AC_ARG_ENABLE(tofu,
269                 AC_HELP_STRING([--disable-tofu],
270                                [disable the TOFU trust model]),
271               use_tofu=$enableval, use_tofu=$use_trust_models)
272 AC_MSG_RESULT($use_tofu)
273 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
274     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
275 fi
276
277 AC_MSG_CHECKING([whether to enable libdns])
278 AC_ARG_ENABLE(libdns,
279                 AC_HELP_STRING([--disable-libdns],
280                                [do not build with libdns support]),
281               use_libdns=$enableval, use_libdns=yes)
282 AC_MSG_RESULT($use_libdns)
283 if test x"$use_libdns" = xyes ; then
284     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
285 fi
286 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
287
288
289 #
290 # Options to disable algorithm
291 #
292
293 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
294 # Elgamal is a MUST algorithm
295 # DSA is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
297 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
298 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
299
300 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
301 # 3DES is a MUST algorithm
302 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
303 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
307 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
309 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
310 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
311
312 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
313 # SHA1 is a MUST algorithm
314 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
315 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
316 # SHA256 is a MUST algorithm for GnuPG.
317 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
318 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
319
320
321 # Allow disabling of zip support.
322 # This is in general not a good idea because according to rfc4880 OpenPGP
323 # implementations SHOULD support ZLIB.
324 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
325 AC_ARG_ENABLE(zip,
326    AC_HELP_STRING([--disable-zip],
327                   [disable the ZIP and ZLIB compression algorithm]),
328    use_zip=$enableval)
329 AC_MSG_RESULT($use_zip)
330
331 # Allow disabling of bzib2 support.
332 # It is defined only after we confirm the library is available later
333 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
334 AC_ARG_ENABLE(bzip2,
335    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
336    use_bzip2=$enableval)
337 AC_MSG_RESULT($use_bzip2)
338
339 # Configure option to allow or disallow execution of external
340 # programs, like a photo viewer.
341 AC_MSG_CHECKING([whether to enable external program execution])
342 AC_ARG_ENABLE(exec,
343     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
344     use_exec=$enableval)
345 AC_MSG_RESULT($use_exec)
346 if test "$use_exec" = no ; then
347     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
348 fi
349
350 if test "$use_exec" = yes ; then
351   AC_MSG_CHECKING([whether to enable photo ID viewing])
352   AC_ARG_ENABLE(photo-viewers,
353       [  --disable-photo-viewers disable photo ID viewers],
354       [if test "$enableval" = no ; then
355          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
356       fi],enableval=yes)
357   gnupg_cv_enable_photo_viewers=$enableval
358   AC_MSG_RESULT($enableval)
359
360   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
361     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
362     AC_ARG_WITH(photo-viewer,
363         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
364         [if test "$withval" = yes ; then
365            withval=no
366         elif test "$withval" != no ; then
367            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
368                             [if set, restrict photo-viewer to this])
369         fi],withval=no)
370     AC_MSG_RESULT($withval)
371   fi
372 fi
373
374
375 #
376 # Check for the key/uid cache size.  This can't be zero, but can be
377 # pretty small on embedded systems.  This is used for the gpg part.
378 #
379 AC_MSG_CHECKING([for the size of the key and uid cache])
380 AC_ARG_ENABLE(key-cache,
381         AC_HELP_STRING([--enable-key-cache=SIZE],
382                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
383 if test "$enableval" = "no"; then
384    enableval=5
385 elif test "$enableval" = "yes" || test "$enableval" = ""; then
386    enableval=4096
387 fi
388 changequote(,)dnl
389 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
390 changequote([,])dnl
391 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
392    AC_MSG_ERROR([invalid key-cache size])
393 fi
394 AC_MSG_RESULT($key_cache_size)
395 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
396                   [Size of the key and UID caches])
397
398
399
400 #
401 # Check whether we want to use Linux capabilities
402 #
403 AC_MSG_CHECKING([whether use of capabilities is requested])
404 AC_ARG_WITH(capabilities,
405     [  --with-capabilities     use linux capabilities [default=no]],
406 [use_capabilities="$withval"],[use_capabilities=no])
407 AC_MSG_RESULT($use_capabilities)
408
409 #
410 # Check whether to disable the card support
411 AC_MSG_CHECKING([whether smartcard support is requested])
412 AC_ARG_ENABLE(card-support,
413               AC_HELP_STRING([--disable-card-support],
414                              [disable smartcard support]),
415               card_support=$enableval)
416 AC_MSG_RESULT($card_support)
417 if test "$card_support" = yes ; then
418   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
419 else
420   build_scdaemon=no
421 fi
422
423 #
424 # Allow disabling of internal CCID support.
425 # It is defined only after we confirm the library is available later
426 #
427 AC_MSG_CHECKING([whether to enable the internal CCID driver])
428 AC_ARG_ENABLE(ccid-driver,
429               AC_HELP_STRING([--disable-ccid-driver],
430                              [disable the internal CCID driver]),
431               use_ccid_driver=$enableval)
432 AC_MSG_RESULT($use_ccid_driver)
433
434 AC_MSG_CHECKING([whether to auto start dirmngr])
435 AC_ARG_ENABLE(dirmngr-auto-start,
436               AC_HELP_STRING([--disable-dirmngr-auto-start],
437                              [disable auto starting of the dirmngr]),
438               dirmngr_auto_start=$enableval)
439 AC_MSG_RESULT($dirmngr_auto_start)
440 if test "$dirmngr_auto_start" = yes ; then
441     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
442               [Define to enable auto starting of the dirmngr])
443 fi
444
445
446 #
447 # To avoid double inclusion of config.h which might happen at some
448 # places, we add the usual double inclusion protection at the top of
449 # config.h.
450 #
451 AH_TOP([
452 #ifndef GNUPG_CONFIG_H_INCLUDED
453 #define GNUPG_CONFIG_H_INCLUDED
454 ])
455
456 #
457 # Stuff which goes at the bottom of config.h.
458 #
459 AH_BOTTOM([
460 /* This is the major version number of GnuPG so that
461    source included files can test for this.  Note, that
462    we use 2 here even for GnuPG 1.9.x. */
463 #define GNUPG_MAJOR_VERSION 2
464
465 /* Now to separate file name parts.
466    Please note that the string version must not contain more
467    than one character because the code assumes strlen()==1 */
468 #ifdef HAVE_DOSISH_SYSTEM
469 #define DIRSEP_C '\\'
470 #define DIRSEP_S "\\"
471 #define EXTSEP_C '.'
472 #define EXTSEP_S "."
473 #define PATHSEP_C ';'
474 #define PATHSEP_S ";"
475 #define EXEEXT_S ".exe"
476 #else
477 #define DIRSEP_C '/'
478 #define DIRSEP_S "/"
479 #define EXTSEP_C '.'
480 #define EXTSEP_S "."
481 #define PATHSEP_C ':'
482 #define PATHSEP_S ":"
483 #define EXEEXT_S ""
484 #endif
485
486 /* This is the same as VERSION, but should be overridden if the
487    platform cannot handle things like dots '.' in filenames. Set
488    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
489    uses for dots and dashes. */
490 #define SAFE_VERSION VERSION
491 #define SAFE_VERSION_DOT  '.'
492 #define SAFE_VERSION_DASH '-'
493
494 /* Some global constants.
495  * Note that the homedir must not end in a slash.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
499 # else
500 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
501 # endif
502 #elif defined(__VMS)
503 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
504 #else
505 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
506 #endif
507 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
508 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
509
510 /* For some systems (DOS currently), we hardcode the path here.  For
511    POSIX systems the values are constructed by the Makefiles, so that
512    the values may be overridden by the make invocations; this is to
513    comply with the GNU coding standards.  Note that these values are
514    only defaults.  */
515 #ifdef HAVE_DOSISH_SYSTEM
516 # ifdef HAVE_DRIVE_LETTERS
517 #  define GNUPG_BINDIR      "c:\\gnupg"
518 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
519 #  define GNUPG_LIBDIR      "c:\\gnupg"
520 #  define GNUPG_DATADIR     "c:\\gnupg"
521 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
522 # else
523 #  define GNUPG_BINDIR      "\\gnupg"
524 #  define GNUPG_LIBEXECDIR  "\\gnupg"
525 #  define GNUPG_LIBDIR      "\\gnupg"
526 #  define GNUPG_DATADIR     "\\gnupg"
527 #  define GNUPG_SYSCONFDIR  "\\gnupg"
528 # endif
529 #endif
530
531 /* Derive some other constants. */
532 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
533 #define EXEC_TEMPFILE_ONLY
534 #endif
535
536
537 /* We didn't define endianness above, so get it from OS macros.  This
538    is intended for making fat binary builds on OS X. */
539 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
540 #if defined(__BIG_ENDIAN__)
541 #define BIG_ENDIAN_HOST 1
542 #elif defined(__LITTLE_ENDIAN__)
543 #define LITTLE_ENDIAN_HOST 1
544 #else
545 #error "No endianness found"
546 #endif
547 #endif
548
549
550 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
551    ldap_start_tls_s because that is the actual symbol used in the
552    library.  winldap.h redefines it to our commonly used value,
553    thus we define our usual macro here.  */
554 #ifdef HAVE_LDAP_START_TLS_SA
555 # ifndef HAVE_LDAP_START_TLS_S
556 #  define HAVE_LDAP_START_TLS_S 1
557 # endif
558 #endif
559
560 /* Enable the es_ macros from gpgrt.  */
561 #define GPGRT_ENABLE_ES_MACROS 1
562
563 /* Enable the log_ macros from gpgrt.  */
564 #define GPGRT_ENABLE_LOG_MACROS 1
565
566 /* Tell libgcrypt not to use its own libgpg-error implementation. */
567 #define USE_LIBGPG_ERROR 1
568
569 /* Tell Libgcrypt not to include deprecated definitions.  */
570 #define GCRYPT_NO_DEPRECATED 1
571
572 /* Our HTTP code is used in estream mode.  */
573 #define HTTP_USE_ESTREAM 1
574
575 /* Under W32 we do an explicit socket initialization, thus we need to
576    avoid the on-demand initialization which would also install an atexit
577    handler.  */
578 #define HTTP_NO_WSASTARTUP
579
580 /* Under Windows we use the gettext code from libgpg-error.  */
581 #define GPG_ERR_ENABLE_GETTEXT_MACROS
582
583 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
584 #define GPG_ERR_ENABLE_ERRNO_MACROS
585
586 #endif /*GNUPG_CONFIG_H_INCLUDED*/
587 ])
588
589
590 AM_MAINTAINER_MODE
591 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
592
593 # Checks for programs.
594 AC_MSG_NOTICE([checking for programs])
595 AC_PROG_MAKE_SET
596 AM_SANITY_CHECK
597 missing_dir=`cd $ac_aux_dir && pwd`
598 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
599 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
600 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
601 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
602 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
603 AM_SILENT_RULES
604 AC_PROG_AWK
605 AC_PROG_CC
606 AC_PROG_CPP
607 AM_PROG_CC_C_O
608 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
609   AC_MSG_ERROR([[No C-89 compiler found]])
610 fi
611 AC_PROG_INSTALL
612 AC_PROG_LN_S
613 AC_PROG_RANLIB
614 AC_CHECK_TOOL(AR, ar, :)
615 AC_PATH_PROG(PERL,"perl")
616 AC_CHECK_TOOL(WINDRES, windres, :)
617 AC_PATH_PROG(YAT2M, "yat2m", "./yat2m" )
618 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
619 AC_ISC_POSIX
620 AC_SYS_LARGEFILE
621 GNUPG_CHECK_USTAR
622
623
624 # We need to compile and run a program on the build machine.  A
625 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
626 # the AC archive is broken for autoconf 2.57.  Given that there is no
627 # newer version of that macro, we assume that it is also broken for
628 # autoconf 2.61 and thus we use a simple but usually sufficient
629 # approach.
630 AC_MSG_CHECKING(for cc for build)
631 if test "$cross_compiling" = "yes"; then
632   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
633 else
634   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
635 fi
636 AC_MSG_RESULT($CC_FOR_BUILD)
637 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
638
639 # We need to call this macro because other pkg-config macros are
640 # not always used.
641 PKG_PROG_PKG_CONFIG
642
643
644 try_gettext=yes
645 require_iconv=yes
646 have_dosish_system=no
647 have_w32_system=no
648 have_w32ce_system=no
649 have_android_system=no
650 use_simple_gettext=no
651 use_ldapwrapper=yes
652 mmap_needed=yes
653 require_pipe_to_unblock_pselect=yes
654 case "${host}" in
655     *-mingw32*)
656         # special stuff for Windoze NT
657         ac_cv_have_dev_random=no
658         AC_DEFINE(USE_ONLY_8DOT3,1,
659                   [Set this to limit filenames to the 8.3 format])
660         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
661                   [Because the Unix gettext has too much overhead on
662                    MingW32 systems and these systems lack Posix functions,
663                    we use a simplified version of gettext])
664         have_dosish_system=yes
665         have_w32_system=yes
666         require_iconv=no
667         use_ldapwrapper=no  # Fixme: Do this only for CE.
668         require_pipe_to_unblock_pselect=no
669         case "${host}" in
670           *-mingw32ce*)
671             have_w32ce_system=yes
672             ;;
673           *)
674             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
675                       [Defined if the OS supports drive letters.])
676             ;;
677         esac
678         try_gettext="no"
679         use_simple_gettext=yes
680         mmap_needed=no
681         ;;
682     i?86-emx-os2 | i?86-*-os2*emx )
683         # OS/2 with the EMX environment
684         ac_cv_have_dev_random=no
685         AC_DEFINE(HAVE_DRIVE_LETTERS)
686         have_dosish_system=yes
687         try_gettext="no"
688         ;;
689
690     i?86-*-msdosdjgpp*)
691         # DOS with the DJGPP environment
692         ac_cv_have_dev_random=no
693         AC_DEFINE(HAVE_DRIVE_LETTERS)
694         have_dosish_system=yes
695         try_gettext="no"
696         ;;
697
698     *-*-hpux*)
699         if test -z "$GCC" ; then
700             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
701         fi
702         ;;
703     *-dec-osf4*)
704         if test -z "$GCC" ; then
705             # Suppress all warnings
706             # to get rid of the unsigned/signed char mismatch warnings.
707             CFLAGS="-w $CFLAGS"
708         fi
709         ;;
710     *-dec-osf5*)
711         if test -z "$GCC" ; then
712             # Use the newer compiler `-msg_disable ptrmismatch1' to
713             # get rid of the unsigned/signed char mismatch warnings.
714             # Using this may hide other pointer mismatch warnings, but
715             # it at least lets other warning classes through
716             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
717         fi
718         ;;
719     m68k-atari-mint)
720         ;;
721     *-linux-android*)
722         have_android_system=yes
723         # Android is fully utf-8 and we do not want to use iconv to
724         # keeps things simple
725         require_iconv=no
726         ;;
727     *-apple-darwin*)
728         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
729                   Expose all libc features (__DARWIN_C_FULL).)
730         ;;
731     *-*-netbsd*)
732         require_pipe_to_unblock_pselect=yes
733         ;;
734     *)
735         ;;
736 esac
737
738 if test "$require_pipe_to_unblock_pselect" = yes; then
739    AC_DEFINE(HAVE_PSELECT_NO_EINTR, 1,
740              [Defined if we run on systems like NetBSD, where
741               pselect cannot be unblocked by signal from a thread
742               within the same process.  We use pipe in this case, instead.])
743 fi
744
745 if test "$have_dosish_system" = yes; then
746    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
747              [Defined if we run on some of the PCDOS like systems
748               (DOS, Windoze. OS/2) with special properties like
749               no file modes, case insensitive file names and preferred
750               use of backslashes as directory name separators.])
751 fi
752 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
753
754 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
755
756 if test "$have_w32_system" = yes; then
757    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
758    if test "$have_w32ce_system" = yes; then
759       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
760    fi
761 fi
762 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
763 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
764
765 if test "$have_android_system" = yes; then
766    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
767 fi
768 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
769
770
771 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
772 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
773
774
775 #
776 # Checks for libraries.
777 #
778 AC_MSG_NOTICE([checking for libraries])
779
780
781 #
782 # libgpg-error is a library with error codes shared between GnuPG
783 # related projects.
784 #
785 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
786                   have_gpg_error=yes,have_gpg_error=no)
787
788
789 #
790 # Libgcrypt is our generic crypto library
791 #
792 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
793         have_libgcrypt=yes,have_libgcrypt=no)
794
795
796 #
797 # libassuan is used for IPC
798 #
799 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
800                   have_libassuan=yes,have_libassuan=no)
801 if test "$have_libassuan" = "yes"; then
802   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
803                      [version of the libassuan library])
804   show_tor_support="only .onion"
805 fi
806
807
808 #
809 # libksba is our X.509 support library
810 #
811 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
812
813
814 #
815 # libusb allows us to use the integrated CCID smartcard reader driver.
816 #
817 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
818 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
819    case "${host}" in
820      *-mingw32*)
821        LIBUSB_NAME=
822        LIBUSB_LIBS=
823        LIBUSB_CPPFLAGS=
824        ;;
825      *-*-darwin*)
826        LIBUSB_NAME=usb-1.0
827        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
828        ;;
829      *-*-freebsd*)
830        # FreeBSD has a native 1.0 compatible library by -lusb.
831        LIBUSB_NAME=usb
832        LIBUSB_LIBS=
833        ;;
834      *)
835        LIBUSB_NAME=usb-1.0
836        LIBUSB_LIBS=
837        ;;
838    esac
839 fi
840 if test x"$LIBUSB_NAME" != x ; then
841    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
842                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
843                   have_libusb=yes ])
844    AC_MSG_CHECKING([libusb include dir])
845    usb_incdir_found="no"
846    for _incdir in "" "/usr/include/libusb-1.0" \
847        "/usr/local/include/libusb-1.0" "/usr/pkg/include/libusb-1.0"; do
848      _libusb_save_cppflags=$CPPFLAGS
849      if test -n "${_incdir}"; then
850        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
851      fi
852      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
853      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
854      CPPFLAGS=${_libusb_save_cppflags}
855      if test "$usb_incdir_found" = "yes"; then
856        break
857      fi
858    done
859    if test "$usb_incdir_found" = "yes"; then
860      AC_MSG_RESULT([${usb_incdir}])
861    else
862      AC_MSG_RESULT([not found])
863      usb_incdir=""
864      have_libusb=no
865      if test "$use_ccid_driver" != yes; then
866        use_ccid_driver=no
867      fi
868      LIBUSB_LIBS=""
869    fi
870
871    if test "$have_libusb" = yes; then
872      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
873    fi
874    if test x"$usb_incdir" = x; then
875      LIBUSB_CPPFLAGS=""
876    else
877      LIBUSB_CPPFLAGS="-I${usb_incdir}"
878    fi
879 fi
880 AC_SUBST(LIBUSB_LIBS)
881 AC_SUBST(LIBUSB_CPPFLAGS)
882
883 #
884 # Check whether it is necessary to link against libdl.
885 # (For example to load libpcsclite)
886 #
887 gnupg_dlopen_save_libs="$LIBS"
888 LIBS=""
889 AC_SEARCH_LIBS(dlopen, c dl,,,)
890 DL_LIBS=$LIBS
891 AC_SUBST(DL_LIBS)
892 LIBS="$gnupg_dlopen_save_libs"
893
894
895 # Checks for g10
896
897 AC_ARG_ENABLE(sqlite,
898                 AC_HELP_STRING([--disable-sqlite],
899                                [disable the use of SQLITE]),
900               try_sqlite=$enableval, try_sqlite=yes)
901
902 if test x"$use_tofu" = xyes ; then
903   if test x"$try_sqlite" = xyes ; then
904     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
905                                  [have_sqlite=yes],
906                                  [have_sqlite=no])
907   fi
908   if test "$have_sqlite" = "yes"; then
909     :
910     AC_SUBST([SQLITE3_CFLAGS])
911     AC_SUBST([SQLITE3_LIBS])
912   else
913     use_tofu=no
914     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
915     AC_MSG_WARN([[
916 ***
917 *** Building without SQLite support - TOFU disabled
918 ***
919 *** $tmp]])
920   fi
921 fi
922
923 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
924
925 if test x"$use_tofu" = xyes ; then
926     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
927 fi
928
929
930 # Checks for g13
931
932 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
933 AC_DEFINE_UNQUOTED(ENCFS,
934         "${ENCFS}", [defines the filename of the encfs program])
935
936 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
937 AC_DEFINE_UNQUOTED(FUSERMOUNT,
938         "${FUSERMOUNT}", [defines the filename of the fusermount program])
939
940
941 # Checks for dirmngr
942
943
944 #
945 # Checks for symcryptrun:
946 #
947
948 # libutil has openpty() and login_tty().
949 AC_CHECK_LIB(util, openpty,
950               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
951                 AC_DEFINE(HAVE_LIBUTIL,1,
952                          [defined if libutil is available])
953              ])
954 AC_SUBST(LIBUTIL_LIBS)
955
956 # shred is used to clean temporary plain text files.
957 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
958 AC_DEFINE_UNQUOTED(SHRED,
959         "${SHRED}", [defines the filename of the shred program])
960
961
962 #
963 # Check whether the nPth library is available
964 #
965 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
966 if test "$have_npth" = "yes"; then
967   AC_DEFINE(HAVE_NPTH, 1,
968               [Defined if the New Portable Thread Library is available])
969   AC_DEFINE(USE_NPTH, 1,
970               [Defined if support for nPth is requested and nPth is available])
971 else
972   AC_MSG_WARN([[
973 ***
974 *** To support concurrent access for example in gpg-agent and the SCdaemon
975 *** we need the support of the New Portable Threads Library.
976 ***]])
977 fi
978
979
980 #
981 # NTBTLS is our TLS library.  If it is not available fallback to
982 # GNUTLS.
983 #
984 AC_ARG_ENABLE(ntbtls,
985               AC_HELP_STRING([--disable-ntbtls],
986                              [disable the use of NTBTLS as TLS library]),
987               try_ntbtls=$enableval, try_ntbtls=yes)
988 if test x"$try_ntbtls" = xyes ; then
989   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
990                  [have_ntbtls=yes],[have_ntbtls=no])
991 fi
992 if test "$have_ntbtls" = yes ; then
993    use_tls_library=ntbtls
994    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
995 else
996   AC_ARG_ENABLE(gnutls,
997                 AC_HELP_STRING([--disable-gnutls],
998                                [disable GNUTLS as fallback TLS library]),
999                 try_gnutls=$enableval, try_gnutls=yes)
1000   if test x"$try_gnutls" = xyes ; then
1001     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
1002                                    [have_gnutls=yes],
1003                                    [have_gnutls=no])
1004   fi
1005   if test "$have_gnutls" = "yes"; then
1006     AC_SUBST([LIBGNUTLS_CFLAGS])
1007     AC_SUBST([LIBGNUTLS_LIBS])
1008     use_tls_library=gnutls
1009     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
1010   else
1011     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
1012     AC_MSG_WARN([[
1013 ***
1014 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1015 ***
1016 *** $tmp]])
1017   fi
1018 fi
1019
1020 #
1021 # Allow to set a fixed trust store file for system provided certificates.
1022 #
1023 AC_ARG_WITH([default-trust-store-file],
1024             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1025                             [Use FILE as system trust store])],
1026             default_trust_store_file="$withval",
1027             default_trust_store_file="")
1028 if test x"$default_trust_store_file" = xno;then
1029   default_trust_store_file=""
1030 fi
1031 if test x"$default_trust_store_file" != x ; then
1032   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1033     ["$default_trust_store_file"], [Use as default system trust store file])
1034 fi
1035
1036
1037 AC_MSG_NOTICE([checking for networking options])
1038
1039 #
1040 # Must check for network library requirements before doing link tests
1041 # for ldap, for example. If ldap libs are static (or dynamic and without
1042 # ELF runtime link paths), then link will fail and LDAP support won't
1043 # be detected.
1044 #
1045 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1046         [NETLIBS="-lnsl $NETLIBS"]))
1047 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1048         [NETLIBS="-lsocket $NETLIBS"]))
1049
1050
1051 #
1052 # Check standard resolver functions.
1053 #
1054 if test "$build_dirmngr" = "yes"; then
1055   _dns_save_libs=$LIBS
1056   LIBS=""
1057
1058   # Find the system resolver which can always be enabled with
1059   # the dirmngr option --standard-resolver.
1060
1061   # the double underscore thing is a glibc-ism?
1062   AC_SEARCH_LIBS(res_query,resolv bind,,
1063                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1064   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1065                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1066
1067   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1068   # and for some reason fools us into believing we don't need
1069   # -lresolv even if we do.  Since the test program checking for the
1070   # symbol does not include <resolv.h>, we need to check for the
1071   # renamed symbol explicitly.
1072   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1073       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1074           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1075
1076   if test x"$have_resolver" != xno ; then
1077
1078       # Make sure that the BIND 4 resolver interface is workable before
1079       # enabling any code that calls it.  At some point I'll rewrite the
1080       # code to use the BIND 8 resolver API.
1081       # We might also want to use libdns instead.
1082
1083     AC_MSG_CHECKING([whether the resolver is usable])
1084     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1085 #include <netinet/in.h>
1086 #include <arpa/nameser.h>
1087 #include <resolv.h>]],
1088 [[unsigned char answer[PACKETSZ];
1089   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1090   dn_skipname(0,0);
1091   dn_expand(0,0,0,0,0);
1092 ]])],have_resolver=yes,have_resolver=no)
1093     AC_MSG_RESULT($have_resolver)
1094
1095     # This is Apple-specific and somewhat bizarre as they changed the
1096     # define in bind 8 for some reason.
1097
1098     if test x"$have_resolver" != xyes ; then
1099       AC_MSG_CHECKING(
1100            [whether I can make the resolver usable with BIND_8_COMPAT])
1101       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1102 #include <sys/types.h>
1103 #include <netinet/in.h>
1104 #include <arpa/nameser.h>
1105 #include <resolv.h>]],
1106 [[unsigned char answer[PACKETSZ];
1107   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1108   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1109 ]])],[have_resolver=yes ; need_compat=yes])
1110       AC_MSG_RESULT($have_resolver)
1111     fi
1112   fi
1113
1114   if test x"$have_resolver" = xyes ; then
1115     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1116     DNSLIBS="$DNSLIBS $LIBS"
1117     if test x"$need_compat" = xyes ; then
1118       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1119     fi
1120     if test "$use_libdns" = yes; then
1121      show_tor_support=yes
1122     fi
1123   elif test "$use_libdns" = yes; then
1124     show_tor_support=yes
1125   else
1126     AC_MSG_WARN([[
1127 ***
1128 *** The system's DNS resolver is not usable.
1129 *** Dirmngr functionality is limited.
1130 ***]])
1131     show_tor_support="${show_tor_support} (no system resolver)"
1132   fi
1133
1134   if test "$have_w32_system" = yes; then
1135     if test "$use_libdns" = yes; then
1136       DNSLIBS="$DNSLIBS -liphlpapi"
1137     fi
1138   fi
1139
1140   LIBS=$_dns_save_libs
1141 fi
1142
1143 AC_SUBST(DNSLIBS)
1144
1145
1146 #
1147 # Check for LDAP
1148 #
1149 # Note that running the check changes the variable
1150 # gnupg_have_ldap from "n/a" to "no" or "yes".
1151
1152 AC_ARG_ENABLE(ldap,
1153     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1154     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1155
1156 if test "$gnupg_have_ldap" != "no" ; then
1157   if test "$build_dirmngr" = "yes" ; then
1158      GNUPG_CHECK_LDAP($NETLIBS)
1159      AC_CHECK_LIB(lber, ber_free,
1160                   [ LBER_LIBS="$LBER_LIBS -llber"
1161                     AC_DEFINE(HAVE_LBER,1,
1162                              [defined if liblber is available])
1163                     have_lber=yes
1164                  ])
1165   fi
1166 fi
1167 AC_SUBST(LBER_LIBS)
1168 if test "$gnupg_have_ldap" = "no"; then
1169     AC_MSG_WARN([[
1170 ***
1171 *** Building without LDAP support.
1172 *** No CRL access or X.509 certificate search available.
1173 ***]])
1174 fi
1175
1176 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1177 if test "$gnupg_have_ldap" = yes ; then
1178   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1179 else
1180  use_ldapwrapper=no
1181 fi
1182
1183 if test "$use_ldapwrapper" = yes; then
1184    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1185 fi
1186 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1187
1188
1189
1190
1191 #
1192 # Check for sendmail
1193 #
1194 # This isn't necessarily sendmail itself, but anything that gives a
1195 # sendmail-ish interface to the outside world.  That includes Exim,
1196 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1197 AC_ARG_WITH(mailprog,
1198       AC_HELP_STRING([--with-mailprog=NAME],
1199                      [use "NAME -t" for mail transport]),
1200              ,with_mailprog=yes)
1201 if test x"$with_mailprog" = xyes ; then
1202     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1203 elif test x"$with_mailprog" != xno ; then
1204     AC_MSG_CHECKING([for a mail transport program])
1205     AC_SUBST(SENDMAIL,$with_mailprog)
1206     AC_MSG_RESULT($with_mailprog)
1207 fi
1208
1209
1210 #
1211 # Construct a printable name of the OS
1212 #
1213 case "${host}" in
1214     *-mingw32ce*)
1215         PRINTABLE_OS_NAME="W32CE"
1216         ;;
1217     *-mingw32*)
1218         PRINTABLE_OS_NAME="MingW32"
1219         ;;
1220     *-*-cygwin*)
1221         PRINTABLE_OS_NAME="Cygwin"
1222         ;;
1223     i?86-emx-os2 | i?86-*-os2*emx )
1224         PRINTABLE_OS_NAME="OS/2"
1225         ;;
1226     i?86-*-msdosdjgpp*)
1227         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1228         try_dynload=no
1229         ;;
1230     *-linux*)
1231         PRINTABLE_OS_NAME="GNU/Linux"
1232         ;;
1233     *)
1234         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1235         ;;
1236 esac
1237 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1238                    [A human readable text with the name of the OS])
1239
1240
1241 #
1242 # Checking for iconv
1243 #
1244 if test "$require_iconv" = yes; then
1245   AM_ICONV
1246 else
1247   LIBICONV=
1248   LTLIBICONV=
1249   AC_SUBST(LIBICONV)
1250   AC_SUBST(LTLIBICONV)
1251 fi
1252
1253
1254 #
1255 # Check for gettext
1256 #
1257 # This is "GNU gnupg" - The project-id script from gettext
1258 #                       needs this string
1259 #
1260 AC_MSG_NOTICE([checking for gettext])
1261 AM_PO_SUBDIRS
1262 AM_GNU_GETTEXT_VERSION([0.17])
1263 if test "$try_gettext" = yes; then
1264   AM_GNU_GETTEXT([external],[need-ngettext])
1265
1266   # gettext requires some extra checks.  These really should be part of
1267   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1268   # function checks to here.
1269
1270   AC_CHECK_FUNCS(strchr)
1271 else
1272   USE_NLS=no
1273   USE_INCLUDED_LIBINTL=no
1274   BUILD_INCLUDED_LIBINTL=no
1275   POSUB=po
1276   AC_SUBST(USE_NLS)
1277   AC_SUBST(USE_INCLUDED_LIBINTL)
1278   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1279   AC_SUBST(POSUB)
1280 fi
1281
1282 # We use HAVE_LANGINFO_CODESET in a couple of places.
1283 AM_LANGINFO_CODESET
1284
1285 # Checks required for our use of locales
1286 gt_LC_MESSAGES
1287
1288
1289 #
1290 # SELinux support
1291 #
1292 if test "$selinux_support" = yes ; then
1293   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1294 fi
1295
1296
1297 #
1298 # Checks for header files.
1299 #
1300 AC_MSG_NOTICE([checking for header files])
1301 AC_HEADER_STDC
1302 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1303                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1304                   stdint.h signal.h util.h libutil.h termios.h \
1305                   ucred.h sys/ucred.h sys/sysmacros.h sys/mkdev.h])
1306
1307 AC_HEADER_TIME
1308
1309
1310 #
1311 # Checks for typedefs, structures, and compiler characteristics.
1312 #
1313 AC_MSG_NOTICE([checking for system characteristics])
1314 AC_C_CONST
1315 AC_C_INLINE
1316 AC_C_VOLATILE
1317 AC_TYPE_SIZE_T
1318 AC_TYPE_MODE_T
1319 AC_TYPE_SIGNAL
1320 AC_DECL_SYS_SIGLIST
1321
1322 gl_HEADER_SYS_SOCKET
1323 gl_TYPE_SOCKLEN_T
1324
1325 AC_SEARCH_LIBS([inet_addr], [nsl])
1326
1327 AC_ARG_ENABLE(endian-check,
1328               AC_HELP_STRING([--disable-endian-check],
1329               [disable the endian check and trust the OS provided macros]),
1330               endiancheck=$enableval,endiancheck=yes)
1331
1332 if test x"$endiancheck" = xyes ; then
1333   GNUPG_CHECK_ENDIAN
1334 fi
1335
1336 # fixme: we should get rid of the byte type
1337 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1338 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1339 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1340 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1341 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1342
1343 AC_CHECK_SIZEOF(unsigned short)
1344 AC_CHECK_SIZEOF(unsigned int)
1345 AC_CHECK_SIZEOF(unsigned long)
1346 AC_CHECK_SIZEOF(unsigned long long)
1347 AC_HEADER_TIME
1348 AC_CHECK_SIZEOF(time_t,,[[
1349 #include <stdio.h>
1350 #if TIME_WITH_SYS_TIME
1351 # include <sys/time.h>
1352 # include <time.h>
1353 #else
1354 # if HAVE_SYS_TIME_H
1355 #  include <sys/time.h>
1356 # else
1357 #  include <time.h>
1358 # endif
1359 #endif
1360 ]])
1361 GNUPG_TIME_T_UNSIGNED
1362
1363
1364 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1365    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1366    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1367     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1368 fi
1369
1370
1371 #
1372 # Checks for library functions.
1373 #
1374 AC_MSG_NOTICE([checking for library functions])
1375 AC_CHECK_DECLS(getpagesize)
1376 AC_FUNC_FSEEKO
1377 AC_FUNC_VPRINTF
1378 AC_FUNC_FORK
1379 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1380 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1381 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1382 AC_CHECK_FUNCS([canonicalize_file_name])
1383 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1384 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1385 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1386 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1387 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1388                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1389                 flockfile funlockfile getpwnam getpwuid \
1390                 getenv inet_pton strpbrk])
1391
1392 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1393 # Given that we use nanosleep only as an optimization over a select
1394 # based wait function we want it only if it is available in libc.
1395 _save_libs="$LIBS"
1396 AC_SEARCH_LIBS([nanosleep], [],
1397                [AC_DEFINE(HAVE_NANOSLEEP,1,
1398                 [Define to 1 if you have the `nanosleep' function in libc.])])
1399 LIBS="$_save_libs"
1400
1401
1402 # See whether libc supports the Linux inotify interface
1403 case "${host}" in
1404     *-*-linux*)
1405         AC_CHECK_FUNCS([inotify_init])
1406         ;;
1407 esac
1408
1409
1410 if test "$have_android_system" = yes; then
1411    # On Android ttyname is a stub but prints an error message.
1412    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1413              [Defined if ttyname does not work properly])
1414 fi
1415
1416 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1417
1418 # Dirmngr requires mmap on Unix systems.
1419 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1420   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1421 fi
1422
1423
1424 #
1425 # Check for the getsockopt SO_PEERCRED, etc.
1426 #
1427 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1428 #include <sys/socket.h> ])
1429
1430 # (Open)Solaris
1431 AC_CHECK_FUNCS([getpeerucred])
1432
1433
1434 #
1435 # W32 specific test
1436 #
1437 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1438
1439 #
1440 # Sanity check regex.  Tests adapted from mutt.
1441 #
1442 AC_MSG_CHECKING([whether regular expression support is requested])
1443 AC_ARG_ENABLE(regex,
1444   AC_HELP_STRING([--disable-regex],
1445     [do not handle regular expressions in trust signatures]),
1446   use_regex=$enableval, use_regex=yes)
1447 AC_MSG_RESULT($use_regex)
1448
1449 if test "$use_regex" = yes ; then
1450   _cppflags="${CPPFLAGS}"
1451   _ldflags="${LDFLAGS}"
1452   AC_ARG_WITH(regex,
1453      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1454       [
1455       if test -d "$withval" ; then
1456         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1457         LDFLAGS="${LDFLAGS} -L$withval/lib"
1458       fi
1459       ],withval="")
1460
1461   # Does the system have regex functions at all?
1462   AC_SEARCH_LIBS([regcomp], [regex])
1463   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1464
1465   if test $gnupg_cv_have_regex = no; then
1466     use_regex=no
1467   else
1468     if test x"$cross_compiling" = xyes; then
1469       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1470     else
1471       AC_CACHE_CHECK([whether your system's regexp library is broken],
1472        [gnupg_cv_regex_broken],
1473        AC_TRY_RUN([
1474 #include <unistd.h>
1475 #include <regex.h>
1476 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1477        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1478
1479       if test $gnupg_cv_regex_broken = yes; then
1480         AC_MSG_WARN([your regex is broken - disabling regex use])
1481         use_regex=no
1482       fi
1483     fi
1484   fi
1485   CPPFLAGS="${_cppflags}"
1486   LDFLAGS="${_ldflags}"
1487 fi
1488
1489 if test "$use_regex" != yes ; then
1490   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1491 fi
1492 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1493
1494
1495
1496 #
1497 # Do we have zlib? Must do it here because Solaris failed
1498 # when compiling a conftest (due to the "-lz" from LIBS).
1499 # Note that we combine zlib and bzlib2 in ZLIBS.
1500 #
1501 if test "$use_zip" = yes ; then
1502   _cppflags="${CPPFLAGS}"
1503   _ldflags="${LDFLAGS}"
1504   AC_ARG_WITH(zlib,
1505     [  --with-zlib=DIR         use libz in DIR],[
1506       if test -d "$withval"; then
1507         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1508         LDFLAGS="${LDFLAGS} -L$withval/lib"
1509       fi
1510     ])
1511
1512   AC_CHECK_HEADER(zlib.h,
1513      AC_CHECK_LIB(z, deflateInit2_,
1514        [
1515        ZLIBS="-lz"
1516        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1517        ],
1518        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1519        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1520 fi
1521
1522
1523 #
1524 # Check whether we can support bzip2
1525 #
1526 if test "$use_bzip2" = yes ; then
1527   _cppflags="${CPPFLAGS}"
1528   _ldflags="${LDFLAGS}"
1529   AC_ARG_WITH(bzip2,
1530      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1531       [
1532       if test -d "$withval" ; then
1533         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1534         LDFLAGS="${LDFLAGS} -L$withval/lib"
1535       fi
1536       ],withval="")
1537
1538   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1539   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1540   # woefully out of date.
1541   if test "$withval" != no ; then
1542      AC_CHECK_HEADER(bzlib.h,
1543         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1544           [
1545           have_bz2=yes
1546           ZLIBS="$ZLIBS -lbz2"
1547           AC_DEFINE(HAVE_BZIP2,1,
1548                   [Defined if the bz2 compression library is available])
1549           ],
1550           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1551           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1552   fi
1553 fi
1554 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1555 AC_SUBST(ZLIBS)
1556
1557
1558 # Check for readline support
1559 GNUPG_CHECK_READLINE
1560
1561
1562 if test "$development_version" = yes; then
1563     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1564             [Defined if this is not a regular release])
1565 fi
1566
1567 if test "$USE_MAINTAINER_MODE" = "yes"; then
1568     AC_DEFINE(MAINTAINER_MODE,1,
1569             [Defined if this build is in maintainer mode])
1570 fi
1571
1572 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1573
1574 GNUPG_CHECK_GNUMAKE
1575
1576 # Add some extra libs here so that previous tests don't fail for
1577 # mysterious reasons - the final link step should bail out.
1578 # W32SOCKLIBS is also defined so that if can be used for tools not
1579 # requiring any network stuff but linking to code in libcommon which
1580 # tracks in winsock stuff (e.g. init_common_subsystems).
1581 if test "$have_w32_system" = yes; then
1582    if test "$have_w32ce_system" = yes; then
1583      W32SOCKLIBS="-lws2"
1584    else
1585      W32SOCKLIBS="-lws2_32"
1586    fi
1587    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1588 fi
1589
1590 AC_SUBST(NETLIBS)
1591 AC_SUBST(W32SOCKLIBS)
1592
1593 #
1594 # Setup gcc specific options
1595 #
1596 USE_C99_CFLAGS=
1597 AC_MSG_NOTICE([checking for cc features])
1598 if test "$GCC" = yes; then
1599     mycflags=
1600     mycflags_save=$CFLAGS
1601
1602     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1603     # options.  This is the case for gcc >= 4.6
1604     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1605     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1606 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1607 #kickerror
1608 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1609     AC_MSG_RESULT($_gcc_silent_wno)
1610
1611     # Note that it is okay to use CFLAGS here because these are just
1612     # warning options and the user should have a chance of overriding
1613     # them.
1614     if test "$USE_MAINTAINER_MODE" = "yes"; then
1615         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1616         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1617         if test x"$_gcc_silent_wno" = xyes ; then
1618           _gcc_wopt=yes
1619         else
1620           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1621           CFLAGS="-Wno-missing-field-initializers"
1622           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1623                             [_gcc_wopt=yes],[_gcc_wopt=no])
1624           AC_MSG_RESULT($_gcc_wopt)
1625         fi
1626         if test x"$_gcc_wopt" = xyes ; then
1627           mycflags="$mycflags -W -Wno-sign-compare -Wno-format-zero-length"
1628           mycflags="$mycflags -Wno-missing-field-initializers"
1629         fi
1630
1631         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1632         CFLAGS="-Wdeclaration-after-statement"
1633         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1634         AC_MSG_RESULT($_gcc_wopt)
1635         if test x"$_gcc_wopt" = xyes ; then
1636           mycflags="$mycflags -Wdeclaration-after-statement"
1637         fi
1638
1639         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1640         CFLAGS="-Wlogical-op -Werror"
1641         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1642         AC_MSG_RESULT($_gcc_wopt)
1643         if test x"$_gcc_wopt" = xyes ; then
1644           mycflags="$mycflags -Wlogical-op"
1645         fi
1646
1647         AC_MSG_CHECKING([if gcc supports -Wvla])
1648         CFLAGS="-Wvla"
1649         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1650         AC_MSG_RESULT($_gcc_wopt)
1651         if test x"$_gcc_wopt" = xyes ; then
1652           mycflags="$mycflags -Wvla"
1653         fi
1654
1655     else
1656         mycflags="$mycflags -Wall"
1657     fi
1658
1659     if test x"$_gcc_silent_wno" = xyes ; then
1660       _gcc_psign=yes
1661     else
1662       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1663       CFLAGS="-Wno-pointer-sign"
1664       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1665                         [_gcc_psign=yes],[_gcc_psign=no])
1666       AC_MSG_RESULT($_gcc_psign)
1667     fi
1668     if test x"$_gcc_psign" = xyes ; then
1669        mycflags="$mycflags -Wno-pointer-sign"
1670     fi
1671
1672     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1673     CFLAGS="-Wpointer-arith"
1674     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1675     AC_MSG_RESULT($_gcc_psign)
1676     if test x"$_gcc_psign" = xyes ; then
1677        mycflags="$mycflags -Wpointer-arith"
1678     fi
1679
1680     CFLAGS="$mycflags $mycflags_save"
1681     if test "$use_libdns" = yes; then
1682        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1683        USE_C99_CFLAGS="-std=gnu99"
1684     fi
1685 fi
1686
1687 AC_SUBST(USE_C99_CFLAGS)
1688
1689
1690 #
1691 # This is handy for debugging so the compiler doesn't rearrange
1692 # things and eliminate variables.
1693 #
1694 AC_ARG_ENABLE(optimization,
1695    AC_HELP_STRING([--disable-optimization],
1696                   [disable compiler optimization]),
1697                   [if test $enableval = no ; then
1698                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1699                    fi])
1700
1701 #
1702 # log_debug has certain requirements which might hamper portability.
1703 # Thus we use an option to enable it.
1704 #
1705 AC_MSG_CHECKING([whether to enable log_clock])
1706 AC_ARG_ENABLE(log_clock,
1707               AC_HELP_STRING([--enable-log-clock],
1708                              [enable log_clock timestamps]),
1709               enable_log_clock=$enableval, enable_log_clock=no)
1710 AC_MSG_RESULT($enable_log_clock)
1711 if test "$enable_log_clock" = yes ; then
1712   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1713 fi
1714
1715 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1716 # misbehaving autoconf tests in case the user supplied -Werror.
1717 #
1718 AC_ARG_ENABLE(werror,
1719    AC_HELP_STRING([--enable-werror],
1720                   [append -Werror to CFLAGS]),
1721                   [if test $enableval = yes ; then
1722                       CFLAGS="$CFLAGS -Werror"
1723                    fi])
1724
1725 #
1726 # Configure option --enable-all-tests
1727 #
1728 AC_MSG_CHECKING([whether "make check" shall run all tests])
1729 AC_ARG_ENABLE(all-tests,
1730               AC_HELP_STRING([--enable-all-tests],
1731                              [let "make check" run all tests]),
1732               run_all_tests=$enableval, run_all_tests=no)
1733 AC_MSG_RESULT($run_all_tests)
1734 if test "$run_all_tests" = "yes"; then
1735     AC_DEFINE(RUN_ALL_TESTS,1,
1736             [Defined if "make check" shall run all tests])
1737 fi
1738
1739 #
1740 # We do not want support for the GNUPG_BUILDDIR environment variable
1741 # in a released version.  However, our regression tests suite requires
1742 # this and thus we build with support for it during "make distcheck".
1743 # This configure option implements this along with the top Makefile's
1744 # AM_DISTCHECK_CONFIGURE_FLAGS.
1745 #
1746 gnupg_builddir_envvar=no
1747 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1748               gnupg_builddir_envvar=$enableval)
1749 if test x"$gnupg_builddir_envvar" = x"yes"; then
1750    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1751       [This is only used with "make distcheck"])
1752 fi
1753
1754
1755 #
1756 # To avoid problems with systemd cleaning up the /run/user directory,
1757 # this option will make GnuPG try to use /run/gnupg/user as socket dir
1758 # before /run/user
1759 #
1760 AC_ARG_ENABLE(run-gnupg-user-socket,
1761     AC_HELP_STRING([--enable-run-gnupg-user-socket],
1762                    [try /run/gnupg/user for sockets prior to /run/user]),
1763     use_run_gnupg_user_socket=$enableval)
1764 if test x"$use_run_gnupg_user_socket" = x"yes"; then
1765    AC_DEFINE(USE_RUN_GNUPG_USER_SOCKET, 1,
1766             [If defined try /run/gnupg/user before /run/user])
1767 fi
1768
1769
1770 #
1771 # Decide what to build
1772 #
1773
1774 build_scdaemon_extra=""
1775 if test "$build_scdaemon" = "yes"; then
1776   if test $have_libusb = no; then
1777      build_scdaemon_extra="without internal CCID driver"
1778   fi
1779   if test -n "$build_scdaemon_extra"; then
1780      build_scdaemon_extra="(${build_scdaemon_extra})"
1781   fi
1782 fi
1783
1784
1785 #
1786 # Set variables for use by automake makefiles.
1787 #
1788 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1789 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1790 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1791 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1792 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1793 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1794 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1795 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1796 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1797 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1798
1799 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1800 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1801 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1802
1803 #
1804 # Set some defines for use gpgconf.
1805 #
1806 if test "$build_gpg" = yes ; then
1807     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1808 fi
1809 if test "$build_gpgsm" = yes ; then
1810     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1811 fi
1812 if test "$build_agent" = yes ; then
1813     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1814 fi
1815 if test "$build_scdaemon" = yes ; then
1816     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1817 fi
1818 if test "$build_dirmngr" = yes ; then
1819     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1820 fi
1821 if test "$build_g13" = yes ; then
1822     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1823 fi
1824
1825
1826 #
1827 # Define Name strings
1828 #
1829 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1830
1831 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1832 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1833
1834 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1835 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1836
1837 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1838 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1839                                         [The displayed name of gpg-agent])
1840
1841 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1842 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1843                                        [The displayed name of scdaemon])
1844
1845 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1846 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1847                                       [The displayed name of dirmngr])
1848
1849 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1850 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1851
1852 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1853 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1854                                       [The displayed name of gpgconf])
1855
1856 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1857
1858 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1859                    [The name of the agent socket])
1860 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1861                    [The name of the agent socket for remote access])
1862 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1863                    [The name of the agent socket for browsers])
1864 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1865                    [The name of the agent socket for ssh])
1866 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1867                    [The name of the dirmngr info envvar])
1868 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1869                    [The name of the SCdaemon socket])
1870 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1871                    [The name of the dirmngr socket])
1872 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1873                    "hkps://hkps.pool.sks-keyservers.net",
1874       [The default keyserver for dirmngr to use, if none is explicitly given])
1875
1876 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1877
1878 if test "$have_w32_system" = yes; then
1879   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1880                      [The directory part of the W32 registry keys])
1881 fi
1882
1883
1884 #
1885 # Provide information about the build.
1886 #
1887 BUILD_REVISION="mym4_revision"
1888 AC_SUBST(BUILD_REVISION)
1889 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1890                    [GIT commit id revision used to build this package])
1891
1892 changequote(,)dnl
1893 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1894 changequote([,])dnl
1895 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1896 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1897 AC_SUBST(BUILD_VERSION)
1898 AC_SUBST(BUILD_FILEVERSION)
1899
1900 AC_ARG_ENABLE([build-timestamp],
1901   AC_HELP_STRING([--enable-build-timestamp],
1902                  [set an explicit build timestamp for reproducibility.
1903                   (default is the current time in ISO-8601 format)]),
1904      [if test "$enableval" = "yes"; then
1905         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1906       else
1907         BUILD_TIMESTAMP="$enableval"
1908       fi
1909       BUILD_HOSTNAME="$ac_hostname"],
1910      [BUILD_TIMESTAMP="<none>"
1911       BUILD_HOSTNAME="<anon>"])
1912 AC_SUBST(BUILD_TIMESTAMP)
1913 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1914                    [The time this package was configured for a build])
1915 AC_SUBST(BUILD_HOSTNAME)
1916
1917
1918 #
1919 # Print errors here so that they are visible all
1920 # together and the user can acquire them all together.
1921 #
1922 die=no
1923 if test "$have_gpg_error" = "no"; then
1924    die=yes
1925    AC_MSG_NOTICE([[
1926 ***
1927 *** You need libgpg-error to build this program.
1928 **  This library is for example available at
1929 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1930 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1931 ***]])
1932 fi
1933 if test "$have_libgcrypt" = "no"; then
1934    die=yes
1935    AC_MSG_NOTICE([[
1936 ***
1937 *** You need libgcrypt to build this program.
1938 **  This library is for example available at
1939 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1940 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1941 ***]])
1942 fi
1943 if test "$have_libassuan" = "no"; then
1944    die=yes
1945    AC_MSG_NOTICE([[
1946 ***
1947 *** You need libassuan to build this program.
1948 *** This library is for example available at
1949 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1950 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1951 ***]])
1952 fi
1953 if test "$have_ksba" = "no"; then
1954     die=yes
1955     AC_MSG_NOTICE([[
1956 ***
1957 *** You need libksba to build this program.
1958 *** This library is for example available at
1959 ***   https://gnupg.org/ftp/gcrypt/libksba/
1960 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1961 ***]])
1962 fi
1963 if test "$gnupg_have_ldap" = yes; then
1964   if test "$have_w32ce_system" = yes; then
1965     AC_MSG_NOTICE([[
1966 *** Note that CeGCC might be broken, a package fixing this is:
1967 ***    http://files.kolab.org/local/windows-ce/
1968 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1969 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1970 ***]])
1971    fi
1972 fi
1973 if test "$have_npth" = "no"; then
1974     die=yes
1975     AC_MSG_NOTICE([[
1976 ***
1977 *** It is now required to build with support for the
1978 *** New Portable Threads Library (nPth). Please install this
1979 *** library first.  The library is for example available at
1980 ***   https://gnupg.org/ftp/gcrypt/npth/
1981 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1982 ***]])
1983 fi
1984
1985 if test "$require_iconv" = yes; then
1986   if test "$am_func_iconv" != yes; then
1987     die=yes
1988     AC_MSG_NOTICE([[
1989 ***
1990 *** The system does not provide a working iconv function.  Please
1991 *** install a suitable library; for example GNU Libiconv which is
1992 *** available at:
1993 ***   https://ftp.gnu.org/gnu/libiconv/
1994 ***]])
1995   fi
1996 fi
1997
1998 if test "$use_ccid_driver" = yes; then
1999   if test "$have_libusb" != yes; then
2000     die=yes
2001     AC_MSG_NOTICE([[
2002 ***
2003 *** You need libusb to build the internal ccid driver.  Please
2004 *** install a libusb suitable for your system.
2005 ***]])
2006   fi
2007 fi
2008
2009 if test "$die" = "yes"; then
2010     AC_MSG_ERROR([[
2011 ***
2012 *** Required libraries not found. Please consult the above messages
2013 *** and install them before running configure again.
2014 ***]])
2015 fi
2016
2017
2018
2019 AC_CONFIG_FILES([ m4/Makefile
2020 Makefile
2021 po/Makefile.in
2022 common/Makefile
2023 common/w32info-rc.h
2024 kbx/Makefile
2025 g10/Makefile
2026 sm/Makefile
2027 agent/Makefile
2028 scd/Makefile
2029 g13/Makefile
2030 dirmngr/Makefile
2031 tools/gpg-zip
2032 tools/Makefile
2033 doc/Makefile
2034 tests/Makefile
2035 tests/gpgscm/Makefile
2036 tests/openpgp/Makefile
2037 tests/migrations/Makefile
2038 tests/gpgsm/Makefile
2039 tests/gpgme/Makefile
2040 tests/pkits/Makefile
2041 g10/gpg.w32-manifest
2042 ])
2043
2044
2045 AC_OUTPUT
2046
2047
2048 echo "
2049         GnuPG v${VERSION} has been configured as follows:
2050
2051         Revision:  mym4_revision  (mym4_revision_dec)
2052         Platform:  $PRINTABLE_OS_NAME ($host)
2053
2054         OpenPGP:   $build_gpg
2055         S/MIME:    $build_gpgsm
2056         Agent:     $build_agent
2057         Smartcard: $build_scdaemon $build_scdaemon_extra
2058         G13:       $build_g13
2059         Dirmngr:   $build_dirmngr
2060         Gpgtar:    $build_gpgtar
2061         WKS tools: $build_wks_tools
2062
2063         Protect tool:      $show_gnupg_protect_tool_pgm
2064         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2065         Default agent:     $show_gnupg_agent_pgm
2066         Default pinentry:  $show_gnupg_pinentry_pgm
2067         Default scdaemon:  $show_gnupg_scdaemon_pgm
2068         Default dirmngr:   $show_gnupg_dirmngr_pgm
2069
2070         Dirmngr auto start:  $dirmngr_auto_start
2071         Readline support:    $gnupg_cv_have_readline
2072         LDAP support:        $gnupg_have_ldap
2073         TLS support:         $use_tls_library
2074         TOFU support:        $use_tofu
2075         Tor support:         $show_tor_support
2076 "
2077 if test x"$use_regex" != xyes ; then
2078 echo "
2079         Warning: No regular expression support available.
2080                  OpenPGP trust signatures won't work.
2081                  gpg-check-pattern will not be built.
2082 "
2083 fi
2084 if test "x${gpg_config_script_warn}" != x; then
2085 cat <<G10EOF
2086         Warning: Mismatches between the target platform and the
2087                  to be used libraries have been detected for:
2088                   ${gpg_config_script_warn}
2089                  Please check above for more warning messages.
2090
2091 G10EOF
2092 fi