Still making gpg2 work.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 1.9
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002,
3 #               2003, 2004, 2005 Free Software Foundation, Inc.
4
5 # This file is part of GnuPG.
6
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20
21 # Process this file with autoconf to produce a configure script.
22 AC_PREREQ(2.52)
23 min_automake_version="1.9.3"
24
25 # Remember to change the version number immediately *after* a release.
26 # Set my_issvn to "yes" for non-released code.  Remember to run an
27 # "svn up" and "autogen.sh" right before creating a distribution.
28 m4_define([my_version], [1.9.21])
29 m4_define([my_issvn], [yes])
30
31
32 m4_define([svn_revision], m4_esyscmd([echo -n $((svn info 2>/dev/null \
33             || echo 'Revision: 0')|sed -n '/^Revision:/ {s/[^0-9]//gp;q}')]))
34 AC_INIT([gnupg], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
35         [gnupg-devel@gnupg.org])
36 # Set development_version to yes if the minor number is odd or you
37 # feel that the default check for a development version is not
38 # sufficient.
39 development_version=yes
40 NEED_GPG_ERROR_VERSION=1.0
41
42 NEED_LIBGCRYPT_API=1
43 NEED_LIBGCRYPT_VERSION=1.1.94
44
45 NEED_LIBASSUAN_VERSION=0.6.10
46
47 NEED_KSBA_VERSION=0.9.13
48
49
50 PACKAGE=$PACKAGE_NAME
51 PACKAGE_GT=${PACKAGE_NAME}2
52 VERSION=$PACKAGE_VERSION
53
54 AC_CONFIG_AUX_DIR(scripts)
55 AC_CONFIG_SRCDIR(sm/gpgsm.c)
56 AM_CONFIG_HEADER(config.h)
57 AC_CANONICAL_TARGET()
58 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
59
60 AC_GNU_SOURCE
61
62 # Some status variables to give feedback at the end of a configure run
63 have_gpg_error=no
64 have_libgcrypt=no 
65 have_libassuan=no
66 have_ksba=no
67 have_pth=no
68
69 GNUPG_BUILD_PROGRAM(gpg, no)
70 GNUPG_BUILD_PROGRAM(gpgsm, yes)
71 GNUPG_BUILD_PROGRAM(agent, yes)
72 GNUPG_BUILD_PROGRAM(scdaemon, yes)
73 GNUPG_BUILD_PROGRAM(symcryptrun, no)
74
75
76 AC_SUBST(PACKAGE)
77 AC_SUBST(PACKAGE_GT)
78 AC_SUBST(VERSION)
79 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
80 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
81                                 [Name of this package for gettext])
82 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
83 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
84                                         [Bug report address])
85 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
86                                        [Required version of Libgcrypt])
87 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
88                                        [Required version of Libksba])
89
90
91
92 # The default is to use the modules from this package and the few
93 # other packages in a standard place; i.e where this package gets
94 # installed.  With these options it is possible to override these
95 # ${prefix} depended values with fixed paths, which can't be replaced
96 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
97 AC_ARG_WITH(agent-pgm,
98     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
99           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
100 AC_SUBST(GNUPG_AGENT_PGM)
101 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
102 show_gnupg_agent_pgm="(default)"
103 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
104
105 AC_ARG_WITH(pinentry-pgm,
106     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
107           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
108 AC_SUBST(GNUPG_PINENTRY_PGM)
109 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
110 show_gnupg_pinentry_pgm="(default)"
111 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
112
113
114 AC_ARG_WITH(scdaemon-pgm,
115     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
116           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
117 AC_SUBST(GNUPG_SCDAEMON_PGM)
118 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
119 show_gnupg_scdaemon_pgm="(default)"
120 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
121
122
123 AC_ARG_WITH(dirmngr-pgm,
124     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
125           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
126 AC_SUBST(GNUPG_DIRMNGR_PGM)
127 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
128 show_gnupg_dirmngr_pgm="(default)"
129 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
130
131 AC_ARG_WITH(protect-tool-pgm,
132     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
133           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
134 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
135 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
136 show_gnupg_protect_tool_pgm="(default)"
137 test -n "$GNUPG_PROTECT_TOOL_PGM" \
138       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
139
140
141
142 # Some folks want to use only the agent form this packet.  Make it
143 # easier for them by providing the configure option
144 # --enable-only-agent.
145 AC_ARG_ENABLE(agent-only,
146     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
147     build_agent_only=$enableval)
148
149
150 # Allow disabling of bzib2 support.
151 # It is defined only after we confirm the library is available later
152 use_bzip2=yes
153 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
154 AC_ARG_ENABLE(bzip2,
155    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
156    use_bzip2=$enableval)
157 AC_MSG_RESULT($use_bzip2)
158
159
160 # Configure option to allow or disallow execution of external
161 # programs, like a photo viewer.
162 AC_MSG_CHECKING([whether to enable external program execution])
163 AC_ARG_ENABLE(exec,
164     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
165     use_exec=$enableval)
166 AC_MSG_RESULT($use_exec)
167 if test "$use_exec" = no ; then
168     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
169 fi
170
171 if test "$use_exec" = yes ; then
172   AC_MSG_CHECKING([whether to enable photo ID viewing])
173   AC_ARG_ENABLE(photo-viewers,
174       [  --disable-photo-viewers disable photo ID viewers],
175       [if test "$enableval" = no ; then
176          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
177       fi],enableval=yes)
178   gnupg_cv_enable_photo_viewers=$enableval
179   AC_MSG_RESULT($enableval)
180
181   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
182     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
183     AC_ARG_WITH(photo-viewer,
184         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
185         [if test "$withval" = yes ; then
186            withval=no
187         elif test "$withval" != no ; then
188            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
189                             [if set, restrict photo-viewer to this])
190         fi],withval=no)
191     AC_MSG_RESULT($withval)
192   fi
193
194   AC_MSG_CHECKING([whether to enable external keyserver helpers])
195   AC_ARG_ENABLE(keyserver-helpers,
196       [  --disable-keyserver-helpers  disable all external keyserver support],
197       [if test "$enableval" = no ; then
198          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
199                   [define to disable keyserver helpers])
200       fi],enableval=yes)
201   gnupg_cv_enable_keyserver_helpers=$enableval
202   AC_MSG_RESULT($enableval)
203
204   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
205     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
206     AC_ARG_ENABLE(ldap,
207     [  --disable-ldap          disable LDAP keyserver interface],
208         try_ldap=$enableval, try_ldap=yes)
209     AC_MSG_RESULT($try_ldap)
210
211     AC_MSG_CHECKING([whether HKP keyserver support is requested])
212     AC_ARG_ENABLE(hkp,
213     [  --disable-hkp           disable HKP keyserver interface],
214         try_hkp=$enableval, try_hkp=yes)
215     AC_MSG_RESULT($try_hkp)
216
217     if test "$try_hkp" = yes ; then
218       AC_SUBST(GPGKEYS_HKP,"gpgkeys_hkp$EXEEXT")
219     fi
220
221     AC_MSG_CHECKING([whether email keyserver support is requested])
222     AC_ARG_ENABLE(mailto,
223     [  --disable-mailto        disable email keyserver interface],
224         try_mailto=$enableval, try_mailto=yes)
225     AC_MSG_RESULT($try_mailto)
226     fi
227
228     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
229     AC_ARG_ENABLE(keyserver-path,
230         [  --disable-keyserver-path disable the exec-path option for keyserver helpers],
231         [if test "$enableval" = no ; then
232          AC_DEFINE(DISABLE_KEYSERVER_PATH,1,[define to disable exec-path for keyserver helpers])
233         fi],enableval=yes)
234     AC_MSG_RESULT($enableval)
235   fi
236
237
238 dnl
239 dnl Check for the key/uid cache size.  This can't be zero, but can be
240 dnl pretty small on embedded systems.
241 dnl
242 AC_MSG_CHECKING([for the size of the key and uid cache])
243 AC_ARG_ENABLE(key-cache,
244         AC_HELP_STRING([--enable-key-cache=SIZE],[Set key cache to SIZE (default 4096)]),,enableval=4096)
245
246 if test "$enableval" = "no"; then
247    enableval=5
248 elif test "$enableval" = "yes" || test "$enableval" = ""; then
249    enableval=4096
250 fi
251
252 changequote(,)dnl
253 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
254 changequote([,])dnl
255
256 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
257    AC_MSG_ERROR([invalid key-cache size])
258 fi
259
260 AC_MSG_RESULT($key_cache_size)
261 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,[Size of the key and UID caches])
262
263
264
265 dnl
266 dnl Check whether we want to use Linux capabilities
267 dnl
268 AC_MSG_CHECKING([whether use of capabilities is requested])
269 AC_ARG_WITH(capabilities,
270     [  --with-capabilities     use linux capabilities [default=no]],
271 [use_capabilities="$withval"],[use_capabilities=no])
272 AC_MSG_RESULT($use_capabilities)
273
274
275 AH_BOTTOM([
276 /* Some global constants. */
277 #ifdef HAVE_DRIVE_LETTERS
278 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
279 #elif defined(__VMS)
280 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg" 
281 #else
282 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
283 #endif 
284 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
285
286 /* Tell libgcrypt not to use its own libgpg-error implementation. */
287 #define USE_LIBGPG_ERROR 1
288
289 /* This is the major version number of GnuPG so that
290    source included files can test for this.  Note, that\
291    we use 2 here even for GnuPG 1.9.x. */
292 #define GNUPG_MAJOR_VERSION 2
293
294 /* Now to separate file name parts.
295    Please note that the string version must not contain more
296    than one character because the code assumes strlen()==1 */
297 #ifdef HAVE_DOSISH_SYSTEM
298 #define DIRSEP_C '\\'
299 #define DIRSEP_S "\\"
300 #define EXTSEP_C '.'
301 #define EXTSEP_S "."
302 #define PATHSEP_C ';'
303 #define PATHSEP_S ";"
304 #define EXEEXT_S ".exe"
305 #else
306 #define DIRSEP_C '/'
307 #define DIRSEP_S "/"
308 #define EXTSEP_C '.'
309 #define EXTSEP_S "."
310 #define PATHSEP_C ':'
311 #define PATHSEP_S ":"
312 #define EXEEXT_S ""
313 #endif
314
315 /* This is the same as VERSION, but should be overridden if the
316    platform cannot handle things like dots '.' in filenames. Set
317    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
318    uses for dots and dashes. */
319 #define SAFE_VERSION VERSION
320 #define SAFE_VERSION_DOT  '.'
321 #define SAFE_VERSION_DASH '-'
322
323 /* For some systems (DOS currently), we hardcode the path here.  For
324    POSIX systems the values are constructed by the Makefiles, so that
325    the values may be overridden by the make invocations; this is to
326    comply with the GNU coding standards. */
327 #ifdef HAVE_DRIVE_LETTERS
328 #define GNUPG_BINDIR      "c:\\gnupg"
329 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
330 #define GNUPG_LIBDIR      "c:\\gnupg"
331 #define GNUPG_DATADIR     "c:\\gnupg"
332 #endif
333
334 /* Setup the hardwired names of modules. */
335 #ifndef GNUPG_DEFAULT_AGENT
336 #define GNUPG_DEFAULT_AGENT    ( GNUPG_BINDIR DIRSEP_S "gpg-agent" EXEEXT_S )
337 #endif
338 #ifndef GNUPG_DEFAULT_PINENTRY
339 #define GNUPG_DEFAULT_PINENTRY ( GNUPG_BINDIR DIRSEP_S "pinentry" EXEEXT_S )
340 #endif
341 #ifndef GNUPG_DEFAULT_SCDAEMON
342 #define GNUPG_DEFAULT_SCDAEMON ( GNUPG_BINDIR DIRSEP_S "scdaemon" EXEEXT_S )
343 #endif
344 #ifndef GNUPG_DEFAULT_DIRMNGR
345 #define GNUPG_DEFAULT_DIRMNGR  ( GNUPG_BINDIR DIRSEP_S "dirmngr" EXEEXT_S )
346 #endif
347 #ifndef GNUPG_DEFAULT_PROTECT_TOOL
348 #define GNUPG_DEFAULT_PROTECT_TOOL \
349                     ( GNUPG_LIBEXECDIR DIRSEP_S "gpg-protect-tool" EXEEXT_S )
350 #endif
351
352
353 /* Derive some other constants. */
354 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
355 #define EXEC_TEMPFILE_ONLY
356 #endif
357
358 /* Temporary hacks to avoid requring a libgpg-error update. */
359 #if !HAVE_DECL_GPG_ERR_LOCKED
360 #define GPG_ERR_LOCKED  173
361 #endif
362
363 ])
364
365 AM_MAINTAINER_MODE
366
367 # Checks for programs.
368 AC_PROG_MAKE_SET
369 AM_SANITY_CHECK
370 missing_dir=`cd $ac_aux_dir && pwd`
371 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
372 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
373 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
374 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
375 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
376 AC_PROG_AWK
377 AC_PROG_CC
378 AC_PROG_CPP
379 AC_PROG_INSTALL
380 AC_PROG_LN_S
381 AC_PROG_MAKE_SET
382 AC_PROG_RANLIB
383 AC_CHECK_TOOL(AR, ar, :)
384 AC_PATH_PROG(PERL,"perl")
385 AC_ISC_POSIX
386 gl_EARLY
387 AC_SYS_LARGEFILE
388 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
389 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
390 GNUPG_CHECK_FAQPROG
391 GNUPG_CHECK_DOCBOOK_TO_TEXI
392
393
394 try_gettext=yes
395 have_dosish_system=no
396 have_w32_system=no
397 case "${host}" in
398     *-mingw32*)
399         # special stuff for Windoze NT
400         ac_cv_have_dev_random=no
401         AC_DEFINE(USE_ONLY_8DOT3,1,
402                   [set this to limit filenames to the 8.3 format])
403         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
404                   [defined if we must run on a stupid file system])
405         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
406                   [because the Unix gettext has too much overhead on
407                    MingW32 systems and these systems lack Posix functions,
408                    we use a simplified version of gettext])
409         have_dosish_system=yes
410         have_w32_system=yes
411         try_gettext="no"
412         ;;
413     i?86-emx-os2 | i?86-*-os2*emx )
414         # OS/2 with the EMX environment
415         ac_cv_have_dev_random=no
416         AC_DEFINE(HAVE_DRIVE_LETTERS)
417         have_dosish_system=yes
418         try_gettext="no"
419         ;;
420
421     i?86-*-msdosdjgpp*)
422         # DOS with the DJGPP environment
423         ac_cv_have_dev_random=no
424         AC_DEFINE(HAVE_DRIVE_LETTERS)
425         have_dosish_system=yes
426         try_gettext="no"
427         ;;
428
429     *-*-freebsd*)
430        # FreeBSD
431        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
432        LDFLAGS="$LDFLAGS -L/usr/local/lib"
433        ;;
434
435     *-*-hpux*)
436         if test -z "$GCC" ; then
437             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
438         fi
439         ;;
440     *-dec-osf4*)
441         if test -z "$GCC" ; then
442             # Suppress all warnings
443             # to get rid of the unsigned/signed char mismatch warnings.
444             CFLAGS="$CFLAGS -w"
445         fi
446         ;;
447     *-dec-osf5*)
448         if test -z "$GCC" ; then
449             # Use the newer compiler `-msg_disable ptrmismatch' to
450             # get rid of the unsigned/signed char mismatch warnings.
451             # Using this may hide other pointer mismatch warnings, but
452             # it at least lets other warning classes through
453             CFLAGS="$CFLAGS -msg_disable ptrmismatch"
454         fi
455         ;;
456     m68k-atari-mint)
457         ;;
458     *)
459        ;;
460 esac
461
462 if test "$have_dosish_system" = yes; then
463    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
464              [Defined if we run on some of the PCDOS like systems 
465               (DOS, Windoze. OS/2) with special properties like
466               no file modes])
467 fi
468 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
469
470 if test "$have_w32_system" = yes; then
471    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
472 fi
473 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
474
475 # These need to go after AC_PROG_CC so that $EXEEXT is defined
476 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
477
478
479 #
480 # Checks for libraries.
481 #
482
483
484 #
485 # libgpg-error is a library with error codes shared between GnuPG
486 # related projects.
487 #
488 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
489                   have_gpg_error=yes,have_gpg_error=no)
490 _tmp_gpg_error_save_cflags="$CFLAGS"
491 CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
492 AC_CHECK_DECLS(GPG_ERR_LOCKED,,,[#include <gpg-error.h>])
493 CFLAGS="${_tmp_gpg_error_save_cflags}"
494
495
496 #
497 # Libgcrypt is our generic crypto library
498 #
499 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
500         have_libgcrypt=yes,have_libgcrypt=no)
501
502
503 #
504 # libassuan is used for IPC
505 #
506 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_VERSION",
507                   have_libassuan=yes,have_libassuan=no)
508
509
510 #
511 # libksba is our X.509 support library
512 #
513 AM_PATH_KSBA("$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
514
515 #
516 # libusb allows us to use the integrated CCID smartcard reader driver.
517 #
518 AC_CHECK_LIB(usb, usb_bulk_write,
519               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
520                 AC_DEFINE(HAVE_LIBUSB,1,
521                          [defined if libusb is available])
522              ])
523 AC_SUBST(LIBUSB_LIBS)
524 AC_CHECK_FUNCS(usb_create_match)
525
526 #
527 # Check wether it is necessary to link against libdl.
528 #
529 LIBS=""
530 AC_SEARCH_LIBS(dlopen, c dl,,,)
531 DL_LIBS=$LIBS
532 AC_SUBST(DL_LIBS)
533
534 #
535 # Checks for symcryptrun:
536 #
537
538 # libutil has openpty() and login_tty().
539 AC_CHECK_LIB(util, openpty,
540               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
541                 AC_DEFINE(HAVE_LIBUTIL,1,
542                          [defined if libutil is available])
543              ])
544 AC_SUBST(LIBUTIL_LIBS)
545
546 # shred is used to clean temporary plain text files.
547 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
548 AC_DEFINE_UNQUOTED(SHRED,
549         "${SHRED}", [defines the filename of the shred program])
550
551
552 #
553 # Check whether the (highly desirable) GNU Pth library is available
554 # Note, that we include a Pth emulation for W32.
555 #
556 AC_ARG_WITH(pth-prefix,
557             AC_HELP_STRING([--with-pth-prefix=PFX],
558                            [prefix where GNU Pth is installed (optional)]),
559      pth_config_prefix="$withval", pth_config_prefix="")
560 if test x$pth_config_prefix != x ; then
561    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
562 fi
563 AC_PATH_PROG(PTH_CONFIG, pth-config, no)
564 if test "$have_w32_system" = no; then
565  if test "$PTH_CONFIG" = "no"; then
566     AC_MSG_WARN([[
567 ***
568 *** To support concurrent access to the gpg-agent and the SCdaemon
569 *** we need the support of the GNU Portable Threads Library.
570 *** Download it from ftp://ftp.gnu.org/gnu/pth/
571 *** On a Debian GNU/Linux system you might want to try 
572 ***   apt-get install libpth-dev
573 ***]])
574  else
575   GNUPG_PTH_VERSION_CHECK(1.3.7)
576   if test $have_pth = yes; then      
577      PTH_CFLAGS=`$PTH_CONFIG --cflags`
578      PTH_LIBS=`$PTH_CONFIG --ldflags`
579      PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs`"
580      AC_DEFINE(USE_GNU_PTH, 1,
581               [Defined if the GNU Portable Thread Library should be used])
582      AC_DEFINE(HAVE_PTH, 1,
583               [Defined if the GNU Pth is available])
584   fi
585  fi
586 else 
587  have_pth=yes
588  PTH_CFLAGS=""
589  PTH_LIBS=""
590  AC_DEFINE(USE_GNU_PTH, 1)
591  AC_DEFINE(HAVE_PTH, 1)
592 fi
593 AC_SUBST(PTH_CFLAGS)
594 AC_SUBST(PTH_LIBS)
595
596
597 dnl Must check for network library requirements before doing link tests
598 dnl for ldap, for example. If ldap libs are static (or dynamic and without
599 dnl ELF runtime link paths), then link will fail and LDAP support won't
600 dnl be detected.
601
602 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
603         [NETLIBS="-lnsl $NETLIBS"]))
604 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
605         [NETLIBS="-lsocket $NETLIBS"]))
606
607 dnl Now try for the resolver functions so we can use DNS SRV
608
609 AC_ARG_ENABLE(dns-srv,
610    AC_HELP_STRING([--disable-dns-srv],[disable the use of DNS SRV in HKP]),
611    use_dns_srv=$enableval,use_dns_srv=yes)
612
613 if test x"$try_hkp" = xyes && test x"$use_dns_srv" = xyes ; then
614   _srv_save_libs=$LIBS
615   LIBS=""
616   # the double underscore thing is a glibc-ism?
617   AC_SEARCH_LIBS(res_query,resolv bind,,
618                  AC_SEARCH_LIBS(__res_query,resolv bind,,use_dns_srv=no))
619   AC_SEARCH_LIBS(dn_expand,resolv bind,,
620                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,use_dns_srv=no))
621   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
622                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,use_dns_srv=no))
623
624   if test x"$use_dns_srv" = xyes ; then
625      AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
626      SRVLIBS=$LIBS
627   else
628      AC_MSG_WARN([Resolver functions not found.  Disabling DNS SRV.])
629   fi
630   LIBS=$_srv_save_libs
631 fi
632
633 AC_SUBST(SRVLIBS)
634
635 # Try and link a LDAP test program to weed out unusable LDAP
636 # libraries.  -lldap [-llber [-lresolv]] is for OpenLDAP.  OpenLDAP in
637 # general is terrible with creating weird dependencies.  If all else
638 # fails, the user can play guess-the-dependency by using something
639 # like ./configure LDAPLIBS="-Lfoo -lbar"
640
641 if test "$try_ldap" = yes ; then
642   for MY_LDAPLIBS in ${LDAPLIBS+"$LDAPLIBS"} "-lldap" "-lldap -llber" "-lldap -llber -lresolv"; do
643     _ldap_save_libs=$LIBS
644     LIBS="$MY_LDAPLIBS $NETLIBS $LIBS"
645
646     AC_MSG_CHECKING([whether LDAP via \"$MY_LDAPLIBS\" is present and sane])
647     AC_TRY_LINK([#include <ldap.h>],[ldap_open("foobar",1234);],
648                 [gnupg_cv_func_ldap_init=yes],[gnupg_cv_func_ldap_init=no])
649     AC_MSG_RESULT([$gnupg_cv_func_ldap_init])
650
651     if test $gnupg_cv_func_ldap_init = no; then
652       AC_MSG_CHECKING([whether I can make LDAP be sane with lber.h])
653       AC_TRY_LINK([#include <lber.h>
654 #include <ldap.h>],[ldap_open("foobar",1234);],
655          [gnupg_cv_func_ldaplber_init=yes],[gnupg_cv_func_ldaplber_init=no])
656       AC_MSG_RESULT([$gnupg_cv_func_ldaplber_init])
657     fi
658
659     if test "$gnupg_cv_func_ldaplber_init" = yes ; then
660        AC_DEFINE(NEED_LBER_H,1,[Define if the LDAP library requires including lber.h before ldap.h])
661     fi
662
663     if test "$gnupg_cv_func_ldap_init" = yes || \
664         test "$gnupg_cv_func_ldaplber_init" = yes ; then
665        LDAPLIBS=$MY_LDAPLIBS
666        GPGKEYS_LDAP="gpgkeys_ldap$EXEEXT"
667
668        AC_MSG_CHECKING([whether LDAP supports ldap_get_option])
669
670        if test "$gnupg_cv_func_ldap_init" = yes ; then
671           AC_TRY_LINK([#include <ldap.h>],
672              [ldap_get_option((void *)0,0,(void *)0);],
673              [gnupg_cv_func_ldap_get_option=yes],
674              [gnupg_cv_func_ldap_get_option=no])
675         else
676           AC_TRY_LINK([#include <lber.h>
677 #include <ldap.h>],[ldap_get_option((void *)0,0,(void *)0);],
678              [gnupg_cv_func_ldap_get_option=yes],
679              [gnupg_cv_func_ldap_get_option=no])
680        fi
681
682        AC_MSG_RESULT([$gnupg_cv_func_ldap_get_option])
683
684        if test "$gnupg_cv_func_ldap_get_option" = yes ; then
685           AC_DEFINE(HAVE_LDAP_GET_OPTION,1,[Define if the LDAP library has ldap_get_option])
686        else
687           AC_MSG_CHECKING([whether LDAP supports ld_errno])
688
689           if test "$gnupg_cv_func_ldap_init" = yes ; then
690             AC_TRY_COMPILE([#include <ldap.h>],
691                [LDAP *ldap; ldap->ld_errno;],
692                [gnupg_cv_func_ldap_ld_errno=yes],
693                [gnupg_cv_func_ldap_ld_errno=no])
694            else
695             AC_TRY_LINK([#include <lber.h>
696 #include <ldap.h>],[LDAP *ldap; ldap->ld_errno;],
697                [gnupg_cv_func_ldap_ld_errno=yes],
698                [gnupg_cv_func_ldap_ld_errno=no])
699           fi
700
701           AC_MSG_RESULT([$gnupg_cv_func_ldap_ld_errno])
702
703           if test "$gnupg_cv_func_ldap_ld_errno" = yes ; then
704              AC_DEFINE(HAVE_LDAP_LD_ERRNO,1,[Define if the LDAP library supports ld_errno])
705           fi
706        fi
707     fi
708
709     LIBS=$_ldap_save_libs
710
711     if test "$GPGKEYS_LDAP" != "" ; then break; fi
712   done
713 fi
714
715 AC_SUBST(GPGKEYS_LDAP)
716 AC_SUBST(LDAPLIBS)
717
718 dnl This isn't necessarily sendmail itself, but anything that gives a
719 dnl sendmail-ish interface to the outside world.  That includes qmail,
720 dnl postfix, etc.  Basically, anything that can handle "sendmail -t".
721
722 if test "$try_mailto" = yes ; then
723   AC_ARG_WITH(mailprog,[  --with-mailprog=NAME    use "NAME -t" for mail transport],,with_mailprog=yes)
724
725   if test "$with_mailprog" = yes ; then
726     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
727     if test "$ac_cv_path_SENDMAIL" ; then
728       GPGKEYS_MAILTO="gpgkeys_mailto"
729     fi
730   elif test "$with_mailprog" != no ; then
731     AC_MSG_CHECKING([for a mail transport program])
732     AC_SUBST(SENDMAIL,$with_mailprog)
733     AC_MSG_RESULT($with_mailprog)
734     GPGKEYS_MAILTO="gpgkeys_mailto"
735   fi
736 fi
737
738 AC_SUBST(GPGKEYS_MAILTO)
739
740 case "${host}" in
741     *-mingw32*)
742         PRINTABLE_OS_NAME="MingW32"
743         ;;
744     *-*-cygwin*)
745         PRINTABLE_OS_NAME="Cygwin"
746         ;;
747     i?86-emx-os2 | i?86-*-os2*emx )
748         PRINTABLE_OS_NAME="OS/2"
749         ;;
750     i?86-*-msdosdjgpp*)
751         PRINTABLE_OS_NAME="MSDOS/DJGPP"
752         try_dynload=no
753         ;;
754     *-linux*)
755         PRINTABLE_OS_NAME="GNU/Linux"
756         ;;
757     *)
758         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
759         ;;
760 esac
761 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
762                    [A human readable text with the name of the OS])
763
764
765 AM_GNU_GETTEXT_VERSION(0.14.1)
766 if test "$try_gettext" = yes; then
767   AM_GNU_GETTEXT(,[need-ngettext])
768
769   # gettext requires some extra checks.  These really should be part of
770   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
771   # function checks to here.
772
773   AC_CHECK_FUNCS(strchr)
774 else
775   USE_NLS=no
776   USE_INCLUDED_LIBINTL=no
777   BUILD_INCLUDED_LIBINTL=no
778   AC_SUBST(USE_NLS)
779   AC_SUBST(USE_INCLUDED_LIBINTL)
780   AC_SUBST(BUILD_INCLUDED_LIBINTL)
781 fi
782
783 # Checks for header files.
784 AC_HEADER_STDC
785 AC_CHECK_HEADERS(string.h unistd.h langinfo.h termio.h locale.h)
786
787 # Checks for typedefs, structures, and compiler characteristics.
788 AC_C_CONST
789 AC_C_INLINE
790 AC_TYPE_SIZE_T
791 AC_TYPE_SIGNAL
792 AC_DECL_SYS_SIGLIST
793
794 GNUPG_CHECK_ENDIAN
795
796 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
797 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
798 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
799 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
800 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
801
802 AC_CHECK_SIZEOF(unsigned short)
803 AC_CHECK_SIZEOF(unsigned int)
804 AC_CHECK_SIZEOF(unsigned long)
805 AC_CHECK_SIZEOF(unsigned long long)
806 # Ensure that we have UINT64_C before we bother to check for uint64_t
807 # fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
808 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
809    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
810 uint64_t foo=UINT64_C(42);]),gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
811 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
812    AC_CHECK_SIZEOF(uint64_t)
813 fi
814  
815
816
817
818 if test "$ac_cv_sizeof_unsigned_short" = "0" \
819    || test "$ac_cv_sizeof_unsigned_int" = "0" \
820    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
821     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
822 fi
823
824 dnl Do we have any 64-bit data types?
825 if test "$ac_cv_sizeof_unsigned_int" != "8" \
826    && test "$ac_cv_sizeof_unsigned_long" != "8" \
827    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
828    && test "$ac_cv_sizeof_uint64_t" != "8"; then
829     AC_MSG_WARN([No 64-bit types.  Disabling SHA-384, and SHA-512])
830 else
831   if test x"$use_sha512" = xyes ; then
832      AC_SUBST(SHA512_O,sha512.o)
833      AC_DEFINE(USE_SHA512,1,[Define to include the SHA-384 and SHA-512 digests])
834   fi
835 fi
836
837 # fixme: do we really need this - it should be encapsulated in libassuan
838 GNUPG_SYS_SO_PEERCRED
839
840 # Checks for library functions.
841 AC_FUNC_FSEEKO
842 AC_FUNC_VPRINTF
843 AC_FUNC_FORK
844 AC_CHECK_FUNCS(strerror stpcpy strsep strlwr tcgetattr strtoul mmap)
845 AC_CHECK_FUNCS(strcasecmp strncasecmp ctermid times gmtime_r)
846 AC_CHECK_FUNCS(memmove gettimeofday getrusage setrlimit clock_gettime)
847 AC_CHECK_FUNCS(atexit raise getpagesize strftime nl_langinfo setlocale)
848 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask rand pipe stat getaddrinfo)
849 AC_CHECK_FUNCS(fseeko ftello ttyname isascii)
850
851 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
852
853 # gnulib checks
854 gl_SOURCE_BASE(gl)
855 gl_M4_BASE(gl/m4)
856 gl_MODULES(setenv strsep mkdtemp vasprintf xsize)
857 gl_INIT
858
859 # These are needed by libjnlib - fixme: we should have macros for them
860 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp strtol)
861 AC_CHECK_FUNCS(getrusage setrlimit stat setlocale)
862 AC_CHECK_FUNCS(flockfile funlockfile fopencookie funopen)
863
864
865 #
866 # check for gethrtime and run a testprogram to see whether
867 # it is broken.  It has been reported that some Solaris and HP UX systems 
868 # raise an SIGILL
869 #
870 #  fixme: Do we need this - iirc, this is only used by libgcrypt.
871 #
872 AC_CACHE_CHECK([for gethrtime], 
873                [gnupg_cv_func_gethrtime],
874                [AC_TRY_LINK([#include <sys/times.h>],[
875                    hrtime_t tv;
876                    tv = gethrtime();
877                  ],
878                  [gnupg_cv_func_gethrtime=yes],
879                  [gnupg_cv_func_gethrtime=no])
880                ])
881 if test $gnupg_cv_func_gethrtime = yes; then
882      AC_DEFINE([HAVE_GETHRTIME], 1,
883                [Define if you have the `gethrtime(2)' function.])
884      AC_CACHE_CHECK([whether gethrtime is broken], 
885                [gnupg_cv_func_broken_gethrtime],
886                [AC_TRY_RUN([
887                    #include <sys/times.h>
888                    int main () {
889                    hrtime_t tv;
890                    tv = gethrtime(); 
891                  }
892                  ],
893                  [gnupg_cv_func_broken_gethrtime=no],
894                  [gnupg_cv_func_broken_gethrtime=yes],
895                  [gnupg_cv_func_broken_gethrtime=assume-no])
896                 ])
897     if test $gnupg_cv_func_broken_gethrtime = yes; then
898       AC_DEFINE([HAVE_BROKEN_GETHRTIME], 1,
899       [Define if `gethrtime(2)' does not work correctly i.e. issues a SIGILL.])
900     fi
901 fi
902      
903
904 GNUPG_CHECK_MLOCK
905 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
906
907 dnl
908 dnl Check whether we can use Linux capabilities as requested
909 dnl
910 #  fixme: Still required?
911 #
912 if test "$use_capabilities" = "yes" ; then
913 use_capabilities=no
914 AC_CHECK_HEADERS(sys/capability.h)
915 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
916   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
917   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
918      AC_DEFINE(USE_CAPABILITIES,1,
919                [define if capabilities should be used])
920      AC_SUBST(CAPLIBS,"-lcap")
921      use_capabilities=yes
922   fi
923 fi
924 if test "$use_capabilities" = "no" ; then
925     AC_MSG_WARN([[
926 ***
927 *** The use of capabilities on this system is not possible.
928 *** You need a recent Linux kernel and some patches:
929 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
930 ***   fcap-module-990613.tar.gz     (kernel module)
931 ***   libcap-1.92.tar.gz            (user mode library and utilities)
932 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
933 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
934 ***]])
935 fi
936 fi
937
938
939 # Sanity check regex.  Tests adapted from mutt.
940
941 AC_MSG_CHECKING([whether regular expression support is requested])
942 AC_ARG_ENABLE(regex,
943 [  --disable-regex         do not handle regular expressions in trust sigs],
944      use_regex=$enableval, use_regex=yes)
945 AC_MSG_RESULT($use_regex)
946
947 if test "$use_regex" = yes ; then
948   AC_MSG_CHECKING([whether the included regex lib is requested])
949   AC_ARG_WITH(included-regex,
950       [  --with-included-regex   use the included GNU regex library],
951       [gnupg_cv_included_regex="$withval"],[gnupg_cv_included_regex=no])
952   AC_MSG_RESULT($gnupg_cv_included_regex)
953
954   if test $gnupg_cv_included_regex = no ; then
955      # Does the system have regex functions at all?
956      AC_CHECK_FUNC(regcomp,gnupg_cv_included_regex=no,
957                            gnupg_cv_included_regex=yes)
958   fi
959
960   if test $gnupg_cv_included_regex = no ; then
961      AC_CACHE_CHECK([whether your system's regexp library is broken],
962        [gnupg_cv_regex_broken],
963        AC_TRY_RUN([
964 #include <unistd.h>
965 #include <regex.h>
966 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
967        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
968
969      if test $gnupg_cv_regex_broken = yes ; then
970       AC_MSG_WARN(your regex is broken - using the included GNU regex instead.)
971       gnupg_cv_included_regex=yes
972      fi
973   fi
974
975   if test $gnupg_cv_included_regex = yes; then
976      AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex lib ])
977      AC_SUBST(REGEX_O,regex.o)
978   fi
979 else
980
981   AC_DEFINE(DISABLE_REGEX,1,[ Define to disable regular expression support ])
982 fi
983
984 #
985 # Do we have zlib? Must do it here because Solaris failed
986 # when compiling a conftest (due to the "-lz" from LIBS).
987 # Note that we combine zlib and bzlib2 in ZLIBS.
988 #
989 _cppflags="${CPPFLAGS}"
990 _ldflags="${LDFLAGS}"
991 AC_ARG_WITH(zlib,
992   [  --with-zlib=DIR         use libz in DIR],[
993     if test -d "$withval"; then
994       CPPFLAGS="${CPPFLAGS} -I$withval/include"
995       LDFLAGS="${LDFLAGS} -L$withval/lib"
996     fi
997   ])
998
999 AC_CHECK_HEADER(zlib.h,
1000       AC_CHECK_LIB(z, deflateInit2_,
1001        ZLIBS="-lz",
1002        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1003        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1004
1005 #
1006 # Check whether we can support bzip2
1007
1008 if test "$use_bzip2" = yes ; then
1009   _cppflags="${CPPFLAGS}"
1010   _ldflags="${LDFLAGS}"
1011   AC_ARG_WITH(bzip2,
1012      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1013       [
1014       if test -d "$withval" ; then
1015         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1016         LDFLAGS="${LDFLAGS} -L$withval/lib"
1017       fi
1018       ],withval="")
1019
1020   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1021   # required stdio.h to be included before bzlib.h, and Solaris 9 is 
1022   # woefully out of date.
1023   if test "$withval" != no ; then
1024      AC_CHECK_HEADER(bzlib.h,
1025         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1026           [
1027           have_bz2=yes
1028           ZLIBS="$ZLIBS -lbz2"
1029           AC_DEFINE(HAVE_BZIP2,1,
1030                   [Defined if the bz2 compression library is available])
1031           ],
1032           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1033           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1034   fi
1035 fi
1036 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1037 AC_SUBST(ZLIBS)
1038
1039
1040 # See wether we want to run the long test suite.
1041 AC_ARG_WITH(pkits-tests,
1042     AC_HELP_STRING([--with-pkits-tests],[run the PKITS based tests]),
1043     [run_pkits_tests=$withval], [run_pkits_tests=no])
1044 AM_CONDITIONAL(RUN_PKITS_TESTS, test "$run_pkits_tests" = "yes")
1045
1046
1047 # Allow users to append something to the version string without
1048 # flagging it as development version.  The user version parts is
1049 # considered everything after a dash. 
1050 if test "$development_version" != yes; then
1051   changequote(,)dnl
1052   tmp_pat='[a-zA-Z]'
1053   changequote([,])dnl
1054   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1055     development_version=yes
1056   fi
1057 fi
1058 if test "$development_version" = yes; then
1059     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1060             [Defined if this is not a regular release])
1061 fi
1062
1063 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1064
1065 GNUPG_CHECK_GNUMAKE
1066
1067 # Add some extra libs here so that previous tests don't fail for
1068 # mysterious reasons - the final link step should bail out. 
1069 if test "$have_w32_system" = yes; then
1070    W32LIBS="-lwsock32"
1071 fi
1072
1073
1074 if test "$GCC" = yes; then
1075     if test "$USE_MAINTAINER_MODE" = "yes"; then
1076         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1077         CFLAGS="$CFLAGS -Wno-format-y2k -Wformat-security"
1078     else
1079         CFLAGS="$CFLAGS -Wall"
1080     fi
1081 fi
1082
1083 #
1084 # This is handy for debugging so the compiler doesn't rearrange
1085 # things and eliminate variables.
1086 #
1087 AC_ARG_ENABLE(optimization,
1088    AC_HELP_STRING([--disable-optimization],
1089                   [disable compiler optimization]),
1090                   [if test $enableval = no ; then
1091                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1092                    fi])
1093
1094
1095
1096
1097 AC_SUBST(NETLIBS)
1098 AC_SUBST(W32LIBS)
1099
1100
1101 # We use jnlib, so tell other modules about it
1102 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
1103           [Defined if jnlib style logging functions are available])
1104
1105 # For W32 we need to use our Pth emulation code
1106 if test "$have_w32_system" = yes; then
1107   AC_CONFIG_LINKS(pth.h:jnlib/w32-pth.h)
1108 fi
1109
1110
1111 #
1112 # Decide what to build
1113 #
1114 missing_pth=no
1115 if test $have_ksba = no; then
1116   build_gpgsm=no
1117   build_scdaemon=no
1118 fi
1119
1120 build_agent_threaded=""
1121 if test "$build_agent" = "yes"; then
1122   if test $have_pth = no; then
1123      build_agent_threaded="(not multi-threaded)"
1124      missing_pth=yes
1125   fi
1126 fi
1127
1128 build_scdaemon_extra=""
1129 if test "$build_scdaemon" = "yes"; then
1130   tmp=""
1131   if test $have_pth = no; then
1132      build_scdaemon_extra="not multi-threaded"
1133      tmp=", "
1134      missing_pth=yes
1135   fi
1136   if test -n "$build_scdaemon_extra"; then
1137      build_scdaemon_extra="(${build_scdaemon_extra})"
1138   fi
1139 fi
1140
1141
1142 if test "$build_agent_only" = "yes" ; then
1143   build_gpg=no
1144   build_gpgsm=no
1145   build_scdaemon=no
1146 fi
1147
1148
1149 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1150 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1151 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1152 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1153 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1154
1155
1156
1157 #
1158 # Print errors here so that they are visible all
1159 # together and the user can acquire them all together.
1160 #
1161 die=no
1162 if test "$have_gpg_error" = "no"; then
1163    die=yes
1164    AC_MSG_NOTICE([[
1165 ***  
1166 *** You need libgpg-error to build this program.
1167 **  This library is for example available at
1168 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1169 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1170 ***]])
1171 fi
1172 if test "$have_libgcrypt" = "no"; then
1173    die=yes
1174    AC_MSG_NOTICE([[
1175 ***  
1176 *** You need libgcrypt to build this program.
1177 **  This library is for example available at
1178 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1179 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API) is required.)
1180 ***]])
1181 fi
1182 if test "$have_libassuan" = "no"; then
1183    die=yes
1184    AC_MSG_NOTICE([[
1185 ***
1186 *** You need libassuan to build this program.
1187 *** This library is for example available at
1188 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libassuan/
1189 *** (at least version $NEED_LIBASSUAN_VERSION is required).
1190 ***]])
1191 fi
1192 if test "$have_ksba" = "no"; then
1193     AC_MSG_NOTICE([[
1194 ***
1195 *** You need libksba to build this program.
1196 *** This library is for example available at
1197 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libksba/
1198 *** (at least version $NEED_KSBA_VERSION is required).
1199 ***]])
1200 fi
1201 if test "$missing_pth" = "yes"; then
1202     AC_MSG_NOTICE([[
1203 ***
1204 *** It is now required to build with support for the
1205 *** GNU Portable Threads Library (Pth). Please install this
1206 *** library first.  The library is for example available at
1207 ***   ftp://ftp.gnu.org/gnu/pth/
1208 *** On a Debian GNU/Linux system you can install it using 
1209 ***   apt-get install libpth-dev
1210 ***]])
1211    die=yes
1212 fi
1213
1214 if test "$die" = "yes"; then
1215     AC_MSG_ERROR([[
1216 ***
1217 *** Required libraries not found. Please consult the above messages
1218 *** and install them before running configure again.
1219 ***]])
1220 fi
1221
1222
1223
1224 AC_CONFIG_FILES([ m4/Makefile 
1225 Makefile
1226 po/Makefile.in
1227 intl/Makefile
1228 gl/Makefile
1229 jnlib/Makefile
1230 common/Makefile
1231 kbx/Makefile
1232 g10/Makefile
1233 sm/Makefile
1234 agent/Makefile
1235 scd/Makefile
1236 tools/Makefile
1237 doc/Makefile
1238 tests/Makefile
1239 ])
1240 AC_OUTPUT
1241
1242 #tests/pkits/Makefile
1243
1244
1245
1246
1247 echo "
1248         GnuPG v${VERSION} has been configured as follows:
1249         
1250         Platform:  $PRINTABLE_OS_NAME ($host)
1251
1252         OpenPGP:   $build_gpg
1253         S/MIME:    $build_gpgsm
1254         Agent:     $build_agent $build_agent_threaded
1255         Smartcard: $build_scdaemon $build_scdaemon_extra
1256
1257         Protect tool:      $show_gnupg_protect_tool_pgm
1258         Default agent:     $show_gnupg_agent_pgm
1259         Default pinentry:  $show_gnupg_pinentry_pgm
1260         Default scdaemon:  $show_gnupg_scdaemon_pgm
1261         Default dirmngr:   $show_gnupg_dirmngr_pgm
1262
1263         PKITS based tests: $run_pkits_tests
1264 "
1265