tools: Allow retrieval of signed data from mime-maker.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [16])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_adns=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 card_support=yes
114 use_ccid_driver=auto
115 dirmngr_auto_start=yes
116 use_tls_library=no
117 large_secmem=no
118 show_tor_support=no
119
120
121 GNUPG_BUILD_PROGRAM(gpg, yes)
122 GNUPG_BUILD_PROGRAM(gpgsm, yes)
123 # The agent is a required part and can't be disabled anymore.
124 build_agent=yes
125 GNUPG_BUILD_PROGRAM(scdaemon, yes)
126 GNUPG_BUILD_PROGRAM(g13, no)
127 GNUPG_BUILD_PROGRAM(dirmngr, yes)
128 GNUPG_BUILD_PROGRAM(tools, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 # We use gpgtar to unpack test data, hence we always build it.  If the
132 # user opts out, we simply don't install it.
133 GNUPG_BUILD_PROGRAM(gpgtar, yes)
134 GNUPG_BUILD_PROGRAM(wks-tools, no)
135
136 AC_SUBST(PACKAGE)
137 AC_SUBST(PACKAGE_GT)
138 AC_SUBST(VERSION)
139 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
141                                 [Name of this package for gettext])
142 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
144                                         [Bug report address])
145 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
146                                        [Required version of Libgcrypt])
147 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
148                                        [Required version of Libksba])
149 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
150                                        [Required version of NTBTLS])
151
152
153
154 # The default is to use the modules from this package and the few
155 # other packages in a standard place; i.e where this package gets
156 # installed.  With these options it is possible to override these
157 # ${prefix} depended values with fixed paths, which can't be replaced
158 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
159 AC_ARG_WITH(agent-pgm,
160     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
161           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
162 AC_SUBST(GNUPG_AGENT_PGM)
163 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
164 show_gnupg_agent_pgm="(default)"
165 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
166
167 AC_ARG_WITH(pinentry-pgm,
168     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
169           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
170 AC_SUBST(GNUPG_PINENTRY_PGM)
171 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
172 show_gnupg_pinentry_pgm="(default)"
173 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
174
175
176 AC_ARG_WITH(scdaemon-pgm,
177     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
178           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
179 AC_SUBST(GNUPG_SCDAEMON_PGM)
180 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
181 show_gnupg_scdaemon_pgm="(default)"
182 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
183
184
185 AC_ARG_WITH(dirmngr-pgm,
186     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
187           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
188 AC_SUBST(GNUPG_DIRMNGR_PGM)
189 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
190 show_gnupg_dirmngr_pgm="(default)"
191 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
192
193 AC_ARG_WITH(protect-tool-pgm,
194     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
195           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
196 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
197 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
198 show_gnupg_protect_tool_pgm="(default)"
199 test -n "$GNUPG_PROTECT_TOOL_PGM" \
200       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
201
202 AC_ARG_WITH(dirmngr-ldap-pgm,
203     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
204           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
205 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
206 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
207 show_gnupg_dirmngr_ldap_pgm="(default)"
208 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
209       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
210
211 #
212 # On some platforms gpg2 is usually installed as gpg without using a
213 # symlink.  For correct operation of gpgconf it needs to know the
214 # installed name of gpg.  This option sets "gpg2"'s installed name to
215 # just "gpg".  Note that it might be required to rename gpg2 to gpg
216 # manually after the build process.
217 #
218 AC_ARG_ENABLE(gpg2-is-gpg,
219     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
220     gpg2_is_gpg=$enableval)
221 if test "$gpg2_is_gpg" != "yes"; then
222    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
223 fi
224 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=$use_trust_models)
267 AC_MSG_RESULT($use_tofu)
268 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
269     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
270 fi
271
272
273
274 #
275 # Options to disable algorithm
276 #
277
278 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
279 # Elgamal is a MUST algorithm
280 # DSA is a MUST algorithm
281 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
282 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
283 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
284
285 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
286 # 3DES is a MUST algorithm
287 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
288 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
289 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
290 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
291 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
292 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
293 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
294 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
295 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
296
297 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
298 # SHA1 is a MUST algorithm
299 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
300 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
301 # SHA256 is a MUST algorithm for GnuPG.
302 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
303 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
304
305
306 # Allow disabling of zip support.
307 # This is in general not a good idea because according to rfc4880 OpenPGP
308 # implementations SHOULD support ZLIB.
309 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
310 AC_ARG_ENABLE(zip,
311    AC_HELP_STRING([--disable-zip],
312                   [disable the ZIP and ZLIB compression algorithm]),
313    use_zip=$enableval)
314 AC_MSG_RESULT($use_zip)
315
316 # Allow disabling of bzib2 support.
317 # It is defined only after we confirm the library is available later
318 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
319 AC_ARG_ENABLE(bzip2,
320    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
321    use_bzip2=$enableval)
322 AC_MSG_RESULT($use_bzip2)
323
324 # Configure option to allow or disallow execution of external
325 # programs, like a photo viewer.
326 AC_MSG_CHECKING([whether to enable external program execution])
327 AC_ARG_ENABLE(exec,
328     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
329     use_exec=$enableval)
330 AC_MSG_RESULT($use_exec)
331 if test "$use_exec" = no ; then
332     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
333 fi
334
335 if test "$use_exec" = yes ; then
336   AC_MSG_CHECKING([whether to enable photo ID viewing])
337   AC_ARG_ENABLE(photo-viewers,
338       [  --disable-photo-viewers disable photo ID viewers],
339       [if test "$enableval" = no ; then
340          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
341       fi],enableval=yes)
342   gnupg_cv_enable_photo_viewers=$enableval
343   AC_MSG_RESULT($enableval)
344
345   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
346     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
347     AC_ARG_WITH(photo-viewer,
348         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
349         [if test "$withval" = yes ; then
350            withval=no
351         elif test "$withval" != no ; then
352            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
353                             [if set, restrict photo-viewer to this])
354         fi],withval=no)
355     AC_MSG_RESULT($withval)
356   fi
357 fi
358
359
360 #
361 # Check for the key/uid cache size.  This can't be zero, but can be
362 # pretty small on embedded systems.  This is used for the gpg part.
363 #
364 AC_MSG_CHECKING([for the size of the key and uid cache])
365 AC_ARG_ENABLE(key-cache,
366         AC_HELP_STRING([--enable-key-cache=SIZE],
367                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
368 if test "$enableval" = "no"; then
369    enableval=5
370 elif test "$enableval" = "yes" || test "$enableval" = ""; then
371    enableval=4096
372 fi
373 changequote(,)dnl
374 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
375 changequote([,])dnl
376 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
377    AC_MSG_ERROR([invalid key-cache size])
378 fi
379 AC_MSG_RESULT($key_cache_size)
380 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
381                   [Size of the key and UID caches])
382
383
384
385 #
386 # Check whether we want to use Linux capabilities
387 #
388 AC_MSG_CHECKING([whether use of capabilities is requested])
389 AC_ARG_WITH(capabilities,
390     [  --with-capabilities     use linux capabilities [default=no]],
391 [use_capabilities="$withval"],[use_capabilities=no])
392 AC_MSG_RESULT($use_capabilities)
393
394 #
395 # Check whether to disable the card support
396 AC_MSG_CHECKING([whether smartcard support is requested])
397 AC_ARG_ENABLE(card-support,
398               AC_HELP_STRING([--disable-card-support],
399                              [disable smartcard support]),
400               card_support=$enableval)
401 AC_MSG_RESULT($card_support)
402 if test "$card_support" = yes ; then
403   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
404 else
405   build_scdaemon=no
406 fi
407
408 #
409 # Allow disabling of internal CCID support.
410 # It is defined only after we confirm the library is available later
411 #
412 AC_MSG_CHECKING([whether to enable the internal CCID driver])
413 AC_ARG_ENABLE(ccid-driver,
414               AC_HELP_STRING([--disable-ccid-driver],
415                              [disable the internal CCID driver]),
416               use_ccid_driver=$enableval)
417 AC_MSG_RESULT($use_ccid_driver)
418
419 AC_MSG_CHECKING([whether to auto start dirmngr])
420 AC_ARG_ENABLE(dirmngr-auto-start,
421               AC_HELP_STRING([--disable-dirmngr-auto-start],
422                              [disable auto starting of the dirmngr]),
423               dirmngr_auto_start=$enableval)
424 AC_MSG_RESULT($dirmngr_auto_start)
425 if test "$dirmngr_auto_start" = yes ; then
426     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
427               [Define to enable auto starting of the dirmngr])
428 fi
429
430
431 #
432 # To avoid double inclusion of config.h which might happen at some
433 # places, we add the usual double inclusion protection at the top of
434 # config.h.
435 #
436 AH_TOP([
437 #ifndef GNUPG_CONFIG_H_INCLUDED
438 #define GNUPG_CONFIG_H_INCLUDED
439 ])
440
441 #
442 # Stuff which goes at the bottom of config.h.
443 #
444 AH_BOTTOM([
445 /* This is the major version number of GnuPG so that
446    source included files can test for this.  Note, that
447    we use 2 here even for GnuPG 1.9.x. */
448 #define GNUPG_MAJOR_VERSION 2
449
450 /* Now to separate file name parts.
451    Please note that the string version must not contain more
452    than one character because the code assumes strlen()==1 */
453 #ifdef HAVE_DOSISH_SYSTEM
454 #define DIRSEP_C '\\'
455 #define DIRSEP_S "\\"
456 #define EXTSEP_C '.'
457 #define EXTSEP_S "."
458 #define PATHSEP_C ';'
459 #define PATHSEP_S ";"
460 #define EXEEXT_S ".exe"
461 #else
462 #define DIRSEP_C '/'
463 #define DIRSEP_S "/"
464 #define EXTSEP_C '.'
465 #define EXTSEP_S "."
466 #define PATHSEP_C ':'
467 #define PATHSEP_S ":"
468 #define EXEEXT_S ""
469 #endif
470
471 /* This is the same as VERSION, but should be overridden if the
472    platform cannot handle things like dots '.' in filenames. Set
473    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
474    uses for dots and dashes. */
475 #define SAFE_VERSION VERSION
476 #define SAFE_VERSION_DOT  '.'
477 #define SAFE_VERSION_DASH '-'
478
479 /* Some global constants. */
480 #ifdef HAVE_DOSISH_SYSTEM
481 # ifdef HAVE_DRIVE_LETTERS
482 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
483 # else
484 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
485 # endif
486 #elif defined(__VMS)
487 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
488 #else
489 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
490 #endif
491 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
492 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
493
494 /* For some systems (DOS currently), we hardcode the path here.  For
495    POSIX systems the values are constructed by the Makefiles, so that
496    the values may be overridden by the make invocations; this is to
497    comply with the GNU coding standards.  Note that these values are
498    only defaults.  */
499 #ifdef HAVE_DOSISH_SYSTEM
500 # ifdef HAVE_DRIVE_LETTERS
501 #  define GNUPG_BINDIR      "c:\\gnupg"
502 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
503 #  define GNUPG_LIBDIR      "c:\\gnupg"
504 #  define GNUPG_DATADIR     "c:\\gnupg"
505 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
506 # else
507 #  define GNUPG_BINDIR      "\\gnupg"
508 #  define GNUPG_LIBEXECDIR  "\\gnupg"
509 #  define GNUPG_LIBDIR      "\\gnupg"
510 #  define GNUPG_DATADIR     "\\gnupg"
511 #  define GNUPG_SYSCONFDIR  "\\gnupg"
512 # endif
513 #endif
514
515 /* Derive some other constants. */
516 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
517 #define EXEC_TEMPFILE_ONLY
518 #endif
519
520
521 /* We didn't define endianness above, so get it from OS macros.  This
522    is intended for making fat binary builds on OS X. */
523 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
524 #if defined(__BIG_ENDIAN__)
525 #define BIG_ENDIAN_HOST 1
526 #elif defined(__LITTLE_ENDIAN__)
527 #define LITTLE_ENDIAN_HOST 1
528 #else
529 #error "No endianness found"
530 #endif
531 #endif
532
533
534 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
535    ldap_start_tls_s because that is the actual symbol used in the
536    library.  winldap.h redefines it to our commonly used value,
537    thus we define our usual macro here.  */
538 #ifdef HAVE_LDAP_START_TLS_SA
539 # ifndef HAVE_LDAP_START_TLS_S
540 #  define HAVE_LDAP_START_TLS_S 1
541 # endif
542 #endif
543
544 /* Provide the es_ macro for estream.  */
545 #define GPGRT_ENABLE_ES_MACROS 1
546
547 /* Tell libgcrypt not to use its own libgpg-error implementation. */
548 #define USE_LIBGPG_ERROR 1
549
550 /* Tell Libgcrypt not to include deprecated definitions.  */
551 #define GCRYPT_NO_DEPRECATED 1
552
553 /* Our HTTP code is used in estream mode.  */
554 #define HTTP_USE_ESTREAM 1
555
556 /* Under W32 we do an explicit socket initialization, thus we need to
557    avoid the on-demand initialization which would also install an atexit
558    handler.  */
559 #define HTTP_NO_WSASTARTUP
560
561 /* Under Windows we use the gettext code from libgpg-error.  */
562 #define GPG_ERR_ENABLE_GETTEXT_MACROS
563
564 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
565 #define GPG_ERR_ENABLE_ERRNO_MACROS
566
567 #endif /*GNUPG_CONFIG_H_INCLUDED*/
568 ])
569
570
571 AM_MAINTAINER_MODE
572 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
573
574 # Checks for programs.
575 AC_MSG_NOTICE([checking for programs])
576 AC_PROG_MAKE_SET
577 AM_SANITY_CHECK
578 missing_dir=`cd $ac_aux_dir && pwd`
579 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
580 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
581 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
582 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
583 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
584 AM_SILENT_RULES
585 AC_PROG_AWK
586 AC_PROG_CC
587 AC_PROG_CPP
588 AM_PROG_CC_C_O
589 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
590   AC_MSG_ERROR([[No C-89 compiler found]])
591 fi
592 AC_PROG_INSTALL
593 AC_PROG_LN_S
594 AC_PROG_RANLIB
595 AC_CHECK_TOOL(AR, ar, :)
596 AC_PATH_PROG(PERL,"perl")
597 AC_CHECK_TOOL(WINDRES, windres, :)
598 AC_ISC_POSIX
599 AC_SYS_LARGEFILE
600 GNUPG_CHECK_USTAR
601
602
603 # We need to compile and run a program on the build machine.  A
604 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
605 # the AC archive is broken for autoconf 2.57.  Given that there is no
606 # newer version of that macro, we assume that it is also broken for
607 # autoconf 2.61 and thus we use a simple but usually sufficient
608 # approach.
609 AC_MSG_CHECKING(for cc for build)
610 if test "$cross_compiling" = "yes"; then
611   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
612 else
613   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
614 fi
615 AC_MSG_RESULT($CC_FOR_BUILD)
616 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
617
618 # We need to call this macro because other pkg-config macros are
619 # not always used.
620 PKG_PROG_PKG_CONFIG
621
622
623 try_gettext=yes
624 require_iconv=yes
625 have_dosish_system=no
626 have_w32_system=no
627 have_w32ce_system=no
628 have_android_system=no
629 run_tests=yes
630 use_simple_gettext=no
631 use_ldapwrapper=yes
632 mmap_needed=yes
633 case "${host}" in
634     *-mingw32*)
635         # special stuff for Windoze NT
636         ac_cv_have_dev_random=no
637         AC_DEFINE(USE_ONLY_8DOT3,1,
638                   [Set this to limit filenames to the 8.3 format])
639         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
640                   [Because the Unix gettext has too much overhead on
641                    MingW32 systems and these systems lack Posix functions,
642                    we use a simplified version of gettext])
643         have_dosish_system=yes
644         have_w32_system=yes
645         require_iconv=no
646         run_tests=no
647         use_ldapwrapper=no  # Fixme: Do this only for CE.
648         case "${host}" in
649           *-mingw32ce*)
650             have_w32ce_system=yes
651             ;;
652           *)
653             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
654                       [Defined if the OS supports drive letters.])
655             ;;
656         esac
657         try_gettext="no"
658         use_simple_gettext=yes
659         mmap_needed=no
660         ;;
661     i?86-emx-os2 | i?86-*-os2*emx )
662         # OS/2 with the EMX environment
663         ac_cv_have_dev_random=no
664         AC_DEFINE(HAVE_DRIVE_LETTERS)
665         have_dosish_system=yes
666         try_gettext="no"
667         ;;
668
669     i?86-*-msdosdjgpp*)
670         # DOS with the DJGPP environment
671         ac_cv_have_dev_random=no
672         AC_DEFINE(HAVE_DRIVE_LETTERS)
673         have_dosish_system=yes
674         try_gettext="no"
675         ;;
676
677     *-*-hpux*)
678         if test -z "$GCC" ; then
679             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
680         fi
681         ;;
682     *-dec-osf4*)
683         if test -z "$GCC" ; then
684             # Suppress all warnings
685             # to get rid of the unsigned/signed char mismatch warnings.
686             CFLAGS="-w $CFLAGS"
687         fi
688         ;;
689     *-dec-osf5*)
690         if test -z "$GCC" ; then
691             # Use the newer compiler `-msg_disable ptrmismatch1' to
692             # get rid of the unsigned/signed char mismatch warnings.
693             # Using this may hide other pointer mismatch warnings, but
694             # it at least lets other warning classes through
695             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
696         fi
697         ;;
698     m68k-atari-mint)
699         ;;
700     *-linux-android*)
701         have_android_system=yes
702         # Android is fully utf-8 and we do not want to use iconv to
703         # keeps things simple
704         require_iconv=no
705         run_tests=no
706         ;;
707     *)
708        ;;
709 esac
710
711 if test "$have_dosish_system" = yes; then
712    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
713              [Defined if we run on some of the PCDOS like systems
714               (DOS, Windoze. OS/2) with special properties like
715               no file modes, case insensitive file names and preferred
716               use of backslashes as directory name separators.])
717 fi
718 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
719
720 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
721
722 if test "$have_w32_system" = yes; then
723    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
724    if test "$have_w32ce_system" = yes; then
725       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
726    fi
727 fi
728 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
729 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
730
731 if test "$have_android_system" = yes; then
732    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
733 fi
734 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
735
736 if test "$run_tests" = yes; then
737    AC_DEFINE(RUN_TESTS,1, [Defined if we should run the tests])
738 fi
739 AM_CONDITIONAL(RUN_TESTS, test "$run_tests" = yes)
740
741
742 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
743 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
744
745
746 #
747 # Checks for libraries.
748 #
749 AC_MSG_NOTICE([checking for libraries])
750
751
752 #
753 # libgpg-error is a library with error codes shared between GnuPG
754 # related projects.
755 #
756 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
757                   have_gpg_error=yes,have_gpg_error=no)
758
759
760 #
761 # Libgcrypt is our generic crypto library
762 #
763 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
764         have_libgcrypt=yes,have_libgcrypt=no)
765
766
767 #
768 # libassuan is used for IPC
769 #
770 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
771                   have_libassuan=yes,have_libassuan=no)
772 if test "$have_libassuan" = "yes"; then
773   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
774                      [version of the libassuan library])
775   show_tor_support="only .onion"
776 fi
777
778
779 #
780 # libksba is our X.509 support library
781 #
782 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
783
784
785 #
786 # libusb allows us to use the integrated CCID smartcard reader driver.
787 #
788 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
789 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
790    case "${host}" in
791      *-mingw32*)
792        LIBUSB_NAME=
793        LIBUSB_LIBS=
794        LIBUSB_CPPFLAGS=
795        ;;
796      *-*-darwin*)
797        LIBUSB_NAME=usb-1.0
798        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
799        ;;
800      *-*-freebsd*)
801        # FreeBSD has a native 1.0 compatible library by -lusb.
802        LIBUSB_NAME=usb
803        LIBUSB_LIBS=
804        ;;
805      *)
806        LIBUSB_NAME=usb-1.0
807        LIBUSB_LIBS=
808        ;;
809    esac
810 fi
811 if test x"$LIBUSB_NAME" != x ; then
812    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
813                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
814                   have_libusb=yes ])
815    AC_MSG_CHECKING([libusb include dir])
816    usb_incdir_found="no"
817    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
818      _libusb_save_cppflags=$CPPFLAGS
819      if test -n "${_incdir}"; then
820        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
821      fi
822      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
823      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
824      CPPFLAGS=${_libusb_save_cppflags}
825      if test "$usb_incdir_found" = "yes"; then
826        break
827      fi
828    done
829    if test "$usb_incdir_found" = "yes"; then
830      AC_MSG_RESULT([${usb_incdir}])
831    else
832      AC_MSG_RESULT([not found])
833      usb_incdir=""
834      have_libusb=no
835      if test "$use_ccid_driver" != yes; then
836        use_ccid_driver=no
837      fi
838      LIBUSB_LIBS=""
839    fi
840
841    if test "$have_libusb" = yes; then
842      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
843    fi
844    if test x"$usb_incdir" = x; then
845      LIBUSB_CPPFLAGS=""
846    else
847      LIBUSB_CPPFLAGS="-I${usb_incdir}"
848    fi
849 fi
850 AC_SUBST(LIBUSB_LIBS)
851 AC_SUBST(LIBUSB_CPPFLAGS)
852
853 #
854 # Check wether it is necessary to link against libdl.
855 # (For example to load libpcsclite)
856 #
857 gnupg_dlopen_save_libs="$LIBS"
858 LIBS=""
859 AC_SEARCH_LIBS(dlopen, c dl,,,)
860 DL_LIBS=$LIBS
861 AC_SUBST(DL_LIBS)
862 LIBS="$gnupg_dlopen_save_libs"
863
864
865 # Checks for g10
866
867 AC_ARG_ENABLE(sqlite,
868                 AC_HELP_STRING([--disable-sqlite],
869                                [disable the use of SQLITE]),
870               try_sqlite=$enableval, try_sqlite=yes)
871
872 if test x"$use_tofu" = xyes ; then
873   if test x"$try_sqlite" = xyes ; then
874     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
875                                  [have_sqlite=yes],
876                                  [have_sqlite=no])
877   fi
878   if test "$have_sqlite" = "yes"; then
879     :
880     AC_SUBST([SQLITE3_CFLAGS])
881     AC_SUBST([SQLITE3_LIBS])
882   else
883     use_tofu=no
884     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
885     AC_MSG_WARN([[
886 ***
887 *** Building without SQLite support - TOFU disabled
888 ***
889 *** $tmp]])
890   fi
891 fi
892
893 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
894
895 if test x"$use_tofu" = xyes ; then
896     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
897 fi
898
899
900 # Checks for g13
901
902 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
903 AC_DEFINE_UNQUOTED(ENCFS,
904         "${ENCFS}", [defines the filename of the encfs program])
905
906 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
907 AC_DEFINE_UNQUOTED(FUSERMOUNT,
908         "${FUSERMOUNT}", [defines the filename of the fusermount program])
909
910
911 # Checks for dirmngr
912
913
914 #
915 # Checks for symcryptrun:
916 #
917
918 # libutil has openpty() and login_tty().
919 AC_CHECK_LIB(util, openpty,
920               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
921                 AC_DEFINE(HAVE_LIBUTIL,1,
922                          [defined if libutil is available])
923              ])
924 AC_SUBST(LIBUTIL_LIBS)
925
926 # shred is used to clean temporary plain text files.
927 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
928 AC_DEFINE_UNQUOTED(SHRED,
929         "${SHRED}", [defines the filename of the shred program])
930
931
932 #
933 # Check whether the nPth library is available
934 #
935 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
936 if test "$have_npth" = "yes"; then
937   AC_DEFINE(HAVE_NPTH, 1,
938               [Defined if the New Portable Thread Library is available])
939   AC_DEFINE(USE_NPTH, 1,
940               [Defined if support for nPth is requested and nPth is available])
941 else
942   AC_MSG_WARN([[
943 ***
944 *** To support concurrent access for example in gpg-agent and the SCdaemon
945 *** we need the support of the New Portable Threads Library.
946 ***]])
947 fi
948
949
950 #
951 # NTBTLS is our TLS library.  If it is not available fallback to
952 # GNUTLS.
953 #
954 AC_ARG_ENABLE(ntbtls,
955               AC_HELP_STRING([--disable-ntbtls],
956                              [disable the use of NTBTLS as TLS library]),
957               try_ntbtls=$enableval, try_ntbtls=yes)
958 if test x"$try_ntbtls" = xyes ; then
959   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
960                  [have_ntbtls=yes],[have_ntbtls=no])
961 fi
962 if test "$have_ntbtls" = yes ; then
963    use_tls_library=ntbtls
964    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
965 else
966   AC_ARG_ENABLE(gnutls,
967                 AC_HELP_STRING([--disable-gnutls],
968                                [disable GNUTLS as fallback TLS library]),
969                 try_gnutls=$enableval, try_gnutls=yes)
970   if test x"$try_gnutls" = xyes ; then
971     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
972                                    [have_gnutls=yes],
973                                    [have_gnutls=no])
974   fi
975   if test "$have_gnutls" = "yes"; then
976     AC_SUBST([LIBGNUTLS_CFLAGS])
977     AC_SUBST([LIBGNUTLS_LIBS])
978     use_tls_library=gnutls
979     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
980   else
981     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
982     AC_MSG_WARN([[
983 ***
984 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
985 ***
986 *** $tmp]])
987   fi
988 fi
989
990
991 AC_MSG_NOTICE([checking for networking options])
992
993 #
994 # Must check for network library requirements before doing link tests
995 # for ldap, for example. If ldap libs are static (or dynamic and without
996 # ELF runtime link paths), then link will fail and LDAP support won't
997 # be detected.
998 #
999 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1000         [NETLIBS="-lnsl $NETLIBS"]))
1001 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1002         [NETLIBS="-lsocket $NETLIBS"]))
1003
1004
1005 #
1006 # Check for ADNS.
1007 #
1008 _cppflags="${CPPFLAGS}"
1009 _ldflags="${LDFLAGS}"
1010 AC_ARG_WITH(adns,
1011             AC_HELP_STRING([--with-adns=DIR],
1012                            [look for the adns library in DIR]),
1013             [if test -d "$withval"; then
1014                CPPFLAGS="${CPPFLAGS} -I$withval/include"
1015                LDFLAGS="${LDFLAGS} -L$withval/lib"
1016              fi])
1017 if test "$with_adns" != "no"; then
1018   AC_CHECK_HEADERS(adns.h,AC_CHECK_LIB(adns, adns_init_strcfg,[have_adns=yes]))
1019   AC_CHECK_FUNCS(adns_free)
1020   AC_MSG_CHECKING([if adns supports adns_if_tormode])
1021   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1022     #include <adns.h>
1023     adns_initflags flags = adns_if_tormode;
1024   ]],[])],[adns_if_tormode=yes],[adns_if_tormode=no])
1025   AC_MSG_RESULT($adns_if_tormode)
1026   if test x"$adns_if_tormode" = xyes; then
1027     AC_DEFINE(HAVE_ADNS_IF_TORMODE,1,[define if adns_if_tormode is available])
1028     if test "$show_tor_support" != "no"; then
1029       show_tor_support=yes
1030     fi
1031   fi
1032 fi
1033 CPPFLAGS=${_cppflags}
1034 LDFLAGS=${_ldflags}
1035 if test "$have_adns" = "yes"; then
1036   ADNSLIBS="-ladns"
1037 fi
1038
1039
1040 #
1041 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
1042 #
1043 AC_ARG_ENABLE(dns-srv,
1044               AC_HELP_STRING([--disable-dns-srv],
1045                              [disable the use of DNS SRV in HKP and HTTP]),
1046               use_dns_srv=$enableval,use_dns_srv=yes)
1047
1048 AC_ARG_ENABLE(dns-cert,
1049    AC_HELP_STRING([--disable-dns-cert],
1050         [disable the use of CERT records in DNS]),
1051    use_dns_cert=$enableval,use_dns_cert=yes)
1052
1053 if test x"$use_dns_srv" = xyes || test x"$use_dns_cert" = xyes; then
1054   _dns_save_libs=$LIBS
1055   LIBS=""
1056
1057   if test x"$have_adns" = xyes ; then
1058     # We prefer ADNS.
1059     DNSLIBS="$ADNSLIBS"
1060     AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
1061
1062     if test x"$use_dns_srv" = xyes ; then
1063         AC_DEFINE(USE_DNS_SRV,1)
1064     fi
1065
1066     if test x"$use_dns_cert" = xyes ; then
1067         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1068     fi
1069   else
1070     # With no ADNS find the system resolver.
1071
1072     # the double underscore thing is a glibc-ism?
1073     AC_SEARCH_LIBS(res_query,resolv bind,,
1074                    AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1075     AC_SEARCH_LIBS(dn_expand,resolv bind,,
1076                    AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1077
1078     # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1079     # and for some reason fools us into believing we don't need
1080     # -lresolv even if we do.  Since the test program checking for the
1081     # symbol does not include <resolv.h>, we need to check for the
1082     # renamed symbol explicitly.
1083     AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1084         AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1085             AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1086
1087     if test x"$have_resolver" != xno ; then
1088
1089       # Make sure that the BIND 4 resolver interface is workable before
1090       # enabling any code that calls it.  At some point I'll rewrite the
1091       # code to use the BIND 8 resolver API.
1092       # We might also want to use adns instead.  Problem with ADNS is that
1093       # it does not support v6.
1094
1095       AC_MSG_CHECKING([whether the resolver is usable])
1096       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1097 #include <netinet/in.h>
1098 #include <arpa/nameser.h>
1099 #include <resolv.h>]],
1100 [[unsigned char answer[PACKETSZ];
1101   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1102   dn_skipname(0,0);
1103   dn_expand(0,0,0,0,0);
1104 ]])],have_resolver=yes,have_resolver=no)
1105       AC_MSG_RESULT($have_resolver)
1106
1107       # This is Apple-specific and somewhat bizarre as they changed the
1108       # define in bind 8 for some reason.
1109
1110       if test x"$have_resolver" != xyes ; then
1111          AC_MSG_CHECKING(
1112              [whether I can make the resolver usable with BIND_8_COMPAT])
1113         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1114 #include <sys/types.h>
1115 #include <netinet/in.h>
1116 #include <arpa/nameser.h>
1117 #include <resolv.h>]],
1118 [[unsigned char answer[PACKETSZ];
1119   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1120   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1121 ]])],[have_resolver=yes ; need_compat=yes])
1122          AC_MSG_RESULT($have_resolver)
1123       fi
1124     fi
1125
1126     if test x"$have_resolver" = xyes ; then
1127       DNSLIBS=$LIBS
1128
1129       if test x"$use_dns_srv" = xyes ; then
1130          AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
1131       fi
1132
1133       if test x"$use_dns_cert" = xyes ; then
1134         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
1135       fi
1136
1137       if test x"$need_compat" = xyes ; then
1138         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1139       fi
1140     else
1141       use_dns_srv=no
1142       use_dns_cert=no
1143     fi
1144   fi
1145
1146   LIBS=$_dns_save_libs
1147 fi
1148
1149 AC_SUBST(DNSLIBS)
1150
1151 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1152
1153
1154 #
1155 # Check for LDAP
1156 #
1157 # Note that running the check changes the variable
1158 # gnupg_have_ldap from "n/a" to "no" or "yes".
1159
1160 AC_ARG_ENABLE(ldap,
1161     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1162     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1163
1164 if test "$gnupg_have_ldap" != "no" ; then
1165   if test "$build_dirmngr" = "yes" ; then
1166      GNUPG_CHECK_LDAP($NETLIBS)
1167      AC_CHECK_LIB(lber, ber_free,
1168                   [ LBER_LIBS="$LBER_LIBS -llber"
1169                     AC_DEFINE(HAVE_LBER,1,
1170                              [defined if liblber is available])
1171                     have_lber=yes
1172                  ])
1173   fi
1174 fi
1175 AC_SUBST(LBER_LIBS)
1176 if test "$gnupg_have_ldap" = "no"; then
1177     AC_MSG_WARN([[
1178 ***
1179 *** Building without LDAP support.
1180 *** No CRL access or X.509 certificate search available.
1181 ***]])
1182 fi
1183
1184 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1185 if test "$gnupg_have_ldap" = yes ; then
1186   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1187 else
1188  use_ldapwrapper=no
1189 fi
1190
1191 if test "$use_ldapwrapper" = yes; then
1192    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1193 fi
1194 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1195
1196
1197
1198
1199 #
1200 # Check for sendmail
1201 #
1202 # This isn't necessarily sendmail itself, but anything that gives a
1203 # sendmail-ish interface to the outside world.  That includes Exim,
1204 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1205 AC_ARG_WITH(mailprog,
1206       AC_HELP_STRING([--with-mailprog=NAME],
1207                      [use "NAME -t" for mail transport]),
1208              ,with_mailprog=yes)
1209 if test x"$with_mailprog" = xyes ; then
1210     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1211 elif test x"$with_mailprog" != xno ; then
1212     AC_MSG_CHECKING([for a mail transport program])
1213     AC_SUBST(SENDMAIL,$with_mailprog)
1214     AC_MSG_RESULT($with_mailprog)
1215 fi
1216
1217
1218 #
1219 # Construct a printable name of the OS
1220 #
1221 case "${host}" in
1222     *-mingw32ce*)
1223         PRINTABLE_OS_NAME="W32CE"
1224         ;;
1225     *-mingw32*)
1226         PRINTABLE_OS_NAME="MingW32"
1227         ;;
1228     *-*-cygwin*)
1229         PRINTABLE_OS_NAME="Cygwin"
1230         ;;
1231     i?86-emx-os2 | i?86-*-os2*emx )
1232         PRINTABLE_OS_NAME="OS/2"
1233         ;;
1234     i?86-*-msdosdjgpp*)
1235         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1236         try_dynload=no
1237         ;;
1238     *-linux*)
1239         PRINTABLE_OS_NAME="GNU/Linux"
1240         ;;
1241     *)
1242         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1243         ;;
1244 esac
1245 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1246                    [A human readable text with the name of the OS])
1247
1248
1249 #
1250 # Checking for iconv
1251 #
1252 if test "$require_iconv" = yes; then
1253   AM_ICONV
1254 else
1255   LIBICONV=
1256   LTLIBICONV=
1257   AC_SUBST(LIBICONV)
1258   AC_SUBST(LTLIBICONV)
1259 fi
1260
1261
1262 #
1263 # Check for gettext
1264 #
1265 # This is "GNU gnupg" - The project-id script from gettext
1266 #                       needs this string
1267 #
1268 AC_MSG_NOTICE([checking for gettext])
1269 AM_PO_SUBDIRS
1270 AM_GNU_GETTEXT_VERSION([0.17])
1271 if test "$try_gettext" = yes; then
1272   AM_GNU_GETTEXT([external],[need-ngettext])
1273
1274   # gettext requires some extra checks.  These really should be part of
1275   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1276   # function checks to here.
1277
1278   AC_CHECK_FUNCS(strchr)
1279 else
1280   USE_NLS=no
1281   USE_INCLUDED_LIBINTL=no
1282   BUILD_INCLUDED_LIBINTL=no
1283   POSUB=po
1284   AC_SUBST(USE_NLS)
1285   AC_SUBST(USE_INCLUDED_LIBINTL)
1286   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1287   AC_SUBST(POSUB)
1288 fi
1289
1290 # We use HAVE_LANGINFO_CODESET in a couple of places.
1291 AM_LANGINFO_CODESET
1292
1293 # Checks required for our use of locales
1294 gt_LC_MESSAGES
1295
1296
1297 #
1298 # SELinux support
1299 #
1300 if test "$selinux_support" = yes ; then
1301   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1302 fi
1303
1304
1305 #
1306 # Checks for header files.
1307 #
1308 AC_MSG_NOTICE([checking for header files])
1309 AC_HEADER_STDC
1310 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1311                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1312                   signal.h])
1313 AC_HEADER_TIME
1314
1315
1316 #
1317 # Checks for typedefs, structures, and compiler characteristics.
1318 #
1319 AC_MSG_NOTICE([checking for system characteristics])
1320 AC_C_CONST
1321 AC_C_INLINE
1322 AC_C_VOLATILE
1323 AC_TYPE_SIZE_T
1324 AC_TYPE_MODE_T
1325 AC_TYPE_SIGNAL
1326 AC_DECL_SYS_SIGLIST
1327
1328 gl_HEADER_SYS_SOCKET
1329 gl_TYPE_SOCKLEN_T
1330
1331 AC_SEARCH_LIBS([inet_addr], [nsl])
1332
1333 AC_ARG_ENABLE(endian-check,
1334               AC_HELP_STRING([--disable-endian-check],
1335               [disable the endian check and trust the OS provided macros]),
1336               endiancheck=$enableval,endiancheck=yes)
1337
1338 if test x"$endiancheck" = xyes ; then
1339   GNUPG_CHECK_ENDIAN
1340 fi
1341
1342 # fixme: we should get rid of the byte type
1343 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1344 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1345 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1346 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1347 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1348
1349 AC_CHECK_SIZEOF(unsigned short)
1350 AC_CHECK_SIZEOF(unsigned int)
1351 AC_CHECK_SIZEOF(unsigned long)
1352 AC_CHECK_SIZEOF(unsigned long long)
1353 AC_HEADER_TIME
1354 AC_CHECK_SIZEOF(time_t,,[[
1355 #include <stdio.h>
1356 #if TIME_WITH_SYS_TIME
1357 # include <sys/time.h>
1358 # include <time.h>
1359 #else
1360 # if HAVE_SYS_TIME_H
1361 #  include <sys/time.h>
1362 # else
1363 #  include <time.h>
1364 # endif
1365 #endif
1366 ]])
1367 GNUPG_TIME_T_UNSIGNED
1368
1369
1370 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1371    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1372    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1373     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1374 fi
1375
1376
1377 #
1378 # Checks for library functions.
1379 #
1380 AC_MSG_NOTICE([checking for library functions])
1381 AC_CHECK_DECLS(getpagesize)
1382 AC_FUNC_FSEEKO
1383 AC_FUNC_VPRINTF
1384 AC_FUNC_FORK
1385 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1386 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1387 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1388 AC_CHECK_FUNCS([canonicalize_file_name])
1389 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1390 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1391 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1392 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1393 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1394                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1395                 flockfile funlockfile getpwnam getpwuid \
1396                 getenv inet_pton strpbrk])
1397
1398 # See whether libc supports the Linux inotify interface
1399 case "${host}" in
1400     *-*-linux*)
1401         AC_CHECK_FUNCS([inotify_init])
1402         ;;
1403 esac
1404
1405
1406 if test "$have_android_system" = yes; then
1407    # On Android ttyname is a stub but prints an error message.
1408    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1409              [Defined if ttyname does not work properly])
1410 fi
1411
1412 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1413
1414 # Dirmngr requires mmap on Unix systems.
1415 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1416   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1417 fi
1418
1419 #
1420 # W32 specific test
1421 #
1422 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1423
1424 #
1425 # Sanity check regex.  Tests adapted from mutt.
1426 #
1427 AC_MSG_CHECKING([whether regular expression support is requested])
1428 AC_ARG_ENABLE(regex,
1429   AC_HELP_STRING([--disable-regex],
1430     [do not handle regular expressions in trust signatures]),
1431   use_regex=$enableval, use_regex=yes)
1432 AC_MSG_RESULT($use_regex)
1433
1434 if test "$use_regex" = yes ; then
1435   _cppflags="${CPPFLAGS}"
1436   _ldflags="${LDFLAGS}"
1437   AC_ARG_WITH(regex,
1438      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1439       [
1440       if test -d "$withval" ; then
1441         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1442         LDFLAGS="${LDFLAGS} -L$withval/lib"
1443       fi
1444       ],withval="")
1445
1446   # Does the system have regex functions at all?
1447   AC_SEARCH_LIBS([regcomp], [regex])
1448   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1449
1450   if test $gnupg_cv_have_regex = no; then
1451     use_regex=no
1452   else
1453     if test x"$cross_compiling" = xyes; then
1454       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1455     else
1456       AC_CACHE_CHECK([whether your system's regexp library is broken],
1457        [gnupg_cv_regex_broken],
1458        AC_TRY_RUN([
1459 #include <unistd.h>
1460 #include <regex.h>
1461 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1462        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1463
1464       if test $gnupg_cv_regex_broken = yes; then
1465         AC_MSG_WARN([your regex is broken - disabling regex use])
1466         use_regex=no
1467       fi
1468     fi
1469   fi
1470   CPPFLAGS="${_cppflags}"
1471   LDFLAGS="${_ldflags}"
1472 fi
1473
1474 if test "$use_regex" != yes ; then
1475   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1476 fi
1477 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1478
1479
1480
1481 #
1482 # Do we have zlib? Must do it here because Solaris failed
1483 # when compiling a conftest (due to the "-lz" from LIBS).
1484 # Note that we combine zlib and bzlib2 in ZLIBS.
1485 #
1486 if test "$use_zip" = yes ; then
1487   _cppflags="${CPPFLAGS}"
1488   _ldflags="${LDFLAGS}"
1489   AC_ARG_WITH(zlib,
1490     [  --with-zlib=DIR         use libz in DIR],[
1491       if test -d "$withval"; then
1492         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1493         LDFLAGS="${LDFLAGS} -L$withval/lib"
1494       fi
1495     ])
1496
1497   AC_CHECK_HEADER(zlib.h,
1498      AC_CHECK_LIB(z, deflateInit2_,
1499        [
1500        ZLIBS="-lz"
1501        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1502        ],
1503        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1504        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1505 fi
1506
1507
1508 #
1509 # Check whether we can support bzip2
1510 #
1511 if test "$use_bzip2" = yes ; then
1512   _cppflags="${CPPFLAGS}"
1513   _ldflags="${LDFLAGS}"
1514   AC_ARG_WITH(bzip2,
1515      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1516       [
1517       if test -d "$withval" ; then
1518         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1519         LDFLAGS="${LDFLAGS} -L$withval/lib"
1520       fi
1521       ],withval="")
1522
1523   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1524   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1525   # woefully out of date.
1526   if test "$withval" != no ; then
1527      AC_CHECK_HEADER(bzlib.h,
1528         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1529           [
1530           have_bz2=yes
1531           ZLIBS="$ZLIBS -lbz2"
1532           AC_DEFINE(HAVE_BZIP2,1,
1533                   [Defined if the bz2 compression library is available])
1534           ],
1535           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1536           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1537   fi
1538 fi
1539 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1540 AC_SUBST(ZLIBS)
1541
1542
1543 # Check for readline support
1544 GNUPG_CHECK_READLINE
1545
1546
1547 if test "$development_version" = yes; then
1548     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1549             [Defined if this is not a regular release])
1550 fi
1551
1552 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1553
1554 GNUPG_CHECK_GNUMAKE
1555
1556 # Add some extra libs here so that previous tests don't fail for
1557 # mysterious reasons - the final link step should bail out.
1558 # W32SOCKLIBS is also defined so that if can be used for tools not
1559 # requiring any network stuff but linking to code in libcommon which
1560 # tracks in winsock stuff (e.g. init_common_subsystems).
1561 if test "$have_w32_system" = yes; then
1562    if test "$have_w32ce_system" = yes; then
1563      W32SOCKLIBS="-lws2"
1564    else
1565      W32SOCKLIBS="-lws2_32"
1566    fi
1567    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1568 fi
1569
1570 AC_SUBST(NETLIBS)
1571 AC_SUBST(W32SOCKLIBS)
1572
1573 #
1574 # Setup gcc specific options
1575 #
1576 AC_MSG_NOTICE([checking for cc features])
1577 if test "$GCC" = yes; then
1578     mycflags=
1579     mycflags_save=$CFLAGS
1580
1581     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1582     # options.  This is the case for gcc >= 4.6
1583     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1584     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1585 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1586 #kickerror
1587 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1588     AC_MSG_RESULT($_gcc_silent_wno)
1589
1590     # Note that it is okay to use CFLAGS here because these are just
1591     # warning options and the user should have a chance of overriding
1592     # them.
1593     if test "$USE_MAINTAINER_MODE" = "yes"; then
1594         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1595         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1596         if test x"$_gcc_silent_wno" = xyes ; then
1597           _gcc_wopt=yes
1598         else
1599           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1600           CFLAGS="-Wno-missing-field-initializers"
1601           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1602                             [_gcc_wopt=yes],[_gcc_wopt=no])
1603           AC_MSG_RESULT($_gcc_wopt)
1604         fi
1605         if test x"$_gcc_wopt" = xyes ; then
1606           mycflags="$mycflags -W -Wno-sign-compare"
1607           mycflags="$mycflags -Wno-missing-field-initializers"
1608         fi
1609
1610         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1611         CFLAGS="-Wdeclaration-after-statement"
1612         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1613         AC_MSG_RESULT($_gcc_wopt)
1614         if test x"$_gcc_wopt" = xyes ; then
1615           mycflags="$mycflags -Wdeclaration-after-statement"
1616         fi
1617     else
1618         mycflags="$mycflags -Wall"
1619     fi
1620
1621     if test x"$_gcc_silent_wno" = xyes ; then
1622       _gcc_psign=yes
1623     else
1624       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1625       CFLAGS="-Wno-pointer-sign"
1626       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1627                         [_gcc_psign=yes],[_gcc_psign=no])
1628       AC_MSG_RESULT($_gcc_psign)
1629     fi
1630     if test x"$_gcc_psign" = xyes ; then
1631        mycflags="$mycflags -Wno-pointer-sign"
1632     fi
1633
1634     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1635     CFLAGS="-Wpointer-arith"
1636     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1637     AC_MSG_RESULT($_gcc_psign)
1638     if test x"$_gcc_psign" = xyes ; then
1639        mycflags="$mycflags -Wpointer-arith"
1640     fi
1641
1642     CFLAGS="$mycflags $mycflags_save"
1643 fi
1644
1645
1646 #
1647 # This is handy for debugging so the compiler doesn't rearrange
1648 # things and eliminate variables.
1649 #
1650 AC_ARG_ENABLE(optimization,
1651    AC_HELP_STRING([--disable-optimization],
1652                   [disable compiler optimization]),
1653                   [if test $enableval = no ; then
1654                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1655                    fi])
1656
1657 #
1658 # Add user CFLAGS.
1659 #
1660 CFLAGS="$CFLAGS $CFLAGS_orig"
1661
1662 #
1663 # Decide what to build
1664 #
1665
1666 build_scdaemon_extra=""
1667 if test "$build_scdaemon" = "yes"; then
1668   if test $have_libusb = no; then
1669      build_scdaemon_extra="without internal CCID driver"
1670   fi
1671   if test -n "$build_scdaemon_extra"; then
1672      build_scdaemon_extra="(${build_scdaemon_extra})"
1673   fi
1674 fi
1675
1676
1677 #
1678 # Set variables for use by automake makefiles.
1679 #
1680 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1681 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1682 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1683 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1684 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1685 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1686 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1687 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1688 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1689 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1690 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1691
1692 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1693 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1694 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1695
1696 AM_CONDITIONAL(RUN_GPG_TESTS,
1697                test x$cross_compiling = xno -a "$build_gpg" = yes )
1698
1699 #
1700 # Set some defines for use gpgconf.
1701 #
1702 if test "$build_gpg" = yes ; then
1703     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1704 fi
1705 if test "$build_gpgsm" = yes ; then
1706     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1707 fi
1708 if test "$build_agent" = yes ; then
1709     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1710 fi
1711 if test "$build_scdaemon" = yes ; then
1712     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1713 fi
1714 if test "$build_dirmngr" = yes ; then
1715     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1716 fi
1717 if test "$build_g13" = yes ; then
1718     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1719 fi
1720
1721
1722 #
1723 # Define Name strings
1724 #
1725 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1726
1727 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1728 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1729
1730 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1731 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1732
1733 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1734 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1735                                         [The displayed name of gpg-agent])
1736
1737 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1738 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1739                                        [The displayed name of scdaemon])
1740
1741 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1742 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1743                                       [The displayed name of dirmngr])
1744
1745 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1746 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1747
1748 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1749 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1750                                       [The displayed name of gpgconf])
1751
1752 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1753
1754 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1755                    [The name of the agent socket])
1756 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1757                    [The name of the agent socket for ssh])
1758 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1759                    [The name of the dirmngr info envvar])
1760 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1761                    [The name of the SCdaemon socket])
1762 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1763                    [The name of the dirmngr socket])
1764
1765 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1766
1767 if test "$have_w32_system" = yes; then
1768   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1769                      [The directory part of the W32 registry keys])
1770 fi
1771
1772
1773 #
1774 # Provide information about the build.
1775 #
1776 BUILD_REVISION="mym4_revision"
1777 AC_SUBST(BUILD_REVISION)
1778 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1779                    [GIT commit id revision used to build this package])
1780
1781 changequote(,)dnl
1782 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1783 changequote([,])dnl
1784 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1785 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1786 AC_SUBST(BUILD_VERSION)
1787 AC_SUBST(BUILD_FILEVERSION)
1788
1789 AC_ARG_ENABLE([build-timestamp],
1790   AC_HELP_STRING([--enable-build-timestamp],
1791                  [set an explicit build timestamp for reproducibility.
1792                   (default is the current time in ISO-8601 format)]),
1793      [if test "$enableval" = "yes"; then
1794         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1795       else
1796         BUILD_TIMESTAMP="$enableval"
1797       fi
1798       BUILD_HOSTNAME="$ac_hostname"],
1799      [BUILD_TIMESTAMP="<none>"
1800       BUILD_HOSTNAME="<anon>"])
1801 AC_SUBST(BUILD_TIMESTAMP)
1802 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1803                    [The time this package was configured for a build])
1804 AC_SUBST(BUILD_HOSTNAME)
1805
1806
1807 #
1808 # Print errors here so that they are visible all
1809 # together and the user can acquire them all together.
1810 #
1811 die=no
1812 if test "$have_gpg_error" = "no"; then
1813    die=yes
1814    AC_MSG_NOTICE([[
1815 ***
1816 *** You need libgpg-error to build this program.
1817 **  This library is for example available at
1818 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1819 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1820 ***]])
1821 fi
1822 if test "$have_libgcrypt" = "no"; then
1823    die=yes
1824    AC_MSG_NOTICE([[
1825 ***
1826 *** You need libgcrypt to build this program.
1827 **  This library is for example available at
1828 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1829 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1830 ***]])
1831 fi
1832 if test "$have_libassuan" = "no"; then
1833    die=yes
1834    AC_MSG_NOTICE([[
1835 ***
1836 *** You need libassuan to build this program.
1837 *** This library is for example available at
1838 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1839 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1840 ***]])
1841 fi
1842 if test "$have_ksba" = "no"; then
1843     die=yes
1844     AC_MSG_NOTICE([[
1845 ***
1846 *** You need libksba to build this program.
1847 *** This library is for example available at
1848 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1849 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1850 ***]])
1851 fi
1852 if test "$gnupg_have_ldap" = yes; then
1853   if test "$have_w32ce_system" = yes; then
1854     AC_MSG_NOTICE([[
1855 *** Note that CeGCC might be broken, a package fixing this is:
1856 ***    http://files.kolab.org/local/windows-ce/
1857 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1858 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1859 ***]])
1860    fi
1861 fi
1862 if test "$have_npth" = "no"; then
1863     die=yes
1864     AC_MSG_NOTICE([[
1865 ***
1866 *** It is now required to build with support for the
1867 *** New Portable Threads Library (nPth). Please install this
1868 *** library first.  The library is for example available at
1869 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1870 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1871 ***]])
1872 fi
1873
1874 if test "$require_iconv" = yes; then
1875   if test "$am_func_iconv" != yes; then
1876     die=yes
1877     AC_MSG_NOTICE([[
1878 ***
1879 *** The system does not provide a working iconv function.  Please
1880 *** install a suitable library; for example GNU Libiconv which is
1881 *** available at:
1882 ***   http://ftp.gnu.org/gnu/libiconv/
1883 ***]])
1884   fi
1885 fi
1886
1887 if test "$use_ccid_driver" = yes; then
1888   if test "$have_libusb" != yes; then
1889     die=yes
1890     AC_MSG_NOTICE([[
1891 ***
1892 *** You need libusb to build the internal ccid driver.  Please
1893 *** install a libusb suitable for your system.
1894 ***]])
1895   fi
1896 fi
1897
1898 if test "$die" = "yes"; then
1899     AC_MSG_ERROR([[
1900 ***
1901 *** Required libraries not found. Please consult the above messages
1902 *** and install them before running configure again.
1903 ***]])
1904 fi
1905
1906
1907
1908 AC_CONFIG_FILES([ m4/Makefile
1909 Makefile
1910 po/Makefile.in
1911 common/Makefile
1912 common/w32info-rc.h
1913 kbx/Makefile
1914 g10/Makefile
1915 sm/Makefile
1916 agent/Makefile
1917 scd/Makefile
1918 g13/Makefile
1919 dirmngr/Makefile
1920 tools/gpg-zip
1921 tools/Makefile
1922 doc/Makefile
1923 tests/Makefile
1924 tests/gpgscm/Makefile
1925 tests/openpgp/Makefile
1926 tests/migrations/Makefile
1927 tests/pkits/Makefile
1928 g10/gpg.w32-manifest
1929 ])
1930
1931
1932 AC_OUTPUT
1933
1934
1935 echo "
1936         GnuPG v${VERSION} has been configured as follows:
1937
1938         Revision:  mym4_revision  (mym4_revision_dec)
1939         Platform:  $PRINTABLE_OS_NAME ($host)
1940
1941         OpenPGP:   $build_gpg
1942         S/MIME:    $build_gpgsm
1943         Agent:     $build_agent
1944         Smartcard: $build_scdaemon $build_scdaemon_extra
1945         G13:       $build_g13
1946         Dirmngr:   $build_dirmngr
1947         Gpgtar:    $build_gpgtar
1948         WKS tools: $build_wks_tools
1949
1950         Protect tool:      $show_gnupg_protect_tool_pgm
1951         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1952         Default agent:     $show_gnupg_agent_pgm
1953         Default pinentry:  $show_gnupg_pinentry_pgm
1954         Default scdaemon:  $show_gnupg_scdaemon_pgm
1955         Default dirmngr:   $show_gnupg_dirmngr_pgm
1956
1957         Dirmngr auto start:  $dirmngr_auto_start
1958         Readline support:    $gnupg_cv_have_readline
1959         LDAP support:        $gnupg_have_ldap
1960         DNS SRV support:     $use_dns_srv
1961         TLS support:         $use_tls_library
1962         TOFU support:        $use_tofu
1963         Tor support:         $show_tor_support
1964 "
1965 if test x"$use_regex" != xyes ; then
1966 echo "
1967         Warning: No regular expression support available.
1968                  OpenPGP trust signatures won't work.
1969                  gpg-check-pattern will not be built.
1970 "
1971 fi
1972 if test "x${gpg_config_script_warn}" != x; then
1973 cat <<G10EOF
1974         Warning: Mismatches between the target platform and the
1975                  to be used libraries have been detected for:
1976                   ${gpg_config_script_warn}
1977                  Please check above for more warning messages.
1978
1979 G10EOF
1980 fi