Fix --output option used when with --export-secret-kety-p12.
[gnupg.git] / m4 / inttypes-pri.m4
1 # inttypes-pri.m4 serial 4 (gettext-0.16)
2 dnl Copyright (C) 1997-2002, 2006 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 dnl From Bruno Haible.
8
9 AC_PREREQ(2.52)
10
11 # Define PRI_MACROS_BROKEN if <inttypes.h> exists and defines the PRI*
12 # macros to non-string values.  This is the case on AIX 4.3.3.
13
14 AC_DEFUN([gt_INTTYPES_PRI],
15 [
16   AC_CHECK_HEADERS([inttypes.h])
17   if test $ac_cv_header_inttypes_h = yes; then
18     AC_CACHE_CHECK([whether the inttypes.h PRIxNN macros are broken],
19       gt_cv_inttypes_pri_broken,
20       [
21         AC_TRY_COMPILE([#include <inttypes.h>
22 #ifdef PRId32
23 char *p = PRId32;
24 #endif
25 ], [], gt_cv_inttypes_pri_broken=no, gt_cv_inttypes_pri_broken=yes)
26       ])
27   fi
28   if test "$gt_cv_inttypes_pri_broken" = yes; then
29     AC_DEFINE_UNQUOTED(PRI_MACROS_BROKEN, 1,
30       [Define if <inttypes.h> exists and defines unusable PRI* macros.])
31     PRI_MACROS_BROKEN=1
32   else
33     PRI_MACROS_BROKEN=0
34   fi
35   AC_SUBST([PRI_MACROS_BROKEN])
36 ])