Merge branch 'STABLE-BRANCH-2-2' into master
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998-2017 Free Software Foundation, Inc.
3 # Copyright (C) 1998-2017 Werner Koch
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <https://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.14"
23
24 # To build a release you need to create a tag with the version number
25 # (git tag -s gnupg-2.n.m) and run "./autogen.sh --force".  Please
26 # bump the version number immediately *after* the release and do
27 # another commit and push so that the git magic is able to work.
28 m4_define([mym4_package],[gnupg])
29 m4_define([mym4_major], [2])
30 m4_define([mym4_minor], [3])
31 m4_define([mym4_micro], [0])
32
33 # To start a new development series, i.e a new major or minor number
34 # you need to mark an arbitrary commit before the first beta release
35 # with an annotated tag.  For example the 2.1 branch starts off with
36 # the tag "gnupg-2.1-base".  This is used as the base for counting
37 # beta numbers before the first release of a series.
38
39 # Below is m4 magic to extract and compute the git revision number,
40 # the decimalized short revision number, a beta version string and a
41 # flag indicating a development version (mym4_isbeta).  Note that the
42 # m4 processing is done by autoconf and not during the configure run.
43 m4_define([mym4_verslist], m4_split(m4_esyscmd([./autogen.sh --find-version] \
44                            mym4_package mym4_major mym4_minor mym4_micro),[:]))
45 m4_define([mym4_isbeta],       m4_argn(2, mym4_verslist))
46 m4_define([mym4_version],      m4_argn(4, mym4_verslist))
47 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
48 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
49 m4_esyscmd([echo ]mym4_version[>VERSION])
50 AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
51
52 # When changing the SWDB tag please also adjust the hard coded tags in
53 # build-aux/speedo.mk and Makefile.am
54 AC_DEFINE_UNQUOTED(GNUPG_SWDB_TAG, "gnupg22", [swdb tag for this branch])
55
56 NEED_GPG_ERROR_VERSION=1.24
57
58 NEED_LIBGCRYPT_API=1
59 NEED_LIBGCRYPT_VERSION=1.7.0
60
61 NEED_LIBASSUAN_API=2
62 NEED_LIBASSUAN_VERSION=2.4.3
63
64 NEED_KSBA_API=1
65 NEED_KSBA_VERSION=1.3.4
66
67 NEED_NTBTLS_API=1
68 NEED_NTBTLS_VERSION=0.1.0
69
70 NEED_NPTH_API=1
71 NEED_NPTH_VERSION=1.2
72
73
74 NEED_GNUTLS_VERSION=3.0
75
76 NEED_SQLITE_VERSION=3.7
77
78 development_version=mym4_isbeta
79 PACKAGE=$PACKAGE_NAME
80 PACKAGE_GT=${PACKAGE_NAME}2
81 VERSION=$PACKAGE_VERSION
82
83 AC_CONFIG_AUX_DIR([build-aux])
84 AC_CONFIG_SRCDIR([sm/gpgsm.c])
85 AC_CONFIG_HEADER([config.h])
86 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
87 AC_CANONICAL_HOST
88 AB_INIT
89
90 AC_GNU_SOURCE
91
92
93 # Some status variables.
94 have_gpg_error=no
95 have_libgcrypt=no
96 have_libassuan=no
97 have_ksba=no
98 have_ntbtls=no
99 have_gnutls=no
100 have_sqlite=no
101 have_npth=no
102 have_libusb=no
103 have_system_resolver=no
104 gnupg_have_ldap="n/a"
105
106 use_zip=yes
107 use_bzip2=yes
108 use_exec=yes
109 use_trust_models=yes
110 use_tofu=yes
111 use_libdns=yes
112 card_support=yes
113 use_ccid_driver=auto
114 dirmngr_auto_start=yes
115 use_tls_library=no
116 large_secmem=no
117 show_tor_support=no
118
119 # gpg is a required part and can't be disabled anymore.
120 build_gpg=yes
121 GNUPG_BUILD_PROGRAM(gpgsm, yes)
122 # The agent is a required part and can't be disabled anymore.
123 build_agent=yes
124 GNUPG_BUILD_PROGRAM(scdaemon, yes)
125 GNUPG_BUILD_PROGRAM(g13, no)
126 GNUPG_BUILD_PROGRAM(dirmngr, yes)
127 GNUPG_BUILD_PROGRAM(doc, yes)
128 GNUPG_BUILD_PROGRAM(symcryptrun, no)
129 # We use gpgtar to unpack test data, hence we always build it.  If the
130 # user opts out, we simply don't install it.
131 GNUPG_BUILD_PROGRAM(gpgtar, yes)
132 GNUPG_BUILD_PROGRAM(wks-tools, no)
133
134 AC_SUBST(PACKAGE)
135 AC_SUBST(PACKAGE_GT)
136 AC_SUBST(VERSION)
137 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
138 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
139                                 [Name of this package for gettext])
140 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
141 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
142                                         [Bug report address])
143 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
144                                        [Required version of Libgcrypt])
145 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
146                                        [Required version of Libksba])
147 AC_DEFINE_UNQUOTED(NEED_NTBTLS_VERSION, "$NEED_NTBTLS_VERSION",
148                                        [Required version of NTBTLS])
149
150
151
152 # The default is to use the modules from this package and the few
153 # other packages in a standard place; i.e where this package gets
154 # installed.  With these options it is possible to override these
155 # ${prefix} depended values with fixed paths, which can't be replaced
156 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
157 AC_ARG_WITH(agent-pgm,
158     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
159           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
160 AC_SUBST(GNUPG_AGENT_PGM)
161 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
162 show_gnupg_agent_pgm="(default)"
163 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
164
165 AC_ARG_WITH(pinentry-pgm,
166     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
167           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
168 AC_SUBST(GNUPG_PINENTRY_PGM)
169 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
170 show_gnupg_pinentry_pgm="(default)"
171 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
172
173
174 AC_ARG_WITH(scdaemon-pgm,
175     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
176           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
177 AC_SUBST(GNUPG_SCDAEMON_PGM)
178 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
179 show_gnupg_scdaemon_pgm="(default)"
180 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
181
182
183 AC_ARG_WITH(dirmngr-pgm,
184     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
185           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
186 AC_SUBST(GNUPG_DIRMNGR_PGM)
187 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
188 show_gnupg_dirmngr_pgm="(default)"
189 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
190
191 AC_ARG_WITH(protect-tool-pgm,
192     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
193           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
194 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
195 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
196 show_gnupg_protect_tool_pgm="(default)"
197 test -n "$GNUPG_PROTECT_TOOL_PGM" \
198       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
199
200 AC_ARG_WITH(dirmngr-ldap-pgm,
201     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmngr ldap wrapper)],
202           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
203 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
204 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
205 show_gnupg_dirmngr_ldap_pgm="(default)"
206 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
207       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
208
209
210 #
211 # For a long time gpg 2.x was installed as gpg2.  This changed with
212 # 2.2.  This option can be used to install gpg under the name gpg2.
213 #
214 AC_ARG_ENABLE(gpg-is-gpg2,
215     AC_HELP_STRING([--enable-gpg-is-gpg2],[Set installed name of gpg to gpg2]),
216     gpg_is_gpg2=$enableval)
217 if test "$gpg_is_gpg2" = "yes"; then
218    AC_DEFINE(USE_GPG2_HACK, 1, [Define to install gpg as gpg2])
219 fi
220 AM_CONDITIONAL(USE_GPG2_HACK, test "$gpg_is_gpg2" = "yes")
221
222
223 # SELinux support includes tracking of sensitive files to avoid
224 # leaking their contents through processing these files by gpg itself
225 AC_MSG_CHECKING([whether SELinux support is requested])
226 AC_ARG_ENABLE(selinux-support,
227               AC_HELP_STRING([--enable-selinux-support],
228                              [enable SELinux support]),
229               selinux_support=$enableval, selinux_support=no)
230 AC_MSG_RESULT($selinux_support)
231
232
233 AC_MSG_CHECKING([whether to allocate extra secure memory])
234 AC_ARG_ENABLE(large-secmem,
235               AC_HELP_STRING([--enable-large-secmem],
236                              [allocate extra secure memory]),
237               large_secmem=$enableval, large_secmem=no)
238 AC_MSG_RESULT($large_secmem)
239 if test "$large_secmem" = yes ; then
240    SECMEM_BUFFER_SIZE=65536
241 else
242    SECMEM_BUFFER_SIZE=32768
243 fi
244 AC_DEFINE_UNQUOTED(SECMEM_BUFFER_SIZE,$SECMEM_BUFFER_SIZE,
245                    [Size of secure memory buffer])
246
247 AC_MSG_CHECKING([calibrated passphrase-stretching (s2k) duration])
248 AC_ARG_WITH(agent-s2k-calibration,
249               AC_HELP_STRING([--with-agent-s2k-calibration=MSEC],
250                              [calibrate passphrase stretching (s2k) to MSEC milliseconds]),
251               agent_s2k_calibration=$withval, agent_s2k_calibration=100)
252 AC_MSG_RESULT($agent_s2k_calibration milliseconds)
253 AC_DEFINE_UNQUOTED(AGENT_S2K_CALIBRATION, $agent_s2k_calibration,
254                    [Agent s2k calibration time (ms)])
255
256 AC_MSG_CHECKING([whether to enable trust models])
257 AC_ARG_ENABLE(trust-models,
258               AC_HELP_STRING([--disable-trust-models],
259                              [disable all trust models except "always"]),
260               use_trust_models=$enableval)
261 AC_MSG_RESULT($use_trust_models)
262 if test "$use_trust_models" = no ; then
263     AC_DEFINE(NO_TRUST_MODELS, 1,
264              [Define to include only trust-model always])
265 fi
266
267 AC_MSG_CHECKING([whether to enable TOFU])
268 AC_ARG_ENABLE(tofu,
269                 AC_HELP_STRING([--disable-tofu],
270                                [disable the TOFU trust model]),
271               use_tofu=$enableval, use_tofu=$use_trust_models)
272 AC_MSG_RESULT($use_tofu)
273 if test "$use_trust_models" = no && test "$use_tofu" = yes; then
274     AC_MSG_ERROR([both --disable-trust-models and --enable-tofu given])
275 fi
276
277 AC_MSG_CHECKING([whether to enable libdns])
278 AC_ARG_ENABLE(libdns,
279                 AC_HELP_STRING([--disable-libdns],
280                                [do not build with libdns support]),
281               use_libdns=$enableval, use_libdns=yes)
282 AC_MSG_RESULT($use_libdns)
283 if test x"$use_libdns" = xyes ; then
284     AC_DEFINE(USE_LIBDNS, 1, [Build with integrated libdns support])
285 fi
286 AM_CONDITIONAL(USE_LIBDNS, test "$use_libdns" = yes)
287
288
289 #
290 # Options to disable algorithm
291 #
292
293 GNUPG_GPG_DISABLE_ALGO([rsa],[RSA public key])
294 # Elgamal is a MUST algorithm
295 # DSA is a MUST algorithm
296 GNUPG_GPG_DISABLE_ALGO([ecdh],[ECDH public key])
297 GNUPG_GPG_DISABLE_ALGO([ecdsa],[ECDSA public key])
298 GNUPG_GPG_DISABLE_ALGO([eddsa],[EdDSA public key])
299
300 GNUPG_GPG_DISABLE_ALGO([idea],[IDEA cipher])
301 # 3DES is a MUST algorithm
302 GNUPG_GPG_DISABLE_ALGO([cast5],[CAST5 cipher])
303 GNUPG_GPG_DISABLE_ALGO([blowfish],[BLOWFISH cipher])
304 GNUPG_GPG_DISABLE_ALGO([aes128],[AES128 cipher])
305 GNUPG_GPG_DISABLE_ALGO([aes192],[AES192 cipher])
306 GNUPG_GPG_DISABLE_ALGO([aes256],[AES256 cipher])
307 GNUPG_GPG_DISABLE_ALGO([twofish],[TWOFISH cipher])
308 GNUPG_GPG_DISABLE_ALGO([camellia128],[CAMELLIA128 cipher])
309 GNUPG_GPG_DISABLE_ALGO([camellia192],[CAMELLIA192 cipher])
310 GNUPG_GPG_DISABLE_ALGO([camellia256],[CAMELLIA256 cipher])
311
312 GNUPG_GPG_DISABLE_ALGO([md5],[MD5 hash])
313 # SHA1 is a MUST algorithm
314 GNUPG_GPG_DISABLE_ALGO([rmd160],[RIPE-MD160 hash])
315 GNUPG_GPG_DISABLE_ALGO([sha224],[SHA-224 hash])
316 # SHA256 is a MUST algorithm for GnuPG.
317 GNUPG_GPG_DISABLE_ALGO([sha384],[SHA-384 hash])
318 GNUPG_GPG_DISABLE_ALGO([sha512],[SHA-512 hash])
319
320
321 # Allow disabling of zip support.
322 # This is in general not a good idea because according to rfc4880 OpenPGP
323 # implementations SHOULD support ZLIB.
324 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
325 AC_ARG_ENABLE(zip,
326    AC_HELP_STRING([--disable-zip],
327                   [disable the ZIP and ZLIB compression algorithm]),
328    use_zip=$enableval)
329 AC_MSG_RESULT($use_zip)
330
331 # Allow disabling of bzib2 support.
332 # It is defined only after we confirm the library is available later
333 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
334 AC_ARG_ENABLE(bzip2,
335    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
336    use_bzip2=$enableval)
337 AC_MSG_RESULT($use_bzip2)
338
339 # Configure option to allow or disallow execution of external
340 # programs, like a photo viewer.
341 AC_MSG_CHECKING([whether to enable external program execution])
342 AC_ARG_ENABLE(exec,
343     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
344     use_exec=$enableval)
345 AC_MSG_RESULT($use_exec)
346 if test "$use_exec" = no ; then
347     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
348 fi
349
350 if test "$use_exec" = yes ; then
351   AC_MSG_CHECKING([whether to enable photo ID viewing])
352   AC_ARG_ENABLE(photo-viewers,
353       [  --disable-photo-viewers disable photo ID viewers],
354       [if test "$enableval" = no ; then
355          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
356       fi],enableval=yes)
357   gnupg_cv_enable_photo_viewers=$enableval
358   AC_MSG_RESULT($enableval)
359
360   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
361     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
362     AC_ARG_WITH(photo-viewer,
363         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
364         [if test "$withval" = yes ; then
365            withval=no
366         elif test "$withval" != no ; then
367            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
368                             [if set, restrict photo-viewer to this])
369         fi],withval=no)
370     AC_MSG_RESULT($withval)
371   fi
372 fi
373
374
375 #
376 # Check for the key/uid cache size.  This can't be zero, but can be
377 # pretty small on embedded systems.  This is used for the gpg part.
378 #
379 AC_MSG_CHECKING([for the size of the key and uid cache])
380 AC_ARG_ENABLE(key-cache,
381         AC_HELP_STRING([--enable-key-cache=SIZE],
382                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
383 if test "$enableval" = "no"; then
384    enableval=5
385 elif test "$enableval" = "yes" || test "$enableval" = ""; then
386    enableval=4096
387 fi
388 changequote(,)dnl
389 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
390 changequote([,])dnl
391 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
392    AC_MSG_ERROR([invalid key-cache size])
393 fi
394 AC_MSG_RESULT($key_cache_size)
395 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
396                   [Size of the key and UID caches])
397
398
399
400 #
401 # Check whether we want to use Linux capabilities
402 #
403 AC_MSG_CHECKING([whether use of capabilities is requested])
404 AC_ARG_WITH(capabilities,
405     [  --with-capabilities     use linux capabilities [default=no]],
406 [use_capabilities="$withval"],[use_capabilities=no])
407 AC_MSG_RESULT($use_capabilities)
408
409 #
410 # Check whether to disable the card support
411 AC_MSG_CHECKING([whether smartcard support is requested])
412 AC_ARG_ENABLE(card-support,
413               AC_HELP_STRING([--disable-card-support],
414                              [disable smartcard support]),
415               card_support=$enableval)
416 AC_MSG_RESULT($card_support)
417 if test "$card_support" = yes ; then
418   AC_DEFINE(ENABLE_CARD_SUPPORT,1,[Define to include smartcard support])
419 else
420   build_scdaemon=no
421 fi
422
423 #
424 # Allow disabling of internal CCID support.
425 # It is defined only after we confirm the library is available later
426 #
427 AC_MSG_CHECKING([whether to enable the internal CCID driver])
428 AC_ARG_ENABLE(ccid-driver,
429               AC_HELP_STRING([--disable-ccid-driver],
430                              [disable the internal CCID driver]),
431               use_ccid_driver=$enableval)
432 AC_MSG_RESULT($use_ccid_driver)
433
434 AC_MSG_CHECKING([whether to auto start dirmngr])
435 AC_ARG_ENABLE(dirmngr-auto-start,
436               AC_HELP_STRING([--disable-dirmngr-auto-start],
437                              [disable auto starting of the dirmngr]),
438               dirmngr_auto_start=$enableval)
439 AC_MSG_RESULT($dirmngr_auto_start)
440 if test "$dirmngr_auto_start" = yes ; then
441     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
442               [Define to enable auto starting of the dirmngr])
443 fi
444
445
446 #
447 # To avoid double inclusion of config.h which might happen at some
448 # places, we add the usual double inclusion protection at the top of
449 # config.h.
450 #
451 AH_TOP([
452 #ifndef GNUPG_CONFIG_H_INCLUDED
453 #define GNUPG_CONFIG_H_INCLUDED
454 ])
455
456 #
457 # Stuff which goes at the bottom of config.h.
458 #
459 AH_BOTTOM([
460 /* This is the major version number of GnuPG so that
461    source included files can test for this.  Note, that
462    we use 2 here even for GnuPG 1.9.x. */
463 #define GNUPG_MAJOR_VERSION 2
464
465 /* Now to separate file name parts.
466    Please note that the string version must not contain more
467    than one character because the code assumes strlen()==1 */
468 #ifdef HAVE_DOSISH_SYSTEM
469 #define DIRSEP_C '\\'
470 #define DIRSEP_S "\\"
471 #define EXTSEP_C '.'
472 #define EXTSEP_S "."
473 #define PATHSEP_C ';'
474 #define PATHSEP_S ";"
475 #define EXEEXT_S ".exe"
476 #else
477 #define DIRSEP_C '/'
478 #define DIRSEP_S "/"
479 #define EXTSEP_C '.'
480 #define EXTSEP_S "."
481 #define PATHSEP_C ':'
482 #define PATHSEP_S ":"
483 #define EXEEXT_S ""
484 #endif
485
486 /* This is the same as VERSION, but should be overridden if the
487    platform cannot handle things like dots '.' in filenames. Set
488    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
489    uses for dots and dashes. */
490 #define SAFE_VERSION VERSION
491 #define SAFE_VERSION_DOT  '.'
492 #define SAFE_VERSION_DASH '-'
493
494 /* Some global constants.
495  * Note that the homedir must not end in a slash.  */
496 #ifdef HAVE_DOSISH_SYSTEM
497 # ifdef HAVE_DRIVE_LETTERS
498 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
499 # else
500 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
501 # endif
502 #elif defined(__VMS)
503 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
504 #else
505 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
506 #endif
507 #define GNUPG_PRIVATE_KEYS_DIR  "private-keys-v1.d"
508 #define GNUPG_OPENPGP_REVOC_DIR "openpgp-revocs.d"
509
510 /* For some systems (DOS currently), we hardcode the path here.  For
511    POSIX systems the values are constructed by the Makefiles, so that
512    the values may be overridden by the make invocations; this is to
513    comply with the GNU coding standards.  Note that these values are
514    only defaults.  */
515 #ifdef HAVE_DOSISH_SYSTEM
516 # ifdef HAVE_DRIVE_LETTERS
517 #  define GNUPG_BINDIR      "c:\\gnupg"
518 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
519 #  define GNUPG_LIBDIR      "c:\\gnupg"
520 #  define GNUPG_DATADIR     "c:\\gnupg"
521 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
522 # else
523 #  define GNUPG_BINDIR      "\\gnupg"
524 #  define GNUPG_LIBEXECDIR  "\\gnupg"
525 #  define GNUPG_LIBDIR      "\\gnupg"
526 #  define GNUPG_DATADIR     "\\gnupg"
527 #  define GNUPG_SYSCONFDIR  "\\gnupg"
528 # endif
529 #endif
530
531 /* Derive some other constants. */
532 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
533 #define EXEC_TEMPFILE_ONLY
534 #endif
535
536
537 /* We didn't define endianness above, so get it from OS macros.  This
538    is intended for making fat binary builds on OS X. */
539 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
540 #if defined(__BIG_ENDIAN__)
541 #define BIG_ENDIAN_HOST 1
542 #elif defined(__LITTLE_ENDIAN__)
543 #define LITTLE_ENDIAN_HOST 1
544 #else
545 #error "No endianness found"
546 #endif
547 #endif
548
549
550 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
551    ldap_start_tls_s because that is the actual symbol used in the
552    library.  winldap.h redefines it to our commonly used value,
553    thus we define our usual macro here.  */
554 #ifdef HAVE_LDAP_START_TLS_SA
555 # ifndef HAVE_LDAP_START_TLS_S
556 #  define HAVE_LDAP_START_TLS_S 1
557 # endif
558 #endif
559
560 /* Provide the es_ macro for estream.  */
561 #define GPGRT_ENABLE_ES_MACROS 1
562
563 /* Tell libgcrypt not to use its own libgpg-error implementation. */
564 #define USE_LIBGPG_ERROR 1
565
566 /* Tell Libgcrypt not to include deprecated definitions.  */
567 #define GCRYPT_NO_DEPRECATED 1
568
569 /* Our HTTP code is used in estream mode.  */
570 #define HTTP_USE_ESTREAM 1
571
572 /* Under W32 we do an explicit socket initialization, thus we need to
573    avoid the on-demand initialization which would also install an atexit
574    handler.  */
575 #define HTTP_NO_WSASTARTUP
576
577 /* Under Windows we use the gettext code from libgpg-error.  */
578 #define GPG_ERR_ENABLE_GETTEXT_MACROS
579
580 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
581 #define GPG_ERR_ENABLE_ERRNO_MACROS
582
583 #endif /*GNUPG_CONFIG_H_INCLUDED*/
584 ])
585
586
587 AM_MAINTAINER_MODE
588 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
589
590 # Checks for programs.
591 AC_MSG_NOTICE([checking for programs])
592 AC_PROG_MAKE_SET
593 AM_SANITY_CHECK
594 missing_dir=`cd $ac_aux_dir && pwd`
595 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
596 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
597 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
598 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
599 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
600 AM_SILENT_RULES
601 AC_PROG_AWK
602 AC_PROG_CC
603 AC_PROG_CPP
604 AM_PROG_CC_C_O
605 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
606   AC_MSG_ERROR([[No C-89 compiler found]])
607 fi
608 AC_PROG_INSTALL
609 AC_PROG_LN_S
610 AC_PROG_RANLIB
611 AC_CHECK_TOOL(AR, ar, :)
612 AC_PATH_PROG(PERL,"perl")
613 AC_CHECK_TOOL(WINDRES, windres, :)
614 AC_PATH_PROG(YAT2M, "yat2m")
615 AC_ARG_VAR(YAT2M, [tool to convert texi to man pages])
616 AM_CONDITIONAL(HAVE_YAT2M, test -n "$ac_cv_path_YAT2M")
617 AC_ISC_POSIX
618 AC_SYS_LARGEFILE
619 GNUPG_CHECK_USTAR
620
621
622 # We need to compile and run a program on the build machine.  A
623 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
624 # the AC archive is broken for autoconf 2.57.  Given that there is no
625 # newer version of that macro, we assume that it is also broken for
626 # autoconf 2.61 and thus we use a simple but usually sufficient
627 # approach.
628 AC_MSG_CHECKING(for cc for build)
629 if test "$cross_compiling" = "yes"; then
630   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
631 else
632   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
633 fi
634 AC_MSG_RESULT($CC_FOR_BUILD)
635 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
636
637 # We need to call this macro because other pkg-config macros are
638 # not always used.
639 PKG_PROG_PKG_CONFIG
640
641
642 try_gettext=yes
643 require_iconv=yes
644 have_dosish_system=no
645 have_w32_system=no
646 have_w32ce_system=no
647 have_android_system=no
648 use_simple_gettext=no
649 use_ldapwrapper=yes
650 mmap_needed=yes
651 case "${host}" in
652     *-mingw32*)
653         # special stuff for Windoze NT
654         ac_cv_have_dev_random=no
655         AC_DEFINE(USE_ONLY_8DOT3,1,
656                   [Set this to limit filenames to the 8.3 format])
657         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
658                   [Because the Unix gettext has too much overhead on
659                    MingW32 systems and these systems lack Posix functions,
660                    we use a simplified version of gettext])
661         have_dosish_system=yes
662         have_w32_system=yes
663         require_iconv=no
664         use_ldapwrapper=no  # Fixme: Do this only for CE.
665         case "${host}" in
666           *-mingw32ce*)
667             have_w32ce_system=yes
668             ;;
669           *)
670             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
671                       [Defined if the OS supports drive letters.])
672             ;;
673         esac
674         try_gettext="no"
675         use_simple_gettext=yes
676         mmap_needed=no
677         ;;
678     i?86-emx-os2 | i?86-*-os2*emx )
679         # OS/2 with the EMX environment
680         ac_cv_have_dev_random=no
681         AC_DEFINE(HAVE_DRIVE_LETTERS)
682         have_dosish_system=yes
683         try_gettext="no"
684         ;;
685
686     i?86-*-msdosdjgpp*)
687         # DOS with the DJGPP environment
688         ac_cv_have_dev_random=no
689         AC_DEFINE(HAVE_DRIVE_LETTERS)
690         have_dosish_system=yes
691         try_gettext="no"
692         ;;
693
694     *-*-hpux*)
695         if test -z "$GCC" ; then
696             CFLAGS="-Ae -D_HPUX_SOURCE $CFLAGS"
697         fi
698         ;;
699     *-dec-osf4*)
700         if test -z "$GCC" ; then
701             # Suppress all warnings
702             # to get rid of the unsigned/signed char mismatch warnings.
703             CFLAGS="-w $CFLAGS"
704         fi
705         ;;
706     *-dec-osf5*)
707         if test -z "$GCC" ; then
708             # Use the newer compiler `-msg_disable ptrmismatch1' to
709             # get rid of the unsigned/signed char mismatch warnings.
710             # Using this may hide other pointer mismatch warnings, but
711             # it at least lets other warning classes through
712             CFLAGS="-msg_disable ptrmismatch1 $CFLAGS"
713         fi
714         ;;
715     m68k-atari-mint)
716         ;;
717     *-linux-android*)
718         have_android_system=yes
719         # Android is fully utf-8 and we do not want to use iconv to
720         # keeps things simple
721         require_iconv=no
722         ;;
723     *-apple-darwin*)
724         AC_DEFINE(_DARWIN_C_SOURCE, 900000L,
725                   Expose all libc features (__DARWIN_C_FULL).)
726         ;;
727     *)
728        ;;
729 esac
730
731 if test "$have_dosish_system" = yes; then
732    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
733              [Defined if we run on some of the PCDOS like systems
734               (DOS, Windoze. OS/2) with special properties like
735               no file modes, case insensitive file names and preferred
736               use of backslashes as directory name separators.])
737 fi
738 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
739
740 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
741
742 if test "$have_w32_system" = yes; then
743    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
744    if test "$have_w32ce_system" = yes; then
745       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
746    fi
747 fi
748 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
749 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
750
751 if test "$have_android_system" = yes; then
752    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
753 fi
754 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
755
756
757 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
758 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
759
760
761 #
762 # Checks for libraries.
763 #
764 AC_MSG_NOTICE([checking for libraries])
765
766
767 #
768 # libgpg-error is a library with error codes shared between GnuPG
769 # related projects.
770 #
771 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
772                   have_gpg_error=yes,have_gpg_error=no)
773
774
775 #
776 # Libgcrypt is our generic crypto library
777 #
778 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
779         have_libgcrypt=yes,have_libgcrypt=no)
780
781
782 #
783 # libassuan is used for IPC
784 #
785 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
786                   have_libassuan=yes,have_libassuan=no)
787 if test "$have_libassuan" = "yes"; then
788   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
789                      [version of the libassuan library])
790   show_tor_support="only .onion"
791 fi
792
793
794 #
795 # libksba is our X.509 support library
796 #
797 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
798
799
800 #
801 # libusb allows us to use the integrated CCID smartcard reader driver.
802 #
803 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
804 if test "$use_ccid_driver" = auto || test "$use_ccid_driver" = yes; then
805    case "${host}" in
806      *-mingw32*)
807        LIBUSB_NAME=
808        LIBUSB_LIBS=
809        LIBUSB_CPPFLAGS=
810        ;;
811      *-*-darwin*)
812        LIBUSB_NAME=usb-1.0
813        LIBUSB_LIBS="-Wl,-framework,CoreFoundation -Wl,-framework,IOKit"
814        ;;
815      *-*-freebsd*)
816        # FreeBSD has a native 1.0 compatible library by -lusb.
817        LIBUSB_NAME=usb
818        LIBUSB_LIBS=
819        ;;
820      *)
821        LIBUSB_NAME=usb-1.0
822        LIBUSB_LIBS=
823        ;;
824    esac
825 fi
826 if test x"$LIBUSB_NAME" != x ; then
827    AC_CHECK_LIB($LIBUSB_NAME, libusb_init,
828                 [ LIBUSB_LIBS="-l$LIBUSB_NAME $LIBUSB_LIBS"
829                   have_libusb=yes ])
830    AC_MSG_CHECKING([libusb include dir])
831    usb_incdir_found="no"
832    for _incdir in "" "/usr/include/libusb-1.0" "/usr/local/include/libusb-1.0"; do
833      _libusb_save_cppflags=$CPPFLAGS
834      if test -n "${_incdir}"; then
835        CPPFLAGS="-I${_incdir} ${CPPFLAGS}"
836      fi
837      AC_PREPROC_IFELSE([AC_LANG_SOURCE([[@%:@include <libusb.h>]])],
838      [usb_incdir=${_incdir}; usb_incdir_found="yes"], [])
839      CPPFLAGS=${_libusb_save_cppflags}
840      if test "$usb_incdir_found" = "yes"; then
841        break
842      fi
843    done
844    if test "$usb_incdir_found" = "yes"; then
845      AC_MSG_RESULT([${usb_incdir}])
846    else
847      AC_MSG_RESULT([not found])
848      usb_incdir=""
849      have_libusb=no
850      if test "$use_ccid_driver" != yes; then
851        use_ccid_driver=no
852      fi
853      LIBUSB_LIBS=""
854    fi
855
856    if test "$have_libusb" = yes; then
857      AC_DEFINE(HAVE_LIBUSB,1, [defined if libusb is available])
858    fi
859    if test x"$usb_incdir" = x; then
860      LIBUSB_CPPFLAGS=""
861    else
862      LIBUSB_CPPFLAGS="-I${usb_incdir}"
863    fi
864 fi
865 AC_SUBST(LIBUSB_LIBS)
866 AC_SUBST(LIBUSB_CPPFLAGS)
867
868 #
869 # Check whether it is necessary to link against libdl.
870 # (For example to load libpcsclite)
871 #
872 gnupg_dlopen_save_libs="$LIBS"
873 LIBS=""
874 AC_SEARCH_LIBS(dlopen, c dl,,,)
875 DL_LIBS=$LIBS
876 AC_SUBST(DL_LIBS)
877 LIBS="$gnupg_dlopen_save_libs"
878
879
880 # Checks for g10
881
882 AC_ARG_ENABLE(sqlite,
883                 AC_HELP_STRING([--disable-sqlite],
884                                [disable the use of SQLITE]),
885               try_sqlite=$enableval, try_sqlite=yes)
886
887 if test x"$use_tofu" = xyes ; then
888   if test x"$try_sqlite" = xyes ; then
889     PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= $NEED_SQLITE_VERSION],
890                                  [have_sqlite=yes],
891                                  [have_sqlite=no])
892   fi
893   if test "$have_sqlite" = "yes"; then
894     :
895     AC_SUBST([SQLITE3_CFLAGS])
896     AC_SUBST([SQLITE3_LIBS])
897   else
898     use_tofu=no
899     tmp=$(echo "$SQLITE3_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
900     AC_MSG_WARN([[
901 ***
902 *** Building without SQLite support - TOFU disabled
903 ***
904 *** $tmp]])
905   fi
906 fi
907
908 AM_CONDITIONAL(SQLITE3, test "$have_sqlite" = "yes")
909
910 if test x"$use_tofu" = xyes ; then
911     AC_DEFINE(USE_TOFU, 1, [Enable to build the TOFU code])
912 fi
913
914
915 # Checks for g13
916
917 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
918 AC_DEFINE_UNQUOTED(ENCFS,
919         "${ENCFS}", [defines the filename of the encfs program])
920
921 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
922 AC_DEFINE_UNQUOTED(FUSERMOUNT,
923         "${FUSERMOUNT}", [defines the filename of the fusermount program])
924
925
926 # Checks for dirmngr
927
928
929 #
930 # Checks for symcryptrun:
931 #
932
933 # libutil has openpty() and login_tty().
934 AC_CHECK_LIB(util, openpty,
935               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
936                 AC_DEFINE(HAVE_LIBUTIL,1,
937                          [defined if libutil is available])
938              ])
939 AC_SUBST(LIBUTIL_LIBS)
940
941 # shred is used to clean temporary plain text files.
942 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
943 AC_DEFINE_UNQUOTED(SHRED,
944         "${SHRED}", [defines the filename of the shred program])
945
946
947 #
948 # Check whether the nPth library is available
949 #
950 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
951 if test "$have_npth" = "yes"; then
952   AC_DEFINE(HAVE_NPTH, 1,
953               [Defined if the New Portable Thread Library is available])
954   AC_DEFINE(USE_NPTH, 1,
955               [Defined if support for nPth is requested and nPth is available])
956 else
957   AC_MSG_WARN([[
958 ***
959 *** To support concurrent access for example in gpg-agent and the SCdaemon
960 *** we need the support of the New Portable Threads Library.
961 ***]])
962 fi
963
964
965 #
966 # NTBTLS is our TLS library.  If it is not available fallback to
967 # GNUTLS.
968 #
969 AC_ARG_ENABLE(ntbtls,
970               AC_HELP_STRING([--disable-ntbtls],
971                              [disable the use of NTBTLS as TLS library]),
972               try_ntbtls=$enableval, try_ntbtls=yes)
973 if test x"$try_ntbtls" = xyes ; then
974   AM_PATH_NTBTLS("$NEED_NTBTLS_API:$NEED_NTBTLS_VERSION",
975                  [have_ntbtls=yes],[have_ntbtls=no])
976 fi
977 if test "$have_ntbtls" = yes ; then
978    use_tls_library=ntbtls
979    AC_DEFINE(HTTP_USE_NTBTLS, 1, [Enable NTBTLS support in http.c])
980 else
981   AC_ARG_ENABLE(gnutls,
982                 AC_HELP_STRING([--disable-gnutls],
983                                [disable GNUTLS as fallback TLS library]),
984                 try_gnutls=$enableval, try_gnutls=yes)
985   if test x"$try_gnutls" = xyes ; then
986     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= $NEED_GNUTLS_VERSION],
987                                    [have_gnutls=yes],
988                                    [have_gnutls=no])
989   fi
990   if test "$have_gnutls" = "yes"; then
991     AC_SUBST([LIBGNUTLS_CFLAGS])
992     AC_SUBST([LIBGNUTLS_LIBS])
993     use_tls_library=gnutls
994     AC_DEFINE(HTTP_USE_GNUTLS, 1, [Enable GNUTLS support in http.c])
995   else
996     tmp=$(echo "$LIBGNUTLS_PKG_ERRORS" | tr '\n' '\v' | sed 's/\v/\n*** /g')
997     AC_MSG_WARN([[
998 ***
999 *** Building without NTBTLS and GNUTLS - no TLS access to keyservers.
1000 ***
1001 *** $tmp]])
1002   fi
1003 fi
1004
1005 #
1006 # Allow to set a fixed trust store file for system provided certificates.
1007 #
1008 AC_ARG_WITH([default-trust-store-file],
1009             [AC_HELP_STRING([--with-default-trust-store-file=FILE],
1010                             [Use FILE as system trust store])],
1011             default_trust_store_file="$withval",
1012             default_trust_store_file="")
1013 if test x"$default_trust_store_file" = xno;then
1014   default_trust_store_file=""
1015 fi
1016 if test x"$default_trust_store_file" != x ; then
1017   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
1018     ["$default_trust_store_file"], [Use as default system trust store file])
1019 fi
1020
1021
1022 AC_MSG_NOTICE([checking for networking options])
1023
1024 #
1025 # Must check for network library requirements before doing link tests
1026 # for ldap, for example. If ldap libs are static (or dynamic and without
1027 # ELF runtime link paths), then link will fail and LDAP support won't
1028 # be detected.
1029 #
1030 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
1031         [NETLIBS="-lnsl $NETLIBS"]))
1032 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
1033         [NETLIBS="-lsocket $NETLIBS"]))
1034
1035
1036 #
1037 # Check standard resolver functions.
1038 #
1039 if test "$build_dirmngr" = "yes"; then
1040   _dns_save_libs=$LIBS
1041   LIBS=""
1042
1043   # Find the system resolver which can always be enabled with
1044   # the dirmngr option --standard-resolver.
1045
1046   # the double underscore thing is a glibc-ism?
1047   AC_SEARCH_LIBS(res_query,resolv bind,,
1048                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
1049   AC_SEARCH_LIBS(dn_expand,resolv bind,,
1050                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
1051
1052   # macOS renames dn_skipname into res_9_dn_skipname in <resolv.h>,
1053   # and for some reason fools us into believing we don't need
1054   # -lresolv even if we do.  Since the test program checking for the
1055   # symbol does not include <resolv.h>, we need to check for the
1056   # renamed symbol explicitly.
1057   AC_SEARCH_LIBS(res_9_dn_skipname,resolv bind,,
1058       AC_SEARCH_LIBS(dn_skipname,resolv bind,,
1059           AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no)))
1060
1061   if test x"$have_resolver" != xno ; then
1062
1063       # Make sure that the BIND 4 resolver interface is workable before
1064       # enabling any code that calls it.  At some point I'll rewrite the
1065       # code to use the BIND 8 resolver API.
1066       # We might also want to use libdns instead.
1067
1068     AC_MSG_CHECKING([whether the resolver is usable])
1069     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1070 #include <netinet/in.h>
1071 #include <arpa/nameser.h>
1072 #include <resolv.h>]],
1073 [[unsigned char answer[PACKETSZ];
1074   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1075   dn_skipname(0,0);
1076   dn_expand(0,0,0,0,0);
1077 ]])],have_resolver=yes,have_resolver=no)
1078     AC_MSG_RESULT($have_resolver)
1079
1080     # This is Apple-specific and somewhat bizarre as they changed the
1081     # define in bind 8 for some reason.
1082
1083     if test x"$have_resolver" != xyes ; then
1084       AC_MSG_CHECKING(
1085            [whether I can make the resolver usable with BIND_8_COMPAT])
1086       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
1087 #include <sys/types.h>
1088 #include <netinet/in.h>
1089 #include <arpa/nameser.h>
1090 #include <resolv.h>]],
1091 [[unsigned char answer[PACKETSZ];
1092   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
1093   dn_skipname(0,0); dn_expand(0,0,0,0,0);
1094 ]])],[have_resolver=yes ; need_compat=yes])
1095       AC_MSG_RESULT($have_resolver)
1096     fi
1097   fi
1098
1099   if test x"$have_resolver" = xyes ; then
1100     AC_DEFINE(HAVE_SYSTEM_RESOLVER,1,[The system's resolver is usable.])
1101     DNSLIBS="$DNSLIBS $LIBS"
1102     if test x"$need_compat" = xyes ; then
1103       AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
1104     fi
1105     if test "$use_libdns" = yes; then
1106      show_tor_support=yes
1107     fi
1108   elif test "$use_libdns" = yes; then
1109     show_tor_support=yes
1110   else
1111     AC_MSG_WARN([[
1112 ***
1113 *** The system's DNS resolver is not usable.
1114 *** Dirmngr functionality is limited.
1115 ***]])
1116     show_tor_support="${show_tor_support} (no system resolver)"
1117   fi
1118
1119   if test "$have_w32_system" = yes; then
1120     if test "$use_libdns" = yes; then
1121       DNSLIBS="$DNSLIBS -liphlpapi"
1122     fi
1123   fi
1124
1125   LIBS=$_dns_save_libs
1126 fi
1127
1128 AC_SUBST(DNSLIBS)
1129
1130
1131 #
1132 # Check for LDAP
1133 #
1134 # Note that running the check changes the variable
1135 # gnupg_have_ldap from "n/a" to "no" or "yes".
1136
1137 AC_ARG_ENABLE(ldap,
1138     AC_HELP_STRING([--disable-ldap],[disable LDAP support]),
1139     [if test "$enableval" = "no"; then gnupg_have_ldap=no; fi])
1140
1141 if test "$gnupg_have_ldap" != "no" ; then
1142   if test "$build_dirmngr" = "yes" ; then
1143      GNUPG_CHECK_LDAP($NETLIBS)
1144      AC_CHECK_LIB(lber, ber_free,
1145                   [ LBER_LIBS="$LBER_LIBS -llber"
1146                     AC_DEFINE(HAVE_LBER,1,
1147                              [defined if liblber is available])
1148                     have_lber=yes
1149                  ])
1150   fi
1151 fi
1152 AC_SUBST(LBER_LIBS)
1153 if test "$gnupg_have_ldap" = "no"; then
1154     AC_MSG_WARN([[
1155 ***
1156 *** Building without LDAP support.
1157 *** No CRL access or X.509 certificate search available.
1158 ***]])
1159 fi
1160
1161 AM_CONDITIONAL(USE_LDAP, [test "$gnupg_have_ldap" = yes])
1162 if test "$gnupg_have_ldap" = yes ; then
1163   AC_DEFINE(USE_LDAP,1,[Defined if LDAP is support])
1164 else
1165  use_ldapwrapper=no
1166 fi
1167
1168 if test "$use_ldapwrapper" = yes; then
1169    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
1170 fi
1171 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
1172
1173
1174
1175
1176 #
1177 # Check for sendmail
1178 #
1179 # This isn't necessarily sendmail itself, but anything that gives a
1180 # sendmail-ish interface to the outside world.  That includes Exim,
1181 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1182 AC_ARG_WITH(mailprog,
1183       AC_HELP_STRING([--with-mailprog=NAME],
1184                      [use "NAME -t" for mail transport]),
1185              ,with_mailprog=yes)
1186 if test x"$with_mailprog" = xyes ; then
1187     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1188 elif test x"$with_mailprog" != xno ; then
1189     AC_MSG_CHECKING([for a mail transport program])
1190     AC_SUBST(SENDMAIL,$with_mailprog)
1191     AC_MSG_RESULT($with_mailprog)
1192 fi
1193
1194
1195 #
1196 # Construct a printable name of the OS
1197 #
1198 case "${host}" in
1199     *-mingw32ce*)
1200         PRINTABLE_OS_NAME="W32CE"
1201         ;;
1202     *-mingw32*)
1203         PRINTABLE_OS_NAME="MingW32"
1204         ;;
1205     *-*-cygwin*)
1206         PRINTABLE_OS_NAME="Cygwin"
1207         ;;
1208     i?86-emx-os2 | i?86-*-os2*emx )
1209         PRINTABLE_OS_NAME="OS/2"
1210         ;;
1211     i?86-*-msdosdjgpp*)
1212         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1213         try_dynload=no
1214         ;;
1215     *-linux*)
1216         PRINTABLE_OS_NAME="GNU/Linux"
1217         ;;
1218     *)
1219         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1220         ;;
1221 esac
1222 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1223                    [A human readable text with the name of the OS])
1224
1225
1226 #
1227 # Checking for iconv
1228 #
1229 if test "$require_iconv" = yes; then
1230   AM_ICONV
1231 else
1232   LIBICONV=
1233   LTLIBICONV=
1234   AC_SUBST(LIBICONV)
1235   AC_SUBST(LTLIBICONV)
1236 fi
1237
1238
1239 #
1240 # Check for gettext
1241 #
1242 # This is "GNU gnupg" - The project-id script from gettext
1243 #                       needs this string
1244 #
1245 AC_MSG_NOTICE([checking for gettext])
1246 AM_PO_SUBDIRS
1247 AM_GNU_GETTEXT_VERSION([0.17])
1248 if test "$try_gettext" = yes; then
1249   AM_GNU_GETTEXT([external],[need-ngettext])
1250
1251   # gettext requires some extra checks.  These really should be part of
1252   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1253   # function checks to here.
1254
1255   AC_CHECK_FUNCS(strchr)
1256 else
1257   USE_NLS=no
1258   USE_INCLUDED_LIBINTL=no
1259   BUILD_INCLUDED_LIBINTL=no
1260   POSUB=po
1261   AC_SUBST(USE_NLS)
1262   AC_SUBST(USE_INCLUDED_LIBINTL)
1263   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1264   AC_SUBST(POSUB)
1265 fi
1266
1267 # We use HAVE_LANGINFO_CODESET in a couple of places.
1268 AM_LANGINFO_CODESET
1269
1270 # Checks required for our use of locales
1271 gt_LC_MESSAGES
1272
1273
1274 #
1275 # SELinux support
1276 #
1277 if test "$selinux_support" = yes ; then
1278   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1279 fi
1280
1281
1282 #
1283 # Checks for header files.
1284 #
1285 AC_MSG_NOTICE([checking for header files])
1286 AC_HEADER_STDC
1287 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1288                   pty.h utmp.h pwd.h inttypes.h signal.h sys/select.h     \
1289                   stdint.h signal.h util.h libutil.h termios.h \
1290                   ucred.h sys/sysmacros.h sys/mkdev.h])
1291
1292 AC_HEADER_TIME
1293
1294
1295 #
1296 # Checks for typedefs, structures, and compiler characteristics.
1297 #
1298 AC_MSG_NOTICE([checking for system characteristics])
1299 AC_C_CONST
1300 AC_C_INLINE
1301 AC_C_VOLATILE
1302 AC_TYPE_SIZE_T
1303 AC_TYPE_MODE_T
1304 AC_TYPE_SIGNAL
1305 AC_DECL_SYS_SIGLIST
1306
1307 gl_HEADER_SYS_SOCKET
1308 gl_TYPE_SOCKLEN_T
1309
1310 AC_SEARCH_LIBS([inet_addr], [nsl])
1311
1312 AC_ARG_ENABLE(endian-check,
1313               AC_HELP_STRING([--disable-endian-check],
1314               [disable the endian check and trust the OS provided macros]),
1315               endiancheck=$enableval,endiancheck=yes)
1316
1317 if test x"$endiancheck" = xyes ; then
1318   GNUPG_CHECK_ENDIAN
1319 fi
1320
1321 # fixme: we should get rid of the byte type
1322 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1323 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1324 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1325 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1326 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1327
1328 AC_CHECK_SIZEOF(unsigned short)
1329 AC_CHECK_SIZEOF(unsigned int)
1330 AC_CHECK_SIZEOF(unsigned long)
1331 AC_CHECK_SIZEOF(unsigned long long)
1332 AC_HEADER_TIME
1333 AC_CHECK_SIZEOF(time_t,,[[
1334 #include <stdio.h>
1335 #if TIME_WITH_SYS_TIME
1336 # include <sys/time.h>
1337 # include <time.h>
1338 #else
1339 # if HAVE_SYS_TIME_H
1340 #  include <sys/time.h>
1341 # else
1342 #  include <time.h>
1343 # endif
1344 #endif
1345 ]])
1346 GNUPG_TIME_T_UNSIGNED
1347
1348
1349 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1350    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1351    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1352     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1353 fi
1354
1355
1356 #
1357 # Checks for library functions.
1358 #
1359 AC_MSG_NOTICE([checking for library functions])
1360 AC_CHECK_DECLS(getpagesize)
1361 AC_FUNC_FSEEKO
1362 AC_FUNC_VPRINTF
1363 AC_FUNC_FORK
1364 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1365 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1366 AC_CHECK_FUNCS([setenv unsetenv fcntl ftruncate inet_ntop])
1367 AC_CHECK_FUNCS([canonicalize_file_name])
1368 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1369 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1370 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1371 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1372 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1373                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1374                 flockfile funlockfile getpwnam getpwuid \
1375                 getenv inet_pton strpbrk])
1376
1377 # On some systems (e.g. Solaris) nanosleep requires linking to librl.
1378 # Given that we use nanosleep only as an optimization over a select
1379 # based wait function we want it only if it is available in libc.
1380 _save_libs="$LIBS"
1381 AC_SEARCH_LIBS([nanosleep], [],
1382                [AC_DEFINE(HAVE_NANOSLEEP,1,
1383                 [Define to 1 if you have the `nanosleep' function in libc.])])
1384 LIBS="$_save_libs"
1385
1386
1387 # See whether libc supports the Linux inotify interface
1388 case "${host}" in
1389     *-*-linux*)
1390         AC_CHECK_FUNCS([inotify_init])
1391         ;;
1392 esac
1393
1394
1395 if test "$have_android_system" = yes; then
1396    # On Android ttyname is a stub but prints an error message.
1397    AC_DEFINE(HAVE_BROKEN_TTYNAME,1,
1398              [Defined if ttyname does not work properly])
1399 fi
1400
1401 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1402
1403 # Dirmngr requires mmap on Unix systems.
1404 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1405   AC_MSG_ERROR([[Sorry, the current implementation requires mmap.]])
1406 fi
1407
1408
1409 #
1410 # Check for the getsockopt SO_PEERCRED, etc.
1411 #
1412 AC_CHECK_MEMBERS([struct ucred.pid, struct ucred.cr_pid, struct sockpeercred.pid], [], [], [#include <sys/types.h>
1413 #include <sys/socket.h> ])
1414
1415 # (Open)Solaris
1416 AC_CHECK_FUNCS([getpeerucred])
1417
1418
1419 #
1420 # W32 specific test
1421 #
1422 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1423
1424 #
1425 # Sanity check regex.  Tests adapted from mutt.
1426 #
1427 AC_MSG_CHECKING([whether regular expression support is requested])
1428 AC_ARG_ENABLE(regex,
1429   AC_HELP_STRING([--disable-regex],
1430     [do not handle regular expressions in trust signatures]),
1431   use_regex=$enableval, use_regex=yes)
1432 AC_MSG_RESULT($use_regex)
1433
1434 if test "$use_regex" = yes ; then
1435   _cppflags="${CPPFLAGS}"
1436   _ldflags="${LDFLAGS}"
1437   AC_ARG_WITH(regex,
1438      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1439       [
1440       if test -d "$withval" ; then
1441         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1442         LDFLAGS="${LDFLAGS} -L$withval/lib"
1443       fi
1444       ],withval="")
1445
1446   # Does the system have regex functions at all?
1447   AC_SEARCH_LIBS([regcomp], [regex])
1448   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1449
1450   if test $gnupg_cv_have_regex = no; then
1451     use_regex=no
1452   else
1453     if test x"$cross_compiling" = xyes; then
1454       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1455     else
1456       AC_CACHE_CHECK([whether your system's regexp library is broken],
1457        [gnupg_cv_regex_broken],
1458        AC_TRY_RUN([
1459 #include <unistd.h>
1460 #include <regex.h>
1461 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1462        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1463
1464       if test $gnupg_cv_regex_broken = yes; then
1465         AC_MSG_WARN([your regex is broken - disabling regex use])
1466         use_regex=no
1467       fi
1468     fi
1469   fi
1470   CPPFLAGS="${_cppflags}"
1471   LDFLAGS="${_ldflags}"
1472 fi
1473
1474 if test "$use_regex" != yes ; then
1475   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1476 fi
1477 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1478
1479
1480
1481 #
1482 # Do we have zlib? Must do it here because Solaris failed
1483 # when compiling a conftest (due to the "-lz" from LIBS).
1484 # Note that we combine zlib and bzlib2 in ZLIBS.
1485 #
1486 if test "$use_zip" = yes ; then
1487   _cppflags="${CPPFLAGS}"
1488   _ldflags="${LDFLAGS}"
1489   AC_ARG_WITH(zlib,
1490     [  --with-zlib=DIR         use libz in DIR],[
1491       if test -d "$withval"; then
1492         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1493         LDFLAGS="${LDFLAGS} -L$withval/lib"
1494       fi
1495     ])
1496
1497   AC_CHECK_HEADER(zlib.h,
1498      AC_CHECK_LIB(z, deflateInit2_,
1499        [
1500        ZLIBS="-lz"
1501        AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1502        ],
1503        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1504        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1505 fi
1506
1507
1508 #
1509 # Check whether we can support bzip2
1510 #
1511 if test "$use_bzip2" = yes ; then
1512   _cppflags="${CPPFLAGS}"
1513   _ldflags="${LDFLAGS}"
1514   AC_ARG_WITH(bzip2,
1515      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1516       [
1517       if test -d "$withval" ; then
1518         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1519         LDFLAGS="${LDFLAGS} -L$withval/lib"
1520       fi
1521       ],withval="")
1522
1523   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1524   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1525   # woefully out of date.
1526   if test "$withval" != no ; then
1527      AC_CHECK_HEADER(bzlib.h,
1528         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1529           [
1530           have_bz2=yes
1531           ZLIBS="$ZLIBS -lbz2"
1532           AC_DEFINE(HAVE_BZIP2,1,
1533                   [Defined if the bz2 compression library is available])
1534           ],
1535           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1536           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1537   fi
1538 fi
1539 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1540 AC_SUBST(ZLIBS)
1541
1542
1543 # Check for readline support
1544 GNUPG_CHECK_READLINE
1545
1546
1547 if test "$development_version" = yes; then
1548     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1549             [Defined if this is not a regular release])
1550 fi
1551
1552 if test "$USE_MAINTAINER_MODE" = "yes"; then
1553     AC_DEFINE(MAINTAINER_MODE,1,
1554             [Defined if this build is in maintainer mode])
1555 fi
1556
1557 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1558
1559 GNUPG_CHECK_GNUMAKE
1560
1561 # Add some extra libs here so that previous tests don't fail for
1562 # mysterious reasons - the final link step should bail out.
1563 # W32SOCKLIBS is also defined so that if can be used for tools not
1564 # requiring any network stuff but linking to code in libcommon which
1565 # tracks in winsock stuff (e.g. init_common_subsystems).
1566 if test "$have_w32_system" = yes; then
1567    if test "$have_w32ce_system" = yes; then
1568      W32SOCKLIBS="-lws2"
1569    else
1570      W32SOCKLIBS="-lws2_32"
1571    fi
1572    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1573 fi
1574
1575 AC_SUBST(NETLIBS)
1576 AC_SUBST(W32SOCKLIBS)
1577
1578 #
1579 # Setup gcc specific options
1580 #
1581 USE_C99_CFLAGS=
1582 AC_MSG_NOTICE([checking for cc features])
1583 if test "$GCC" = yes; then
1584     mycflags=
1585     mycflags_save=$CFLAGS
1586
1587     # Check whether gcc does not emit a diagnositc for unknown -Wno-*
1588     # options.  This is the case for gcc >= 4.6
1589     AC_MSG_CHECKING([if gcc ignores unknown -Wno-* options])
1590     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1591 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6 )
1592 #kickerror
1593 #endif]],[])],[_gcc_silent_wno=yes],[_gcc_silent_wno=no])
1594     AC_MSG_RESULT($_gcc_silent_wno)
1595
1596     # Note that it is okay to use CFLAGS here because these are just
1597     # warning options and the user should have a chance of overriding
1598     # them.
1599     if test "$USE_MAINTAINER_MODE" = "yes"; then
1600         mycflags="$mycflags -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1601         mycflags="$mycflags -Wformat -Wno-format-y2k -Wformat-security"
1602         if test x"$_gcc_silent_wno" = xyes ; then
1603           _gcc_wopt=yes
1604         else
1605           AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1606           CFLAGS="-Wno-missing-field-initializers"
1607           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1608                             [_gcc_wopt=yes],[_gcc_wopt=no])
1609           AC_MSG_RESULT($_gcc_wopt)
1610         fi
1611         if test x"$_gcc_wopt" = xyes ; then
1612           mycflags="$mycflags -W -Wno-sign-compare"
1613           mycflags="$mycflags -Wno-missing-field-initializers"
1614         fi
1615
1616         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1617         CFLAGS="-Wdeclaration-after-statement"
1618         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1619         AC_MSG_RESULT($_gcc_wopt)
1620         if test x"$_gcc_wopt" = xyes ; then
1621           mycflags="$mycflags -Wdeclaration-after-statement"
1622         fi
1623
1624         AC_MSG_CHECKING([if gcc supports -Wlogical-op])
1625         CFLAGS="-Wlogical-op -Werror"
1626         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1627         AC_MSG_RESULT($_gcc_wopt)
1628         if test x"$_gcc_wopt" = xyes ; then
1629           mycflags="$mycflags -Wlogical-op"
1630         fi
1631
1632         AC_MSG_CHECKING([if gcc supports -Wvla])
1633         CFLAGS="-Wvla"
1634         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1635         AC_MSG_RESULT($_gcc_wopt)
1636         if test x"$_gcc_wopt" = xyes ; then
1637           mycflags="$mycflags -Wvla"
1638         fi
1639
1640     else
1641         mycflags="$mycflags -Wall"
1642     fi
1643
1644     if test x"$_gcc_silent_wno" = xyes ; then
1645       _gcc_psign=yes
1646     else
1647       AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1648       CFLAGS="-Wno-pointer-sign"
1649       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
1650                         [_gcc_psign=yes],[_gcc_psign=no])
1651       AC_MSG_RESULT($_gcc_psign)
1652     fi
1653     if test x"$_gcc_psign" = xyes ; then
1654        mycflags="$mycflags -Wno-pointer-sign"
1655     fi
1656
1657     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1658     CFLAGS="-Wpointer-arith"
1659     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1660     AC_MSG_RESULT($_gcc_psign)
1661     if test x"$_gcc_psign" = xyes ; then
1662        mycflags="$mycflags -Wpointer-arith"
1663     fi
1664
1665     CFLAGS="$mycflags $mycflags_save"
1666     if test "$use_libdns" = yes; then
1667        # dirmngr/dns.{c,h} require C99 and GNU extensions.  */
1668        USE_C99_CFLAGS="-std=gnu99"
1669     fi
1670 fi
1671
1672 AC_SUBST(USE_C99_CFLAGS)
1673
1674
1675 #
1676 # This is handy for debugging so the compiler doesn't rearrange
1677 # things and eliminate variables.
1678 #
1679 AC_ARG_ENABLE(optimization,
1680    AC_HELP_STRING([--disable-optimization],
1681                   [disable compiler optimization]),
1682                   [if test $enableval = no ; then
1683                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1684                    fi])
1685
1686 #
1687 # log_debug has certain requirements which might hamper portability.
1688 # Thus we use an option to enable it.
1689 #
1690 AC_MSG_CHECKING([whether to enable log_clock])
1691 AC_ARG_ENABLE(log_clock,
1692               AC_HELP_STRING([--enable-log-clock],
1693                              [enable log_clock timestamps]),
1694               enable_log_clock=$enableval, enable_log_clock=no)
1695 AC_MSG_RESULT($enable_log_clock)
1696 if test "$enable_log_clock" = yes ; then
1697   AC_DEFINE(ENABLE_LOG_CLOCK,1,[Defined to use log_clock timestamps])
1698 fi
1699
1700 # Add -Werror to CFLAGS.  This hack can be used to avoid problems with
1701 # misbehaving autoconf tests in case the user supplied -Werror.
1702 #
1703 AC_ARG_ENABLE(werror,
1704    AC_HELP_STRING([--enable-werror],
1705                   [append -Werror to CFLAGS]),
1706                   [if test $enableval = yes ; then
1707                       CFLAGS="$CFLAGS -Werror"
1708                    fi])
1709
1710 #
1711 # Configure option --enable-all-tests
1712 #
1713 AC_MSG_CHECKING([whether "make check" shall run all tests])
1714 AC_ARG_ENABLE(all-tests,
1715               AC_HELP_STRING([--enable-all-tests],
1716                              [let "make check" run all tests]),
1717               run_all_tests=$enableval, run_all_tests=no)
1718 AC_MSG_RESULT($run_all_tests)
1719 if test "$run_all_tests" = "yes"; then
1720     AC_DEFINE(RUN_ALL_TESTS,1,
1721             [Defined if "make check" shall run all tests])
1722 fi
1723
1724 #
1725 # We do not want support for the GNUPG_BUILDDIR environment variable
1726 # in a released version.  However, our regression tests suite requires
1727 # this and thus we build with support for it during "make distcheck".
1728 # This configure option implements this along with the top Makefile's
1729 # AM_DISTCHECK_CONFIGURE_FLAGS.
1730 #
1731 gnupg_builddir_envvar=no
1732 AC_ARG_ENABLE(gnupg-builddir-envvar,,
1733               gnupg_builddir_envvar=$enableval)
1734 if test x"$gnupg_builddir_envvar" = x"yes"; then
1735    AC_DEFINE(ENABLE_GNUPG_BUILDDIR_ENVVAR, 1,
1736       [This is only used with "make distcheck"])
1737 fi
1738
1739 #
1740 # Decide what to build
1741 #
1742
1743 build_scdaemon_extra=""
1744 if test "$build_scdaemon" = "yes"; then
1745   if test $have_libusb = no; then
1746      build_scdaemon_extra="without internal CCID driver"
1747   fi
1748   if test -n "$build_scdaemon_extra"; then
1749      build_scdaemon_extra="(${build_scdaemon_extra})"
1750   fi
1751 fi
1752
1753
1754 #
1755 # Set variables for use by automake makefiles.
1756 #
1757 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1758 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1759 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1760 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1761 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1762 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1763 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1764 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1765 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1766 AM_CONDITIONAL(BUILD_WKS_TOOLS,   test "$build_wks_tools" = "yes")
1767
1768 AM_CONDITIONAL(ENABLE_CARD_SUPPORT, test "$card_support" = yes)
1769 AM_CONDITIONAL(NO_TRUST_MODELS,     test "$use_trust_models" = no)
1770 AM_CONDITIONAL(USE_TOFU,            test "$use_tofu" = yes)
1771
1772 #
1773 # Set some defines for use gpgconf.
1774 #
1775 if test "$build_gpg" = yes ; then
1776     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1777 fi
1778 if test "$build_gpgsm" = yes ; then
1779     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1780 fi
1781 if test "$build_agent" = yes ; then
1782     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1783 fi
1784 if test "$build_scdaemon" = yes ; then
1785     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1786 fi
1787 if test "$build_dirmngr" = yes ; then
1788     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if DIRMNGR is to be build])
1789 fi
1790 if test "$build_g13" = yes ; then
1791     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1792 fi
1793
1794
1795 #
1796 # Define Name strings
1797 #
1798 AC_DEFINE_UNQUOTED(GNUPG_NAME, "GnuPG", [The name of the project])
1799
1800 AC_DEFINE_UNQUOTED(GPG_NAME, "gpg", [The name of the OpenPGP tool])
1801 AC_DEFINE_UNQUOTED(GPG_DISP_NAME, "GnuPG", [The displayed name of gpg])
1802
1803 AC_DEFINE_UNQUOTED(GPGSM_NAME, "gpgsm", [The name of the S/MIME tool])
1804 AC_DEFINE_UNQUOTED(GPGSM_DISP_NAME, "GPGSM", [The displayed name of gpgsm])
1805
1806 AC_DEFINE_UNQUOTED(GPG_AGENT_NAME, "gpg-agent", [The name of the agent])
1807 AC_DEFINE_UNQUOTED(GPG_AGENT_DISP_NAME, "GPG Agent",
1808                                         [The displayed name of gpg-agent])
1809
1810 AC_DEFINE_UNQUOTED(SCDAEMON_NAME, "scdaemon", [The name of the scdaemon])
1811 AC_DEFINE_UNQUOTED(SCDAEMON_DISP_NAME, "SCDaemon",
1812                                        [The displayed name of scdaemon])
1813
1814 AC_DEFINE_UNQUOTED(DIRMNGR_NAME, "dirmngr", [The name of the dirmngr])
1815 AC_DEFINE_UNQUOTED(DIRMNGR_DISP_NAME, "DirMngr",
1816                                       [The displayed name of dirmngr])
1817
1818 AC_DEFINE_UNQUOTED(G13_NAME, "g13", [The name of the g13 tool])
1819 AC_DEFINE_UNQUOTED(G13_DISP_NAME, "G13", [The displayed name of g13])
1820
1821 AC_DEFINE_UNQUOTED(GPGCONF_NAME, "gpgconf", [The name of the gpgconf tool])
1822 AC_DEFINE_UNQUOTED(GPGCONF_DISP_NAME, "GPGConf",
1823                                       [The displayed name of gpgconf])
1824
1825 AC_DEFINE_UNQUOTED(GPGTAR_NAME, "gpgtar", [The name of the gpgtar tool])
1826
1827 AC_DEFINE_UNQUOTED(GPG_AGENT_SOCK_NAME, "S.gpg-agent",
1828                    [The name of the agent socket])
1829 AC_DEFINE_UNQUOTED(GPG_AGENT_EXTRA_SOCK_NAME, "S.gpg-agent.extra",
1830                    [The name of the agent socket for remote access])
1831 AC_DEFINE_UNQUOTED(GPG_AGENT_BROWSER_SOCK_NAME, "S.gpg-agent.browser",
1832                    [The name of the agent socket for browsers])
1833 AC_DEFINE_UNQUOTED(GPG_AGENT_SSH_SOCK_NAME, "S.gpg-agent.ssh",
1834                    [The name of the agent socket for ssh])
1835 AC_DEFINE_UNQUOTED(DIRMNGR_INFO_NAME, "DIRMNGR_INFO",
1836                    [The name of the dirmngr info envvar])
1837 AC_DEFINE_UNQUOTED(SCDAEMON_SOCK_NAME, "S.scdaemon",
1838                    [The name of the SCdaemon socket])
1839 AC_DEFINE_UNQUOTED(DIRMNGR_SOCK_NAME, "S.dirmngr",
1840                    [The name of the dirmngr socket])
1841 AC_DEFINE_UNQUOTED(DIRMNGR_DEFAULT_KEYSERVER,
1842                    "hkps://hkps.pool.sks-keyservers.net",
1843       [The default keyserver for dirmngr to use, if none is explicitly given])
1844
1845 AC_DEFINE_UNQUOTED(GPGEXT_GPG, "gpg", [The standard binary file suffix])
1846
1847 if test "$have_w32_system" = yes; then
1848   AC_DEFINE_UNQUOTED(GNUPG_REGISTRY_DIR, "Software\\\\GNU\\\\GnuPG",
1849                      [The directory part of the W32 registry keys])
1850 fi
1851
1852
1853 #
1854 # Provide information about the build.
1855 #
1856 BUILD_REVISION="mym4_revision"
1857 AC_SUBST(BUILD_REVISION)
1858 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
1859                    [GIT commit id revision used to build this package])
1860
1861 changequote(,)dnl
1862 BUILD_VERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
1863 changequote([,])dnl
1864 BUILD_VERSION="${BUILD_VERSION}mym4_revision_dec"
1865 BUILD_FILEVERSION=`echo "${BUILD_VERSION}" | tr . ,`
1866 AC_SUBST(BUILD_VERSION)
1867 AC_SUBST(BUILD_FILEVERSION)
1868
1869 AC_ARG_ENABLE([build-timestamp],
1870   AC_HELP_STRING([--enable-build-timestamp],
1871                  [set an explicit build timestamp for reproducibility.
1872                   (default is the current time in ISO-8601 format)]),
1873      [if test "$enableval" = "yes"; then
1874         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
1875       else
1876         BUILD_TIMESTAMP="$enableval"
1877       fi
1878       BUILD_HOSTNAME="$ac_hostname"],
1879      [BUILD_TIMESTAMP="<none>"
1880       BUILD_HOSTNAME="<anon>"])
1881 AC_SUBST(BUILD_TIMESTAMP)
1882 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
1883                    [The time this package was configured for a build])
1884 AC_SUBST(BUILD_HOSTNAME)
1885
1886
1887 #
1888 # Print errors here so that they are visible all
1889 # together and the user can acquire them all together.
1890 #
1891 die=no
1892 if test "$have_gpg_error" = "no"; then
1893    die=yes
1894    AC_MSG_NOTICE([[
1895 ***
1896 *** You need libgpg-error to build this program.
1897 **  This library is for example available at
1898 ***   https://gnupg.org/ftp/gcrypt/libgpg-error
1899 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1900 ***]])
1901 fi
1902 if test "$have_libgcrypt" = "no"; then
1903    die=yes
1904    AC_MSG_NOTICE([[
1905 ***
1906 *** You need libgcrypt to build this program.
1907 **  This library is for example available at
1908 ***   https://gnupg.org/ftp/gcrypt/libgcrypt/
1909 *** (at least version $NEED_LIBGCRYPT_VERSION (API $NEED_LIBGCRYPT_API) is required.)
1910 ***]])
1911 fi
1912 if test "$have_libassuan" = "no"; then
1913    die=yes
1914    AC_MSG_NOTICE([[
1915 ***
1916 *** You need libassuan to build this program.
1917 *** This library is for example available at
1918 ***   https://gnupg.org/ftp/gcrypt/libassuan/
1919 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1920 ***]])
1921 fi
1922 if test "$have_ksba" = "no"; then
1923     die=yes
1924     AC_MSG_NOTICE([[
1925 ***
1926 *** You need libksba to build this program.
1927 *** This library is for example available at
1928 ***   https://gnupg.org/ftp/gcrypt/libksba/
1929 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1930 ***]])
1931 fi
1932 if test "$gnupg_have_ldap" = yes; then
1933   if test "$have_w32ce_system" = yes; then
1934     AC_MSG_NOTICE([[
1935 *** Note that CeGCC might be broken, a package fixing this is:
1936 ***    http://files.kolab.org/local/windows-ce/
1937 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1938 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1939 ***]])
1940    fi
1941 fi
1942 if test "$have_npth" = "no"; then
1943     die=yes
1944     AC_MSG_NOTICE([[
1945 ***
1946 *** It is now required to build with support for the
1947 *** New Portable Threads Library (nPth). Please install this
1948 *** library first.  The library is for example available at
1949 ***   https://gnupg.org/ftp/gcrypt/npth/
1950 *** (at least version $NEED_NPTH_VERSION (API $NEED_NPTH_API) is required).
1951 ***]])
1952 fi
1953
1954 if test "$require_iconv" = yes; then
1955   if test "$am_func_iconv" != yes; then
1956     die=yes
1957     AC_MSG_NOTICE([[
1958 ***
1959 *** The system does not provide a working iconv function.  Please
1960 *** install a suitable library; for example GNU Libiconv which is
1961 *** available at:
1962 ***   https://ftp.gnu.org/gnu/libiconv/
1963 ***]])
1964   fi
1965 fi
1966
1967 if test "$use_ccid_driver" = yes; then
1968   if test "$have_libusb" != yes; then
1969     die=yes
1970     AC_MSG_NOTICE([[
1971 ***
1972 *** You need libusb to build the internal ccid driver.  Please
1973 *** install a libusb suitable for your system.
1974 ***]])
1975   fi
1976 fi
1977
1978 if test "$die" = "yes"; then
1979     AC_MSG_ERROR([[
1980 ***
1981 *** Required libraries not found. Please consult the above messages
1982 *** and install them before running configure again.
1983 ***]])
1984 fi
1985
1986
1987
1988 AC_CONFIG_FILES([ m4/Makefile
1989 Makefile
1990 po/Makefile.in
1991 common/Makefile
1992 common/w32info-rc.h
1993 kbx/Makefile
1994 g10/Makefile
1995 sm/Makefile
1996 agent/Makefile
1997 scd/Makefile
1998 g13/Makefile
1999 dirmngr/Makefile
2000 tools/gpg-zip
2001 tools/Makefile
2002 doc/Makefile
2003 tests/Makefile
2004 tests/gpgscm/Makefile
2005 tests/openpgp/Makefile
2006 tests/migrations/Makefile
2007 tests/gpgsm/Makefile
2008 tests/gpgme/Makefile
2009 tests/pkits/Makefile
2010 g10/gpg.w32-manifest
2011 ])
2012
2013
2014 AC_OUTPUT
2015
2016
2017 echo "
2018         GnuPG v${VERSION} has been configured as follows:
2019
2020         Revision:  mym4_revision  (mym4_revision_dec)
2021         Platform:  $PRINTABLE_OS_NAME ($host)
2022
2023         OpenPGP:   $build_gpg
2024         S/MIME:    $build_gpgsm
2025         Agent:     $build_agent
2026         Smartcard: $build_scdaemon $build_scdaemon_extra
2027         G13:       $build_g13
2028         Dirmngr:   $build_dirmngr
2029         Gpgtar:    $build_gpgtar
2030         WKS tools: $build_wks_tools
2031
2032         Protect tool:      $show_gnupg_protect_tool_pgm
2033         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
2034         Default agent:     $show_gnupg_agent_pgm
2035         Default pinentry:  $show_gnupg_pinentry_pgm
2036         Default scdaemon:  $show_gnupg_scdaemon_pgm
2037         Default dirmngr:   $show_gnupg_dirmngr_pgm
2038
2039         Dirmngr auto start:  $dirmngr_auto_start
2040         Readline support:    $gnupg_cv_have_readline
2041         LDAP support:        $gnupg_have_ldap
2042         TLS support:         $use_tls_library
2043         TOFU support:        $use_tofu
2044         Tor support:         $show_tor_support
2045 "
2046 if test x"$use_regex" != xyes ; then
2047 echo "
2048         Warning: No regular expression support available.
2049                  OpenPGP trust signatures won't work.
2050                  gpg-check-pattern will not be built.
2051 "
2052 fi
2053 if test "x${gpg_config_script_warn}" != x; then
2054 cat <<G10EOF
2055         Warning: Mismatches between the target platform and the
2056                  to be used libraries have been detected for:
2057                   ${gpg_config_script_warn}
2058                  Please check above for more warning messages.
2059
2060 G10EOF
2061 fi