* configure.ac: Removed OpenSC detection and options.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.9.3"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Add a "-cvs" prefix for non-released code.
27 AC_INIT(gnupg, 1.9.17-cvs, gnupg-devel@gnupg.org)
28 # Set development_version to yes if the minor number is odd or you
29 # feel that the default check for a development version is not
30 # sufficient.
31 development_version=yes
32 NEED_GPG_ERROR_VERSION=1.0
33
34 NEED_LIBGCRYPT_API=1
35 NEED_LIBGCRYPT_VERSION=1.1.94
36
37 NEED_LIBASSUAN_VERSION=0.6.9
38
39 NEED_KSBA_VERSION=0.9.11
40
41
42 PACKAGE=$PACKAGE_NAME
43 PACKAGE_GT=${PACKAGE_NAME}2
44 VERSION=$PACKAGE_VERSION
45
46 AC_CONFIG_AUX_DIR(scripts)
47 AC_CONFIG_SRCDIR(sm/gpgsm.c)
48 AM_CONFIG_HEADER(config.h)
49 AC_CANONICAL_TARGET()
50 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
51
52 AC_GNU_SOURCE
53
54 # Some status variables to give feedback at the end of a configure run
55 have_gpg_error=no
56 have_libgcrypt=no 
57 have_libassuan=no
58 have_ksba=no
59 have_pth=no
60
61 GNUPG_BUILD_PROGRAM(gpg, no)
62 GNUPG_BUILD_PROGRAM(gpgsm, yes)
63 GNUPG_BUILD_PROGRAM(agent, yes)
64 GNUPG_BUILD_PROGRAM(scdaemon, yes)
65 GNUPG_BUILD_PROGRAM(symcryptrun, no)
66
67
68 AC_SUBST(PACKAGE)
69 AC_SUBST(PACKAGE_GT)
70 AC_SUBST(VERSION)
71 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
72 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
73                                 [Name of this package for gettext])
74 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
75 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
76                                         [Bug report address])
77 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
78                                        [Required version of Libgcrypt])
79 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
80                                        [Required version of Libksba])
81
82
83
84 # The default is to use the modules from this package and the few
85 # other packages in a standard place; i.e where this package gets
86 # installed.  With these options it is possible to override these
87 # ${prefix} depended values with fixed paths, which can't be replaced
88 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
89 AC_ARG_WITH(agent-pgm,
90     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
91           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
92 AC_SUBST(GNUPG_AGENT_PGM)
93 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
94 show_gnupg_agent_pgm="(default)"
95 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
96
97 AC_ARG_WITH(pinentry-pgm,
98     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
99           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
100 AC_SUBST(GNUPG_PINENTRY_PGM)
101 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
102 show_gnupg_pinentry_pgm="(default)"
103 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
104
105
106 AC_ARG_WITH(scdaemon-pgm,
107     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
108           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
109 AC_SUBST(GNUPG_SCDAEMON_PGM)
110 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
111 show_gnupg_scdaemon_pgm="(default)"
112 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
113
114
115 AC_ARG_WITH(dirmngr-pgm,
116     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
117           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
118 AC_SUBST(GNUPG_DIRMNGR_PGM)
119 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
120 show_gnupg_dirmngr_pgm="(default)"
121 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
122
123 AC_ARG_WITH(protect-tool-pgm,
124     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
125           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
126 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
127 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
128 show_gnupg_protect_tool_pgm="(default)"
129 test -n "$GNUPG_PROTECT_TOOL_PGM" \
130       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
131
132
133
134 # Some folks want to use only the agent form this packet.  Make it
135 # easier for them by providing the configure option
136 # --enable-only-agent.
137 AC_ARG_ENABLE(agent-only,
138     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
139     build_agent_only=$enableval)
140
141
142 # Configure option to allow or disallow execution of external
143 # programs, like a photo viewer.
144 AC_MSG_CHECKING([whether to enable external program execution])
145 AC_ARG_ENABLE(exec,
146     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
147     use_exec=$enableval)
148 AC_MSG_RESULT($use_exec)
149 if test "$use_exec" = no ; then
150     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
151 fi
152
153 if test "$use_exec" = yes ; then
154   AC_MSG_CHECKING([whether to enable photo ID viewing])
155   AC_ARG_ENABLE(photo-viewers,
156       [  --disable-photo-viewers disable photo ID viewers],
157       [if test "$enableval" = no ; then
158          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
159       fi],enableval=yes)
160   gnupg_cv_enable_photo_viewers=$enableval
161   AC_MSG_RESULT($enableval)
162
163   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
164     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
165     AC_ARG_WITH(photo-viewer,
166         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
167         [if test "$withval" = yes ; then
168            withval=no
169         elif test "$withval" != no ; then
170            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
171                             [if set, restrict photo-viewer to this])
172         fi],withval=no)
173     AC_MSG_RESULT($withval)
174   fi
175
176   AC_MSG_CHECKING([whether to enable external keyserver helpers])
177   AC_ARG_ENABLE(keyserver-helpers,
178       [  --disable-keyserver-helpers  disable all external keyserver support],
179       [if test "$enableval" = no ; then
180          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
181                   [define to disable keyserver helpers])
182       fi],enableval=yes)
183   gnupg_cv_enable_keyserver_helpers=$enableval
184   AC_MSG_RESULT($enableval)
185
186   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
187     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
188     AC_ARG_ENABLE(ldap,
189     [  --disable-ldap          disable LDAP keyserver interface],
190         try_ldap=$enableval, try_ldap=yes)
191     AC_MSG_RESULT($try_ldap)
192
193     AC_MSG_CHECKING([whether HKP keyserver support is requested])
194     AC_ARG_ENABLE(hkp,
195     [  --disable-hkp           disable HKP keyserver interface],
196         try_hkp=$enableval, try_hkp=yes)
197     AC_MSG_RESULT($try_hkp)
198
199     if test "$try_hkp" = yes ; then
200       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
201     fi
202
203     AC_MSG_CHECKING([whether email keyserver support is requested])
204     AC_ARG_ENABLE(mailto,
205     [  --disable-mailto        disable email keyserver interface],
206         try_mailto=$enableval, try_mailto=yes)
207     AC_MSG_RESULT($try_mailto)
208     fi
209
210     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
211     AC_ARG_ENABLE(keyserver-path,
212         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
213         [if test "$enableval" = no ; then
214          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
215         fi],enableval=yes)
216     AC_MSG_RESULT($enableval)
217   fi
218
219 dnl
220 dnl Check whether we want to use Linux capabilities
221 dnl
222 AC_MSG_CHECKING([whether use of capabilities is requested])
223 AC_ARG_WITH(capabilities,
224     [  --with-capabilities     use linux capabilities [default=no]],
225 [use_capabilities="$withval"],[use_capabilities=no])
226 AC_MSG_RESULT($use_capabilities)
227
228
229 AH_BOTTOM([
230 /* Some global constants. */
231 #ifdef HAVE_DRIVE_LETTERS
232 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
233 #elif defined(__VMS)
234 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
235 #else
236 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
237 #endif 
238 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
239
240 /* Tell libgcrypt not to use its own libgpg-error implementation. */
241 #define USE_LIBGPG_ERROR 1
242
243 /* This is the major version number of GnuPG so that
244    source included files can test for this.  Note, that\
245    we use 2 here even for GnuPG 1.9.x. */
246 #define GNUPG_MAJOR_VERSION 2
247
248 /* Now to separate file name parts.
249    Please note that the string version must not contain more
250    than one character because the code assumes strlen()==1 */
251 #ifdef HAVE_DOSISH_SYSTEM
252 #define DIRSEP_C '\\'
253 #define DIRSEP_S "\\"
254 #define EXTSEP_C '.'
255 #define EXTSEP_S "."
256 #define PATHSEP_C ';'
257 #define PATHSEP_S ";"
258 #define EXEEXT_S ".exe"
259 #else
260 #define DIRSEP_C '/'
261 #define DIRSEP_S "/"
262 #define EXTSEP_C '.'
263 #define EXTSEP_S "."
264 #define PATHSEP_C ':'
265 #define PATHSEP_S ":"
266 #define EXEEXT_S ""
267 #endif
268
269 /* This is the same as VERSION, but should be overridden if the
270    platform cannot handle things like dots '.' in filenames. Set
271    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
272    uses for dots and dashes. */
273 #define SAFE_VERSION VERSION
274 #define SAFE_VERSION_DOT  '.'
275 #define SAFE_VERSION_DASH '-'
276
277 /* For some systems (DOS currently), we hardcode the path here.  For
278    POSIX systems the values are constructed by the Makefiles, so that
279    the values may be overridden by the make invocations; this is to
280    comply with the GNU coding standards. */
281 #ifdef HAVE_DRIVE_LETTERS
282 #define GNUPG_BINDIR      "c:\\gnupg"
283 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
284 #define GNUPG_LIBDIR      "c:\\gnupg"
285 #define GNUPG_DATADIR     "c:\\gnupg"
286 #endif
287
288 /* Setup the hardwired names of modules. */
289 #ifndef GNUPG_DEFAULT_AGENT
290 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
291 #endif
292 #ifndef GNUPG_DEFAULT_PINENTRY
293 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
294 #endif
295 #ifndef GNUPG_DEFAULT_SCDAEMON
296 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
297 #endif
298 #ifndef GNUPG_DEFAULT_DIRMNGR
299 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
300 #endif
301 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
302 #define GNUPG_DEFAULT_PROTECT_TOOL \
303                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
304 #endif
305
306
307 /* Derive some other constants. */
308 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
309 #define EXEC_TEMPFILE_ONLY
310 #endif
311
312 /* Temporary hacks to avoid requring a libgpg-error update. */
313 #if !HAVE_DECL_GPG_ERR_LOCKED
314 #define GPG_ERR_LOCKED  173
315 #endif
316
317 ])
318
319 AM_MAINTAINER_MODE
320
321 # Checks for programs.
322 AC_PROG_MAKE_SET
323 AM_SANITY_CHECK
324 missing_dir=`cd $ac_aux_dir && pwd`
325 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
326 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
327 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
328 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
329 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
330 AC_PROG_AWK
331 AC_PROG_CC
332 AC_PROG_CPP
333 AC_PROG_INSTALL
334 AC_PROG_LN_S
335 AC_PROG_MAKE_SET
336 AC_PROG_RANLIB
337 AC_CHECK_TOOL(AR, ar, :)
338 AC_PATH_PROG(PERL,"perl")
339 AC_ISC_POSIX
340 AC_SYS_LARGEFILE
341 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
342 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
343 GNUPG_CHECK_FAQPROG
344 GNUPG_CHECK_DOCBOOK_TO_TEXI
345
346
347 try_gettext=yes
348 have_dosish_system=no
349 have_w32_system=no
350 case "${host}" in
351     *-mingw32*)
352         # special stuff for Windoze NT
353         ac_cv_have_dev_random=no
354         AC_DEFINE(USE_ONLY_8DOT3,1,
355                   [set this to limit filenames to the 8.3 format])
356         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
357                   [defined if we must run on a stupid file system])
358         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
359                   [because the Unix gettext has too much overhead on
360                    MingW32 systems and these systems lack Posix functions,
361                    we use a simplified version of gettext])
362         have_dosish_system=yes
363         have_w32_system=yes
364         try_gettext="no"
365         ;;
366     i?86-emx-os2 | i?86-*-os2*emx )
367         # OS/2 with the EMX environment
368         ac_cv_have_dev_random=no
369         AC_DEFINE(HAVE_DRIVE_LETTERS)
370         have_dosish_system=yes
371         try_gettext="no"
372         ;;
373
374     i?86-*-msdosdjgpp*)
375         # DOS with the DJGPP environment
376         ac_cv_have_dev_random=no
377         AC_DEFINE(HAVE_DRIVE_LETTERS)
378         have_dosish_system=yes
379         try_gettext="no"
380         ;;
381
382     *-*-freebsd*)
383        # FreeBSD
384        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
385        LDFLAGS="$LDFLAGS -L/usr/local/lib"
386        ;;
387
388     *-*-hpux*)
389         if test -z "$GCC" ; then
390             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
391         fi
392         ;;
393     *-dec-osf4*)
394         if test -z "$GCC" ; then
395             # Suppress all warnings
396             # to get rid of the unsigned/signed char mismatch warnings.
397             CFLAGS="$CFLAGS -w"
398         fi
399         ;;
400     *-dec-osf5*)
401         if test -z "$GCC" ; then
402             # Use the newer compiler `-msg_disable ptrmismatch' to
403             # get rid of the unsigned/signed char mismatch warnings.
404             # Using this may hide other pointer mismatch warnings, but
405             # it at least lets other warning classes through
406             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
407         fi
408         ;;
409     m68k-atari-mint)
410         ;;
411     *)
412        ;;
413 esac
414
415 if test "$have_dosish_system" = yes; then
416    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
417              [Defined if we run on some of the PCDOS like systems 
418               (DOS, Windoze. OS/2) with special properties like
419               no file modes])
420 fi
421 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
422
423 if test "$have_w32_system" = yes; then
424    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
425 fi
426 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
427
428
429
430 #
431 # Checks for libraries.
432 #
433
434
435 #
436 # libgpg-error is a library with error codes shared between GnuPG
437 # related projects.
438 #
439 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
440                   have_gpg_error=yes,have_gpg_error=no)
441 _tmp_gpg_error_save_cflags="$CFLAGS"
442 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
443 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
444 CFLAGS="${_tmp_gpg_error_save_cflags}"
445
446
447 #
448 # Libgcrypt is our generic crypto library
449 #
450 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
451         have_libgcrypt=yes,have_libgcrypt=no)
452
453
454 #
455 # libassuan is used for IPC
456 #
457 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
458                   have_libassuan=yes,have_libassuan=no)
459
460
461 #
462 # libksba is our X.509 support library
463 #
464 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
465
466 #
467 # libusb allows us to use the integrated CCID smartcard reader driver.
468 #
469 AC_CHECK_LIB(usb, usb_bulk_write,
470               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
471                 AC_DEFINE(HAVE_LIBUSB,1,
472                          [defined if libusb is available])
473              ])
474 AC_SUBST(LIBUSB_LIBS)
475 AC_CHECK_FUNCS(usb_create_match)
476
477 #
478 # Check wether it is necessary to link against libdl.
479 #
480 LIBS=""
481 AC_SEARCH_LIBS(dlopen, c dl,,,)
482 DL_LIBS=$LIBS
483 AC_SUBST(DL_LIBS)
484
485 #
486 # Checks for symcryptrun:
487 #
488
489 # libutil has openpty() and login_tty().
490 AC_CHECK_LIB(util, openpty,
491               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
492                 AC_DEFINE(HAVE_LIBUTIL,1,
493                          [defined if libutil is available])
494              ])
495 AC_SUBST(LIBUTIL_LIBS)
496
497 # shred is used to clean temporary plain text files.
498 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
499 AC_DEFINE_UNQUOTED(SHRED,
500         "${SHRED}", [defines the filename of the shred program])
501
502
503 #
504 # Check whether the (highly desirable) GNU Pth library is available
505 # Note, that we include a Pth emulation for W32.
506 #
507 AC_ARG_WITH(pth-prefix,
508             AC_HELP_STRING([--with-pth-prefix=PFX],
509                            [prefix where GNU Pth is installed (optional)]),
510      pth_config_prefix="$withval", pth_config_prefix="")
511 if test x$pth_config_prefix != x ; then
512    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
513 fi
514 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
515 if test "$have_w32_system" = no; then
516  if test "$PTH_CONFIG" = "no"; then
517     AC_MSG_WARN([[
518 ***
519 *** To support concurrent access to the gpg-agent and the SCdaemon
520 *** we need the support of the GNU Portable Threads Library.
521 *** Download it from ftp://ftp.gnu.org/gnu/pth/
522 *** On a Debian GNU/Linux system you might want to try 
523 ***   apt-get install libpth-dev
524 ***]])
525  else
526   GNUPG_PTH_VERSION_CHECK(1.3.7)
527   if test $have_pth = yes; then      
528      PTH_CFLAGS=`$PTH_CONFIG --cflags`
529      PTH_LIBS=`$PTH_CONFIG --ldflags`
530      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
531      AC_DEFINE(USE_GNU_PTH, 1,
532               [Defined if the GNU Portable Thread Library should be used])
533   fi
534  fi
535 else 
536  have_pth=yes
537  PTH_CFLAGS=""
538  PTH_LIBS=""
539  AC_DEFINE(USE_GNU_PTH, 1)
540 fi
541 AC_SUBST(PTH_CFLAGS)
542 AC_SUBST(PTH_LIBS)
543
544 AC_ARG_ENABLE(threads,
545     AC_HELP_STRING([--disable-threads],[allow building without Pth support])
546              )
547
548
549 dnl Must check for network library requirements before doing link tests
550 dnl for ldap, for example. If ldap libs are static (or dynamic and without
551 dnl ELF runtime link paths), then link will fail and LDAP support won't
552 dnl be detected.
553
554 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
555         [NETLIBS="-lnsl $NETLIBS"]))
556 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
557         [NETLIBS="-lsocket $NETLIBS"]))
558
559 dnl Now try for the resolver functions so we can use DNS SRV
560
561 AC_ARG_ENABLE(dns-srv,
562    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
563    use_dns_srv=$enableval,use_dns_srv=yes)
564
565 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
566   _srv_save_libs=$LIBS
567   LIBS=""
568   # the double underscore thing is a glibc-ism?
569   AC_SEARCH_LIBS(res_query,resolv bind,,
570                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
571   AC_SEARCH_LIBS(dn_expand,resolv bind,,
572                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
573   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
574                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
575
576   if test x"$use_dns_srv" = xyes ; then
577      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
578      SRVLIBS=$LIBS
579   else
580      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
581   fi
582   LIBS=$_srv_save_libs
583 fi
584
585 AC_SUBST(SRVLIBS)
586
587 # Try and link a LDAP test program to weed out unusable LDAP
588 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
589 # general is terrible with creating weird dependencies.  If all else
590 # fails, the user can play guess-the-dependency by using something
591 # like ./configure LDAPLIBS="-Lfoo -lbar"
592
593 if test "$try_ldap" = yes ; then
594   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
595     _ldap_save_libs=$LIBS
596     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
597
598     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
599     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
600                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
601     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
602
603     if test $gnupg_cv_func_ldap_init = no; then
604       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
605       AC_TRY_LINK([#include <lber.h>
606 #include <ldap.h>],[ldap_open("foobar",1234);],
607          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
608       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
609     fi
610
611     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
612        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
613     fi
614
615     if test "$gnupg_cv_func_ldap_init" = yes || \
616         test "$gnupg_cv_func_ldaplber_init" = yes ; then
617        LDAPLIBS=$MY_LDAPLIBS
618        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
619
620        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
621
622        if test "$gnupg_cv_func_ldap_init" = yes ; then
623           AC_TRY_LINK([#include <ldap.h>],
624              [ldap_get_option((void *)0,0,(void *)0);],
625              [gnupg_cv_func_ldap_get_option=yes],
626              [gnupg_cv_func_ldap_get_option=no])
627         else
628           AC_TRY_LINK([#include <lber.h>
629 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
630              [gnupg_cv_func_ldap_get_option=yes],
631              [gnupg_cv_func_ldap_get_option=no])
632        fi
633
634        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
635
636        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
637           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
638        else
639           AC_MSG_CHECKING([whether LDAP supports ld_errno])
640
641           if test "$gnupg_cv_func_ldap_init" = yes ; then
642             AC_TRY_COMPILE([#include <ldap.h>],
643                [LDAP *ldap; ldap->ld_errno;],
644                [gnupg_cv_func_ldap_ld_errno=yes],
645                [gnupg_cv_func_ldap_ld_errno=no])
646            else
647             AC_TRY_LINK([#include <lber.h>
648 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
649                [gnupg_cv_func_ldap_ld_errno=yes],
650                [gnupg_cv_func_ldap_ld_errno=no])
651           fi
652
653           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
654
655           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
656              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
657           fi
658        fi
659     fi
660
661     LIBS=$_ldap_save_libs
662
663     if test "$GPGKEYS_LDAP" != "" ; then break; fi
664   done
665 fi
666
667 AC_SUBST(GPGKEYS_LDAP)
668 AC_SUBST(LDAPLIBS)
669
670 dnl This isn't necessarily sendmail itself, but anything that gives a
671 dnl sendmail-ish interface to the outside world.  That includes qmail,
672 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
673
674 if test "$try_mailto" = yes ; then
675   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
676
677   if test "$with_mailprog" = yes ; then
678     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
679     if test "$ac_cv_path_SENDMAIL" ; then
680       GPGKEYS_MAILTO="gpgkeys_mailto"
681     fi
682   elif test "$with_mailprog" != no ; then
683     AC_MSG_CHECKING([for a mail transport program])
684     AC_SUBST(SENDMAIL,$with_mailprog)
685     AC_MSG_RESULT($with_mailprog)
686     GPGKEYS_MAILTO="gpgkeys_mailto"
687   fi
688 fi
689
690 AC_SUBST(GPGKEYS_MAILTO)
691
692 case "${host}" in
693     *-mingw32*)
694         PRINTABLE_OS_NAME="MingW32"
695         ;;
696     *-*-cygwin*)
697         PRINTABLE_OS_NAME="Cygwin"
698         ;;
699     i?86-emx-os2 | i?86-*-os2*emx )
700         PRINTABLE_OS_NAME="OS/2"
701         ;;
702     i?86-*-msdosdjgpp*)
703         PRINTABLE_OS_NAME="MSDOS/DJGPP"
704         try_dynload=no
705         ;;
706     *-linux*)
707         PRINTABLE_OS_NAME="GNU/Linux"
708         ;;
709     *)
710         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
711         ;;
712 esac
713 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
714                    [A human readable text with the name of the OS])
715
716
717 AM_GNU_GETTEXT_VERSION(0.14.1)
718 if test "$try_gettext" = yes; then
719   AM_GNU_GETTEXT(,[need-ngettext])
720
721   # gettext requires some extra checks.  These really should be part of
722   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
723   # function checks to here.
724
725   AC_CHECK_FUNCS(strchr)
726 else
727   USE_NLS=no
728   USE_INCLUDED_LIBINTL=no
729   BUILD_INCLUDED_LIBINTL=no
730   AC_SUBST(USE_NLS)
731   AC_SUBST(USE_INCLUDED_LIBINTL)
732   AC_SUBST(BUILD_INCLUDED_LIBINTL)
733 fi
734
735 # Checks for header files.
736 AC_HEADER_STDC
737 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
738
739 # Checks for typedefs, structures, and compiler characteristics.
740 AC_C_CONST
741 AC_C_INLINE
742 AC_TYPE_SIZE_T
743 AC_TYPE_SIGNAL
744 AC_DECL_SYS_SIGLIST
745
746 GNUPG_CHECK_ENDIAN
747
748 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
749 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
750 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
751 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
752 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
753
754 AC_CHECK_SIZEOF(unsigned short)
755 AC_CHECK_SIZEOF(unsigned int)
756 AC_CHECK_SIZEOF(unsigned long)
757 AC_CHECK_SIZEOF(unsigned long long)
758 # Ensure that we have UINT64_C before we bother to check for uint64_t
759 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
760 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
761    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
762 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
763 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
764    AC_CHECK_SIZEOF(uint64_t)
765 fi
766  
767
768
769
770 if test "$ac_cv_sizeof_unsigned_short" = "0" \
771    || test "$ac_cv_sizeof_unsigned_int" = "0" \
772    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
773     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
774 fi
775
776 dnl Do we have any 64-bit data types?
777 if test "$ac_cv_sizeof_unsigned_int" != "8" \
778    && test "$ac_cv_sizeof_unsigned_long" != "8" \
779    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
780    && test "$ac_cv_sizeof_uint64_t" != "8"; then
781     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
782 else
783   if test x"$use_sha512" = xyes ; then
784      AC_SUBST(SHA512_O,sha512.o)
785      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
786   fi
787 fi
788
789 # fixme: do we really need this - it should be encapsulated in libassuan
790 GNUPG_SYS_SO_PEERCRED
791
792 # Checks for library functions.
793 AC_FUNC_FSEEKO
794 AC_FUNC_VPRINTF
795 AC_FUNC_FORK
796 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
797 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
798 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
799 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
800 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
801
802 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
803
804 # These are needed by libjnlib - fixme: we should have macros for them
805 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
806 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
807 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
808
809 AC_REPLACE_FUNCS(vasprintf)
810 AC_REPLACE_FUNCS(mkdtemp)
811 AC_REPLACE_FUNCS(fseeko ftello)
812 AC_REPLACE_FUNCS(isascii)
813 AC_REPLACE_FUNCS(putc_unlocked)
814 AC_REPLACE_FUNCS(strsep)
815 AC_REPLACE_FUNCS(ttyname)
816
817
818
819 #
820 # check for gethrtime and run a testprogram to see whether
821 # it is broken.  It has been reported that some Solaris and HP UX systems 
822 # raise an SIGILL
823 #
824 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
825 #
826 AC_CACHE_CHECK([for gethrtime], 
827                [gnupg_cv_func_gethrtime],
828                [AC_TRY_LINK([#include <sys/times.h>],[
829                    hrtime_t tv;
830                    tv = gethrtime();
831                  ],
832                  [gnupg_cv_func_gethrtime=yes],
833                  [gnupg_cv_func_gethrtime=no])
834                ])
835 if test $gnupg_cv_func_gethrtime = yes; then
836      AC_DEFINE([HAVE_GETHRTIME], 1,
837                [Define if you have the `gethrtime(2)' function.])
838      AC_CACHE_CHECK([whether gethrtime is broken], 
839                [gnupg_cv_func_broken_gethrtime],
840                [AC_TRY_RUN([
841                    #include <sys/times.h>
842                    int main () {
843                    hrtime_t tv;
844                    tv = gethrtime(); 
845                  }
846                  ],
847                  [gnupg_cv_func_broken_gethrtime=no],
848                  [gnupg_cv_func_broken_gethrtime=yes],
849                  [gnupg_cv_func_broken_gethrtime=assume-no])
850                 ])
851     if test $gnupg_cv_func_broken_gethrtime = yes; then
852       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
853       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
854     fi
855 fi
856      
857
858 GNUPG_CHECK_MLOCK
859 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
860
861 dnl
862 dnl Check whether we can use Linux capabilities as requested
863 dnl
864 #  fixme: Still required?
865 #
866 if test "$use_capabilities" = "yes" ; then
867 use_capabilities=no
868 AC_CHECK_HEADERS(sys/capability.h)
869 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
870   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
871   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
872      AC_DEFINE(USE_CAPABILITIES,1,
873                [define if capabilities should be used])
874      AC_SUBST(CAPLIBS,"-lcap")
875      use_capabilities=yes
876   fi
877 fi
878 if test "$use_capabilities" = "no" ; then
879     AC_MSG_WARN([[
880 ***
881 *** The use of capabilities on this system is not possible.
882 *** You need a recent Linux kernel and some patches:
883 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
884 ***   fcap-module-990613.tar.gz     (kernel module)
885 ***   libcap-1.92.tar.gz            (user mode library and utilities)
886 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
887 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
888 ***]])
889 fi
890 fi
891
892
893 # Sanity check regex.  Tests adapted from mutt.
894
895 AC_MSG_CHECKING([whether regular expression support is requested])
896 AC_ARG_ENABLE(regex,
897 [  --disable-regex         do not handle regular expressions in trust sigs],
898      use_regex=$enableval, use_regex=yes)
899 AC_MSG_RESULT($use_regex)
900
901 if test "$use_regex" = yes ; then
902   AC_MSG_CHECKING([whether the included regex lib is requested])
903   AC_ARG_WITH(included-regex,
904       [  --with-included-regex   use the included GNU regex library],
905       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
906   AC_MSG_RESULT($gnupg_cv_included_regex)
907
908   if test $gnupg_cv_included_regex = no ; then
909      # Does the system have regex functions at all?
910      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
911                            gnupg_cv_included_regex=yes)
912   fi
913
914   if test $gnupg_cv_included_regex = no ; then
915      AC_CACHE_CHECK([whether your system's regexp library is broken],
916        [gnupg_cv_regex_broken],
917        AC_TRY_RUN([
918 #include <unistd.h>
919 #include <regex.h>
920 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
921        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
922
923      if test $gnupg_cv_regex_broken = yes ; then
924       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
925       gnupg_cv_included_regex=yes
926      fi
927   fi
928
929   if test $gnupg_cv_included_regex = yes; then
930      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
931      AC_SUBST(REGEX_O,regex.o)
932   fi
933 else
934
935   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
936 fi
937
938 dnl Do we have zlib? Must do it here because Solaris failed
939 dnl when compiling a conftest (due to the "-lz" from LIBS).
940 _cppflags="${CPPFLAGS}"
941 _ldflags="${LDFLAGS}"
942
943 AC_ARG_WITH(zlib,
944   [  --with-zlib=DIR         use libz in DIR],[
945     if test -d "$withval"; then
946       CPPFLAGS="${CPPFLAGS} -I$withval/include"
947       LDFLAGS="${LDFLAGS} -L$withval/lib"
948     fi
949   ])
950
951 AC_CHECK_HEADER(zlib.h,
952       AC_CHECK_LIB(z, deflateInit2_,
953        LIBS="$LIBS -lz",
954        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
955        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
956  
957
958
959 # See wether we want to run the long test suite.
960 AC_ARG_WITH(pkits-tests,
961     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
962     [run_pkits_tests=$withval], [run_pkits_tests=no])
963 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
964
965
966 # Allow users to append something to the version string without
967 # flagging it as development version.  The user version parts is
968 # considered everything after a dash. 
969 if test "$development_version" != yes; then
970   changequote(,)dnl
971   tmp_pat='[a-zA-Z]'
972   changequote([,])dnl
973   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
974     development_version=yes
975   fi
976 fi
977 if test "$development_version" = yes; then
978     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
979             [Defined if this is not a regular release])
980 fi
981
982 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
983
984 GNUPG_CHECK_GNUMAKE
985
986 # Add some extra libs here so that previous tests don't fail for
987 # mysterious reasons - the final link step should bail out. 
988 if test "$have_w32_system" = yes; then
989    W32LIBS="-lwsock32"
990 fi
991
992
993 if test "$GCC" = yes; then
994     if test "$USE_MAINTAINER_MODE" = "yes"; then
995         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
996         CFLAGS="$CFLAGS -Wformat-nonliteral"
997     else
998         CFLAGS="$CFLAGS -Wall"
999     fi
1000 fi
1001
1002 AC_SUBST(NETLIBS)
1003 AC_SUBST(W32LIBS)
1004
1005
1006 # We use jnlib, so tell other modules about it
1007 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1008           [Defined if jnlib style logging functions are available])
1009
1010 # For W32 we need to use our Pth emulation code
1011 if test "$have_w32_system" = yes; then
1012   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1013 fi
1014
1015
1016 #
1017 # Decide what to build
1018 #
1019 missing_pth=no
1020 if test $have_ksba = no; then
1021   build_gpgsm=no
1022   build_scdaemon=no
1023 fi
1024
1025 build_agent_threaded=""
1026 if test "$build_agent" = "yes"; then
1027   if test $have_pth = no; then
1028      build_agent_threaded="(not multi-threaded)"
1029      missing_pth=yes
1030   fi
1031 fi
1032
1033 build_scdaemon_extra=""
1034 if test "$build_scdaemon" = "yes"; then
1035   tmp=""
1036   if test $have_pth = no; then
1037      build_scdaemon_extra="not multi-threaded"
1038      tmp=", "
1039      missing_pth=yes
1040   fi
1041   if test -n "$build_scdaemon_extra"; then
1042      build_scdaemon_extra="(${build_scdaemon_extra})"
1043   fi
1044 fi
1045
1046
1047 if test "$build_agent_only" = "yes" ; then
1048   build_gpg=no
1049   build_gpgsm=no
1050   build_scdaemon=no
1051 fi
1052
1053
1054 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1055 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1056 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1057 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1058 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1059
1060
1061
1062 #
1063 # Print errors here so that they are visible all
1064 # together and the user can acquire them all together.
1065 #
1066 die=no
1067 if test "$have_gpg_error" = "no"; then
1068    die=yes
1069    AC_MSG_NOTICE([[
1070 ***  
1071 *** You need libgpg-error to build this program.
1072 **  This library is for example available at
1073 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1074 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1075 ***]])
1076 fi
1077 if test "$have_libgcrypt" = "no"; then
1078    die=yes
1079    AC_MSG_NOTICE([[
1080 ***  
1081 *** You need libgcrypt to build this program.
1082 **  This library is for example available at
1083 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1084 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1085 ***]])
1086 fi
1087 if test "$have_libassuan" = "no"; then
1088    die=yes
1089    AC_MSG_NOTICE([[
1090 ***
1091 *** You need libassuan to build this program.
1092 *** This library is for example available at
1093 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1094 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1095 ***]])
1096 fi
1097 if test "$have_ksba" = "no"; then
1098     AC_MSG_NOTICE([[
1099 ***
1100 *** You need libksba to build this program.
1101 *** This library is for example available at
1102 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1103 *** (at least version $NEED_KSBA_VERSION is required).
1104 ***]])
1105 fi
1106 if test "$missing_pth" = "yes"; then
1107     AC_MSG_NOTICE([[
1108 ***
1109 *** It is strongly suggested to build with support for the
1110 *** GNU Portable Threads Library (Pth). Please install this
1111 *** library first or use --disable-threads to allow building
1112 *** anyway.  The library is for example available at
1113 ***   ftp://ftp.gnu.org/gnu/pth/
1114 *** On a Debian GNU/Linux system you can install it using 
1115 ***   apt-get install libpth-dev
1116 ***]])
1117   if test "$enable_threads" != "no"; then
1118      die=yes
1119   fi
1120 fi
1121
1122 if test "$die" = "yes"; then
1123     AC_MSG_ERROR([[
1124 ***
1125 *** Required libraries not found. Please consult the above messages
1126 *** and install them before running configure again.
1127 ***]])
1128 fi
1129
1130
1131
1132 AC_CONFIG_FILES([ m4/Makefile 
1133 Makefile
1134 po/Makefile.in
1135 intl/Makefile
1136 jnlib/Makefile
1137 common/Makefile
1138 kbx/Makefile
1139 g10/Makefile
1140 sm/Makefile
1141 agent/Makefile
1142 scd/Makefile
1143 tools/Makefile
1144 doc/Makefile
1145 tests/Makefile
1146 ])
1147 AC_OUTPUT
1148
1149 #tests/pkits/Makefile
1150
1151
1152
1153
1154 echo "
1155         GnuPG v${VERSION} has been configured as follows:
1156         
1157         Platform:  $PRINTABLE_OS_NAME ($host)
1158
1159         OpenPGP:   $build_gpg
1160         S/MIME:    $build_gpgsm
1161         Agent:     $build_agent $build_agent_threaded
1162         Smartcard: $build_scdaemon $build_scdaemon_extra
1163
1164         Protect tool:      $show_gnupg_protect_tool_pgm
1165         Default agent:     $show_gnupg_agent_pgm
1166         Default pinentry:  $show_gnupg_pinentry_pgm
1167         Default scdaemon:  $show_gnupg_scdaemon_pgm
1168         Default dirmngr:   $show_gnupg_dirmngr_pgm
1169
1170         PKITS based tests: $run_pkits_tests
1171 "
1172