(keybox_release): Close the file pointer.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.7.9"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.14-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=0.7
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.6
38
39 NEED_KSBA_VERSION=0.9.7
40
41 NEED_OPENSC_VERSION=0.8.0
42
43
44
45 PACKAGE=$PACKAGE_NAME
46 PACKAGE_GT=${PACKAGE_NAME}2
47 VERSION=$PACKAGE_VERSION
48
49 AC_CONFIG_AUX_DIR(scripts)
50 AC_CONFIG_SRCDIR(sm/gpgsm.c)
51 AM_CONFIG_HEADER(config.h)
52 AC_CANONICAL_TARGET()
53 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
54
55 AC_GNU_SOURCE
56
57 # Some status variables to give feedback at the end of a configure run
58 have_gpg_error=no
59 have_libgcrypt=no 
60 have_libassuan=no
61 have_ksba=no
62 have_opensc=no
63 have_pth=no
64
65 GNUPG_BUILD_PROGRAM(gpg, yes)
66 GNUPG_BUILD_PROGRAM(gpgsm, yes)
67 GNUPG_BUILD_PROGRAM(agent, yes)
68 GNUPG_BUILD_PROGRAM(scdaemon, yes)
69
70
71 AC_SUBST(PACKAGE)
72 AC_SUBST(PACKAGE_GT)
73 AC_SUBST(VERSION)
74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
76                                 [Name of this package for gettext])
77 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
78 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
79                                         [Bug report address])
80 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
81                                        [Required version of Libgcrypt])
82 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
83                                        [Required version of Libksba])
84
85
86
87 # The default is to use the modules from this package and the few
88 # other packages in a standard place; i.e where this package gets
89 # installed.  With these options it is possible to override these
90 # ${prefix} depended values with fixed paths, which can't be replaced
91 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
94           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
95 AC_SUBST(GNUPG_AGENT_PGM)
96 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
97 show_gnupg_agent_pgm="(default)"
98 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
99
100 AC_ARG_WITH(pinentry-pgm,
101     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
102           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
103 AC_SUBST(GNUPG_PINENTRY_PGM)
104 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
105 show_gnupg_pinentry_pgm="(default)"
106 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
107
108
109 AC_ARG_WITH(scdaemon-pgm,
110     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
111           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
112 AC_SUBST(GNUPG_SCDAEMON_PGM)
113 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
114 show_gnupg_scdaemon_pgm="(default)"
115 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
116
117
118 AC_ARG_WITH(dirmngr-pgm,
119     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
120           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
121 AC_SUBST(GNUPG_DIRMNGR_PGM)
122 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
123 show_gnupg_dirmngr_pgm="(default)"
124 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
125
126 AC_ARG_WITH(protect-tool-pgm,
127     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
128           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
129 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
130 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
131 show_gnupg_protect_tool_pgm="(default)"
132 test -n "$GNUPG_PROTECT_TOOL_PGM" \
133       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
134
135
136 # Some folks want to use only the agent form this packet.  Make it
137 # easier for them by providing the configure option
138 # --enable-only-agent.
139 AC_ARG_ENABLE(agent-only,
140     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
141     build_agent_only=$enableval)
142
143
144 # Configure option to allow or disallow execution of external
145 # programs, like a photo viewer.
146 AC_MSG_CHECKING([whether to enable external program execution])
147 AC_ARG_ENABLE(exec,
148     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
149     use_exec=$enableval)
150 AC_MSG_RESULT($use_exec)
151 if test "$use_exec" = no ; then
152     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
153 fi
154
155 if test "$use_exec" = yes ; then
156   AC_MSG_CHECKING([whether to enable photo ID viewing])
157   AC_ARG_ENABLE(photo-viewers,
158       [  --disable-photo-viewers disable photo ID viewers],
159       [if test "$enableval" = no ; then
160          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
161       fi],enableval=yes)
162   gnupg_cv_enable_photo_viewers=$enableval
163   AC_MSG_RESULT($enableval)
164
165   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
166     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
167     AC_ARG_WITH(photo-viewer,
168         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
169         [if test "$withval" = yes ; then
170            withval=no
171         elif test "$withval" != no ; then
172            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
173                             [if set, restrict photo-viewer to this])
174         fi],withval=no)
175     AC_MSG_RESULT($withval)
176   fi
177
178   AC_MSG_CHECKING([whether to enable external keyserver helpers])
179   AC_ARG_ENABLE(keyserver-helpers,
180       [  --disable-keyserver-helpers  disable all external keyserver support],
181       [if test "$enableval" = no ; then
182          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
183                   [define to disable keyserver helpers])
184       fi],enableval=yes)
185   gnupg_cv_enable_keyserver_helpers=$enableval
186   AC_MSG_RESULT($enableval)
187
188   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
189     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
190     AC_ARG_ENABLE(ldap,
191     [  --disable-ldap          disable LDAP keyserver interface],
192         try_ldap=$enableval, try_ldap=yes)
193     AC_MSG_RESULT($try_ldap)
194
195     AC_MSG_CHECKING([whether HKP keyserver support is requested])
196     AC_ARG_ENABLE(hkp,
197     [  --disable-hkp           disable HKP keyserver interface],
198         try_hkp=$enableval, try_hkp=yes)
199     AC_MSG_RESULT($try_hkp)
200
201     if test "$try_hkp" = yes ; then
202       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
203     fi
204
205     AC_MSG_CHECKING([whether email keyserver support is requested])
206     AC_ARG_ENABLE(mailto,
207     [  --disable-mailto        disable email keyserver interface],
208         try_mailto=$enableval, try_mailto=yes)
209     AC_MSG_RESULT($try_mailto)
210     fi
211
212     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
213     AC_ARG_ENABLE(keyserver-path,
214         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
215         [if test "$enableval" = no ; then
216          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
217         fi],enableval=yes)
218     AC_MSG_RESULT($enableval)
219   fi
220
221 AC_MSG_CHECKING([whether the included zlib is requested])
222 AC_ARG_WITH(included-zlib,
223     [  --with-included-zlib    use the zlib code included here],
224 [g10_force_zlib=yes], [g10_force_zlib=no] )
225 AC_MSG_RESULT($g10_force_zlib)
226
227 dnl
228 dnl Check whether we want to use Linux capabilities
229 dnl
230 AC_MSG_CHECKING([whether use of capabilities is requested])
231 AC_ARG_WITH(capabilities,
232     [  --with-capabilities     use linux capabilities [default=no]],
233 [use_capabilities="$withval"],[use_capabilities=no])
234 AC_MSG_RESULT($use_capabilities)
235
236
237 AH_BOTTOM([
238 /* Some global constants. */
239 #ifdef HAVE_DRIVE_LETTERS
240 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
241 #elif defined(__VMS)
242 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
243 #else
244 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
245 #endif 
246 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
247
248 /* Tell libgcrypt not to use its own libgpg-error implementation. */
249 #define USE_LIBGPG_ERROR 1
250
251 /* This is the major version number of GnuPG so that
252    source included files can test for this.  Note, that\
253    we use 2 here even for GnuPG 1.9.x. */
254 #define GNUPG_MAJOR_VERSION 2
255
256 /* Now to separate file name parts.
257    Please note that the string version must not contain more
258    than one character because the code assumes strlen()==1 */
259 #ifdef HAVE_DOSISH_SYSTEM
260 #define DIRSEP_C '\\'
261 #define EXTSEP_C '.'
262 #define DIRSEP_S "\\"
263 #define EXTSEP_S "."
264 #else
265 #define DIRSEP_C '/'
266 #define EXTSEP_C '.'
267 #define DIRSEP_S "/"
268 #define EXTSEP_S "."
269 #endif
270
271 /* This is the same as VERSION, but should be overridden if the
272    platform cannot handle things like dots '.' in filenames. Set
273    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
274    uses for dots and dashes. */
275 #define SAFE_VERSION VERSION
276 #define SAFE_VERSION_DOT  '.'
277 #define SAFE_VERSION_DASH '-'
278
279 /* For some systems (DOS currently), we hardcode the path here.  For
280    POSIX systems the values are constructed by the Makefiles, so that
281    the values may be overridden by the make invocations; this is to
282    comply with the GNU coding standards. */
283 #ifdef HAVE_DRIVE_LETTERS
284 #define GNUPG_BINDIR      "c:\\gnupg"
285 #define GNUPG_LIBEXECDIR  "c:\\lib\\gnupg"
286 #define GNUPG_LIBDIR      "c:\\lib\\gnupg"
287 #define GNUPG_DATADIR     "c:\\lib\\gnupg"
288 #endif
289
290 /* Setup the hardwired names of modules. */
291 #ifndef GNUPG_DEFAULT_AGENT
292 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" )
293 #endif
294 #ifndef GNUPG_DEFAULT_PINENTRY
295 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" )
296 #endif
297 #ifndef GNUPG_DEFAULT_SCDAEMON
298 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" )
299 #endif
300 #ifndef GNUPG_DEFAULT_DIRMNGR
301 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" )
302 #endif
303 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
304 #define GNUPG_DEFAULT_PROTECT_TOOL \
305                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" )
306 #endif
307
308
309 /* Derive some other constants. */
310 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
311 #define EXEC_TEMPFILE_ONLY
312 #endif
313
314 ])
315
316 AM_MAINTAINER_MODE
317
318 # Checks for programs.
319 AC_PROG_MAKE_SET
320 AM_SANITY_CHECK
321 missing_dir=`cd $ac_aux_dir && pwd`
322 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
323 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
324 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
325 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
326 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
327 AC_PROG_AWK
328 AC_PROG_CC
329 AC_PROG_CPP
330 AC_PROG_INSTALL
331 AC_PROG_LN_S
332 AC_PROG_MAKE_SET
333 AC_PROG_RANLIB
334 AC_CHECK_TOOL(AR, ar, :)
335 AC_PATH_PROG(PERL,"perl")
336 AC_ISC_POSIX
337 AC_SYS_LARGEFILE
338 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
339 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
340 GNUPG_CHECK_FAQPROG
341 GNUPG_CHECK_DOCBOOK_TO_TEXI
342
343
344 try_gettext=yes
345 have_dosish_system=no
346 have_w32_system=no
347 case "${host}" in
348     *-mingw32*)
349         # special stuff for Windoze NT
350         ac_cv_have_dev_random=no
351         AC_DEFINE(USE_ONLY_8DOT3,1,
352                   [set this to limit filenames to the 8.3 format])
353         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
354                   [defined if we must run on a stupid file system])
355         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
356                   [because the Unix gettext has too much overhead on
357                    MingW32 systems and these systems lack Posix functions,
358                    we use a simplified version of gettext])
359         have_dosish_system=yes
360         have_w32_system=yes
361         try_gettext="no"
362         ;;
363     i?86-emx-os2 | i?86-*-os2*emx )
364         # OS/2 with the EMX environment
365         ac_cv_have_dev_random=no
366         AC_DEFINE(HAVE_DRIVE_LETTERS)
367         have_dosish_system=yes
368         try_gettext="no"
369         ;;
370
371     i?86-*-msdosdjgpp*)
372         # DOS with the DJGPP environment
373         ac_cv_have_dev_random=no
374         AC_DEFINE(HAVE_DRIVE_LETTERS)
375         have_dosish_system=yes
376         try_gettext="no"
377         ;;
378
379     *-*-freebsd*)
380        # FreeBSD
381        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
382        LDFLAGS="$LDFLAGS -L/usr/local/lib"
383        ;;
384
385     *-*-hpux*)
386         if test -z "$GCC" ; then
387             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
388         fi
389         ;;
390     *-dec-osf4*)
391         if test -z "$GCC" ; then
392             # Suppress all warnings
393             # to get rid of the unsigned/signed char mismatch warnings.
394             CFLAGS="$CFLAGS -w"
395         fi
396         ;;
397     *-dec-osf5*)
398         if test -z "$GCC" ; then
399             # Use the newer compiler `-msg_disable ptrmismatch' to
400             # get rid of the unsigned/signed char mismatch warnings.
401             # Using this may hide other pointer mismatch warnings, but
402             # it at least lets other warning classes through
403             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
404         fi
405         ;;
406     m68k-atari-mint)
407         ;;
408     *)
409        ;;
410 esac
411
412 if test "$have_dosish_system" = yes; then
413    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
414              [Defined if we run on some of the PCDOS like systems 
415               (DOS, Windoze. OS/2) with special properties like
416               no file modes])
417 fi
418 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
419
420 if test "$have_w32_system" = yes; then
421    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
422 fi
423 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
424
425
426
427 #
428 # Checks for libraries.
429 #
430
431
432 #
433 # libgpg-error is a library with error codes shared between GnuPG
434 # related projects.
435 #
436 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
437                   have_gpg_error=yes,have_gpg_error=no)
438
439
440 #
441 # Libgcrypt is our generic crypto library
442 #
443 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
444         have_libgcrypt=yes,have_libgcrypt=no)
445
446
447 #
448 # libassuan is used for IPC
449 #
450 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
451                   have_libassuan=yes,have_libassuan=no)
452
453
454 #
455 # libksba is our X.509 support library
456 #
457 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
458
459 #
460 # libusb allows us to use the integrated CCID smartcard reader driver.
461 #
462 AC_CHECK_LIB(usb, usb_bulk_write,
463               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
464                 AC_DEFINE(HAVE_LIBUSB,1,
465                          [defined if libusb is available])
466              ])
467 AC_SUBST(LIBUSB_LIBS)
468 AC_CHECK_FUNCS(usb_create_match)
469
470 #
471 # Check wether it is necessary to link against libdl.
472 #
473 LIBS=""
474 AC_SEARCH_LIBS(dlopen, c dl,,,)
475 DL_LIBS=$LIBS
476 AC_SUBST(DL_LIBS)
477
478 #
479 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
480 # build a limited SCdaemon
481 #
482 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
483 if test $have_opensc = yes; then
484   AC_DEFINE(HAVE_OPENSC,1,
485             [defined if the OpenSC library is available])
486 fi
487 AM_CONDITIONAL(HAVE_OPENSC, test "$have_opensc" = "yes")
488
489 #
490 # Check whether the (highly desirable) GNU Pth library is available
491 # Note, that we include a Pth emulation for W32.
492 #
493 AC_ARG_WITH(pth-prefix,
494             AC_HELP_STRING([--with-pth-prefix=PFX],
495                            [prefix where GNU Pth is installed (optional)]),
496      pth_config_prefix="$withval", pth_config_prefix="")
497 if test x$pth_config_prefix != x ; then
498    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
499 fi
500 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
501 if test "$have_w32_system" = no; then
502  if test "$PTH_CONFIG" = "no"; then
503     AC_MSG_WARN([[
504 ***
505 *** To support concurrent access to the gpg-agent and the SCdaemon
506 *** we need the support of the GNU Portable Threads Library.
507 *** Download it from ftp://ftp.gnu.org/gnu/pth/
508 *** On a Debian GNU/Linux system you might want to try 
509 ***   apt-get install libpth-dev
510 ***]])
511  else
512   GNUPG_PTH_VERSION_CHECK(1.3.7)
513   if test $have_pth = yes; then      
514      PTH_CFLAGS=`$PTH_CONFIG --cflags`
515      PTH_LIBS=`$PTH_CONFIG --ldflags`
516      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
517      AC_DEFINE(USE_GNU_PTH, 1,
518               [Defined if the GNU Portable Thread Library should be used])
519   fi
520  fi
521 else 
522  have_pth=yes
523  PTH_CFLAGS=""
524  PTH_LIBS=""
525  AC_DEFINE(USE_GNU_PTH, 1)
526 fi
527 AC_SUBST(PTH_CFLAGS)
528 AC_SUBST(PTH_LIBS)
529
530 AC_ARG_ENABLE(threads,
531     AC_HELP_STRING([--disable-threads],[allow building without Pth support]);
532     
533 )
534
535
536 dnl Must check for network library requirements before doing link tests
537 dnl for ldap, for example. If ldap libs are static (or dynamic and without
538 dnl ELF runtime link paths), then link will fail and LDAP support won't
539 dnl be detected.
540
541 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
542         [NETLIBS="-lnsl $NETLIBS"]))
543 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
544         [NETLIBS="-lsocket $NETLIBS"]))
545
546 dnl Now try for the resolver functions so we can use DNS SRV
547
548 AC_ARG_ENABLE(dns-srv,
549    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
550    use_dns_srv=$enableval,use_dns_srv=yes)
551
552 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
553   _srv_save_libs=$LIBS
554   LIBS=""
555   # the double underscore thing is a glibc-ism?
556   AC_SEARCH_LIBS(res_query,resolv bind,,
557                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
558   AC_SEARCH_LIBS(dn_expand,resolv bind,,
559                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
560   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
561                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
562
563   if test x"$use_dns_srv" = xyes ; then
564      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
565      SRVLIBS=$LIBS
566   else
567      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
568   fi
569   LIBS=$_srv_save_libs
570 fi
571
572 AC_SUBST(SRVLIBS)
573
574 # Try and link a LDAP test program to weed out unusable LDAP
575 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
576 # general is terrible with creating weird dependencies.  If all else
577 # fails, the user can play guess-the-dependency by using something
578 # like ./configure LDAPLIBS="-Lfoo -lbar"
579
580 if test "$try_ldap" = yes ; then
581   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
582     _ldap_save_libs=$LIBS
583     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
584
585     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
586     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
587                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
588     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
589
590     if test $gnupg_cv_func_ldap_init = no; then
591       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
592       AC_TRY_LINK([#include <lber.h>
593 #include <ldap.h>],[ldap_open("foobar",1234);],
594          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
595       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
596     fi
597
598     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
599        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
600     fi
601
602     if test "$gnupg_cv_func_ldap_init" = yes || \
603         test "$gnupg_cv_func_ldaplber_init" = yes ; then
604        LDAPLIBS=$MY_LDAPLIBS
605        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
606
607        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
608
609        if test "$gnupg_cv_func_ldap_init" = yes ; then
610           AC_TRY_LINK([#include <ldap.h>],
611              [ldap_get_option((void *)0,0,(void *)0);],
612              [gnupg_cv_func_ldap_get_option=yes],
613              [gnupg_cv_func_ldap_get_option=no])
614         else
615           AC_TRY_LINK([#include <lber.h>
616 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
617              [gnupg_cv_func_ldap_get_option=yes],
618              [gnupg_cv_func_ldap_get_option=no])
619        fi
620
621        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
622
623        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
624           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
625        else
626           AC_MSG_CHECKING([whether LDAP supports ld_errno])
627
628           if test "$gnupg_cv_func_ldap_init" = yes ; then
629             AC_TRY_COMPILE([#include <ldap.h>],
630                [LDAP *ldap; ldap->ld_errno;],
631                [gnupg_cv_func_ldap_ld_errno=yes],
632                [gnupg_cv_func_ldap_ld_errno=no])
633            else
634             AC_TRY_LINK([#include <lber.h>
635 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
636                [gnupg_cv_func_ldap_ld_errno=yes],
637                [gnupg_cv_func_ldap_ld_errno=no])
638           fi
639
640           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
641
642           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
643              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
644           fi
645        fi
646     fi
647
648     LIBS=$_ldap_save_libs
649
650     if test "$GPGKEYS_LDAP" != "" ; then break; fi
651   done
652 fi
653
654 AC_SUBST(GPGKEYS_LDAP)
655 AC_SUBST(LDAPLIBS)
656
657 dnl This isn't necessarily sendmail itself, but anything that gives a
658 dnl sendmail-ish interface to the outside world.  That includes qmail,
659 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
660
661 if test "$try_mailto" = yes ; then
662   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
663
664   if test "$with_mailprog" = yes ; then
665     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
666     if test "$ac_cv_path_SENDMAIL" ; then
667       GPGKEYS_MAILTO="gpgkeys_mailto"
668     fi
669   elif test "$with_mailprog" != no ; then
670     AC_MSG_CHECKING([for a mail transport program])
671     AC_SUBST(SENDMAIL,$with_mailprog)
672     AC_MSG_RESULT($with_mailprog)
673     GPGKEYS_MAILTO="gpgkeys_mailto"
674   fi
675 fi
676
677 AC_SUBST(GPGKEYS_MAILTO)
678
679 case "${host}" in
680     *-mingw32*)
681         PRINTABLE_OS_NAME="MingW32"
682         ;;
683     *-*-cygwin*)
684         PRINTABLE_OS_NAME="Cygwin"
685         ;;
686     i?86-emx-os2 | i?86-*-os2*emx )
687         PRINTABLE_OS_NAME="OS/2"
688         ;;
689     i?86-*-msdosdjgpp*)
690         PRINTABLE_OS_NAME="MSDOS/DJGPP"
691         try_dynload=no
692         ;;
693     *-linux*)
694         PRINTABLE_OS_NAME="GNU/Linux"
695         ;;
696     *)
697         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
698         ;;
699 esac
700 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
701                    [A human readable text with the name of the OS])
702
703
704 AM_GNU_GETTEXT_VERSION(0.14.1)
705 if test "$try_gettext" = yes; then
706   AM_GNU_GETTEXT(,[need-ngettext])
707
708   # gettext requires some extra checks.  These really should be part of
709   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
710   # function checks to here.
711
712   AC_CHECK_FUNCS(strchr)
713 else
714   USE_NLS=no
715   USE_INCLUDED_LIBINTL=no
716   BUILD_INCLUDED_LIBINTL=no
717   AC_SUBST(USE_NLS)
718   AC_SUBST(USE_INCLUDED_LIBINTL)
719   AC_SUBST(BUILD_INCLUDED_LIBINTL)
720 fi
721
722 # Checks for header files.
723 AC_HEADER_STDC
724 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
725
726 # Checks for typedefs, structures, and compiler characteristics.
727 AC_C_CONST
728 AC_C_INLINE
729 AC_TYPE_SIZE_T
730 AC_TYPE_SIGNAL
731 AC_DECL_SYS_SIGLIST
732
733 GNUPG_CHECK_ENDIAN
734
735 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
736 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
737 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
738 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
739 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
740
741 AC_CHECK_SIZEOF(unsigned short)
742 AC_CHECK_SIZEOF(unsigned int)
743 AC_CHECK_SIZEOF(unsigned long)
744 AC_CHECK_SIZEOF(unsigned long long)
745 # Ensure that we have UINT64_C before we bother to check for uint64_t
746 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
747 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
748    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
749 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
750 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
751    AC_CHECK_SIZEOF(uint64_t)
752 fi
753  
754
755
756
757 if test "$ac_cv_sizeof_unsigned_short" = "0" \
758    || test "$ac_cv_sizeof_unsigned_int" = "0" \
759    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
760     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
761 fi
762
763 dnl Do we have any 64-bit data types?
764 if test "$ac_cv_sizeof_unsigned_int" != "8" \
765    && test "$ac_cv_sizeof_unsigned_long" != "8" \
766    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
767    && test "$ac_cv_sizeof_uint64_t" != "8"; then
768     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
769 else
770   if test x"$use_sha512" = xyes ; then
771      AC_SUBST(SHA512_O,sha512.o)
772      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
773   fi
774 fi
775
776 # fixme: do we really need this - it should be encapsulated in libassuan
777 GNUPG_SYS_SO_PEERCRED
778
779 # Checks for library functions.
780 AC_FUNC_FSEEKO
781 AC_FUNC_VPRINTF
782 AC_FUNC_FORK
783 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
784 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
785 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
786 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
787 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
788
789 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
790
791 # These are needed by libjnlib - fixme: we should have macros for them
792 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
793 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
794 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
795
796 AC_REPLACE_FUNCS(vasprintf)
797 AC_REPLACE_FUNCS(mkdtemp)
798 AC_REPLACE_FUNCS(fseeko ftello)
799 AC_REPLACE_FUNCS(isascii)
800 AC_REPLACE_FUNCS(putc_unlocked)
801 AC_REPLACE_FUNCS(strsep)
802
803
804
805 #
806 # check for gethrtime and run a testprogram to see whether
807 # it is broken.  It has been reported that some Solaris and HP UX systems 
808 # raise an SIGILL
809 #
810 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
811 #
812 AC_CACHE_CHECK([for gethrtime], 
813                [gnupg_cv_func_gethrtime],
814                [AC_TRY_LINK([#include <sys/times.h>],[
815                    hrtime_t tv;
816                    tv = gethrtime();
817                  ],
818                  [gnupg_cv_func_gethrtime=yes],
819                  [gnupg_cv_func_gethrtime=no])
820                ])
821 if test $gnupg_cv_func_gethrtime = yes; then
822      AC_DEFINE([HAVE_GETHRTIME], 1,
823                [Define if you have the `gethrtime(2)' function.])
824      AC_CACHE_CHECK([whether gethrtime is broken], 
825                [gnupg_cv_func_broken_gethrtime],
826                [AC_TRY_RUN([
827                    #include <sys/times.h>
828                    int main () {
829                    hrtime_t tv;
830                    tv = gethrtime(); 
831                  }
832                  ],
833                  [gnupg_cv_func_broken_gethrtime=no],
834                  [gnupg_cv_func_broken_gethrtime=yes],
835                  [gnupg_cv_func_broken_gethrtime=assume-no])
836                 ])
837     if test $gnupg_cv_func_broken_gethrtime = yes; then
838       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
839       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
840     fi
841 fi
842      
843
844 GNUPG_CHECK_MLOCK
845 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
846
847 dnl
848 dnl Check whether we can use Linux capabilities as requested
849 dnl
850 #  fixme: Still required?
851 #
852 if test "$use_capabilities" = "yes" ; then
853 use_capabilities=no
854 AC_CHECK_HEADERS(sys/capability.h)
855 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
856   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
857   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
858      AC_DEFINE(USE_CAPABILITIES,1,
859                [define if capabilities should be used])
860      AC_SUBST(CAPLIBS,"-lcap")
861      use_capabilities=yes
862   fi
863 fi
864 if test "$use_capabilities" = "no" ; then
865     AC_MSG_WARN([[
866 ***
867 *** The use of capabilities on this system is not possible.
868 *** You need a recent Linux kernel and some patches:
869 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
870 ***   fcap-module-990613.tar.gz     (kernel module)
871 ***   libcap-1.92.tar.gz            (user mode library and utilities)
872 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
873 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
874 ***]])
875 fi
876 fi
877
878
879 # Sanity check regex.  Tests adapted from mutt.
880
881 AC_MSG_CHECKING([whether regular expression support is requested])
882 AC_ARG_ENABLE(regex,
883 [  --disable-regex         do not handle regular expressions in trust sigs],
884      use_regex=$enableval, use_regex=yes)
885 AC_MSG_RESULT($use_regex)
886
887 if test "$use_regex" = yes ; then
888   AC_MSG_CHECKING([whether the included regex lib is requested])
889   AC_ARG_WITH(included-regex,
890       [  --with-included-regex   use the included GNU regex library],
891       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
892   AC_MSG_RESULT($gnupg_cv_included_regex)
893
894   if test $gnupg_cv_included_regex = no ; then
895      # Does the system have regex functions at all?
896      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
897                            gnupg_cv_included_regex=yes)
898   fi
899
900   if test $gnupg_cv_included_regex = no ; then
901      AC_CACHE_CHECK([whether your system's regexp library is broken],
902        [gnupg_cv_regex_broken],
903        AC_TRY_RUN([
904 #include <unistd.h>
905 #include <regex.h>
906 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
907        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
908
909      if test $gnupg_cv_regex_broken = yes ; then
910       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
911       gnupg_cv_included_regex=yes
912      fi
913   fi
914
915   if test $gnupg_cv_included_regex = yes; then
916      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
917      AC_SUBST(REGEX_O,regex.o)
918   fi
919 else
920
921   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
922 fi
923
924 dnl Do we have zlib? Must do it here because Solaris failed
925 dnl when compiling a conftest (due to the "-lz" from LIBS).
926 use_local_zlib=yes
927 if test "$g10_force_zlib" = "yes"; then
928   :
929 else
930   _cppflags="${CPPFLAGS}"
931   _ldflags="${LDFLAGS}"
932
933   AC_ARG_WITH(zlib,
934   [  --with-zlib=DIR         use libz in DIR],[
935     if test -d "$withval"; then
936       CPPFLAGS="${CPPFLAGS} -I$withval/include"
937       LDFLAGS="${LDFLAGS} -L$withval/lib"
938     fi
939   ])
940
941   AC_CHECK_HEADER(zlib.h,
942       AC_CHECK_LIB(z, deflateInit2_,
943        use_local_zlib=no
944        LIBS="$LIBS -lz",
945        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
946        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
947 fi
948  
949 if test "$use_local_zlib" = yes ; then
950     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
951     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
952     ZLIBS="../zlib/libzlib.a"
953 else
954     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
955     ZLIBS=
956 fi
957 AC_SUBST(ZLIBS)
958
959
960 # See wether we want to run the long test suite.
961 AC_ARG_WITH(pkits-tests,
962     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
963     [run_pkits_tests=$withval], [run_pkits_tests=no])
964 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
965
966
967 # Allow users to append something to the version string without
968 # flagging it as development version.  The user version parts is
969 # considered everything after a dash. 
970 if test "$development_version" != yes; then
971   changequote(,)dnl
972   tmp_pat='[a-zA-Z]'
973   changequote([,])dnl
974   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
975     development_version=yes
976   fi
977 fi
978 if test "$development_version" = yes; then
979     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
980             [Defined if this is not a regular release])
981 fi
982
983 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
984
985 GNUPG_CHECK_GNUMAKE
986
987 # Add some extra libs here so that previous tests don't fail for
988 # mysterious reasons - the final link step should bail out. 
989 if test "$have_w32_system" = yes; then
990    W32LIBS="-lwsock32"
991 fi
992
993
994 if test "$GCC" = yes; then
995     if test "$USE_MAINTAINER_MODE" = "yes"; then
996         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
997         CFLAGS="$CFLAGS -Wformat-nonliteral"
998     else
999         CFLAGS="$CFLAGS -Wall"
1000     fi
1001 fi
1002
1003 AC_SUBST(NETLIBS)
1004 AC_SUBST(W32LIBS)
1005
1006
1007 # We use jnlib, so tell other modules about it
1008 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1009           [Defined if jnlib style logging functions are available])
1010
1011 # For W32 we need to use our Pth emulation code
1012 if test "$have_w32_system" = yes; then
1013   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1014 fi
1015
1016
1017 #
1018 # Decide what to build
1019 #
1020 missing_pth=no
1021 if test $have_ksba = no; then
1022   build_gpgsm=no
1023   build_scdaemon=no
1024 fi
1025
1026 build_agent_threaded=""
1027 if test "$build_agent" = "yes"; then
1028   if test $have_pth = no; then
1029      build_agent_threaded="(not multi-threaded)"
1030      missing_pth=yes
1031   fi
1032 fi
1033
1034 build_scdaemon_extra=""
1035 if test "$build_scdaemon" = "yes"; then
1036   tmp=""
1037   if test $have_pth = no; then
1038      build_scdaemon_extra="not multi-threaded"
1039      tmp=", "
1040      missing_pth=yes
1041   fi
1042   if test $have_opensc = no; then
1043      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
1044      tmp=", "
1045   fi      
1046   if test -n "$build_scdaemon_extra"; then
1047      build_scdaemon_extra="(${build_scdaemon_extra})"
1048   fi
1049 fi
1050
1051 if test "$build_agent_only" = "yes" ; then
1052   build_gpg=no
1053   build_gpgsm=no
1054   build_scdaemon=no
1055 fi
1056
1057 # We don't yet want to build some parts for W32
1058 case "${host}" in 
1059     *-mingw32*) 
1060       build_gpg=no
1061       ;;
1062 esac
1063
1064
1065 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1066 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1067 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1068 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1069
1070
1071
1072 #
1073 # Print errors here so that they are visible all
1074 # together and the user can acquire them all together.
1075 #
1076 die=no
1077 if test "$have_gpg_error" = "no"; then
1078    die=yes
1079    AC_MSG_NOTICE([[
1080 ***  
1081 *** You need libgpg-error to build this program.
1082 **  This library is for example available at
1083 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgpg-error
1084 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1085 ***]])
1086 fi
1087 if test "$have_libgcrypt" = "no"; then
1088    die=yes
1089    AC_MSG_NOTICE([[
1090 ***  
1091 *** You need libgcrypt to build this program.
1092 **  This library is for example available at
1093 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1094 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1095 ***]])
1096 fi
1097 if test "$have_libassuan" = "no"; then
1098    die=yes
1099    AC_MSG_NOTICE([[
1100 ***
1101 *** You need libassuan to build this program.
1102 *** This library is for example available at
1103 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1104 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1105 ***]])
1106 fi
1107 if test "$have_ksba" = "no"; then
1108     AC_MSG_NOTICE([[
1109 ***
1110 *** You need libksba to build this program.
1111 *** This library is for example available at
1112 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1113 *** (at least version $NEED_KSBA_VERSION is required).
1114 ***]])
1115 fi
1116 if test "$missing_pth" = "yes"; then
1117     AC_MSG_NOTICE([[
1118 ***
1119 *** It is strongly suggested to build with support for the
1120 *** GNU Portable Threads Library (Pth). Please install this
1121 *** library first or use --disable-threads to allow building
1122 *** anyway.  The library is for example available at
1123 ***   ftp://ftp.gnu.org/gnu/pth/
1124 *** On a Debian GNU/Linux system you can install it using 
1125 ***   apt-get install libpth-dev
1126 ***]])
1127   if test "$enable_threads" != "no"; then
1128      die=yes
1129   fi
1130 fi
1131
1132 if test "$die" = "yes"; then
1133     AC_MSG_ERROR([[
1134 ***
1135 *** Required libraries not found. Please consult the above messages
1136 *** and install them before running configure again.
1137 ***]])
1138 fi
1139
1140
1141
1142 AC_CONFIG_FILES([ m4/Makefile 
1143 Makefile
1144 po/Makefile.in
1145 intl/Makefile
1146 jnlib/Makefile
1147 common/Makefile
1148 kbx/Makefile
1149 g10/Makefile
1150 sm/Makefile
1151 agent/Makefile
1152 scd/Makefile
1153 tools/Makefile
1154 doc/Makefile
1155 tests/Makefile
1156 ])
1157 AC_OUTPUT
1158
1159 #tests/pkits/Makefile
1160
1161
1162
1163
1164 echo "
1165         GnuPG v${VERSION} has been configured as follows:
1166         
1167         Platform:  $PRINTABLE_OS_NAME ($host)
1168
1169         OpenPGP:   $build_gpg
1170         S/MIME:    $build_gpgsm
1171         Agent:     $build_agent $build_agent_threaded
1172         Smartcard: $build_scdaemon $build_scdaemon_extra
1173
1174         Protect tool:      $show_gnupg_protect_tool_pgm
1175         Default agent:     $show_gnupg_agent_pgm
1176         Default pinentry:  $show_gnupg_pinentry_pgm
1177         Default scdaemon:  $show_gnupg_scdaemon_pgm
1178         Default dirmngr:   $show_gnupg_dirmngr_pgm
1179
1180         PKITS based tests: $run_pkits_tests
1181 "
1182