Require libassuan 2.1.0.
[gnupg.git] / configure.ac
1 # configure.ac - for GnuPG 2.1
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
3 #               2008, 2009, 2010, 2011 Free Software Foundation, Inc.
4 #
5 # This file is part of GnuPG.
6 #
7 # GnuPG is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # GnuPG is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 # Process this file with autoconf to produce a configure script.
21 AC_PREREQ(2.61)
22 min_automake_version="1.10"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 m4_define([my_version], [2.1.0])
28 m4_define([my_issvn], [yes])
29
30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
32 m4_define([git_revision], m4_esyscmd([git branch -v 2>/dev/null \
33           | awk '/^\* / {printf "%s",$3}']))
34 m4_define([my_full_version], [my_version[]m4_if(my_issvn,[yes],
35           [m4_if(git_revision,[],[-svn[]svn_revision],[-git[]git_revision])])])
36
37 AC_INIT([gnupg],[my_full_version], [http://bugs.gnupg.org])
38 # Set development_version to yes if the minor number is odd or you
39 # feel that the default check for a development version is not
40 # sufficient.
41 development_version=no
42
43 NEED_GPG_ERROR_VERSION=1.10
44
45 NEED_LIBGCRYPT_API=1
46 NEED_LIBGCRYPT_VERSION=1.5.0
47
48 NEED_LIBASSUAN_API=2
49 NEED_LIBASSUAN_VERSION=2.1.0
50
51 NEED_KSBA_API=1
52 NEED_KSBA_VERSION=1.2.0
53
54 NEED_NPTH_API=1
55 NEED_NPTH_VERSION=0.0
56
57
58 PACKAGE=$PACKAGE_NAME
59 PACKAGE_GT=${PACKAGE_NAME}2
60 VERSION=$PACKAGE_VERSION
61
62 AC_CONFIG_AUX_DIR(scripts)
63 AC_CONFIG_SRCDIR(sm/gpgsm.c)
64 AM_CONFIG_HEADER(config.h)
65 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
66 AC_CANONICAL_HOST
67 AB_INIT
68
69 AC_GNU_SOURCE
70
71 # Some status variables.
72 have_gpg_error=no
73 have_libgcrypt=no
74 have_libassuan=no
75 have_ksba=no
76 have_npth=no
77 have_libusb=no
78 have_adns=no
79
80 use_zip=yes
81 use_bzip2=yes
82 use_exec=yes
83 disable_keyserver_path=no
84 use_ccid_driver=yes
85 use_standard_socket=yes
86 dirmngr_auto_start=no
87
88 try_ks_ldap=no
89
90 GNUPG_BUILD_PROGRAM(gpg, yes)
91 GNUPG_BUILD_PROGRAM(gpgsm, yes)
92 GNUPG_BUILD_PROGRAM(agent, yes)
93 GNUPG_BUILD_PROGRAM(scdaemon, yes)
94 GNUPG_BUILD_PROGRAM(g13, yes)
95 GNUPG_BUILD_PROGRAM(dirmngr, yes)
96 GNUPG_BUILD_PROGRAM(tools, yes)
97 GNUPG_BUILD_PROGRAM(doc, yes)
98 GNUPG_BUILD_PROGRAM(symcryptrun, no)
99 GNUPG_BUILD_PROGRAM(gpgtar, no)
100
101 AC_SUBST(PACKAGE)
102 AC_SUBST(PACKAGE_GT)
103 AC_SUBST(VERSION)
104 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
105 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
106                                 [Name of this package for gettext])
107 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
108 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
109                                         [Bug report address])
110 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
111                                        [Required version of Libgcrypt])
112 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
113                                        [Required version of Libksba])
114
115
116
117 # The default is to use the modules from this package and the few
118 # other packages in a standard place; i.e where this package gets
119 # installed.  With these options it is possible to override these
120 # ${prefix} depended values with fixed paths, which can't be replaced
121 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
122 AC_ARG_WITH(agent-pgm,
123     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
124           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
125 AC_SUBST(GNUPG_AGENT_PGM)
126 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
127 show_gnupg_agent_pgm="(default)"
128 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
129
130 AC_ARG_WITH(pinentry-pgm,
131     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
132           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
133 AC_SUBST(GNUPG_PINENTRY_PGM)
134 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
135 show_gnupg_pinentry_pgm="(default)"
136 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
137
138
139 AC_ARG_WITH(scdaemon-pgm,
140     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
141           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
142 AC_SUBST(GNUPG_SCDAEMON_PGM)
143 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
144 show_gnupg_scdaemon_pgm="(default)"
145 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
146
147
148 AC_ARG_WITH(dirmngr-pgm,
149     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
150           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
151 AC_SUBST(GNUPG_DIRMNGR_PGM)
152 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
153 show_gnupg_dirmngr_pgm="(default)"
154 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
155
156 AC_ARG_WITH(protect-tool-pgm,
157     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
158           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
159 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
160 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
161 show_gnupg_protect_tool_pgm="(default)"
162 test -n "$GNUPG_PROTECT_TOOL_PGM" \
163       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
164
165 AC_ARG_WITH(dirmngr-ldap-pgm,
166     [  --with-dirmngr-ldap-pgm=PATH  Use PATH as the default for the dirmnge ldap wrapper)],
167           GNUPG_DIRMNGR_LDAP_PGM="$withval", GNUPG_DIRMNGR_LDAP_PGM="" )
168 AC_SUBST(GNUPG_DIRMNGR_LDAP_PGM)
169 AM_CONDITIONAL(GNUPG_DIRMNGR_LDAP_PGM, test -n "$GNUPG_DIRMNGR_LDAP_PGM")
170 show_gnupg_dirmngr_ldap_pgm="(default)"
171 test -n "$GNUPG_DIRMNGR_LDAP_PGM" \
172       && show_gnupg_dirmngr_ldap_pgm="$GNUPG_DIRMNGR_LDAP_PGM"
173
174 #
175 # On some platforms gpg2 is usually installed as gpg without using a
176 # symlink.  For correct operation of gpgconf it needs to know the
177 # installed name of gpg.  This option sets "gpg2"'s installed name to
178 # just "gpg".  Note that it might be required to rename gpg2 to gpg
179 # manually after the build process.
180 #
181 AC_ARG_ENABLE(gpg2-is-gpg,
182     AC_HELP_STRING([--enable-gpg2-is-gpg],[Set installed name of gpg2 to gpg]),
183     gpg2_is_gpg=$enableval)
184 if test "$gpg2_is_gpg" = "yes"; then
185    name_of_installed_gpg=gpg
186 else
187    name_of_installed_gpg=gpg2
188 fi
189 AC_DEFINE_UNQUOTED(NAME_OF_INSTALLED_GPG, "$name_of_installed_gpg",
190                    [The name of the installed GPG tool])
191
192
193 # Some folks want to use only the agent from this packet.  Make it
194 # easier for them by providing the configure option
195 # --enable-only-agent.
196 AC_ARG_ENABLE(agent-only,
197     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
198     build_agent_only=$enableval)
199
200 # SELinux support includes tracking of sensitive files to avoid
201 # leaking their contents through processing these files by gpg itself
202 AC_MSG_CHECKING([whether SELinux support is requested])
203 AC_ARG_ENABLE(selinux-support,
204               AC_HELP_STRING([--enable-selinux-support],
205                              [enable SELinux support]),
206               selinux_support=$enableval, selinux_support=no)
207 AC_MSG_RESULT($selinux_support)
208
209 # Allow disabling of zip support.
210 # This is in general not a good idea because according to rfc4880 OpenPGP
211 # implementations SHOULD support ZLIB.
212 AC_MSG_CHECKING([whether to enable the ZIP and ZLIB compression algorithm])
213 AC_ARG_ENABLE(zip,
214    AC_HELP_STRING([--disable-zip],
215                   [disable the ZIP and ZLIB compression algorithm]),
216    use_zip=$enableval)
217 AC_MSG_RESULT($use_zip)
218
219 # Allow disabling of bzib2 support.
220 # It is defined only after we confirm the library is available later
221 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
222 AC_ARG_ENABLE(bzip2,
223    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
224    use_bzip2=$enableval)
225 AC_MSG_RESULT($use_bzip2)
226
227 # Configure option to allow or disallow execution of external
228 # programs, like a photo viewer.
229 AC_MSG_CHECKING([whether to enable external program execution])
230 AC_ARG_ENABLE(exec,
231     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
232     use_exec=$enableval)
233 AC_MSG_RESULT($use_exec)
234 if test "$use_exec" = no ; then
235     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
236 fi
237
238 if test "$use_exec" = yes ; then
239   AC_MSG_CHECKING([whether to enable photo ID viewing])
240   AC_ARG_ENABLE(photo-viewers,
241       [  --disable-photo-viewers disable photo ID viewers],
242       [if test "$enableval" = no ; then
243          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
244       fi],enableval=yes)
245   gnupg_cv_enable_photo_viewers=$enableval
246   AC_MSG_RESULT($enableval)
247
248   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
249     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
250     AC_ARG_WITH(photo-viewer,
251         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
252         [if test "$withval" = yes ; then
253            withval=no
254         elif test "$withval" != no ; then
255            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
256                             [if set, restrict photo-viewer to this])
257         fi],withval=no)
258     AC_MSG_RESULT($withval)
259   fi
260
261   AC_MSG_CHECKING([whether to enable external keyserver helpers])
262   AC_ARG_ENABLE(keyserver-helpers,
263       [  --disable-keyserver-helpers  disable all external keyserver support],
264       [if test "$enableval" = no ; then
265          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
266                   [define to disable keyserver helpers])
267       fi],enableval=yes)
268   gnupg_cv_enable_keyserver_helpers=$enableval
269   AC_MSG_RESULT($enableval)
270
271   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
272     # LDAP is defined only after we confirm the library is available later
273     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
274     AC_ARG_ENABLE(ldap,
275       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
276       try_ks_ldap=$enableval, try_ks_ldap=yes)
277     AC_MSG_RESULT($try_ks_ldap)
278
279     AC_MSG_CHECKING([whether HKP keyserver support is requested])
280     AC_ARG_ENABLE(hkp,
281       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
282       try_hkp=$enableval, try_hkp=yes)
283     AC_MSG_RESULT($try_hkp)
284
285     AC_MSG_CHECKING([whether finger key fetching support is requested])
286     AC_ARG_ENABLE(finger,
287       AC_HELP_STRING([--disable-finger],
288         [disable finger key fetching interface only]),
289       try_finger=$enableval, try_finger=yes)
290     AC_MSG_RESULT($try_finger)
291
292     AC_MSG_CHECKING([whether generic object key fetching support is requested])
293     AC_ARG_ENABLE(generic,
294       AC_HELP_STRING([--disable-generic],
295         [disable generic object key fetching interface only]),
296       try_generic=$enableval, try_generic=yes)
297     AC_MSG_RESULT($try_generic)
298
299     AC_MSG_CHECKING([whether email keyserver support is requested])
300     AC_ARG_ENABLE(mailto,
301       AC_HELP_STRING([--enable-mailto],
302         [enable email keyserver interface only]),
303       try_mailto=$enableval, try_mailto=no)
304     AC_MSG_RESULT($try_mailto)
305   fi
306
307   AC_MSG_CHECKING([whether keyserver exec-path is enabled])
308   AC_ARG_ENABLE(keyserver-path,
309       AC_HELP_STRING([--disable-keyserver-path],
310         [disable the exec-path option for keyserver helpers]),
311       [if test "$enableval" = no ; then
312          disable_keyserver_path=yes
313       fi],enableval=yes)
314   AC_MSG_RESULT($enableval)
315 fi
316
317
318 #
319 # Check for the key/uid cache size.  This can't be zero, but can be
320 # pretty small on embedded systems.  This is used for the gpg part.
321 #
322 AC_MSG_CHECKING([for the size of the key and uid cache])
323 AC_ARG_ENABLE(key-cache,
324         AC_HELP_STRING([--enable-key-cache=SIZE],
325                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
326 if test "$enableval" = "no"; then
327    enableval=5
328 elif test "$enableval" = "yes" || test "$enableval" = ""; then
329    enableval=4096
330 fi
331 changequote(,)dnl
332 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
333 changequote([,])dnl
334 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
335    AC_MSG_ERROR([invalid key-cache size])
336 fi
337 AC_MSG_RESULT($key_cache_size)
338 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
339                   [Size of the key and UID caches])
340
341
342
343 #
344 # Check whether we want to use Linux capabilities
345 #
346 AC_MSG_CHECKING([whether use of capabilities is requested])
347 AC_ARG_WITH(capabilities,
348     [  --with-capabilities     use linux capabilities [default=no]],
349 [use_capabilities="$withval"],[use_capabilities=no])
350 AC_MSG_RESULT($use_capabilities)
351
352
353 #
354 # Allow disabling of internal CCID support.
355 # It is defined only after we confirm the library is available later
356 #
357 AC_MSG_CHECKING([whether to enable the internal CCID driver])
358 AC_ARG_ENABLE(ccid-driver,
359               AC_HELP_STRING([--disable-ccid-driver],
360                              [disable the internal CCID driver]),
361               use_ccid_driver=$enableval)
362 AC_MSG_RESULT($use_ccid_driver)
363
364 #
365 # Dirmngr is nowadays a system service and thus it usually does no
366 # make sense to start it as needed.  However on some systems this is
367 # possible; this option enable the feature.
368 #
369 AC_MSG_CHECKING([whether to auto start dirmngr])
370 AC_ARG_ENABLE(dirmngr-auto-start,
371               AC_HELP_STRING([--enable-dirmngr-auto-start],
372                              [enable auto starting of the dirmngr]),
373               dirmngr_auto_start=$enableval)
374 AC_MSG_RESULT($dirmngr_auto_start)
375 if test "$dirmngr_auto_start" = yes ; then
376     AC_DEFINE(USE_DIRMNGR_AUTO_START,1,
377               [Define to enable auto starting of the dirmngr])
378 fi
379
380
381 #
382 # To avoid double inclusion of config.h which might happen at some
383 # places, we add the usual double inclusion protection at the top of
384 # config.h.
385 #
386 AH_TOP([
387 #ifndef GNUPG_CONFIG_H_INCLUDED
388 #define GNUPG_CONFIG_H_INCLUDED
389 ])
390
391 #
392 # Stuff which goes at the bottom of config.h.
393 #
394 AH_BOTTOM([
395 /* This is the major version number of GnuPG so that
396    source included files can test for this.  Note, that
397    we use 2 here even for GnuPG 1.9.x. */
398 #define GNUPG_MAJOR_VERSION 2
399
400 /* Now to separate file name parts.
401    Please note that the string version must not contain more
402    than one character because the code assumes strlen()==1 */
403 #ifdef HAVE_DOSISH_SYSTEM
404 #define DIRSEP_C '\\'
405 #define DIRSEP_S "\\"
406 #define EXTSEP_C '.'
407 #define EXTSEP_S "."
408 #define PATHSEP_C ';'
409 #define PATHSEP_S ";"
410 #define EXEEXT_S ".exe"
411 #else
412 #define DIRSEP_C '/'
413 #define DIRSEP_S "/"
414 #define EXTSEP_C '.'
415 #define EXTSEP_S "."
416 #define PATHSEP_C ':'
417 #define PATHSEP_S ":"
418 #define EXEEXT_S ""
419 #endif
420
421 /* This is the same as VERSION, but should be overridden if the
422    platform cannot handle things like dots '.' in filenames. Set
423    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
424    uses for dots and dashes. */
425 #define SAFE_VERSION VERSION
426 #define SAFE_VERSION_DOT  '.'
427 #define SAFE_VERSION_DASH '-'
428
429 /* Some global constants. */
430 #ifdef HAVE_DOSISH_SYSTEM
431 # ifdef HAVE_DRIVE_LETTERS
432 #  define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
433 # else
434 #  define GNUPG_DEFAULT_HOMEDIR "/gnupg"
435 # endif
436 #elif defined(__VMS)
437 #define GNUPG_DEFAULT_HOMEDIR "/SYS$LOGIN/gnupg"
438 #else
439 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
440 #endif
441 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
442
443 /* For some systems (DOS currently), we hardcode the path here.  For
444    POSIX systems the values are constructed by the Makefiles, so that
445    the values may be overridden by the make invocations; this is to
446    comply with the GNU coding standards.  Note that these values are
447    only defaults.  */
448 #ifdef HAVE_DOSISH_SYSTEM
449 # ifdef HAVE_DRIVE_LETTERS
450 #  define GNUPG_BINDIR      "c:\\gnupg"
451 #  define GNUPG_LIBEXECDIR  "c:\\gnupg"
452 #  define GNUPG_LIBDIR      "c:\\gnupg"
453 #  define GNUPG_DATADIR     "c:\\gnupg"
454 #  define GNUPG_SYSCONFDIR  "c:\\gnupg"
455 # else
456 #  define GNUPG_BINDIR      "\\gnupg"
457 #  define GNUPG_LIBEXECDIR  "\\gnupg"
458 #  define GNUPG_LIBDIR      "\\gnupg"
459 #  define GNUPG_DATADIR     "\\gnupg"
460 #  define GNUPG_SYSCONFDIR  "\\gnupg"
461 # endif
462 #endif
463
464 /* Derive some other constants. */
465 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
466 #define EXEC_TEMPFILE_ONLY
467 #endif
468
469
470 /* We didn't define endianness above, so get it from OS macros.  This
471    is intended for making fat binary builds on OS X. */
472 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
473 #if defined(__BIG_ENDIAN__)
474 #define BIG_ENDIAN_HOST 1
475 #elif defined(__LITTLE_ENDIAN__)
476 #define LITTLE_ENDIAN_HOST 1
477 #else
478 #error "No endianness found"
479 #endif
480 #endif
481
482
483 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
484    ldap_start_tls_s because that is the actual symbol used in the
485    library.  winldap.h redefines it to our commonly used value,
486    thus we define our usual macro here.  */
487 #ifdef HAVE_LDAP_START_TLS_SA
488 # ifndef HAVE_LDAP_START_TLS_S
489 #  define HAVE_LDAP_START_TLS_S 1
490 # endif
491 #endif
492
493
494 /* Tell libgcrypt not to use its own libgpg-error implementation. */
495 #define USE_LIBGPG_ERROR 1
496
497 /* We use jnlib, so tell other modules about it.  */
498 #define HAVE_JNLIB_LOGGING 1
499
500 /* Our HTTP code is used in estream mode.  */
501 #define HTTP_USE_ESTREAM 1
502
503 /* Under W32 we do an explicit socket initialization, thus we need to
504    avoid the on-demand initialization which would also install an atexit
505    handler.  */
506 #define HTTP_NO_WSASTARTUP
507
508 /* We always include support for the OpenPGP card.  */
509 #define ENABLE_CARD_SUPPORT 1
510
511 /* We want to use the libgcrypt provided memory allocation for
512    asprintf.  */
513 #define _ESTREAM_PRINTF_REALLOC       gcry_realloc
514 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "../common/util.h"
515
516 /* Under Windows we use the gettext code from libgpg-error.  */
517 #define GPG_ERR_ENABLE_GETTEXT_MACROS
518
519 /* Under WindowsCE we use the strerror replacement from libgpg-error.  */
520 #define GPG_ERR_ENABLE_ERRNO_MACROS
521
522 #endif /*GNUPG_CONFIG_H_INCLUDED*/
523 ])
524
525
526 AM_MAINTAINER_MODE
527
528 # Checks for programs.
529 AC_MSG_NOTICE([checking for programs])
530 AC_PROG_MAKE_SET
531 AM_SANITY_CHECK
532 missing_dir=`cd $ac_aux_dir && pwd`
533 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
534 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
535 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
536 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
537 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
538 AC_PROG_AWK
539 AC_PROG_CC
540 AC_PROG_CPP
541 AM_PROG_CC_C_O
542 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
543   AC_MSG_ERROR([[No C-89 compiler found]])
544 fi
545 AC_PROG_INSTALL
546 AC_PROG_LN_S
547 AC_PROG_RANLIB
548 AC_CHECK_TOOL(AR, ar, :)
549 AC_PATH_PROG(PERL,"perl")
550 AC_CHECK_TOOL(WINDRES, windres, :)
551 AC_ISC_POSIX
552 gl_EARLY
553 AC_SYS_LARGEFILE
554 GNUPG_CHECK_USTAR
555
556 # We need to compile and run a program on the build machine.  A
557 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
558 # the AC archive is broken for autoconf 2.57.  Given that there is no
559 # newer version of that macro, we assume that it is also broken for
560 # autoconf 2.61 and thus we use a simple but usually sufficient
561 # approach.
562 AC_MSG_CHECKING(for cc for build)
563 if test "$cross_compiling" = "yes"; then
564   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
565 else
566   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
567 fi
568 AC_MSG_RESULT($CC_FOR_BUILD)
569 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
570
571
572
573 try_gettext=yes
574 have_dosish_system=no
575 have_w32_system=no
576 have_w32ce_system=no
577 use_simple_gettext=no
578 use_ldapwrapper=yes
579 mmap_needed=yes
580 case "${host}" in
581     *-mingw32*)
582         # special stuff for Windoze NT
583         ac_cv_have_dev_random=no
584         AC_DEFINE(USE_ONLY_8DOT3,1,
585                   [Set this to limit filenames to the 8.3 format])
586         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
587                   [Because the Unix gettext has too much overhead on
588                    MingW32 systems and these systems lack Posix functions,
589                    we use a simplified version of gettext])
590         disable_keyserver_path=yes
591         have_dosish_system=yes
592         have_w32_system=yes
593         use_ldapwrapper=no  # Fixme: Do this only for CE.
594         case "${host}" in
595           *-mingw32ce*)
596             have_w32ce_system=yes
597             ;;
598           *)
599             AC_DEFINE(HAVE_DRIVE_LETTERS,1,
600                       [Defined if the OS supports drive letters.])
601             ;;
602         esac
603         try_gettext="no"
604         use_simple_gettext=yes
605         mmap_needed=no
606         ;;
607     i?86-emx-os2 | i?86-*-os2*emx )
608         # OS/2 with the EMX environment
609         ac_cv_have_dev_random=no
610         AC_DEFINE(HAVE_DRIVE_LETTERS)
611         have_dosish_system=yes
612         try_gettext="no"
613         ;;
614
615     i?86-*-msdosdjgpp*)
616         # DOS with the DJGPP environment
617         ac_cv_have_dev_random=no
618         AC_DEFINE(HAVE_DRIVE_LETTERS)
619         have_dosish_system=yes
620         try_gettext="no"
621         ;;
622
623     *-*-freebsd*)
624        # FreeBSD
625        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
626        LDFLAGS="$LDFLAGS -L/usr/local/lib"
627        ;;
628
629     *-*-hpux*)
630         if test -z "$GCC" ; then
631             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
632         fi
633         ;;
634     *-dec-osf4*)
635         if test -z "$GCC" ; then
636             # Suppress all warnings
637             # to get rid of the unsigned/signed char mismatch warnings.
638             CFLAGS="$CFLAGS -w"
639         fi
640         ;;
641     *-dec-osf5*)
642         if test -z "$GCC" ; then
643             # Use the newer compiler `-msg_disable ptrmismatch1' to
644             # get rid of the unsigned/signed char mismatch warnings.
645             # Using this may hide other pointer mismatch warnings, but
646             # it at least lets other warning classes through
647             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
648         fi
649         ;;
650     m68k-atari-mint)
651         ;;
652     *)
653        ;;
654 esac
655
656 if test "$have_dosish_system" = yes; then
657    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
658              [Defined if we run on some of the PCDOS like systems
659               (DOS, Windoze. OS/2) with special properties like
660               no file modes, case insensitive file names and preferred
661               use of backslashes as directory name separators.])
662 fi
663 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
664
665 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
666
667 if test "$have_w32_system" = yes; then
668    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
669    if test "$have_w32ce_system" = yes; then
670       AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
671    fi
672 fi
673 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
674 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
675
676 if test "$use_ldapwrapper" = yes; then
677    AC_DEFINE(USE_LDAPWRAPPER,1, [Build dirmngr with LDAP wrapper process])
678 fi
679 AM_CONDITIONAL(USE_LDAPWRAPPER, test "$use_ldapwrapper" = yes)
680
681 if test "$disable_keyserver_path" = yes; then
682     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
683               [Defined to disable exec-path for keyserver helpers])
684 fi
685
686 #
687 # Allows enabling the use of a standard socket by default This is
688 # gpg-agent's option --[no-]use-standard-socket.  For Windows we force
689 # the use of this.
690 #
691 AC_MSG_CHECKING([whether to use a standard socket by default])
692 AC_ARG_ENABLE(standard-socket,
693               AC_HELP_STRING([--disable-standard-socket],
694                              [don't use a standard socket by default]),
695               use_standard_socket=$enableval)
696 tmp=""
697 if test "$use_standard_socket" != yes; then
698   if test "$have_w32_system" = yes; then
699     use_standard_socket=yes
700     tmp=" (forced)"
701   fi
702 fi
703 AC_MSG_RESULT($use_standard_socket$tmp)
704 if test "$use_standard_socket" = yes; then
705   AC_DEFINE(USE_STANDARD_SOCKET,1,
706             [Use the standard socket for the agent by default])
707 fi
708
709
710 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
711 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
712
713 if test x"$try_hkp" = xyes ; then
714   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
715 fi
716
717 if test x"$try_finger" = xyes ; then
718   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
719 fi
720
721
722
723 #
724 # Checks for libraries.
725 #
726 AC_MSG_NOTICE([checking for libraries])
727
728
729 #
730 # libgpg-error is a library with error codes shared between GnuPG
731 # related projects.
732 #
733 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
734                   have_gpg_error=yes,have_gpg_error=no)
735
736
737 #
738 # Libgcrypt is our generic crypto library
739 #
740 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
741         have_libgcrypt=yes,have_libgcrypt=no)
742
743
744 #
745 # libassuan is used for IPC
746 #
747 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
748                   have_libassuan=yes,have_libassuan=no)
749 if test "$have_libassuan" = "yes"; then
750   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
751                      [version of the libassuan library])
752 fi
753
754
755
756 #
757 # libksba is our X.509 support library
758 #
759 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
760
761
762 #
763 # libusb allows us to use the integrated CCID smartcard reader driver.
764 #
765 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
766 if test "$use_ccid_driver" = yes ; then
767   AC_CHECK_LIB(usb, usb_bulk_write,
768                 [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
769                   AC_DEFINE(HAVE_LIBUSB,1,
770                            [defined if libusb is available])
771                   have_libusb=yes
772                ])
773   AC_CHECK_FUNCS(usb_create_match)
774 fi
775 AC_SUBST(LIBUSB_LIBS)
776
777 #
778 # Check wether it is necessary to link against libdl.
779 #
780 gnupg_dlopen_save_libs="$LIBS"
781 LIBS=""
782 AC_SEARCH_LIBS(dlopen, c dl,,,)
783 DL_LIBS=$LIBS
784 AC_SUBST(DL_LIBS)
785 LIBS="$gnupg_dlopen_save_libs"
786
787 # Checks for g13
788
789 AC_PATH_PROG(ENCFS, encfs, /usr/bin/encfs)
790 AC_DEFINE_UNQUOTED(ENCFS,
791         "${ENCFS}", [defines the filename of the encfs program])
792
793 AC_PATH_PROG(FUSERMOUNT, fusermount, /usr/bin/fusermount)
794 AC_DEFINE_UNQUOTED(FUSERMOUNT,
795         "${FUSERMOUNT}", [defines the filename of the fusermount program])
796
797
798 # Checks for dirmngr
799
800
801 #
802 # Checks for symcryptrun:
803 #
804
805 # libutil has openpty() and login_tty().
806 AC_CHECK_LIB(util, openpty,
807               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
808                 AC_DEFINE(HAVE_LIBUTIL,1,
809                          [defined if libutil is available])
810              ])
811 AC_SUBST(LIBUTIL_LIBS)
812
813 # shred is used to clean temporary plain text files.
814 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
815 AC_DEFINE_UNQUOTED(SHRED,
816         "${SHRED}", [defines the filename of the shred program])
817
818
819 #
820 # Check whether the GNU Pth library is available
821 # Note, that we include a Pth emulation for W32.
822 #
823 AM_PATH_NPTH("$NEED_NPTH_API:$NEED_NPTH_VERSION",have_npth=yes,have_npth=no)
824 if test "$have_npth" = "yes"; then
825   AC_DEFINE(USE_NPTH, 1,
826               [Defined if the New Portable Thread Library should be used])
827 else
828   AC_MSG_WARN([[
829 ***
830 *** To support concurrent access to the gpg-agent and the SCdaemon
831 *** we need the support of the New Portable Threads Library.
832 *** Download it from FIXME
833 *** On a Debian GNU/Linux system you might want to try
834 ***   apt-get install libnpth-dev
835 ***]])
836 fi
837
838
839 AC_MSG_NOTICE([checking for networking options])
840
841 #
842 # Must check for network library requirements before doing link tests
843 # for ldap, for example. If ldap libs are static (or dynamic and without
844 # ELF runtime link paths), then link will fail and LDAP support won't
845 # be detected.
846 #
847 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
848         [NETLIBS="-lnsl $NETLIBS"]))
849 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
850         [NETLIBS="-lsocket $NETLIBS"]))
851
852
853 #
854 # Check for ADNS.
855 #
856 _cppflags="${CPPFLAGS}"
857 _ldflags="${LDFLAGS}"
858 AC_ARG_WITH(adns,
859             AC_HELP_STRING([--with-adns=DIR],
860                            [look for the adns library in DIR]),
861             [if test -d "$withval"; then
862                CPPFLAGS="${CPPFLAGS} -I$withval/include"
863                LDFLAGS="${LDFLAGS} -L$withval/lib"
864              fi])
865 if test "$with_adns" != "no"; then
866   AC_CHECK_HEADERS(adns.h,
867                 AC_CHECK_LIB(adns, adns_init,
868                              [have_adns=yes],
869                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
870                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
871 fi
872 if test "$have_adns" = "yes"; then
873   ADNSLIBS="-ladns"
874 fi
875 AC_SUBST(ADNSLIBS)
876 # Newer adns versions feature a free function to be used under W32.
877 AC_CHECK_FUNCS(adns_free)
878
879
880
881 #
882 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
883 #
884 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
885   AC_ARG_ENABLE(dns-srv,
886      AC_HELP_STRING([--disable-dns-srv],
887                     [disable the use of DNS SRV in HKP and HTTP]),
888                 use_dns_srv=$enableval,use_dns_srv=yes)
889 fi
890
891 AC_ARG_ENABLE(dns-pka,
892    AC_HELP_STRING([--disable-dns-pka],
893         [disable the use of PKA records in DNS]),
894    use_dns_pka=$enableval,use_dns_pka=yes)
895
896 AC_ARG_ENABLE(dns-cert,
897    AC_HELP_STRING([--disable-dns-cert],
898         [disable the use of CERT records in DNS]),
899    use_dns_cert=$enableval,use_dns_cert=yes)
900
901 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
902    || test x"$use_dns_cert" = xyes; then
903   _dns_save_libs=$LIBS
904   LIBS=""
905   # the double underscore thing is a glibc-ism?
906   AC_SEARCH_LIBS(res_query,resolv bind,,
907                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
908   AC_SEARCH_LIBS(dn_expand,resolv bind,,
909                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
910   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
911                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
912
913   if test x"$have_resolver" != xno ; then
914
915     # Make sure that the BIND 4 resolver interface is workable before
916     # enabling any code that calls it.  At some point I'll rewrite the
917     # code to use the BIND 8 resolver API.
918     # We might also want to use adns instead.  Problem with ADNS is that
919     # it does not support v6.
920
921     AC_MSG_CHECKING([whether the resolver is usable])
922     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
923 #include <netinet/in.h>
924 #include <arpa/nameser.h>
925 #include <resolv.h>]],
926 [[unsigned char answer[PACKETSZ];
927   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
928   dn_skipname(0,0);
929   dn_expand(0,0,0,0,0);
930 ]])],have_resolver=yes,have_resolver=no)
931     AC_MSG_RESULT($have_resolver)
932
933     # This is Apple-specific and somewhat bizarre as they changed the
934     # define in bind 8 for some reason.
935
936     if test x"$have_resolver" != xyes ; then
937        AC_MSG_CHECKING(
938              [whether I can make the resolver usable with BIND_8_COMPAT])
939        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define BIND_8_COMPAT
940 #include <sys/types.h>
941 #include <netinet/in.h>
942 #include <arpa/nameser.h>
943 #include <resolv.h>]],
944 [[unsigned char answer[PACKETSZ];
945   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
946   dn_skipname(0,0); dn_expand(0,0,0,0,0);
947 ]])],[have_resolver=yes ; need_compat=yes])
948        AC_MSG_RESULT($have_resolver)
949     fi
950   fi
951
952   if test x"$have_resolver" = xyes ; then
953      DNSLIBS=$LIBS
954
955      if test x"$use_dns_srv" = xyes ; then
956         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
957      fi
958
959      if test x"$use_dns_pka" = xyes ; then
960         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
961      fi
962
963      if test x"$use_dns_cert" = xyes ; then
964         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
965      fi
966
967      if test x"$need_compat" = xyes ; then
968         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
969      fi
970   else
971      # If we have no resolver library but ADNS (e.g. under W32) enable the
972      # code parts which can be used with ADNS.
973      if test x"$have_adns" = xyes ; then
974         DNSLIBS="$ADNSLIBS"
975         AC_DEFINE(USE_ADNS,1,[Use ADNS as resolver library.])
976
977         if test x"$use_dns_srv" = xyes ; then
978            AC_DEFINE(USE_DNS_SRV,1)
979         fi
980
981         if test x"$use_dns_pka" = xyes ; then
982            AC_DEFINE(USE_DNS_PKA,1)
983         fi
984
985         if test x"$use_dns_cert" = xyes ; then
986            AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
987         fi
988      else
989         use_dns_srv=no
990         use_dns_pka=no
991         use_dns_cert=no
992      fi
993   fi
994
995   LIBS=$_dns_save_libs
996 fi
997
998 AC_SUBST(DNSLIBS)
999
1000 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
1001
1002
1003 #
1004 # Check for LDAP
1005 #
1006 if test "$try_ks_ldap" = yes || test "$build_dirmngr" = "yes" ; then
1007    GNUPG_CHECK_LDAP($NETLIBS)
1008 fi
1009
1010 #
1011 # Check for curl.  We fake the curl API if libcurl isn't installed.
1012 # We require 7.10 or later as we use curl_version_info().
1013 #
1014 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
1015 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
1016
1017 # Generic, for us, means curl
1018
1019 if test x"$try_generic" = xyes ; then
1020    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
1021 fi
1022
1023 #
1024 # Check for sendmail
1025 #
1026 # This isn't necessarily sendmail itself, but anything that gives a
1027 # sendmail-ish interface to the outside world.  That includes Exim,
1028 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
1029 if test "$try_mailto" = yes ; then
1030   AC_ARG_WITH(mailprog,
1031       AC_HELP_STRING([--with-mailprog=NAME],
1032                      [use "NAME -t" for mail transport]),
1033              ,with_mailprog=yes)
1034
1035   if test x"$with_mailprog" = xyes ; then
1036     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
1037     if test "$ac_cv_path_SENDMAIL" ; then
1038       GPGKEYS_MAILTO="gpg2keys_mailto"
1039     fi
1040   elif test x"$with_mailprog" != xno ; then
1041     AC_MSG_CHECKING([for a mail transport program])
1042     AC_SUBST(SENDMAIL,$with_mailprog)
1043     AC_MSG_RESULT($with_mailprog)
1044     GPGKEYS_MAILTO="gpg2keys_mailto"
1045   fi
1046 fi
1047
1048 AC_SUBST(GPGKEYS_MAILTO)
1049
1050 #
1051 # Construct a printable name of the OS
1052 #
1053 case "${host}" in
1054     *-mingw32ce*)
1055         PRINTABLE_OS_NAME="W32CE"
1056         ;;
1057     *-mingw32*)
1058         PRINTABLE_OS_NAME="MingW32"
1059         ;;
1060     *-*-cygwin*)
1061         PRINTABLE_OS_NAME="Cygwin"
1062         ;;
1063     i?86-emx-os2 | i?86-*-os2*emx )
1064         PRINTABLE_OS_NAME="OS/2"
1065         ;;
1066     i?86-*-msdosdjgpp*)
1067         PRINTABLE_OS_NAME="MSDOS/DJGPP"
1068         try_dynload=no
1069         ;;
1070     *-linux*)
1071         PRINTABLE_OS_NAME="GNU/Linux"
1072         ;;
1073     *)
1074         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
1075         ;;
1076 esac
1077 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
1078                    [A human readable text with the name of the OS])
1079
1080
1081 #
1082 # Checking for iconv
1083 #
1084 AM_ICONV
1085
1086
1087 #
1088 # Check for gettext
1089 #
1090 # This is "GNU gnupg" - The project-id script from gettext
1091 #                       needs this string
1092 #
1093 AC_MSG_NOTICE([checking for gettext])
1094 AM_PO_SUBDIRS
1095 AM_GNU_GETTEXT_VERSION([0.17])
1096 if test "$try_gettext" = yes; then
1097   AM_GNU_GETTEXT([external],[need-ngettext])
1098
1099   # gettext requires some extra checks.  These really should be part of
1100   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
1101   # function checks to here.
1102
1103   AC_CHECK_FUNCS(strchr)
1104 else
1105   USE_NLS=no
1106   USE_INCLUDED_LIBINTL=no
1107   BUILD_INCLUDED_LIBINTL=no
1108   POSUB=po
1109   AC_SUBST(USE_NLS)
1110   AC_SUBST(USE_INCLUDED_LIBINTL)
1111   AC_SUBST(BUILD_INCLUDED_LIBINTL)
1112   AC_SUBST(POSUB)
1113 fi
1114
1115 # We use HAVE_LANGINFO_CODESET in a couple of places.
1116 AM_LANGINFO_CODESET
1117
1118 # Checks required for our use locales
1119 gt_LC_MESSAGES
1120
1121
1122 #
1123 # SELinux support
1124 #
1125 if test "$selinux_support" = yes ; then
1126   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
1127 fi
1128
1129
1130 #
1131 # Checks for header files.
1132 #
1133 AC_MSG_NOTICE([checking for header files])
1134 AC_HEADER_STDC
1135 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h \
1136                   pty.h utmp.h pwd.h inttypes.h signal.h])
1137 AC_HEADER_TIME
1138
1139
1140 #
1141 # Checks for typedefs, structures, and compiler characteristics.
1142 #
1143 AC_MSG_NOTICE([checking for system characteristics])
1144 AC_C_CONST
1145 AC_C_INLINE
1146 AC_C_VOLATILE
1147 AC_TYPE_SIZE_T
1148 AC_TYPE_MODE_T
1149 AC_TYPE_SIGNAL
1150 AC_DECL_SYS_SIGLIST
1151
1152 gl_HEADER_SYS_SOCKET
1153 gl_TYPE_SOCKLEN_T
1154
1155 AC_ARG_ENABLE(endian-check,
1156               AC_HELP_STRING([--disable-endian-check],
1157               [disable the endian check and trust the OS provided macros]),
1158               endiancheck=$enableval,endiancheck=yes)
1159
1160 if test x"$endiancheck" = xyes ; then
1161   GNUPG_CHECK_ENDIAN
1162 fi
1163
1164 # fixme: we should get rid of the byte type
1165 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
1166 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
1167 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1168 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1169 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1170
1171 AC_CHECK_SIZEOF(unsigned short)
1172 AC_CHECK_SIZEOF(unsigned int)
1173 AC_CHECK_SIZEOF(unsigned long)
1174 AC_CHECK_SIZEOF(unsigned long long)
1175 AC_HEADER_TIME
1176 AC_CHECK_SIZEOF(time_t,,[[
1177 #include <stdio.h>
1178 #if TIME_WITH_SYS_TIME
1179 # include <sys/time.h>
1180 # include <time.h>
1181 #else
1182 # if HAVE_SYS_TIME_H
1183 #  include <sys/time.h>
1184 # else
1185 #  include <time.h>
1186 # endif
1187 #endif
1188 ]])
1189 GNUPG_TIME_T_UNSIGNED
1190
1191
1192 # Ensure that we have UINT64_C before we bother to check for uint64_t
1193 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1194 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1195    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
1196        [[uint64_t foo=UINT64_C(42);]])],
1197      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1198 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1199    AC_CHECK_SIZEOF(uint64_t)
1200 fi
1201
1202 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1203    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1204    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1205     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1206 fi
1207
1208
1209 #
1210 # Checks for library functions.
1211 #
1212 AC_MSG_NOTICE([checking for library functions])
1213 AC_CHECK_DECLS(getpagesize)
1214 AC_FUNC_FSEEKO
1215 AC_FUNC_VPRINTF
1216 AC_FUNC_FORK
1217 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap canonicalize_file_name])
1218 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r strtoull])
1219 AC_CHECK_FUNCS([unsetenv fcntl ftruncate canonicalize_file_name])
1220 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1221 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1222 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe getaddrinfo])
1223 AC_CHECK_FUNCS([ttyname rand ftello fsync stat lstat])
1224
1225 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1226
1227 # Dirmngr requires mmap on Unix systems.
1228 if test $ac_cv_func_mmap != yes -a $mmap_needed = yes; then
1229   AC_MSG_ERROR([[Sorry, the current implemenation requires mmap.]])
1230 fi
1231
1232 #
1233 # These are needed by the jnlib parts in common.
1234 # Note:  We already checked pwd.h.
1235 AC_CHECK_HEADERS([signal.h])
1236 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol \
1237                 memrchr isascii timegm getrusage setrlimit stat setlocale   \
1238                 flockfile funlockfile fopencookie funopen getpwnam getpwuid \
1239                 getenv inet_pton])
1240 # end jnlib checks.
1241
1242
1243
1244 #
1245 # gnulib checks
1246 #
1247 gl_SOURCE_BASE([gl])
1248 gl_M4_BASE([gl/m4])
1249 gl_MODULES([setenv mkdtemp xsize strpbrk])
1250 gl_INIT
1251
1252
1253 #
1254 # W32 specific test
1255 #
1256 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1257
1258 #
1259 # Sanity check regex.  Tests adapted from mutt.
1260 #
1261 AC_MSG_CHECKING([whether regular expression support is requested])
1262 AC_ARG_ENABLE(regex,
1263   AC_HELP_STRING([--disable-regex],
1264     [do not handle regular expressions in trust signatures]),
1265   use_regex=$enableval, use_regex=yes)
1266 AC_MSG_RESULT($use_regex)
1267
1268 if test "$use_regex" = yes ; then
1269   _cppflags="${CPPFLAGS}"
1270   _ldflags="${LDFLAGS}"
1271   AC_ARG_WITH(regex,
1272      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1273       [
1274       if test -d "$withval" ; then
1275         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1276         LDFLAGS="${LDFLAGS} -L$withval/lib"
1277       fi
1278       ],withval="")
1279
1280   # Does the system have regex functions at all?
1281   AC_SEARCH_LIBS([regcomp], [regex])
1282   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1283
1284   if test $gnupg_cv_have_regex = no; then
1285     use_regex=no
1286   else
1287     if test x"$cross_compiling" = xyes; then
1288       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1289     else
1290       AC_CACHE_CHECK([whether your system's regexp library is broken],
1291        [gnupg_cv_regex_broken],
1292        AC_TRY_RUN([
1293 #include <unistd.h>
1294 #include <regex.h>
1295 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1296        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1297
1298       if test $gnupg_cv_regex_broken = yes; then
1299         AC_MSG_WARN([your regex is broken - disabling regex use])
1300         use_regex=no
1301       fi
1302     fi
1303   fi
1304   CPPFLAGS="${_cppflags}"
1305   LDFLAGS="${_ldflags}"
1306 fi
1307
1308 if test "$use_regex" != yes ; then
1309   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1310 fi
1311 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1312
1313
1314
1315 #
1316 # Do we have zlib? Must do it here because Solaris failed
1317 # when compiling a conftest (due to the "-lz" from LIBS).
1318 # Note that we combine zlib and bzlib2 in ZLIBS.
1319 #
1320 if test "$use_zip" = yes ; then
1321   _cppflags="${CPPFLAGS}"
1322   _ldflags="${LDFLAGS}"
1323   AC_ARG_WITH(zlib,
1324     [  --with-zlib=DIR         use libz in DIR],[
1325       if test -d "$withval"; then
1326         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1327         LDFLAGS="${LDFLAGS} -L$withval/lib"
1328       fi
1329     ])
1330
1331   AC_CHECK_HEADER(zlib.h,
1332         AC_CHECK_LIB(z, deflateInit2_,
1333          ZLIBS="-lz",
1334          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1335          CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1336
1337   AC_DEFINE(HAVE_ZIP,1, [Defined if ZIP and ZLIB are supported])
1338 fi
1339
1340
1341 #
1342 # Check whether we can support bzip2
1343 #
1344 if test "$use_bzip2" = yes ; then
1345   _cppflags="${CPPFLAGS}"
1346   _ldflags="${LDFLAGS}"
1347   AC_ARG_WITH(bzip2,
1348      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1349       [
1350       if test -d "$withval" ; then
1351         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1352         LDFLAGS="${LDFLAGS} -L$withval/lib"
1353       fi
1354       ],withval="")
1355
1356   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1357   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1358   # woefully out of date.
1359   if test "$withval" != no ; then
1360      AC_CHECK_HEADER(bzlib.h,
1361         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1362           [
1363           have_bz2=yes
1364           ZLIBS="$ZLIBS -lbz2"
1365           AC_DEFINE(HAVE_BZIP2,1,
1366                   [Defined if the bz2 compression library is available])
1367           ],
1368           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1369           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1370   fi
1371 fi
1372 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1373 AC_SUBST(ZLIBS)
1374
1375
1376 # Check for readline support
1377 GNUPG_CHECK_READLINE
1378
1379 #
1380 # Allow users to append something to the version string without
1381 # flagging it as development version.  The user version parts is
1382 # considered everything after a dash.
1383 #
1384 if test "$development_version" != yes; then
1385   changequote(,)dnl
1386   tmp_pat='[a-zA-Z]'
1387   changequote([,])dnl
1388   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1389     development_version=yes
1390   fi
1391 fi
1392 if test "$development_version" = yes; then
1393     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1394             [Defined if this is not a regular release])
1395 fi
1396
1397 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1398
1399 GNUPG_CHECK_GNUMAKE
1400
1401 # Add some extra libs here so that previous tests don't fail for
1402 # mysterious reasons - the final link step should bail out.
1403 # W32SOCKLIBS is also defined so that if can be used for tools not
1404 # requiring any network stuff but linking to code in libcommon which
1405 # tracks in winsock stuff (e.g. init_common_subsystems).
1406 if test "$have_w32_system" = yes; then
1407    if test "$have_w32ce_system" = yes; then
1408      W32SOCKLIBS="-lws2"
1409    else
1410      W32SOCKLIBS="-lws2_32"
1411    fi
1412    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1413 fi
1414
1415 AC_SUBST(NETLIBS)
1416 AC_SUBST(W32SOCKLIBS)
1417
1418 #
1419 # Setup gcc specific options
1420 #
1421 AC_MSG_NOTICE([checking for cc features])
1422 if test "$GCC" = yes; then
1423     # Note that it is okay to use CFLAGS here because this are just
1424     # warning options and the user should have a chance of overriding
1425     # them.
1426     if test "$USE_MAINTAINER_MODE" = "yes"; then
1427         CFLAGS="$CFLAGS -O3 -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1428         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1429         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1430         _gcc_cflags_save=$CFLAGS
1431         CFLAGS="-Wno-missing-field-initializers"
1432         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1433         AC_MSG_RESULT($_gcc_wopt)
1434         CFLAGS=$_gcc_cflags_save;
1435         if test x"$_gcc_wopt" = xyes ; then
1436           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1437         fi
1438         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1439         _gcc_cflags_save=$CFLAGS
1440         CFLAGS="-Wdeclaration-after-statement"
1441         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1442         AC_MSG_RESULT($_gcc_wopt)
1443         CFLAGS=$_gcc_cflags_save;
1444         if test x"$_gcc_wopt" = xyes ; then
1445           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1446         fi
1447     else
1448         CFLAGS="$CFLAGS -Wall"
1449     fi
1450
1451     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1452     _gcc_cflags_save=$CFLAGS
1453     CFLAGS="-Wno-pointer-sign"
1454     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1455     AC_MSG_RESULT($_gcc_psign)
1456     CFLAGS=$_gcc_cflags_save;
1457     if test x"$_gcc_psign" = xyes ; then
1458        CFLAGS="$CFLAGS -Wno-pointer-sign"
1459     fi
1460
1461     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1462     _gcc_cflags_save=$CFLAGS
1463     CFLAGS="-Wpointer-arith"
1464     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_psign=yes,_gcc_psign=no)
1465     AC_MSG_RESULT($_gcc_psign)
1466     CFLAGS=$_gcc_cflags_save;
1467     if test x"$_gcc_psign" = xyes ; then
1468        CFLAGS="$CFLAGS -Wpointer-arith"
1469     fi
1470 fi
1471
1472
1473 #
1474 # This is handy for debugging so the compiler doesn't rearrange
1475 # things and eliminate variables.
1476 #
1477 AC_ARG_ENABLE(optimization,
1478    AC_HELP_STRING([--disable-optimization],
1479                   [disable compiler optimization]),
1480                   [if test $enableval = no ; then
1481                       CFLAGS=`echo $CFLAGS | sed s/-O[[1-9]]\ /-O0\ /g`
1482                    fi])
1483
1484 #
1485 # Prepare building of estream
1486 #
1487 estream_INIT
1488
1489
1490 #
1491 # Decide what to build
1492 #
1493 if test "$have_adns" = "yes"; then
1494   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1495 fi
1496
1497
1498 missing_npth=no
1499 if test $have_ksba = no; then
1500   build_gpgsm=no
1501   build_scdaemon=no
1502 fi
1503
1504 build_agent_threaded=""
1505 if test "$build_agent" = "yes"; then
1506   if test $have_npth = no; then
1507      build_agent_threaded="(not multi-threaded)"
1508      missing_npth=yes
1509   fi
1510 fi
1511
1512 build_scdaemon_extra=""
1513 if test "$build_scdaemon" = "yes"; then
1514   tmp=""
1515   if test $have_npth = no; then
1516      build_scdaemon_extra="not multi-threaded"
1517      tmp=", "
1518      missing_npth=yes
1519   fi
1520   if test $have_libusb = no; then
1521      build_scdaemon_extra="${tmp}without internal CCID driver"
1522      tmp=", "
1523   fi
1524   if test -n "$build_scdaemon_extra"; then
1525      build_scdaemon_extra="(${build_scdaemon_extra})"
1526   fi
1527 fi
1528
1529
1530 if test "$build_agent_only" = "yes" ; then
1531   build_gpg=no
1532   build_gpgsm=no
1533   build_scdaemon=no
1534   build_tools=no
1535   build_doc=no
1536 fi
1537
1538 #
1539 # Set variables for use by th automake makefile.
1540 #
1541 AM_CONDITIONAL(BUILD_GPG,         test "$build_gpg" = "yes")
1542 AM_CONDITIONAL(BUILD_GPGSM,       test "$build_gpgsm" = "yes")
1543 AM_CONDITIONAL(BUILD_AGENT,       test "$build_agent" = "yes")
1544 AM_CONDITIONAL(BUILD_SCDAEMON,    test "$build_scdaemon" = "yes")
1545 AM_CONDITIONAL(BUILD_G13,         test "$build_g13" = "yes")
1546 AM_CONDITIONAL(BUILD_DIRMNGR,     test "$build_dirmngr" = "yes")
1547 AM_CONDITIONAL(BUILD_TOOLS,       test "$build_tools" = "yes")
1548 AM_CONDITIONAL(BUILD_DOC,         test "$build_doc" = "yes")
1549 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1550 AM_CONDITIONAL(BUILD_GPGTAR,      test "$build_gpgtar" = "yes")
1551
1552 AM_CONDITIONAL(RUN_GPG_TESTS,
1553                test x$cross_compiling = xno -a "$build_gpg" = yes )
1554
1555 #
1556 # Set some defines for use gpgconf.
1557 #
1558 if test "$build_gpg" = yes ; then
1559     AC_DEFINE(BUILD_WITH_GPG,1,[Defined if GPG is to be build])
1560 fi
1561 if test "$build_gpgsm" = yes ; then
1562     AC_DEFINE(BUILD_WITH_GPGSM,1,[Defined if GPGSM is to be build])
1563 fi
1564 if test "$build_agent" = yes ; then
1565     AC_DEFINE(BUILD_WITH_AGENT,1,[Defined if GPG-AGENT is to be build])
1566 fi
1567 if test "$build_scdaemon" = yes ; then
1568     AC_DEFINE(BUILD_WITH_SCDAEMON,1,[Defined if SCDAEMON is to be build])
1569 fi
1570 if test "$build_dirmngr" = yes ; then
1571     AC_DEFINE(BUILD_WITH_DIRMNGR,1,[Defined if SCDAEMON is to be build])
1572 fi
1573 if test "$build_g13" = yes ; then
1574     AC_DEFINE(BUILD_WITH_G13,1,[Defined if G13 is to be build])
1575 fi
1576
1577
1578
1579 #
1580 # Print errors here so that they are visible all
1581 # together and the user can acquire them all together.
1582 #
1583 die=no
1584 if test "$have_gpg_error" = "no"; then
1585    die=yes
1586    AC_MSG_NOTICE([[
1587 ***
1588 *** You need libgpg-error to build this program.
1589 **  This library is for example available at
1590 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1591 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1592 ***]])
1593 fi
1594 if test "$have_libgcrypt" = "no"; then
1595    die=yes
1596    AC_MSG_NOTICE([[
1597 ***
1598 *** You need libgcrypt to build this program.
1599 **  This library is for example available at
1600 ***   ftp://ftp.gnupg.org/gcrypt/alpha/libgcrypt/
1601 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1602 ***]])
1603 dnl elif test "$gnupg_cv_gcry_kdf_derive" = no; then
1604 dnl    die=yes
1605 dnl    AC_MSG_NOTICE([[
1606 dnl ***
1607 dnl *** Libgcrypt 1.5.0 has not yet been released and thus the API
1608 dnl *** is a bit in a flux.  Your version misses the function
1609 dnl ***        gcry_kdf_derive
1610 dnl *** You need to install a newer Libgcrypt version.
1611 dnl #***]])
1612 fi
1613 if test "$have_libassuan" = "no"; then
1614    die=yes
1615    AC_MSG_NOTICE([[
1616 ***
1617 *** You need libassuan to build this program.
1618 *** This library is for example available at
1619 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1620 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1621 ***]])
1622 fi
1623 if test "$have_ksba" = "no"; then
1624     AC_MSG_NOTICE([[
1625 ***
1626 *** You need libksba to build this program.
1627 *** This library is for example available at
1628 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1629 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1630 ***]])
1631 fi
1632 if test "$gnupg_have_ldap" = "no"; then
1633     die=yes
1634     AC_MSG_NOTICE([[
1635 ***
1636 *** You need a LDAP library to build this program.
1637 *** Check out
1638 ***    http://www.openldap.org
1639 *** for a suitable implementation.
1640 ***]])
1641    if test "$have_w32ce_system" = yes; then
1642     AC_MSG_NOTICE([[
1643 *** Note that CeGCC might be broken, a package fixing this is:
1644 ***    http://files.kolab.org/local/windows-ce/
1645 ***                           source/wldap32_0.1-mingw32ce.orig.tar.gz
1646 ***                           binary/wldap32-ce-arm-dev_0.1-1_all.deb
1647 ***]])
1648    fi
1649 fi
1650 if test "$missing_npth" = "yes"; then
1651     AC_MSG_NOTICE([[
1652 ***
1653 *** It is now required to build with support for the
1654 *** New Portable Threads Library (NPth). Please install this
1655 *** library first.  The library is for example available at
1656 ***   FIXME
1657 *** On a Debian GNU/Linux system you can install it using
1658 ***   apt-get install libnpth-dev
1659 *** To build GnuPG for Windows you need to use the W32NPTH
1660 *** package; available at:
1661 ***   ftp://ftp.g10code.com/g10code/w32npth/
1662 ***]])
1663    die=yes
1664 fi
1665
1666 if test "$die" = "yes"; then
1667     AC_MSG_ERROR([[
1668 ***
1669 *** Required libraries not found. Please consult the above messages
1670 *** and install them before running configure again.
1671 ***]])
1672 fi
1673
1674
1675
1676 AC_CONFIG_FILES([ m4/Makefile
1677 Makefile
1678 po/Makefile.in
1679 gl/Makefile
1680 include/Makefile
1681 common/Makefile
1682 kbx/Makefile
1683 g10/Makefile
1684 sm/Makefile
1685 agent/Makefile
1686 scd/Makefile
1687 g13/Makefile
1688 dirmngr/Makefile
1689 tools/gpg-zip
1690 tools/Makefile
1691 doc/Makefile
1692 tests/Makefile
1693 tests/openpgp/Makefile
1694 tests/pkits/Makefile
1695 ])
1696 #keyserver/Makefile
1697 #keyserver/gpg2keys_mailto
1698 #keyserver/gpg2keys_test
1699
1700
1701 AC_OUTPUT
1702
1703
1704 echo "
1705         GnuPG v${VERSION} has been configured as follows:
1706
1707         Platform:  $PRINTABLE_OS_NAME ($host)
1708
1709         OpenPGP:   $build_gpg
1710         S/MIME:    $build_gpgsm
1711         Agent:     $build_agent $build_agent_threaded
1712         Smartcard: $build_scdaemon $build_scdaemon_extra
1713         G13:       $build_g13
1714         Dirmngr:   $build_dirmngr
1715         Gpgtar:    $build_gpgtar
1716
1717         Protect tool:      $show_gnupg_protect_tool_pgm
1718         LDAP wrapper:      $show_gnupg_dirmngr_ldap_pgm
1719         Default agent:     $show_gnupg_agent_pgm
1720         Default pinentry:  $show_gnupg_pinentry_pgm
1721         Default scdaemon:  $show_gnupg_scdaemon_pgm
1722         Default dirmngr:   $show_gnupg_dirmngr_pgm
1723
1724         Use standard socket: $use_standard_socket
1725         Dirmngr auto start:  $dirmngr_auto_start
1726 "
1727 if test x"$use_regex" != xyes ; then
1728 echo "
1729         Warning: No regular expression support available.
1730                  OpenPGP trust signatures won't work.
1731                  gpg-check-pattern will not be build.
1732 "
1733 fi