gpgscm: Add flags to the interpreter.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [17])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_adns=no
106 have_system_resolver=no
107 gnupg_have_ldap="n/a"
108
109 use_zip=yes
110 use_bzip2=yes
111 use_exec=yes
112 use_trust_models=yes
113 use_tofu=yes
114 card_support=yes
115 use_ccid_driver=auto
116 dirmngr_auto_start=yes
117 use_tls_library=no
118 large_secmem=no
119 show_tor_support=no
120
121
122 GNUPG_BUILD_PROGRAM(gpg, yes)
123 GNUPG_BUILD_PROGRAM(gpgsm, yes)
124 # The agent is a required part and can't be disabled anymore.
125 build_agent=yes
126 GNUPG_BUILD_PROGRAM(scdaemon, yes)
127 GNUPG_BUILD_PROGRAM(g13, no)
128 GNUPG_BUILD_PROGRAM(dirmngr, yes)
129 GNUPG_BUILD_PROGRAM(tools, yes)
130 GNUPG_BUILD_PROGRAM(doc, yes)
131 GNUPG_BUILD_PROGRAM(symcryptrun, no)
132 # We use gpgtar to unpack test data, hence we always build it.  If the
133 # user opts out, we simply don't install it.
134 GNUPG_BUILD_PROGRAM(gpgtar, yes)
135 GNUPG_BUILD_PROGRAM(wks-tools, no)
136
137 AC_SUBST(PACKAGE)
138 AC_SUBST(PACKAGE_GT)
139 AC_SUBST(VERSION)
140 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
142                                 [Name of this package for gettext])
143 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
144 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
145                                         [Bug report address])
146 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
147                                        [Required version of Libgcrypt])
148 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
149                                        [Required version of Libksba])
150 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
151                                        [Required version of NTBTLS])
152
153
154
155 # The default is to use the modules from this package and the few
156 # other packages in a standard place; i.e where this package gets
157 # installed.  With these options it is possible to override these
158 # ${prefix} depended values with fixed paths, which can't be replaced
159 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
160 AC_ARG_WITH(agent-pgm,
161     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
162           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
163 AC_SUBST(GNUPG_AGENT_PGM)
164 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
165 show_gnupg_agent_pgm="(default)"
166 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
167
168 AC_ARG_WITH(pinentry-pgm,
169     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
170           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
171 AC_SUBST(GNUPG_PINENTRY_PGM)
172 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
173 show_gnupg_pinentry_pgm="(default)"
174 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
175
176
177 AC_ARG_WITH(scdaemon-pgm,
178     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
179           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
180 AC_SUBST(GNUPG_SCDAEMON_PGM)
181 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
182 show_gnupg_scdaemon_pgm="(default)"
183 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
184
185
186 AC_ARG_WITH(dirmngr-pgm,
187     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
188           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
189 AC_SUBST(GNUPG_DIRMNGR_PGM)
190 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
191 show_gnupg_dirmngr_pgm="(default)"
192 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
193
194 AC_ARG_WITH(protect-tool-pgm,
195     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
196           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
197 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
198 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
199 show_gnupg_protect_tool_pgm="(default)"
200 test -n "$GNUPG_PROTECT_TOOL_PGM" \
201       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
202
203 AC_ARG_WITH(dirmngr-ldap-pgm,
204     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
205           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
206 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
207 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
208 show_gnupg_dirmngr_ldap_pgm="(default)"
209 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
210       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
211
212 #
213 # On some platforms gpg2 is usually installed as gpg without using a
214 # symlink.  For correct operation of gpgconf it needs to know the
215 # installed name of gpg.  This option sets "gpg2"'s installed name to
216 # just "gpg".  Note that it might be required to rename gpg2 to gpg
217 # manually after the build process.
218 #
219 AC_ARG_ENABLE(gpg2-is-gpg,
220     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
221     gpg2_is_gpg=$enableval)
222 if test "$gpg2_is_gpg" != "yes"; then
223    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
224 fi
225 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
226
227
228 # SELinux support includes tracking of sensitive files to avoid
229 # leaking their contents through processing these files by gpg itself
230 AC_MSG_CHECKING([whether SELinux support is requested])
231 AC_ARG_ENABLE(selinux-support,
232               AC_HELP_STRING([--enable-selinux-support],
233                              [enable SELinux support]),
234               selinux_support=$enableval, selinux_support=no)
235 AC_MSG_RESULT($selinux_support)
236
237
238 AC_MSG_CHECKING([whether to allocate extra secure memory])
239 AC_ARG_ENABLE(large-secmem,
240               AC_HELP_STRING([--enable-large-secmem],
241                              [allocate extra secure memory]),
242               large_secmem=$enableval, large_secmem=no)
243 AC_MSG_RESULT($large_secmem)
244 if test "$large_secmem" = yes ; then
245    SECMEM_BUFFER_SIZE=65536
246 else
247    SECMEM_BUFFER_SIZE=32768
248 fi
249 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
250                    [Size of secure memory buffer])
251
252 AC_MSG_CHECKING([whether to enable trust models])
253 AC_ARG_ENABLE(trust-models,
254               AC_HELP_STRING([--disable-trust-models],
255                              [disable all trust models except "always"]),
256               use_trust_models=$enableval)
257 AC_MSG_RESULT($use_trust_models)
258 if test "$use_trust_models" = no ; then
259     AC_DEFINE(NO_TRUST_MODELS, 1,
260              [Define to include only trust-model always])
261 fi
262
263 AC_MSG_CHECKING([whether to enable TOFU])
264 AC_ARG_ENABLE(tofu,
265                 AC_HELP_STRING([--disable-tofu],
266                                [disable the TOFU trust model]),
267               use_tofu=$enableval, use_tofu=$use_trust_models)
268 AC_MSG_RESULT($use_tofu)
269 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
270     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
271 fi
272
273
274
275 #
276 # Options to disable algorithm
277 #
278
279 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
280 # Elgamal is a MUST algorithm
281 # DSA is a MUST algorithm
282 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
283 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
284 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
285
286 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
287 # 3DES is a MUST algorithm
288 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
289 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
290 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
291 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
292 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
293 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
294 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
295 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
296 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
297
298 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
299 # SHA1 is a MUST algorithm
300 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
301 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
302 # SHA256 is a MUST algorithm for GnuPG.
303 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
304 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
305
306
307 # Allow disabling of zip support.
308 # This is in general not a good idea because according to rfc4880 OpenPGP
309 # implementations SHOULD support ZLIB.
310 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
311 AC_ARG_ENABLE(zip,
312    AC_HELP_STRING([--disable-zip],
313                   [disable the ZIP and ZLIB compression algorithm]),
314    use_zip=$enableval)
315 AC_MSG_RESULT($use_zip)
316
317 # Allow disabling of bzib2 support.
318 # It is defined only after we confirm the library is available later
319 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
320 AC_ARG_ENABLE(bzip2,
321    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
322    use_bzip2=$enableval)
323 AC_MSG_RESULT($use_bzip2)
324
325 # Configure option to allow or disallow execution of external
326 # programs, like a photo viewer.
327 AC_MSG_CHECKING([whether to enable external program execution])
328 AC_ARG_ENABLE(exec,
329     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
330     use_exec=$enableval)
331 AC_MSG_RESULT($use_exec)
332 if test "$use_exec" = no ; then
333     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
334 fi
335
336 if test "$use_exec" = yes ; then
337   AC_MSG_CHECKING([whether to enable photo ID viewing])
338   AC_ARG_ENABLE(photo-viewers,
339       [  --disable-photo-viewers disable photo ID viewers],
340       [if test "$enableval" = no ; then
341          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
342       fi],enableval=yes)
343   gnupg_cv_enable_photo_viewers=$enableval
344   AC_MSG_RESULT($enableval)
345
346   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
347     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
348     AC_ARG_WITH(photo-viewer,
349         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
350         [if test "$withval" = yes ; then
351            withval=no
352         elif test "$withval" != no ; then
353            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
354                             [if set, restrict photo-viewer to this])
355         fi],withval=no)
356     AC_MSG_RESULT($withval)
357   fi
358 fi
359
360
361 #
362 # Check for the key/uid cache size.  This can't be zero, but can be
363 # pretty small on embedded systems.  This is used for the gpg part.
364 #
365 AC_MSG_CHECKING([for the size of the key and uid cache])
366 AC_ARG_ENABLE(key-cache,
367         AC_HELP_STRING([--enable-key-cache=SIZE],
368                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
369 if test "$enableval" = "no"; then
370    enableval=5
371 elif test "$enableval" = "yes" || test "$enableval" = ""; then
372    enableval=4096
373 fi
374 changequote(,)dnl
375 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
376 changequote([,])dnl
377 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
378    AC_MSG_ERROR([invalid key-cache size])
379 fi
380 AC_MSG_RESULT($key_cache_size)
381 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
382                   [Size of the key and UID caches])
383
384
385
386 #
387 # Check whether we want to use Linux capabilities
388 #
389 AC_MSG_CHECKING([whether use of capabilities is requested])
390 AC_ARG_WITH(capabilities,
391     [  --with-capabilities     use linux capabilities [default=no]],
392 [use_capabilities="$withval"],[use_capabilities=no])
393 AC_MSG_RESULT($use_capabilities)
394
395 #
396 # Check whether to disable the card support
397 AC_MSG_CHECKING([whether smartcard support is requested])
398 AC_ARG_ENABLE(card-support,
399               AC_HELP_STRING([--disable-card-support],
400                              [disable smartcard support]),
401               card_support=$enableval)
402 AC_MSG_RESULT($card_support)
403 if test "$card_support" = yes ; then
404   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
405 else
406   build_scdaemon=no
407 fi
408
409 #
410 # Allow disabling of internal CCID support.
411 # It is defined only after we confirm the library is available later
412 #
413 AC_MSG_CHECKING([whether to enable the internal CCID driver])
414 AC_ARG_ENABLE(ccid-driver,
415               AC_HELP_STRING([--disable-ccid-driver],
416                              [disable the internal CCID driver]),
417               use_ccid_driver=$enableval)
418 AC_MSG_RESULT($use_ccid_driver)
419
420 AC_MSG_CHECKING([whether to auto start dirmngr])
421 AC_ARG_ENABLE(dirmngr-auto-start,
422               AC_HELP_STRING([--disable-dirmngr-auto-start],
423                              [disable auto starting of the dirmngr]),
424               dirmngr_auto_start=$enableval)
425 AC_MSG_RESULT($dirmngr_auto_start)
426 if test "$dirmngr_auto_start" = yes ; then
427     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
428               [Define to enable auto starting of the dirmngr])
429 fi
430
431
432 #
433 # To avoid double inclusion of config.h which might happen at some
434 # places, we add the usual double inclusion protection at the top of
435 # config.h.
436 #
437 AH_TOP([
438 #ifndef GNUPG_CONFIG_H_INCLUDED
439 #define GNUPG_CONFIG_H_INCLUDED
440 ])
441
442 #
443 # Stuff which goes at the bottom of config.h.
444 #
445 AH_BOTTOM([
446 /* This is the major version number of GnuPG so that
447    source included files can test for this.  Note, that
448    we use 2 here even for GnuPG 1.9.x. */
449 #define GNUPG_MAJOR_VERSION 2
450
451 /* Now to separate file name parts.
452    Please note that the string version must not contain more
453    than one character because the code assumes strlen()==1 */
454 #ifdef HAVE_DOSISH_SYSTEM
455 #define DIRSEP_C '\\'
456 #define DIRSEP_S "\\"
457 #define EXTSEP_C '.'
458 #define EXTSEP_S "."
459 #define PATHSEP_C ';'
460 #define PATHSEP_S ";"
461 #define EXEEXT_S ".exe"
462 #else
463 #define DIRSEP_C '/'
464 #define DIRSEP_S "/"
465 #define EXTSEP_C '.'
466 #define EXTSEP_S "."
467 #define PATHSEP_C ':'
468 #define PATHSEP_S ":"
469 #define EXEEXT_S ""
470 #endif
471
472 /* This is the same as VERSION, but should be overridden if the
473    platform cannot handle things like dots '.' in filenames. Set
474    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
475    uses for dots and dashes. */
476 #define SAFE_VERSION VERSION
477 #define SAFE_VERSION_DOT  '.'
478 #define SAFE_VERSION_DASH '-'
479
480 /* Some global constants. */
481 #ifdef HAVE_DOSISH_SYSTEM
482 # ifdef HAVE_DRIVE_LETTERS
483 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
484 # else
485 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
486 # endif
487 #elif defined(__VMS)
488 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
489 #else
490 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
491 #endif
492 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
493 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
494
495 /* For some systems (DOS currently), we hardcode the path here.  For
496    POSIX systems the values are constructed by the Makefiles, so that
497    the values may be overridden by the make invocations; this is to
498    comply with the GNU coding standards.  Note that these values are
499    only defaults.  */
500 #ifdef HAVE_DOSISH_SYSTEM
501 # ifdef HAVE_DRIVE_LETTERS
502 #  define GNUPG_BINDIR      "c:\\gnupg"
503 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
504 #  define GNUPG_LIBDIR      "c:\\gnupg"
505 #  define GNUPG_DATADIR     "c:\\gnupg"
506 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
507 # else
508 #  define GNUPG_BINDIR      "\\gnupg"
509 #  define GNUPG_LIBEXECDIR  "\\gnupg"
510 #  define GNUPG_LIBDIR      "\\gnupg"
511 #  define GNUPG_DATADIR     "\\gnupg"
512 #  define GNUPG_SYSCONFDIR  "\\gnupg"
513 # endif
514 #endif
515
516 /* Derive some other constants. */
517 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
518 #define EXEC_TEMPFILE_ONLY
519 #endif
520
521
522 /* We didn't define endianness above, so get it from OS macros.  This
523    is intended for making fat binary builds on OS X. */
524 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
525 #if defined(__BIG_ENDIAN__)
526 #define BIG_ENDIAN_HOST 1
527 #elif defined(__LITTLE_ENDIAN__)
528 #define LITTLE_ENDIAN_HOST 1
529 #else
530 #error "No endianness found"
531 #endif
532 #endif
533
534
535 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
536    ldap_start_tls_s because that is the actual symbol used in the
537    library.  winldap.h redefines it to our commonly used value,
538    thus we define our usual macro here.  */
539 #ifdef HAVE_LDAP_START_TLS_SA
540 # ifndef HAVE_LDAP_START_TLS_S
541 #  define HAVE_LDAP_START_TLS_S 1
542 # endif
543 #endif
544
545 /* Provide the es_ macro for estream.  */
546 #define GPGRT_ENABLE_ES_MACROS 1
547
548 /* Tell libgcrypt not to use its own libgpg-error implementation. */
549 #define USE_LIBGPG_ERROR 1
550
551 /* Tell Libgcrypt not to include deprecated definitions.  */
552 #define GCRYPT_NO_DEPRECATED 1
553
554 /* Our HTTP code is used in estream mode.  */
555 #define HTTP_USE_ESTREAM 1
556
557 /* Under W32 we do an explicit socket initialization, thus we need to
558    avoid the on-demand initialization which would also install an atexit
559    handler.  */
560 #define HTTP_NO_WSASTARTUP
561
562 /* Under Windows we use the gettext code from libgpg-error.  */
563 #define GPG_ERR_ENABLE_GETTEXT_MACROS
564
565 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
566 #define GPG_ERR_ENABLE_ERRNO_MACROS
567
568 #endif /*GNUPG_CONFIG_H_INCLUDED*/
569 ])
570
571
572 AM_MAINTAINER_MODE
573 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
574
575 # Checks for programs.
576 AC_MSG_NOTICE([checking for programs])
577 AC_PROG_MAKE_SET
578 AM_SANITY_CHECK
579 missing_dir=`cd $ac_aux_dir && pwd`
580 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
581 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
582 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
583 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
584 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
585 AM_SILENT_RULES
586 AC_PROG_AWK
587 AC_PROG_CC
588 AC_PROG_CPP
589 AM_PROG_CC_C_O
590 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
591   AC_MSG_ERROR([[No C-89 compiler found]])
592 fi
593 AC_PROG_INSTALL
594 AC_PROG_LN_S
595 AC_PROG_RANLIB
596 AC_CHECK_TOOL(AR, ar, :)
597 AC_PATH_PROG(PERL,"perl")
598 AC_CHECK_TOOL(WINDRES, windres, :)
599 AC_ISC_POSIX
600 AC_SYS_LARGEFILE
601 GNUPG_CHECK_USTAR
602
603
604 # We need to compile and run a program on the build machine.  A
605 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
606 # the AC archive is broken for autoconf 2.57.  Given that there is no
607 # newer version of that macro, we assume that it is also broken for
608 # autoconf 2.61 and thus we use a simple but usually sufficient
609 # approach.
610 AC_MSG_CHECKING(for cc for build)
611 if test "$cross_compiling" = "yes"; then
612   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
613 else
614   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
615 fi
616 AC_MSG_RESULT($CC_FOR_BUILD)
617 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
618
619 # We need to call this macro because other pkg-config macros are
620 # not always used.
621 PKG_PROG_PKG_CONFIG
622
623
624 try_gettext=yes
625 require_iconv=yes
626 have_dosish_system=no
627 have_w32_system=no
628 have_w32ce_system=no
629 have_android_system=no
630 use_simple_gettext=no
631 use_ldapwrapper=yes
632 mmap_needed=yes
633 case "${host}" in
634     *-mingw32*)
635         # special stuff for Windoze NT
636         ac_cv_have_dev_random=no
637         AC_DEFINE(USE_ONLY_8DOT3,1,
638                   [Set this to limit filenames to the 8.3 format])
639         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
640                   [Because the Unix gettext has too much overhead on
641                    MingW32 systems and these systems lack Posix functions,
642                    we use a simplified version of gettext])
643         have_dosish_system=yes
644         have_w32_system=yes
645         require_iconv=no
646         use_ldapwrapper=no  # Fixme: Do this only for CE.
647         case "${host}" in
648           *-mingw32ce*)
649             have_w32ce_system=yes
650             ;;
651           *)
652             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
653                       [Defined if the OS supports drive letters.])
654             ;;
655         esac
656         try_gettext="no"
657         use_simple_gettext=yes
658         mmap_needed=no
659         ;;
660     i?86-emx-os2 | i?86-*-os2*emx )
661         # OS/2 with the EMX environment
662         ac_cv_have_dev_random=no
663         AC_DEFINE(HAVE_DRIVE_LETTERS)
664         have_dosish_system=yes
665         try_gettext="no"
666         ;;
667
668     i?86-*-msdosdjgpp*)
669         # DOS with the DJGPP environment
670         ac_cv_have_dev_random=no
671         AC_DEFINE(HAVE_DRIVE_LETTERS)
672         have_dosish_system=yes
673         try_gettext="no"
674         ;;
675
676     *-*-hpux*)
677         if test -z "$GCC" ; then
678             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
679         fi
680         ;;
681     *-dec-osf4*)
682         if test -z "$GCC" ; then
683             # Suppress all warnings
684             # to get rid of the unsigned/signed char mismatch warnings.
685             CFLAGS="-w $CFLAGS"
686         fi
687         ;;
688     *-dec-osf5*)
689         if test -z "$GCC" ; then
690             # Use the newer compiler `-msg_disable ptrmismatch1' to
691             # get rid of the unsigned/signed char mismatch warnings.
692             # Using this may hide other pointer mismatch warnings, but
693             # it at least lets other warning classes through
694             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
695         fi
696         ;;
697     m68k-atari-mint)
698         ;;
699     *-linux-android*)
700         have_android_system=yes
701         # Android is fully utf-8 and we do not want to use iconv to
702         # keeps things simple
703         require_iconv=no
704         ;;
705     *)
706        ;;
707 esac
708
709 if test "$have_dosish_system" = yes; then
710    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
711              [Defined if we run on some of the PCDOS like systems
712               (DOS, Windoze. OS/2) with special properties like
713               no file modes, case insensitive file names and preferred
714               use of backslashes as directory name separators.])
715 fi
716 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
717
718 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
719
720 if test "$have_w32_system" = yes; then
721    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
722    if test "$have_w32ce_system" = yes; then
723       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
724    fi
725 fi
726 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
727 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
728
729 if test "$have_android_system" = yes; then
730    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
731 fi
732 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
733
734
735 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
736 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
737
738
739 #
740 # Checks for libraries.
741 #
742 AC_MSG_NOTICE([checking for libraries])
743
744
745 #
746 # libgpg-error is a library with error codes shared between GnuPG
747 # related projects.
748 #
749 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
750                   have_gpg_error=yes,have_gpg_error=no)
751
752
753 #
754 # Libgcrypt is our generic crypto library
755 #
756 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
757         have_libgcrypt=yes,have_libgcrypt=no)
758
759
760 #
761 # libassuan is used for IPC
762 #
763 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
764                   have_libassuan=yes,have_libassuan=no)
765 if test "$have_libassuan" = "yes"; then
766   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
767                      [version of the libassuan library])
768   show_tor_support="only .onion"
769 fi
770
771
772 #
773 # libksba is our X.509 support library
774 #
775 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
776
777
778 #
779 # libusb allows us to use the integrated CCID smartcard reader driver.
780 #
781 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
782 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
783    case "${host}" in
784      *-mingw32*)
785        LIBUSB_NAME=
786        LIBUSB_LIBS=
787        LIBUSB_CPPFLAGS=
788        ;;
789      *-*-darwin*)
790        LIBUSB_NAME=usb-1.0
791        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
792        ;;
793      *-*-freebsd*)
794        # FreeBSD has a native 1.0 compatible library by -lusb.
795        LIBUSB_NAME=usb
796        LIBUSB_LIBS=
797        ;;
798      *)
799        LIBUSB_NAME=usb-1.0
800        LIBUSB_LIBS=
801        ;;
802    esac
803 fi
804 if test x"$LIBUSB_NAME" != x ; then
805    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
806                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
807                   have_libusb=yes ])
808    AC_MSG_CHECKING([libusb include dir])
809    usb_incdir_found="no"
810    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
811      _libusb_save_cppflags=$CPPFLAGS
812      if test -n "${_incdir}"; then
813        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
814      fi
815      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
816      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
817      CPPFLAGS=${_libusb_save_cppflags}
818      if test "$usb_incdir_found" = "yes"; then
819        break
820      fi
821    done
822    if test "$usb_incdir_found" = "yes"; then
823      AC_MSG_RESULT([${usb_incdir}])
824    else
825      AC_MSG_RESULT([not found])
826      usb_incdir=""
827      have_libusb=no
828      if test "$use_ccid_driver" != yes; then
829        use_ccid_driver=no
830      fi
831      LIBUSB_LIBS=""
832    fi
833
834    if test "$have_libusb" = yes; then
835      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
836    fi
837    if test x"$usb_incdir" = x; then
838      LIBUSB_CPPFLAGS=""
839    else
840      LIBUSB_CPPFLAGS="-I${usb_incdir}"
841    fi
842 fi
843 AC_SUBST(LIBUSB_LIBS)
844 AC_SUBST(LIBUSB_CPPFLAGS)
845
846 #
847 # Check wether it is necessary to link against libdl.
848 # (For example to load libpcsclite)
849 #
850 gnupg_dlopen_save_libs="$LIBS"
851 LIBS=""
852 AC_SEARCH_LIBS(dlopen, c dl,,,)
853 DL_LIBS=$LIBS
854 AC_SUBST(DL_LIBS)
855 LIBS="$gnupg_dlopen_save_libs"
856
857
858 # Checks for g10
859
860 AC_ARG_ENABLE(sqlite,
861                 AC_HELP_STRING([--disable-sqlite],
862                                [disable the use of SQLITE]),
863               try_sqlite=$enableval, try_sqlite=yes)
864
865 if test x"$use_tofu" = xyes ; then
866   if test x"$try_sqlite" = xyes ; then
867     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
868                                  [have_sqlite=yes],
869                                  [have_sqlite=no])
870   fi
871   if test "$have_sqlite" = "yes"; then
872     :
873     AC_SUBST([SQLITE3_CFLAGS])
874     AC_SUBST([SQLITE3_LIBS])
875   else
876     use_tofu=no
877     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
878     AC_MSG_WARN([[
879 ***
880 *** Building without SQLite support - TOFU disabled
881 ***
882 *** $tmp]])
883   fi
884 fi
885
886 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
887
888 if test x"$use_tofu" = xyes ; then
889     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
890 fi
891
892
893 # Checks for g13
894
895 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
896 AC_DEFINE_UNQUOTED(ENCFS,
897         "${ENCFS}", [defines the filename of the encfs program])
898
899 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
900 AC_DEFINE_UNQUOTED(FUSERMOUNT,
901         "${FUSERMOUNT}", [defines the filename of the fusermount program])
902
903
904 # Checks for dirmngr
905
906
907 #
908 # Checks for symcryptrun:
909 #
910
911 # libutil has openpty() and login_tty().
912 AC_CHECK_LIB(util, openpty,
913               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
914                 AC_DEFINE(HAVE_LIBUTIL,1,
915                          [defined if libutil is available])
916              ])
917 AC_SUBST(LIBUTIL_LIBS)
918
919 # shred is used to clean temporary plain text files.
920 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
921 AC_DEFINE_UNQUOTED(SHRED,
922         "${SHRED}", [defines the filename of the shred program])
923
924
925 #
926 # Check whether the nPth library is available
927 #
928 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
929 if test "$have_npth" = "yes"; then
930   AC_DEFINE(HAVE_NPTH, 1,
931               [Defined if the New Portable Thread Library is available])
932   AC_DEFINE(USE_NPTH, 1,
933               [Defined if support for nPth is requested and nPth is available])
934 else
935   AC_MSG_WARN([[
936 ***
937 *** To support concurrent access for example in gpg-agent and the SCdaemon
938 *** we need the support of the New Portable Threads Library.
939 ***]])
940 fi
941
942
943 #
944 # NTBTLS is our TLS library.  If it is not available fallback to
945 # GNUTLS.
946 #
947 AC_ARG_ENABLE(ntbtls,
948               AC_HELP_STRING([--disable-ntbtls],
949                              [disable the use of NTBTLS as TLS library]),
950               try_ntbtls=$enableval, try_ntbtls=yes)
951 if test x"$try_ntbtls" = xyes ; then
952   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
953                  [have_ntbtls=yes],[have_ntbtls=no])
954 fi
955 if test "$have_ntbtls" = yes ; then
956    use_tls_library=ntbtls
957    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
958 else
959   AC_ARG_ENABLE(gnutls,
960                 AC_HELP_STRING([--disable-gnutls],
961                                [disable GNUTLS as fallback TLS library]),
962                 try_gnutls=$enableval, try_gnutls=yes)
963   if test x"$try_gnutls" = xyes ; then
964     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
965                                    [have_gnutls=yes],
966                                    [have_gnutls=no])
967   fi
968   if test "$have_gnutls" = "yes"; then
969     AC_SUBST([LIBGNUTLS_CFLAGS])
970     AC_SUBST([LIBGNUTLS_LIBS])
971     use_tls_library=gnutls
972     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
973   else
974     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
975     AC_MSG_WARN([[
976 ***
977 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
978 ***
979 *** $tmp]])
980   fi
981 fi
982
983
984 AC_MSG_NOTICE([checking for networking options])
985
986 #
987 # Must check for network library requirements before doing link tests
988 # for ldap, for example. If ldap libs are static (or dynamic and without
989 # ELF runtime link paths), then link will fail and LDAP support won't
990 # be detected.
991 #
992 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
993         [NETLIBS="-lnsl $NETLIBS"]))
994 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
995         [NETLIBS="-lsocket $NETLIBS"]))
996
997
998 #
999 # Check for ADNS.
1000 #
1001 _cppflags="${CPPFLAGS}"
1002 _ldflags="${LDFLAGS}"
1003 AC_ARG_WITH(adns,
1004             AC_HELP_STRING([--with-adns=DIR],
1005                            [look for the adns library in DIR]),
1006             [if test -d "$withval"; then
1007                CPPFLAGS="${CPPFLAGS} -I$withval/include"
1008                LDFLAGS="${LDFLAGS} -L$withval/lib"
1009              fi])
1010 if test "$with_adns" != "no"; then
1011   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
1012   AC_CHECK_FUNCS(adns_free)
1013   AC_MSG_CHECKING([if adns supports adns_if_tormode])
1014   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1015     #include <adns.h>
1016     adns_initflags flags = adns_if_tormode;
1017   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
1018   AC_MSG_RESULT($adns_if_tormode)
1019   if test x"$adns_if_tormode" = xyes; then
1020     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
1021     if test "$show_tor_support" != "no"; then
1022       show_tor_support=yes
1023     fi
1024   fi
1025 fi
1026 CPPFLAGS=${_cppflags}
1027 LDFLAGS=${_ldflags}
1028 if test "$have_adns" = "yes"; then
1029   DNSLIBS="-ladns"
1030   AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1031 else
1032   DNSLIBS=""
1033 fi
1034
1035
1036 #
1037 # Check standard resolver functions.
1038 #
1039 if test "$build_dirmngr" = "yes"; then
1040   _dns_save_libs=$LIBS
1041   LIBS=""
1042
1043   # Find the system resolver which can always be enabled with
1044   # the dirmngr option --standard-resolver.
1045
1046   # the double underscore thing is a glibc-ism?
1047   AC_SEARCH_LIBS(res_query,resolv bind,,
1048                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1049   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1050                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1051
1052   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1053   # and for some reason fools us into believing we don't need
1054   # -lresolv even if we do.  Since the test program checking for the
1055   # symbol does not include <resolv.h>, we need to check for the
1056   # renamed symbol explicitly.
1057   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1058       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1059           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1060
1061   if test x"$have_resolver" != xno ; then
1062
1063       # Make sure that the BIND 4 resolver interface is workable before
1064       # enabling any code that calls it.  At some point I'll rewrite the
1065       # code to use the BIND 8 resolver API.
1066       # We might also want to use adns instead.  Problem with ADNS is that
1067       # it does not support v6.
1068
1069     AC_MSG_CHECKING([whether the resolver is usable])
1070     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1071 #include <netinet/in.h>
1072 #include <arpa/nameser.h>
1073 #include <resolv.h>]],
1074 [[unsigned char answer[PACKETSZ];
1075   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1076   dn_skipname(0,0);
1077   dn_expand(0,0,0,0,0);
1078 ]])],have_resolver=yes,have_resolver=no)
1079     AC_MSG_RESULT($have_resolver)
1080
1081     # This is Apple-specific and somewhat bizarre as they changed the
1082     # define in bind 8 for some reason.
1083
1084     if test x"$have_resolver" != xyes ; then
1085       AC_MSG_CHECKING(
1086            [whether I can make the resolver usable with BIND_8_COMPAT])
1087       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1088 #include <sys/types.h>
1089 #include <netinet/in.h>
1090 #include <arpa/nameser.h>
1091 #include <resolv.h>]],
1092 [[unsigned char answer[PACKETSZ];
1093   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1094   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1095 ]])],[have_resolver=yes ; need_compat=yes])
1096       AC_MSG_RESULT($have_resolver)
1097     fi
1098   fi
1099
1100   if test x"$have_resolver" = xyes ; then
1101     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1102     DNSLIBS="$DNSLIBS $LIBS"
1103     if test x"$need_compat" = xyes ; then
1104       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1105     fi
1106   else
1107     AC_MSG_WARN([[
1108 ***
1109 *** The system's DNS resolver is not usable.
1110 *** Dirmngr functionality is limited.
1111 ***]])
1112    show_tor_support="${show_tor_support} (no system resolver)"
1113   fi
1114
1115   LIBS=$_dns_save_libs
1116 fi
1117
1118 AC_SUBST(DNSLIBS)
1119
1120
1121 #
1122 # Check for LDAP
1123 #
1124 # Note that running the check changes the variable
1125 # gnupg_have_ldap from "n/a" to "no" or "yes".
1126
1127 AC_ARG_ENABLE(ldap,
1128     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1129     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1130
1131 if test "$gnupg_have_ldap" != "no" ; then
1132   if test "$build_dirmngr" = "yes" ; then
1133      GNUPG_CHECK_LDAP($NETLIBS)
1134      AC_CHECK_LIB(lber, ber_free,
1135                   [ LBER_LIBS="$LBER_LIBS -llber"
1136                     AC_DEFINE(HAVE_LBER,1,
1137                              [defined if liblber is available])
1138                     have_lber=yes
1139                  ])
1140   fi
1141 fi
1142 AC_SUBST(LBER_LIBS)
1143 if test "$gnupg_have_ldap" = "no"; then
1144     AC_MSG_WARN([[
1145 ***
1146 *** Building without LDAP support.
1147 *** No CRL access or X.509 certificate search available.
1148 ***]])
1149 fi
1150
1151 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1152 if test "$gnupg_have_ldap" = yes ; then
1153   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1154 else
1155  use_ldapwrapper=no
1156 fi
1157
1158 if test "$use_ldapwrapper" = yes; then
1159    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1160 fi
1161 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1162
1163
1164
1165
1166 #
1167 # Check for sendmail
1168 #
1169 # This isn't necessarily sendmail itself, but anything that gives a
1170 # sendmail-ish interface to the outside world.  That includes Exim,
1171 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1172 AC_ARG_WITH(mailprog,
1173       AC_HELP_STRING([--with-mailprog=NAME],
1174                      [use "NAME -t" for mail transport]),
1175              ,with_mailprog=yes)
1176 if test x"$with_mailprog" = xyes ; then
1177     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1178 elif test x"$with_mailprog" != xno ; then
1179     AC_MSG_CHECKING([for a mail transport program])
1180     AC_SUBST(SENDMAIL,$with_mailprog)
1181     AC_MSG_RESULT($with_mailprog)
1182 fi
1183
1184
1185 #
1186 # Construct a printable name of the OS
1187 #
1188 case "${host}" in
1189     *-mingw32ce*)
1190         PRINTABLE_OS_NAME="W32CE"
1191         ;;
1192     *-mingw32*)
1193         PRINTABLE_OS_NAME="MingW32"
1194         ;;
1195     *-*-cygwin*)
1196         PRINTABLE_OS_NAME="Cygwin"
1197         ;;
1198     i?86-emx-os2 | i?86-*-os2*emx )
1199         PRINTABLE_OS_NAME="OS/2"
1200         ;;
1201     i?86-*-msdosdjgpp*)
1202         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1203         try_dynload=no
1204         ;;
1205     *-linux*)
1206         PRINTABLE_OS_NAME="GNU/Linux"
1207         ;;
1208     *)
1209         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1210         ;;
1211 esac
1212 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1213                    [A human readable text with the name of the OS])
1214
1215
1216 #
1217 # Checking for iconv
1218 #
1219 if test "$require_iconv" = yes; then
1220   AM_ICONV
1221 else
1222   LIBICONV=
1223   LTLIBICONV=
1224   AC_SUBST(LIBICONV)
1225   AC_SUBST(LTLIBICONV)
1226 fi
1227
1228
1229 #
1230 # Check for gettext
1231 #
1232 # This is "GNU gnupg" - The project-id script from gettext
1233 #                       needs this string
1234 #
1235 AC_MSG_NOTICE([checking for gettext])
1236 AM_PO_SUBDIRS
1237 AM_GNU_GETTEXT_VERSION([0.17])
1238 if test "$try_gettext" = yes; then
1239   AM_GNU_GETTEXT([external],[need-ngettext])
1240
1241   # gettext requires some extra checks.  These really should be part of
1242   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1243   # function checks to here.
1244
1245   AC_CHECK_FUNCS(strchr)
1246 else
1247   USE_NLS=no
1248   USE_INCLUDED_LIBINTL=no
1249   BUILD_INCLUDED_LIBINTL=no
1250   POSUB=po
1251   AC_SUBST(USE_NLS)
1252   AC_SUBST(USE_INCLUDED_LIBINTL)
1253   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1254   AC_SUBST(POSUB)
1255 fi
1256
1257 # We use HAVE_LANGINFO_CODESET in a couple of places.
1258 AM_LANGINFO_CODESET
1259
1260 # Checks required for our use of locales
1261 gt_LC_MESSAGES
1262
1263
1264 #
1265 # SELinux support
1266 #
1267 if test "$selinux_support" = yes ; then
1268   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1269 fi
1270
1271
1272 #
1273 # Checks for header files.
1274 #
1275 AC_MSG_NOTICE([checking for header files])
1276 AC_HEADER_STDC
1277 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1278                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1279                   signal.h])
1280 AC_HEADER_TIME
1281
1282
1283 #
1284 # Checks for typedefs, structures, and compiler characteristics.
1285 #
1286 AC_MSG_NOTICE([checking for system characteristics])
1287 AC_C_CONST
1288 AC_C_INLINE
1289 AC_C_VOLATILE
1290 AC_TYPE_SIZE_T
1291 AC_TYPE_MODE_T
1292 AC_TYPE_SIGNAL
1293 AC_DECL_SYS_SIGLIST
1294
1295 gl_HEADER_SYS_SOCKET
1296 gl_TYPE_SOCKLEN_T
1297
1298 AC_SEARCH_LIBS([inet_addr], [nsl])
1299
1300 AC_ARG_ENABLE(endian-check,
1301               AC_HELP_STRING([--disable-endian-check],
1302               [disable the endian check and trust the OS provided macros]),
1303               endiancheck=$enableval,endiancheck=yes)
1304
1305 if test x"$endiancheck" = xyes ; then
1306   GNUPG_CHECK_ENDIAN
1307 fi
1308
1309 # fixme: we should get rid of the byte type
1310 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1311 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1312 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1313 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1314 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1315
1316 AC_CHECK_SIZEOF(unsigned short)
1317 AC_CHECK_SIZEOF(unsigned int)
1318 AC_CHECK_SIZEOF(unsigned long)
1319 AC_CHECK_SIZEOF(unsigned long long)
1320 AC_HEADER_TIME
1321 AC_CHECK_SIZEOF(time_t,,[[
1322 #include <stdio.h>
1323 #if TIME_WITH_SYS_TIME
1324 # include <sys/time.h>
1325 # include <time.h>
1326 #else
1327 # if HAVE_SYS_TIME_H
1328 #  include <sys/time.h>
1329 # else
1330 #  include <time.h>
1331 # endif
1332 #endif
1333 ]])
1334 GNUPG_TIME_T_UNSIGNED
1335
1336
1337 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1338    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1339    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1340     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1341 fi
1342
1343
1344 #
1345 # Checks for library functions.
1346 #
1347 AC_MSG_NOTICE([checking for library functions])
1348 AC_CHECK_DECLS(getpagesize)
1349 AC_FUNC_FSEEKO
1350 AC_FUNC_VPRINTF
1351 AC_FUNC_FORK
1352 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1353 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1354 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1355 AC_CHECK_FUNCS([canonicalize_file_name])
1356 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1357 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1358 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1359 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1360 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1361                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1362                 flockfile funlockfile getpwnam getpwuid \
1363                 getenv inet_pton strpbrk])
1364
1365 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1366 # Given that we use nanosleep only as an optimization over a select
1367 # based wait function we want it only if it is available in libc.
1368 _save_libs="$LIBS"
1369 AC_SEARCH_LIBS([nanosleep], [],
1370                [AC_DEFINE(HAVE_NANOSLEEP,1,
1371                 [Define to 1 if you have the `nanosleep' function in libc.])])
1372 LIBS="$_save_libs"
1373
1374
1375 # See whether libc supports the Linux inotify interface
1376 case "${host}" in
1377     *-*-linux*)
1378         AC_CHECK_FUNCS([inotify_init])
1379         ;;
1380 esac
1381
1382
1383 if test "$have_android_system" = yes; then
1384    # On Android ttyname is a stub but prints an error message.
1385    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1386              [Defined if ttyname does not work properly])
1387 fi
1388
1389 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1390
1391 # Dirmngr requires mmap on Unix systems.
1392 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1393   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1394 fi
1395
1396 #
1397 # W32 specific test
1398 #
1399 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1400
1401 #
1402 # Sanity check regex.  Tests adapted from mutt.
1403 #
1404 AC_MSG_CHECKING([whether regular expression support is requested])
1405 AC_ARG_ENABLE(regex,
1406   AC_HELP_STRING([--disable-regex],
1407     [do not handle regular expressions in trust signatures]),
1408   use_regex=$enableval, use_regex=yes)
1409 AC_MSG_RESULT($use_regex)
1410
1411 if test "$use_regex" = yes ; then
1412   _cppflags="${CPPFLAGS}"
1413   _ldflags="${LDFLAGS}"
1414   AC_ARG_WITH(regex,
1415      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1416       [
1417       if test -d "$withval" ; then
1418         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1419         LDFLAGS="${LDFLAGS} -L$withval/lib"
1420       fi
1421       ],withval="")
1422
1423   # Does the system have regex functions at all?
1424   AC_SEARCH_LIBS([regcomp], [regex])
1425   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1426
1427   if test $gnupg_cv_have_regex = no; then
1428     use_regex=no
1429   else
1430     if test x"$cross_compiling" = xyes; then
1431       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1432     else
1433       AC_CACHE_CHECK([whether your system's regexp library is broken],
1434        [gnupg_cv_regex_broken],
1435        AC_TRY_RUN([
1436 #include <unistd.h>
1437 #include <regex.h>
1438 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1439        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1440
1441       if test $gnupg_cv_regex_broken = yes; then
1442         AC_MSG_WARN([your regex is broken - disabling regex use])
1443         use_regex=no
1444       fi
1445     fi
1446   fi
1447   CPPFLAGS="${_cppflags}"
1448   LDFLAGS="${_ldflags}"
1449 fi
1450
1451 if test "$use_regex" != yes ; then
1452   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1453 fi
1454 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1455
1456
1457
1458 #
1459 # Do we have zlib? Must do it here because Solaris failed
1460 # when compiling a conftest (due to the "-lz" from LIBS).
1461 # Note that we combine zlib and bzlib2 in ZLIBS.
1462 #
1463 if test "$use_zip" = yes ; then
1464   _cppflags="${CPPFLAGS}"
1465   _ldflags="${LDFLAGS}"
1466   AC_ARG_WITH(zlib,
1467     [  --with-zlib=DIR         use libz in DIR],[
1468       if test -d "$withval"; then
1469         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1470         LDFLAGS="${LDFLAGS} -L$withval/lib"
1471       fi
1472     ])
1473
1474   AC_CHECK_HEADER(zlib.h,
1475      AC_CHECK_LIB(z, deflateInit2_,
1476        [
1477        ZLIBS="-lz"
1478        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1479        ],
1480        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1481        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1482 fi
1483
1484
1485 #
1486 # Check whether we can support bzip2
1487 #
1488 if test "$use_bzip2" = yes ; then
1489   _cppflags="${CPPFLAGS}"
1490   _ldflags="${LDFLAGS}"
1491   AC_ARG_WITH(bzip2,
1492      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1493       [
1494       if test -d "$withval" ; then
1495         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1496         LDFLAGS="${LDFLAGS} -L$withval/lib"
1497       fi
1498       ],withval="")
1499
1500   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1501   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1502   # woefully out of date.
1503   if test "$withval" != no ; then
1504      AC_CHECK_HEADER(bzlib.h,
1505         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1506           [
1507           have_bz2=yes
1508           ZLIBS="$ZLIBS -lbz2"
1509           AC_DEFINE(HAVE_BZIP2,1,
1510                   [Defined if the bz2 compression library is available])
1511           ],
1512           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1513           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1514   fi
1515 fi
1516 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1517 AC_SUBST(ZLIBS)
1518
1519
1520 # Check for readline support
1521 GNUPG_CHECK_READLINE
1522
1523
1524 if test "$development_version" = yes; then
1525     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1526             [Defined if this is not a regular release])
1527 fi
1528
1529 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1530
1531 GNUPG_CHECK_GNUMAKE
1532
1533 # Add some extra libs here so that previous tests don't fail for
1534 # mysterious reasons - the final link step should bail out.
1535 # W32SOCKLIBS is also defined so that if can be used for tools not
1536 # requiring any network stuff but linking to code in libcommon which
1537 # tracks in winsock stuff (e.g. init_common_subsystems).
1538 if test "$have_w32_system" = yes; then
1539    if test "$have_w32ce_system" = yes; then
1540      W32SOCKLIBS="-lws2"
1541    else
1542      W32SOCKLIBS="-lws2_32"
1543    fi
1544    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1545 fi
1546
1547 AC_SUBST(NETLIBS)
1548 AC_SUBST(W32SOCKLIBS)
1549
1550 #
1551 # Setup gcc specific options
1552 #
1553 AC_MSG_NOTICE([checking for cc features])
1554 if test "$GCC" = yes; then
1555     mycflags=
1556     mycflags_save=$CFLAGS
1557
1558     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1559     # options.  This is the case for gcc >= 4.6
1560     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1561     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1562 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1563 #kickerror
1564 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1565     AC_MSG_RESULT($_gcc_silent_wno)
1566
1567     # Note that it is okay to use CFLAGS here because these are just
1568     # warning options and the user should have a chance of overriding
1569     # them.
1570     if test "$USE_MAINTAINER_MODE" = "yes"; then
1571         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1572         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1573         if test x"$_gcc_silent_wno" = xyes ; then
1574           _gcc_wopt=yes
1575         else
1576           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1577           CFLAGS="-Wno-missing-field-initializers"
1578           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1579                             [_gcc_wopt=yes],[_gcc_wopt=no])
1580           AC_MSG_RESULT($_gcc_wopt)
1581         fi
1582         if test x"$_gcc_wopt" = xyes ; then
1583           mycflags="$mycflags -W -Wno-sign-compare"
1584           mycflags="$mycflags -Wno-missing-field-initializers"
1585         fi
1586
1587         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1588         CFLAGS="-Wdeclaration-after-statement"
1589         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1590         AC_MSG_RESULT($_gcc_wopt)
1591         if test x"$_gcc_wopt" = xyes ; then
1592           mycflags="$mycflags -Wdeclaration-after-statement"
1593         fi
1594     else
1595         mycflags="$mycflags -Wall"
1596     fi
1597
1598     if test x"$_gcc_silent_wno" = xyes ; then
1599       _gcc_psign=yes
1600     else
1601       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1602       CFLAGS="-Wno-pointer-sign"
1603       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1604                         [_gcc_psign=yes],[_gcc_psign=no])
1605       AC_MSG_RESULT($_gcc_psign)
1606     fi
1607     if test x"$_gcc_psign" = xyes ; then
1608        mycflags="$mycflags -Wno-pointer-sign"
1609     fi
1610
1611     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1612     CFLAGS="-Wpointer-arith"
1613     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1614     AC_MSG_RESULT($_gcc_psign)
1615     if test x"$_gcc_psign" = xyes ; then
1616        mycflags="$mycflags -Wpointer-arith"
1617     fi
1618
1619     CFLAGS="$mycflags $mycflags_save"
1620 fi
1621
1622
1623 #
1624 # This is handy for debugging so the compiler doesn't rearrange
1625 # things and eliminate variables.
1626 #
1627 AC_ARG_ENABLE(optimization,
1628    AC_HELP_STRING([--disable-optimization],
1629                   [disable compiler optimization]),
1630                   [if test $enableval = no ; then
1631                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1632                    fi])
1633
1634 #
1635 # Add user CFLAGS.
1636 #
1637 CFLAGS="$CFLAGS $CFLAGS_orig"
1638
1639 #
1640 # Decide what to build
1641 #
1642
1643 build_scdaemon_extra=""
1644 if test "$build_scdaemon" = "yes"; then
1645   if test $have_libusb = no; then
1646      build_scdaemon_extra="without internal CCID driver"
1647   fi
1648   if test -n "$build_scdaemon_extra"; then
1649      build_scdaemon_extra="(${build_scdaemon_extra})"
1650   fi
1651 fi
1652
1653
1654 #
1655 # Set variables for use by automake makefiles.
1656 #
1657 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1658 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1659 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1660 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1661 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1662 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1663 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1664 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1665 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1666 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1667 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1668
1669 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1670 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1671 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1672
1673 #
1674 # Set some defines for use gpgconf.
1675 #
1676 if test "$build_gpg" = yes ; then
1677     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1678 fi
1679 if test "$build_gpgsm" = yes ; then
1680     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1681 fi
1682 if test "$build_agent" = yes ; then
1683     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1684 fi
1685 if test "$build_scdaemon" = yes ; then
1686     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1687 fi
1688 if test "$build_dirmngr" = yes ; then
1689     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1690 fi
1691 if test "$build_g13" = yes ; then
1692     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1693 fi
1694
1695
1696 #
1697 # Define Name strings
1698 #
1699 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1700
1701 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1702 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1703
1704 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1705 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1706
1707 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1708 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1709                                         [The displayed name of gpg-agent])
1710
1711 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1712 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1713                                        [The displayed name of scdaemon])
1714
1715 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1716 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1717                                       [The displayed name of dirmngr])
1718
1719 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1720 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1721
1722 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1723 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1724                                       [The displayed name of gpgconf])
1725
1726 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1727
1728 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1729                    [The name of the agent socket])
1730 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1731                    [The name of the agent socket for remote access])
1732 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1733                    [The name of the agent socket for browsers])
1734 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1735                    [The name of the agent socket for ssh])
1736 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1737                    [The name of the dirmngr info envvar])
1738 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1739                    [The name of the SCdaemon socket])
1740 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1741                    [The name of the dirmngr socket])
1742 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1743                    "hkps://hkps.pool.sks-keyservers.net",
1744       [The default keyserver for dirmngr to use, if none is explicitly given])
1745
1746 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1747
1748 if test "$have_w32_system" = yes; then
1749   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1750                      [The directory part of the W32 registry keys])
1751 fi
1752
1753
1754 #
1755 # Provide information about the build.
1756 #
1757 BUILD_REVISION="mym4_revision"
1758 AC_SUBST(BUILD_REVISION)
1759 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1760                    [GIT commit id revision used to build this package])
1761
1762 changequote(,)dnl
1763 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1764 changequote([,])dnl
1765 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1766 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1767 AC_SUBST(BUILD_VERSION)
1768 AC_SUBST(BUILD_FILEVERSION)
1769
1770 AC_ARG_ENABLE([build-timestamp],
1771   AC_HELP_STRING([--enable-build-timestamp],
1772                  [set an explicit build timestamp for reproducibility.
1773                   (default is the current time in ISO-8601 format)]),
1774      [if test "$enableval" = "yes"; then
1775         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1776       else
1777         BUILD_TIMESTAMP="$enableval"
1778       fi
1779       BUILD_HOSTNAME="$ac_hostname"],
1780      [BUILD_TIMESTAMP="<none>"
1781       BUILD_HOSTNAME="<anon>"])
1782 AC_SUBST(BUILD_TIMESTAMP)
1783 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1784                    [The time this package was configured for a build])
1785 AC_SUBST(BUILD_HOSTNAME)
1786
1787
1788 #
1789 # Print errors here so that they are visible all
1790 # together and the user can acquire them all together.
1791 #
1792 die=no
1793 if test "$have_gpg_error" = "no"; then
1794    die=yes
1795    AC_MSG_NOTICE([[
1796 ***
1797 *** You need libgpg-error to build this program.
1798 **  This library is for example available at
1799 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1800 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1801 ***]])
1802 fi
1803 if test "$have_libgcrypt" = "no"; then
1804    die=yes
1805    AC_MSG_NOTICE([[
1806 ***
1807 *** You need libgcrypt to build this program.
1808 **  This library is for example available at
1809 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1810 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1811 ***]])
1812 fi
1813 if test "$have_libassuan" = "no"; then
1814    die=yes
1815    AC_MSG_NOTICE([[
1816 ***
1817 *** You need libassuan to build this program.
1818 *** This library is for example available at
1819 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1820 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1821 ***]])
1822 fi
1823 if test "$have_ksba" = "no"; then
1824     die=yes
1825     AC_MSG_NOTICE([[
1826 ***
1827 *** You need libksba to build this program.
1828 *** This library is for example available at
1829 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1830 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1831 ***]])
1832 fi
1833 if test "$gnupg_have_ldap" = yes; then
1834   if test "$have_w32ce_system" = yes; then
1835     AC_MSG_NOTICE([[
1836 *** Note that CeGCC might be broken, a package fixing this is:
1837 ***    http://files.kolab.org/local/windows-ce/
1838 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1839 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1840 ***]])
1841    fi
1842 fi
1843 if test "$have_npth" = "no"; then
1844     die=yes
1845     AC_MSG_NOTICE([[
1846 ***
1847 *** It is now required to build with support for the
1848 *** New Portable Threads Library (nPth). Please install this
1849 *** library first.  The library is for example available at
1850 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1851 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1852 ***]])
1853 fi
1854
1855 if test "$require_iconv" = yes; then
1856   if test "$am_func_iconv" != yes; then
1857     die=yes
1858     AC_MSG_NOTICE([[
1859 ***
1860 *** The system does not provide a working iconv function.  Please
1861 *** install a suitable library; for example GNU Libiconv which is
1862 *** available at:
1863 ***   http://ftp.gnu.org/gnu/libiconv/
1864 ***]])
1865   fi
1866 fi
1867
1868 if test "$use_ccid_driver" = yes; then
1869   if test "$have_libusb" != yes; then
1870     die=yes
1871     AC_MSG_NOTICE([[
1872 ***
1873 *** You need libusb to build the internal ccid driver.  Please
1874 *** install a libusb suitable for your system.
1875 ***]])
1876   fi
1877 fi
1878
1879 if test "$die" = "yes"; then
1880     AC_MSG_ERROR([[
1881 ***
1882 *** Required libraries not found. Please consult the above messages
1883 *** and install them before running configure again.
1884 ***]])
1885 fi
1886
1887
1888
1889 AC_CONFIG_FILES([ m4/Makefile
1890 Makefile
1891 po/Makefile.in
1892 common/Makefile
1893 common/w32info-rc.h
1894 kbx/Makefile
1895 g10/Makefile
1896 sm/Makefile
1897 agent/Makefile
1898 scd/Makefile
1899 g13/Makefile
1900 dirmngr/Makefile
1901 tools/gpg-zip
1902 tools/Makefile
1903 doc/Makefile
1904 tests/Makefile
1905 tests/gpgscm/Makefile
1906 tests/openpgp/Makefile
1907 tests/migrations/Makefile
1908 tests/pkits/Makefile
1909 g10/gpg.w32-manifest
1910 ])
1911
1912
1913 AC_OUTPUT
1914
1915
1916 echo "
1917         GnuPG v${VERSION} has been configured as follows:
1918
1919         Revision:  mym4_revision  (mym4_revision_dec)
1920         Platform:  $PRINTABLE_OS_NAME ($host)
1921
1922         OpenPGP:   $build_gpg
1923         S/MIME:    $build_gpgsm
1924         Agent:     $build_agent
1925         Smartcard: $build_scdaemon $build_scdaemon_extra
1926         G13:       $build_g13
1927         Dirmngr:   $build_dirmngr
1928         Gpgtar:    $build_gpgtar
1929         WKS tools: $build_wks_tools
1930
1931         Protect tool:      $show_gnupg_protect_tool_pgm
1932         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1933         Default agent:     $show_gnupg_agent_pgm
1934         Default pinentry:  $show_gnupg_pinentry_pgm
1935         Default scdaemon:  $show_gnupg_scdaemon_pgm
1936         Default dirmngr:   $show_gnupg_dirmngr_pgm
1937
1938         Dirmngr auto start:  $dirmngr_auto_start
1939         Readline support:    $gnupg_cv_have_readline
1940         LDAP support:        $gnupg_have_ldap
1941         TLS support:         $use_tls_library
1942         TOFU support:        $use_tofu
1943         Tor support:         $show_tor_support
1944 "
1945 if test x"$use_regex" != xyes ; then
1946 echo "
1947         Warning: No regular expression support available.
1948                  OpenPGP trust signatures won't work.
1949                  gpg-check-pattern will not be built.
1950 "
1951 fi
1952 if test "x${gpg_config_script_warn}" != x; then
1953 cat <<G10EOF
1954         Warning: Mismatches between the target platform and the
1955                  to be used libraries have been detected for:
1956                   ${gpg_config_script_warn}
1957                  Please check above for more warning messages.
1958
1959 G10EOF
1960 fi