f008d23e7fa6dffd174829126d6c0059544b569c
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
3 #               2008, 2009, 2010, 2011 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 m4_define([my_full_version], [my_version[]m4_if(my_issvn,[yes],
35           [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])])
36
37 AC_INIT([gnupg],[my_full_version], [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.10
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.5.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.1.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.2.0
53
54 NEED_NPTH_API=1
55 NEED_NPTH_VERSION=0.0
56
57
58 PACKAGE=$PACKAGE_NAME
59 PACKAGE_GT=${PACKAGE_NAME}2
60 VERSION=$PACKAGE_VERSION
61
62 AC_CONFIG_AUX_DIR(scripts)
63 AC_CONFIG_SRCDIR(sm/gpgsm.c)
64 AM_CONFIG_HEADER(config.h)
65 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
66 AC_CANONICAL_HOST
67 AB_INIT
68
69 AC_GNU_SOURCE
70
71 # Some status variables.
72 have_gpg_error=no
73 have_libgcrypt=no
74 have_libassuan=no
75 have_ksba=no
76 have_npth=no
77 have_libusb=no
78 have_adns=no
79
80 use_zip=yes
81 use_bzip2=yes
82 use_exec=yes
83 disable_keyserver_path=no
84 use_ccid_driver=yes
85 use_standard_socket=yes
86 dirmngr_auto_start=no
87
88 try_ks_ldap=no
89
90 GNUPG_BUILD_PROGRAM(gpg, yes)
91 GNUPG_BUILD_PROGRAM(gpgsm, yes)
92 GNUPG_BUILD_PROGRAM(agent, yes)
93 GNUPG_BUILD_PROGRAM(scdaemon, yes)
94 GNUPG_BUILD_PROGRAM(g13, yes)
95 GNUPG_BUILD_PROGRAM(dirmngr, yes)
96 GNUPG_BUILD_PROGRAM(tools, yes)
97 GNUPG_BUILD_PROGRAM(doc, yes)
98 GNUPG_BUILD_PROGRAM(symcryptrun, no)
99 GNUPG_BUILD_PROGRAM(gpgtar, no)
100
101 AC_SUBST(PACKAGE)
102 AC_SUBST(PACKAGE_GT)
103 AC_SUBST(VERSION)
104 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
105 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
106                                 [Name of this package for gettext])
107 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
108 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
109                                         [Bug report address])
110 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
111                                        [Required version of Libgcrypt])
112 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
113                                        [Required version of Libksba])
114
115
116
117 # The default is to use the modules from this package and the few
118 # other packages in a standard place; i.e where this package gets
119 # installed.  With these options it is possible to override these
120 # ${prefix} depended values with fixed paths, which can't be replaced
121 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
122 AC_ARG_WITH(agent-pgm,
123     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
124           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
125 AC_SUBST(GNUPG_AGENT_PGM)
126 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
127 show_gnupg_agent_pgm="(default)"
128 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
129
130 AC_ARG_WITH(pinentry-pgm,
131     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
132           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
133 AC_SUBST(GNUPG_PINENTRY_PGM)
134 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
135 show_gnupg_pinentry_pgm="(default)"
136 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
137
138
139 AC_ARG_WITH(scdaemon-pgm,
140     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
141           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
142 AC_SUBST(GNUPG_SCDAEMON_PGM)
143 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
144 show_gnupg_scdaemon_pgm="(default)"
145 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
146
147
148 AC_ARG_WITH(dirmngr-pgm,
149     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
150           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
151 AC_SUBST(GNUPG_DIRMNGR_PGM)
152 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
153 show_gnupg_dirmngr_pgm="(default)"
154 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
155
156 AC_ARG_WITH(protect-tool-pgm,
157     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
158           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
159 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
160 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
161 show_gnupg_protect_tool_pgm="(default)"
162 test -n "$GNUPG_PROTECT_TOOL_PGM" \
163       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
164
165 AC_ARG_WITH(dirmngr-ldap-pgm,
166     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
167           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
168 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
169 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
170 show_gnupg_dirmngr_ldap_pgm="(default)"
171 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
172       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
173
174 #
175 # On some platforms gpg2 is usually installed as gpg without using a
176 # symlink.  For correct operation of gpgconf it needs to know the
177 # installed name of gpg.  This option sets "gpg2"'s installed name to
178 # just "gpg".  Note that it might be required to rename gpg2 to gpg
179 # manually after the build process.
180 #
181 AC_ARG_ENABLE(gpg2-is-gpg,
182     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
183     gpg2_is_gpg=$enableval)
184 if test "$gpg2_is_gpg" = "yes"; then
185    name_of_installed_gpg=gpg
186 else
187    name_of_installed_gpg=gpg2
188 fi
189 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
190                    [The name of the installed GPG tool])
191
192
193 # Some folks want to use only the agent from this packet.  Make it
194 # easier for them by providing the configure option
195 # --enable-only-agent.
196 AC_ARG_ENABLE(agent-only,
197     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
198     build_agent_only=$enableval)
199
200 # SELinux support includes tracking of sensitive files to avoid
201 # leaking their contents through processing these files by gpg itself
202 AC_MSG_CHECKING([whether SELinux support is requested])
203 AC_ARG_ENABLE(selinux-support,
204               AC_HELP_STRING([--enable-selinux-support],
205                              [enable SELinux support]),
206               selinux_support=$enableval, selinux_support=no)
207 AC_MSG_RESULT($selinux_support)
208
209 # Allow disabling of zip support.
210 # This is in general not a good idea because according to rfc4880 OpenPGP
211 # implementations SHOULD support ZLIB.
212 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
213 AC_ARG_ENABLE(zip,
214    AC_HELP_STRING([--disable-zip],
215                   [disable the ZIP and ZLIB compression algorithm]),
216    use_zip=$enableval)
217 AC_MSG_RESULT($use_zip)
218
219 # Allow disabling of bzib2 support.
220 # It is defined only after we confirm the library is available later
221 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
222 AC_ARG_ENABLE(bzip2,
223    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
224    use_bzip2=$enableval)
225 AC_MSG_RESULT($use_bzip2)
226
227 # Configure option to allow or disallow execution of external
228 # programs, like a photo viewer.
229 AC_MSG_CHECKING([whether to enable external program execution])
230 AC_ARG_ENABLE(exec,
231     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
232     use_exec=$enableval)
233 AC_MSG_RESULT($use_exec)
234 if test "$use_exec" = no ; then
235     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
236 fi
237
238 if test "$use_exec" = yes ; then
239   AC_MSG_CHECKING([whether to enable photo ID viewing])
240   AC_ARG_ENABLE(photo-viewers,
241       [  --disable-photo-viewers disable photo ID viewers],
242       [if test "$enableval" = no ; then
243          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
244       fi],enableval=yes)
245   gnupg_cv_enable_photo_viewers=$enableval
246   AC_MSG_RESULT($enableval)
247
248   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
249     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
250     AC_ARG_WITH(photo-viewer,
251         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
252         [if test "$withval" = yes ; then
253            withval=no
254         elif test "$withval" != no ; then
255            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
256                             [if set, restrict photo-viewer to this])
257         fi],withval=no)
258     AC_MSG_RESULT($withval)
259   fi
260
261   AC_MSG_CHECKING([whether to enable external keyserver helpers])
262   AC_ARG_ENABLE(keyserver-helpers,
263       [  --disable-keyserver-helpers  disable all external keyserver support],
264       [if test "$enableval" = no ; then
265          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
266                   [define to disable keyserver helpers])
267       fi],enableval=yes)
268   gnupg_cv_enable_keyserver_helpers=$enableval
269   AC_MSG_RESULT($enableval)
270
271   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
272     # LDAP is defined only after we confirm the library is available later
273     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
274     AC_ARG_ENABLE(ldap,
275       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
276       try_ks_ldap=$enableval, try_ks_ldap=yes)
277     AC_MSG_RESULT($try_ks_ldap)
278
279     AC_MSG_CHECKING([whether HKP keyserver support is requested])
280     AC_ARG_ENABLE(hkp,
281       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
282       try_hkp=$enableval, try_hkp=yes)
283     AC_MSG_RESULT($try_hkp)
284
285     AC_MSG_CHECKING([whether finger key fetching support is requested])
286     AC_ARG_ENABLE(finger,
287       AC_HELP_STRING([--disable-finger],
288         [disable finger key fetching interface only]),
289       try_finger=$enableval, try_finger=yes)
290     AC_MSG_RESULT($try_finger)
291
292     AC_MSG_CHECKING([whether generic object key fetching support is requested])
293     AC_ARG_ENABLE(generic,
294       AC_HELP_STRING([--disable-generic],
295         [disable generic object key fetching interface only]),
296       try_generic=$enableval, try_generic=yes)
297     AC_MSG_RESULT($try_generic)
298
299     AC_MSG_CHECKING([whether email keyserver support is requested])
300     AC_ARG_ENABLE(mailto,
301       AC_HELP_STRING([--enable-mailto],
302         [enable email keyserver interface only]),
303       try_mailto=$enableval, try_mailto=no)
304     AC_MSG_RESULT($try_mailto)
305   fi
306
307   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
308   AC_ARG_ENABLE(keyserver-path,
309       AC_HELP_STRING([--disable-keyserver-path],
310         [disable the exec-path option for keyserver helpers]),
311       [if test "$enableval" = no ; then
312          disable_keyserver_path=yes
313       fi],enableval=yes)
314   AC_MSG_RESULT($enableval)
315 fi
316
317
318 #
319 # Check for the key/uid cache size.  This can't be zero, but can be
320 # pretty small on embedded systems.  This is used for the gpg part.
321 #
322 AC_MSG_CHECKING([for the size of the key and uid cache])
323 AC_ARG_ENABLE(key-cache,
324         AC_HELP_STRING([--enable-key-cache=SIZE],
325                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
326 if test "$enableval" = "no"; then
327    enableval=5
328 elif test "$enableval" = "yes" || test "$enableval" = ""; then
329    enableval=4096
330 fi
331 changequote(,)dnl
332 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
333 changequote([,])dnl
334 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
335    AC_MSG_ERROR([invalid key-cache size])
336 fi
337 AC_MSG_RESULT($key_cache_size)
338 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
339                   [Size of the key and UID caches])
340
341
342
343 #
344 # Check whether we want to use Linux capabilities
345 #
346 AC_MSG_CHECKING([whether use of capabilities is requested])
347 AC_ARG_WITH(capabilities,
348     [  --with-capabilities     use linux capabilities [default=no]],
349 [use_capabilities="$withval"],[use_capabilities=no])
350 AC_MSG_RESULT($use_capabilities)
351
352
353 #
354 # Allow disabling of internal CCID support.
355 # It is defined only after we confirm the library is available later
356 #
357 AC_MSG_CHECKING([whether to enable the internal CCID driver])
358 AC_ARG_ENABLE(ccid-driver,
359               AC_HELP_STRING([--disable-ccid-driver],
360                              [disable the internal CCID driver]),
361               use_ccid_driver=$enableval)
362 AC_MSG_RESULT($use_ccid_driver)
363
364 #
365 # Dirmngr is nowadays a system service and thus it usually does no
366 # make sense to start it as needed.  However on some systems this is
367 # possible; this option enable the feature.
368 #
369 AC_MSG_CHECKING([whether to auto start dirmngr])
370 AC_ARG_ENABLE(dirmngr-auto-start,
371               AC_HELP_STRING([--enable-dirmngr-auto-start],
372                              [enable auto starting of the dirmngr]),
373               dirmngr_auto_start=$enableval)
374 AC_MSG_RESULT($dirmngr_auto_start)
375 if test "$dirmngr_auto_start" = yes ; then
376     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
377               [Define to enable auto starting of the dirmngr])
378 fi
379
380
381 #
382 # To avoid double inclusion of config.h which might happen at some
383 # places, we add the usual double inclusion protection at the top of
384 # config.h.
385 #
386 AH_TOP([
387 #ifndef GNUPG_CONFIG_H_INCLUDED
388 #define GNUPG_CONFIG_H_INCLUDED
389 ])
390
391 #
392 # Stuff which goes at the bottom of config.h.
393 #
394 AH_BOTTOM([
395 /* This is the major version number of GnuPG so that
396    source included files can test for this.  Note, that
397    we use 2 here even for GnuPG 1.9.x. */
398 #define GNUPG_MAJOR_VERSION 2
399
400 /* Now to separate file name parts.
401    Please note that the string version must not contain more
402    than one character because the code assumes strlen()==1 */
403 #ifdef HAVE_DOSISH_SYSTEM
404 #define DIRSEP_C '\\'
405 #define DIRSEP_S "\\"
406 #define EXTSEP_C '.'
407 #define EXTSEP_S "."
408 #define PATHSEP_C ';'
409 #define PATHSEP_S ";"
410 #define EXEEXT_S ".exe"
411 #else
412 #define DIRSEP_C '/'
413 #define DIRSEP_S "/"
414 #define EXTSEP_C '.'
415 #define EXTSEP_S "."
416 #define PATHSEP_C ':'
417 #define PATHSEP_S ":"
418 #define EXEEXT_S ""
419 #endif
420
421 /* This is the same as VERSION, but should be overridden if the
422    platform cannot handle things like dots '.' in filenames. Set
423    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
424    uses for dots and dashes. */
425 #define SAFE_VERSION VERSION
426 #define SAFE_VERSION_DOT  '.'
427 #define SAFE_VERSION_DASH '-'
428
429 /* Some global constants. */
430 #ifdef HAVE_DOSISH_SYSTEM
431 # ifdef HAVE_DRIVE_LETTERS
432 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
433 # else
434 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
435 # endif
436 #elif defined(__VMS)
437 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
438 #else
439 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
440 #endif
441 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
442
443 /* For some systems (DOS currently), we hardcode the path here.  For
444    POSIX systems the values are constructed by the Makefiles, so that
445    the values may be overridden by the make invocations; this is to
446    comply with the GNU coding standards.  Note that these values are
447    only defaults.  */
448 #ifdef HAVE_DOSISH_SYSTEM
449 # ifdef HAVE_DRIVE_LETTERS
450 #  define GNUPG_BINDIR      "c:\\gnupg"
451 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
452 #  define GNUPG_LIBDIR      "c:\\gnupg"
453 #  define GNUPG_DATADIR     "c:\\gnupg"
454 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
455 # else
456 #  define GNUPG_BINDIR      "\\gnupg"
457 #  define GNUPG_LIBEXECDIR  "\\gnupg"
458 #  define GNUPG_LIBDIR      "\\gnupg"
459 #  define GNUPG_DATADIR     "\\gnupg"
460 #  define GNUPG_SYSCONFDIR  "\\gnupg"
461 # endif
462 #endif
463
464 /* Derive some other constants. */
465 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
466 #define EXEC_TEMPFILE_ONLY
467 #endif
468
469
470 /* We didn't define endianness above, so get it from OS macros.  This
471    is intended for making fat binary builds on OS X. */
472 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
473 #if defined(__BIG_ENDIAN__)
474 #define BIG_ENDIAN_HOST 1
475 #elif defined(__LITTLE_ENDIAN__)
476 #define LITTLE_ENDIAN_HOST 1
477 #else
478 #error "No endianness found"
479 #endif
480 #endif
481
482
483 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
484    ldap_start_tls_s because that is the actual symbol used in the
485    library.  winldap.h redefines it to our commonly used value,
486    thus we define our usual macro here.  */
487 #ifdef HAVE_LDAP_START_TLS_SA
488 # ifndef HAVE_LDAP_START_TLS_S
489 #  define HAVE_LDAP_START_TLS_S 1
490 # endif
491 #endif
492
493
494 /* Tell libgcrypt not to use its own libgpg-error implementation. */
495 #define USE_LIBGPG_ERROR 1
496
497 /* We use jnlib, so tell other modules about it.  */
498 #define HAVE_JNLIB_LOGGING 1
499
500 /* Our HTTP code is used in estream mode.  */
501 #define HTTP_USE_ESTREAM 1
502
503 /* Under W32 we do an explicit socket initialization, thus we need to
504    avoid the on-demand initialization which would also install an atexit
505    handler.  */
506 #define HTTP_NO_WSASTARTUP
507
508 /* We always include support for the OpenPGP card.  */
509 #define ENABLE_CARD_SUPPORT 1
510
511 /* We want to use the libgcrypt provided memory allocation for
512    asprintf.  */
513 #define _ESTREAM_PRINTF_REALLOC       gcry_realloc
514 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
515
516 /* Under Windows we use the gettext code from libgpg-error.  */
517 #define GPG_ERR_ENABLE_GETTEXT_MACROS
518
519 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
520 #define GPG_ERR_ENABLE_ERRNO_MACROS
521
522 #endif /*GNUPG_CONFIG_H_INCLUDED*/
523 ])
524
525
526 AM_MAINTAINER_MODE
527
528 # Checks for programs.
529 AC_MSG_NOTICE([checking for programs])
530 AC_PROG_MAKE_SET
531 AM_SANITY_CHECK
532 missing_dir=`cd $ac_aux_dir && pwd`
533 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
534 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
535 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
536 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
537 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
538 AC_PROG_AWK
539 AC_PROG_CC
540 AC_PROG_CPP
541 AM_PROG_CC_C_O
542 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
543   AC_MSG_ERROR([[No C-89 compiler found]])
544 fi
545 AC_PROG_INSTALL
546 AC_PROG_LN_S
547 AC_PROG_RANLIB
548 AC_CHECK_TOOL(AR, ar, :)
549 AC_PATH_PROG(PERL,"perl")
550 AC_CHECK_TOOL(WINDRES, windres, :)
551 AC_ISC_POSIX
552 gl_EARLY
553 AC_SYS_LARGEFILE
554 GNUPG_CHECK_USTAR
555
556 # We need to compile and run a program on the build machine.  A
557 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
558 # the AC archive is broken for autoconf 2.57.  Given that there is no
559 # newer version of that macro, we assume that it is also broken for
560 # autoconf 2.61 and thus we use a simple but usually sufficient
561 # approach.
562 AC_MSG_CHECKING(for cc for build)
563 if test "$cross_compiling" = "yes"; then
564   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
565 else
566   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
567 fi
568 AC_MSG_RESULT($CC_FOR_BUILD)
569 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
570
571
572
573 try_gettext=yes
574 have_dosish_system=no
575 have_w32_system=no
576 have_w32ce_system=no
577 use_simple_gettext=no
578 use_ldapwrapper=yes
579 mmap_needed=yes
580 case "${host}" in
581     *-mingw32*)
582         # special stuff for Windoze NT
583         ac_cv_have_dev_random=no
584         AC_DEFINE(USE_ONLY_8DOT3,1,
585                   [Set this to limit filenames to the 8.3 format])
586         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
587                   [Because the Unix gettext has too much overhead on
588                    MingW32 systems and these systems lack Posix functions,
589                    we use a simplified version of gettext])
590         disable_keyserver_path=yes
591         have_dosish_system=yes
592         have_w32_system=yes
593         use_ldapwrapper=no  # Fixme: Do this only for CE.
594         case "${host}" in
595           *-mingw32ce*)
596             have_w32ce_system=yes
597             ;;
598           *)
599             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
600                       [Defined if the OS supports drive letters.])
601             ;;
602         esac
603         try_gettext="no"
604         use_simple_gettext=yes
605         mmap_needed=no
606         ;;
607     i?86-emx-os2 | i?86-*-os2*emx )
608         # OS/2 with the EMX environment
609         ac_cv_have_dev_random=no
610         AC_DEFINE(HAVE_DRIVE_LETTERS)
611         have_dosish_system=yes
612         try_gettext="no"
613         ;;
614
615     i?86-*-msdosdjgpp*)
616         # DOS with the DJGPP environment
617         ac_cv_have_dev_random=no
618         AC_DEFINE(HAVE_DRIVE_LETTERS)
619         have_dosish_system=yes
620         try_gettext="no"
621         ;;
622
623     *-*-freebsd*)
624        # FreeBSD
625        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
626        LDFLAGS="$LDFLAGS -L/usr/local/lib"
627        ;;
628
629     *-*-hpux*)
630         if test -z "$GCC" ; then
631             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
632         fi
633         ;;
634     *-dec-osf4*)
635         if test -z "$GCC" ; then
636             # Suppress all warnings
637             # to get rid of the unsigned/signed char mismatch warnings.
638             CFLAGS="$CFLAGS -w"
639         fi
640         ;;
641     *-dec-osf5*)
642         if test -z "$GCC" ; then
643             # Use the newer compiler `-msg_disable ptrmismatch1' to
644             # get rid of the unsigned/signed char mismatch warnings.
645             # Using this may hide other pointer mismatch warnings, but
646             # it at least lets other warning classes through
647             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
648         fi
649         ;;
650     m68k-atari-mint)
651         ;;
652     *)
653        ;;
654 esac
655
656 if test "$have_dosish_system" = yes; then
657    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
658              [Defined if we run on some of the PCDOS like systems
659               (DOS, Windoze. OS/2) with special properties like
660               no file modes, case insensitive file names and preferred
661               use of backslashes as directory name separators.])
662 fi
663 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
664
665 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
666
667 if test "$have_w32_system" = yes; then
668    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
669    if test "$have_w32ce_system" = yes; then
670       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
671    fi
672 fi
673 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
674 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
675
676 if test "$use_ldapwrapper" = yes; then
677    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
678 fi
679 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
680
681 if test "$disable_keyserver_path" = yes; then
682     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
683               [Defined to disable exec-path for keyserver helpers])
684 fi
685
686 #
687 # Allows enabling the use of a standard socket by default This is
688 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
689 # the use of this.
690 #
691 AC_MSG_CHECKING([whether to use a standard socket by default])
692 AC_ARG_ENABLE(standard-socket,
693               AC_HELP_STRING([--disable-standard-socket],
694                              [don't use a standard socket by default]),
695               use_standard_socket=$enableval)
696 tmp=""
697 if test "$use_standard_socket" != yes; then
698   if test "$have_w32_system" = yes; then
699     use_standard_socket=yes
700     tmp=" (forced)"
701   fi
702 fi
703 AC_MSG_RESULT($use_standard_socket$tmp)
704 if test "$use_standard_socket" = yes; then
705   AC_DEFINE(USE_STANDARD_SOCKET,1,
706             [Use the standard socket for the agent by default])
707 fi
708
709
710 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
711 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
712
713 if test x"$try_hkp" = xyes ; then
714   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
715 fi
716
717 if test x"$try_finger" = xyes ; then
718   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
719 fi
720
721
722
723 #
724 # Checks for libraries.
725 #
726 AC_MSG_NOTICE([checking for libraries])
727
728
729 #
730 # libgpg-error is a library with error codes shared between GnuPG
731 # related projects.
732 #
733 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
734                   have_gpg_error=yes,have_gpg_error=no)
735
736
737 #
738 # Libgcrypt is our generic crypto library
739 #
740 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
741         have_libgcrypt=yes,have_libgcrypt=no)
742
743
744 #
745 # libassuan is used for IPC
746 #
747 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
748                   have_libassuan=yes,have_libassuan=no)
749 if test "$have_libassuan" = "yes"; then
750   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
751                      [version of the libassuan library])
752 fi
753
754
755
756 #
757 # libksba is our X.509 support library
758 #
759 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
760
761
762 #
763 # libusb allows us to use the integrated CCID smartcard reader driver.
764 #
765 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
766 if test "$use_ccid_driver" = yes ; then
767   AC_CHECK_LIB(usb, usb_bulk_write,
768                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
769                   AC_DEFINE(HAVE_LIBUSB,1,
770                            [defined if libusb is available])
771                   have_libusb=yes
772                ])
773   AC_CHECK_FUNCS(usb_create_match)
774 fi
775 AC_SUBST(LIBUSB_LIBS)
776
777 #
778 # Check wether it is necessary to link against libdl.
779 #
780 gnupg_dlopen_save_libs="$LIBS"
781 LIBS=""
782 AC_SEARCH_LIBS(dlopen, c dl,,,)
783 DL_LIBS=$LIBS
784 AC_SUBST(DL_LIBS)
785 LIBS="$gnupg_dlopen_save_libs"
786
787 # Checks for g13
788
789 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
790 AC_DEFINE_UNQUOTED(ENCFS,
791         "${ENCFS}", [defines the filename of the encfs program])
792
793 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
794 AC_DEFINE_UNQUOTED(FUSERMOUNT,
795         "${FUSERMOUNT}", [defines the filename of the fusermount program])
796
797
798 # Checks for dirmngr
799
800
801 #
802 # Checks for symcryptrun:
803 #
804
805 # libutil has openpty() and login_tty().
806 AC_CHECK_LIB(util, openpty,
807               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
808                 AC_DEFINE(HAVE_LIBUTIL,1,
809                          [defined if libutil is available])
810              ])
811 AC_SUBST(LIBUTIL_LIBS)
812
813 # shred is used to clean temporary plain text files.
814 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
815 AC_DEFINE_UNQUOTED(SHRED,
816         "${SHRED}", [defines the filename of the shred program])
817
818
819 #
820 # Check whether the nPth library is available
821 #
822 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
823 if test "$have_npth" = "yes"; then
824   # We define this macro because some code parts require it.
825   AC_DEFINE(USE_NPTH, 1,
826               [Defined if the New Portable Thread Library is available])
827 else
828   AC_MSG_WARN([[
829 ***
830 *** To support concurrent access for example in gpg-agent and the SCdaemon
831 *** we need the support of the New Portable Threads Library.
832 ***]])
833 fi
834
835
836 AC_MSG_NOTICE([checking for networking options])
837
838 #
839 # Must check for network library requirements before doing link tests
840 # for ldap, for example. If ldap libs are static (or dynamic and without
841 # ELF runtime link paths), then link will fail and LDAP support won't
842 # be detected.
843 #
844 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
845         [NETLIBS="-lnsl $NETLIBS"]))
846 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
847         [NETLIBS="-lsocket $NETLIBS"]))
848
849
850 #
851 # Check for ADNS.
852 #
853 _cppflags="${CPPFLAGS}"
854 _ldflags="${LDFLAGS}"
855 AC_ARG_WITH(adns,
856             AC_HELP_STRING([--with-adns=DIR],
857                            [look for the adns library in DIR]),
858             [if test -d "$withval"; then
859                CPPFLAGS="${CPPFLAGS} -I$withval/include"
860                LDFLAGS="${LDFLAGS} -L$withval/lib"
861              fi])
862 if test "$with_adns" != "no"; then
863   AC_CHECK_HEADERS(adns.h,
864                 AC_CHECK_LIB(adns, adns_init,
865                              [have_adns=yes],
866                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
867                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
868 fi
869 if test "$have_adns" = "yes"; then
870   ADNSLIBS="-ladns"
871 fi
872 AC_SUBST(ADNSLIBS)
873 # Newer adns versions feature a free function to be used under W32.
874 AC_CHECK_FUNCS(adns_free)
875
876
877
878 #
879 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
880 #
881 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
882   AC_ARG_ENABLE(dns-srv,
883      AC_HELP_STRING([--disable-dns-srv],
884                     [disable the use of DNS SRV in HKP and HTTP]),
885                 use_dns_srv=$enableval,use_dns_srv=yes)
886 fi
887
888 AC_ARG_ENABLE(dns-pka,
889    AC_HELP_STRING([--disable-dns-pka],
890         [disable the use of PKA records in DNS]),
891    use_dns_pka=$enableval,use_dns_pka=yes)
892
893 AC_ARG_ENABLE(dns-cert,
894    AC_HELP_STRING([--disable-dns-cert],
895         [disable the use of CERT records in DNS]),
896    use_dns_cert=$enableval,use_dns_cert=yes)
897
898 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
899    || test x"$use_dns_cert" = xyes; then
900   _dns_save_libs=$LIBS
901   LIBS=""
902   # the double underscore thing is a glibc-ism?
903   AC_SEARCH_LIBS(res_query,resolv bind,,
904                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
905   AC_SEARCH_LIBS(dn_expand,resolv bind,,
906                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
907   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
908                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
909
910   if test x"$have_resolver" != xno ; then
911
912     # Make sure that the BIND 4 resolver interface is workable before
913     # enabling any code that calls it.  At some point I'll rewrite the
914     # code to use the BIND 8 resolver API.
915     # We might also want to use adns instead.  Problem with ADNS is that
916     # it does not support v6.
917
918     AC_MSG_CHECKING([whether the resolver is usable])
919     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
920 #include <netinet/in.h>
921 #include <arpa/nameser.h>
922 #include <resolv.h>]],
923 [[unsigned char answer[PACKETSZ];
924   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
925   dn_skipname(0,0);
926   dn_expand(0,0,0,0,0);
927 ]])],have_resolver=yes,have_resolver=no)
928     AC_MSG_RESULT($have_resolver)
929
930     # This is Apple-specific and somewhat bizarre as they changed the
931     # define in bind 8 for some reason.
932
933     if test x"$have_resolver" != xyes ; then
934        AC_MSG_CHECKING(
935              [whether I can make the resolver usable with BIND_8_COMPAT])
936        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
937 #include <sys/types.h>
938 #include <netinet/in.h>
939 #include <arpa/nameser.h>
940 #include <resolv.h>]],
941 [[unsigned char answer[PACKETSZ];
942   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
943   dn_skipname(0,0); dn_expand(0,0,0,0,0);
944 ]])],[have_resolver=yes ; need_compat=yes])
945        AC_MSG_RESULT($have_resolver)
946     fi
947   fi
948
949   if test x"$have_resolver" = xyes ; then
950      DNSLIBS=$LIBS
951
952      if test x"$use_dns_srv" = xyes ; then
953         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
954      fi
955
956      if test x"$use_dns_pka" = xyes ; then
957         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
958      fi
959
960      if test x"$use_dns_cert" = xyes ; then
961         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
962      fi
963
964      if test x"$need_compat" = xyes ; then
965         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
966      fi
967   else
968      # If we have no resolver library but ADNS (e.g. under W32) enable the
969      # code parts which can be used with ADNS.
970      if test x"$have_adns" = xyes ; then
971         DNSLIBS="$ADNSLIBS"
972         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
973
974         if test x"$use_dns_srv" = xyes ; then
975            AC_DEFINE(USE_DNS_SRV,1)
976         fi
977
978         if test x"$use_dns_pka" = xyes ; then
979            AC_DEFINE(USE_DNS_PKA,1)
980         fi
981
982         if test x"$use_dns_cert" = xyes ; then
983            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
984         fi
985      else
986         use_dns_srv=no
987         use_dns_pka=no
988         use_dns_cert=no
989      fi
990   fi
991
992   LIBS=$_dns_save_libs
993 fi
994
995 AC_SUBST(DNSLIBS)
996
997 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
998
999
1000 #
1001 # Check for LDAP
1002 #
1003 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
1004    GNUPG_CHECK_LDAP($NETLIBS)
1005 fi
1006
1007 #
1008 # Check for curl.  We fake the curl API if libcurl isn't installed.
1009 # We require 7.10 or later as we use curl_version_info().
1010 #
1011 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
1012 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
1013
1014 # Generic, for us, means curl
1015
1016 if test x"$try_generic" = xyes ; then
1017    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
1018 fi
1019
1020 #
1021 # Check for sendmail
1022 #
1023 # This isn't necessarily sendmail itself, but anything that gives a
1024 # sendmail-ish interface to the outside world.  That includes Exim,
1025 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1026 if test "$try_mailto" = yes ; then
1027   AC_ARG_WITH(mailprog,
1028       AC_HELP_STRING([--with-mailprog=NAME],
1029                      [use "NAME -t" for mail transport]),
1030              ,with_mailprog=yes)
1031
1032   if test x"$with_mailprog" = xyes ; then
1033     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1034     if test "$ac_cv_path_SENDMAIL" ; then
1035       GPGKEYS_MAILTO="gpg2keys_mailto"
1036     fi
1037   elif test x"$with_mailprog" != xno ; then
1038     AC_MSG_CHECKING([for a mail transport program])
1039     AC_SUBST(SENDMAIL,$with_mailprog)
1040     AC_MSG_RESULT($with_mailprog)
1041     GPGKEYS_MAILTO="gpg2keys_mailto"
1042   fi
1043 fi
1044
1045 AC_SUBST(GPGKEYS_MAILTO)
1046
1047 #
1048 # Construct a printable name of the OS
1049 #
1050 case "${host}" in
1051     *-mingw32ce*)
1052         PRINTABLE_OS_NAME="W32CE"
1053         ;;
1054     *-mingw32*)
1055         PRINTABLE_OS_NAME="MingW32"
1056         ;;
1057     *-*-cygwin*)
1058         PRINTABLE_OS_NAME="Cygwin"
1059         ;;
1060     i?86-emx-os2 | i?86-*-os2*emx )
1061         PRINTABLE_OS_NAME="OS/2"
1062         ;;
1063     i?86-*-msdosdjgpp*)
1064         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1065         try_dynload=no
1066         ;;
1067     *-linux*)
1068         PRINTABLE_OS_NAME="GNU/Linux"
1069         ;;
1070     *)
1071         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1072         ;;
1073 esac
1074 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1075                    [A human readable text with the name of the OS])
1076
1077
1078 #
1079 # Checking for iconv
1080 #
1081 AM_ICONV
1082
1083
1084 #
1085 # Check for gettext
1086 #
1087 # This is "GNU gnupg" - The project-id script from gettext
1088 #                       needs this string
1089 #
1090 AC_MSG_NOTICE([checking for gettext])
1091 AM_PO_SUBDIRS
1092 AM_GNU_GETTEXT_VERSION([0.17])
1093 if test "$try_gettext" = yes; then
1094   AM_GNU_GETTEXT([external],[need-ngettext])
1095
1096   # gettext requires some extra checks.  These really should be part of
1097   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1098   # function checks to here.
1099
1100   AC_CHECK_FUNCS(strchr)
1101 else
1102   USE_NLS=no
1103   USE_INCLUDED_LIBINTL=no
1104   BUILD_INCLUDED_LIBINTL=no
1105   POSUB=po
1106   AC_SUBST(USE_NLS)
1107   AC_SUBST(USE_INCLUDED_LIBINTL)
1108   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1109   AC_SUBST(POSUB)
1110 fi
1111
1112 # We use HAVE_LANGINFO_CODESET in a couple of places.
1113 AM_LANGINFO_CODESET
1114
1115 # Checks required for our use locales
1116 gt_LC_MESSAGES
1117
1118
1119 #
1120 # SELinux support
1121 #
1122 if test "$selinux_support" = yes ; then
1123   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1124 fi
1125
1126
1127 #
1128 # Checks for header files.
1129 #
1130 AC_MSG_NOTICE([checking for header files])
1131 AC_HEADER_STDC
1132 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1133                   pty.h utmp.h pwd.h inttypes.h signal.h])
1134 AC_HEADER_TIME
1135
1136
1137 #
1138 # Checks for typedefs, structures, and compiler characteristics.
1139 #
1140 AC_MSG_NOTICE([checking for system characteristics])
1141 AC_C_CONST
1142 AC_C_INLINE
1143 AC_C_VOLATILE
1144 AC_TYPE_SIZE_T
1145 AC_TYPE_MODE_T
1146 AC_TYPE_SIGNAL
1147 AC_DECL_SYS_SIGLIST
1148
1149 gl_HEADER_SYS_SOCKET
1150 gl_TYPE_SOCKLEN_T
1151
1152 AC_ARG_ENABLE(endian-check,
1153               AC_HELP_STRING([--disable-endian-check],
1154               [disable the endian check and trust the OS provided macros]),
1155               endiancheck=$enableval,endiancheck=yes)
1156
1157 if test x"$endiancheck" = xyes ; then
1158   GNUPG_CHECK_ENDIAN
1159 fi
1160
1161 # fixme: we should get rid of the byte type
1162 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1163 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1164 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1165 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1166 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1167
1168 AC_CHECK_SIZEOF(unsigned short)
1169 AC_CHECK_SIZEOF(unsigned int)
1170 AC_CHECK_SIZEOF(unsigned long)
1171 AC_CHECK_SIZEOF(unsigned long long)
1172 AC_HEADER_TIME
1173 AC_CHECK_SIZEOF(time_t,,[[
1174 #include <stdio.h>
1175 #if TIME_WITH_SYS_TIME
1176 # include <sys/time.h>
1177 # include <time.h>
1178 #else
1179 # if HAVE_SYS_TIME_H
1180 #  include <sys/time.h>
1181 # else
1182 #  include <time.h>
1183 # endif
1184 #endif
1185 ]])
1186 GNUPG_TIME_T_UNSIGNED
1187
1188
1189 # Ensure that we have UINT64_C before we bother to check for uint64_t
1190 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1191 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1192    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1193        [[uint64_t foo=UINT64_C(42);]])],
1194      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1195 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1196    AC_CHECK_SIZEOF(uint64_t)
1197 fi
1198
1199 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1200    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1201    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1202     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1203 fi
1204
1205
1206 #
1207 # Checks for library functions.
1208 #
1209 AC_MSG_NOTICE([checking for library functions])
1210 AC_CHECK_DECLS(getpagesize)
1211 AC_FUNC_FSEEKO
1212 AC_FUNC_VPRINTF
1213 AC_FUNC_FORK
1214 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1215 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1216 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1217 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1218 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1219 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1220 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1221
1222 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1223
1224 # Dirmngr requires mmap on Unix systems.
1225 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1226   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1227 fi
1228
1229 #
1230 # These are needed by the jnlib parts in common.
1231 # Note:  We already checked pwd.h.
1232 AC_CHECK_HEADERS([signal.h])
1233 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1234                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1235                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1236                 getenv inet_pton])
1237 # end jnlib checks.
1238
1239
1240
1241 #
1242 # gnulib checks
1243 #
1244 gl_SOURCE_BASE([gl])
1245 gl_M4_BASE([gl/m4])
1246 gl_MODULES([setenv mkdtemp xsize strpbrk])
1247 gl_INIT
1248
1249
1250 #
1251 # W32 specific test
1252 #
1253 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1254
1255 #
1256 # Sanity check regex.  Tests adapted from mutt.
1257 #
1258 AC_MSG_CHECKING([whether regular expression support is requested])
1259 AC_ARG_ENABLE(regex,
1260   AC_HELP_STRING([--disable-regex],
1261     [do not handle regular expressions in trust signatures]),
1262   use_regex=$enableval, use_regex=yes)
1263 AC_MSG_RESULT($use_regex)
1264
1265 if test "$use_regex" = yes ; then
1266   _cppflags="${CPPFLAGS}"
1267   _ldflags="${LDFLAGS}"
1268   AC_ARG_WITH(regex,
1269      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1270       [
1271       if test -d "$withval" ; then
1272         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1273         LDFLAGS="${LDFLAGS} -L$withval/lib"
1274       fi
1275       ],withval="")
1276
1277   # Does the system have regex functions at all?
1278   AC_SEARCH_LIBS([regcomp], [regex])
1279   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1280
1281   if test $gnupg_cv_have_regex = no; then
1282     use_regex=no
1283   else
1284     if test x"$cross_compiling" = xyes; then
1285       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1286     else
1287       AC_CACHE_CHECK([whether your system's regexp library is broken],
1288        [gnupg_cv_regex_broken],
1289        AC_TRY_RUN([
1290 #include <unistd.h>
1291 #include <regex.h>
1292 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1293        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1294
1295       if test $gnupg_cv_regex_broken = yes; then
1296         AC_MSG_WARN([your regex is broken - disabling regex use])
1297         use_regex=no
1298       fi
1299     fi
1300   fi
1301   CPPFLAGS="${_cppflags}"
1302   LDFLAGS="${_ldflags}"
1303 fi
1304
1305 if test "$use_regex" != yes ; then
1306   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1307 fi
1308 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1309
1310
1311
1312 #
1313 # Do we have zlib? Must do it here because Solaris failed
1314 # when compiling a conftest (due to the "-lz" from LIBS).
1315 # Note that we combine zlib and bzlib2 in ZLIBS.
1316 #
1317 if test "$use_zip" = yes ; then
1318   _cppflags="${CPPFLAGS}"
1319   _ldflags="${LDFLAGS}"
1320   AC_ARG_WITH(zlib,
1321     [  --with-zlib=DIR         use libz in DIR],[
1322       if test -d "$withval"; then
1323         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1324         LDFLAGS="${LDFLAGS} -L$withval/lib"
1325       fi
1326     ])
1327
1328   AC_CHECK_HEADER(zlib.h,
1329         AC_CHECK_LIB(z, deflateInit2_,
1330          ZLIBS="-lz",
1331          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1332          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1333
1334   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1335 fi
1336
1337
1338 #
1339 # Check whether we can support bzip2
1340 #
1341 if test "$use_bzip2" = yes ; then
1342   _cppflags="${CPPFLAGS}"
1343   _ldflags="${LDFLAGS}"
1344   AC_ARG_WITH(bzip2,
1345      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1346       [
1347       if test -d "$withval" ; then
1348         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1349         LDFLAGS="${LDFLAGS} -L$withval/lib"
1350       fi
1351       ],withval="")
1352
1353   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1354   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1355   # woefully out of date.
1356   if test "$withval" != no ; then
1357      AC_CHECK_HEADER(bzlib.h,
1358         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1359           [
1360           have_bz2=yes
1361           ZLIBS="$ZLIBS -lbz2"
1362           AC_DEFINE(HAVE_BZIP2,1,
1363                   [Defined if the bz2 compression library is available])
1364           ],
1365           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1366           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1367   fi
1368 fi
1369 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1370 AC_SUBST(ZLIBS)
1371
1372
1373 # Check for readline support
1374 GNUPG_CHECK_READLINE
1375
1376 #
1377 # Allow users to append something to the version string without
1378 # flagging it as development version.  The user version parts is
1379 # considered everything after a dash.
1380 #
1381 if test "$development_version" != yes; then
1382   changequote(,)dnl
1383   tmp_pat='[a-zA-Z]'
1384   changequote([,])dnl
1385   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1386     development_version=yes
1387   fi
1388 fi
1389 if test "$development_version" = yes; then
1390     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1391             [Defined if this is not a regular release])
1392 fi
1393
1394 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1395
1396 GNUPG_CHECK_GNUMAKE
1397
1398 # Add some extra libs here so that previous tests don't fail for
1399 # mysterious reasons - the final link step should bail out.
1400 # W32SOCKLIBS is also defined so that if can be used for tools not
1401 # requiring any network stuff but linking to code in libcommon which
1402 # tracks in winsock stuff (e.g. init_common_subsystems).
1403 if test "$have_w32_system" = yes; then
1404    if test "$have_w32ce_system" = yes; then
1405      W32SOCKLIBS="-lws2"
1406    else
1407      W32SOCKLIBS="-lws2_32"
1408    fi
1409    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1410 fi
1411
1412 AC_SUBST(NETLIBS)
1413 AC_SUBST(W32SOCKLIBS)
1414
1415 #
1416 # Setup gcc specific options
1417 #
1418 AC_MSG_NOTICE([checking for cc features])
1419 if test "$GCC" = yes; then
1420     # Note that it is okay to use CFLAGS here because this are just
1421     # warning options and the user should have a chance of overriding
1422     # them.
1423     if test "$USE_MAINTAINER_MODE" = "yes"; then
1424         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1425         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1426         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1427         _gcc_cflags_save=$CFLAGS
1428         CFLAGS="-Wno-missing-field-initializers"
1429         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1430         AC_MSG_RESULT($_gcc_wopt)
1431         CFLAGS=$_gcc_cflags_save;
1432         if test x"$_gcc_wopt" = xyes ; then
1433           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1434         fi
1435         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1436         _gcc_cflags_save=$CFLAGS
1437         CFLAGS="-Wdeclaration-after-statement"
1438         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1439         AC_MSG_RESULT($_gcc_wopt)
1440         CFLAGS=$_gcc_cflags_save;
1441         if test x"$_gcc_wopt" = xyes ; then
1442           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1443         fi
1444     else
1445         CFLAGS="$CFLAGS -Wall"
1446     fi
1447
1448     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1449     _gcc_cflags_save=$CFLAGS
1450     CFLAGS="-Wno-pointer-sign"
1451     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1452     AC_MSG_RESULT($_gcc_psign)
1453     CFLAGS=$_gcc_cflags_save;
1454     if test x"$_gcc_psign" = xyes ; then
1455        CFLAGS="$CFLAGS -Wno-pointer-sign"
1456     fi
1457
1458     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1459     _gcc_cflags_save=$CFLAGS
1460     CFLAGS="-Wpointer-arith"
1461     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1462     AC_MSG_RESULT($_gcc_psign)
1463     CFLAGS=$_gcc_cflags_save;
1464     if test x"$_gcc_psign" = xyes ; then
1465        CFLAGS="$CFLAGS -Wpointer-arith"
1466     fi
1467 fi
1468
1469
1470 #
1471 # This is handy for debugging so the compiler doesn't rearrange
1472 # things and eliminate variables.
1473 #
1474 AC_ARG_ENABLE(optimization,
1475    AC_HELP_STRING([--disable-optimization],
1476                   [disable compiler optimization]),
1477                   [if test $enableval = no ; then
1478                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1479                    fi])
1480
1481 #
1482 # Prepare building of estream
1483 #
1484 estream_INIT
1485
1486
1487 #
1488 # Decide what to build
1489 #
1490 if test "$have_adns" = "yes"; then
1491   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1492 fi
1493
1494
1495 if test $have_ksba = no; then
1496   build_gpgsm=no
1497   build_scdaemon=no
1498 fi
1499
1500 build_scdaemon_extra=""
1501 if test "$build_scdaemon" = "yes"; then
1502   if test $have_libusb = no; then
1503      build_scdaemon_extra="${tmp}without internal CCID driver"
1504   fi
1505   if test -n "$build_scdaemon_extra"; then
1506      build_scdaemon_extra="(${build_scdaemon_extra})"
1507   fi
1508 fi
1509
1510
1511 if test "$build_agent_only" = "yes" ; then
1512   build_gpg=no
1513   build_gpgsm=no
1514   build_scdaemon=no
1515   build_tools=no
1516   build_doc=no
1517 fi
1518
1519 #
1520 # Set variables for use by th automake makefile.
1521 #
1522 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1523 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1524 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1525 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1526 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1527 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1528 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1529 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1530 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1531 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1532
1533 AM_CONDITIONAL(RUN_GPG_TESTS,
1534                test x$cross_compiling = xno -a "$build_gpg" = yes )
1535
1536 #
1537 # Set some defines for use gpgconf.
1538 #
1539 if test "$build_gpg" = yes ; then
1540     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1541 fi
1542 if test "$build_gpgsm" = yes ; then
1543     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1544 fi
1545 if test "$build_agent" = yes ; then
1546     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1547 fi
1548 if test "$build_scdaemon" = yes ; then
1549     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1550 fi
1551 if test "$build_dirmngr" = yes ; then
1552     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1553 fi
1554 if test "$build_g13" = yes ; then
1555     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1556 fi
1557
1558
1559
1560 #
1561 # Print errors here so that they are visible all
1562 # together and the user can acquire them all together.
1563 #
1564 die=no
1565 if test "$have_gpg_error" = "no"; then
1566    die=yes
1567    AC_MSG_NOTICE([[
1568 ***
1569 *** You need libgpg-error to build this program.
1570 **  This library is for example available at
1571 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1572 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1573 ***]])
1574 fi
1575 if test "$have_libgcrypt" = "no"; then
1576    die=yes
1577    AC_MSG_NOTICE([[
1578 ***
1579 *** You need libgcrypt to build this program.
1580 **  This library is for example available at
1581 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1582 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1583 ***]])
1584 dnl elif test "$gnupg_cv_gcry_kdf_derive" = no; then
1585 dnl    die=yes
1586 dnl    AC_MSG_NOTICE([[
1587 dnl ***
1588 dnl *** Libgcrypt 1.5.0 has not yet been released and thus the API
1589 dnl *** is a bit in a flux.  Your version misses the function
1590 dnl ***        gcry_kdf_derive
1591 dnl *** You need to install a newer Libgcrypt version.
1592 dnl #***]])
1593 fi
1594 if test "$have_libassuan" = "no"; then
1595    die=yes
1596    AC_MSG_NOTICE([[
1597 ***
1598 *** You need libassuan to build this program.
1599 *** This library is for example available at
1600 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1601 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1602 ***]])
1603 fi
1604 if test "$have_ksba" = "no"; then
1605     AC_MSG_NOTICE([[
1606 ***
1607 *** You need libksba to build this program.
1608 *** This library is for example available at
1609 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1610 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1611 ***]])
1612 fi
1613 if test "$gnupg_have_ldap" = "no"; then
1614     die=yes
1615     AC_MSG_NOTICE([[
1616 ***
1617 *** You need a LDAP library to build this program.
1618 *** Check out
1619 ***    http://www.openldap.org
1620 *** for a suitable implementation.
1621 ***]])
1622    if test "$have_w32ce_system" = yes; then
1623     AC_MSG_NOTICE([[
1624 *** Note that CeGCC might be broken, a package fixing this is:
1625 ***    http://files.kolab.org/local/windows-ce/
1626 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1627 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1628 ***]])
1629    fi
1630 fi
1631 if test "$have_npth" = "no"; then
1632     AC_MSG_NOTICE([[
1633 ***
1634 *** It is now required to build with support for the
1635 *** New Portable Threads Library (NPth). Please install this
1636 *** library first.  The library is for example available at
1637 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1638 *** On a Debian GNU/Linux system you can install it using
1639 ***   apt-get install libnpth-dev
1640 ***]])
1641    die=yes
1642 fi
1643
1644 if test "$die" = "yes"; then
1645     AC_MSG_ERROR([[
1646 ***
1647 *** Required libraries not found. Please consult the above messages
1648 *** and install them before running configure again.
1649 ***]])
1650 fi
1651
1652
1653
1654 AC_CONFIG_FILES([ m4/Makefile
1655 Makefile
1656 po/Makefile.in
1657 gl/Makefile
1658 include/Makefile
1659 common/Makefile
1660 kbx/Makefile
1661 g10/Makefile
1662 sm/Makefile
1663 agent/Makefile
1664 scd/Makefile
1665 g13/Makefile
1666 dirmngr/Makefile
1667 tools/gpg-zip
1668 tools/Makefile
1669 doc/Makefile
1670 tests/Makefile
1671 tests/openpgp/Makefile
1672 tests/pkits/Makefile
1673 ])
1674 #keyserver/Makefile
1675 #keyserver/gpg2keys_mailto
1676 #keyserver/gpg2keys_test
1677
1678
1679 AC_OUTPUT
1680
1681
1682 echo "
1683         GnuPG v${VERSION} has been configured as follows:
1684
1685         Platform:  $PRINTABLE_OS_NAME ($host)
1686
1687         OpenPGP:   $build_gpg
1688         S/MIME:    $build_gpgsm
1689         Agent:     $build_agent
1690         Smartcard: $build_scdaemon $build_scdaemon_extra
1691         G13:       $build_g13
1692         Dirmngr:   $build_dirmngr
1693         Gpgtar:    $build_gpgtar
1694
1695         Protect tool:      $show_gnupg_protect_tool_pgm
1696         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1697         Default agent:     $show_gnupg_agent_pgm
1698         Default pinentry:  $show_gnupg_pinentry_pgm
1699         Default scdaemon:  $show_gnupg_scdaemon_pgm
1700         Default dirmngr:   $show_gnupg_dirmngr_pgm
1701
1702         Use standard socket: $use_standard_socket
1703         Dirmngr auto start:  $dirmngr_auto_start
1704 "
1705 if test x"$use_regex" != xyes ; then
1706 echo "
1707         Warning: No regular expression support available.
1708                  OpenPGP trust signatures won't work.
1709                  gpg-check-pattern will not be build.
1710 "
1711 fi