bd64976be22c475cf464525a9b9e1f17e57d9942
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.7.6"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.7-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=0.7
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.4
38
39 NEED_KSBA_VERSION=0.9.4
40
41 NEED_OPENSC_VERSION=0.8.0
42
43
44
45 PACKAGE=$PACKAGE_NAME
46 VERSION=$PACKAGE_VERSION
47
48 AC_CONFIG_AUX_DIR(scripts)
49 AC_CONFIG_SRCDIR(sm/gpgsm.c)
50 AM_CONFIG_HEADER(config.h)
51 AC_CANONICAL_TARGET()
52 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
53
54 AC_GNU_SOURCE
55
56 # Some status variables to give feedback at the end of a configure run
57 have_gpg_error=no
58 have_libgcrypt=no 
59 have_libassuan=no
60 have_ksba=no
61 have_opensc=no
62 have_pth=no
63
64 GNUPG_BUILD_PROGRAM(gpg, yes)
65 GNUPG_BUILD_PROGRAM(gpgsm, yes)
66 GNUPG_BUILD_PROGRAM(agent, yes)
67 GNUPG_BUILD_PROGRAM(scdaemon, yes)
68
69
70 AC_SUBST(PACKAGE)
71 AC_SUBST(VERSION)
72 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
73 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
74 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
75                                         [Bug report address])
76 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
77                                        [Required version of Libgcrypt])
78 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
79                                        [Required version of Libksba])
80
81
82
83 # The default is to use the modules from this package and the few
84 # other packages in a standard place; i.e where this package gets
85 # installed.  With these options it is possible to override these
86 # ${prefix} depended values with fixed paths, which can't be replaced
87 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
88 AC_ARG_WITH(agent-pgm,
89     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
90           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
91 AC_SUBST(GNUPG_AGENT_PGM)
92 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
93 show_gnupg_agent_pgm="(default)"
94 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
95
96 AC_ARG_WITH(pinentry-pgm,
97     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
98           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
99 AC_SUBST(GNUPG_PINENTRY_PGM)
100 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
101 show_gnupg_pinentry_pgm="(default)"
102 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
103
104
105 AC_ARG_WITH(scdaemon-pgm,
106     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
107           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
108 AC_SUBST(GNUPG_SCDAEMON_PGM)
109 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
110 show_gnupg_scdaemon_pgm="(default)"
111 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
112
113
114 AC_ARG_WITH(dirmngr-pgm,
115     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
116           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
117 AC_SUBST(GNUPG_DIRMNGR_PGM)
118 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
119 show_gnupg_dirmngr_pgm="(default)"
120 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
121
122 AC_ARG_WITH(protect-tool-pgm,
123     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
124           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
125 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
126 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
127 show_gnupg_protect_tool_pgm="(default)"
128 test -n "$GNUPG_PROTECT_TOOL_PGM" \
129       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
130
131
132
133 # Configure option to allow ot disallow execution of external
134 # programs, like a photo viewer.
135 AC_MSG_CHECKING([whether to enable external program execution])
136 AC_ARG_ENABLE(exec,
137     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
138     use_exec=$enableval)
139 AC_MSG_RESULT($use_exec)
140 if test "$use_exec" = no ; then
141     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
142 fi
143
144 if test "$use_exec" = yes ; then
145   AC_MSG_CHECKING([whether to enable photo ID viewing])
146   AC_ARG_ENABLE(photo-viewers,
147       [  --disable-photo-viewers disable photo ID viewers],
148       [if test "$enableval" = no ; then
149          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
150       fi],enableval=yes)
151   gnupg_cv_enable_photo_viewers=$enableval
152   AC_MSG_RESULT($enableval)
153
154   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
155     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
156     AC_ARG_WITH(photo-viewer,
157         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
158         [if test "$withval" = yes ; then
159            withval=no
160         elif test "$withval" != no ; then
161            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
162                             [if set, restrict photo-viewer to this])
163         fi],withval=no)
164     AC_MSG_RESULT($withval)
165   fi
166
167   AC_MSG_CHECKING([whether to enable external keyserver helpers])
168   AC_ARG_ENABLE(keyserver-helpers,
169       [  --disable-keyserver-helpers  disable all external keyserver support],
170       [if test "$enableval" = no ; then
171          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
172                   [define to disable keyserver helpers])
173       fi],enableval=yes)
174   gnupg_cv_enable_keyserver_helpers=$enableval
175   AC_MSG_RESULT($enableval)
176
177   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
178     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
179     AC_ARG_ENABLE(ldap,
180     [  --disable-ldap          disable LDAP keyserver interface],
181         try_ldap=$enableval, try_ldap=yes)
182     AC_MSG_RESULT($try_ldap)
183
184     AC_MSG_CHECKING([whether HKP keyserver support is requested])
185     AC_ARG_ENABLE(hkp,
186     [  --disable-hkp           disable HKP keyserver interface],
187         try_hkp=$enableval, try_hkp=yes)
188     AC_MSG_RESULT($try_hkp)
189
190     if test "$try_hkp" = yes ; then
191       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
192     fi
193
194     AC_MSG_CHECKING([whether email keyserver support is requested])
195     AC_ARG_ENABLE(mailto,
196     [  --disable-mailto        disable email keyserver interface],
197         try_mailto=$enableval, try_mailto=yes)
198     AC_MSG_RESULT($try_mailto)
199     fi
200
201     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
202     AC_ARG_ENABLE(keyserver-path,
203         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
204         [if test "$enableval" = no ; then
205          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
206         fi],enableval=yes)
207     AC_MSG_RESULT($enableval)
208   fi
209
210 AC_MSG_CHECKING([whether the included zlib is requested])
211 AC_ARG_WITH(included-zlib,
212     [  --with-included-zlib    use the zlib code included here],
213 [g10_force_zlib=yes], [g10_force_zlib=no] )
214 AC_MSG_RESULT($g10_force_zlib)
215
216 dnl
217 dnl Check whether we want to use Linux capabilities
218 dnl
219 AC_MSG_CHECKING([whether use of capabilities is requested])
220 AC_ARG_WITH(capabilities,
221     [  --with-capabilities     use linux capabilities [default=no]],
222 [use_capabilities="$withval"],[use_capabilities=no])
223 AC_MSG_RESULT($use_capabilities)
224
225
226 AH_BOTTOM([
227 /* Some global constants. */
228 #ifdef HAVE_DRIVE_LETTERS
229 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
230 #elif defined(__VMS)
231 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
232 #else
233 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
234 #endif 
235 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
236
237 /* Tell libgcrypt not to use its own libgpg-error implementation. */
238 #define USE_LIBGPG_ERROR 1
239
240 /* This is the major version number of GnuPG so that
241    source included files can test for this.  Note, that\
242    we use 2 here even for GnuPG 1.9.x. */
243 #define GNUPG_MAJOR_VERSION 2
244
245 /* Now to separate file name parts.
246    Please note that the string version must not contain more
247    than one character because the code assumes strlen()==1 */
248 #ifdef HAVE_DOSISH_SYSTEM
249 #define DIRSEP_C '\\'
250 #define EXTSEP_C '.'
251 #define DIRSEP_S "\\"
252 #define EXTSEP_S "."
253 #else
254 #define DIRSEP_C '/'
255 #define EXTSEP_C '.'
256 #define DIRSEP_S "/"
257 #define EXTSEP_S "."
258 #endif
259
260 /* This is the same as VERSION, but should be overridden if the
261    platform cannot handle things like dots '.' in filenames. Set
262    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
263    uses for dots and dashes. */
264 #define SAFE_VERSION VERSION
265 #define SAFE_VERSION_DOT  '.'
266 #define SAFE_VERSION_DASH '-'
267
268 /* For some systems (DOS currently), we hardcode the path here.  For
269    POSIX systems the values are constructed by the Makefiles, so that
270    the values may be overridden by the make invocations; this is to
271    comply with the GNU coding standards. */
272 #ifdef HAVE_DRIVE_LETTERS
273 #define GNUPG_BINDIR      "c:\\gnupg"
274 #define GNUPG_LIBEXECDIR  "c:\\lib\\gnupg"
275 #define GNUPG_LIBDIR      "c:\\lib\\gnupg"
276 #define GNUPG_DATADIR     "c:\\lib\\gnupg"
277 #endif
278
279 /* Setup the hardwired names of modules. */
280 #ifndef GNUPG_DEFAULT_AGENT
281 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" )
282 #endif
283 #ifndef GNUPG_DEFAULT_PINENTRY
284 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" )
285 #endif
286 #ifndef GNUPG_DEFAULT_SCDAEMON
287 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" )
288 #endif
289 #ifndef GNUPG_DEFAULT_DIRMNGR
290 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" )
291 #endif
292 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
293 #define GNUPG_DEFAULT_PROTECT_TOOL \
294                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" )
295 #endif
296
297
298 /* Derive some other constants. */
299 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
300 #define EXEC_TEMPFILE_ONLY
301 #endif
302
303 ])
304
305 AM_MAINTAINER_MODE
306
307 # Checks for programs.
308 AC_PROG_MAKE_SET
309 AM_SANITY_CHECK
310 missing_dir=`cd $ac_aux_dir && pwd`
311 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
312 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
313 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
314 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
315 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
316 AC_PROG_AWK
317 AC_PROG_CC
318 AC_PROG_CPP
319 AC_PROG_INSTALL
320 AC_PROG_LN_S
321 AC_PROG_MAKE_SET
322 AC_PROG_RANLIB
323 AC_CHECK_TOOL(AR, ar, :)
324 AC_PATH_PROG(PERL,"perl")
325 AC_ISC_POSIX
326 AC_SYS_LARGEFILE
327 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
328 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
329 GNUPG_CHECK_FAQPROG
330 GNUPG_CHECK_DOCBOOK_TO_TEXI
331
332
333 try_gettext=yes
334 have_dosish_system=no
335 case "${target}" in
336     *-*-mingw32*)
337         # special stuff for Windoze NT
338         ac_cv_have_dev_random=no
339         AC_DEFINE(USE_ONLY_8DOT3,1,
340                   [set this to limit filenames to the 8.3 format])
341         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
342                   [defined if we must run on a stupid file system])
343         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
344                   [because the Unix gettext has too much overhead on
345                    MingW32 systems and these systems lack Posix functions,
346                    we use a simplified version of gettext])
347         have_dosish_system=yes
348         try_gettext="no"
349         ;;
350     i?86-emx-os2 | i?86-*-os2*emx )
351         # OS/2 with the EMX environment
352         ac_cv_have_dev_random=no
353         AC_DEFINE(HAVE_DRIVE_LETTERS)
354         have_dosish_system=yes
355         try_gettext="no"
356         ;;
357
358     i?86-*-msdosdjgpp*)
359         # DOS with the DJGPP environment
360         ac_cv_have_dev_random=no
361         AC_DEFINE(HAVE_DRIVE_LETTERS)
362         have_dosish_system=yes
363         try_gettext="no"
364         ;;
365
366     *-*-freebsd*)
367        # FreeBSD
368        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
369        LDFLAGS="$LDFLAGS -L/usr/local/lib"
370        ;;
371
372     *-*-hpux*)
373         if test -z "$GCC" ; then
374             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
375         fi
376         ;;
377     *-dec-osf4*)
378         if test -z "$GCC" ; then
379             # Suppress all warnings
380             # to get rid of the unsigned/signed char mismatch warnings.
381             CFLAGS="$CFLAGS -w"
382         fi
383         ;;
384     *-dec-osf5*)
385         if test -z "$GCC" ; then
386             # Use the newer compiler `-msg_disable ptrmismatch' to
387             # get rid of the unsigned/signed char mismatch warnings.
388             # Using this may hide other pointer mismatch warnings, but
389             # it at least lets other warning classes through
390             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
391         fi
392         ;;
393     m68k-atari-mint)
394         ;;
395     *)
396        ;;
397 esac
398
399 if test "$have_dosish_system" = yes; then
400    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
401              [defined if we run on some of the PCDOS like systems 
402               (DOS, Windoze. OS/2) with special properties like
403               no file modes])
404 fi
405 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
406
407
408 #
409 # Checks for libraries.
410 #
411
412
413 #
414 # libgpg-error is a library with error codes shared between GnuPG
415 # related projects.
416 #
417 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
418                   have_gpg_error=yes,have_gpg_error=no)
419
420
421 #
422 # Libgcrypt is our generic crypto library
423 #
424 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
425         have_libgcrypt=yes,have_libgcrypt=no)
426
427
428 #
429 # libassuan is used for IPC
430 #
431 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
432                   have_libassuan=yes,have_libassuan=no)
433
434
435 #
436 # libksba is our X.509 support library
437 #
438 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
439
440 #
441 # libusb allows us to use the integrated CCID smartcard reader driver.
442 #
443 # Note, that we need the CVS version.  FIXME: libusb should have a
444 # regular check as the other libraries do.
445 #
446 AC_CHECK_LIB(usb, usb_find_device,
447               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
448                 AC_DEFINE(HAVE_LIBUSB,1,
449                          [defined if libusb is available])
450              ])
451 AC_SUBST(LIBUSB_LIBS)
452
453
454 #
455 # OpenSC is needed by the SCdaemon - if it is not availbale we can only
456 # build a limited SCdaemon
457 #
458 AM_PATH_OPENSC("$NEED_OPENSC_VERSION",have_opensc=yes,have_opensc=no)
459 if test $have_opensc = yes; then
460   AC_DEFINE(HAVE_OPENSC,1,
461             [defined if the OpenSC library is available])
462 fi
463
464 #
465 # Check whether the (highly desirable) GNU Pth library is available
466 #
467 AC_ARG_WITH(pth-prefix,
468             AC_HELP_STRING([--with-pth-prefix=PFX],
469                            [prefix where GNU Pth is installed (optional)]),
470      pth_config_prefix="$withval", pth_config_prefix="")
471 if test x$pth_config_prefix != x ; then
472    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
473 fi
474 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
475 if test "$PTH_CONFIG" = "no"; then
476     AC_MSG_WARN([[
477 ***
478 *** To support concurrent access to the gpg-agent and the SCdaemon
479 *** we need the support of the GNU Portable Threads Library.
480 *** Download it from ftp://ftp.gnu.org/gnu/pth/
481 *** On a Debian GNU/Linux system you might want to try 
482 ***   apt-get install libpth-dev
483 ***]])
484 else
485   GNUPG_PTH_VERSION_CHECK(1.3.7)
486   if test $have_pth = yes; then      
487      PTH_CFLAGS=`$PTH_CONFIG --cflags`
488      PTH_LIBS=`$PTH_CONFIG --ldflags`
489      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
490      AC_DEFINE(USE_GNU_PTH, 1,
491               [Defined if the GNU Portable Thread Library should be used])
492   fi
493 fi
494 AC_SUBST(PTH_CFLAGS)
495 AC_SUBST(PTH_LIBS)
496
497 AC_ARG_ENABLE(threads,
498     AC_HELP_STRING([--disable-threads],[allow building without Pth support]);
499     
500 )
501
502
503 dnl Must check for network library requirements before doing link tests
504 dnl for ldap, for example. If ldap libs are static (or dynamic and without
505 dnl ELF runtime link paths), then link will fail and LDAP support won't
506 dnl be detected.
507
508 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
509         [NETLIBS="-lnsl $NETLIBS"]))
510 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
511         [NETLIBS="-lsocket $NETLIBS"]))
512
513 dnl Now try for the resolver functions so we can use DNS SRV
514
515 AC_ARG_ENABLE(dns-srv,
516    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
517    use_dns_srv=$enableval,use_dns_srv=yes)
518
519 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
520   _srv_save_libs=$LIBS
521   LIBS=""
522   # the double underscore thing is a glibc-ism?
523   AC_SEARCH_LIBS(res_query,resolv bind,,
524                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
525   AC_SEARCH_LIBS(dn_expand,resolv bind,,
526                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
527   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
528                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
529
530   if test x"$use_dns_srv" = xyes ; then
531      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
532      SRVLIBS=$LIBS
533   else
534      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
535   fi
536   LIBS=$_srv_save_libs
537 fi
538
539 AC_SUBST(SRVLIBS)
540
541 # Try and link a LDAP test program to weed out unusable LDAP
542 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
543 # general is terrible with creating weird dependencies.  If all else
544 # fails, the user can play guess-the-dependency by using something
545 # like ./configure LDAPLIBS="-Lfoo -lbar"
546
547 if test "$try_ldap" = yes ; then
548   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
549     _ldap_save_libs=$LIBS
550     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
551
552     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
553     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
554                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
555     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
556
557     if test $gnupg_cv_func_ldap_init = no; then
558       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
559       AC_TRY_LINK([#include <lber.h>
560 #include <ldap.h>],[ldap_open("foobar",1234);],
561          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
562       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
563     fi
564
565     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
566        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
567     fi
568
569     if test "$gnupg_cv_func_ldap_init" = yes || \
570         test "$gnupg_cv_func_ldaplber_init" = yes ; then
571        LDAPLIBS=$MY_LDAPLIBS
572        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
573
574        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
575
576        if test "$gnupg_cv_func_ldap_init" = yes ; then
577           AC_TRY_LINK([#include <ldap.h>],
578              [ldap_get_option((void *)0,0,(void *)0);],
579              [gnupg_cv_func_ldap_get_option=yes],
580              [gnupg_cv_func_ldap_get_option=no])
581         else
582           AC_TRY_LINK([#include <lber.h>
583 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
584              [gnupg_cv_func_ldap_get_option=yes],
585              [gnupg_cv_func_ldap_get_option=no])
586        fi
587
588        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
589
590        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
591           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
592        else
593           AC_MSG_CHECKING([whether LDAP supports ld_errno])
594
595           if test "$gnupg_cv_func_ldap_init" = yes ; then
596             AC_TRY_COMPILE([#include <ldap.h>],
597                [LDAP *ldap; ldap->ld_errno;],
598                [gnupg_cv_func_ldap_ld_errno=yes],
599                [gnupg_cv_func_ldap_ld_errno=no])
600            else
601             AC_TRY_LINK([#include <lber.h>
602 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
603                [gnupg_cv_func_ldap_ld_errno=yes],
604                [gnupg_cv_func_ldap_ld_errno=no])
605           fi
606
607           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
608
609           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
610              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
611           fi
612        fi
613     fi
614
615     LIBS=$_ldap_save_libs
616
617     if test "$GPGKEYS_LDAP" != "" ; then break; fi
618   done
619 fi
620
621 AC_SUBST(GPGKEYS_LDAP)
622 AC_SUBST(LDAPLIBS)
623
624 dnl This isn't necessarily sendmail itself, but anything that gives a
625 dnl sendmail-ish interface to the outside world.  That includes qmail,
626 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
627
628 if test "$try_mailto" = yes ; then
629   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
630
631   if test "$with_mailprog" = yes ; then
632     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
633     if test "$ac_cv_path_SENDMAIL" ; then
634       GPGKEYS_MAILTO="gpgkeys_mailto"
635     fi
636   elif test "$with_mailprog" != no ; then
637     AC_MSG_CHECKING([for a mail transport program])
638     AC_SUBST(SENDMAIL,$with_mailprog)
639     AC_MSG_RESULT($with_mailprog)
640     GPGKEYS_MAILTO="gpgkeys_mailto"
641   fi
642 fi
643
644 AC_SUBST(GPGKEYS_MAILTO)
645
646 case "${target}" in
647     *-*-mingw32*)
648         PRINTABLE_OS_NAME="MingW32"
649         ;;
650     *-*-cygwin*)
651         PRINTABLE_OS_NAME="Cygwin"
652         ;;
653     i?86-emx-os2 | i?86-*-os2*emx )
654         PRINTABLE_OS_NAME="OS/2"
655         ;;
656     i?86-*-msdosdjgpp*)
657         PRINTABLE_OS_NAME="MSDOS/DJGPP"
658         try_dynload=no
659         ;;
660     *-linux*)
661         PRINTABLE_OS_NAME="GNU/Linux"
662         ;;
663     *)
664         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
665         ;;
666 esac
667 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
668                    [A human readable text with the name of the OS])
669
670
671 AM_GNU_GETTEXT_VERSION(0.12.1)
672 if test "$try_gettext" = yes; then
673   AM_GNU_GETTEXT(,[need-ngettext])
674
675   # gettext requires some extra checks.  These really should be part of
676   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
677   # function checks to here.
678
679   AC_CHECK_FUNCS(strchr)
680 else
681   USE_NLS=no
682   USE_INCLUDED_LIBINTL=no
683   BUILD_INCLUDED_LIBINTL=no
684   AC_SUBST(USE_NLS)
685   AC_SUBST(USE_INCLUDED_LIBINTL)
686   AC_SUBST(BUILD_INCLUDED_LIBINTL)
687 fi
688
689 # Checks for header files.
690 AC_HEADER_STDC
691 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
692
693 # Checks for typedefs, structures, and compiler characteristics.
694 AC_C_CONST
695 AC_C_INLINE
696 AC_TYPE_SIZE_T
697 AC_TYPE_SIGNAL
698 AC_DECL_SYS_SIGLIST
699
700 GNUPG_CHECK_ENDIAN
701
702 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
703 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
704 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
705 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
706 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
707
708 AC_CHECK_SIZEOF(unsigned short)
709 AC_CHECK_SIZEOF(unsigned int)
710 AC_CHECK_SIZEOF(unsigned long)
711 AC_CHECK_SIZEOF(unsigned long long)
712 # Ensure that we have UINT64_C before we bother to check for uint64_t
713 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
714 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
715    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
716 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
717 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
718    AC_CHECK_SIZEOF(uint64_t)
719 fi
720  
721
722
723
724 if test "$ac_cv_sizeof_unsigned_short" = "0" \
725    || test "$ac_cv_sizeof_unsigned_int" = "0" \
726    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
727     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
728 fi
729
730 dnl Do we have any 64-bit data types?
731 if test "$ac_cv_sizeof_unsigned_int" != "8" \
732    && test "$ac_cv_sizeof_unsigned_long" != "8" \
733    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
734    && test "$ac_cv_sizeof_uint64_t" != "8"; then
735     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
736 else
737   if test x"$use_sha512" = xyes ; then
738      AC_SUBST(SHA512_O,sha512.o)
739      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
740   fi
741 fi
742
743 GNUPG_SYS_SO_PEERCRED
744
745 # Checks for library functions.
746 AC_FUNC_FSEEKO
747 AC_FUNC_VPRINTF
748 AC_FUNC_FORK
749 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
750 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
751 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
752 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
753 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
754
755 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
756
757 # These are needed by libjnlib - fixme: we should have macros for them
758 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
759 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
760 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
761
762 AC_REPLACE_FUNCS(vasprintf)
763 AC_REPLACE_FUNCS(fopencookie)
764 AC_REPLACE_FUNCS(mkdtemp)
765 AC_REPLACE_FUNCS(fseeko ftello)
766 AC_REPLACE_FUNCS(isascii)
767 AC_REPLACE_FUNCS(putc_unlocked)
768
769
770
771
772 #
773 # check for gethrtime and run a testprogram to see whether
774 # it is broken.  It has been reported that some Solaris and HP UX systems 
775 # raise an SIGILL
776 #
777 AC_CACHE_CHECK([for gethrtime], 
778                [gnupg_cv_func_gethrtime],
779                [AC_TRY_LINK([#include <sys/times.h>],[
780                    hrtime_t tv;
781                    tv = gethrtime();
782                  ],
783                  [gnupg_cv_func_gethrtime=yes],
784                  [gnupg_cv_func_gethrtime=no])
785                ])
786 if test $gnupg_cv_func_gethrtime = yes; then
787      AC_DEFINE([HAVE_GETHRTIME], 1,
788                [Define if you have the `gethrtime(2)' function.])
789      AC_CACHE_CHECK([whether gethrtime is broken], 
790                [gnupg_cv_func_broken_gethrtime],
791                [AC_TRY_RUN([
792                    #include <sys/times.h>
793                    int main () {
794                    hrtime_t tv;
795                    tv = gethrtime(); 
796                  }
797                  ],
798                  [gnupg_cv_func_broken_gethrtime=no],
799                  [gnupg_cv_func_broken_gethrtime=yes],
800                  [gnupg_cv_func_broken_gethrtime=assume-no])
801                 ])
802     if test $gnupg_cv_func_broken_gethrtime = yes; then
803       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
804       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
805     fi
806 fi
807      
808
809 GNUPG_CHECK_MLOCK
810 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
811
812 dnl
813 dnl Check whether we can use Linux capabilities as requested
814 dnl
815 if test "$use_capabilities" = "yes" ; then
816 use_capabilities=no
817 AC_CHECK_HEADERS(sys/capability.h)
818 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
819   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
820   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
821      AC_DEFINE(USE_CAPABILITIES,1,
822                [define if capabilities should be used])
823      AC_SUBST(CAPLIBS,"-lcap")
824      use_capabilities=yes
825   fi
826 fi
827 if test "$use_capabilities" = "no" ; then
828     AC_MSG_WARN([[
829 ***
830 *** The use of capabilities on this system is not possible.
831 *** You need a recent Linux kernel and some patches:
832 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
833 ***   fcap-module-990613.tar.gz     (kernel module)
834 ***   libcap-1.92.tar.gz            (user mode library and utilities)
835 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
836 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
837 ***]])
838 fi
839 fi
840
841
842 # Sanity check regex.  Tests adapted from mutt.
843
844 AC_MSG_CHECKING([whether regular expression support is requested])
845 AC_ARG_ENABLE(regex,
846 [  --disable-regex         do not handle regular expressions in trust sigs],
847      use_regex=$enableval, use_regex=yes)
848 AC_MSG_RESULT($use_regex)
849
850 if test "$use_regex" = yes ; then
851   AC_MSG_CHECKING([whether the included regex lib is requested])
852   AC_ARG_WITH(included-regex,
853       [  --with-included-regex   use the included GNU regex library],
854       [gnupg_cv_included_regex=yes],[gnupg_cv_included_regex=no])
855   AC_MSG_RESULT($gnupg_cv_included_regex)
856
857   if test $gnupg_cv_included_regex = no ; then
858      # Does the system have regex functions at all?
859      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
860                            gnupg_cv_included_regex=yes)
861   fi
862
863   if test $gnupg_cv_included_regex = no ; then
864      AC_CACHE_CHECK([whether your system's regexp library is broken],
865        [gnupg_cv_regex_broken],
866        AC_TRY_RUN([
867 #include <unistd.h>
868 #include <regex.h>
869 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
870        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
871
872      if test $gnupg_cv_regex_broken = yes ; then
873       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
874       gnupg_cv_included_regex=yes
875      fi
876   fi
877
878   if test $gnupg_cv_included_regex = yes; then
879      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
880      AC_SUBST(REGEX_O,regex.o)
881   fi
882 else
883
884   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
885 fi
886
887 dnl Do we have zlib? Must do it here because Solaris failed
888 dnl when compiling a conftest (due to the "-lz" from LIBS).
889 use_local_zlib=yes
890 if test "$g10_force_zlib" = "yes"; then
891   :
892 else
893   _cppflags="${CPPFLAGS}"
894   _ldflags="${LDFLAGS}"
895
896   AC_ARG_WITH(zlib,
897   [  --with-zlib=DIR         use libz in DIR],[
898     if test -d "$withval"; then
899       CPPFLAGS="${CPPFLAGS} -I$withval/include"
900       LDFLAGS="${LDFLAGS} -L$withval/lib"
901     fi
902   ])
903
904   AC_CHECK_HEADER(zlib.h,
905       AC_CHECK_LIB(z, deflateInit2_,
906        use_local_zlib=no
907        LIBS="$LIBS -lz",
908        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
909        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
910 fi
911  
912 if test "$use_local_zlib" = yes ; then
913     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
914     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
915     ZLIBS="../zlib/libzlib.a"
916 else
917     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
918     ZLIBS=
919 fi
920 AC_SUBST(ZLIBS)
921
922 # Allow users to append something to the version string without
923 # flagging it as development version.  The user version parts is
924 # considered everything after a dash. 
925 if test "$development_version" != yes; then
926   changequote(,)dnl
927   tmp_pat='[a-zA-Z]'
928   changequote([,])dnl
929   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
930     development_version=yes
931   fi
932 fi
933 if test "$development_version" = yes; then
934     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
935             [Defined if this is not a regular release])
936 fi
937
938 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
939
940 GNUPG_CHECK_GNUMAKE
941
942 # add some extra libs here so that previous tests don't fail for
943 # mysterious reasons - the final link step should bail out. 
944 case "${target}" in
945     *-*-mingw32*)
946         W32LIBS="-lwsock32"
947         ;;
948     *)
949        ;;
950 esac
951
952
953 if test "$GCC" = yes; then
954     if test "$USE_MAINTAINER_MODE" = "yes"; then
955         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
956         CFLAGS="$CFLAGS -Wformat-nonliteral"
957     else
958         CFLAGS="$CFLAGS -Wall"
959     fi
960 fi
961
962 AC_SUBST(NETLIBS)
963 AC_SUBST(W32LIBS)
964
965
966 # We use jnlib, so tell other modules about it
967 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
968         [Defined if jnlib style logging fucntions are available])
969
970
971
972 #
973 # Decide what to build
974 #
975 missing_pth=no
976 if test $have_ksba = no; then
977   build_gpgsm=no
978   build_scdaemon=no
979 fi
980
981 build_agent_threaded=""
982 if test "$build_agent" = "yes"; then
983   if test $have_pth = no; then
984      build_agent_threaded="(not multi-threaded)"
985      missing_pth=yes
986   fi
987 fi
988
989 build_scdaemon_extra=""
990 if test "$build_scdaemon" = "yes"; then
991   tmp=""
992   if test $have_pth = no; then
993      build_scdaemon_extra="not multi-threaded"
994      tmp=", "
995      missing_pth=yes
996   fi
997   if test $have_opensc = no; then
998      build_scdaemon_extra="${build_scdaemon_extra}${tmp}no pkcs#15"
999      tmp=", "
1000   fi      
1001   if test -n "$build_scdaemon_extra"; then
1002      build_scdaemon_extra="(${build_scdaemon_extra})"
1003   fi
1004 fi
1005
1006 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1007 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1008 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1009 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1010
1011
1012
1013 #
1014 # Print errors here so that they are visible all
1015 # together and the user can acquire them all together.
1016 #
1017 die=no
1018 if test "$have_gpg_error" = "no"; then
1019    die=yes
1020    AC_MSG_NOTICE([[
1021 ***  
1022 *** You need libgpg-error to build this program.
1023 **  This library is for example available at
1024 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgpg-error
1025 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1026 ***]])
1027 fi
1028 if test "$have_libgcrypt" = "no"; then
1029    die=yes
1030    AC_MSG_NOTICE([[
1031 ***  
1032 *** You need libgcrypt to build this program.
1033 **  This library is for example available at
1034 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1035 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1036 ***]])
1037 fi
1038 if test "$have_libassuan" = "no"; then
1039    die=yes
1040    AC_MSG_NOTICE([[
1041 ***
1042 *** You need libassuan to build this program.
1043 *** This library is for example available at
1044 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1045 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1046 ***]])
1047 fi
1048 if test "$have_ksba" = "no"; then
1049    die=yes
1050     AC_MSG_NOTICE([[
1051 ***
1052 *** You need libksba to build this program.
1053 *** This library is for example available at
1054 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1055 *** (at least version $NEED_KSBA_VERSION is required).
1056 ***]])
1057 fi
1058 if test "$missing_pth" = "yes"; then
1059     AC_MSG_NOTICE([[
1060 ***
1061 *** It is strongly suggested to build with support for the
1062 *** GNU Portable Threads Library (Pth). Please install this
1063 *** library first or use --disable-threads to allow building
1064 *** anyway.  The library is for example available at
1065 ***   ftp://ftp.gnu.org/gnu/pth/
1066 *** On a Debian GNU/Linux system you can install it using 
1067 ***   apt-get install libpth-dev
1068 ***]])
1069   if test "$enable_threads" != "no"; then
1070      die=yes
1071   fi
1072 fi
1073
1074 if test "$die" = "yes"; then
1075     AC_MSG_ERROR([[
1076 ***
1077 *** Required libraries not found. Please consult the above messages
1078 *** and install them before running configure again.
1079 ***]])
1080 fi
1081
1082
1083
1084 AC_CONFIG_FILES([ m4/Makefile 
1085 Makefile
1086 po/Makefile.in
1087 intl/Makefile
1088 jnlib/Makefile
1089 common/Makefile
1090 kbx/Makefile
1091 g10/Makefile
1092 sm/Makefile
1093 agent/Makefile
1094 scd/Makefile
1095 tools/Makefile
1096 doc/Makefile
1097 tests/Makefile
1098 ])
1099 AC_OUTPUT
1100
1101
1102
1103
1104 echo "
1105         GnuPG v${VERSION} has been configured as follows:
1106         
1107         Platform:  $PRINTABLE_OS_NAME ($target)
1108
1109         OpenPGP:   $build_gpg
1110         S/MIME:    $build_gpgsm
1111         Agent:     $build_agent $build_agent_threaded
1112         Smartcard: $build_scdaemon $build_scdaemon_extra
1113
1114         Protect tool:     $show_gnupg_protect_tool_pgm
1115         Default agent:    $show_gnupg_agent_pgm
1116         Default pinentry: $show_gnupg_pinentry_pgm
1117         Default scdaemon: $show_gnupg_scdaemon_pgm
1118         Default dirmngr:  $show_gnupg_dirmngr_pgm
1119 "
1120