e5d79389d83976abfc4560c0cafc4d50171488d1
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_PREREQ(2.13)
11 AC_INIT(g10/g10.c)
12 AC_CONFIG_AUX_DIR(scripts)
13 AM_CONFIG_HEADER(config.h)
14
15
16 VERSION=`cat $srcdir/VERSION`
17 PACKAGE=gnupg
18 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
19 static_modules="sha1 md5 rmd160"
20 AC_SUBST(VERSION)
21 AC_SUBST(PACKAGE)
22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
24
25 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
26                                                 $srcdir/cipher/Makefile.am`
27
28 dnl
29 dnl  Check for random module options
30 dnl
31 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
32 dnl         and check against this list
33
34 AC_MSG_CHECKING([which static random module to use])
35 AC_ARG_ENABLE(static-rnd,
36     [  --enable-static-rnd=[egd|unix|linux|none]  ],
37 [use_static_rnd=$enableval], [use_static_rnd=default] )
38
39 if test "$use_static_rnd" = no; then
40     use_static_rnd=default
41 fi
42
43 case "$use_static_rnd" in
44     egd | linux | unix | none | default )
45       AC_MSG_RESULT($use_static_rnd)
46       ;;
47     * )
48       AC_MSG_RESULT(invalid argument)
49       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
50       ;;
51 esac
52
53 dnl
54 dnl See whether the user wants to disable checking for /dev/random
55
56 AC_MSG_CHECKING([whether use of /dev/random is requested])
57 AC_ARG_ENABLE(dev-random,
58 [  --disable-dev-random    disable the use of dev random],
59     try_dev_random=$enableval, try_dev_random=yes)
60 AC_MSG_RESULT($try_dev_random)
61
62
63 dnl
64 dnl  Check other options
65 dnl
66
67 AC_MSG_CHECKING([whether use of extensions is requested])
68 AC_ARG_ENABLE(dynload,
69 [  --disable-dynload       disable use of extensions],
70     try_dynload=$enableval, try_dynload=yes)
71 AC_MSG_RESULT($try_dynload)
72
73 AC_MSG_CHECKING([whether assembler modules are requested])
74 AC_ARG_ENABLE(asm,
75 [  --disable-asm           do not use assembler modules],
76      try_asm_modules=$enableval, try_asm_modules=yes)
77 AC_MSG_RESULT($try_asm_modules)
78
79 AC_MSG_CHECKING([whether memory debugging is requested])
80 AC_ARG_ENABLE(m-debug,
81 [  --enable-m-debug        enable debugging of memory allocation],
82 use_m_debug=$enableval, use_m_debug=no)
83 AC_MSG_RESULT($use_m_debug)
84 if test "$use_m_debug" = yes; then
85     AC_DEFINE(M_DEBUG)
86     use_m_guard=yes
87 else
88     AC_MSG_CHECKING([whether memory guard is requested])
89     AC_ARG_ENABLE(m-guard,
90     [  --enable-m-guard        enable memory guard facility],
91     use_m_guard=$enableval, use_m_guard=no)
92     AC_MSG_RESULT($use_m_guard)
93 fi
94 if test "$use_m_guard" = yes ; then
95     AC_DEFINE(M_GUARD)
96 fi
97
98
99 AC_MSG_CHECKING([whether included zlib is requested])
100 AC_ARG_WITH(included-zlib,
101     [  --with-included-zlib    use the zlib code included here],
102 [g10_force_zlib=yes], [g10_force_zlib=no] )
103 AC_MSG_RESULT($g10_force_zlib)
104
105 dnl
106 dnl Check wether we want to compile libgcrypt
107 dnl
108 AC_MSG_CHECKING([whether compilation of libgcrypt is requested])
109 AC_ARG_ENABLE(libgcrypt,
110     [  --enable-libgcrypt      compile the libgcrypt [default=no]],
111 [compile_libgcrypt="$enableval"],[compile_libgcrypt=no])
112 AM_CONDITIONAL(COMPILE_LIBGCRYPT, test x$compile_libgcrypt = xyes)
113 AC_MSG_RESULT($compile_libgcrypt)
114
115
116 dnl
117 dnl Check whether we want to use Linux capabilities
118 dnl
119 AC_MSG_CHECKING([whether use of capabilities is requested])
120 AC_ARG_WITH(capabilities,
121     [  --with-capabilities     use linux capabilities [default=no]],
122 [use_capabilities="$withval"],[use_capabilities=no])
123 AC_MSG_RESULT($use_capabilities)
124
125
126 dnl Checks for programs.
127
128 AC_CANONICAL_SYSTEM
129 AC_ARG_PROGRAM
130 AC_PROG_MAKE_SET
131 AM_SANITY_CHECK
132 missing_dir=`cd $ac_aux_dir && pwd`
133 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
134 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
135 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
136 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
137 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
138 AC_PROG_CC
139 AC_PROG_CPP
140 AC_ISC_POSIX
141 AC_PROG_INSTALL
142 AC_PROG_RANLIB
143 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
144 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
145
146
147 dnl
148 dnl Don't default to build shared libs
149 dnl
150 AM_DISABLE_SHARED
151 AM_PROG_LIBTOOL
152
153
154 MPI_OPT_FLAGS=""
155 if test "$GCC" = yes; then
156     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
157 fi
158
159
160 try_gettext=yes
161 try_gdbm=yes
162 case "${target}" in
163     i386--mingw32)
164         # special stuff for Windoze NT
165         cross_compiling=yes
166         CC="i386--mingw32-gcc"
167         CPP="i386--mingw32-gcc -E"
168         RANLIB="i386--mingw32-ranlib"
169         ac_cv_have_dev_random=no
170         AC_DEFINE(USE_ONLY_8DOT3)
171         AC_DEFINE(HAVE_DRIVE_LETTERS)
172         AC_DEFINE(HAVE_DOSISH_SYSTEM)
173         try_gettext="no"
174         try_gdbm="no"
175         ;;
176     i386-emx-os2 | i[3456]86-pc-os2*emx )
177         # OS/2 with the EMX environment
178         ac_cv_have_dev_random=no
179         AC_DEFINE(HAVE_DRIVE_LETTERS)
180         AC_DEFINE(HAVE_DOSISH_SYSTEM)
181         try_gettext="no"
182         try_gdbm="no"
183         ;;
184
185     *-*-hpux*)
186         if test -z "$GCC" ; then
187             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
188         fi
189         ;;
190     *-dec-osf4*)
191         if test -z "$GCC" ; then
192             # Suppress all warnings
193             # to get rid of the unsigned/signed char mismatch warnings.
194             CFLAGS="$CFLAGS -w"
195         fi
196         ;;
197     m68k-atari-mint)
198         ;;
199     *)
200        ;;
201 esac
202
203 AC_SUBST(MPI_OPT_FLAGS)
204 GNUPG_SYS_SYMBOL_UNDERSCORE
205 GNUPG_CHECK_PIC
206 GNUPG_CHECK_RDYNAMIC
207 if test "$NO_PIC" = yes; then
208     try_dynload=no
209 fi
210
211
212 case "${target}" in
213     i386--mingw32)
214         PRINTABLE_OS_NAME="MingW32"
215         ;;
216     i386-emx-os2 | i[3456]86-pc-os2*emx )
217         PRINTABLE_OS_NAME="OS/2"
218         ;;
219     *-linux*)
220         PRINTABLE_OS_NAME="GNU/Linux"
221         ;;
222     *)
223         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
224         ;;
225 esac
226 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
227
228 dnl  Fixme: Are these the best flags for OpenBSD????
229 dnl (I have removed the -lc from * ...CFLAGS for test purposes.)
230 case "${target}" in
231     *-openbsd*)
232         NAME_OF_DEV_RANDOM="/dev/srandom"
233         NAME_OF_DEV_URANDOM="/dev/urandom"
234         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
235         ;;
236     *)
237         NAME_OF_DEV_RANDOM="/dev/random"
238         NAME_OF_DEV_URANDOM="/dev/urandom"
239         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"
240         ;;
241 esac
242 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
243 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
244 AC_SUBST(MPI_OPT_FLAGS)
245
246
247 dnl Checks for libraries.
248
249 if test "$try_gettext" = yes; then
250 AM_GNU_GETTEXT
251 else
252 USE_NLS=no
253 USE_INCLUDED_LIBINTL=no
254 AC_SUBST(USE_NLS)
255 AC_SUBST(USE_INCLUDED_LIBINTL)
256 fi
257
258 dnl
259 dnl There are lot of misconfigured systems.  We include
260 dnl gdbm support only if the lib and the header is installed.
261 dnl
262 if test "$try_gdbm" = yes; then
263 AC_CHECK_HEADERS(gdbm.h)
264 if test "$ac_cv_header_gdbm_h" = yes ; then
265   AC_CHECK_LIB(gdbm,gdbm_firstkey)
266 fi
267 fi
268
269
270 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
271 dnl gethostbyname in libsocket but needs libnsl for socket.
272 AC_CHECK_LIB(nsl, gethostbyname)
273 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
274 if test x$ac_need_libsocket = x1; then
275     LIBS="$LIBS -lsocket"
276 fi
277 if test x$ac_try_nsl = x1; then
278     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
279     if test x$ac_need_libnsl = x1
280     then
281         LIBS="$LIBS -lnsl"
282     fi
283 fi
284
285
286 if test "$try_dynload" = yes ; then
287   AC_CHECK_LIB(dl,dlopen)
288   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
289     AC_DEFINE(USE_DYNAMIC_LINKING)
290     AC_DEFINE(HAVE_DL_DLOPEN)
291     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
292     use_gnupg_extensions=yes
293   else
294     AC_CHECK_LIB(c,dlopen)
295     if test "$ac_cv_lib_c_dlopen" = "yes"; then
296       AC_DEFINE(USE_DYNAMIC_LINKING)
297       AC_DEFINE(HAVE_DL_DLOPEN)
298       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
299       use_gnupg_extensions=yes
300     else
301       AC_CHECK_LIB(dld,shl_load)
302       if test "$ac_cv_lib_dld_shl_load" = "yes"; then
303         AC_DEFINE(USE_DYNAMIC_LINKING)
304         AC_DEFINE(HAVE_DL_SHL_LOAD)
305         DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
306         use_gnupg_extensions=yes
307 dnl -----------------
308 dnl  DLD is not ready for use. So I better disable this test
309 dnl
310 dnl    AC_CHECK_LIB(dld,dld_link)
311 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
312 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
313 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
314 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
315 dnl      use_gnupg_extensions=yes
316 dnl ---------------
317       fi
318     fi
319   fi
320 else
321   AC_MSG_CHECKING(for dynamic loading)
322   DYNLINK_LDFLAGS=
323   DYNLINK_MOD_CFLAGS=
324   use_gnupg_extensions=no
325   AC_MSG_RESULT(has been disabled)
326 fi
327
328 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
329 AC_SUBST(DYNLINK_LDFLAGS)
330 AC_SUBST(DYNLINK_MOD_CFLAGS)
331
332
333 dnl Checks for header files.
334 AC_HEADER_STDC
335 AC_CHECK_HEADERS(unistd.h langinfo.h)
336
337
338 dnl Checks for typedefs, structures, and compiler characteristics.
339 AC_C_CONST
340 AC_C_INLINE
341 AC_TYPE_SIZE_T
342 AC_TYPE_SIGNAL
343 AC_DECL_SYS_SIGLIST
344
345 GNUPG_CHECK_ENDIAN
346
347
348 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
349 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
350 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
351 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
352 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
353
354 AC_CHECK_SIZEOF(unsigned short, 2)
355 AC_CHECK_SIZEOF(unsigned int, 4)
356 AC_CHECK_SIZEOF(unsigned long, 4)
357
358 if test "$ac_cv_sizeof_unsigned_short" = "0" \
359    || test "$ac_cv_sizeof_unsigned_int" = "0" \
360    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
361     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
362 fi
363
364
365
366 dnl Checks for library functions.
367 AC_FUNC_VPRINTF
368 AC_CHECK_FUNCS(strerror stpcpy strlwr stricmp tcgetattr rand strtoul mmap)
369 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
370 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
371
372 GNUPG_CHECK_MLOCK
373
374 dnl
375 dnl Check whether we can use Linux capabilities as requested
376 dnl
377 if test "$use_capabilities" = "yes" ; then
378 use_capabilities=no
379 AC_CHECK_HEADERS(sys/capability.h)
380 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
381   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
382   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
383      AC_DEFINE(USE_CAPABILITIES)
384      use_capabilities=yes
385   fi
386 fi
387 if test "$use_capabilities" = "no" ; then
388     AC_MSG_WARN([[
389 *** The use of capabilities on this system is not possible.
390 *** You need a recent Linux kernel and some patches:
391 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
392 ***   fcap-module-990613.tar.gz     (kernel module)
393 ***   libcap-1.92.tar.gz            (user mode library and utilities)
394 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
395 *** set (filesystems menu). Be warned: This code is *really* ALPHA.]])
396 fi
397 fi
398
399
400 GNUPG_CHECK_IPC
401 if test "$ac_cv_header_sys_shm_h" = "yes"; then
402   AC_DEFINE(USE_SHM_COPROCESSING)
403 fi
404
405 dnl
406 dnl check whether we have a random device
407 dnl
408 if test "$try_dev_random" = yes ; then
409     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
410     [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
411       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
412     if test "$ac_cv_have_dev_random" = yes; then
413         AC_DEFINE(HAVE_DEV_RANDOM)
414     fi
415 else
416     AC_MSG_CHECKING(for random device)
417     ac_cv_have_dev_random=no
418     AC_MSG_RESULT(has been disabled)
419 fi
420
421 dnl
422 dnl and whether this device supports ioctl
423 dnl (Note, that we should do a real test here)
424 dnl
425 if test "$ac_cv_have_dev_random" = yes ; then
426     AC_CHECK_HEADERS(linux/random.h)
427     AC_CACHE_CHECK(for random device ioctl, ac_cv_have_dev_random_ioctl,
428       [ if test "$ac_cv_header_linux_random_h" = yes ; then
429           ac_cv_have_dev_random_ioctl=yes;
430         else
431           ac_cv_have_dev_random_ioctl=no;
432         fi
433       ])
434     if test "$ac_cv_have_dev_random_ioctl" = yes; then
435         AC_DEFINE(HAVE_DEV_RANDOM_IOCTL)
436     fi
437 fi
438
439
440 dnl
441 dnl Figure out the default linkage mode for cipher modules
442 dnl
443 dnl (We always need a static rmd160)
444 static_modules="$static_modules rmd160"
445 if test "$use_static_rnd" = default; then
446   if test "$ac_cv_have_dev_random" = yes; then
447       static_modules="$static_modules rndlinux"
448   else
449       case "${target}" in
450           i386--mingw32)
451               static_modules="$static_modules rndw32"
452               ;;
453           i386-emx-os2|i[3456]86-pc-os2*emx)
454               static_modules="$static_modules rndos2"
455               ;;
456           m68k-atari-mint)
457               static_modules="$static_modules rndatari"
458               ;;
459           *)
460               static_modules="$static_modules rndunix"
461              ;;
462       esac
463   fi
464 else
465   if test "$use_static_rnd" = none; then
466     :
467   else
468     static_modules="$static_modules rnd$use_static_rnd"
469   fi
470 fi
471
472 dnl
473 dnl Parse the modules list and build the list
474 dnl of static and dymically linked modules
475 dnl
476 STATIC_CIPHER_NAMES=""
477 STATIC_CIPHER_OBJS=""
478 DYNAMIC_CIPHER_MODS=""
479 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
480 for name in $MODULES_IN_CIPHER; do
481     x="no"
482     for i in $static_modules; do
483         if test "$name" = "$i" ; then
484             x="yes"
485         fi
486     done;
487     if test $x = yes; then
488         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
489         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
490     else
491         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
492         GNUPG_MSG_PRINT([$name])
493     fi
494 done
495 AC_MSG_RESULT()
496 AC_SUBST(STATIC_CIPHER_OBJS)
497 AC_SUBST(STATIC_CIPHER_NAMES)
498 AC_SUBST(DYNAMIC_CIPHER_MODS)
499
500 dnl
501 dnl And build the constructor file
502 dnl
503
504 test -d cipher || mkdir cipher
505 cat <<G10EOF >cipher/construct.c
506 /* automatically generated by configure - do not edit */
507
508 G10EOF
509 GNUPG_MSG_PRINT([statically linked cipher modules:])
510 for name in $STATIC_CIPHER_NAMES; do
511     echo "void ${name}_constructor(void);" >>cipher/construct.c
512     GNUPG_MSG_PRINT([$name])
513 done
514 AC_MSG_RESULT()
515 cat <<G10EOF >>cipher/construct.c
516
517 void
518 cipher_modules_constructor(void)
519 {
520     static int done = 0;
521     if( done )
522         return;
523     done = 1;
524
525 G10EOF
526 for name in $STATIC_CIPHER_NAMES; do
527     echo "   ${name}_constructor();" >>cipher/construct.c
528 done
529 echo '}' >>cipher/construct.c
530
531
532
533
534 dnl
535 dnl Figure how to link the cipher modules
536 dnl
537 AC_SUBST(STATIC_CIPHER_OBJS)
538 AC_SUBST(DYNAMIC_CIPHER_MODS)
539
540
541 dnl setup assembler stuff
542 AC_MSG_CHECKING(for mpi assembler functions)
543 if test -f $srcdir/mpi/config.links ; then
544     . $srcdir/mpi/config.links
545     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
546     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
547     ac_cv_mpi_sflags="$mpi_sflags"
548     ac_cv_mpi_config_done="yes"
549     AC_MSG_RESULT(done)
550 else
551     AC_MSG_RESULT(failed)
552     AC_MSG_ERROR([mpi/config.links missing!])
553 fi
554 MPI_EXTRA_ASM_OBJS=""
555 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
556 GNUPG_MSG_PRINT([mpi extra asm functions:])
557 for i in $ac_cv_mpi_extra_asm_modules; do
558     GNUPG_MSG_PRINT([$i])
559     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
560 done
561 AC_MSG_RESULT()
562 fi
563 AC_SUBST(MPI_EXTRA_ASM_OBJS)
564 MPI_SFLAGS="$ac_cv_mpi_sflags"
565 AC_SUBST(MPI_SFLAGS)
566
567 dnl Do we have zlib? Must do it here because Solaris failed
568 dnl when compiling a conftest (due to the "-lz" from LIBS).
569 use_local_zlib=yes
570 if test "$g10_force_zlib" = "yes"; then
571   :
572 else
573   AC_CHECK_HEADERS(zlib.h)
574   if test "$ac_cv_header_zlib_h" = yes ; then
575       AC_CHECK_LIB(z,deflateInit2_,use_local_zlib=no,:)
576   fi
577 fi
578
579 if test "$use_local_zlib" = yes ; then
580     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
581     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
582     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
583     ZLIBS="../zlib/libzlib.a"
584 else
585     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
586     ZLIBS=
587     LIBS="-lz $LIBS"
588 fi
589 AC_SUBST(ZLIBS)
590
591
592 changequote(,)dnl
593 tmp_pat='[a-zA-Z]'
594 changequote([,])dnl
595 if echo "$VERSION" | grep $tmp_pat >/dev/null ; then
596     AC_DEFINE(IS_DEVELOPMENT_VERSION)
597 fi
598
599 GNUPG_DO_LINK_FILES
600
601
602 AC_OUTPUT_COMMANDS([
603 cat >g10defs.tmp <<G10EOF
604 /* Generated automatically by configure */
605 #ifdef HAVE_DRIVE_LETTERS
606   #define G10_LOCALEDIR "c:/lib/gnupg/locale"
607   #define GNUPG_LIBDIR  "c:/lib/gnupg"
608   #define GNUPG_DATADIR "c:/lib/gnupg"
609 #else
610   #define G10_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
611   #define GNUPG_LIBDIR  "${libdir}/gnupg"
612   #define GNUPG_DATADIR "${datadir}/gnupg"
613 #endif
614 G10EOF
615 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
616     echo "g10defs.h is unchanged"
617     rm -f g10defs.tmp
618 else
619     rm -f g10defs.h
620     mv g10defs.tmp g10defs.h
621     echo "g10defs.h created"
622 fi
623 ],[
624 prefix=$prefix
625 exec_prefix=$exec_prefix
626 libdir=$libdir
627 datadir=$datadir
628 DATADIRNAME=$DATADIRNAME
629 ])
630
631
632 AC_OUTPUT([
633 Makefile
634 intl/Makefile
635 po/Makefile.in
636 util/Makefile
637 mpi/Makefile
638 cipher/Makefile
639 g10/Makefile
640 doc/Makefile
641 tools/Makefile
642 zlib/Makefile
643 checks/Makefile
644 gcrypt/Makefile
645 ])
646
647 dnl *-*wedit:notab*-*  Please keep this as the last line.