* getkey.c (merge_selfsigs_subkey), sig-check.c (signature_check2),
[gnupg.git] / m4 / libusb.m4
1 dnl Check for libusb
2 dnl Copyright (C) 2004 Free Software Foundation, Inc.
3 dnl
4 dnl This file is free software, distributed under the terms of the GNU
5 dnl General Public License.  As a special exception to the GNU General
6 dnl Public License, this file may be distributed as part of a program
7 dnl that contains a configuration script generated by Autoconf, under
8 dnl the same distribution terms as the rest of that program.
9 dnl
10 dnl Defines HAVE_LIBUSB to 1 if a working libusb setup is found, and sets
11 dnl @LIBUSB@ to the necessary libraries.  HAVE_USB_GET_BUSSES is set if
12 dnl usb_get_busses() exists.
13
14 AC_DEFUN([GNUPG_CHECK_LIBUSB],
15 [
16   AC_ARG_WITH(libusb,
17      AC_HELP_STRING([--with-libusb=DIR],
18         [look for the libusb library in DIR]),
19      [_do_libusb=$withval],[_do_libusb=yes])
20
21   if test "$_do_libusb" != "no" ; then
22      if test -d "$withval" ; then
23         CPPFLAGS="${CPPFLAGS} -I$withval/include"
24         LDFLAGS="${LDFLAGS} -L$withval/lib"
25      fi
26
27      _libusb_save_libs=$LIBS
28      LIBS="$LIBS -lusb"
29
30      AC_MSG_CHECKING([whether libusb is present and sane])
31
32      AC_LINK_IFELSE(AC_LANG_PROGRAM([#include <usb.h>],[
33 usb_bulk_write(NULL,0,NULL,0,0);
34 ]),_found_libusb=yes,_found_libusb=no)
35
36      AC_MSG_RESULT([$_found_libusb])
37
38      if test $_found_libusb = yes ; then
39         AC_DEFINE(HAVE_LIBUSB,1,
40            [Define to 1 if you have a fully functional libusb library.])
41         AC_SUBST(LIBUSB,"-lusb")
42         AC_CHECK_FUNCS(usb_get_busses)
43      fi
44
45      LIBS=$_libusb_save_libs
46
47      unset _libusb_save_libs
48      unset _found_libusb
49   fi
50 ])dnl