disconnectafter wake-up bug fix by Bob Dunlop.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004, 2005, 2006 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
20 # USA.
21
22 # Process this file with autoconf to produce a configure script.
23 AC_PREREQ(2.52)
24 min_automake_version="1.9.3"
25
26 # Remember to change the version number immediately *after* a release.
27 # Set my_issvn to "yes" for non-released code.  Remember to run an
28 # "svn up" and "autogen.sh" right before creating a distribution.
29 m4_define([my_version], [1.9.23])
30 m4_define([my_issvn], [yes])
31
32
33 m4_define([svn_revision], m4_esyscmd([echo -n $((svn info 2>/dev/null \
34             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q}')]))
35 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
36         [bug-gnupg@gnupg.org])
37 # Set development_version to yes if the minor number is odd or you
38 # feel that the default check for a development version is not
39 # sufficient.
40 development_version=yes
41
42 NEED_GPG_ERROR_VERSION=1.2
43
44 NEED_LIBGCRYPT_API=1
45 NEED_LIBGCRYPT_VERSION=1.1.94
46
47 NEED_LIBASSUAN_VERSION=0.6.10
48
49 NEED_KSBA_VERSION=0.9.16
50
51
52 PACKAGE=$PACKAGE_NAME
53 PACKAGE_GT=${PACKAGE_NAME}2
54 VERSION=$PACKAGE_VERSION
55
56 AC_CONFIG_AUX_DIR(scripts)
57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
58 AM_CONFIG_HEADER(config.h)
59 AC_CANONICAL_TARGET()
60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
61 AB_INIT
62
63 AC_GNU_SOURCE
64
65 # Some status variables.
66 have_gpg_error=no
67 have_libgcrypt=no 
68 have_libassuan=no
69 have_ksba=no
70 have_pth=no
71
72 use_bzip2=yes
73 use_exec=yes
74 disable_keyserver_path=no
75
76
77 GNUPG_BUILD_PROGRAM(gpg, no)
78 GNUPG_BUILD_PROGRAM(gpgsm, yes)
79 GNUPG_BUILD_PROGRAM(agent, yes)
80 GNUPG_BUILD_PROGRAM(scdaemon, yes)
81 GNUPG_BUILD_PROGRAM(symcryptrun, no)
82
83 AC_SUBST(PACKAGE)
84 AC_SUBST(PACKAGE_GT)
85 AC_SUBST(VERSION)
86 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
87 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
88                                 [Name of this package for gettext])
89 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
90 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
91                                         [Bug report address])
92 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
93                                        [Required version of Libgcrypt])
94 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
95                                        [Required version of Libksba])
96
97
98
99 # The default is to use the modules from this package and the few
100 # other packages in a standard place; i.e where this package gets
101 # installed.  With these options it is possible to override these
102 # ${prefix} depended values with fixed paths, which can't be replaced
103 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
104 AC_ARG_WITH(agent-pgm,
105     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
106           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
107 AC_SUBST(GNUPG_AGENT_PGM)
108 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
109 show_gnupg_agent_pgm="(default)"
110 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
111
112 AC_ARG_WITH(pinentry-pgm,
113     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
114           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
115 AC_SUBST(GNUPG_PINENTRY_PGM)
116 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
117 show_gnupg_pinentry_pgm="(default)"
118 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
119
120
121 AC_ARG_WITH(scdaemon-pgm,
122     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
123           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
124 AC_SUBST(GNUPG_SCDAEMON_PGM)
125 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
126 show_gnupg_scdaemon_pgm="(default)"
127 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
128
129
130 AC_ARG_WITH(dirmngr-pgm,
131     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
132           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
133 AC_SUBST(GNUPG_DIRMNGR_PGM)
134 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
135 show_gnupg_dirmngr_pgm="(default)"
136 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
137
138 AC_ARG_WITH(protect-tool-pgm,
139     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
140           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
141 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
142 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
143 show_gnupg_protect_tool_pgm="(default)"
144 test -n "$GNUPG_PROTECT_TOOL_PGM" \
145       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
146
147
148 # Some folks want to use only the agent from this packet.  Make it
149 # easier for them by providing the configure option
150 # --enable-only-agent.
151 AC_ARG_ENABLE(agent-only,
152     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
153     build_agent_only=$enableval)
154
155
156 # SELinux support includes tracking of sensitive files to avoid
157 # leaking their contents through processing these files by gpg itself
158 AC_MSG_CHECKING([whether SELinux support is requested])
159 AC_ARG_ENABLE(selinux-support,
160               AC_HELP_STRING([--enable-selinux-support],
161                              [enable SELinux support]),
162               selinux_support=$enableval, selinux_support=no)
163 AC_MSG_RESULT($selinux_support)
164
165 # Allow disabling of bzib2 support.
166 # It is defined only after we confirm the library is available later
167 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
168 AC_ARG_ENABLE(bzip2,
169    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
170    use_bzip2=$enableval)
171 AC_MSG_RESULT($use_bzip2)
172
173
174 # Configure option to allow or disallow execution of external
175 # programs, like a photo viewer.
176 AC_MSG_CHECKING([whether to enable external program execution])
177 AC_ARG_ENABLE(exec,
178     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
179     use_exec=$enableval)
180 AC_MSG_RESULT($use_exec)
181 if test "$use_exec" = no ; then
182     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
183 fi
184
185 if test "$use_exec" = yes ; then
186   AC_MSG_CHECKING([whether to enable photo ID viewing])
187   AC_ARG_ENABLE(photo-viewers,
188       [  --disable-photo-viewers disable photo ID viewers],
189       [if test "$enableval" = no ; then
190          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
191       fi],enableval=yes)
192   gnupg_cv_enable_photo_viewers=$enableval
193   AC_MSG_RESULT($enableval)
194
195   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
196     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
197     AC_ARG_WITH(photo-viewer,
198         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
199         [if test "$withval" = yes ; then
200            withval=no
201         elif test "$withval" != no ; then
202            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
203                             [if set, restrict photo-viewer to this])
204         fi],withval=no)
205     AC_MSG_RESULT($withval)
206   fi
207
208   AC_MSG_CHECKING([whether to enable external keyserver helpers])
209   AC_ARG_ENABLE(keyserver-helpers,
210       [  --disable-keyserver-helpers  disable all external keyserver support],
211       [if test "$enableval" = no ; then
212          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
213                   [define to disable keyserver helpers])
214       fi],enableval=yes)
215   gnupg_cv_enable_keyserver_helpers=$enableval
216   AC_MSG_RESULT($enableval)
217
218   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
219     # LDAP is defined only after we confirm the library is available later
220     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
221     AC_ARG_ENABLE(ldap,
222       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
223       try_ldap=$enableval, try_ldap=yes)
224     AC_MSG_RESULT($try_ldap)
225
226     AC_MSG_CHECKING([whether HKP keyserver support is requested])
227     AC_ARG_ENABLE(hkp,
228       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
229       try_hkp=$enableval, try_hkp=yes)
230     AC_MSG_RESULT($try_hkp)
231
232     AC_MSG_CHECKING([whether finger key fetching support is requested])
233     AC_ARG_ENABLE(finger,
234       AC_HELP_STRING([--disable-finger],
235         [disable finger key fetching interface only]),
236       try_finger=$enableval, try_finger=yes)
237     AC_MSG_RESULT($try_finger)
238
239     AC_MSG_CHECKING([whether generic object key fetching support is requested])
240     AC_ARG_ENABLE(generic,
241       AC_HELP_STRING([--disable-generic],
242         [disable generic object key fetching interface only]),
243       try_generic=$enableval, try_generic=yes)
244     AC_MSG_RESULT($try_generic)
245
246     AC_MSG_CHECKING([whether email keyserver support is requested])
247     AC_ARG_ENABLE(mailto,
248       AC_HELP_STRING([--enable-mailto],
249         [enable email keyserver interface only]),
250       try_mailto=$enableval, try_mailto=no)
251     AC_MSG_RESULT($try_mailto)
252     fi
253
254     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
255     AC_ARG_ENABLE(keyserver-path,
256       AC_HELP_STRING([--disable-keyserver-path],
257         [disable the exec-path option for keyserver helpers]),
258       [if test "$enableval" = no ; then
259          disable_keyserver_path=yes
260       fi],enableval=yes)
261     AC_MSG_RESULT($enableval)
262   fi
263
264
265 #
266 # Check for the key/uid cache size.  This can't be zero, but can be
267 # pretty small on embedded systems.  This is used for the gpg part.
268 #
269 AC_MSG_CHECKING([for the size of the key and uid cache])
270 AC_ARG_ENABLE(key-cache,
271         AC_HELP_STRING([--enable-key-cache=SIZE],
272                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
273 if test "$enableval" = "no"; then
274    enableval=5
275 elif test "$enableval" = "yes" || test "$enableval" = ""; then
276    enableval=4096
277 fi
278 changequote(,)dnl
279 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
280 changequote([,])dnl
281 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
282    AC_MSG_ERROR([invalid key-cache size])
283 fi
284 AC_MSG_RESULT($key_cache_size)
285 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
286                   [Size of the key and UID caches])
287
288
289
290 #
291 # Check whether we want to use Linux capabilities
292 #
293 AC_MSG_CHECKING([whether use of capabilities is requested])
294 AC_ARG_WITH(capabilities,
295     [  --with-capabilities     use linux capabilities [default=no]],
296 [use_capabilities="$withval"],[use_capabilities=no])
297 AC_MSG_RESULT($use_capabilities)
298
299 #
300 # To avoid double inclusion of config.h which might happen at some
301 # places, we add the usual double inclusion protection at the top of
302 # config.h.
303 #
304 AH_TOP([
305 #ifndef GNUPG_CONFIG_H_INCLUDED
306 #define GNUPG_CONFIG_H_INCLUDED
307 ])
308
309 #
310 # Stuff which goes at the bottom of config.h.
311 #
312 AH_BOTTOM([
313 /* This is the major version number of GnuPG so that
314    source included files can test for this.  Note, that
315    we use 2 here even for GnuPG 1.9.x. */
316 #define GNUPG_MAJOR_VERSION 2
317
318 /* Now to separate file name parts.
319    Please note that the string version must not contain more
320    than one character because the code assumes strlen()==1 */
321 #ifdef HAVE_DOSISH_SYSTEM
322 #define DIRSEP_C '\\'
323 #define DIRSEP_S "\\"
324 #define EXTSEP_C '.'
325 #define EXTSEP_S "."
326 #define PATHSEP_C ';'
327 #define PATHSEP_S ";"
328 #define EXEEXT_S ".exe"
329 #else
330 #define DIRSEP_C '/'
331 #define DIRSEP_S "/"
332 #define EXTSEP_C '.'
333 #define EXTSEP_S "."
334 #define PATHSEP_C ':'
335 #define PATHSEP_S ":"
336 #define EXEEXT_S ""
337 #endif
338
339 /* This is the same as VERSION, but should be overridden if the
340    platform cannot handle things like dots '.' in filenames. Set
341    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
342    uses for dots and dashes. */
343 #define SAFE_VERSION VERSION
344 #define SAFE_VERSION_DOT  '.'
345 #define SAFE_VERSION_DASH '-'
346
347 /* Some global constants. */
348 #ifdef HAVE_DRIVE_LETTERS
349 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
350 #elif defined(__VMS)
351 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
352 #else
353 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
354 #endif 
355 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
356
357 /* For some systems (DOS currently), we hardcode the path here.  For
358    POSIX systems the values are constructed by the Makefiles, so that
359    the values may be overridden by the make invocations; this is to
360    comply with the GNU coding standards. */
361 #ifdef HAVE_DRIVE_LETTERS
362 #define GNUPG_BINDIR      "c:\\gnupg"
363 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
364 #define GNUPG_LIBDIR      "c:\\gnupg"
365 #define GNUPG_DATADIR     "c:\\gnupg"
366 #endif
367
368 /* Setup the hardwired names of modules. */
369 #ifndef GNUPG_DEFAULT_AGENT
370 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
371 #endif
372 #ifndef GNUPG_DEFAULT_PINENTRY
373 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
374 #endif
375 #ifndef GNUPG_DEFAULT_SCDAEMON
376 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
377 #endif
378 #ifndef GNUPG_DEFAULT_DIRMNGR
379 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
380 #endif
381 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
382 #define GNUPG_DEFAULT_PROTECT_TOOL \
383                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
384 #endif
385
386
387 /* Derive some other constants. */
388 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
389 #define EXEC_TEMPFILE_ONLY
390 #endif
391
392
393 /* We didn't define endianness above, so get it from OS macros.  This
394    is intended for making fat binary builds on OS X. */
395 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
396 #if defined(__BIG_ENDIAN__)
397 #define BIG_ENDIAN_HOST 1
398 #elif defined(__LITTLE_ENDIAN__)
399 #define LITTLE_ENDIAN_HOST 1
400 #else
401 #error "No endianness found"
402 #endif
403 #endif
404
405
406 /* Tell libgcrypt not to use its own libgpg-error implementation. */
407 #define USE_LIBGPG_ERROR 1
408
409 /* We use jnlib, so tell other modules about it.  */
410 #define HAVE_JNLIB_LOGGING 1
411
412 /* Our HTTP code is used in estream mode.  */
413 #define HTTP_USE_ESTREAM 1
414
415 /* We always include support for the OpenPGP card.  */
416 #define ENABLE_CARD_SUPPORT 1
417
418
419 #endif /*GNUPG_CONFIG_H_INCLUDED*/
420 ])
421
422
423 AM_MAINTAINER_MODE
424
425 # Checks for programs.
426 AC_PROG_MAKE_SET
427 AM_SANITY_CHECK
428 missing_dir=`cd $ac_aux_dir && pwd`
429 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
430 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
431 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
432 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
433 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
434 AC_PROG_AWK
435 AC_PROG_CC
436 AC_PROG_CPP
437 AC_PROG_INSTALL
438 AC_PROG_LN_S
439 AC_PROG_RANLIB
440 AC_CHECK_TOOL(AR, ar, :)
441 AC_PATH_PROG(PERL,"perl")
442 AC_ISC_POSIX
443 gl_EARLY
444 AC_SYS_LARGEFILE
445 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
446 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
447 GNUPG_CHECK_FAQPROG
448 GNUPG_CHECK_DOCBOOK_TO_TEXI
449 GNUPG_CHECK_USTAR
450
451
452 try_gettext=yes
453 have_dosish_system=no
454 have_w32_system=no
455 use_simple_gettext=no
456 case "${host}" in
457     *-mingw32*)
458         # special stuff for Windoze NT
459         ac_cv_have_dev_random=no
460         AC_DEFINE(USE_ONLY_8DOT3,1,
461                   [set this to limit filenames to the 8.3 format])
462         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
463                   [defined if we must run on a stupid file system])
464         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
465                   [because the Unix gettext has too much overhead on
466                    MingW32 systems and these systems lack Posix functions,
467                    we use a simplified version of gettext])
468         disable_keyserver_path=yes
469         have_dosish_system=yes
470         have_w32_system=yes
471         try_gettext="no"
472         use_simple_gettext=yes
473         ;;
474     i?86-emx-os2 | i?86-*-os2*emx )
475         # OS/2 with the EMX environment
476         ac_cv_have_dev_random=no
477         AC_DEFINE(HAVE_DRIVE_LETTERS)
478         have_dosish_system=yes
479         try_gettext="no"
480         ;;
481
482     i?86-*-msdosdjgpp*)
483         # DOS with the DJGPP environment
484         ac_cv_have_dev_random=no
485         AC_DEFINE(HAVE_DRIVE_LETTERS)
486         have_dosish_system=yes
487         try_gettext="no"
488         ;;
489
490     *-*-freebsd*)
491        # FreeBSD
492        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
493        LDFLAGS="$LDFLAGS -L/usr/local/lib"
494        ;;
495
496     *-*-hpux*)
497         if test -z "$GCC" ; then
498             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
499         fi
500         ;;
501     *-dec-osf4*)
502         if test -z "$GCC" ; then
503             # Suppress all warnings
504             # to get rid of the unsigned/signed char mismatch warnings.
505             CFLAGS="$CFLAGS -w"
506         fi
507         ;;
508     *-dec-osf5*)
509         if test -z "$GCC" ; then
510             # Use the newer compiler `-msg_disable ptrmismatch1' to
511             # get rid of the unsigned/signed char mismatch warnings.
512             # Using this may hide other pointer mismatch warnings, but
513             # it at least lets other warning classes through
514             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
515         fi
516         ;;
517     m68k-atari-mint)
518         ;;
519     *)
520        ;;
521 esac
522
523 if test "$have_dosish_system" = yes; then
524    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
525              [Defined if we run on some of the PCDOS like systems 
526               (DOS, Windoze. OS/2) with special properties like
527               no file modes])
528 fi
529 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
530
531 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
532
533 if test "$have_w32_system" = yes; then
534    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
535 fi
536 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
537
538 if test "$disable_keyserver_path" = yes; then
539     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
540               [Defined to disable exec-path for keyserver helpers])
541 fi
542
543 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
544 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
545
546 if test x"$try_hkp" = xyes ; then
547   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
548 fi
549
550 if test x"$try_finger" = xyes ; then
551   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
552 fi
553
554
555
556 #
557 # Checks for libraries.
558 #
559
560
561 #
562 # libgpg-error is a library with error codes shared between GnuPG
563 # related projects.
564 #
565 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
566                   have_gpg_error=yes,have_gpg_error=no)
567 _tmp_gpg_error_save_cflags="$CFLAGS"
568 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
569 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
570 CFLAGS="${_tmp_gpg_error_save_cflags}"
571
572
573 #
574 # Libgcrypt is our generic crypto library
575 #
576 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
577         have_libgcrypt=yes,have_libgcrypt=no)
578
579
580 #
581 # libassuan is used for IPC
582 #
583 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
584                   have_libassuan=yes,have_libassuan=no)
585
586
587 #
588 # libksba is our X.509 support library
589 #
590 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
591
592
593 #
594 # libusb allows us to use the integrated CCID smartcard reader driver.
595 #
596 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
597 AC_CHECK_LIB(usb, usb_bulk_write,
598               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
599                 AC_DEFINE(HAVE_LIBUSB,1,
600                          [defined if libusb is available])
601              ])
602 AC_SUBST(LIBUSB_LIBS)
603 AC_CHECK_FUNCS(usb_create_match)
604
605 #
606 # Check wether it is necessary to link against libdl.
607 #
608 LIBS=""
609 AC_SEARCH_LIBS(dlopen, c dl,,,)
610 DL_LIBS=$LIBS
611 AC_SUBST(DL_LIBS)
612
613 #
614 # Checks for symcryptrun:
615 #
616
617 # libutil has openpty() and login_tty().
618 AC_CHECK_LIB(util, openpty,
619               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
620                 AC_DEFINE(HAVE_LIBUTIL,1,
621                          [defined if libutil is available])
622              ])
623 AC_SUBST(LIBUTIL_LIBS)
624
625 # shred is used to clean temporary plain text files.
626 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
627 AC_DEFINE_UNQUOTED(SHRED,
628         "${SHRED}", [defines the filename of the shred program])
629
630
631
632 #
633 # Check whether the GNU Pth library is available
634 # Note, that we include a Pth emulation for W32.
635 #
636 AC_ARG_WITH(pth-prefix,
637             AC_HELP_STRING([--with-pth-prefix=PFX],
638                            [prefix where GNU Pth is installed (optional)]),
639      pth_config_prefix="$withval", pth_config_prefix="")
640 if test x$pth_config_prefix != x ; then
641    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
642 fi
643 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
644 if test "$have_w32_system" = no; then
645  if test "$PTH_CONFIG" = "no"; then
646     AC_MSG_WARN([[
647 ***
648 *** To support concurrent access to the gpg-agent and the SCdaemon
649 *** we need the support of the GNU Portable Threads Library.
650 *** Download it from ftp://ftp.gnu.org/gnu/pth/
651 *** On a Debian GNU/Linux system you might want to try 
652 ***   apt-get install libpth-dev
653 ***]])
654  else
655   GNUPG_PTH_VERSION_CHECK(1.3.7)
656   if test $have_pth = yes; then      
657      PTH_CFLAGS=`$PTH_CONFIG --cflags`
658      PTH_LIBS=`$PTH_CONFIG --ldflags`
659      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs --all`"
660      AC_DEFINE(USE_GNU_PTH, 1,
661               [Defined if the GNU Portable Thread Library should be used])
662      AC_DEFINE(HAVE_PTH, 1,
663               [Defined if the GNU Pth is available])
664   fi
665  fi
666 else 
667  have_pth=yes
668  PTH_CFLAGS=""
669  PTH_LIBS=""
670  AC_DEFINE(USE_GNU_PTH, 1)
671  AC_DEFINE(HAVE_PTH, 1)
672 fi
673 AC_SUBST(PTH_CFLAGS)
674 AC_SUBST(PTH_LIBS)
675
676
677 #
678 # Must check for network library requirements before doing link tests
679 # for ldap, for example. If ldap libs are static (or dynamic and without
680 # ELF runtime link paths), then link will fail and LDAP support won't
681 # be detected.
682 #
683 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
684         [NETLIBS="-lnsl $NETLIBS"]))
685 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
686         [NETLIBS="-lsocket $NETLIBS"]))
687
688 #
689 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
690 #
691 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
692   AC_ARG_ENABLE(dns-srv,
693      AC_HELP_STRING([--disable-dns-srv],
694                     [disable the use of DNS SRV in HKP and HTTP]),
695                 use_dns_srv=$enableval,use_dns_srv=yes)
696 fi
697
698 AC_ARG_ENABLE(dns-pka,
699    AC_HELP_STRING([--disable-dns-pka],
700         [disable the use of PKA records in DNS]),
701    use_dns_pka=$enableval,use_dns_pka=yes)
702
703 AC_ARG_ENABLE(dns-cert,
704    AC_HELP_STRING([--disable-dns-cert],
705         [disable the use of CERT records in DNS]),
706    use_dns_cert=$enableval,use_dns_cert=yes)
707
708 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
709    || test x"$use_dns_cert" = xyes; then
710   _dns_save_libs=$LIBS
711   LIBS=""
712   # the double underscore thing is a glibc-ism?
713   AC_SEARCH_LIBS(res_query,resolv bind,,
714                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
715   AC_SEARCH_LIBS(dn_expand,resolv bind,,
716                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
717   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
718                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
719
720   if test x"$have_resolver" != xno ; then
721
722     # Make sure that the BIND 4 resolver interface is workable before
723     # enabling any code that calls it.  At some point I'll rewrite the
724     # code to use the BIND 8 resolver API.
725
726     AC_MSG_CHECKING([whether the resolver is usable])
727     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
728 #include <netinet/in.h>
729 #include <arpa/nameser.h>
730 #include <resolv.h>],
731 [[unsigned char answer[PACKETSZ];
732   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
733   dn_skipname(0,0); 
734   dn_expand(0,0,0,0,0);
735 ]])],have_resolver=yes,have_resolver=no)
736     AC_MSG_RESULT($have_resolver)
737
738     # This is Apple-specific and somewhat bizarre as they changed the
739     # define in bind 8 for some reason.
740
741     if test x"$have_resolver" != xyes ; then
742        AC_MSG_CHECKING(
743              [whether I can make the resolver usable with BIND_8_COMPAT])
744        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
745 #include <sys/types.h>
746 #include <netinet/in.h>
747 #include <arpa/nameser.h>
748 #include <resolv.h>],
749 [[unsigned char answer[PACKETSZ];
750   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
751   dn_skipname(0,0); dn_expand(0,0,0,0,0);
752 ]])],[have_resolver=yes ; need_compat=yes])
753        AC_MSG_RESULT($have_resolver)
754     fi
755   fi
756
757   if test x"$have_resolver" = xyes ; then
758      DNSLIBS=$LIBS
759
760      if test x"$use_dns_srv" = xyes ; then
761         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
762      fi
763
764      if test x"$use_dns_pka" = xyes ; then
765         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
766      fi
767
768      if test x"$use_dns_cert" = xyes ; then
769         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
770      fi
771
772      if test x"$need_compat" = xyes ; then
773         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
774      fi
775   else
776      use_dns_srv=no
777      use_dns_pka=no
778      use_dns_cert=no
779   fi
780
781   LIBS=$_dns_save_libs
782 fi
783
784 AC_SUBST(DNSLIBS)
785
786 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
787
788 #
789 # Check for LDAP
790 #
791 if test "$try_ldap" = yes ; then
792    GNUPG_CHECK_LDAP($NETLIBS)
793 fi
794
795 #
796 # Check for curl.  We fake the curl API if libcurl isn't installed.
797 #
798 LIBCURL_CHECK_CONFIG([yes],,,[fake_curl=yes])
799 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
800
801 # Generic, for us, means curl
802
803 if test x"$try_generic" = xyes ; then
804    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
805 fi
806
807 #
808 # Check for sendmail
809 #
810 # This isn't necessarily sendmail itself, but anything that gives a
811 # sendmail-ish interface to the outside world.  That includes Exim,
812 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
813 if test "$try_mailto" = yes ; then
814   AC_ARG_WITH(mailprog,
815       AC_HELP_STRING([--with-mailprog=NAME],
816                      [use "NAME -t" for mail transport]),
817              ,with_mailprog=yes)
818
819   if test x"$with_mailprog" = xyes ; then
820     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
821     if test "$ac_cv_path_SENDMAIL" ; then
822       GPGKEYS_MAILTO="gpg2keys_mailto"
823     fi
824   elif test x"$with_mailprog" != xno ; then
825     AC_MSG_CHECKING([for a mail transport program])
826     AC_SUBST(SENDMAIL,$with_mailprog)
827     AC_MSG_RESULT($with_mailprog)
828     GPGKEYS_MAILTO="gpg2keys_mailto"
829   fi
830 fi
831
832 AC_SUBST(GPGKEYS_MAILTO)
833
834 #
835 # Construct a printable name of the OS
836 #
837 case "${host}" in
838     *-mingw32*)
839         PRINTABLE_OS_NAME="MingW32"
840         ;;
841     *-*-cygwin*)
842         PRINTABLE_OS_NAME="Cygwin"
843         ;;
844     i?86-emx-os2 | i?86-*-os2*emx )
845         PRINTABLE_OS_NAME="OS/2"
846         ;;
847     i?86-*-msdosdjgpp*)
848         PRINTABLE_OS_NAME="MSDOS/DJGPP"
849         try_dynload=no
850         ;;
851     *-linux*)
852         PRINTABLE_OS_NAME="GNU/Linux"
853         ;;
854     *)
855         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
856         ;;
857 esac
858 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
859                    [A human readable text with the name of the OS])
860
861
862 #
863 # Check for gettext
864 #
865 AM_GNU_GETTEXT_VERSION(0.14.1)
866 if test "$try_gettext" = yes; then
867   AM_GNU_GETTEXT(,[need-ngettext])
868
869   # gettext requires some extra checks.  These really should be part of
870   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
871   # function checks to here.
872
873   AC_CHECK_FUNCS(strchr)
874 else
875   USE_NLS=no
876   USE_INCLUDED_LIBINTL=no
877   BUILD_INCLUDED_LIBINTL=no
878   AC_SUBST(USE_NLS)
879   AC_SUBST(USE_INCLUDED_LIBINTL)
880   AC_SUBST(BUILD_INCLUDED_LIBINTL)
881   AM_PO_SUBDIRS
882 fi
883
884
885 #
886 # SELinux support
887 #
888 if test "$selinux_support" = yes ; then
889   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
890 fi
891
892
893 #
894 # Checks for header files.
895 #
896 AC_HEADER_STDC
897 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
898 AC_CHECK_HEADERS([pwd.h inttypes.h])
899 # Note that we do not check for iconv here because this is done anyway
900 # by the gettext checks and thus it allows us to disable the use of
901 # iconv by using --disable-nls.
902
903
904 #
905 # Checks for typedefs, structures, and compiler characteristics.
906 #
907 AC_C_CONST
908 AC_C_INLINE
909 AC_C_VOLATILE
910 AC_TYPE_SIZE_T
911 AC_TYPE_MODE_T
912 AC_TYPE_SIGNAL
913 AC_DECL_SYS_SIGLIST
914
915 AC_ARG_ENABLE(endian-check,
916               AC_HELP_STRING([--disable-endian-check],
917               [disable the endian check and trust the OS provided macros]),
918               endiancheck=$enableval,endiancheck=yes)
919
920 if test x"$endiancheck" = xyes ; then
921   GNUPG_CHECK_ENDIAN
922 fi
923
924 # fixme: we should get rid of the byte type
925 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
926 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
927 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
928 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
929 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
930
931 AC_CHECK_SIZEOF(unsigned short)
932 AC_CHECK_SIZEOF(unsigned int)
933 AC_CHECK_SIZEOF(unsigned long)
934 AC_CHECK_SIZEOF(unsigned long long)
935 # Ensure that we have UINT64_C before we bother to check for uint64_t
936 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
937 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
938    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
939        uint64_t foo=UINT64_C(42);]),
940      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
941 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
942    AC_CHECK_SIZEOF(uint64_t)
943 fi
944
945 if test "$ac_cv_sizeof_unsigned_short" = "0" \
946    || test "$ac_cv_sizeof_unsigned_int" = "0" \
947    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
948     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
949 fi
950
951 #
952 # fixme: do we really need this - it should be encapsulated in libassuan
953 #
954 GNUPG_SYS_SO_PEERCRED
955
956
957 #
958 # Checks for library functions.
959 #
960 AC_CHECK_DECLS(getpagesize)
961 AC_FUNC_FSEEKO
962 AC_FUNC_VPRINTF
963 AC_FUNC_FORK
964 AC_CHECK_FUNCS([strerror stpcpy strsep strlwr tcgetattr strtoul mmap])
965 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times timegm gmtime_r])
966 AC_CHECK_FUNCS([unsetenv getpwnam getpwuid fcntl ftruncate])
967 AC_CHECK_FUNCS([memmove gettimeofday getrusage setrlimit clock_gettime])
968 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
969 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
970 AC_CHECK_FUNCS([ttyname isascii memrchr rand ftello])
971
972 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
973
974 #
975 # gnulib checks
976 #
977 gl_SOURCE_BASE(gl)
978 gl_M4_BASE(gl/m4)
979 gl_MODULES(setenv strsep mkdtemp vasprintf xsize)
980 gl_INIT
981
982
983 #
984 # These are needed by libjnlib - fixme: we should have macros for them
985 #
986 AC_CHECK_FUNCS([memicmp stpcpy strlwr strtoul memmove stricmp strtol])
987 AC_CHECK_FUNCS([getrusage setrlimit stat setlocale])
988 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen])
989
990
991 #
992 # W32 specific test
993 #
994 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
995
996
997 #
998 # Sanity check regex.  Tests adapted from mutt.
999 # FIXME: We should use the the regex from gnulib
1000 #
1001 AC_MSG_CHECKING([whether regular expression support is requested])
1002 AC_ARG_ENABLE(regex,
1003   AC_HELP_STRING([--disable-regex],
1004     [do not handle regular expressions in trust signatures]),
1005   use_regex=$enableval, use_regex=yes)
1006 AC_MSG_RESULT($use_regex)
1007
1008 if test "$use_regex" = yes ; then
1009   AC_MSG_CHECKING([whether the included regex lib is requested])
1010   AC_ARG_WITH(included-regex,
1011       [  --with-included-regex   use the included GNU regex library],
1012       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1013   AC_MSG_RESULT($gnupg_cv_included_regex)
1014
1015   if test $gnupg_cv_included_regex = no ; then
1016      # Does the system have regex functions at all?
1017      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1018                            gnupg_cv_included_regex=yes)
1019   fi
1020
1021   if test $gnupg_cv_included_regex = no ; then
1022      AC_CACHE_CHECK([whether your system's regexp library is broken],
1023        [gnupg_cv_regex_broken],
1024        AC_TRY_RUN([
1025 #include <unistd.h>
1026 #include <regex.h>
1027 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1028        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1029
1030      if test $gnupg_cv_regex_broken = yes ; then
1031       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1032       gnupg_cv_included_regex=yes
1033      fi
1034   fi
1035
1036   if test $gnupg_cv_included_regex = yes; then
1037      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1038   fi
1039 else
1040   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1041 fi
1042
1043 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1044
1045
1046
1047 #
1048 # Do we have zlib? Must do it here because Solaris failed
1049 # when compiling a conftest (due to the "-lz" from LIBS).
1050 # Note that we combine zlib and bzlib2 in ZLIBS.
1051 #
1052 _cppflags="${CPPFLAGS}"
1053 _ldflags="${LDFLAGS}"
1054 AC_ARG_WITH(zlib,
1055   [  --with-zlib=DIR         use libz in DIR],[
1056     if test -d "$withval"; then
1057       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1058       LDFLAGS="${LDFLAGS} -L$withval/lib"
1059     fi
1060   ])
1061
1062 AC_CHECK_HEADER(zlib.h,
1063       AC_CHECK_LIB(z, deflateInit2_,
1064        ZLIBS="-lz",
1065        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1066        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1067
1068 #
1069 # Check whether we can support bzip2
1070
1071 if test "$use_bzip2" = yes ; then
1072   _cppflags="${CPPFLAGS}"
1073   _ldflags="${LDFLAGS}"
1074   AC_ARG_WITH(bzip2,
1075      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1076       [
1077       if test -d "$withval" ; then
1078         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1079         LDFLAGS="${LDFLAGS} -L$withval/lib"
1080       fi
1081       ],withval="")
1082
1083   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1084   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1085   # woefully out of date.
1086   if test "$withval" != no ; then
1087      AC_CHECK_HEADER(bzlib.h,
1088         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1089           [
1090           have_bz2=yes
1091           ZLIBS="$ZLIBS -lbz2"
1092           AC_DEFINE(HAVE_BZIP2,1,
1093                   [Defined if the bz2 compression library is available])
1094           ],
1095           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1096           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1097   fi
1098 fi
1099 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1100 AC_SUBST(ZLIBS)
1101
1102
1103 # Check for readline support
1104 GNUPG_CHECK_READLINE
1105
1106 # See wether we want to run the long test suite.
1107 AC_ARG_WITH(pkits-tests,
1108     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
1109     [run_pkits_tests=$withval], [run_pkits_tests=no])
1110 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
1111
1112 #
1113 # Allow users to append something to the version string without
1114 # flagging it as development version.  The user version parts is
1115 # considered everything after a dash. 
1116 #
1117 if test "$development_version" != yes; then
1118   changequote(,)dnl
1119   tmp_pat='[a-zA-Z]'
1120   changequote([,])dnl
1121   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1122     development_version=yes
1123   fi
1124 fi
1125 if test "$development_version" = yes; then
1126     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1127             [Defined if this is not a regular release])
1128 fi
1129
1130 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1131
1132 GNUPG_CHECK_GNUMAKE
1133
1134 # Add some extra libs here so that previous tests don't fail for
1135 # mysterious reasons - the final link step should bail out. 
1136 if test "$have_w32_system" = yes; then
1137    W32LIBS="-lwsock32"
1138 fi
1139
1140 AC_SUBST(NETLIBS)
1141 AC_SUBST(W32LIBS)
1142
1143
1144 #
1145 # Setup gcc specific options
1146 #
1147 if test "$GCC" = yes; then
1148     # Note that it is okay to use CFLAGS here because this are just
1149     # warning options and the user should have a chance of overriding
1150     # them.
1151     if test "$USE_MAINTAINER_MODE" = "yes"; then
1152         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1153         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security -Wformat-nonliteral"
1154     else
1155         CFLAGS="$CFLAGS -Wall"
1156     fi
1157
1158     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1159     _gcc_cflags_save=$CFLAGS
1160     CFLAGS="-Wno-pointer-sign"
1161     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1162     AC_MSG_RESULT($_gcc_psign)
1163     CFLAGS=$_gcc_cflags_save;
1164     if test x"$_gcc_psign" = xyes ; then
1165        CFLAGS="$CFLAGS -Wno-pointer-sign"
1166     fi
1167 fi
1168
1169
1170 #
1171 # This is handy for debugging so the compiler doesn't rearrange
1172 # things and eliminate variables.
1173 #
1174 AC_ARG_ENABLE(optimization,
1175    AC_HELP_STRING([--disable-optimization],
1176                   [disable compiler optimization]),
1177                   [if test $enableval = no ; then
1178                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1179                    fi])
1180
1181 #
1182 # For W32 we need to use our Pth emulation code
1183 #
1184 if test "$have_w32_system" = yes; then
1185   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1186 fi
1187
1188
1189 #
1190 # Decide what to build
1191 #
1192 missing_pth=no
1193 if test $have_ksba = no; then
1194   build_gpgsm=no
1195   build_scdaemon=no
1196 fi
1197
1198 build_agent_threaded=""
1199 if test "$build_agent" = "yes"; then
1200   if test $have_pth = no; then
1201      build_agent_threaded="(not multi-threaded)"
1202      missing_pth=yes
1203   fi
1204 fi
1205
1206 build_scdaemon_extra=""
1207 if test "$build_scdaemon" = "yes"; then
1208   tmp=""
1209   if test $have_pth = no; then
1210      build_scdaemon_extra="not multi-threaded"
1211      tmp=", "
1212      missing_pth=yes
1213   fi
1214   if test -n "$build_scdaemon_extra"; then
1215      build_scdaemon_extra="(${build_scdaemon_extra})"
1216   fi
1217 fi
1218
1219
1220 if test "$build_agent_only" = "yes" ; then
1221   build_gpg=no
1222   build_gpgsm=no
1223   build_scdaemon=no
1224 fi
1225
1226
1227 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1228 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1229 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1230 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1231 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1232
1233
1234
1235 #
1236 # Print errors here so that they are visible all
1237 # together and the user can acquire them all together.
1238 #
1239 die=no
1240 if test "$have_gpg_error" = "no"; then
1241    die=yes
1242    AC_MSG_NOTICE([[
1243 ***  
1244 *** You need libgpg-error to build this program.
1245 **  This library is for example available at
1246 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1247 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1248 ***]])
1249 fi
1250 if test "$have_libgcrypt" = "no"; then
1251    die=yes
1252    AC_MSG_NOTICE([[
1253 ***  
1254 *** You need libgcrypt to build this program.
1255 **  This library is for example available at
1256 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1257 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1258 ***]])
1259 fi
1260 if test "$have_libassuan" = "no"; then
1261    die=yes
1262    AC_MSG_NOTICE([[
1263 ***
1264 *** You need libassuan to build this program.
1265 *** This library is for example available at
1266 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1267 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1268 ***]])
1269 fi
1270 if test "$have_ksba" = "no"; then
1271     AC_MSG_NOTICE([[
1272 ***
1273 *** You need libksba to build this program.
1274 *** This library is for example available at
1275 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1276 *** (at least version $NEED_KSBA_VERSION is required).
1277 ***]])
1278 fi
1279 if test "$missing_pth" = "yes"; then
1280     AC_MSG_NOTICE([[
1281 ***
1282 *** It is now required to build with support for the
1283 *** GNU Portable Threads Library (Pth). Please install this
1284 *** library first.  The library is for example available at
1285 ***   ftp://ftp.gnu.org/gnu/pth/
1286 *** On a Debian GNU/Linux system you can install it using 
1287 ***   apt-get install libpth-dev
1288 ***]])
1289    die=yes
1290 fi
1291
1292 if test "$die" = "yes"; then
1293     AC_MSG_ERROR([[
1294 ***
1295 *** Required libraries not found. Please consult the above messages
1296 *** and install them before running configure again.
1297 ***]])
1298 fi
1299
1300
1301
1302 AC_CONFIG_FILES([ m4/Makefile 
1303 Makefile
1304 po/Makefile.in
1305 intl/Makefile
1306 gl/Makefile
1307 jnlib/Makefile
1308 common/Makefile
1309 kbx/Makefile
1310 g10/Makefile
1311 sm/Makefile
1312 agent/Makefile
1313 scd/Makefile
1314 keyserver/Makefile
1315 tools/Makefile
1316 doc/Makefile
1317 tests/Makefile
1318 ])
1319 AC_OUTPUT
1320
1321 #tests/pkits/Makefile
1322
1323
1324
1325
1326 echo "
1327         GnuPG v${VERSION} has been configured as follows:
1328         
1329         Platform:  $PRINTABLE_OS_NAME ($host)
1330
1331         OpenPGP:   $build_gpg
1332         S/MIME:    $build_gpgsm
1333         Agent:     $build_agent $build_agent_threaded
1334         Smartcard: $build_scdaemon $build_scdaemon_extra
1335
1336         Protect tool:      $show_gnupg_protect_tool_pgm
1337         Default agent:     $show_gnupg_agent_pgm
1338         Default pinentry:  $show_gnupg_pinentry_pgm
1339         Default scdaemon:  $show_gnupg_scdaemon_pgm
1340         Default dirmngr:   $show_gnupg_dirmngr_pgm
1341
1342         PKITS based tests: $run_pkits_tests
1343 "
1344