dirmngr: Require a c99 compiler
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2012 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2016 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [1])
31 m4_define([mym4_micro], [17])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 NEED_GPG_ERROR_VERSION=1.24
53
54 NEED_LIBGCRYPT_API=1
55 NEED_LIBGCRYPT_VERSION=1.7.0
56
57 NEED_LIBASSUAN_API=2
58 NEED_LIBASSUAN_VERSION=2.4.3
59
60 NEED_KSBA_API=1
61 NEED_KSBA_VERSION=1.3.4
62
63 NEED_NTBTLS_API=1
64 NEED_NTBTLS_VERSION=0.1.0
65
66 NEED_NPTH_API=1
67 NEED_NPTH_VERSION=1.2
68
69
70 NEED_GNUTLS_VERSION=3.0
71
72 NEED_SQLITE_VERSION=3.7
73
74 development_version=mym4_isbeta
75 PACKAGE=$PACKAGE_NAME
76 PACKAGE_GT=${PACKAGE_NAME}2
77 VERSION=$PACKAGE_VERSION
78
79 AC_CONFIG_AUX_DIR([build-aux])
80 AC_CONFIG_SRCDIR([sm/gpgsm.c])
81 AC_CONFIG_HEADER([config.h])
82 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
83 AC_CANONICAL_HOST
84 AB_INIT
85
86 AC_GNU_SOURCE
87
88 # Before we do anything with the C compiler, we first save the user's
89 # CFLAGS (they are restored at the end of the configure script).  This
90 # is because some configure checks don't work with -Werror, but we'd
91 # like to use -Werror with our build.
92 CFLAGS_orig=$CFLAGS
93 CFLAGS=
94
95 # Some status variables.
96 have_gpg_error=no
97 have_libgcrypt=no
98 have_libassuan=no
99 have_ksba=no
100 have_ntbtls=no
101 have_gnutls=no
102 have_sqlite=no
103 have_npth=no
104 have_libusb=no
105 have_system_resolver=no
106 gnupg_have_ldap="n/a"
107
108 use_zip=yes
109 use_bzip2=yes
110 use_exec=yes
111 use_trust_models=yes
112 use_tofu=yes
113 card_support=yes
114 use_ccid_driver=auto
115 dirmngr_auto_start=yes
116 use_tls_library=no
117 large_secmem=no
118 show_tor_support=no
119
120
121 GNUPG_BUILD_PROGRAM(gpg, yes)
122 GNUPG_BUILD_PROGRAM(gpgsm, yes)
123 # The agent is a required part and can't be disabled anymore.
124 build_agent=yes
125 GNUPG_BUILD_PROGRAM(scdaemon, yes)
126 GNUPG_BUILD_PROGRAM(g13, no)
127 GNUPG_BUILD_PROGRAM(dirmngr, yes)
128 GNUPG_BUILD_PROGRAM(tools, yes)
129 GNUPG_BUILD_PROGRAM(doc, yes)
130 GNUPG_BUILD_PROGRAM(symcryptrun, no)
131 # We use gpgtar to unpack test data, hence we always build it.  If the
132 # user opts out, we simply don't install it.
133 GNUPG_BUILD_PROGRAM(gpgtar, yes)
134 GNUPG_BUILD_PROGRAM(wks-tools, no)
135
136 AC_SUBST(PACKAGE)
137 AC_SUBST(PACKAGE_GT)
138 AC_SUBST(VERSION)
139 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
140 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
141                                 [Name of this package for gettext])
142 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
143 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
144                                         [Bug report address])
145 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
146                                        [Required version of Libgcrypt])
147 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
148                                        [Required version of Libksba])
149 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
150                                        [Required version of NTBTLS])
151
152
153
154 # The default is to use the modules from this package and the few
155 # other packages in a standard place; i.e where this package gets
156 # installed.  With these options it is possible to override these
157 # ${prefix} depended values with fixed paths, which can't be replaced
158 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
159 AC_ARG_WITH(agent-pgm,
160     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
161           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
162 AC_SUBST(GNUPG_AGENT_PGM)
163 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
164 show_gnupg_agent_pgm="(default)"
165 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
166
167 AC_ARG_WITH(pinentry-pgm,
168     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
169           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
170 AC_SUBST(GNUPG_PINENTRY_PGM)
171 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
172 show_gnupg_pinentry_pgm="(default)"
173 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
174
175
176 AC_ARG_WITH(scdaemon-pgm,
177     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
178           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
179 AC_SUBST(GNUPG_SCDAEMON_PGM)
180 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
181 show_gnupg_scdaemon_pgm="(default)"
182 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
183
184
185 AC_ARG_WITH(dirmngr-pgm,
186     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
187           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
188 AC_SUBST(GNUPG_DIRMNGR_PGM)
189 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
190 show_gnupg_dirmngr_pgm="(default)"
191 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
192
193 AC_ARG_WITH(protect-tool-pgm,
194     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
195           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
196 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
197 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
198 show_gnupg_protect_tool_pgm="(default)"
199 test -n "$GNUPG_PROTECT_TOOL_PGM" \
200       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
201
202 AC_ARG_WITH(dirmngr-ldap-pgm,
203     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
204           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
205 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
206 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
207 show_gnupg_dirmngr_ldap_pgm="(default)"
208 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
209       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
210
211 #
212 # On some platforms gpg2 is usually installed as gpg without using a
213 # symlink.  For correct operation of gpgconf it needs to know the
214 # installed name of gpg.  This option sets "gpg2"'s installed name to
215 # just "gpg".  Note that it might be required to rename gpg2 to gpg
216 # manually after the build process.
217 #
218 AC_ARG_ENABLE(gpg2-is-gpg,
219     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
220     gpg2_is_gpg=$enableval)
221 if test "$gpg2_is_gpg" != "yes"; then
222    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
223 fi
224 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg2_is_gpg" != "yes")
225
226
227 # SELinux support includes tracking of sensitive files to avoid
228 # leaking their contents through processing these files by gpg itself
229 AC_MSG_CHECKING([whether SELinux support is requested])
230 AC_ARG_ENABLE(selinux-support,
231               AC_HELP_STRING([--enable-selinux-support],
232                              [enable SELinux support]),
233               selinux_support=$enableval, selinux_support=no)
234 AC_MSG_RESULT($selinux_support)
235
236
237 AC_MSG_CHECKING([whether to allocate extra secure memory])
238 AC_ARG_ENABLE(large-secmem,
239               AC_HELP_STRING([--enable-large-secmem],
240                              [allocate extra secure memory]),
241               large_secmem=$enableval, large_secmem=no)
242 AC_MSG_RESULT($large_secmem)
243 if test "$large_secmem" = yes ; then
244    SECMEM_BUFFER_SIZE=65536
245 else
246    SECMEM_BUFFER_SIZE=32768
247 fi
248 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
249                    [Size of secure memory buffer])
250
251 AC_MSG_CHECKING([whether to enable trust models])
252 AC_ARG_ENABLE(trust-models,
253               AC_HELP_STRING([--disable-trust-models],
254                              [disable all trust models except "always"]),
255               use_trust_models=$enableval)
256 AC_MSG_RESULT($use_trust_models)
257 if test "$use_trust_models" = no ; then
258     AC_DEFINE(NO_TRUST_MODELS, 1,
259              [Define to include only trust-model always])
260 fi
261
262 AC_MSG_CHECKING([whether to enable TOFU])
263 AC_ARG_ENABLE(tofu,
264                 AC_HELP_STRING([--disable-tofu],
265                                [disable the TOFU trust model]),
266               use_tofu=$enableval, use_tofu=$use_trust_models)
267 AC_MSG_RESULT($use_tofu)
268 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
269     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
270 fi
271
272
273
274 #
275 # Options to disable algorithm
276 #
277
278 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
279 # Elgamal is a MUST algorithm
280 # DSA is a MUST algorithm
281 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
282 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
283 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
284
285 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
286 # 3DES is a MUST algorithm
287 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
288 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
289 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
290 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
291 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
292 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
293 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
294 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
295 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
296
297 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
298 # SHA1 is a MUST algorithm
299 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
300 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
301 # SHA256 is a MUST algorithm for GnuPG.
302 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
303 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
304
305
306 # Allow disabling of zip support.
307 # This is in general not a good idea because according to rfc4880 OpenPGP
308 # implementations SHOULD support ZLIB.
309 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
310 AC_ARG_ENABLE(zip,
311    AC_HELP_STRING([--disable-zip],
312                   [disable the ZIP and ZLIB compression algorithm]),
313    use_zip=$enableval)
314 AC_MSG_RESULT($use_zip)
315
316 # Allow disabling of bzib2 support.
317 # It is defined only after we confirm the library is available later
318 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
319 AC_ARG_ENABLE(bzip2,
320    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
321    use_bzip2=$enableval)
322 AC_MSG_RESULT($use_bzip2)
323
324 # Configure option to allow or disallow execution of external
325 # programs, like a photo viewer.
326 AC_MSG_CHECKING([whether to enable external program execution])
327 AC_ARG_ENABLE(exec,
328     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
329     use_exec=$enableval)
330 AC_MSG_RESULT($use_exec)
331 if test "$use_exec" = no ; then
332     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
333 fi
334
335 if test "$use_exec" = yes ; then
336   AC_MSG_CHECKING([whether to enable photo ID viewing])
337   AC_ARG_ENABLE(photo-viewers,
338       [  --disable-photo-viewers disable photo ID viewers],
339       [if test "$enableval" = no ; then
340          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
341       fi],enableval=yes)
342   gnupg_cv_enable_photo_viewers=$enableval
343   AC_MSG_RESULT($enableval)
344
345   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
346     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
347     AC_ARG_WITH(photo-viewer,
348         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
349         [if test "$withval" = yes ; then
350            withval=no
351         elif test "$withval" != no ; then
352            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
353                             [if set, restrict photo-viewer to this])
354         fi],withval=no)
355     AC_MSG_RESULT($withval)
356   fi
357 fi
358
359
360 #
361 # Check for the key/uid cache size.  This can't be zero, but can be
362 # pretty small on embedded systems.  This is used for the gpg part.
363 #
364 AC_MSG_CHECKING([for the size of the key and uid cache])
365 AC_ARG_ENABLE(key-cache,
366         AC_HELP_STRING([--enable-key-cache=SIZE],
367                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
368 if test "$enableval" = "no"; then
369    enableval=5
370 elif test "$enableval" = "yes" || test "$enableval" = ""; then
371    enableval=4096
372 fi
373 changequote(,)dnl
374 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
375 changequote([,])dnl
376 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
377    AC_MSG_ERROR([invalid key-cache size])
378 fi
379 AC_MSG_RESULT($key_cache_size)
380 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
381                   [Size of the key and UID caches])
382
383
384
385 #
386 # Check whether we want to use Linux capabilities
387 #
388 AC_MSG_CHECKING([whether use of capabilities is requested])
389 AC_ARG_WITH(capabilities,
390     [  --with-capabilities     use linux capabilities [default=no]],
391 [use_capabilities="$withval"],[use_capabilities=no])
392 AC_MSG_RESULT($use_capabilities)
393
394 #
395 # Check whether to disable the card support
396 AC_MSG_CHECKING([whether smartcard support is requested])
397 AC_ARG_ENABLE(card-support,
398               AC_HELP_STRING([--disable-card-support],
399                              [disable smartcard support]),
400               card_support=$enableval)
401 AC_MSG_RESULT($card_support)
402 if test "$card_support" = yes ; then
403   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
404 else
405   build_scdaemon=no
406 fi
407
408 #
409 # Allow disabling of internal CCID support.
410 # It is defined only after we confirm the library is available later
411 #
412 AC_MSG_CHECKING([whether to enable the internal CCID driver])
413 AC_ARG_ENABLE(ccid-driver,
414               AC_HELP_STRING([--disable-ccid-driver],
415                              [disable the internal CCID driver]),
416               use_ccid_driver=$enableval)
417 AC_MSG_RESULT($use_ccid_driver)
418
419 AC_MSG_CHECKING([whether to auto start dirmngr])
420 AC_ARG_ENABLE(dirmngr-auto-start,
421               AC_HELP_STRING([--disable-dirmngr-auto-start],
422                              [disable auto starting of the dirmngr]),
423               dirmngr_auto_start=$enableval)
424 AC_MSG_RESULT($dirmngr_auto_start)
425 if test "$dirmngr_auto_start" = yes ; then
426     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
427               [Define to enable auto starting of the dirmngr])
428 fi
429
430
431 #
432 # To avoid double inclusion of config.h which might happen at some
433 # places, we add the usual double inclusion protection at the top of
434 # config.h.
435 #
436 AH_TOP([
437 #ifndef GNUPG_CONFIG_H_INCLUDED
438 #define GNUPG_CONFIG_H_INCLUDED
439 ])
440
441 #
442 # Stuff which goes at the bottom of config.h.
443 #
444 AH_BOTTOM([
445 /* This is the major version number of GnuPG so that
446    source included files can test for this.  Note, that
447    we use 2 here even for GnuPG 1.9.x. */
448 #define GNUPG_MAJOR_VERSION 2
449
450 /* Now to separate file name parts.
451    Please note that the string version must not contain more
452    than one character because the code assumes strlen()==1 */
453 #ifdef HAVE_DOSISH_SYSTEM
454 #define DIRSEP_C '\\'
455 #define DIRSEP_S "\\"
456 #define EXTSEP_C '.'
457 #define EXTSEP_S "."
458 #define PATHSEP_C ';'
459 #define PATHSEP_S ";"
460 #define EXEEXT_S ".exe"
461 #else
462 #define DIRSEP_C '/'
463 #define DIRSEP_S "/"
464 #define EXTSEP_C '.'
465 #define EXTSEP_S "."
466 #define PATHSEP_C ':'
467 #define PATHSEP_S ":"
468 #define EXEEXT_S ""
469 #endif
470
471 /* This is the same as VERSION, but should be overridden if the
472    platform cannot handle things like dots '.' in filenames. Set
473    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
474    uses for dots and dashes. */
475 #define SAFE_VERSION VERSION
476 #define SAFE_VERSION_DOT  '.'
477 #define SAFE_VERSION_DASH '-'
478
479 /* Some global constants. */
480 #ifdef HAVE_DOSISH_SYSTEM
481 # ifdef HAVE_DRIVE_LETTERS
482 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
483 # else
484 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
485 # endif
486 #elif defined(__VMS)
487 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
488 #else
489 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
490 #endif
491 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
492 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
493
494 /* For some systems (DOS currently), we hardcode the path here.  For
495    POSIX systems the values are constructed by the Makefiles, so that
496    the values may be overridden by the make invocations; this is to
497    comply with the GNU coding standards.  Note that these values are
498    only defaults.  */
499 #ifdef HAVE_DOSISH_SYSTEM
500 # ifdef HAVE_DRIVE_LETTERS
501 #  define GNUPG_BINDIR      "c:\\gnupg"
502 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
503 #  define GNUPG_LIBDIR      "c:\\gnupg"
504 #  define GNUPG_DATADIR     "c:\\gnupg"
505 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
506 # else
507 #  define GNUPG_BINDIR      "\\gnupg"
508 #  define GNUPG_LIBEXECDIR  "\\gnupg"
509 #  define GNUPG_LIBDIR      "\\gnupg"
510 #  define GNUPG_DATADIR     "\\gnupg"
511 #  define GNUPG_SYSCONFDIR  "\\gnupg"
512 # endif
513 #endif
514
515 /* Derive some other constants. */
516 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
517 #define EXEC_TEMPFILE_ONLY
518 #endif
519
520
521 /* We didn't define endianness above, so get it from OS macros.  This
522    is intended for making fat binary builds on OS X. */
523 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
524 #if defined(__BIG_ENDIAN__)
525 #define BIG_ENDIAN_HOST 1
526 #elif defined(__LITTLE_ENDIAN__)
527 #define LITTLE_ENDIAN_HOST 1
528 #else
529 #error "No endianness found"
530 #endif
531 #endif
532
533
534 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
535    ldap_start_tls_s because that is the actual symbol used in the
536    library.  winldap.h redefines it to our commonly used value,
537    thus we define our usual macro here.  */
538 #ifdef HAVE_LDAP_START_TLS_SA
539 # ifndef HAVE_LDAP_START_TLS_S
540 #  define HAVE_LDAP_START_TLS_S 1
541 # endif
542 #endif
543
544 /* Provide the es_ macro for estream.  */
545 #define GPGRT_ENABLE_ES_MACROS 1
546
547 /* Tell libgcrypt not to use its own libgpg-error implementation. */
548 #define USE_LIBGPG_ERROR 1
549
550 /* Tell Libgcrypt not to include deprecated definitions.  */
551 #define GCRYPT_NO_DEPRECATED 1
552
553 /* Our HTTP code is used in estream mode.  */
554 #define HTTP_USE_ESTREAM 1
555
556 /* Under W32 we do an explicit socket initialization, thus we need to
557    avoid the on-demand initialization which would also install an atexit
558    handler.  */
559 #define HTTP_NO_WSASTARTUP
560
561 /* Under Windows we use the gettext code from libgpg-error.  */
562 #define GPG_ERR_ENABLE_GETTEXT_MACROS
563
564 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
565 #define GPG_ERR_ENABLE_ERRNO_MACROS
566
567 #endif /*GNUPG_CONFIG_H_INCLUDED*/
568 ])
569
570
571 AM_MAINTAINER_MODE
572 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
573
574 # Checks for programs.
575 AC_MSG_NOTICE([checking for programs])
576 AC_PROG_MAKE_SET
577 AM_SANITY_CHECK
578 missing_dir=`cd $ac_aux_dir && pwd`
579 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
580 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
581 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
582 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
583 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
584 AM_SILENT_RULES
585 AC_PROG_AWK
586 AC_PROG_CC
587 AC_PROG_CPP
588 AM_PROG_CC_C_O
589 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
590   AC_MSG_ERROR([[No C-89 compiler found]])
591 fi
592 AC_PROG_INSTALL
593 AC_PROG_LN_S
594 AC_PROG_RANLIB
595 AC_CHECK_TOOL(AR, ar, :)
596 AC_PATH_PROG(PERL,"perl")
597 AC_CHECK_TOOL(WINDRES, windres, :)
598 AC_ISC_POSIX
599 AC_SYS_LARGEFILE
600 GNUPG_CHECK_USTAR
601
602
603 # We need to compile and run a program on the build machine.  A
604 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
605 # the AC archive is broken for autoconf 2.57.  Given that there is no
606 # newer version of that macro, we assume that it is also broken for
607 # autoconf 2.61 and thus we use a simple but usually sufficient
608 # approach.
609 AC_MSG_CHECKING(for cc for build)
610 if test "$cross_compiling" = "yes"; then
611   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
612 else
613   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
614 fi
615 AC_MSG_RESULT($CC_FOR_BUILD)
616 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
617
618 # We need to call this macro because other pkg-config macros are
619 # not always used.
620 PKG_PROG_PKG_CONFIG
621
622
623 try_gettext=yes
624 require_iconv=yes
625 have_dosish_system=no
626 have_w32_system=no
627 have_w32ce_system=no
628 have_android_system=no
629 use_simple_gettext=no
630 use_ldapwrapper=yes
631 mmap_needed=yes
632 case "${host}" in
633     *-mingw32*)
634         # special stuff for Windoze NT
635         ac_cv_have_dev_random=no
636         AC_DEFINE(USE_ONLY_8DOT3,1,
637                   [Set this to limit filenames to the 8.3 format])
638         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
639                   [Because the Unix gettext has too much overhead on
640                    MingW32 systems and these systems lack Posix functions,
641                    we use a simplified version of gettext])
642         have_dosish_system=yes
643         have_w32_system=yes
644         require_iconv=no
645         use_ldapwrapper=no  # Fixme: Do this only for CE.
646         case "${host}" in
647           *-mingw32ce*)
648             have_w32ce_system=yes
649             ;;
650           *)
651             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
652                       [Defined if the OS supports drive letters.])
653             ;;
654         esac
655         try_gettext="no"
656         use_simple_gettext=yes
657         mmap_needed=no
658         ;;
659     i?86-emx-os2 | i?86-*-os2*emx )
660         # OS/2 with the EMX environment
661         ac_cv_have_dev_random=no
662         AC_DEFINE(HAVE_DRIVE_LETTERS)
663         have_dosish_system=yes
664         try_gettext="no"
665         ;;
666
667     i?86-*-msdosdjgpp*)
668         # DOS with the DJGPP environment
669         ac_cv_have_dev_random=no
670         AC_DEFINE(HAVE_DRIVE_LETTERS)
671         have_dosish_system=yes
672         try_gettext="no"
673         ;;
674
675     *-*-hpux*)
676         if test -z "$GCC" ; then
677             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
678         fi
679         ;;
680     *-dec-osf4*)
681         if test -z "$GCC" ; then
682             # Suppress all warnings
683             # to get rid of the unsigned/signed char mismatch warnings.
684             CFLAGS="-w $CFLAGS"
685         fi
686         ;;
687     *-dec-osf5*)
688         if test -z "$GCC" ; then
689             # Use the newer compiler `-msg_disable ptrmismatch1' to
690             # get rid of the unsigned/signed char mismatch warnings.
691             # Using this may hide other pointer mismatch warnings, but
692             # it at least lets other warning classes through
693             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
694         fi
695         ;;
696     m68k-atari-mint)
697         ;;
698     *-linux-android*)
699         have_android_system=yes
700         # Android is fully utf-8 and we do not want to use iconv to
701         # keeps things simple
702         require_iconv=no
703         ;;
704     *)
705        ;;
706 esac
707
708 if test "$have_dosish_system" = yes; then
709    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
710              [Defined if we run on some of the PCDOS like systems
711               (DOS, Windoze. OS/2) with special properties like
712               no file modes, case insensitive file names and preferred
713               use of backslashes as directory name separators.])
714 fi
715 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
716
717 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
718
719 if test "$have_w32_system" = yes; then
720    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
721    if test "$have_w32ce_system" = yes; then
722       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
723    fi
724 fi
725 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
726 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
727
728 if test "$have_android_system" = yes; then
729    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
730 fi
731 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
732
733
734 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
735 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
736
737
738 #
739 # Checks for libraries.
740 #
741 AC_MSG_NOTICE([checking for libraries])
742
743
744 #
745 # libgpg-error is a library with error codes shared between GnuPG
746 # related projects.
747 #
748 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
749                   have_gpg_error=yes,have_gpg_error=no)
750
751
752 #
753 # Libgcrypt is our generic crypto library
754 #
755 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
756         have_libgcrypt=yes,have_libgcrypt=no)
757
758
759 #
760 # libassuan is used for IPC
761 #
762 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
763                   have_libassuan=yes,have_libassuan=no)
764 if test "$have_libassuan" = "yes"; then
765   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
766                      [version of the libassuan library])
767   show_tor_support="only .onion"
768 fi
769
770
771 #
772 # libksba is our X.509 support library
773 #
774 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
775
776
777 #
778 # libusb allows us to use the integrated CCID smartcard reader driver.
779 #
780 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
781 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
782    case "${host}" in
783      *-mingw32*)
784        LIBUSB_NAME=
785        LIBUSB_LIBS=
786        LIBUSB_CPPFLAGS=
787        ;;
788      *-*-darwin*)
789        LIBUSB_NAME=usb-1.0
790        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
791        ;;
792      *-*-freebsd*)
793        # FreeBSD has a native 1.0 compatible library by -lusb.
794        LIBUSB_NAME=usb
795        LIBUSB_LIBS=
796        ;;
797      *)
798        LIBUSB_NAME=usb-1.0
799        LIBUSB_LIBS=
800        ;;
801    esac
802 fi
803 if test x"$LIBUSB_NAME" != x ; then
804    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
805                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
806                   have_libusb=yes ])
807    AC_MSG_CHECKING([libusb include dir])
808    usb_incdir_found="no"
809    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
810      _libusb_save_cppflags=$CPPFLAGS
811      if test -n "${_incdir}"; then
812        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
813      fi
814      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
815      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
816      CPPFLAGS=${_libusb_save_cppflags}
817      if test "$usb_incdir_found" = "yes"; then
818        break
819      fi
820    done
821    if test "$usb_incdir_found" = "yes"; then
822      AC_MSG_RESULT([${usb_incdir}])
823    else
824      AC_MSG_RESULT([not found])
825      usb_incdir=""
826      have_libusb=no
827      if test "$use_ccid_driver" != yes; then
828        use_ccid_driver=no
829      fi
830      LIBUSB_LIBS=""
831    fi
832
833    if test "$have_libusb" = yes; then
834      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
835    fi
836    if test x"$usb_incdir" = x; then
837      LIBUSB_CPPFLAGS=""
838    else
839      LIBUSB_CPPFLAGS="-I${usb_incdir}"
840    fi
841 fi
842 AC_SUBST(LIBUSB_LIBS)
843 AC_SUBST(LIBUSB_CPPFLAGS)
844
845 #
846 # Check wether it is necessary to link against libdl.
847 # (For example to load libpcsclite)
848 #
849 gnupg_dlopen_save_libs="$LIBS"
850 LIBS=""
851 AC_SEARCH_LIBS(dlopen, c dl,,,)
852 DL_LIBS=$LIBS
853 AC_SUBST(DL_LIBS)
854 LIBS="$gnupg_dlopen_save_libs"
855
856
857 # Checks for g10
858
859 AC_ARG_ENABLE(sqlite,
860                 AC_HELP_STRING([--disable-sqlite],
861                                [disable the use of SQLITE]),
862               try_sqlite=$enableval, try_sqlite=yes)
863
864 if test x"$use_tofu" = xyes ; then
865   if test x"$try_sqlite" = xyes ; then
866     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
867                                  [have_sqlite=yes],
868                                  [have_sqlite=no])
869   fi
870   if test "$have_sqlite" = "yes"; then
871     :
872     AC_SUBST([SQLITE3_CFLAGS])
873     AC_SUBST([SQLITE3_LIBS])
874   else
875     use_tofu=no
876     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
877     AC_MSG_WARN([[
878 ***
879 *** Building without SQLite support - TOFU disabled
880 ***
881 *** $tmp]])
882   fi
883 fi
884
885 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
886
887 if test x"$use_tofu" = xyes ; then
888     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
889 fi
890
891
892 # Checks for g13
893
894 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
895 AC_DEFINE_UNQUOTED(ENCFS,
896         "${ENCFS}", [defines the filename of the encfs program])
897
898 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
899 AC_DEFINE_UNQUOTED(FUSERMOUNT,
900         "${FUSERMOUNT}", [defines the filename of the fusermount program])
901
902
903 # Checks for dirmngr
904
905
906 #
907 # Checks for symcryptrun:
908 #
909
910 # libutil has openpty() and login_tty().
911 AC_CHECK_LIB(util, openpty,
912               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
913                 AC_DEFINE(HAVE_LIBUTIL,1,
914                          [defined if libutil is available])
915              ])
916 AC_SUBST(LIBUTIL_LIBS)
917
918 # shred is used to clean temporary plain text files.
919 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
920 AC_DEFINE_UNQUOTED(SHRED,
921         "${SHRED}", [defines the filename of the shred program])
922
923
924 #
925 # Check whether the nPth library is available
926 #
927 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
928 if test "$have_npth" = "yes"; then
929   AC_DEFINE(HAVE_NPTH, 1,
930               [Defined if the New Portable Thread Library is available])
931   AC_DEFINE(USE_NPTH, 1,
932               [Defined if support for nPth is requested and nPth is available])
933 else
934   AC_MSG_WARN([[
935 ***
936 *** To support concurrent access for example in gpg-agent and the SCdaemon
937 *** we need the support of the New Portable Threads Library.
938 ***]])
939 fi
940
941
942 #
943 # NTBTLS is our TLS library.  If it is not available fallback to
944 # GNUTLS.
945 #
946 AC_ARG_ENABLE(ntbtls,
947               AC_HELP_STRING([--disable-ntbtls],
948                              [disable the use of NTBTLS as TLS library]),
949               try_ntbtls=$enableval, try_ntbtls=yes)
950 if test x"$try_ntbtls" = xyes ; then
951   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
952                  [have_ntbtls=yes],[have_ntbtls=no])
953 fi
954 if test "$have_ntbtls" = yes ; then
955    use_tls_library=ntbtls
956    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
957 else
958   AC_ARG_ENABLE(gnutls,
959                 AC_HELP_STRING([--disable-gnutls],
960                                [disable GNUTLS as fallback TLS library]),
961                 try_gnutls=$enableval, try_gnutls=yes)
962   if test x"$try_gnutls" = xyes ; then
963     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
964                                    [have_gnutls=yes],
965                                    [have_gnutls=no])
966   fi
967   if test "$have_gnutls" = "yes"; then
968     AC_SUBST([LIBGNUTLS_CFLAGS])
969     AC_SUBST([LIBGNUTLS_LIBS])
970     use_tls_library=gnutls
971     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
972   else
973     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
974     AC_MSG_WARN([[
975 ***
976 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
977 ***
978 *** $tmp]])
979   fi
980 fi
981
982
983 AC_MSG_NOTICE([checking for networking options])
984
985 #
986 # Must check for network library requirements before doing link tests
987 # for ldap, for example. If ldap libs are static (or dynamic and without
988 # ELF runtime link paths), then link will fail and LDAP support won't
989 # be detected.
990 #
991 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
992         [NETLIBS="-lnsl $NETLIBS"]))
993 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
994         [NETLIBS="-lsocket $NETLIBS"]))
995
996
997 #
998 # Check standard resolver functions.
999 #
1000 if test "$build_dirmngr" = "yes"; then
1001   _dns_save_libs=$LIBS
1002   LIBS=""
1003
1004   # Find the system resolver which can always be enabled with
1005   # the dirmngr option --standard-resolver.
1006
1007   # the double underscore thing is a glibc-ism?
1008   AC_SEARCH_LIBS(res_query,resolv bind,,
1009                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1010   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1011                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1012
1013   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1014   # and for some reason fools us into believing we don't need
1015   # -lresolv even if we do.  Since the test program checking for the
1016   # symbol does not include <resolv.h>, we need to check for the
1017   # renamed symbol explicitly.
1018   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1019       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1020           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1021
1022   if test x"$have_resolver" != xno ; then
1023
1024       # Make sure that the BIND 4 resolver interface is workable before
1025       # enabling any code that calls it.  At some point I'll rewrite the
1026       # code to use the BIND 8 resolver API.
1027       # We might also want to use libdns instead.
1028
1029     AC_MSG_CHECKING([whether the resolver is usable])
1030     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1031 #include <netinet/in.h>
1032 #include <arpa/nameser.h>
1033 #include <resolv.h>]],
1034 [[unsigned char answer[PACKETSZ];
1035   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1036   dn_skipname(0,0);
1037   dn_expand(0,0,0,0,0);
1038 ]])],have_resolver=yes,have_resolver=no)
1039     AC_MSG_RESULT($have_resolver)
1040
1041     # This is Apple-specific and somewhat bizarre as they changed the
1042     # define in bind 8 for some reason.
1043
1044     if test x"$have_resolver" != xyes ; then
1045       AC_MSG_CHECKING(
1046            [whether I can make the resolver usable with BIND_8_COMPAT])
1047       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1048 #include <sys/types.h>
1049 #include <netinet/in.h>
1050 #include <arpa/nameser.h>
1051 #include <resolv.h>]],
1052 [[unsigned char answer[PACKETSZ];
1053   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1054   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1055 ]])],[have_resolver=yes ; need_compat=yes])
1056       AC_MSG_RESULT($have_resolver)
1057     fi
1058   fi
1059
1060   if test x"$have_resolver" = xyes ; then
1061     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1062     DNSLIBS="$DNSLIBS $LIBS"
1063     if test x"$need_compat" = xyes ; then
1064       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1065     fi
1066   else
1067     AC_MSG_WARN([[
1068 ***
1069 *** The system's DNS resolver is not usable.
1070 *** Dirmngr functionality is limited.
1071 ***]])
1072    show_tor_support="${show_tor_support} (no system resolver)"
1073   fi
1074
1075   LIBS=$_dns_save_libs
1076 fi
1077
1078 AC_SUBST(DNSLIBS)
1079
1080
1081 #
1082 # Check for LDAP
1083 #
1084 # Note that running the check changes the variable
1085 # gnupg_have_ldap from "n/a" to "no" or "yes".
1086
1087 AC_ARG_ENABLE(ldap,
1088     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1089     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1090
1091 if test "$gnupg_have_ldap" != "no" ; then
1092   if test "$build_dirmngr" = "yes" ; then
1093      GNUPG_CHECK_LDAP($NETLIBS)
1094      AC_CHECK_LIB(lber, ber_free,
1095                   [ LBER_LIBS="$LBER_LIBS -llber"
1096                     AC_DEFINE(HAVE_LBER,1,
1097                              [defined if liblber is available])
1098                     have_lber=yes
1099                  ])
1100   fi
1101 fi
1102 AC_SUBST(LBER_LIBS)
1103 if test "$gnupg_have_ldap" = "no"; then
1104     AC_MSG_WARN([[
1105 ***
1106 *** Building without LDAP support.
1107 *** No CRL access or X.509 certificate search available.
1108 ***]])
1109 fi
1110
1111 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1112 if test "$gnupg_have_ldap" = yes ; then
1113   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1114 else
1115  use_ldapwrapper=no
1116 fi
1117
1118 if test "$use_ldapwrapper" = yes; then
1119    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1120 fi
1121 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1122
1123
1124
1125
1126 #
1127 # Check for sendmail
1128 #
1129 # This isn't necessarily sendmail itself, but anything that gives a
1130 # sendmail-ish interface to the outside world.  That includes Exim,
1131 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1132 AC_ARG_WITH(mailprog,
1133       AC_HELP_STRING([--with-mailprog=NAME],
1134                      [use "NAME -t" for mail transport]),
1135              ,with_mailprog=yes)
1136 if test x"$with_mailprog" = xyes ; then
1137     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1138 elif test x"$with_mailprog" != xno ; then
1139     AC_MSG_CHECKING([for a mail transport program])
1140     AC_SUBST(SENDMAIL,$with_mailprog)
1141     AC_MSG_RESULT($with_mailprog)
1142 fi
1143
1144
1145 #
1146 # Construct a printable name of the OS
1147 #
1148 case "${host}" in
1149     *-mingw32ce*)
1150         PRINTABLE_OS_NAME="W32CE"
1151         ;;
1152     *-mingw32*)
1153         PRINTABLE_OS_NAME="MingW32"
1154         ;;
1155     *-*-cygwin*)
1156         PRINTABLE_OS_NAME="Cygwin"
1157         ;;
1158     i?86-emx-os2 | i?86-*-os2*emx )
1159         PRINTABLE_OS_NAME="OS/2"
1160         ;;
1161     i?86-*-msdosdjgpp*)
1162         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1163         try_dynload=no
1164         ;;
1165     *-linux*)
1166         PRINTABLE_OS_NAME="GNU/Linux"
1167         ;;
1168     *)
1169         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1170         ;;
1171 esac
1172 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1173                    [A human readable text with the name of the OS])
1174
1175
1176 #
1177 # Checking for iconv
1178 #
1179 if test "$require_iconv" = yes; then
1180   AM_ICONV
1181 else
1182   LIBICONV=
1183   LTLIBICONV=
1184   AC_SUBST(LIBICONV)
1185   AC_SUBST(LTLIBICONV)
1186 fi
1187
1188
1189 #
1190 # Check for gettext
1191 #
1192 # This is "GNU gnupg" - The project-id script from gettext
1193 #                       needs this string
1194 #
1195 AC_MSG_NOTICE([checking for gettext])
1196 AM_PO_SUBDIRS
1197 AM_GNU_GETTEXT_VERSION([0.17])
1198 if test "$try_gettext" = yes; then
1199   AM_GNU_GETTEXT([external],[need-ngettext])
1200
1201   # gettext requires some extra checks.  These really should be part of
1202   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1203   # function checks to here.
1204
1205   AC_CHECK_FUNCS(strchr)
1206 else
1207   USE_NLS=no
1208   USE_INCLUDED_LIBINTL=no
1209   BUILD_INCLUDED_LIBINTL=no
1210   POSUB=po
1211   AC_SUBST(USE_NLS)
1212   AC_SUBST(USE_INCLUDED_LIBINTL)
1213   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1214   AC_SUBST(POSUB)
1215 fi
1216
1217 # We use HAVE_LANGINFO_CODESET in a couple of places.
1218 AM_LANGINFO_CODESET
1219
1220 # Checks required for our use of locales
1221 gt_LC_MESSAGES
1222
1223
1224 #
1225 # SELinux support
1226 #
1227 if test "$selinux_support" = yes ; then
1228   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1229 fi
1230
1231
1232 #
1233 # Checks for header files.
1234 #
1235 AC_MSG_NOTICE([checking for header files])
1236 AC_HEADER_STDC
1237 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1238                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1239                   signal.h])
1240 AC_HEADER_TIME
1241
1242
1243 #
1244 # Checks for typedefs, structures, and compiler characteristics.
1245 #
1246 AC_MSG_NOTICE([checking for system characteristics])
1247 AC_C_CONST
1248 AC_C_INLINE
1249 AC_C_VOLATILE
1250 AC_TYPE_SIZE_T
1251 AC_TYPE_MODE_T
1252 AC_TYPE_SIGNAL
1253 AC_DECL_SYS_SIGLIST
1254
1255 gl_HEADER_SYS_SOCKET
1256 gl_TYPE_SOCKLEN_T
1257
1258 AC_SEARCH_LIBS([inet_addr], [nsl])
1259
1260 AC_ARG_ENABLE(endian-check,
1261               AC_HELP_STRING([--disable-endian-check],
1262               [disable the endian check and trust the OS provided macros]),
1263               endiancheck=$enableval,endiancheck=yes)
1264
1265 if test x"$endiancheck" = xyes ; then
1266   GNUPG_CHECK_ENDIAN
1267 fi
1268
1269 # fixme: we should get rid of the byte type
1270 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1271 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1272 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1273 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1274 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1275
1276 AC_CHECK_SIZEOF(unsigned short)
1277 AC_CHECK_SIZEOF(unsigned int)
1278 AC_CHECK_SIZEOF(unsigned long)
1279 AC_CHECK_SIZEOF(unsigned long long)
1280 AC_HEADER_TIME
1281 AC_CHECK_SIZEOF(time_t,,[[
1282 #include <stdio.h>
1283 #if TIME_WITH_SYS_TIME
1284 # include <sys/time.h>
1285 # include <time.h>
1286 #else
1287 # if HAVE_SYS_TIME_H
1288 #  include <sys/time.h>
1289 # else
1290 #  include <time.h>
1291 # endif
1292 #endif
1293 ]])
1294 GNUPG_TIME_T_UNSIGNED
1295
1296
1297 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1298    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1299    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1300     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1301 fi
1302
1303
1304 #
1305 # Checks for library functions.
1306 #
1307 AC_MSG_NOTICE([checking for library functions])
1308 AC_CHECK_DECLS(getpagesize)
1309 AC_FUNC_FSEEKO
1310 AC_FUNC_VPRINTF
1311 AC_FUNC_FORK
1312 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1313 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1314 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1315 AC_CHECK_FUNCS([canonicalize_file_name])
1316 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1317 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1318 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1319 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1320 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1321                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1322                 flockfile funlockfile getpwnam getpwuid \
1323                 getenv inet_pton strpbrk])
1324
1325 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1326 # Given that we use nanosleep only as an optimization over a select
1327 # based wait function we want it only if it is available in libc.
1328 _save_libs="$LIBS"
1329 AC_SEARCH_LIBS([nanosleep], [],
1330                [AC_DEFINE(HAVE_NANOSLEEP,1,
1331                 [Define to 1 if you have the `nanosleep' function in libc.])])
1332 LIBS="$_save_libs"
1333
1334
1335 # See whether libc supports the Linux inotify interface
1336 case "${host}" in
1337     *-*-linux*)
1338         AC_CHECK_FUNCS([inotify_init])
1339         ;;
1340 esac
1341
1342
1343 if test "$have_android_system" = yes; then
1344    # On Android ttyname is a stub but prints an error message.
1345    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1346              [Defined if ttyname does not work properly])
1347 fi
1348
1349 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1350
1351 # Dirmngr requires mmap on Unix systems.
1352 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1353   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1354 fi
1355
1356 #
1357 # W32 specific test
1358 #
1359 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1360
1361 #
1362 # Sanity check regex.  Tests adapted from mutt.
1363 #
1364 AC_MSG_CHECKING([whether regular expression support is requested])
1365 AC_ARG_ENABLE(regex,
1366   AC_HELP_STRING([--disable-regex],
1367     [do not handle regular expressions in trust signatures]),
1368   use_regex=$enableval, use_regex=yes)
1369 AC_MSG_RESULT($use_regex)
1370
1371 if test "$use_regex" = yes ; then
1372   _cppflags="${CPPFLAGS}"
1373   _ldflags="${LDFLAGS}"
1374   AC_ARG_WITH(regex,
1375      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1376       [
1377       if test -d "$withval" ; then
1378         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1379         LDFLAGS="${LDFLAGS} -L$withval/lib"
1380       fi
1381       ],withval="")
1382
1383   # Does the system have regex functions at all?
1384   AC_SEARCH_LIBS([regcomp], [regex])
1385   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1386
1387   if test $gnupg_cv_have_regex = no; then
1388     use_regex=no
1389   else
1390     if test x"$cross_compiling" = xyes; then
1391       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1392     else
1393       AC_CACHE_CHECK([whether your system's regexp library is broken],
1394        [gnupg_cv_regex_broken],
1395        AC_TRY_RUN([
1396 #include <unistd.h>
1397 #include <regex.h>
1398 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1399        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1400
1401       if test $gnupg_cv_regex_broken = yes; then
1402         AC_MSG_WARN([your regex is broken - disabling regex use])
1403         use_regex=no
1404       fi
1405     fi
1406   fi
1407   CPPFLAGS="${_cppflags}"
1408   LDFLAGS="${_ldflags}"
1409 fi
1410
1411 if test "$use_regex" != yes ; then
1412   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1413 fi
1414 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1415
1416
1417
1418 #
1419 # Do we have zlib? Must do it here because Solaris failed
1420 # when compiling a conftest (due to the "-lz" from LIBS).
1421 # Note that we combine zlib and bzlib2 in ZLIBS.
1422 #
1423 if test "$use_zip" = yes ; then
1424   _cppflags="${CPPFLAGS}"
1425   _ldflags="${LDFLAGS}"
1426   AC_ARG_WITH(zlib,
1427     [  --with-zlib=DIR         use libz in DIR],[
1428       if test -d "$withval"; then
1429         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1430         LDFLAGS="${LDFLAGS} -L$withval/lib"
1431       fi
1432     ])
1433
1434   AC_CHECK_HEADER(zlib.h,
1435      AC_CHECK_LIB(z, deflateInit2_,
1436        [
1437        ZLIBS="-lz"
1438        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1439        ],
1440        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1441        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1442 fi
1443
1444
1445 #
1446 # Check whether we can support bzip2
1447 #
1448 if test "$use_bzip2" = yes ; then
1449   _cppflags="${CPPFLAGS}"
1450   _ldflags="${LDFLAGS}"
1451   AC_ARG_WITH(bzip2,
1452      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1453       [
1454       if test -d "$withval" ; then
1455         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1456         LDFLAGS="${LDFLAGS} -L$withval/lib"
1457       fi
1458       ],withval="")
1459
1460   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1461   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1462   # woefully out of date.
1463   if test "$withval" != no ; then
1464      AC_CHECK_HEADER(bzlib.h,
1465         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1466           [
1467           have_bz2=yes
1468           ZLIBS="$ZLIBS -lbz2"
1469           AC_DEFINE(HAVE_BZIP2,1,
1470                   [Defined if the bz2 compression library is available])
1471           ],
1472           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1473           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1474   fi
1475 fi
1476 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1477 AC_SUBST(ZLIBS)
1478
1479
1480 # Check for readline support
1481 GNUPG_CHECK_READLINE
1482
1483
1484 if test "$development_version" = yes; then
1485     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1486             [Defined if this is not a regular release])
1487 fi
1488
1489 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1490
1491 GNUPG_CHECK_GNUMAKE
1492
1493 # Add some extra libs here so that previous tests don't fail for
1494 # mysterious reasons - the final link step should bail out.
1495 # W32SOCKLIBS is also defined so that if can be used for tools not
1496 # requiring any network stuff but linking to code in libcommon which
1497 # tracks in winsock stuff (e.g. init_common_subsystems).
1498 if test "$have_w32_system" = yes; then
1499    if test "$have_w32ce_system" = yes; then
1500      W32SOCKLIBS="-lws2"
1501    else
1502      W32SOCKLIBS="-lws2_32"
1503    fi
1504    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1505 fi
1506
1507 AC_SUBST(NETLIBS)
1508 AC_SUBST(W32SOCKLIBS)
1509
1510 #
1511 # Setup gcc specific options
1512 #
1513 AC_MSG_NOTICE([checking for cc features])
1514 if test "$GCC" = yes; then
1515     mycflags=
1516     mycflags_save=$CFLAGS
1517
1518     # Check whether gcc does not emit a diagnositc for unknow -Wno-*
1519     # options.  This is the case for gcc >= 4.6
1520     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1521     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1522 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1523 #kickerror
1524 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1525     AC_MSG_RESULT($_gcc_silent_wno)
1526
1527     # Note that it is okay to use CFLAGS here because these are just
1528     # warning options and the user should have a chance of overriding
1529     # them.
1530     if test "$USE_MAINTAINER_MODE" = "yes"; then
1531         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1532         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1533         if test x"$_gcc_silent_wno" = xyes ; then
1534           _gcc_wopt=yes
1535         else
1536           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1537           CFLAGS="-Wno-missing-field-initializers"
1538           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1539                             [_gcc_wopt=yes],[_gcc_wopt=no])
1540           AC_MSG_RESULT($_gcc_wopt)
1541         fi
1542         if test x"$_gcc_wopt" = xyes ; then
1543           mycflags="$mycflags -W -Wno-sign-compare"
1544           mycflags="$mycflags -Wno-missing-field-initializers"
1545         fi
1546
1547         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1548         CFLAGS="-Wdeclaration-after-statement"
1549         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1550         AC_MSG_RESULT($_gcc_wopt)
1551         if test x"$_gcc_wopt" = xyes ; then
1552           mycflags="$mycflags -Wdeclaration-after-statement"
1553         fi
1554     else
1555         mycflags="$mycflags -Wall"
1556     fi
1557
1558     if test x"$_gcc_silent_wno" = xyes ; then
1559       _gcc_psign=yes
1560     else
1561       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1562       CFLAGS="-Wno-pointer-sign"
1563       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1564                         [_gcc_psign=yes],[_gcc_psign=no])
1565       AC_MSG_RESULT($_gcc_psign)
1566     fi
1567     if test x"$_gcc_psign" = xyes ; then
1568        mycflags="$mycflags -Wno-pointer-sign"
1569     fi
1570
1571     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1572     CFLAGS="-Wpointer-arith"
1573     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1574     AC_MSG_RESULT($_gcc_psign)
1575     if test x"$_gcc_psign" = xyes ; then
1576        mycflags="$mycflags -Wpointer-arith"
1577     fi
1578
1579     CFLAGS="$mycflags $mycflags_save"
1580     USE_C99_CFLAGS="-std=gnu99"
1581 else
1582     USE_C99_CFLAGS=
1583 fi
1584
1585 AC_SUBST(USE_C99_CFLAGS)
1586
1587
1588 #
1589 # This is handy for debugging so the compiler doesn't rearrange
1590 # things and eliminate variables.
1591 #
1592 AC_ARG_ENABLE(optimization,
1593    AC_HELP_STRING([--disable-optimization],
1594                   [disable compiler optimization]),
1595                   [if test $enableval = no ; then
1596                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1597                    fi])
1598
1599 #
1600 # Add user CFLAGS.
1601 #
1602 CFLAGS="$CFLAGS $CFLAGS_orig"
1603
1604 #
1605 # Decide what to build
1606 #
1607
1608 build_scdaemon_extra=""
1609 if test "$build_scdaemon" = "yes"; then
1610   if test $have_libusb = no; then
1611      build_scdaemon_extra="without internal CCID driver"
1612   fi
1613   if test -n "$build_scdaemon_extra"; then
1614      build_scdaemon_extra="(${build_scdaemon_extra})"
1615   fi
1616 fi
1617
1618
1619 #
1620 # Set variables for use by automake makefiles.
1621 #
1622 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1623 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1624 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1625 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1626 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1627 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1628 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1629 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1630 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1631 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1632 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1633
1634 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1635 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1636 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1637
1638 #
1639 # Set some defines for use gpgconf.
1640 #
1641 if test "$build_gpg" = yes ; then
1642     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1643 fi
1644 if test "$build_gpgsm" = yes ; then
1645     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1646 fi
1647 if test "$build_agent" = yes ; then
1648     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1649 fi
1650 if test "$build_scdaemon" = yes ; then
1651     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1652 fi
1653 if test "$build_dirmngr" = yes ; then
1654     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1655 fi
1656 if test "$build_g13" = yes ; then
1657     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1658 fi
1659
1660
1661 #
1662 # Define Name strings
1663 #
1664 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1665
1666 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1667 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1668
1669 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1670 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1671
1672 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1673 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1674                                         [The displayed name of gpg-agent])
1675
1676 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1677 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1678                                        [The displayed name of scdaemon])
1679
1680 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1681 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1682                                       [The displayed name of dirmngr])
1683
1684 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1685 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1686
1687 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1688 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1689                                       [The displayed name of gpgconf])
1690
1691 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1692
1693 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1694                    [The name of the agent socket])
1695 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1696                    [The name of the agent socket for remote access])
1697 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1698                    [The name of the agent socket for browsers])
1699 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1700                    [The name of the agent socket for ssh])
1701 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1702                    [The name of the dirmngr info envvar])
1703 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1704                    [The name of the SCdaemon socket])
1705 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1706                    [The name of the dirmngr socket])
1707 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1708                    "hkps://hkps.pool.sks-keyservers.net",
1709       [The default keyserver for dirmngr to use, if none is explicitly given])
1710
1711 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1712
1713 if test "$have_w32_system" = yes; then
1714   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "\\\\Software\\\\GNU\\\\GnuPG",
1715                      [The directory part of the W32 registry keys])
1716 fi
1717
1718
1719 #
1720 # Provide information about the build.
1721 #
1722 BUILD_REVISION="mym4_revision"
1723 AC_SUBST(BUILD_REVISION)
1724 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1725                    [GIT commit id revision used to build this package])
1726
1727 changequote(,)dnl
1728 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1729 changequote([,])dnl
1730 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1731 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1732 AC_SUBST(BUILD_VERSION)
1733 AC_SUBST(BUILD_FILEVERSION)
1734
1735 AC_ARG_ENABLE([build-timestamp],
1736   AC_HELP_STRING([--enable-build-timestamp],
1737                  [set an explicit build timestamp for reproducibility.
1738                   (default is the current time in ISO-8601 format)]),
1739      [if test "$enableval" = "yes"; then
1740         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1741       else
1742         BUILD_TIMESTAMP="$enableval"
1743       fi
1744       BUILD_HOSTNAME="$ac_hostname"],
1745      [BUILD_TIMESTAMP="<none>"
1746       BUILD_HOSTNAME="<anon>"])
1747 AC_SUBST(BUILD_TIMESTAMP)
1748 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1749                    [The time this package was configured for a build])
1750 AC_SUBST(BUILD_HOSTNAME)
1751
1752
1753 #
1754 # Print errors here so that they are visible all
1755 # together and the user can acquire them all together.
1756 #
1757 die=no
1758 if test "$have_gpg_error" = "no"; then
1759    die=yes
1760    AC_MSG_NOTICE([[
1761 ***
1762 *** You need libgpg-error to build this program.
1763 **  This library is for example available at
1764 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1765 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1766 ***]])
1767 fi
1768 if test "$have_libgcrypt" = "no"; then
1769    die=yes
1770    AC_MSG_NOTICE([[
1771 ***
1772 *** You need libgcrypt to build this program.
1773 **  This library is for example available at
1774 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1775 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1776 ***]])
1777 fi
1778 if test "$have_libassuan" = "no"; then
1779    die=yes
1780    AC_MSG_NOTICE([[
1781 ***
1782 *** You need libassuan to build this program.
1783 *** This library is for example available at
1784 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1785 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1786 ***]])
1787 fi
1788 if test "$have_ksba" = "no"; then
1789     die=yes
1790     AC_MSG_NOTICE([[
1791 ***
1792 *** You need libksba to build this program.
1793 *** This library is for example available at
1794 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1795 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1796 ***]])
1797 fi
1798 if test "$gnupg_have_ldap" = yes; then
1799   if test "$have_w32ce_system" = yes; then
1800     AC_MSG_NOTICE([[
1801 *** Note that CeGCC might be broken, a package fixing this is:
1802 ***    http://files.kolab.org/local/windows-ce/
1803 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1804 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1805 ***]])
1806    fi
1807 fi
1808 if test "$have_npth" = "no"; then
1809     die=yes
1810     AC_MSG_NOTICE([[
1811 ***
1812 *** It is now required to build with support for the
1813 *** New Portable Threads Library (nPth). Please install this
1814 *** library first.  The library is for example available at
1815 ***   ftp://ftp.gnupg.org/gcrypt/npth/
1816 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1817 ***]])
1818 fi
1819
1820 if test "$require_iconv" = yes; then
1821   if test "$am_func_iconv" != yes; then
1822     die=yes
1823     AC_MSG_NOTICE([[
1824 ***
1825 *** The system does not provide a working iconv function.  Please
1826 *** install a suitable library; for example GNU Libiconv which is
1827 *** available at:
1828 ***   http://ftp.gnu.org/gnu/libiconv/
1829 ***]])
1830   fi
1831 fi
1832
1833 if test "$use_ccid_driver" = yes; then
1834   if test "$have_libusb" != yes; then
1835     die=yes
1836     AC_MSG_NOTICE([[
1837 ***
1838 *** You need libusb to build the internal ccid driver.  Please
1839 *** install a libusb suitable for your system.
1840 ***]])
1841   fi
1842 fi
1843
1844 if test "$die" = "yes"; then
1845     AC_MSG_ERROR([[
1846 ***
1847 *** Required libraries not found. Please consult the above messages
1848 *** and install them before running configure again.
1849 ***]])
1850 fi
1851
1852
1853
1854 AC_CONFIG_FILES([ m4/Makefile
1855 Makefile
1856 po/Makefile.in
1857 common/Makefile
1858 common/w32info-rc.h
1859 kbx/Makefile
1860 g10/Makefile
1861 sm/Makefile
1862 agent/Makefile
1863 scd/Makefile
1864 g13/Makefile
1865 dirmngr/Makefile
1866 tools/gpg-zip
1867 tools/Makefile
1868 doc/Makefile
1869 tests/Makefile
1870 tests/gpgscm/Makefile
1871 tests/openpgp/Makefile
1872 tests/migrations/Makefile
1873 tests/pkits/Makefile
1874 g10/gpg.w32-manifest
1875 ])
1876
1877
1878 AC_OUTPUT
1879
1880
1881 echo "
1882         GnuPG v${VERSION} has been configured as follows:
1883
1884         Revision:  mym4_revision  (mym4_revision_dec)
1885         Platform:  $PRINTABLE_OS_NAME ($host)
1886
1887         OpenPGP:   $build_gpg
1888         S/MIME:    $build_gpgsm
1889         Agent:     $build_agent
1890         Smartcard: $build_scdaemon $build_scdaemon_extra
1891         G13:       $build_g13
1892         Dirmngr:   $build_dirmngr
1893         Gpgtar:    $build_gpgtar
1894         WKS tools: $build_wks_tools
1895
1896         Protect tool:      $show_gnupg_protect_tool_pgm
1897         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1898         Default agent:     $show_gnupg_agent_pgm
1899         Default pinentry:  $show_gnupg_pinentry_pgm
1900         Default scdaemon:  $show_gnupg_scdaemon_pgm
1901         Default dirmngr:   $show_gnupg_dirmngr_pgm
1902
1903         Dirmngr auto start:  $dirmngr_auto_start
1904         Readline support:    $gnupg_cv_have_readline
1905         LDAP support:        $gnupg_have_ldap
1906         TLS support:         $use_tls_library
1907         TOFU support:        $use_tofu
1908         Tor support:         $show_tor_support
1909 "
1910 if test x"$use_regex" != xyes ; then
1911 echo "
1912         Warning: No regular expression support available.
1913                  OpenPGP trust signatures won't work.
1914                  gpg-check-pattern will not be built.
1915 "
1916 fi
1917 if test "x${gpg_config_script_warn}" != x; then
1918 cat <<G10EOF
1919         Warning: Mismatches between the target platform and the
1920                  to be used libraries have been detected for:
1921                   ${gpg_config_script_warn}
1922                  Please check above for more warning messages.
1923
1924 G10EOF
1925 fi