See ChangeLog: Mon May 17 21:54:43 CEST 1999 Werner Koch
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_PREREQ(2.13)
11 AC_INIT(g10/g10.c)
12 AC_CONFIG_AUX_DIR(scripts)
13 AM_CONFIG_HEADER(config.h)
14
15
16 VERSION=`cat $srcdir/VERSION`
17 PACKAGE=gnupg
18 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
19 static_modules="sha1 md5 rmd160"
20 AC_SUBST(VERSION)
21 AC_SUBST(PACKAGE)
22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
24
25 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
26                                                 $srcdir/cipher/Makefile.am`
27
28 dnl
29 dnl  Check for random module options
30 dnl
31 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
32 dnl         and check against this list
33
34 AC_MSG_CHECKING([which static random module to use])
35 AC_ARG_ENABLE(static-rnd,
36     [  --enable-static-rnd=[egd|unix|linux|none]  ],
37 [use_static_rnd=$enableval], [use_static_rnd=default] )
38
39 if test "$use_static_rnd" = no; then
40     use_static_rnd=default
41 fi
42
43 case "$use_static_rnd" in
44     egd | linux | unix | none | default )
45       AC_MSG_RESULT($use_static_rnd)
46       ;;
47     * )
48       AC_MSG_RESULT(invalid argument)
49       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
50       ;;
51 esac
52
53 dnl
54 dnl See whether the user wants to disable checking for /dev/random
55
56 AC_MSG_CHECKING([whether use of /dev/random is requested])
57 AC_ARG_ENABLE(dev-random,
58 [  --disable-dev-random    disable the use of dev random],
59     try_dev_random=$enableval, try_dev_random=yes)
60 AC_MSG_RESULT($try_dev_random)
61
62
63 dnl
64 dnl  Check other options
65 dnl
66
67 AC_MSG_CHECKING([whether use of extensions is requested])
68 AC_ARG_ENABLE(dynload,
69 [  --disable-dynload       disable use of extensions],
70     try_dynload=$enableval, try_dynload=yes)
71 AC_MSG_RESULT($try_dynload)
72
73 AC_MSG_CHECKING([whether assembler modules are requested])
74 AC_ARG_ENABLE(asm,
75 [  --disable-asm           do not use assembler modules],
76      try_asm_modules=$enableval, try_asm_modules=yes)
77 AC_MSG_RESULT($try_asm_modules)
78
79 AC_MSG_CHECKING([whether memory debugging is requested])
80 AC_ARG_ENABLE(m-debug,
81 [  --enable-m-debug        enable debugging of memory allocation],
82 use_m_debug=$enableval, use_m_debug=no)
83 AC_MSG_RESULT($use_m_debug)
84 if test "$use_m_debug" = yes; then
85     AC_DEFINE(M_DEBUG)
86     use_m_guard=yes
87 else
88     AC_MSG_CHECKING([whether memory guard is requested])
89     AC_ARG_ENABLE(m-guard,
90     [  --enable-m-guard        enable memory guard facility],
91     use_m_guard=$enableval, use_m_guard=no)
92     AC_MSG_RESULT($use_m_guard)
93 fi
94 if test "$use_m_guard" = yes ; then
95     AC_DEFINE(M_GUARD)
96 fi
97
98
99 AC_MSG_CHECKING([whether included zlib is requested])
100 AC_ARG_WITH(included-zlib,
101     [  --with-included-zlib    use the zlib code included here],
102 [g10_force_zlib=yes], [g10_force_zlib=no] )
103 AC_MSG_RESULT($g10_force_zlib)
104
105
106 dnl Checks for programs.
107
108 AC_CANONICAL_SYSTEM
109 AC_ARG_PROGRAM
110 AC_PROG_MAKE_SET
111 AM_SANITY_CHECK
112 missing_dir=`cd $ac_aux_dir && pwd`
113 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
114 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
115 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
116 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
117 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
118 AC_PROG_CC
119 AC_PROG_CPP
120 AC_ISC_POSIX
121 AC_PROG_INSTALL
122 AC_PROG_RANLIB
123
124 MPI_OPT_FLAGS=""
125 if test "$GCC" = yes; then
126     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
127 fi
128
129
130 try_gettext=yes
131 try_gdbm=yes
132 case "${target}" in
133     i386--mingw32)
134         # special stuff for Windoze NT
135         cross_compiling=yes
136         CC="i386--mingw32-gcc"
137         CPP="i386--mingw32-gcc -E"
138         RANLIB="i386--mingw32-ranlib"
139         ac_cv_have_dev_random=no
140         AC_DEFINE(USE_ONLY_8DOT3)
141         AC_DEFINE(HAVE_DRIVE_LETTERS)
142         AC_DEFINE(HAVE_DOSISH_SYSTEM)
143         try_gettext="no"
144         try_gdbm="no"
145         ;;
146     i386-emx-os2)
147         # OS/2 with the EMX environment
148         ac_cv_have_dev_random=no
149         AC_DEFINE(HAVE_DRIVE_LETTERS)
150         AC_DEFINE(HAVE_DOSISH_SYSTEM)
151         try_gettext="no"
152         try_gdbm="no"
153         ;;
154     *-*-hpux*)
155         if test -z "$GCC" ; then
156             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
157         fi
158         ;;
159     *-dec-osf4*)
160         if test -z "$GCC" ; then
161             # Suppress all warnings
162             # to get rid of the unsigned/signed char mismatch warnings.
163             CFLAGS="$CFLAGS -w"
164         fi
165         ;;
166     m68k-atari-mint)
167         ;;
168     *)
169        ;;
170 esac
171
172 AC_SUBST(MPI_OPT_FLAGS)
173 GNUPG_SYS_SYMBOL_UNDERSCORE
174 GNUPG_CHECK_PIC
175 GNUPG_CHECK_RDYNAMIC
176 if test "$NO_PIC" = yes; then
177     try_dynload=no
178 fi
179
180
181 case "${target}" in
182     i386--mingw32)
183         PRINTABLE_OS_NAME="MingW32"
184         ;;
185     i386-emx-os2)
186         PRINTABLE_OS_NAME="OS/2"
187         ;;
188     *-linux*)
189         PRINTABLE_OS_NAME="GNU/Linux"
190         ;;
191     *)
192         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
193         ;;
194 esac
195 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
196
197 dnl  Fixme: Are these the best flags for OpenBSD????
198 case "${target}" in
199     *-openbsd*)
200         NAME_OF_DEV_RANDOM="/dev/srandom"
201         NAME_OF_DEV_URANDOM="/dev/urandom"
202         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
203         ;;
204     *)
205         NAME_OF_DEV_RANDOM="/dev/random"
206         NAME_OF_DEV_URANDOM="/dev/urandom"
207         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC -lc"
208         ;;
209 esac
210 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
211 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
212 AC_SUBST(MPI_OPT_FLAGS)
213
214
215 dnl Checks for libraries.
216
217 if test "$try_gettext" = yes; then
218 AM_GNU_GETTEXT
219 fi
220
221 if test "$try_gdbm" = yes; then
222 AC_CHECK_LIB(gdbm,gdbm_firstkey)
223 fi
224
225 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
226 dnl gethostbyname in libsocket but needs libnsl for socket.
227 AC_CHECK_LIB(nsl, gethostbyname)
228 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
229 if test x$ac_need_libsocket = x1; then
230     LIBS="$LIBS -lsocket"
231 fi
232 if test x$ac_try_nsl = x1; then
233     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
234     if test x$ac_need_libnsl = x1
235     then
236         LIBS="$LIBS -lnsl"
237     fi
238 fi
239
240
241 if test "$try_dynload" = yes ; then
242   AC_CHECK_LIB(dl,dlopen)
243   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
244     AC_DEFINE(USE_DYNAMIC_LINKING)
245     AC_DEFINE(HAVE_DL_DLOPEN)
246     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
247     use_gnupg_extensions=yes
248   else
249     AC_CHECK_LIB(c,dlopen)
250     if test "$ac_cv_lib_c_dlopen" = "yes"; then
251       AC_DEFINE(USE_DYNAMIC_LINKING)
252       AC_DEFINE(HAVE_DL_DLOPEN)
253       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
254       use_gnupg_extensions=yes
255 dnl else
256 dnl
257 dnl  DLD is not ready for use. So I better disable this test
258 dnl
259 dnl    AC_CHECK_LIB(dld,dld_link)
260 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
261 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
262 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
263 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
264 dnl      use_gnupg_extensions=yes
265 dnl    fi
266     fi
267   fi
268 else
269   AC_MSG_CHECKING(for dynamic loading)
270   DYNLINK_LDFLAGS=
271   DYNLINK_MOD_CFLAGS=
272   use_gnupg_extensions=no
273   AC_MSG_RESULT(has been disabled)
274 fi
275
276 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
277 AC_SUBST(DYNLINK_LDFLAGS)
278 AC_SUBST(DYNLINK_MOD_CFLAGS)
279
280
281 dnl Checks for header files.
282 AC_HEADER_STDC
283 AC_CHECK_HEADERS(unistd.h langinfo.h)
284
285
286 dnl Checks for typedefs, structures, and compiler characteristics.
287 AC_C_CONST
288 AC_C_INLINE
289 AC_TYPE_SIZE_T
290 AC_TYPE_SIGNAL
291 AC_DECL_SYS_SIGLIST
292
293 GNUPG_CHECK_ENDIAN
294
295
296 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
297 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
298 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
299 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
300 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
301
302 AC_CHECK_SIZEOF(unsigned short, 2)
303 AC_CHECK_SIZEOF(unsigned int, 4)
304 AC_CHECK_SIZEOF(unsigned long, 4)
305
306 if test "$ac_cv_sizeof_unsigned_short" = "0" \
307    || test "$ac_cv_sizeof_unsigned_int" = "0" \
308    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
309     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
310 fi
311
312
313
314 dnl Checks for library functions.
315 AC_FUNC_VPRINTF
316 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
317 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
318 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
319
320 GNUPG_CHECK_MLOCK
321
322 GNUPG_CHECK_IPC
323 if test "$ac_cv_header_sys_shm_h" = "yes"; then
324   AC_DEFINE(USE_SHM_COPROCESSING)
325 fi
326
327 dnl check whether we have a random device
328 if test "$try_dev_random" = yes ; then
329 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
330 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
331   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
332 if test "$ac_cv_have_dev_random" = yes; then
333     AC_DEFINE(HAVE_DEV_RANDOM)
334 fi
335 else
336     AC_MSG_CHECKING(for random device)
337     ac_cv_have_dev_random=no
338     AC_MSG_RESULT(has been disabled)
339 fi
340
341
342 dnl
343 dnl Figure out the default linkage mode for cipher modules
344 dnl
345 dnl (We always need a static rmd160)
346 static_modules="$static_modules rmd160"
347 if test "$use_static_rnd" = default; then
348   if test "$ac_cv_have_dev_random" = yes; then
349       static_modules="$static_modules rndlinux"
350   else
351       case "${target}" in
352           i386--mingw32)
353               static_modules="$static_modules rndw32"
354               ;;
355           i386-emx-os2)
356               static_modules="$static_modules rndos2"
357               ;;
358           m68k-atari-mint)
359               static_modules="$static_modules rndatari"
360               ;;
361           *)
362               static_modules="$static_modules rndunix"
363              ;;
364       esac
365   fi
366 else
367   if test "$use_static_rnd" = none; then
368     :
369   else
370     static_modules="$static_modules rnd$use_static_rnd"
371   fi
372 fi
373
374 dnl
375 dnl Parse the modules list and build the list
376 dnl of static and dymically linked modules
377 dnl
378 STATIC_CIPHER_NAMES=""
379 STATIC_CIPHER_OBJS=""
380 DYNAMIC_CIPHER_MODS=""
381 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
382 for name in $MODULES_IN_CIPHER; do
383     x="no"
384     for i in $static_modules; do
385         if test "$name" = "$i" ; then
386             x="yes"
387         fi
388     done;
389     if test $x = yes; then
390         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
391         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
392     else
393         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
394         GNUPG_MSG_PRINT([$name])
395     fi
396 done
397 AC_MSG_RESULT()
398 AC_SUBST(STATIC_CIPHER_OBJS)
399 AC_SUBST(STATIC_CIPHER_NAMES)
400 AC_SUBST(DYNAMIC_CIPHER_MODS)
401
402 dnl
403 dnl And build the constructor file
404 dnl
405
406 test -d cipher || mkdir cipher
407 cat <<G10EOF >cipher/construct.c
408 /* automatically generated by configure - do not edit */
409
410 G10EOF
411 GNUPG_MSG_PRINT([statically linked cipher modules:])
412 for name in $STATIC_CIPHER_NAMES; do
413     echo "void ${name}_constructor(void);" >>cipher/construct.c
414     GNUPG_MSG_PRINT([$name])
415 done
416 AC_MSG_RESULT()
417 cat <<G10EOF >>cipher/construct.c
418
419 void
420 cipher_modules_constructor(void)
421 {
422     static int done = 0;
423     if( done )
424         return;
425     done = 1;
426
427 G10EOF
428 for name in $STATIC_CIPHER_NAMES; do
429     echo "   ${name}_constructor();" >>cipher/construct.c
430 done
431 echo '}' >>cipher/construct.c
432
433
434
435
436 dnl
437 dnl Figure how to link the cipher modules
438 dnl
439 AC_SUBST(STATIC_CIPHER_OBJS)
440 AC_SUBST(DYNAMIC_CIPHER_MODS)
441
442
443 dnl setup assembler stuff
444 AC_MSG_CHECKING(for mpi assembler functions)
445 if test -f $srcdir/mpi/config.links ; then
446     . $srcdir/mpi/config.links
447     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
448     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
449     ac_cv_mpi_sflags="$mpi_sflags"
450     ac_cv_mpi_config_done="yes"
451     AC_MSG_RESULT(done)
452 else
453     AC_MSG_RESULT(failed)
454     AC_MSG_ERROR([mpi/config.links missing!])
455 fi
456 MPI_EXTRA_ASM_OBJS=""
457 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
458 GNUPG_MSG_PRINT([mpi extra asm functions:])
459 for i in $ac_cv_mpi_extra_asm_modules; do
460     GNUPG_MSG_PRINT([$i])
461     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
462 done
463 AC_MSG_RESULT()
464 fi
465 AC_SUBST(MPI_EXTRA_ASM_OBJS)
466 MPI_SFLAGS="$ac_cv_mpi_sflags"
467 AC_SUBST(MPI_SFLAGS)
468
469 dnl Do we have zlib? Must do it here because Solaris failed
470 dnl when compiling a conftest (due to the "-lz" from LIBS).
471 if test "$g10_force_zlib" = "yes"; then
472     ZLIBS="../zlib/libzlib.a"
473     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
474     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
475     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
476 else
477 AC_CHECK_HEADERS(zlib.h)
478 if test "$ac_cv_header_zlib_h" = yes ; then
479     LIBS="$LIBS -lz"
480     ZLIBS=
481     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
482 else
483     ZLIBS="../zlib/libzlib.a"
484     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
485     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
486     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
487 fi
488 fi
489 AC_SUBST(ZLIBS)
490
491 if echo "$VERSION" | grep '[a-zA-Z]' >/dev/null ; then
492     AC_DEFINE(IS_DEVELOPMENT_VERSION)
493 fi
494
495 GNUPG_DO_LINK_FILES
496
497
498 AC_OUTPUT_COMMANDS([
499 cat >g10defs.tmp <<G10EOF
500 /* Generated automatically by configure */
501 #ifdef HAVE_DRIVE_LETTERS
502   #define G10_LOCALEDIR "c:/lib/gnupg/locale"
503   #define GNUPG_LIBDIR  "c:/lib/gnupg"
504   #define GNUPG_DATADIR "c:/lib/gnupg"
505 #else
506   #define G10_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
507   #define GNUPG_LIBDIR  "${libdir}/gnupg"
508   #define GNUPG_DATADIR "${datadir}/gnupg"
509 #endif
510 G10EOF
511 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
512     echo "g10defs.h is unchanged"
513     rm -f g10defs.tmp
514 else
515     rm -f g10defs.h
516     mv g10defs.tmp g10defs.h
517     echo "g10defs.h created"
518 fi
519 ],[
520 prefix=$prefix
521 exec_prefix=$exec_prefix
522 libdir=$libdir
523 datadir=$datadir
524 DATADIRNAME=$DATADIRNAME
525 ])
526
527
528 AC_OUTPUT([
529 Makefile
530 intl/Makefile
531 po/Makefile.in
532 util/Makefile
533 mpi/Makefile
534 cipher/Makefile
535 g10/Makefile
536 doc/Makefile
537 tools/Makefile
538 zlib/Makefile
539 checks/Makefile
540 ])
541
542 dnl *-*wedit:notab*-*  Please keep this as the last line.