ea6428721056e9e43e7a7e99d06c6992b9100aab
[gnupg.git] / configure.ac
1 dnl configure.ac script for GnuPG
2 dnl Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
3 dnl               2005 Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GnuPG.
6 dnl
7 dnl GnuPG is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl GnuPG is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, 
20 dnl MA 02110-1301, USA
21 dnl
22 dnl (Process this file with autoconf to produce a configure script.)
23
24 AC_PREREQ(2.59)
25 min_automake_version="1.9.3"
26
27 # Remember to change the version number immediately *after* a release
28 # and remove the "-cvs" or "rc" suffix immediately *before* a release.
29 AC_INIT(gnupg, 1.4.3-cvs, bug-gnupg@gnu.org)
30 # Set development_version to yes if the minor number is odd or you
31 # feel that the default check for a development version is not
32 # sufficient.
33 development_version=no
34
35 AC_CONFIG_AUX_DIR(scripts)
36 AC_CONFIG_SRCDIR(g10/gpg.c)
37 AC_CANONICAL_HOST
38 AM_INIT_AUTOMAKE([std-options])
39 AM_CONFIG_HEADER(config.h)
40
41 AC_GNU_SOURCE
42
43 dnl
44 dnl  Check for random module options
45 dnl
46 AC_MSG_CHECKING([which random module to use])
47 AC_ARG_ENABLE(static-rnd,
48     [  --enable-static-rnd=[egd|unix|linux|auto]  ],
49 [use_static_rnd=$enableval], [use_static_rnd=default] )
50
51 if test "$use_static_rnd" = no; then
52     use_static_rnd=default
53 fi
54
55 case "$use_static_rnd" in
56     egd | linux | unix | default )
57       AC_MSG_RESULT($use_static_rnd)
58       ;;
59     auto )
60       AC_MSG_RESULT(automagically selected at runtime)
61       ;;
62     * )
63       AC_MSG_RESULT(invalid argument)
64       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
65       ;;
66 esac
67
68 AC_ARG_WITH(egd-socket,
69     [  --with-egd-socket=NAME  use NAME for the EGD socket],
70             egd_socket_name="$withval", egd_socket_name="" )
71 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
72                    [Define if you don't want the default EGD socket name.
73                     For details see cipher/rndegd.c])
74
75
76 dnl
77 dnl See whether the user wants to disable checking for /dev/random
78
79 AC_MSG_CHECKING([whether use of /dev/random is requested])
80 AC_ARG_ENABLE(dev-random,
81 [  --disable-dev-random    disable the use of dev random],
82     try_dev_random=$enableval, try_dev_random=yes)
83 AC_MSG_RESULT($try_dev_random)
84
85
86 dnl
87 dnl  Check other options
88 dnl
89
90 AC_MSG_CHECKING([whether assembler modules are requested])
91 AC_ARG_ENABLE(asm,
92 [  --disable-asm           do not use assembler modules],
93      try_asm_modules=$enableval, try_asm_modules=yes)
94 AC_MSG_RESULT($try_asm_modules)
95
96 AC_MSG_CHECKING([whether memory guard is requested])
97 AC_ARG_ENABLE(m-guard,
98     [  --enable-m-guard        enable memory guard facility],
99     use_m_guard=$enableval, use_m_guard=no)
100 AC_MSG_RESULT($use_m_guard)
101 if test "$use_m_guard" = yes ; then
102     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
103 fi
104
105 # We don't have a test to check whether as(1) knows about the
106 # non executable stack option.  Thus we provide an option to enable
107 # it.
108 AC_MSG_CHECKING([whether non excutable stack support is requested])
109 AC_ARG_ENABLE(noexecstack,
110               AC_HELP_STRING([--enable-noexecstack],
111                              [enable non executable stack support (gcc only)]),
112               noexecstack_support=$enableval, noexecstack_support=no)
113 AC_MSG_RESULT($noexecstack_support)
114
115 # SELinux support includes tracking of sensitive files to avoid
116 # leaking their contents through processing these files by gpg itself
117 AC_MSG_CHECKING([whether SELinux support is requested])
118 AC_ARG_ENABLE(selinux-support,
119               AC_HELP_STRING([--enable-selinux-support],
120                              [enable SELinux support]),
121               selinux_support=$enableval, selinux_support=no)
122 AC_MSG_RESULT($selinux_support)
123
124
125 AC_MSG_CHECKING([whether the new iconv based code is requested])
126 AC_ARG_ENABLE(gnupg-iconv,
127               AC_HELP_STRING([--disable-gnupg-iconv],
128                              [disable the new iconv code]),
129               gnupg_use_iconv=$enableval, gnupg_use_iconv=yes)
130 AC_MSG_RESULT($gnupg_use_iconv)
131
132 dnl See if we are disabling any algorithms or features for a smaller
133 dnl binary
134
135 try_extensions=no
136
137 use_rsa=yes
138 use_idea=yes
139 use_cast5=yes
140 use_blowfish=yes
141 use_aes=yes
142 use_twofish=yes
143 use_sha256=yes
144 use_sha512=yes
145 use_bzip2=yes
146 use_exec=yes
147 card_support=yes
148 agent_support=yes
149 disable_keyserver_path=no
150
151 AC_ARG_ENABLE(minimal,
152    AC_HELP_STRING([--enable-minimal],[build the smallest gpg binary possible]),
153    use_rsa=no
154    use_idea=no
155    use_cast5=no
156    use_blowfish=no
157    use_aes=no
158    use_twofish=no
159    use_sha256=no
160    use_sha512=no
161    use_bzip2=no
162    use_exec=no
163    card_support=no
164    agent_support=no)
165
166
167 AC_MSG_CHECKING([whether OpenPGP card support is requested])
168 AC_ARG_ENABLE(card-support,
169               AC_HELP_STRING([--disable-card-support],
170                              [disable OpenPGP card support]),
171               card_support=$enableval)
172 AC_MSG_RESULT($card_support)
173
174
175 # Note that we may later disable the agent support based on the platform.
176 AC_MSG_CHECKING([whether gpg-agent support is requested])
177 AC_ARG_ENABLE(agent-support,
178               AC_HELP_STRING([--disable-agent-support],
179                              [disable gpg-agent support]),
180               agent_support=$enableval)
181 AC_MSG_RESULT($agent_support)
182
183
184 AC_MSG_CHECKING([whether to enable the RSA public key algorithm])
185 AC_ARG_ENABLE(rsa,
186    AC_HELP_STRING([--disable-rsa],[disable the RSA public key algorithm]),
187    use_rsa=$enableval)
188 AC_MSG_RESULT($use_rsa)
189 if test x"$use_rsa" = xyes ; then
190    AC_DEFINE(USE_RSA,1,[Define to include the RSA public key algorithm])
191 fi
192
193 AC_MSG_CHECKING([whether to enable the IDEA cipher])
194 AC_ARG_ENABLE(idea,
195    AC_HELP_STRING([--disable-idea],[disable the IDEA cipher]),
196    use_idea=$enableval)
197 AC_MSG_RESULT($use_idea)
198 if test x"$use_idea" = xyes ; then
199    AC_DEFINE(USE_IDEA,1,[Define to include the IDEA cipher])
200
201 # We don't need idea but some people claim that they need it for
202 # research etc., so we allow to place an idea source code into the
203 # cipher directory and statically link it if available, otherwise we
204 # link to a stub.  We don't use AC_CHECK_FILE to avoid caching.
205
206    AC_MSG_CHECKING([for idea cipher module])
207    tmp=""
208    if test -f $srcdir/cipher/idea.c; then 
209       IDEA_O=idea.o
210       tmp=idea
211    else
212       IDEA_O=idea-stub.o
213       tmp=no
214       try_extensions=yes
215    fi
216    AC_SUBST(IDEA_O)
217    AC_MSG_RESULT($tmp)
218 fi
219
220 AC_MSG_CHECKING([whether to enable the CAST5 cipher])
221 AC_ARG_ENABLE(cast5,
222    AC_HELP_STRING([--disable-cast5],[disable the CAST5 cipher]),
223    use_cast5=$enableval)
224 AC_MSG_RESULT($use_cast5)
225 if test x"$use_cast5" = xyes ; then
226    AC_DEFINE(USE_CAST5,1,[Define to include the CAST5 cipher])
227 fi
228
229 AC_MSG_CHECKING([whether to enable the BLOWFISH cipher])
230 AC_ARG_ENABLE(blowfish,
231    AC_HELP_STRING([--disable-blowfish],[disable the BLOWFISH cipher]),
232    use_blowfish=$enableval)
233 AC_MSG_RESULT($use_blowfish)
234 if test x"$use_blowfish" = xyes ; then
235    AC_DEFINE(USE_BLOWFISH,1,[Define to include the BLOWFISH cipher])
236 fi
237
238 AC_MSG_CHECKING([whether to enable the AES ciphers])
239 AC_ARG_ENABLE(aes,
240    AC_HELP_STRING([--disable-aes],[disable the AES, AES192, and AES256 ciphers]),
241    use_aes=$enableval)
242 AC_MSG_RESULT($use_aes)
243 if test x"$use_aes" = xyes ; then
244    AC_DEFINE(USE_AES,1,[Define to include the AES, AES192, and AES256 ciphers])
245 fi
246
247 AC_MSG_CHECKING([whether to enable the TWOFISH cipher])
248 AC_ARG_ENABLE(twofish,
249    AC_HELP_STRING([--disable-twofish],[disable the TWOFISH cipher]),
250    use_twofish=$enableval)
251 AC_MSG_RESULT($use_twofish)
252 if test x"$use_twofish" = xyes ; then
253    AC_DEFINE(USE_TWOFISH,1,[Define to include the TWOFISH cipher])
254 fi
255
256 AC_MSG_CHECKING([whether to enable the SHA-256 digest])
257 AC_ARG_ENABLE(sha256,
258    AC_HELP_STRING([--disable-sha256],[disable the SHA-256 digest]),
259    use_sha256=$enableval)
260 AC_MSG_RESULT($use_sha256)
261 if test x"$use_sha256" = xyes ; then
262    AC_DEFINE(USE_SHA256,1,[Define to include the SHA-256 digest])
263 fi
264
265 dnl SHA512 is defined only after we confirm 64-bit support later
266 AC_MSG_CHECKING([whether to enable the SHA-384 and SHA-512 digests])
267 AC_ARG_ENABLE(sha512,
268    AC_HELP_STRING([--disable-sha512],[disable the SHA-384 and SHA-512 digests]),
269    use_sha512=$enableval)
270 AC_MSG_RESULT($use_sha512)
271
272 dnl BZLIB is defined only after we confirm the library is available later
273 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
274 AC_ARG_ENABLE(bzip2,
275    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
276    use_bzip2=$enableval)
277 AC_MSG_RESULT($use_bzip2)
278
279 AC_MSG_CHECKING([whether to enable external program execution])
280 AC_ARG_ENABLE(exec,
281     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
282     use_exec=$enableval)
283 AC_MSG_RESULT($use_exec)
284 if test "$use_exec" = no ; then
285     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
286 fi
287
288 if test "$use_exec" = yes ; then
289   AC_MSG_CHECKING([whether to enable photo ID viewing])
290   AC_ARG_ENABLE(photo-viewers,
291       [  --disable-photo-viewers disable photo ID viewers],
292       [if test "$enableval" = no ; then
293          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
294       fi],enableval=yes)
295   gnupg_cv_enable_photo_viewers=$enableval
296   AC_MSG_RESULT($enableval)
297
298   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
299     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
300     AC_ARG_WITH(photo-viewer,
301         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
302         [if test "$withval" = yes ; then
303            withval=no
304         elif test "$withval" != no ; then
305            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
306                             [if set, restrict photo-viewer to this])
307         fi],withval=no)
308     AC_MSG_RESULT($withval)
309   fi
310
311   AC_MSG_CHECKING([whether to enable external keyserver helpers])
312   AC_ARG_ENABLE(keyserver-helpers,
313       [  --disable-keyserver-helpers  disable all external keyserver support],
314       [if test "$enableval" = no ; then
315          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
316                   [define to disable keyserver helpers])
317       fi],enableval=yes)
318   gnupg_cv_enable_keyserver_helpers=$enableval
319   AC_MSG_RESULT($enableval)
320
321   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
322 dnl LDAP is defined only after we confirm the library is available later
323     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
324     AC_ARG_ENABLE(ldap,
325       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
326       try_ldap=$enableval, try_ldap=yes)
327     AC_MSG_RESULT($try_ldap)
328
329     AC_MSG_CHECKING([whether HKP keyserver support is requested])
330     AC_ARG_ENABLE(hkp,
331       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
332       try_hkp=$enableval, try_hkp=yes)
333     AC_MSG_RESULT($try_hkp)
334
335     AC_MSG_CHECKING([whether finger key fetching support is requested])
336     AC_ARG_ENABLE(finger,
337       AC_HELP_STRING([--disable-finger],
338         [disable finger key fetching interface only]),
339       try_finger=$enableval, try_finger=yes)
340     AC_MSG_RESULT($try_finger)
341
342     AC_MSG_CHECKING([whether email keyserver support is requested])
343     AC_ARG_ENABLE(mailto,
344       AC_HELP_STRING([--enable-mailto],
345         [enable email keyserver interface only]),
346       try_mailto=$enableval, try_mailto=no)
347     AC_MSG_RESULT($try_mailto)
348     fi
349
350     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
351     AC_ARG_ENABLE(keyserver-path,
352       AC_HELP_STRING([--disable-keyserver-path],
353         [disable the exec-path option for keyserver helpers]),
354       [if test "$enableval" = no ; then
355          disable_keyserver_path=yes
356       fi],enableval=yes)
357     AC_MSG_RESULT($enableval)
358   fi
359
360 AC_MSG_CHECKING([whether the included zlib is requested])
361 AC_ARG_WITH(included-zlib,
362     [  --with-included-zlib    use the zlib code included here],
363 [g10_force_zlib="$withval"], [g10_force_zlib=no] )
364 AC_MSG_RESULT($g10_force_zlib)
365
366 dnl
367 dnl Check for the key/uid cache size.  This can't be zero, but can be
368 dnl pretty small on embedded systems.
369 dnl
370 AC_MSG_CHECKING([for the size of the key and uid cache])
371 AC_ARG_ENABLE(key-cache,
372         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
373
374 if test "$enableval" = "no"; then
375    enableval=5
376 elif test "$enableval" = "yes" || test "$enableval" = ""; then
377    enableval=4096
378 fi
379
380 changequote(,)dnl
381 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
382 changequote([,])dnl
383
384 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
385    AC_MSG_ERROR([invalid key-cache size])
386 fi
387
388 AC_MSG_RESULT($key_cache_size)
389 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
390
391 dnl
392 dnl Check whether we want to use Linux capabilities
393 dnl
394 AC_MSG_CHECKING([whether use of capabilities is requested])
395 AC_ARG_WITH(capabilities,
396     [  --with-capabilities     use linux capabilities [default=no]],
397 [use_capabilities="$withval"],[use_capabilities=no])
398 AC_MSG_RESULT($use_capabilities)
399
400 # To avoid double inclusion of config.h which might happen at some
401 # places, we add the usual double inclusion protection.
402 AH_TOP([
403 #ifndef GNUPG_CONFIG_H_INCLUDED
404 #define GNUPG_CONFIG_H_INCLUDED
405 ])
406
407 AH_BOTTOM([
408 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
409 #define EXEC_TEMPFILE_ONLY
410 #endif
411
412 /* This is the major version number of GnuPG so that
413    source included files can test for this. */
414 #define GNUPG_MAJOR_VERSION 1
415
416 #include "g10defs.h"
417
418 #endif /*GNUPG_CONFIG_H_INCLUDED*/
419 ])
420
421 AM_MAINTAINER_MODE
422
423 dnl Checks for programs.
424
425 AC_PROG_MAKE_SET
426 AM_SANITY_CHECK
427 missing_dir=`cd $ac_aux_dir && pwd`
428 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
429 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
430 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
431 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
432 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
433 AC_PROG_CC
434 AC_PROG_CPP
435 AC_PROG_RANLIB
436 AC_CHECK_TOOL(AR, ar, :)
437 AC_PATH_PROG(PERL,"perl")
438 AC_ISC_POSIX
439 AC_SYS_LARGEFILE
440 AC_PROG_INSTALL
441 AC_PROG_AWK
442 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
443 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
444 GNUPG_CHECK_FAQPROG
445 GNUPG_CHECK_DOCBOOK_TO_TEXI
446 GNUPG_CHECK_USTAR
447
448 MPI_OPT_FLAGS=""
449
450 try_gettext=yes
451 have_dosish_system=no
452 need_dlopen=yes
453 case "${host}" in
454     *-mingw32*)
455         # special stuff for Windoze NT
456         ac_cv_have_dev_random=no
457         AC_DEFINE(USE_ONLY_8DOT3,1,
458                   [set this to limit filenames to the 8.3 format])
459         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
460                   [defined if we must run on a stupid file system])
461         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
462                   [because the Unix gettext has too much overhead on
463                    MingW32 systems and these systems lack Posix functions,
464                    we use a simplified version of gettext])
465         AC_DEFINE(HAVE_W32_SYSTEM,1,
466                   [Defined if we run on a W32 API based system])
467         disable_keyserver_path=yes
468         have_dosish_system=yes
469         need_dlopen=no
470         try_gettext="no"
471         agent_support=no
472         use_simple_gettext=yes
473         have_w32_system=yes
474         ;;
475     i?86-emx-os2 | i?86-*-os2*emx )
476         # OS/2 with the EMX environment
477         ac_cv_have_dev_random=no
478         AC_DEFINE(HAVE_DRIVE_LETTERS)
479         have_dosish_system=yes
480         try_gettext="no"
481         agent_support=no
482         ;;
483
484     i?86-*-msdosdjgpp*)
485         # DOS with the DJGPP environment
486         ac_cv_have_dev_random=no
487         AC_DEFINE(HAVE_DRIVE_LETTERS)
488         have_dosish_system=yes
489         try_gettext="no"
490         agent_support=no
491         ;;
492
493     *-*-hpux*)
494         if test -z "$GCC" ; then
495             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
496         fi
497         ;;
498     *-dec-osf4*)
499         if test -z "$GCC" ; then
500             # Suppress all warnings
501             # to get rid of the unsigned/signed char mismatch warnings.
502             CFLAGS="$CFLAGS -w"
503         fi
504         ;;
505     *-dec-osf5*)
506         if test -z "$GCC" ; then
507             # Use the newer compiler `-msg_disable ptrmismatch' to
508             # get rid of the unsigned/signed char mismatch warnings.
509             # Using this may hide other pointer mismatch warnings, but
510             # it at least lets other warning classes through
511             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
512         fi
513         ;;
514     m68k-atari-mint)
515         ;;
516     *)
517        ;;
518 esac
519
520 if test "$have_dosish_system" = yes; then
521    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
522              [defined if we run on some of the PCDOS like systems 
523               (DOS, Windoze. OS/2) with special properties like
524               no file modes])
525 fi
526 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
527
528 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
529 AM_CONDITIONAL(HAVE_W32_SYSTEM, test x"$have_w32_system" = xyes)
530
531 if test "$disable_keyserver_path" = yes; then
532     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
533               [define to disable exec-path for keyserver helpers])
534 fi
535
536 AC_SUBST(MPI_OPT_FLAGS)
537 GNUPG_SYS_SYMBOL_UNDERSCORE
538
539 dnl These need to go after AC_PROG_CC so that $EXEEXT is defined
540 if test x"$try_hkp" = xyes ; then
541   AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
542 fi
543
544 if test x"$try_finger" = xyes ; then
545   AC_SUBST(GPGKEYS_FINGER,"gpgkeys_finger$EXEEXT")
546 fi
547
548 dnl Must check for network library requirements before doing link tests
549 dnl for ldap, for example. If ldap libs are static (or dynamic and without
550 dnl ELF runtime link paths), then link will fail and LDAP support won't
551 dnl be detected.
552
553 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
554         [NETLIBS="-lnsl $NETLIBS"]))
555 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
556         [NETLIBS="-lsocket $NETLIBS"]))
557
558 dnl Now try for the resolver functions so we can use DNS for SRV, PKA,
559 dnl and CERT.
560
561 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
562    AC_ARG_ENABLE(dns-srv,
563       AC_HELP_STRING([--disable-dns-srv],
564         [disable the use of DNS SRV in HKP and HTTP]),
565       use_dns_srv=$enableval,use_dns_srv=yes)
566 fi
567
568 AC_ARG_ENABLE(dns-pka,
569    AC_HELP_STRING([--disable-dns-pka],
570         [disable the use of PKA records in DNS]),
571    use_dns_pka=$enableval,use_dns_pka=yes)
572
573 AC_ARG_ENABLE(dns-cert,
574    AC_HELP_STRING([--disable-dns-cert],
575         [disable the use of CERT records in DNS]),
576    use_dns_cert=$enableval,use_dns_cert=yes)
577
578 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
579   _srv_save_libs=$LIBS
580   LIBS=""
581   # the double underscore thing is a glibc-ism?
582   AC_SEARCH_LIBS(res_query,resolv bind,,
583                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
584   AC_SEARCH_LIBS(dn_expand,resolv bind,,
585                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
586   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
587                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
588
589   # Make sure that the BIND 4 resolver interface is workable before
590   # enabling any code that calls it.  At some point I'll rewrite the
591   # code to use the BIND 8 resolver API.
592
593   AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
594 #include <netinet/in.h>
595 #include <arpa/nameser.h>
596 #include <resolv.h>],
597 [[unsigned char answer[PACKETSZ]; res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);]])],have_resolver=yes)
598
599   if test x"$have_resolver" = xyes ; then
600      SRVLIBS=$LIBS
601
602      if test x"$use_dns_srv" = xyes ; then
603         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
604      fi
605
606      if test x"$use_dns_pka" = xyes ; then
607         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
608      fi
609
610      if test x"$use_dns_cert" = xyes ; then
611         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
612      fi
613   else
614      use_dns_srv=no
615      use_dns_pka=no
616      use_dns_cert=no
617   fi
618
619   LIBS=$_srv_save_libs
620 fi
621
622 AC_SUBST(SRVLIBS)
623
624 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
625
626 # Check for LDAP
627
628 if test "$try_ldap" = yes ; then
629    GNUPG_CHECK_LDAP($NETLIBS)
630 fi
631
632 # Which keyserver helpers are we building?
633
634 AC_ARG_ENABLE(old-keyserver-helpers,
635    AC_HELP_STRING([--enable-old-keyserver-helpers],[enable old keyserver helpers]),old_ks=$enableval,old_ks=no)
636
637 if test "$old_ks" = yes ; then
638    AC_SUBST(GPGKEYS_HTTP,"gpgkeys_http$EXEEXT")
639 else
640    LIBCURL_CHECK_CONFIG([yes],,[with_curl=yes],[fake_curl=yes])
641    AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
642 fi
643
644 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
645 AM_CONDITIONAL(WITH_CURL,test x"$with_curl" = xyes || test x"$fake_curl" = xyes)
646
647 if test x"$fake_curl" = xyes ; then
648    AC_DEFINE(FAKE_CURL,1,[define to fake the libcurl API internally])
649 fi
650
651 dnl This isn't necessarily sendmail itself, but anything that gives a
652 dnl sendmail-ish interface to the outside world.  That includes qmail,
653 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
654
655 if test "$try_mailto" = yes ; then
656   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
657
658   if test "$with_mailprog" = yes ; then
659     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
660     if test "$ac_cv_path_SENDMAIL" ; then
661       GPGKEYS_MAILTO="gpgkeys_mailto"
662     fi
663   elif test "$with_mailprog" != no ; then
664     AC_MSG_CHECKING([for a mail transport program])
665     AC_SUBST(SENDMAIL,$with_mailprog)
666     AC_MSG_RESULT($with_mailprog)
667     GPGKEYS_MAILTO="gpgkeys_mailto"
668   fi
669 fi
670
671 AC_SUBST(GPGKEYS_MAILTO)
672
673 case "${host}" in
674     *-mingw32*)
675         PRINTABLE_OS_NAME="MingW32"
676         ;;
677     *-*-cygwin*)
678         PRINTABLE_OS_NAME="Cygwin"
679         ;;
680     i?86-emx-os2 | i?86-*-os2*emx )
681         PRINTABLE_OS_NAME="OS/2"
682         ;;
683     i?86-*-msdosdjgpp*)
684         PRINTABLE_OS_NAME="MSDOS/DJGPP"
685         try_extensions=no
686         ;;
687     *-linux*)
688         PRINTABLE_OS_NAME="GNU/Linux"
689         ;;
690     *)
691         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
692         ;;
693 esac
694 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
695                    [A human readable text with the name of the OS])
696
697
698 #
699 # 1. Set names of random devices
700 #
701 NAME_OF_DEV_RANDOM="/dev/random"
702 NAME_OF_DEV_URANDOM="/dev/urandom"
703 case "${host}" in
704     *-openbsd*)
705         NAME_OF_DEV_RANDOM="/dev/srandom"
706         NAME_OF_DEV_URANDOM="/dev/urandom"
707         ;;
708 esac
709 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
710                    [defined to the name of the strong random device])
711 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
712                    [defined to the name of the weaker random device])
713 AC_SUBST(MPI_OPT_FLAGS)
714
715
716 dnl Checks for libraries.
717
718 AM_GNU_GETTEXT_VERSION(0.14.1)
719 if test "$try_gettext" = yes; then
720   AM_GNU_GETTEXT(,[need-ngettext])
721
722   # gettext requires some extra checks.  These really should be part of
723   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
724   # function checks to here.
725
726   AC_CHECK_FUNCS(strchr)
727 else
728   USE_NLS=no
729   USE_INCLUDED_LIBINTL=no
730   BUILD_INCLUDED_LIBINTL=no
731   AC_SUBST(USE_NLS)
732   AC_SUBST(USE_INCLUDED_LIBINTL)
733   AC_SUBST(BUILD_INCLUDED_LIBINTL)
734   AM_PO_SUBDIRS
735 fi
736
737 if test "$try_extensions" = yes || test x"$card_support" = xyes ; then
738   if test "$need_dlopen" = yes; then
739     _dl_save_libs=$LIBS
740     LIBS=""
741     AC_SEARCH_LIBS(dlopen,dl,found_dlopen=yes)
742     if test x"$found_dlopen" = "xyes" ; then
743       AC_DEFINE(HAVE_DL_DLOPEN,1,
744                 [Defined when the dlopen function family is available])
745       DLLIBS=$LIBS
746     else
747       if test "$try_extensions" = yes ; then
748          AC_MSG_NOTICE([dlopen not found.  Disabling extensions.])
749          try_extensions=no
750       fi
751   
752       if test "$card_support" = yes ; then
753          AC_MSG_WARN([dlopen not found.  Disabling OpenPGP card support.])
754          card_support=no
755       fi
756     fi
757     LIBS=$_dl_save_libs
758   fi
759 fi
760
761 AC_SUBST(DLLIBS)
762
763 if test "$card_support" = yes ; then
764   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include OpenPGP card support])
765 fi
766
767 if test "$agent_support" = yes ; then
768   AC_DEFINE(ENABLE_AGENT_SUPPORT,1,[Define to include gpg-agent support])
769 fi
770
771 if test "$try_extensions" = yes ; then
772   AC_DEFINE(USE_DYNAMIC_LINKING,1,[Define to enable the use of extensions])
773 fi
774
775 if test "$selinux_support" = yes ; then
776   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
777 fi
778
779 if test "$gnupg_use_iconv" = yes ; then
780   AC_DEFINE(USE_GNUPG_ICONV,1,[Define to use the new iconv based code])
781 fi
782
783 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
784 AM_CONDITIONAL(ENABLE_AGENT_SUPPORT, test "$agent_support" = yes)
785
786 dnl Checks for header files.
787 AC_HEADER_STDC
788 AC_CHECK_HEADERS([unistd.h langinfo.h termio.h locale.h getopt.h pwd.h])
789
790 # Note that we do not check for iconv here because this is done anyway
791 # by the gettext checks and thus it allows us to disable the use of
792 # iconv by using --disable-nls.
793
794 dnl Checks for typedefs, structures, and compiler characteristics.
795 AC_C_CONST
796 AC_C_INLINE
797 AC_C_VOLATILE
798 AC_TYPE_SIZE_T
799 AC_TYPE_MODE_T
800 AC_TYPE_SIGNAL
801 AC_DECL_SYS_SIGLIST
802
803 GNUPG_CHECK_ENDIAN
804
805 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
806 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
807 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
808 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
809 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
810
811 AC_CHECK_SIZEOF(unsigned short)
812 AC_CHECK_SIZEOF(unsigned int)
813 AC_CHECK_SIZEOF(unsigned long)
814 AC_CHECK_SIZEOF(unsigned long long)
815
816 # Ensure that we have UINT64_C before we bother to check for uint64_t
817 gt_HEADER_INTTYPES_H
818 AC_CACHE_CHECK([for UINT64_C], [gnupg_cv_uint64_c_works],
819                AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>],[
820 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
821
822 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
823    AC_CHECK_SIZEOF(uint64_t)
824 fi
825
826 if test "$ac_cv_sizeof_unsigned_short" = "0" \
827    || test "$ac_cv_sizeof_unsigned_int" = "0" \
828    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
829     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
830 fi
831
832 dnl Do we have any 64-bit data types?
833 if test x"$use_sha512" = xyes \
834    && test "$ac_cv_sizeof_unsigned_int" != "8" \
835    && test "$ac_cv_sizeof_unsigned_long" != "8" \
836    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
837    && test x"$ac_cv_sizeof_uint64_t" != "x8"; then
838     AC_MSG_NOTICE([No 64-bit types.  Disabling SHA-384 and SHA-512.])
839     use_sha512=no
840 fi
841
842 if test x"$use_sha512" ; then
843     AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
844 fi
845
846 AM_CONDITIONAL(USE_SHA512, test x"$use_sha512" = xyes)
847
848 dnl Checks for library functions.
849 AC_CHECK_DECLS(getpagesize)
850 AC_FUNC_FSEEKO
851 AC_FUNC_VPRINTF
852 AC_FUNC_FORK
853 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
854 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times unsetenv getpwnam getpwuid)
855 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
856 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
857 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
858 AC_REPLACE_FUNCS(mkdtemp timegm isascii memrchr)
859
860 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
861
862 # See if getopt is in libiberty.  This is of course not optimal since
863 # it might be somewhere other than libiberty, but does cover the
864 # mingw32 case.
865
866 AC_CHECK_FUNC(getopt,,AC_CHECK_LIB(iberty,getopt,AC_SUBST(GETOPT,"-liberty")))
867
868 #
869 # check for gethrtime and run a testprogram to see whether
870 # it is broken.  It has been reported that some Solaris and HP UX systems 
871 # raise an SIGILL
872 #
873 AC_CACHE_CHECK([for gethrtime], 
874                [gnupg_cv_func_gethrtime],
875                [AC_TRY_LINK([#include <sys/times.h>],[
876                    hrtime_t tv;
877                    tv = gethrtime();
878                  ],
879                  [gnupg_cv_func_gethrtime=yes],
880                  [gnupg_cv_func_gethrtime=no])
881                ])
882 if test $gnupg_cv_func_gethrtime = yes; then
883      AC_DEFINE([HAVE_GETHRTIME], 1,
884                [Define if you have the `gethrtime(2)' function.])
885      AC_CACHE_CHECK([whether gethrtime is broken], 
886                [gnupg_cv_func_broken_gethrtime],
887                [AC_TRY_RUN([
888                    #include <sys/times.h>
889                    int main () {
890                    hrtime_t tv;
891                    tv = gethrtime(); 
892                  }
893                  ],
894                  [gnupg_cv_func_broken_gethrtime=no],
895                  [gnupg_cv_func_broken_gethrtime=yes],
896                  [gnupg_cv_func_broken_gethrtime=assume-no])
897                 ])
898     if test $gnupg_cv_func_broken_gethrtime = yes; then
899       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
900       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
901     fi
902 fi
903      
904
905 GNUPG_CHECK_MLOCK
906 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
907
908 dnl
909 dnl Check whether we can use Linux capabilities as requested
910 dnl
911 if test "$use_capabilities" = "yes" ; then
912
913 AC_MSG_WARN([[
914 ***
915 *** WARNING: using capabilities with GnuPG is experimental code!
916 ***]])
917
918 use_capabilities=no
919 AC_CHECK_HEADERS(sys/capability.h)
920 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
921   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
922   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
923      AC_DEFINE(USE_CAPABILITIES,1,
924                [define if capabilities should be used])
925      AC_SUBST(CAPLIBS,"-lcap")
926      use_capabilities=yes
927   fi
928 fi
929 if test "$use_capabilities" = "no" ; then
930     AC_MSG_WARN([[
931 ***
932 *** The use of capabilities on this system is not possible.
933 *** You need a recent Linux kernel and some patches:
934 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
935 ***   fcap-module-990613.tar.gz     (kernel module)
936 ***   libcap-1.92.tar.gz            (user mode library and utilities)
937 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
938 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
939 ***]])
940 fi
941 fi
942
943
944 GNUPG_CHECK_IPC
945 if test "$ac_cv_header_sys_shm_h" = "yes"; then
946   AC_DEFINE(USE_SHM_COPROCESSING,1,
947             [define if the shared memory interface should be made available])
948 fi
949
950 dnl
951 dnl check whether we have a random device
952 dnl
953 if test "$try_dev_random" = yes ; then
954     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
955     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
956       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
957     if test "$ac_cv_have_dev_random" = yes; then
958         AC_DEFINE(HAVE_DEV_RANDOM,1,
959                  [defined if the system supports a random device] )
960     fi
961 else
962     AC_MSG_CHECKING(for random device)
963     ac_cv_have_dev_random=no
964     AC_MSG_RESULT(has been disabled)
965 fi
966
967
968 dnl
969 dnl Figure out the default random module.
970 dnl
971 random_modules=""
972 if test "$use_static_rnd" = default; then
973      if test "$ac_cv_have_dev_random" = yes; then
974         random_modules="rndlinux"
975      else
976          case "${host}" in
977             *-mingw32*|*-*-cygwin*)
978                 random_modules="rndw32"
979                 ;;
980             i?86-emx-os2|i?86-*-os2*emx)
981                 random_modules="rndos2"
982                 ;;
983             m68k-atari-mint)
984                 random_modules="rndatari"
985                 ;;
986             i?86-*-msdosdjgpp*)
987                 :
988                 ;;
989             *)
990                 random_modules="rndlinux rndegd rndunix"
991                 AC_DEFINE(USE_ALL_RANDOM_MODULES, 1, 
992                           [Allow to select random modules at runtime.])
993                 ;;
994          esac
995      fi
996 else
997   if test "$use_static_rnd" = auto; then
998      random_modules="rndlinux rndegd rndunix"
999      AC_DEFINE(USE_ALL_RANDOM_MODULES, 1)
1000   else
1001      random_modules="rnd$use_static_rnd";
1002   fi
1003 fi
1004
1005 if test -z "$random_modules"; then
1006    AC_MSG_ERROR(no random module available)
1007 fi
1008 print_egd_warning=no
1009 for rndmod in $random_modules "" ; do
1010   case "$rndmod" in
1011     rndlinux)
1012          AC_DEFINE(USE_RNDLINUX,1, 
1013                   [Defined if the /dev/random based RNG should be used.])
1014          use_rndlinux=yes
1015          ;;
1016     rndunix)
1017          AC_DEFINE(USE_RNDUNIX,1, 
1018                   [Defined if the default Unix RNG should be used.])
1019          print_egd_warning=yes
1020          use_rndunix=yes
1021           ;;
1022     rndegd)
1023          AC_DEFINE(USE_RNDEGD,1, 
1024                   [Defined if the EGD based RNG should be used.])
1025          use_rndegd=yes
1026          ;;
1027     rndw32)
1028          AC_DEFINE(USE_RNDW32,1, 
1029                   [Defined if the Windows specific RNG should be used.])
1030          use_rndw32=yes
1031         ;;
1032    esac
1033 done
1034
1035 AM_CONDITIONAL(USE_RNDLINUX, test "$use_rndlinux" = yes)
1036 AM_CONDITIONAL(USE_RNDUNIX,  test "$use_rndunix" = yes)
1037 AM_CONDITIONAL(USE_RNDEGD,   test "$use_rndegd" = yes)
1038 AM_CONDITIONAL(USE_RNDW32,   test "$use_rndw32" = yes)
1039
1040 dnl setup assembler stuff
1041 AC_MSG_CHECKING(for mpi assembler functions)
1042 if test -f $srcdir/mpi/config.links ; then
1043     . $srcdir/mpi/config.links
1044     AC_CONFIG_LINKS("$mpi_ln_list")
1045     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
1046     ac_cv_mpi_sflags="$mpi_sflags"
1047     ac_cv_mpi_config_done="yes"
1048     AC_MSG_RESULT(done)
1049 else
1050     AC_MSG_RESULT(failed)
1051     AC_MSG_ERROR([mpi/config.links missing!])
1052 fi
1053 MPI_EXTRA_ASM_OBJS=""
1054 show_extraasm=""
1055 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
1056 for i in $ac_cv_mpi_extra_asm_modules; do
1057     show_extraasm="$show_extraasm $i"
1058     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
1059 done
1060 fi
1061 AC_SUBST(MPI_EXTRA_ASM_OBJS)
1062 MPI_SFLAGS="$ac_cv_mpi_sflags"
1063 AC_SUBST(MPI_SFLAGS)
1064
1065 # Sanity check regex.  Tests adapted from mutt.
1066
1067 AC_MSG_CHECKING([whether regular expression support is requested])
1068 AC_ARG_ENABLE(regex,
1069   AC_HELP_STRING([--disable-regex],
1070     [do not handle regular expressions in trust signatures]),
1071   use_regex=$enableval, use_regex=yes)
1072 AC_MSG_RESULT($use_regex)
1073
1074 if test "$use_regex" = yes ; then
1075   AC_MSG_CHECKING([whether the included regex lib is requested])
1076   AC_ARG_WITH(included-regex,
1077       [  --with-included-regex   use the included GNU regex library],
1078       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
1079   AC_MSG_RESULT($gnupg_cv_included_regex)
1080
1081   if test $gnupg_cv_included_regex = no ; then
1082      # Does the system have regex functions at all?
1083      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
1084                            gnupg_cv_included_regex=yes)
1085   fi
1086
1087   if test $gnupg_cv_included_regex = no ; then
1088      AC_CACHE_CHECK([whether your system's regexp library is broken],
1089        [gnupg_cv_regex_broken],
1090        AC_TRY_RUN([
1091 #include <unistd.h>
1092 #include <regex.h>
1093 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1094        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1095
1096      if test $gnupg_cv_regex_broken = yes ; then
1097       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
1098       gnupg_cv_included_regex=yes
1099      fi
1100   fi
1101
1102   if test $gnupg_cv_included_regex = yes; then
1103      AC_DEFINE(USE_INTERNAL_REGEX,1,[ Define if you want to use the included regex lib ])
1104   fi
1105 else
1106   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1107 fi
1108
1109 AM_CONDITIONAL(USE_INTERNAL_REGEX, test x"$gnupg_cv_included_regex" = xyes)
1110
1111 dnl Do we have zlib? Must do it here because Solaris failed
1112 dnl when compiling a conftest (due to the "-lz" from LIBS).
1113 use_local_zlib=yes
1114 if test "$g10_force_zlib" = "yes"; then
1115   :
1116 else
1117   _cppflags="${CPPFLAGS}"
1118   _ldflags="${LDFLAGS}"
1119
1120   AC_ARG_WITH(zlib,
1121   [  --with-zlib=DIR         use libz in DIR],[
1122     if test -d "$withval"; then
1123       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1124       LDFLAGS="${LDFLAGS} -L$withval/lib"
1125     fi
1126   ])
1127
1128   AC_CHECK_HEADER(zlib.h,
1129       AC_CHECK_LIB(z, deflateInit2_,
1130        use_local_zlib=no
1131        ZLIBS="-lz",
1132        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1133        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1134 fi
1135
1136 if test "$use_local_zlib" = yes ; then
1137     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
1138     AC_CONFIG_LINKS(zlib.h:zlib/zlib.h zconf.h:zlib/zconf.h )
1139     ZLIBS="../zlib/libzlib.a"
1140 else
1141     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
1142 fi
1143
1144 if test "$use_bzip2" = yes ; then
1145   _cppflags="${CPPFLAGS}"
1146   _ldflags="${LDFLAGS}"
1147   AC_ARG_WITH(bzip2,
1148      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1149       [
1150       if test -d "$withval" ; then
1151         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1152         LDFLAGS="${LDFLAGS} -L$withval/lib"
1153       fi
1154       ],withval="")
1155
1156 # Checking alongside stdio.h as an early version of bzip2 (1.0)
1157 # required stdio.h to be included before bzlib.h, and Solaris 9 is
1158 # woefully out of date.
1159
1160   if test "$withval" != no ; then
1161      AC_CHECK_HEADER(bzlib.h,
1162         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1163           [
1164           have_bz2=yes
1165           ZLIBS="$ZLIBS -lbz2"
1166           AC_DEFINE(HAVE_BZIP2,1,
1167                   [Defined if the bz2 compression library is available])
1168           ],
1169           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1170           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1171   fi
1172 fi
1173
1174 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1175 AC_SUBST(ZLIBS)
1176
1177 # libusb allows us to use the integrated CCID smartcard reader driver.
1178 GNUPG_CHECK_LIBUSB
1179
1180 # Check for readline support
1181 GNUPG_CHECK_READLINE
1182
1183 # Allow users to append something to the version string without
1184 # flagging it as development version.  The user version parts is
1185 # considered everything after a dash. 
1186 if test "$development_version" != yes; then
1187   changequote(,)dnl
1188   tmp_pat='[a-zA-Z]'
1189   changequote([,])dnl
1190   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1191     development_version=yes
1192   fi
1193 fi
1194 if test "$development_version" = yes; then
1195     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1196             [Defined if this is not a regular release])
1197 fi
1198
1199 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1200
1201
1202 # add some extra libs here so that previous tests don't fail for
1203 # mysterious reasons - the final link step should bail out. 
1204 case "${host}" in
1205     *-mingw32*)
1206 dnl      NETLIBS="$NETLIBS -lwsock32"
1207         W32LIBS="-lwsock32"
1208         ;;
1209     *)
1210        ;;
1211 esac
1212
1213 AC_SUBST(NETLIBS)
1214 AC_SUBST(W32LIBS)
1215
1216 # Special options used with gcc.
1217 if test "$GCC" = yes; then
1218     # Note that it is okay to use CFLAGS here because this are just
1219     # warning options and the user should have a chance of overriding
1220     #them.
1221     if test "$USE_MAINTAINER_MODE" = "yes"; then
1222         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1223         CFLAGS="$CFLAGS -Wformat-nonliteral"
1224     else
1225         CFLAGS="$CFLAGS -Wall"
1226     fi
1227
1228     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1229
1230     _gcc_cflags_save=$CFLAGS
1231     CFLAGS="-Wno-pointer-sign"
1232
1233     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1234     AC_MSG_RESULT($_gcc_psign)
1235
1236     CFLAGS=$_gcc_cflags_save;
1237
1238     if test x"$_gcc_psign" = xyes ; then
1239        CFLAGS="$CFLAGS -Wno-pointer-sign"
1240     fi
1241
1242     # Non exec stack hack.  Fixme: Write a test to check whether as
1243     # can cope with it and use the enable-noexecstack option only to
1244     # disable it in case it is required on sime platforms.
1245     if test "$noexecstack_support" = yes; then
1246         NOEXECSTACK_FLAGS="-Wa,--noexecstack"
1247     fi
1248 fi
1249 AC_SUBST(NOEXECSTACK_FLAGS)
1250
1251
1252 if test "$print_egd_warning" = yes; then
1253   AC_MSG_WARN([[
1254 ***
1255 *** The performance of the UNIX random gatherer module is not very good
1256 *** and it does not keep the entropy pool over multiple invocations of
1257 *** GnuPG.  The suggested way to overcome this problem is to use the
1258 ***
1259 ***               Entropy Gathering Daemon (EGD)
1260 ***
1261 *** which provides a entropy source for the whole system.  It is written
1262 *** in Perl and available at the GnuPG FTP servers.  For more information
1263 *** consult the GnuPG webpages:
1264 ***
1265 ***           http://www.gnupg.org/download/#EGD
1266 ***
1267 *** You may want to run ./configure with --enable-static-rnd=egd or
1268 *** --enable-static-rnd=auto to use it.
1269 ***]])
1270 fi
1271
1272 # Note the \\\\ for backslashes.  Autoconf eats one layer, leaving \\
1273
1274 AC_CONFIG_COMMANDS(g10defs.h,[[
1275 cat >g10defs.tmp <<G10EOF
1276 /* Generated automatically by configure */
1277 #ifdef HAVE_DRIVE_LETTERS
1278 #define G10_LOCALEDIR     "c:\\\\lib\\\\gnupg\\\\locale"
1279 #define GNUPG_LIBDIR      "c:\\\\lib\\\\gnupg"
1280 #define GNUPG_LIBEXECDIR  "c:\\\\lib\\\\gnupg"
1281 #define GNUPG_DATADIR     "c:\\\\lib\\\\gnupg"
1282 #define GNUPG_HOMEDIR     "c:\\\\gnupg"
1283 #else
1284 #define G10_LOCALEDIR     "${datadir}/locale"
1285 #define GNUPG_LIBDIR      "${libdir}/gnupg"
1286 #define GNUPG_DATADIR     "${datadir}/gnupg"
1287 #ifdef __VMS
1288 #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
1289 #else
1290 #define GNUPG_HOMEDIR "~/.gnupg" 
1291 #endif
1292 #endif
1293 /* those are here to be redefined by handcrafted g10defs.h.
1294    Please note that the string version must not contain more
1295    than one character because the using code assumes strlen()==1 */
1296 #ifdef HAVE_DOSISH_SYSTEM
1297 #define DIRSEP_C '\\\\'
1298 #define EXTSEP_C '.'
1299 #define DIRSEP_S "\\\\"
1300 #define EXTSEP_S "."
1301 #define PATHSEP_C ';'
1302 #define PATHSEP_S ";"
1303 #else
1304 #define DIRSEP_C '/'
1305 #define EXTSEP_C '.'
1306 #define DIRSEP_S "/"
1307 #define EXTSEP_S "."
1308 #define PATHSEP_C ':'
1309 #define PATHSEP_S ":"
1310 #endif
1311 /* This is the same as VERSION, but should be overridden if the
1312    platform cannot handle things like dots'.' in filenames.  Set
1313    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
1314    uses for dots and dashes. */
1315 #define SAFE_VERSION      VERSION
1316 #define SAFE_VERSION_DOT  '.'
1317 #define SAFE_VERSION_DASH '-'
1318 G10EOF
1319 cat mpi/mpi-asm-defs.h >>g10defs.tmp 
1320 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
1321     echo "g10defs.h is unchanged"
1322     rm -f g10defs.tmp
1323 else
1324     rm -f g10defs.h
1325     mv g10defs.tmp g10defs.h
1326     echo "g10defs.h created"
1327 fi
1328 ]],[[
1329 prefix=$prefix
1330 exec_prefix=$exec_prefix
1331 libdir=$libdir
1332 libexecdir=$libexecdir
1333 datadir=$datadir
1334 DATADIRNAME=$DATADIRNAME
1335 ]])
1336
1337
1338 AC_CONFIG_FILES([
1339 Makefile
1340 m4/Makefile
1341 intl/Makefile
1342 po/Makefile.in
1343 util/Makefile
1344 mpi/Makefile
1345 cipher/Makefile
1346 g10/Makefile
1347 keyserver/Makefile
1348 keyserver/gpgkeys_mailto
1349 keyserver/gpgkeys_test
1350 doc/Makefile
1351 tools/Makefile
1352 tools/gpg-zip
1353 zlib/Makefile
1354 checks/Makefile
1355 ])
1356 AC_OUTPUT
1357
1358 # Give some feedback
1359 echo
1360 echo   "                Configured for: $PRINTABLE_OS_NAME ($host)"
1361 if test -n "$show_extraasm"; then
1362   echo "  Extra cpu specific functions:$show_extraasm"
1363 fi
1364 echo