9b0f04cb4948a95e1a5dc401b610bcd0ee107e34
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004, 2005 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.9.3"
24
25 # Remember to change the version number immediately *after* a release.
26 # Uncomment the my_iscvs macro for non-released code.
27 m4_define(my_version, [1.9.21])
28 m4_define(my_iscvs, yes)
29 AC_INIT([gnupg], my_version[]m4_ifdef([my_iscvs], [-cvs[]m4_translit(
30                  [$Revision$],[Ra-z $:])]), [gnupg-devel@gnupg.org])
31 # Set development_version to yes if the minor number is odd or you
32 # feel that the default check for a development version is not
33 # sufficient.
34 development_version=yes
35 NEED_GPG_ERROR_VERSION=1.0
36
37 NEED_LIBGCRYPT_API=1
38 NEED_LIBGCRYPT_VERSION=1.1.94
39
40 NEED_LIBASSUAN_VERSION=0.6.10
41
42 NEED_KSBA_VERSION=0.9.13
43
44
45 PACKAGE=$PACKAGE_NAME
46 PACKAGE_GT=${PACKAGE_NAME}2
47 VERSION=$PACKAGE_VERSION
48
49 AC_CONFIG_AUX_DIR(scripts)
50 AC_CONFIG_SRCDIR(sm/gpgsm.c)
51 AM_CONFIG_HEADER(config.h)
52 AC_CANONICAL_TARGET()
53 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
54
55 AC_GNU_SOURCE
56
57 # Some status variables to give feedback at the end of a configure run
58 have_gpg_error=no
59 have_libgcrypt=no 
60 have_libassuan=no
61 have_ksba=no
62 have_pth=no
63
64 GNUPG_BUILD_PROGRAM(gpg, no)
65 GNUPG_BUILD_PROGRAM(gpgsm, yes)
66 GNUPG_BUILD_PROGRAM(agent, yes)
67 GNUPG_BUILD_PROGRAM(scdaemon, yes)
68 GNUPG_BUILD_PROGRAM(symcryptrun, no)
69
70
71 AC_SUBST(PACKAGE)
72 AC_SUBST(PACKAGE_GT)
73 AC_SUBST(VERSION)
74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
76                                 [Name of this package for gettext])
77 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
78 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
79                                         [Bug report address])
80 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
81                                        [Required version of Libgcrypt])
82 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
83                                        [Required version of Libksba])
84
85
86
87 # The default is to use the modules from this package and the few
88 # other packages in a standard place; i.e where this package gets
89 # installed.  With these options it is possible to override these
90 # ${prefix} depended values with fixed paths, which can't be replaced
91 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
92 AC_ARG_WITH(agent-pgm,
93     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
94           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
95 AC_SUBST(GNUPG_AGENT_PGM)
96 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
97 show_gnupg_agent_pgm="(default)"
98 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
99
100 AC_ARG_WITH(pinentry-pgm,
101     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
102           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
103 AC_SUBST(GNUPG_PINENTRY_PGM)
104 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
105 show_gnupg_pinentry_pgm="(default)"
106 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
107
108
109 AC_ARG_WITH(scdaemon-pgm,
110     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
111           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
112 AC_SUBST(GNUPG_SCDAEMON_PGM)
113 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
114 show_gnupg_scdaemon_pgm="(default)"
115 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
116
117
118 AC_ARG_WITH(dirmngr-pgm,
119     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
120           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
121 AC_SUBST(GNUPG_DIRMNGR_PGM)
122 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
123 show_gnupg_dirmngr_pgm="(default)"
124 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
125
126 AC_ARG_WITH(protect-tool-pgm,
127     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
128           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
129 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
130 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
131 show_gnupg_protect_tool_pgm="(default)"
132 test -n "$GNUPG_PROTECT_TOOL_PGM" \
133       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
134
135
136
137 # Some folks want to use only the agent form this packet.  Make it
138 # easier for them by providing the configure option
139 # --enable-only-agent.
140 AC_ARG_ENABLE(agent-only,
141     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
142     build_agent_only=$enableval)
143
144
145 # Configure option to allow or disallow execution of external
146 # programs, like a photo viewer.
147 AC_MSG_CHECKING([whether to enable external program execution])
148 AC_ARG_ENABLE(exec,
149     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
150     use_exec=$enableval)
151 AC_MSG_RESULT($use_exec)
152 if test "$use_exec" = no ; then
153     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
154 fi
155
156 if test "$use_exec" = yes ; then
157   AC_MSG_CHECKING([whether to enable photo ID viewing])
158   AC_ARG_ENABLE(photo-viewers,
159       [  --disable-photo-viewers disable photo ID viewers],
160       [if test "$enableval" = no ; then
161          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
162       fi],enableval=yes)
163   gnupg_cv_enable_photo_viewers=$enableval
164   AC_MSG_RESULT($enableval)
165
166   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
167     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
168     AC_ARG_WITH(photo-viewer,
169         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
170         [if test "$withval" = yes ; then
171            withval=no
172         elif test "$withval" != no ; then
173            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
174                             [if set, restrict photo-viewer to this])
175         fi],withval=no)
176     AC_MSG_RESULT($withval)
177   fi
178
179   AC_MSG_CHECKING([whether to enable external keyserver helpers])
180   AC_ARG_ENABLE(keyserver-helpers,
181       [  --disable-keyserver-helpers  disable all external keyserver support],
182       [if test "$enableval" = no ; then
183          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
184                   [define to disable keyserver helpers])
185       fi],enableval=yes)
186   gnupg_cv_enable_keyserver_helpers=$enableval
187   AC_MSG_RESULT($enableval)
188
189   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
190     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
191     AC_ARG_ENABLE(ldap,
192     [  --disable-ldap          disable LDAP keyserver interface],
193         try_ldap=$enableval, try_ldap=yes)
194     AC_MSG_RESULT($try_ldap)
195
196     AC_MSG_CHECKING([whether HKP keyserver support is requested])
197     AC_ARG_ENABLE(hkp,
198     [  --disable-hkp           disable HKP keyserver interface],
199         try_hkp=$enableval, try_hkp=yes)
200     AC_MSG_RESULT($try_hkp)
201
202     if test "$try_hkp" = yes ; then
203       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
204     fi
205
206     AC_MSG_CHECKING([whether email keyserver support is requested])
207     AC_ARG_ENABLE(mailto,
208     [  --disable-mailto        disable email keyserver interface],
209         try_mailto=$enableval, try_mailto=yes)
210     AC_MSG_RESULT($try_mailto)
211     fi
212
213     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
214     AC_ARG_ENABLE(keyserver-path,
215         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
216         [if test "$enableval" = no ; then
217          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
218         fi],enableval=yes)
219     AC_MSG_RESULT($enableval)
220   fi
221
222 dnl
223 dnl Check whether we want to use Linux capabilities
224 dnl
225 AC_MSG_CHECKING([whether use of capabilities is requested])
226 AC_ARG_WITH(capabilities,
227     [  --with-capabilities     use linux capabilities [default=no]],
228 [use_capabilities="$withval"],[use_capabilities=no])
229 AC_MSG_RESULT($use_capabilities)
230
231
232 AH_BOTTOM([
233 /* Some global constants. */
234 #ifdef HAVE_DRIVE_LETTERS
235 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
236 #elif defined(__VMS)
237 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
238 #else
239 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
240 #endif 
241 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
242
243 /* Tell libgcrypt not to use its own libgpg-error implementation. */
244 #define USE_LIBGPG_ERROR 1
245
246 /* This is the major version number of GnuPG so that
247    source included files can test for this.  Note, that\
248    we use 2 here even for GnuPG 1.9.x. */
249 #define GNUPG_MAJOR_VERSION 2
250
251 /* Now to separate file name parts.
252    Please note that the string version must not contain more
253    than one character because the code assumes strlen()==1 */
254 #ifdef HAVE_DOSISH_SYSTEM
255 #define DIRSEP_C '\\'
256 #define DIRSEP_S "\\"
257 #define EXTSEP_C '.'
258 #define EXTSEP_S "."
259 #define PATHSEP_C ';'
260 #define PATHSEP_S ";"
261 #define EXEEXT_S ".exe"
262 #else
263 #define DIRSEP_C '/'
264 #define DIRSEP_S "/"
265 #define EXTSEP_C '.'
266 #define EXTSEP_S "."
267 #define PATHSEP_C ':'
268 #define PATHSEP_S ":"
269 #define EXEEXT_S ""
270 #endif
271
272 /* This is the same as VERSION, but should be overridden if the
273    platform cannot handle things like dots '.' in filenames. Set
274    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
275    uses for dots and dashes. */
276 #define SAFE_VERSION VERSION
277 #define SAFE_VERSION_DOT  '.'
278 #define SAFE_VERSION_DASH '-'
279
280 /* For some systems (DOS currently), we hardcode the path here.  For
281    POSIX systems the values are constructed by the Makefiles, so that
282    the values may be overridden by the make invocations; this is to
283    comply with the GNU coding standards. */
284 #ifdef HAVE_DRIVE_LETTERS
285 #define GNUPG_BINDIR      "c:\\gnupg"
286 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
287 #define GNUPG_LIBDIR      "c:\\gnupg"
288 #define GNUPG_DATADIR     "c:\\gnupg"
289 #endif
290
291 /* Setup the hardwired names of modules. */
292 #ifndef GNUPG_DEFAULT_AGENT
293 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
294 #endif
295 #ifndef GNUPG_DEFAULT_PINENTRY
296 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
297 #endif
298 #ifndef GNUPG_DEFAULT_SCDAEMON
299 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
300 #endif
301 #ifndef GNUPG_DEFAULT_DIRMNGR
302 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
303 #endif
304 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
305 #define GNUPG_DEFAULT_PROTECT_TOOL \
306                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
307 #endif
308
309
310 /* Derive some other constants. */
311 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
312 #define EXEC_TEMPFILE_ONLY
313 #endif
314
315 /* Temporary hacks to avoid requring a libgpg-error update. */
316 #if !HAVE_DECL_GPG_ERR_LOCKED
317 #define GPG_ERR_LOCKED  173
318 #endif
319
320 ])
321
322 AM_MAINTAINER_MODE
323
324 # Checks for programs.
325 AC_PROG_MAKE_SET
326 AM_SANITY_CHECK
327 missing_dir=`cd $ac_aux_dir && pwd`
328 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
329 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
330 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
331 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
332 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
333 AC_PROG_AWK
334 AC_PROG_CC
335 AC_PROG_CPP
336 AC_PROG_INSTALL
337 AC_PROG_LN_S
338 AC_PROG_MAKE_SET
339 AC_PROG_RANLIB
340 AC_CHECK_TOOL(AR, ar, :)
341 AC_PATH_PROG(PERL,"perl")
342 AC_ISC_POSIX
343 gl_EARLY
344 AC_SYS_LARGEFILE
345 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
346 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
347 GNUPG_CHECK_FAQPROG
348 GNUPG_CHECK_DOCBOOK_TO_TEXI
349
350
351 try_gettext=yes
352 have_dosish_system=no
353 have_w32_system=no
354 case "${host}" in
355     *-mingw32*)
356         # special stuff for Windoze NT
357         ac_cv_have_dev_random=no
358         AC_DEFINE(USE_ONLY_8DOT3,1,
359                   [set this to limit filenames to the 8.3 format])
360         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
361                   [defined if we must run on a stupid file system])
362         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
363                   [because the Unix gettext has too much overhead on
364                    MingW32 systems and these systems lack Posix functions,
365                    we use a simplified version of gettext])
366         have_dosish_system=yes
367         have_w32_system=yes
368         try_gettext="no"
369         ;;
370     i?86-emx-os2 | i?86-*-os2*emx )
371         # OS/2 with the EMX environment
372         ac_cv_have_dev_random=no
373         AC_DEFINE(HAVE_DRIVE_LETTERS)
374         have_dosish_system=yes
375         try_gettext="no"
376         ;;
377
378     i?86-*-msdosdjgpp*)
379         # DOS with the DJGPP environment
380         ac_cv_have_dev_random=no
381         AC_DEFINE(HAVE_DRIVE_LETTERS)
382         have_dosish_system=yes
383         try_gettext="no"
384         ;;
385
386     *-*-freebsd*)
387        # FreeBSD
388        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
389        LDFLAGS="$LDFLAGS -L/usr/local/lib"
390        ;;
391
392     *-*-hpux*)
393         if test -z "$GCC" ; then
394             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
395         fi
396         ;;
397     *-dec-osf4*)
398         if test -z "$GCC" ; then
399             # Suppress all warnings
400             # to get rid of the unsigned/signed char mismatch warnings.
401             CFLAGS="$CFLAGS -w"
402         fi
403         ;;
404     *-dec-osf5*)
405         if test -z "$GCC" ; then
406             # Use the newer compiler `-msg_disable ptrmismatch' to
407             # get rid of the unsigned/signed char mismatch warnings.
408             # Using this may hide other pointer mismatch warnings, but
409             # it at least lets other warning classes through
410             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
411         fi
412         ;;
413     m68k-atari-mint)
414         ;;
415     *)
416        ;;
417 esac
418
419 if test "$have_dosish_system" = yes; then
420    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
421              [Defined if we run on some of the PCDOS like systems 
422               (DOS, Windoze. OS/2) with special properties like
423               no file modes])
424 fi
425 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
426
427 if test "$have_w32_system" = yes; then
428    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
429 fi
430 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
431
432
433
434 #
435 # Checks for libraries.
436 #
437
438
439 #
440 # libgpg-error is a library with error codes shared between GnuPG
441 # related projects.
442 #
443 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
444                   have_gpg_error=yes,have_gpg_error=no)
445 _tmp_gpg_error_save_cflags="$CFLAGS"
446 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
447 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
448 CFLAGS="${_tmp_gpg_error_save_cflags}"
449
450
451 #
452 # Libgcrypt is our generic crypto library
453 #
454 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
455         have_libgcrypt=yes,have_libgcrypt=no)
456
457
458 #
459 # libassuan is used for IPC
460 #
461 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
462                   have_libassuan=yes,have_libassuan=no)
463
464
465 #
466 # libksba is our X.509 support library
467 #
468 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
469
470 #
471 # libusb allows us to use the integrated CCID smartcard reader driver.
472 #
473 AC_CHECK_LIB(usb, usb_bulk_write,
474               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
475                 AC_DEFINE(HAVE_LIBUSB,1,
476                          [defined if libusb is available])
477              ])
478 AC_SUBST(LIBUSB_LIBS)
479 AC_CHECK_FUNCS(usb_create_match)
480
481 #
482 # Check wether it is necessary to link against libdl.
483 #
484 LIBS=""
485 AC_SEARCH_LIBS(dlopen, c dl,,,)
486 DL_LIBS=$LIBS
487 AC_SUBST(DL_LIBS)
488
489 #
490 # Checks for symcryptrun:
491 #
492
493 # libutil has openpty() and login_tty().
494 AC_CHECK_LIB(util, openpty,
495               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
496                 AC_DEFINE(HAVE_LIBUTIL,1,
497                          [defined if libutil is available])
498              ])
499 AC_SUBST(LIBUTIL_LIBS)
500
501 # shred is used to clean temporary plain text files.
502 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
503 AC_DEFINE_UNQUOTED(SHRED,
504         "${SHRED}", [defines the filename of the shred program])
505
506
507 #
508 # Check whether the (highly desirable) GNU Pth library is available
509 # Note, that we include a Pth emulation for W32.
510 #
511 AC_ARG_WITH(pth-prefix,
512             AC_HELP_STRING([--with-pth-prefix=PFX],
513                            [prefix where GNU Pth is installed (optional)]),
514      pth_config_prefix="$withval", pth_config_prefix="")
515 if test x$pth_config_prefix != x ; then
516    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
517 fi
518 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
519 if test "$have_w32_system" = no; then
520  if test "$PTH_CONFIG" = "no"; then
521     AC_MSG_WARN([[
522 ***
523 *** To support concurrent access to the gpg-agent and the SCdaemon
524 *** we need the support of the GNU Portable Threads Library.
525 *** Download it from ftp://ftp.gnu.org/gnu/pth/
526 *** On a Debian GNU/Linux system you might want to try 
527 ***   apt-get install libpth-dev
528 ***]])
529  else
530   GNUPG_PTH_VERSION_CHECK(1.3.7)
531   if test $have_pth = yes; then      
532      PTH_CFLAGS=`$PTH_CONFIG --cflags`
533      PTH_LIBS=`$PTH_CONFIG --ldflags`
534      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
535      AC_DEFINE(USE_GNU_PTH, 1,
536               [Defined if the GNU Portable Thread Library should be used])
537      AC_DEFINE(HAVE_PTH, 1,
538               [Defined if the GNU Pth is available])
539   fi
540  fi
541 else 
542  have_pth=yes
543  PTH_CFLAGS=""
544  PTH_LIBS=""
545  AC_DEFINE(USE_GNU_PTH, 1)
546  AC_DEFINE(HAVE_PTH, 1)
547 fi
548 AC_SUBST(PTH_CFLAGS)
549 AC_SUBST(PTH_LIBS)
550
551
552 dnl Must check for network library requirements before doing link tests
553 dnl for ldap, for example. If ldap libs are static (or dynamic and without
554 dnl ELF runtime link paths), then link will fail and LDAP support won't
555 dnl be detected.
556
557 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
558         [NETLIBS="-lnsl $NETLIBS"]))
559 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
560         [NETLIBS="-lsocket $NETLIBS"]))
561
562 dnl Now try for the resolver functions so we can use DNS SRV
563
564 AC_ARG_ENABLE(dns-srv,
565    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
566    use_dns_srv=$enableval,use_dns_srv=yes)
567
568 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
569   _srv_save_libs=$LIBS
570   LIBS=""
571   # the double underscore thing is a glibc-ism?
572   AC_SEARCH_LIBS(res_query,resolv bind,,
573                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
574   AC_SEARCH_LIBS(dn_expand,resolv bind,,
575                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
576   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
577                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
578
579   if test x"$use_dns_srv" = xyes ; then
580      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
581      SRVLIBS=$LIBS
582   else
583      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
584   fi
585   LIBS=$_srv_save_libs
586 fi
587
588 AC_SUBST(SRVLIBS)
589
590 # Try and link a LDAP test program to weed out unusable LDAP
591 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
592 # general is terrible with creating weird dependencies.  If all else
593 # fails, the user can play guess-the-dependency by using something
594 # like ./configure LDAPLIBS="-Lfoo -lbar"
595
596 if test "$try_ldap" = yes ; then
597   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
598     _ldap_save_libs=$LIBS
599     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
600
601     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
602     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
603                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
604     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
605
606     if test $gnupg_cv_func_ldap_init = no; then
607       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
608       AC_TRY_LINK([#include <lber.h>
609 #include <ldap.h>],[ldap_open("foobar",1234);],
610          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
611       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
612     fi
613
614     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
615        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
616     fi
617
618     if test "$gnupg_cv_func_ldap_init" = yes || \
619         test "$gnupg_cv_func_ldaplber_init" = yes ; then
620        LDAPLIBS=$MY_LDAPLIBS
621        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
622
623        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
624
625        if test "$gnupg_cv_func_ldap_init" = yes ; then
626           AC_TRY_LINK([#include <ldap.h>],
627              [ldap_get_option((void *)0,0,(void *)0);],
628              [gnupg_cv_func_ldap_get_option=yes],
629              [gnupg_cv_func_ldap_get_option=no])
630         else
631           AC_TRY_LINK([#include <lber.h>
632 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
633              [gnupg_cv_func_ldap_get_option=yes],
634              [gnupg_cv_func_ldap_get_option=no])
635        fi
636
637        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
638
639        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
640           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
641        else
642           AC_MSG_CHECKING([whether LDAP supports ld_errno])
643
644           if test "$gnupg_cv_func_ldap_init" = yes ; then
645             AC_TRY_COMPILE([#include <ldap.h>],
646                [LDAP *ldap; ldap->ld_errno;],
647                [gnupg_cv_func_ldap_ld_errno=yes],
648                [gnupg_cv_func_ldap_ld_errno=no])
649            else
650             AC_TRY_LINK([#include <lber.h>
651 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
652                [gnupg_cv_func_ldap_ld_errno=yes],
653                [gnupg_cv_func_ldap_ld_errno=no])
654           fi
655
656           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
657
658           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
659              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
660           fi
661        fi
662     fi
663
664     LIBS=$_ldap_save_libs
665
666     if test "$GPGKEYS_LDAP" != "" ; then break; fi
667   done
668 fi
669
670 AC_SUBST(GPGKEYS_LDAP)
671 AC_SUBST(LDAPLIBS)
672
673 dnl This isn't necessarily sendmail itself, but anything that gives a
674 dnl sendmail-ish interface to the outside world.  That includes qmail,
675 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
676
677 if test "$try_mailto" = yes ; then
678   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
679
680   if test "$with_mailprog" = yes ; then
681     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
682     if test "$ac_cv_path_SENDMAIL" ; then
683       GPGKEYS_MAILTO="gpgkeys_mailto"
684     fi
685   elif test "$with_mailprog" != no ; then
686     AC_MSG_CHECKING([for a mail transport program])
687     AC_SUBST(SENDMAIL,$with_mailprog)
688     AC_MSG_RESULT($with_mailprog)
689     GPGKEYS_MAILTO="gpgkeys_mailto"
690   fi
691 fi
692
693 AC_SUBST(GPGKEYS_MAILTO)
694
695 case "${host}" in
696     *-mingw32*)
697         PRINTABLE_OS_NAME="MingW32"
698         ;;
699     *-*-cygwin*)
700         PRINTABLE_OS_NAME="Cygwin"
701         ;;
702     i?86-emx-os2 | i?86-*-os2*emx )
703         PRINTABLE_OS_NAME="OS/2"
704         ;;
705     i?86-*-msdosdjgpp*)
706         PRINTABLE_OS_NAME="MSDOS/DJGPP"
707         try_dynload=no
708         ;;
709     *-linux*)
710         PRINTABLE_OS_NAME="GNU/Linux"
711         ;;
712     *)
713         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
714         ;;
715 esac
716 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
717                    [A human readable text with the name of the OS])
718
719
720 AM_GNU_GETTEXT_VERSION(0.14.1)
721 if test "$try_gettext" = yes; then
722   AM_GNU_GETTEXT(,[need-ngettext])
723
724   # gettext requires some extra checks.  These really should be part of
725   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
726   # function checks to here.
727
728   AC_CHECK_FUNCS(strchr)
729 else
730   USE_NLS=no
731   USE_INCLUDED_LIBINTL=no
732   BUILD_INCLUDED_LIBINTL=no
733   AC_SUBST(USE_NLS)
734   AC_SUBST(USE_INCLUDED_LIBINTL)
735   AC_SUBST(BUILD_INCLUDED_LIBINTL)
736 fi
737
738 # Checks for header files.
739 AC_HEADER_STDC
740 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
741
742 # Checks for typedefs, structures, and compiler characteristics.
743 AC_C_CONST
744 AC_C_INLINE
745 AC_TYPE_SIZE_T
746 AC_TYPE_SIGNAL
747 AC_DECL_SYS_SIGLIST
748
749 GNUPG_CHECK_ENDIAN
750
751 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
752 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
753 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
754 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
755 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
756
757 AC_CHECK_SIZEOF(unsigned short)
758 AC_CHECK_SIZEOF(unsigned int)
759 AC_CHECK_SIZEOF(unsigned long)
760 AC_CHECK_SIZEOF(unsigned long long)
761 # Ensure that we have UINT64_C before we bother to check for uint64_t
762 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
763 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
764    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
765 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
766 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
767    AC_CHECK_SIZEOF(uint64_t)
768 fi
769  
770
771
772
773 if test "$ac_cv_sizeof_unsigned_short" = "0" \
774    || test "$ac_cv_sizeof_unsigned_int" = "0" \
775    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
776     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
777 fi
778
779 dnl Do we have any 64-bit data types?
780 if test "$ac_cv_sizeof_unsigned_int" != "8" \
781    && test "$ac_cv_sizeof_unsigned_long" != "8" \
782    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
783    && test "$ac_cv_sizeof_uint64_t" != "8"; then
784     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
785 else
786   if test x"$use_sha512" = xyes ; then
787      AC_SUBST(SHA512_O,sha512.o)
788      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
789   fi
790 fi
791
792 # fixme: do we really need this - it should be encapsulated in libassuan
793 GNUPG_SYS_SO_PEERCRED
794
795 # Checks for library functions.
796 AC_FUNC_FSEEKO
797 AC_FUNC_VPRINTF
798 AC_FUNC_FORK
799 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
800 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
801 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
802 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
803 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
804 AC_CHECK_FUNCS(fseeko ftello ttyname isascii)
805
806 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
807
808 # gnulib checks
809 gl_SOURCE_BASE(gl)
810 gl_M4_BASE(gl/m4)
811 gl_MODULES(setenv strsep mkdtemp vasprintf xsize)
812 gl_INIT
813
814 # These are needed by libjnlib - fixme: we should have macros for them
815 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
816 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
817 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
818
819
820 #
821 # check for gethrtime and run a testprogram to see whether
822 # it is broken.  It has been reported that some Solaris and HP UX systems 
823 # raise an SIGILL
824 #
825 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
826 #
827 AC_CACHE_CHECK([for gethrtime], 
828                [gnupg_cv_func_gethrtime],
829                [AC_TRY_LINK([#include <sys/times.h>],[
830                    hrtime_t tv;
831                    tv = gethrtime();
832                  ],
833                  [gnupg_cv_func_gethrtime=yes],
834                  [gnupg_cv_func_gethrtime=no])
835                ])
836 if test $gnupg_cv_func_gethrtime = yes; then
837      AC_DEFINE([HAVE_GETHRTIME], 1,
838                [Define if you have the `gethrtime(2)' function.])
839      AC_CACHE_CHECK([whether gethrtime is broken], 
840                [gnupg_cv_func_broken_gethrtime],
841                [AC_TRY_RUN([
842                    #include <sys/times.h>
843                    int main () {
844                    hrtime_t tv;
845                    tv = gethrtime(); 
846                  }
847                  ],
848                  [gnupg_cv_func_broken_gethrtime=no],
849                  [gnupg_cv_func_broken_gethrtime=yes],
850                  [gnupg_cv_func_broken_gethrtime=assume-no])
851                 ])
852     if test $gnupg_cv_func_broken_gethrtime = yes; then
853       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
854       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
855     fi
856 fi
857      
858
859 GNUPG_CHECK_MLOCK
860 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
861
862 dnl
863 dnl Check whether we can use Linux capabilities as requested
864 dnl
865 #  fixme: Still required?
866 #
867 if test "$use_capabilities" = "yes" ; then
868 use_capabilities=no
869 AC_CHECK_HEADERS(sys/capability.h)
870 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
871   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
872   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
873      AC_DEFINE(USE_CAPABILITIES,1,
874                [define if capabilities should be used])
875      AC_SUBST(CAPLIBS,"-lcap")
876      use_capabilities=yes
877   fi
878 fi
879 if test "$use_capabilities" = "no" ; then
880     AC_MSG_WARN([[
881 ***
882 *** The use of capabilities on this system is not possible.
883 *** You need a recent Linux kernel and some patches:
884 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
885 ***   fcap-module-990613.tar.gz     (kernel module)
886 ***   libcap-1.92.tar.gz            (user mode library and utilities)
887 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
888 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
889 ***]])
890 fi
891 fi
892
893
894 # Sanity check regex.  Tests adapted from mutt.
895
896 AC_MSG_CHECKING([whether regular expression support is requested])
897 AC_ARG_ENABLE(regex,
898 [  --disable-regex         do not handle regular expressions in trust sigs],
899      use_regex=$enableval, use_regex=yes)
900 AC_MSG_RESULT($use_regex)
901
902 if test "$use_regex" = yes ; then
903   AC_MSG_CHECKING([whether the included regex lib is requested])
904   AC_ARG_WITH(included-regex,
905       [  --with-included-regex   use the included GNU regex library],
906       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
907   AC_MSG_RESULT($gnupg_cv_included_regex)
908
909   if test $gnupg_cv_included_regex = no ; then
910      # Does the system have regex functions at all?
911      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
912                            gnupg_cv_included_regex=yes)
913   fi
914
915   if test $gnupg_cv_included_regex = no ; then
916      AC_CACHE_CHECK([whether your system's regexp library is broken],
917        [gnupg_cv_regex_broken],
918        AC_TRY_RUN([
919 #include <unistd.h>
920 #include <regex.h>
921 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
922        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
923
924      if test $gnupg_cv_regex_broken = yes ; then
925       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
926       gnupg_cv_included_regex=yes
927      fi
928   fi
929
930   if test $gnupg_cv_included_regex = yes; then
931      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
932      AC_SUBST(REGEX_O,regex.o)
933   fi
934 else
935
936   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
937 fi
938
939 dnl Do we have zlib? Must do it here because Solaris failed
940 dnl when compiling a conftest (due to the "-lz" from LIBS).
941 _cppflags="${CPPFLAGS}"
942 _ldflags="${LDFLAGS}"
943
944 AC_ARG_WITH(zlib,
945   [  --with-zlib=DIR         use libz in DIR],[
946     if test -d "$withval"; then
947       CPPFLAGS="${CPPFLAGS} -I$withval/include"
948       LDFLAGS="${LDFLAGS} -L$withval/lib"
949     fi
950   ])
951
952 AC_CHECK_HEADER(zlib.h,
953       AC_CHECK_LIB(z, deflateInit2_,
954        LIBS="$LIBS -lz",
955        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
956        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
957  
958
959
960 # See wether we want to run the long test suite.
961 AC_ARG_WITH(pkits-tests,
962     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
963     [run_pkits_tests=$withval], [run_pkits_tests=no])
964 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
965
966
967 # Allow users to append something to the version string without
968 # flagging it as development version.  The user version parts is
969 # considered everything after a dash. 
970 if test "$development_version" != yes; then
971   changequote(,)dnl
972   tmp_pat='[a-zA-Z]'
973   changequote([,])dnl
974   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
975     development_version=yes
976   fi
977 fi
978 if test "$development_version" = yes; then
979     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
980             [Defined if this is not a regular release])
981 fi
982
983 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
984
985 GNUPG_CHECK_GNUMAKE
986
987 # Add some extra libs here so that previous tests don't fail for
988 # mysterious reasons - the final link step should bail out. 
989 if test "$have_w32_system" = yes; then
990    W32LIBS="-lwsock32"
991 fi
992
993
994 if test "$GCC" = yes; then
995     if test "$USE_MAINTAINER_MODE" = "yes"; then
996         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
997         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security"
998     else
999         CFLAGS="$CFLAGS -Wall"
1000     fi
1001 fi
1002
1003 AC_SUBST(NETLIBS)
1004 AC_SUBST(W32LIBS)
1005
1006
1007 # We use jnlib, so tell other modules about it
1008 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1009           [Defined if jnlib style logging functions are available])
1010
1011 # For W32 we need to use our Pth emulation code
1012 if test "$have_w32_system" = yes; then
1013   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1014 fi
1015
1016
1017 #
1018 # Decide what to build
1019 #
1020 missing_pth=no
1021 if test $have_ksba = no; then
1022   build_gpgsm=no
1023   build_scdaemon=no
1024 fi
1025
1026 build_agent_threaded=""
1027 if test "$build_agent" = "yes"; then
1028   if test $have_pth = no; then
1029      build_agent_threaded="(not multi-threaded)"
1030      missing_pth=yes
1031   fi
1032 fi
1033
1034 build_scdaemon_extra=""
1035 if test "$build_scdaemon" = "yes"; then
1036   tmp=""
1037   if test $have_pth = no; then
1038      build_scdaemon_extra="not multi-threaded"
1039      tmp=", "
1040      missing_pth=yes
1041   fi
1042   if test -n "$build_scdaemon_extra"; then
1043      build_scdaemon_extra="(${build_scdaemon_extra})"
1044   fi
1045 fi
1046
1047
1048 if test "$build_agent_only" = "yes" ; then
1049   build_gpg=no
1050   build_gpgsm=no
1051   build_scdaemon=no
1052 fi
1053
1054
1055 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1056 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1057 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1058 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1059 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1060
1061
1062
1063 #
1064 # Print errors here so that they are visible all
1065 # together and the user can acquire them all together.
1066 #
1067 die=no
1068 if test "$have_gpg_error" = "no"; then
1069    die=yes
1070    AC_MSG_NOTICE([[
1071 ***  
1072 *** You need libgpg-error to build this program.
1073 **  This library is for example available at
1074 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1075 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1076 ***]])
1077 fi
1078 if test "$have_libgcrypt" = "no"; then
1079    die=yes
1080    AC_MSG_NOTICE([[
1081 ***  
1082 *** You need libgcrypt to build this program.
1083 **  This library is for example available at
1084 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1085 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1086 ***]])
1087 fi
1088 if test "$have_libassuan" = "no"; then
1089    die=yes
1090    AC_MSG_NOTICE([[
1091 ***
1092 *** You need libassuan to build this program.
1093 *** This library is for example available at
1094 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1095 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1096 ***]])
1097 fi
1098 if test "$have_ksba" = "no"; then
1099     AC_MSG_NOTICE([[
1100 ***
1101 *** You need libksba to build this program.
1102 *** This library is for example available at
1103 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1104 *** (at least version $NEED_KSBA_VERSION is required).
1105 ***]])
1106 fi
1107 if test "$missing_pth" = "yes"; then
1108     AC_MSG_NOTICE([[
1109 ***
1110 *** It is now required to build with support for the
1111 *** GNU Portable Threads Library (Pth). Please install this
1112 *** library first.  The library is for example available at
1113 ***   ftp://ftp.gnu.org/gnu/pth/
1114 *** On a Debian GNU/Linux system you can install it using 
1115 ***   apt-get install libpth-dev
1116 ***]])
1117    die=yes
1118 fi
1119
1120 if test "$die" = "yes"; then
1121     AC_MSG_ERROR([[
1122 ***
1123 *** Required libraries not found. Please consult the above messages
1124 *** and install them before running configure again.
1125 ***]])
1126 fi
1127
1128
1129
1130 AC_CONFIG_FILES([ m4/Makefile 
1131 Makefile
1132 po/Makefile.in
1133 intl/Makefile
1134 gl/Makefile
1135 jnlib/Makefile
1136 common/Makefile
1137 kbx/Makefile
1138 g10/Makefile
1139 sm/Makefile
1140 agent/Makefile
1141 scd/Makefile
1142 tools/Makefile
1143 doc/Makefile
1144 tests/Makefile
1145 ])
1146 AC_OUTPUT
1147
1148 #tests/pkits/Makefile
1149
1150
1151
1152
1153 echo "
1154         GnuPG v${VERSION} has been configured as follows:
1155         
1156         Platform:  $PRINTABLE_OS_NAME ($host)
1157
1158         OpenPGP:   $build_gpg
1159         S/MIME:    $build_gpgsm
1160         Agent:     $build_agent $build_agent_threaded
1161         Smartcard: $build_scdaemon $build_scdaemon_extra
1162
1163         Protect tool:      $show_gnupg_protect_tool_pgm
1164         Default agent:     $show_gnupg_agent_pgm
1165         Default pinentry:  $show_gnupg_pinentry_pgm
1166         Default scdaemon:  $show_gnupg_scdaemon_pgm
1167         Default dirmngr:   $show_gnupg_dirmngr_pgm
1168
1169         PKITS based tests: $run_pkits_tests
1170 "
1171