* getkey.c (merge_selfsigs_subkey), sig-check.c (signature_check2),
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   Aug-5-2005
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro defines HAVE_LIBCURL if a working libcurl setup is found,
17 # and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary values.
18 # Other useful defines are LIBCURL_FEATURE_xxx where xxx are the
19 # various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available,
36 # (or use curl_version_info to figure it out at runtime).
37
38 AC_DEFUN([LIBCURL_CHECK_CONFIG],
39 [
40   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
41   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
42   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
43   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
44   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
45
46   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
47   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
48   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
49   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_GOPHER],[Defined if libcurl supports GOPHER])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
54   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
55
56   AC_ARG_WITH(libcurl,
57      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
58      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
59
60   if test "$_libcurl_with" != "no" ; then
61
62      AC_PROG_AWK
63
64      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
65
66      _libcurl_try_link=yes
67
68      if test -d "$_libcurl_with" ; then
69         LIBCURL_CPPFLAGS="-I$withval/include"
70         _libcurl_ldflags="-L$withval/lib"
71         AC_PATH_PROG([_libcurl_config],["$withval/bin/curl-config"])
72      else
73         AC_PATH_PROG([_libcurl_config],[curl-config])
74      fi
75
76      if test x$_libcurl_config != "x" ; then
77         AC_CACHE_CHECK([for the version of libcurl],
78            [libcurl_cv_lib_curl_version],
79            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
80
81         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
82         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
83
84         if test $_libcurl_wanted -gt 0 ; then
85            AC_CACHE_CHECK([for libcurl >= version $2],
86               [libcurl_cv_lib_version_ok],
87               [
88               if test $_libcurl_version -ge $_libcurl_wanted ; then
89                  libcurl_cv_lib_version_ok=yes
90               else
91                  libcurl_cv_lib_version_ok=no
92               fi
93               ])
94         fi
95
96         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
97            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
98               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
99            fi
100            if test x"$LIBCURL" = "x" ; then
101               LIBCURL=`$_libcurl_config --libs`
102
103               # This is so silly, but Apple actually has a bug in their
104               # curl-config script.  Fixed in Tiger, but there are still
105               # lots of Panther installs around.
106               case "${host}" in
107                  powerpc-apple-darwin7*)
108                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
109                  ;;
110               esac
111            fi
112
113            # All curl-config scripts support --feature
114            _libcurl_features=`$_libcurl_config --feature`
115
116            # Is it modern enough to have --protocols? (7.12.4)
117            if test $_libcurl_version -ge 461828 ; then
118               _libcurl_protocols=`$_libcurl_config --protocols`
119            fi
120         else
121            _libcurl_try_link=no
122         fi
123
124         unset _libcurl_wanted
125      fi
126
127      if test $_libcurl_try_link = yes ; then
128
129         # we didn't find curl-config, so let's see if the user-supplied
130         # link line (or failing that, "-lcurl") is enough.
131         LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
132
133         AC_CACHE_CHECK([whether libcurl is usable],
134            [libcurl_cv_lib_curl_usable],
135            [
136            _libcurl_save_cppflags=$CPPFLAGS
137            CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
138            _libcurl_save_libs=$LIBS
139            LIBS="$LIBCURL $LIBS"
140
141            AC_LINK_IFELSE(AC_LANG_PROGRAM([#include <curl/curl.h>],[
142 /* Try and use a few common options to force a failure if we are
143    missing symbols or can't link. */
144 int x;
145 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
146 curl_version_info(CURLVERSION_NOW);
147 x=CURL_ERROR_SIZE;
148 x=CURLOPT_WRITEFUNCTION;
149 x=CURLOPT_FILE;
150 x=CURLOPT_ERRORBUFFER;
151 x=CURLOPT_STDERR;
152 x=CURLOPT_VERBOSE;
153 ]),libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
154
155            CPPFLAGS=$_libcurl_save_cppflags
156            LIBS=$_libcurl_save_libs
157            unset _libcurl_save_cppflags
158            unset _libcurl_save_libs
159            ])
160
161         if test $libcurl_cv_lib_curl_usable = yes ; then
162
163            # Does curl_free() exist in this version of libcurl?
164            # If not, fake it with free()
165
166            _libcurl_save_cppflags=$CPPFLAGS
167            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
168            _libcurl_save_libs=$LIBS
169            LIBS="$LIBS $LIBCURL"
170
171            AC_CHECK_FUNC(curl_free,,
172               AC_DEFINE(curl_free,free,
173                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
174
175            CPPFLAGS=$_libcurl_save_cppflags
176            LIBS=$_libcurl_save_libs
177            unset _libcurl_save_cppflags
178            unset _libcurl_save_libs
179
180            AC_DEFINE(HAVE_LIBCURL,1,
181              [Define to 1 if you have a functional curl library.])
182            AC_SUBST(LIBCURL_CPPFLAGS)
183            AC_SUBST(LIBCURL)
184
185            for _libcurl_feature in $_libcurl_features ; do
186               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
187               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
188            done
189
190            if test "x$_libcurl_protocols" = "x" ; then
191
192               # We don't have --protocols, so just assume that all
193               # protocols are available
194               _libcurl_protocols="HTTP FTP GOPHER FILE TELNET LDAP DICT"
195
196               if test x$libcurl_feature_SSL = xyes ; then
197                  _libcurl_protocols="$_libcurl_protocols HTTPS"
198
199                  # FTPS wasn't standards-compliant until version
200                  # 7.11.0
201                  if test $_libcurl_version -ge 461568; then
202                     _libcurl_protocols="$_libcurl_protocols FTPS"
203                  fi
204               fi
205            fi
206
207            for _libcurl_protocol in $_libcurl_protocols ; do
208               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
209               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
210            done
211         fi
212      fi
213
214      unset _libcurl_try_link
215      unset _libcurl_version_parse
216      unset _libcurl_config
217      unset _libcurl_feature
218      unset _libcurl_features
219      unset _libcurl_protocol
220      unset _libcurl_protocols
221      unset _libcurl_version
222      unset _libcurl_ldflags
223   fi
224
225   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
226      # This is the IF-NO path
227      ifelse([$4],,:,[$4])
228   else
229      # This is the IF-YES path
230      ifelse([$3],,:,[$3])
231   fi
232
233   unset _libcurl_with
234 ])dnl