doc: Fix distchek for generated eps file
[gnupg.git] / m4 / ntbtls.m4
1 dnl Autoconf macros for NTBTLS
2 dnl Copyright (C) 2002, 2004, 2011 Free Software Foundation, Inc.
3 dnl
4 dnl This file is free software; as a special exception the author gives
5 dnl unlimited permission to copy and/or distribute it, with or without
6 dnl modifications, as long as this notice is preserved.
7 dnl
8 dnl This file is distributed in the hope that it will be useful, but
9 dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11 dnl
12 dnl Last-changed: 2018-11-13
13
14
15 dnl AM_PATH_NTBTLS([MINIMUM-VERSION,
16 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
17 dnl
18 dnl Test for NTBTLS and define NTBTLS_CFLAGS and NTBTLS_LIBS.
19 dnl MINIMUN-VERSION is a string with the version number optionalliy prefixed
20 dnl with the API version to also check the API compatibility. Example:
21 dnl a MINIMUN-VERSION of 1:1.2.5 won't pass the test unless the installed
22 dnl version of libgcrypt is at least 1.2.5 *and* the API number is 1.  Using
23 dnl this features allows to prevent build against newer versions of libgcrypt
24 dnl with a changed API.
25 dnl
26 AC_DEFUN([AM_PATH_NTBTLS],
27 [ AC_REQUIRE([AC_CANONICAL_HOST])
28   AC_ARG_WITH(ntbtls-prefix,
29             AC_HELP_STRING([--with-ntbtls-prefix=PFX],
30                            [prefix where NTBTLS is installed (optional)]),
31      ntbtls_config_prefix="$withval", ntbtls_config_prefix="")
32   if test x"${NTBTLS_CONFIG}" = x ; then
33      if test x"${ntbtls_config_prefix}" != x ; then
34         NTBTLS_CONFIG="${ntbtls_config_prefix}/bin/ntbtls-config"
35      fi
36   fi
37
38   use_gpgrt_config=""
39   if test x"${NTBTLS_CONFIG}" = x -a x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
40     if $GPGRT_CONFIG ntbtls --exists; then
41       NTBTLS_CONFIG="$GPGRT_CONFIG ntbtls"
42       AC_MSG_NOTICE([Use gpgrt-config as ntbtls-config])
43       use_gpgrt_config=yes
44     fi
45   fi
46   if test -z "$use_gpgrt_config"; then
47     if test x"${NTBTLS_CONFIG}" = x ; then
48       case "${SYSROOT}" in
49         /*)
50           if test -x "${SYSROOT}/bin/ntbtls-config" ; then
51             NTBTLS_CONFIG="${SYSROOT}/bin/ntbtls-config"
52           fi
53           ;;
54         '')
55           ;;
56          *)
57           AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
58           ;;
59       esac
60     fi
61     AC_PATH_PROG(NTBTLS_CONFIG, ntbtls-config, no)
62   fi
63
64   tmp=ifelse([$1], ,1:1.0.0,$1)
65   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
66      req_ntbtls_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
67      min_ntbtls_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
68   else
69      req_ntbtls_api=0
70      min_ntbtls_version="$tmp"
71   fi
72
73   AC_MSG_CHECKING(for NTBTLS - version >= $min_ntbtls_version)
74   ok=no
75   if test "$NTBTLS_CONFIG" != "no" ; then
76     req_major=`echo $min_ntbtls_version | \
77                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
78     req_minor=`echo $min_ntbtls_version | \
79                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
80     req_micro=`echo $min_ntbtls_version | \
81                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
82     if test -z "$use_gpgrt_config"; then
83       ntbtls_config_version=`$NTBTLS_CONFIG --version`
84     else
85       ntbtls_config_version=`$NTBTLS_CONFIG --modversion`
86     fi
87     major=`echo $ntbtls_config_version | \
88                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
89     minor=`echo $ntbtls_config_version | \
90                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
91     micro=`echo $ntbtls_config_version | \
92                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
93     if test "$major" -gt "$req_major"; then
94         ok=yes
95     else
96         if test "$major" -eq "$req_major"; then
97             if test "$minor" -gt "$req_minor"; then
98                ok=yes
99             else
100                if test "$minor" -eq "$req_minor"; then
101                    if test "$micro" -ge "$req_micro"; then
102                      ok=yes
103                    fi
104                fi
105             fi
106         fi
107     fi
108   fi
109   if test $ok = yes; then
110     AC_MSG_RESULT([yes ($ntbtls_config_version)])
111   else
112     AC_MSG_RESULT(no)
113   fi
114   if test $ok = yes; then
115      # If we have a recent ntbtls, we should also check that the
116      # API is compatible
117      if test "$req_ntbtls_api" -gt 0 ; then
118         if test -z "$use_gpgrt_config"; then
119           tmp=`$NTBTLS_CONFIG --api-version 2>/dev/null || echo 0`
120         else
121           tmp=`$NTBTLS_CONFIG --variable=api_version 2>/dev/null || echo 0`
122         fi
123         if test "$tmp" -gt 0 ; then
124            AC_MSG_CHECKING([NTBTLS API version])
125            if test "$req_ntbtls_api" -eq "$tmp" ; then
126              AC_MSG_RESULT([okay])
127            else
128              ok=no
129              AC_MSG_RESULT([does not match. want=$req_ntbtls_api got=$tmp])
130            fi
131         fi
132      fi
133   fi
134   if test $ok = yes; then
135     NTBTLS_CFLAGS=`$NTBTLS_CONFIG --cflags`
136     NTBTLS_LIBS=`$NTBTLS_CONFIG --libs`
137     ifelse([$2], , :, [$2])
138     if test -z "$use_gpgrt_config"; then
139       ntbtls_config_host=`$NTBTLS_CONFIG --host 2>/dev/null || echo none`
140     else
141       ntbtls_config_host=`$NTBTLS_CONFIG --variable=host 2>/dev/null || echo none`
142     fi
143     if test x"$ntbtls_config_host" != xnone ; then
144       if test x"$ntbtls_config_host" != x"$host" ; then
145   AC_MSG_WARN([[
146 ***
147 *** The config script "$NTBTLS_CONFIG" was
148 *** built for $ntbtls_config_host and thus may not match the
149 *** used host $host.
150 *** You may want to use the configure option --with-ntbtls-prefix
151 *** to specify a matching config script or use \$SYSROOT.
152 ***]])
153         gpg_config_script_warn="$gpg_config_script_warn ntbtls"
154       fi
155     fi
156   else
157     NTBTLS_CFLAGS=""
158     NTBTLS_LIBS=""
159     ifelse([$3], , :, [$3])
160   fi
161   AC_SUBST(NTBTLS_CFLAGS)
162   AC_SUBST(NTBTLS_LIBS)
163 ])