better reporting of bad DNs
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004, 2005, 2006 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
20 # USA.
21
22 # Process this file with autoconf to produce a configure script.
23 AC_PREREQ(2.52)
24 min_automake_version="1.9.3"
25
26 # Remember to change the version number immediately *after* a release.
27 # Set my_issvn to "yes" for non-released code.  Remember to run an
28 # "svn up" and "autogen.sh" right before creating a distribution.
29 m4_define([my_version], [1.9.22])
30 m4_define([my_issvn], [yes])
31
32
33 m4_define([svn_revision], m4_esyscmd([echo -n $((svn info 2>/dev/null \
34             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q}')]))
35 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
36         [gnupg-devel@gnupg.org])
37 # Set development_version to yes if the minor number is odd or you
38 # feel that the default check for a development version is not
39 # sufficient.
40 development_version=yes
41 NEED_GPG_ERROR_VERSION=1.0
42
43 NEED_LIBGCRYPT_API=1
44 NEED_LIBGCRYPT_VERSION=1.1.94
45
46 NEED_LIBASSUAN_VERSION=0.6.10
47
48 NEED_KSBA_VERSION=0.9.13
49
50
51 PACKAGE=$PACKAGE_NAME
52 PACKAGE_GT=${PACKAGE_NAME}2
53 VERSION=$PACKAGE_VERSION
54
55 AC_CONFIG_AUX_DIR(scripts)
56 AC_CONFIG_SRCDIR(sm/gpgsm.c)
57 AM_CONFIG_HEADER(config.h)
58 AC_CANONICAL_TARGET()
59 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
60
61 AC_GNU_SOURCE
62
63 # Some status variables to give feedback at the end of a configure run
64 have_gpg_error=no
65 have_libgcrypt=no 
66 have_libassuan=no
67 have_ksba=no
68 have_pth=no
69
70 GNUPG_BUILD_PROGRAM(gpg, no)
71 GNUPG_BUILD_PROGRAM(gpgsm, yes)
72 GNUPG_BUILD_PROGRAM(agent, yes)
73 GNUPG_BUILD_PROGRAM(scdaemon, yes)
74 GNUPG_BUILD_PROGRAM(symcryptrun, no)
75
76
77 AC_SUBST(PACKAGE)
78 AC_SUBST(PACKAGE_GT)
79 AC_SUBST(VERSION)
80 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
81 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
82                                 [Name of this package for gettext])
83 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
84 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
85                                         [Bug report address])
86 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
87                                        [Required version of Libgcrypt])
88 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
89                                        [Required version of Libksba])
90
91
92
93 # The default is to use the modules from this package and the few
94 # other packages in a standard place; i.e where this package gets
95 # installed.  With these options it is possible to override these
96 # ${prefix} depended values with fixed paths, which can't be replaced
97 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
98 AC_ARG_WITH(agent-pgm,
99     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
100           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
101 AC_SUBST(GNUPG_AGENT_PGM)
102 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
103 show_gnupg_agent_pgm="(default)"
104 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
105
106 AC_ARG_WITH(pinentry-pgm,
107     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
108           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
109 AC_SUBST(GNUPG_PINENTRY_PGM)
110 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
111 show_gnupg_pinentry_pgm="(default)"
112 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
113
114
115 AC_ARG_WITH(scdaemon-pgm,
116     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
117           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
118 AC_SUBST(GNUPG_SCDAEMON_PGM)
119 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
120 show_gnupg_scdaemon_pgm="(default)"
121 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
122
123
124 AC_ARG_WITH(dirmngr-pgm,
125     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
126           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
127 AC_SUBST(GNUPG_DIRMNGR_PGM)
128 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
129 show_gnupg_dirmngr_pgm="(default)"
130 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
131
132 AC_ARG_WITH(protect-tool-pgm,
133     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
134           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
135 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
136 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
137 show_gnupg_protect_tool_pgm="(default)"
138 test -n "$GNUPG_PROTECT_TOOL_PGM" \
139       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
140
141
142
143 # Some folks want to use only the agent form this packet.  Make it
144 # easier for them by providing the configure option
145 # --enable-only-agent.
146 AC_ARG_ENABLE(agent-only,
147     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
148     build_agent_only=$enableval)
149
150
151 # Allow disabling of bzib2 support.
152 # It is defined only after we confirm the library is available later
153 use_bzip2=yes
154 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
155 AC_ARG_ENABLE(bzip2,
156    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
157    use_bzip2=$enableval)
158 AC_MSG_RESULT($use_bzip2)
159
160
161 # Configure option to allow or disallow execution of external
162 # programs, like a photo viewer.
163 AC_MSG_CHECKING([whether to enable external program execution])
164 AC_ARG_ENABLE(exec,
165     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
166     use_exec=$enableval)
167 AC_MSG_RESULT($use_exec)
168 if test "$use_exec" = no ; then
169     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
170 fi
171
172 if test "$use_exec" = yes ; then
173   AC_MSG_CHECKING([whether to enable photo ID viewing])
174   AC_ARG_ENABLE(photo-viewers,
175       [  --disable-photo-viewers disable photo ID viewers],
176       [if test "$enableval" = no ; then
177          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
178       fi],enableval=yes)
179   gnupg_cv_enable_photo_viewers=$enableval
180   AC_MSG_RESULT($enableval)
181
182   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
183     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
184     AC_ARG_WITH(photo-viewer,
185         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
186         [if test "$withval" = yes ; then
187            withval=no
188         elif test "$withval" != no ; then
189            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
190                             [if set, restrict photo-viewer to this])
191         fi],withval=no)
192     AC_MSG_RESULT($withval)
193   fi
194
195   AC_MSG_CHECKING([whether to enable external keyserver helpers])
196   AC_ARG_ENABLE(keyserver-helpers,
197       [  --disable-keyserver-helpers  disable all external keyserver support],
198       [if test "$enableval" = no ; then
199          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
200                   [define to disable keyserver helpers])
201       fi],enableval=yes)
202   gnupg_cv_enable_keyserver_helpers=$enableval
203   AC_MSG_RESULT($enableval)
204
205   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
206     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
207     AC_ARG_ENABLE(ldap,
208     [  --disable-ldap          disable LDAP keyserver interface],
209         try_ldap=$enableval, try_ldap=yes)
210     AC_MSG_RESULT($try_ldap)
211
212     AC_MSG_CHECKING([whether HKP keyserver support is requested])
213     AC_ARG_ENABLE(hkp,
214     [  --disable-hkp           disable HKP keyserver interface],
215         try_hkp=$enableval, try_hkp=yes)
216     AC_MSG_RESULT($try_hkp)
217
218     if test "$try_hkp" = yes ; then
219       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
220     fi
221
222     AC_MSG_CHECKING([whether email keyserver support is requested])
223     AC_ARG_ENABLE(mailto,
224     [  --disable-mailto        disable email keyserver interface],
225         try_mailto=$enableval, try_mailto=yes)
226     AC_MSG_RESULT($try_mailto)
227     fi
228
229     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
230     AC_ARG_ENABLE(keyserver-path,
231         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
232         [if test "$enableval" = no ; then
233          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
234         fi],enableval=yes)
235     AC_MSG_RESULT($enableval)
236   fi
237
238
239 dnl
240 dnl Check for the key/uid cache size.  This can't be zero, but can be
241 dnl pretty small on embedded systems.
242 dnl
243 AC_MSG_CHECKING([for the size of the key and uid cache])
244 AC_ARG_ENABLE(key-cache,
245         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
246
247 if test "$enableval" = "no"; then
248    enableval=5
249 elif test "$enableval" = "yes" || test "$enableval" = ""; then
250    enableval=4096
251 fi
252
253 changequote(,)dnl
254 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
255 changequote([,])dnl
256
257 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
258    AC_MSG_ERROR([invalid key-cache size])
259 fi
260
261 AC_MSG_RESULT($key_cache_size)
262 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
263
264
265
266 dnl
267 dnl Check whether we want to use Linux capabilities
268 dnl
269 AC_MSG_CHECKING([whether use of capabilities is requested])
270 AC_ARG_WITH(capabilities,
271     [  --with-capabilities     use linux capabilities [default=no]],
272 [use_capabilities="$withval"],[use_capabilities=no])
273 AC_MSG_RESULT($use_capabilities)
274
275
276 AH_BOTTOM([
277 /* Some global constants. */
278 #ifdef HAVE_DRIVE_LETTERS
279 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
280 #elif defined(__VMS)
281 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
282 #else
283 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
284 #endif 
285 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
286
287 /* Tell libgcrypt not to use its own libgpg-error implementation. */
288 #define USE_LIBGPG_ERROR 1
289
290 /* This is the major version number of GnuPG so that
291    source included files can test for this.  Note, that\
292    we use 2 here even for GnuPG 1.9.x. */
293 #define GNUPG_MAJOR_VERSION 2
294
295 /* Now to separate file name parts.
296    Please note that the string version must not contain more
297    than one character because the code assumes strlen()==1 */
298 #ifdef HAVE_DOSISH_SYSTEM
299 #define DIRSEP_C '\\'
300 #define DIRSEP_S "\\"
301 #define EXTSEP_C '.'
302 #define EXTSEP_S "."
303 #define PATHSEP_C ';'
304 #define PATHSEP_S ";"
305 #define EXEEXT_S ".exe"
306 #else
307 #define DIRSEP_C '/'
308 #define DIRSEP_S "/"
309 #define EXTSEP_C '.'
310 #define EXTSEP_S "."
311 #define PATHSEP_C ':'
312 #define PATHSEP_S ":"
313 #define EXEEXT_S ""
314 #endif
315
316 /* This is the same as VERSION, but should be overridden if the
317    platform cannot handle things like dots '.' in filenames. Set
318    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
319    uses for dots and dashes. */
320 #define SAFE_VERSION VERSION
321 #define SAFE_VERSION_DOT  '.'
322 #define SAFE_VERSION_DASH '-'
323
324 /* For some systems (DOS currently), we hardcode the path here.  For
325    POSIX systems the values are constructed by the Makefiles, so that
326    the values may be overridden by the make invocations; this is to
327    comply with the GNU coding standards. */
328 #ifdef HAVE_DRIVE_LETTERS
329 #define GNUPG_BINDIR      "c:\\gnupg"
330 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
331 #define GNUPG_LIBDIR      "c:\\gnupg"
332 #define GNUPG_DATADIR     "c:\\gnupg"
333 #endif
334
335 /* Setup the hardwired names of modules. */
336 #ifndef GNUPG_DEFAULT_AGENT
337 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
338 #endif
339 #ifndef GNUPG_DEFAULT_PINENTRY
340 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
341 #endif
342 #ifndef GNUPG_DEFAULT_SCDAEMON
343 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
344 #endif
345 #ifndef GNUPG_DEFAULT_DIRMNGR
346 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
347 #endif
348 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
349 #define GNUPG_DEFAULT_PROTECT_TOOL \
350                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
351 #endif
352
353
354 /* Derive some other constants. */
355 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
356 #define EXEC_TEMPFILE_ONLY
357 #endif
358
359 /* Temporary hacks to avoid requring a libgpg-error update. */
360 #if !HAVE_DECL_GPG_ERR_LOCKED
361 #define GPG_ERR_LOCKED  173
362 #endif
363
364 ])
365
366 AM_MAINTAINER_MODE
367
368 # Checks for programs.
369 AC_PROG_MAKE_SET
370 AM_SANITY_CHECK
371 missing_dir=`cd $ac_aux_dir && pwd`
372 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
373 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
374 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
375 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
376 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
377 AC_PROG_AWK
378 AC_PROG_CC
379 AC_PROG_CPP
380 AC_PROG_INSTALL
381 AC_PROG_LN_S
382 AC_PROG_MAKE_SET
383 AC_PROG_RANLIB
384 AC_CHECK_TOOL(AR, ar, :)
385 AC_PATH_PROG(PERL,"perl")
386 AC_ISC_POSIX
387 gl_EARLY
388 AC_SYS_LARGEFILE
389 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
390 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
391 GNUPG_CHECK_FAQPROG
392 GNUPG_CHECK_DOCBOOK_TO_TEXI
393
394
395 try_gettext=yes
396 have_dosish_system=no
397 have_w32_system=no
398 case "${host}" in
399     *-mingw32*)
400         # special stuff for Windoze NT
401         ac_cv_have_dev_random=no
402         AC_DEFINE(USE_ONLY_8DOT3,1,
403                   [set this to limit filenames to the 8.3 format])
404         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
405                   [defined if we must run on a stupid file system])
406         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
407                   [because the Unix gettext has too much overhead on
408                    MingW32 systems and these systems lack Posix functions,
409                    we use a simplified version of gettext])
410         have_dosish_system=yes
411         have_w32_system=yes
412         try_gettext="no"
413         ;;
414     i?86-emx-os2 | i?86-*-os2*emx )
415         # OS/2 with the EMX environment
416         ac_cv_have_dev_random=no
417         AC_DEFINE(HAVE_DRIVE_LETTERS)
418         have_dosish_system=yes
419         try_gettext="no"
420         ;;
421
422     i?86-*-msdosdjgpp*)
423         # DOS with the DJGPP environment
424         ac_cv_have_dev_random=no
425         AC_DEFINE(HAVE_DRIVE_LETTERS)
426         have_dosish_system=yes
427         try_gettext="no"
428         ;;
429
430     *-*-freebsd*)
431        # FreeBSD
432        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
433        LDFLAGS="$LDFLAGS -L/usr/local/lib"
434        ;;
435
436     *-*-hpux*)
437         if test -z "$GCC" ; then
438             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
439         fi
440         ;;
441     *-dec-osf4*)
442         if test -z "$GCC" ; then
443             # Suppress all warnings
444             # to get rid of the unsigned/signed char mismatch warnings.
445             CFLAGS="$CFLAGS -w"
446         fi
447         ;;
448     *-dec-osf5*)
449         if test -z "$GCC" ; then
450             # Use the newer compiler `-msg_disable ptrmismatch' to
451             # get rid of the unsigned/signed char mismatch warnings.
452             # Using this may hide other pointer mismatch warnings, but
453             # it at least lets other warning classes through
454             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
455         fi
456         ;;
457     m68k-atari-mint)
458         ;;
459     *)
460        ;;
461 esac
462
463 if test "$have_dosish_system" = yes; then
464    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
465              [Defined if we run on some of the PCDOS like systems 
466               (DOS, Windoze. OS/2) with special properties like
467               no file modes])
468 fi
469 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
470
471 if test "$have_w32_system" = yes; then
472    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
473 fi
474 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
475
476 # These need to go after AC_PROG_CC so that $EXEEXT is defined
477 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
478
479
480 #
481 # Checks for libraries.
482 #
483
484
485 #
486 # libgpg-error is a library with error codes shared between GnuPG
487 # related projects.
488 #
489 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
490                   have_gpg_error=yes,have_gpg_error=no)
491 _tmp_gpg_error_save_cflags="$CFLAGS"
492 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
493 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
494 CFLAGS="${_tmp_gpg_error_save_cflags}"
495
496
497 #
498 # Libgcrypt is our generic crypto library
499 #
500 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
501         have_libgcrypt=yes,have_libgcrypt=no)
502
503
504 #
505 # libassuan is used for IPC
506 #
507 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
508                   have_libassuan=yes,have_libassuan=no)
509
510
511 #
512 # libksba is our X.509 support library
513 #
514 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
515 # fixme: Remove the following test and require newer libksba instead.
516 _ksba_save_libs=$LIBS
517 LIBS=$KSBA_LIBS
518 AC_CHECK_FUNCS(ksba_dn_teststr)
519 LIBS=$_ksba_save_libs
520
521 #
522 # libusb allows us to use the integrated CCID smartcard reader driver.
523 #
524 AC_CHECK_LIB(usb, usb_bulk_write,
525               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
526                 AC_DEFINE(HAVE_LIBUSB,1,
527                          [defined if libusb is available])
528              ])
529 AC_SUBST(LIBUSB_LIBS)
530 AC_CHECK_FUNCS(usb_create_match)
531
532 #
533 # Check wether it is necessary to link against libdl.
534 #
535 LIBS=""
536 AC_SEARCH_LIBS(dlopen, c dl,,,)
537 DL_LIBS=$LIBS
538 AC_SUBST(DL_LIBS)
539
540 #
541 # Checks for symcryptrun:
542 #
543
544 # libutil has openpty() and login_tty().
545 AC_CHECK_LIB(util, openpty,
546               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
547                 AC_DEFINE(HAVE_LIBUTIL,1,
548                          [defined if libutil is available])
549              ])
550 AC_SUBST(LIBUTIL_LIBS)
551
552 # shred is used to clean temporary plain text files.
553 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
554 AC_DEFINE_UNQUOTED(SHRED,
555         "${SHRED}", [defines the filename of the shred program])
556
557
558 #
559 # Check whether the (highly desirable) GNU Pth library is available
560 # Note, that we include a Pth emulation for W32.
561 #
562 AC_ARG_WITH(pth-prefix,
563             AC_HELP_STRING([--with-pth-prefix=PFX],
564                            [prefix where GNU Pth is installed (optional)]),
565      pth_config_prefix="$withval", pth_config_prefix="")
566 if test x$pth_config_prefix != x ; then
567    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
568 fi
569 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
570 if test "$have_w32_system" = no; then
571  if test "$PTH_CONFIG" = "no"; then
572     AC_MSG_WARN([[
573 ***
574 *** To support concurrent access to the gpg-agent and the SCdaemon
575 *** we need the support of the GNU Portable Threads Library.
576 *** Download it from ftp://ftp.gnu.org/gnu/pth/
577 *** On a Debian GNU/Linux system you might want to try 
578 ***   apt-get install libpth-dev
579 ***]])
580  else
581   GNUPG_PTH_VERSION_CHECK(1.3.7)
582   if test $have_pth = yes; then      
583      PTH_CFLAGS=`$PTH_CONFIG --cflags`
584      PTH_LIBS=`$PTH_CONFIG --ldflags`
585      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs --all`"
586      AC_DEFINE(USE_GNU_PTH, 1,
587               [Defined if the GNU Portable Thread Library should be used])
588      AC_DEFINE(HAVE_PTH, 1,
589               [Defined if the GNU Pth is available])
590   fi
591  fi
592 else 
593  have_pth=yes
594  PTH_CFLAGS=""
595  PTH_LIBS=""
596  AC_DEFINE(USE_GNU_PTH, 1)
597  AC_DEFINE(HAVE_PTH, 1)
598 fi
599 AC_SUBST(PTH_CFLAGS)
600 AC_SUBST(PTH_LIBS)
601
602
603 dnl Must check for network library requirements before doing link tests
604 dnl for ldap, for example. If ldap libs are static (or dynamic and without
605 dnl ELF runtime link paths), then link will fail and LDAP support won't
606 dnl be detected.
607
608 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
609         [NETLIBS="-lnsl $NETLIBS"]))
610 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
611         [NETLIBS="-lsocket $NETLIBS"]))
612
613 dnl Now try for the resolver functions so we can use DNS SRV
614
615 AC_ARG_ENABLE(dns-srv,
616    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
617    use_dns_srv=$enableval,use_dns_srv=yes)
618
619 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
620   _srv_save_libs=$LIBS
621   LIBS=""
622   # the double underscore thing is a glibc-ism?
623   AC_SEARCH_LIBS(res_query,resolv bind,,
624                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
625   AC_SEARCH_LIBS(dn_expand,resolv bind,,
626                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
627   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
628                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
629
630   if test x"$use_dns_srv" = xyes ; then
631      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
632      SRVLIBS=$LIBS
633   else
634      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
635   fi
636   LIBS=$_srv_save_libs
637 fi
638
639 AC_SUBST(SRVLIBS)
640
641 # Try and link a LDAP test program to weed out unusable LDAP
642 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
643 # general is terrible with creating weird dependencies.  If all else
644 # fails, the user can play guess-the-dependency by using something
645 # like ./configure LDAPLIBS="-Lfoo -lbar"
646
647 if test "$try_ldap" = yes ; then
648   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
649     _ldap_save_libs=$LIBS
650     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
651
652     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
653     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
654                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
655     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
656
657     if test $gnupg_cv_func_ldap_init = no; then
658       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
659       AC_TRY_LINK([#include <lber.h>
660 #include <ldap.h>],[ldap_open("foobar",1234);],
661          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
662       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
663     fi
664
665     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
666        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
667     fi
668
669     if test "$gnupg_cv_func_ldap_init" = yes || \
670         test "$gnupg_cv_func_ldaplber_init" = yes ; then
671        LDAPLIBS=$MY_LDAPLIBS
672        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
673
674        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
675
676        if test "$gnupg_cv_func_ldap_init" = yes ; then
677           AC_TRY_LINK([#include <ldap.h>],
678              [ldap_get_option((void *)0,0,(void *)0);],
679              [gnupg_cv_func_ldap_get_option=yes],
680              [gnupg_cv_func_ldap_get_option=no])
681         else
682           AC_TRY_LINK([#include <lber.h>
683 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
684              [gnupg_cv_func_ldap_get_option=yes],
685              [gnupg_cv_func_ldap_get_option=no])
686        fi
687
688        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
689
690        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
691           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
692        else
693           AC_MSG_CHECKING([whether LDAP supports ld_errno])
694
695           if test "$gnupg_cv_func_ldap_init" = yes ; then
696             AC_TRY_COMPILE([#include <ldap.h>],
697                [LDAP *ldap; ldap->ld_errno;],
698                [gnupg_cv_func_ldap_ld_errno=yes],
699                [gnupg_cv_func_ldap_ld_errno=no])
700            else
701             AC_TRY_LINK([#include <lber.h>
702 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
703                [gnupg_cv_func_ldap_ld_errno=yes],
704                [gnupg_cv_func_ldap_ld_errno=no])
705           fi
706
707           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
708
709           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
710              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
711           fi
712        fi
713     fi
714
715     LIBS=$_ldap_save_libs
716
717     if test "$GPGKEYS_LDAP" != "" ; then break; fi
718   done
719 fi
720
721 AC_SUBST(GPGKEYS_LDAP)
722 AC_SUBST(LDAPLIBS)
723
724
725 # Check for curl.  We fake the curl API if libcurl isn't installed.
726
727 # fixme: need to add this
728 #LIBCURL_CHECK_CONFIG([yes],,,[fake_curl=yes])
729 #AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
730 AM_CONDITIONAL(FAKE_CURL,1)
731
732 # Generic, for us, means curl
733
734 if test x"$try_generic" = xyes ; then
735    AC_SUBST(GPGKEYS_CURL,"gpgkeys_curl$EXEEXT")
736 fi
737
738 dnl This isn't necessarily sendmail itself, but anything that gives a
739 dnl sendmail-ish interface to the outside world.  That includes qmail,
740 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
741
742 if test "$try_mailto" = yes ; then
743   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
744
745   if test "$with_mailprog" = yes ; then
746     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
747     if test "$ac_cv_path_SENDMAIL" ; then
748       GPGKEYS_MAILTO="gpgkeys_mailto"
749     fi
750   elif test "$with_mailprog" != no ; then
751     AC_MSG_CHECKING([for a mail transport program])
752     AC_SUBST(SENDMAIL,$with_mailprog)
753     AC_MSG_RESULT($with_mailprog)
754     GPGKEYS_MAILTO="gpgkeys_mailto"
755   fi
756 fi
757
758 AC_SUBST(GPGKEYS_MAILTO)
759
760 case "${host}" in
761     *-mingw32*)
762         PRINTABLE_OS_NAME="MingW32"
763         ;;
764     *-*-cygwin*)
765         PRINTABLE_OS_NAME="Cygwin"
766         ;;
767     i?86-emx-os2 | i?86-*-os2*emx )
768         PRINTABLE_OS_NAME="OS/2"
769         ;;
770     i?86-*-msdosdjgpp*)
771         PRINTABLE_OS_NAME="MSDOS/DJGPP"
772         try_dynload=no
773         ;;
774     *-linux*)
775         PRINTABLE_OS_NAME="GNU/Linux"
776         ;;
777     *)
778         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
779         ;;
780 esac
781 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
782                    [A human readable text with the name of the OS])
783
784
785 AM_GNU_GETTEXT_VERSION(0.14.1)
786 if test "$try_gettext" = yes; then
787   AM_GNU_GETTEXT(,[need-ngettext])
788
789   # gettext requires some extra checks.  These really should be part of
790   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
791   # function checks to here.
792
793   AC_CHECK_FUNCS(strchr)
794 else
795   USE_NLS=no
796   USE_INCLUDED_LIBINTL=no
797   BUILD_INCLUDED_LIBINTL=no
798   AC_SUBST(USE_NLS)
799   AC_SUBST(USE_INCLUDED_LIBINTL)
800   AC_SUBST(BUILD_INCLUDED_LIBINTL)
801 fi
802
803 # Checks for header files.
804 AC_HEADER_STDC
805 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
806
807 # Checks for typedefs, structures, and compiler characteristics.
808 AC_C_CONST
809 AC_C_INLINE
810 AC_TYPE_SIZE_T
811 AC_TYPE_SIGNAL
812 AC_DECL_SYS_SIGLIST
813
814 GNUPG_CHECK_ENDIAN
815
816 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
817 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
818 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
819 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
820 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
821
822 AC_CHECK_SIZEOF(unsigned short)
823 AC_CHECK_SIZEOF(unsigned int)
824 AC_CHECK_SIZEOF(unsigned long)
825 AC_CHECK_SIZEOF(unsigned long long)
826 # Ensure that we have UINT64_C before we bother to check for uint64_t
827 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
828 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
829    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
830 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
831 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
832    AC_CHECK_SIZEOF(uint64_t)
833 fi
834  
835
836
837
838 if test "$ac_cv_sizeof_unsigned_short" = "0" \
839    || test "$ac_cv_sizeof_unsigned_int" = "0" \
840    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
841     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
842 fi
843
844 dnl Do we have any 64-bit data types?
845 if test "$ac_cv_sizeof_unsigned_int" != "8" \
846    && test "$ac_cv_sizeof_unsigned_long" != "8" \
847    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
848    && test "$ac_cv_sizeof_uint64_t" != "8"; then
849     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
850 else
851   if test x"$use_sha512" = xyes ; then
852      AC_SUBST(SHA512_O,sha512.o)
853      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
854   fi
855 fi
856
857 # fixme: do we really need this - it should be encapsulated in libassuan
858 GNUPG_SYS_SO_PEERCRED
859
860 # Checks for library functions.
861 AC_FUNC_FSEEKO
862 AC_FUNC_VPRINTF
863 AC_FUNC_FORK
864 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
865 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
866 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
867 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
868 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
869 AC_CHECK_FUNCS(fseeko ftello ttyname isascii)
870
871 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
872
873 # gnulib checks
874 gl_SOURCE_BASE(gl)
875 gl_M4_BASE(gl/m4)
876 gl_MODULES(setenv strsep mkdtemp vasprintf xsize)
877 gl_INIT
878
879 # These are needed by libjnlib - fixme: we should have macros for them
880 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
881 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
882 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
883
884
885 #
886 # check for gethrtime and run a testprogram to see whether
887 # it is broken.  It has been reported that some Solaris and HP UX systems 
888 # raise an SIGILL
889 #
890 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
891 #
892 AC_CACHE_CHECK([for gethrtime], 
893                [gnupg_cv_func_gethrtime],
894                [AC_TRY_LINK([#include <sys/times.h>],[
895                    hrtime_t tv;
896                    tv = gethrtime();
897                  ],
898                  [gnupg_cv_func_gethrtime=yes],
899                  [gnupg_cv_func_gethrtime=no])
900                ])
901 if test $gnupg_cv_func_gethrtime = yes; then
902      AC_DEFINE([HAVE_GETHRTIME], 1,
903                [Define if you have the `gethrtime(2)' function.])
904      AC_CACHE_CHECK([whether gethrtime is broken], 
905                [gnupg_cv_func_broken_gethrtime],
906                [AC_TRY_RUN([
907                    #include <sys/times.h>
908                    int main () {
909                    hrtime_t tv;
910                    tv = gethrtime(); 
911                  }
912                  ],
913                  [gnupg_cv_func_broken_gethrtime=no],
914                  [gnupg_cv_func_broken_gethrtime=yes],
915                  [gnupg_cv_func_broken_gethrtime=assume-no])
916                 ])
917     if test $gnupg_cv_func_broken_gethrtime = yes; then
918       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
919       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
920     fi
921 fi
922      
923
924 GNUPG_CHECK_MLOCK
925 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
926
927 dnl
928 dnl Check whether we can use Linux capabilities as requested
929 dnl
930 #  fixme: Still required?
931 #
932 if test "$use_capabilities" = "yes" ; then
933 use_capabilities=no
934 AC_CHECK_HEADERS(sys/capability.h)
935 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
936   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
937   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
938      AC_DEFINE(USE_CAPABILITIES,1,
939                [define if capabilities should be used])
940      AC_SUBST(CAPLIBS,"-lcap")
941      use_capabilities=yes
942   fi
943 fi
944 if test "$use_capabilities" = "no" ; then
945     AC_MSG_WARN([[
946 ***
947 *** The use of capabilities on this system is not possible.
948 *** You need a recent Linux kernel and some patches:
949 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
950 ***   fcap-module-990613.tar.gz     (kernel module)
951 ***   libcap-1.92.tar.gz            (user mode library and utilities)
952 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
953 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
954 ***]])
955 fi
956 fi
957
958
959 # Sanity check regex.  Tests adapted from mutt.
960
961 AC_MSG_CHECKING([whether regular expression support is requested])
962 AC_ARG_ENABLE(regex,
963 [  --disable-regex         do not handle regular expressions in trust sigs],
964      use_regex=$enableval, use_regex=yes)
965 AC_MSG_RESULT($use_regex)
966
967 if test "$use_regex" = yes ; then
968   AC_MSG_CHECKING([whether the included regex lib is requested])
969   AC_ARG_WITH(included-regex,
970       [  --with-included-regex   use the included GNU regex library],
971       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
972   AC_MSG_RESULT($gnupg_cv_included_regex)
973
974   if test $gnupg_cv_included_regex = no ; then
975      # Does the system have regex functions at all?
976      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
977                            gnupg_cv_included_regex=yes)
978   fi
979
980   if test $gnupg_cv_included_regex = no ; then
981      AC_CACHE_CHECK([whether your system's regexp library is broken],
982        [gnupg_cv_regex_broken],
983        AC_TRY_RUN([
984 #include <unistd.h>
985 #include <regex.h>
986 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
987        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
988
989      if test $gnupg_cv_regex_broken = yes ; then
990       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
991       gnupg_cv_included_regex=yes
992      fi
993   fi
994
995   if test $gnupg_cv_included_regex = yes; then
996      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
997      AC_SUBST(REGEX_O,regex.o)
998   fi
999 else
1000
1001   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
1002 fi
1003
1004 #
1005 # Do we have zlib? Must do it here because Solaris failed
1006 # when compiling a conftest (due to the "-lz" from LIBS).
1007 # Note that we combine zlib and bzlib2 in ZLIBS.
1008 #
1009 _cppflags="${CPPFLAGS}"
1010 _ldflags="${LDFLAGS}"
1011 AC_ARG_WITH(zlib,
1012   [  --with-zlib=DIR         use libz in DIR],[
1013     if test -d "$withval"; then
1014       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1015       LDFLAGS="${LDFLAGS} -L$withval/lib"
1016     fi
1017   ])
1018
1019 AC_CHECK_HEADER(zlib.h,
1020       AC_CHECK_LIB(z, deflateInit2_,
1021        ZLIBS="-lz",
1022        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1023        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1024
1025 #
1026 # Check whether we can support bzip2
1027
1028 if test "$use_bzip2" = yes ; then
1029   _cppflags="${CPPFLAGS}"
1030   _ldflags="${LDFLAGS}"
1031   AC_ARG_WITH(bzip2,
1032      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1033       [
1034       if test -d "$withval" ; then
1035         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1036         LDFLAGS="${LDFLAGS} -L$withval/lib"
1037       fi
1038       ],withval="")
1039
1040   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1041   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1042   # woefully out of date.
1043   if test "$withval" != no ; then
1044      AC_CHECK_HEADER(bzlib.h,
1045         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1046           [
1047           have_bz2=yes
1048           ZLIBS="$ZLIBS -lbz2"
1049           AC_DEFINE(HAVE_BZIP2,1,
1050                   [Defined if the bz2 compression library is available])
1051           ],
1052           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1053           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1054   fi
1055 fi
1056 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1057 AC_SUBST(ZLIBS)
1058
1059
1060 # See wether we want to run the long test suite.
1061 AC_ARG_WITH(pkits-tests,
1062     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
1063     [run_pkits_tests=$withval], [run_pkits_tests=no])
1064 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
1065
1066
1067 # Allow users to append something to the version string without
1068 # flagging it as development version.  The user version parts is
1069 # considered everything after a dash. 
1070 if test "$development_version" != yes; then
1071   changequote(,)dnl
1072   tmp_pat='[a-zA-Z]'
1073   changequote([,])dnl
1074   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1075     development_version=yes
1076   fi
1077 fi
1078 if test "$development_version" = yes; then
1079     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1080             [Defined if this is not a regular release])
1081 fi
1082
1083 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1084
1085 GNUPG_CHECK_GNUMAKE
1086
1087 # Add some extra libs here so that previous tests don't fail for
1088 # mysterious reasons - the final link step should bail out. 
1089 if test "$have_w32_system" = yes; then
1090    W32LIBS="-lwsock32"
1091 fi
1092
1093
1094 if test "$GCC" = yes; then
1095     if test "$USE_MAINTAINER_MODE" = "yes"; then
1096         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1097         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security"
1098     else
1099         CFLAGS="$CFLAGS -Wall"
1100     fi
1101 fi
1102
1103 #
1104 # This is handy for debugging so the compiler doesn't rearrange
1105 # things and eliminate variables.
1106 #
1107 AC_ARG_ENABLE(optimization,
1108    AC_HELP_STRING([--disable-optimization],
1109                   [disable compiler optimization]),
1110                   [if test $enableval = no ; then
1111                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1112                    fi])
1113
1114
1115
1116
1117 AC_SUBST(NETLIBS)
1118 AC_SUBST(W32LIBS)
1119
1120
1121 # We use jnlib, so tell other modules about it
1122 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1123           [Defined if jnlib style logging functions are available])
1124
1125 # For W32 we need to use our Pth emulation code
1126 if test "$have_w32_system" = yes; then
1127   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1128 fi
1129
1130
1131 #
1132 # Decide what to build
1133 #
1134 missing_pth=no
1135 if test $have_ksba = no; then
1136   build_gpgsm=no
1137   build_scdaemon=no
1138 fi
1139
1140 build_agent_threaded=""
1141 if test "$build_agent" = "yes"; then
1142   if test $have_pth = no; then
1143      build_agent_threaded="(not multi-threaded)"
1144      missing_pth=yes
1145   fi
1146 fi
1147
1148 build_scdaemon_extra=""
1149 if test "$build_scdaemon" = "yes"; then
1150   tmp=""
1151   if test $have_pth = no; then
1152      build_scdaemon_extra="not multi-threaded"
1153      tmp=", "
1154      missing_pth=yes
1155   fi
1156   if test -n "$build_scdaemon_extra"; then
1157      build_scdaemon_extra="(${build_scdaemon_extra})"
1158   fi
1159 fi
1160
1161
1162 if test "$build_agent_only" = "yes" ; then
1163   build_gpg=no
1164   build_gpgsm=no
1165   build_scdaemon=no
1166 fi
1167
1168
1169 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1170 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1171 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1172 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1173 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1174
1175
1176
1177 #
1178 # Print errors here so that they are visible all
1179 # together and the user can acquire them all together.
1180 #
1181 die=no
1182 if test "$have_gpg_error" = "no"; then
1183    die=yes
1184    AC_MSG_NOTICE([[
1185 ***  
1186 *** You need libgpg-error to build this program.
1187 **  This library is for example available at
1188 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1189 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1190 ***]])
1191 fi
1192 if test "$have_libgcrypt" = "no"; then
1193    die=yes
1194    AC_MSG_NOTICE([[
1195 ***  
1196 *** You need libgcrypt to build this program.
1197 **  This library is for example available at
1198 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1199 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1200 ***]])
1201 fi
1202 if test "$have_libassuan" = "no"; then
1203    die=yes
1204    AC_MSG_NOTICE([[
1205 ***
1206 *** You need libassuan to build this program.
1207 *** This library is for example available at
1208 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1209 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1210 ***]])
1211 fi
1212 if test "$have_ksba" = "no"; then
1213     AC_MSG_NOTICE([[
1214 ***
1215 *** You need libksba to build this program.
1216 *** This library is for example available at
1217 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1218 *** (at least version $NEED_KSBA_VERSION is required).
1219 ***]])
1220 fi
1221 if test "$missing_pth" = "yes"; then
1222     AC_MSG_NOTICE([[
1223 ***
1224 *** It is now required to build with support for the
1225 *** GNU Portable Threads Library (Pth). Please install this
1226 *** library first.  The library is for example available at
1227 ***   ftp://ftp.gnu.org/gnu/pth/
1228 *** On a Debian GNU/Linux system you can install it using 
1229 ***   apt-get install libpth-dev
1230 ***]])
1231    die=yes
1232 fi
1233
1234 if test "$die" = "yes"; then
1235     AC_MSG_ERROR([[
1236 ***
1237 *** Required libraries not found. Please consult the above messages
1238 *** and install them before running configure again.
1239 ***]])
1240 fi
1241
1242
1243
1244 AC_CONFIG_FILES([ m4/Makefile 
1245 Makefile
1246 po/Makefile.in
1247 intl/Makefile
1248 gl/Makefile
1249 jnlib/Makefile
1250 common/Makefile
1251 kbx/Makefile
1252 g10/Makefile
1253 keyserver/Makefile
1254 sm/Makefile
1255 agent/Makefile
1256 scd/Makefile
1257 tools/Makefile
1258 doc/Makefile
1259 tests/Makefile
1260 ])
1261 AC_OUTPUT
1262
1263 #tests/pkits/Makefile
1264
1265
1266
1267
1268 echo "
1269         GnuPG v${VERSION} has been configured as follows:
1270         
1271         Platform:  $PRINTABLE_OS_NAME ($host)
1272
1273         OpenPGP:   $build_gpg
1274         S/MIME:    $build_gpgsm
1275         Agent:     $build_agent $build_agent_threaded
1276         Smartcard: $build_scdaemon $build_scdaemon_extra
1277
1278         Protect tool:      $show_gnupg_protect_tool_pgm
1279         Default agent:     $show_gnupg_agent_pgm
1280         Default pinentry:  $show_gnupg_pinentry_pgm
1281         Default scdaemon:  $show_gnupg_scdaemon_pgm
1282         Default dirmngr:   $show_gnupg_dirmngr_pgm
1283
1284         PKITS based tests: $run_pkits_tests
1285 "
1286