2006-08-04 Marcus Brinkmann <marcus@g10code.de>
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005, 2006 g10 Code GmbH
3
4 # This file is part of GPG4Win
5
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19  
20 # (Process this file with autoconf to produce a configure script.)
21
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 # Remember to change the version number immediately *after* a release.
26 # Set my_issvn to "yes" for non-released code.  Remember to run an
27 # "svn up" and "autogen.sh" right before creating a distribution.
28 # Right after a release the make target "copy-news" is to be called!
29 m4_define([my_version], [1.0.6])
30 m4_define([my_issvn], [yes])
31
32 m4_define([svn_revision], m4_esyscmd([echo -n $((svn info 2>/dev/null \
33           ||echo 'Revision: 0')|sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
34 AC_INIT([gpg4win], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
35         [gpg4win-devel@wald.intevation.org])
36
37 # Remember to update these version numbers also in the NEWS file.
38 MANUALVERSION_EINSTEIGER="2.0.2"
39 MANUALDATE_EINSTEIGER="30. Mai 2006"
40 MANUALVERSION_DURCHBLICKER="2.0.2"
41 MANUALDATE_DURCHBLICKER="30. Mai 2006"
42
43
44 MANUALINPROGRESS_DE=m4_if(my_issvn,[yes],["~und evtl. seitdem weiter bearbeitet"])
45 SVN_REVISION=svn_revision
46 PACKAGE=$PACKAGE_NAME
47 VERSION=$PACKAGE_VERSION
48
49
50 AC_CONFIG_SRCDIR(include/config.nsi.in)
51 AC_CONFIG_MACRO_DIR(m4)
52
53 AM_INIT_AUTOMAKE
54 AM_MAINTAINER_MODE
55 AC_CANONICAL_HOST
56
57 AC_SUBST(PACKAGE)
58 AC_SUBST(VERSION)
59 AC_SUBST(MANUALVERSION_EINSTEIGER)
60 AC_SUBST(MANUALDATE_EINSTEIGER)
61 AC_SUBST(MANUALVERSION_DURCHBLICKER)
62 AC_SUBST(MANUALDATE_DURCHBLICKER)
63 AC_SUBST(MANUALINPROGRESS_DE)
64
65
66 # Generate extended version information.  Note, that for NSIS use we
67 # must not translate the dots to commas in the BUILD_FILEVERSION.
68 BUILD_TIMESTAMP=`date --iso-8601=minutes`
69 BUILD_ISODATE=`date --iso-8601`
70 changequote(,)dnl
71 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
72 changequote([,])dnl
73 BUILD_FILEVERSION="${BUILD_FILEVERSION}${SVN_REVISION}"
74 AC_SUBST(BUILD_TIMESTAMP)
75 AC_SUBST(BUILD_ISODATE)
76 AC_SUBST(BUILD_FILEVERSION)
77
78
79 # For development of this package it is useful to build without
80 # creatign the source installer (takes a long time).  This option may
81 # be used to suppress creation of the source installer.
82 AC_ARG_ENABLE(source-installer,
83     AC_HELP_STRING([--disable-source-installer],
84                    [Do not create the Source installer]),
85                     build_source_installer=$enableval,
86                     build_source_installer=yes)
87 AC_MSG_RESULT($source_installer)
88 AM_CONDITIONAL(BUILD_SOURCE_INSTALLER, test "$build_source_installer" = yes)
89
90
91 # You can build a light version of the installer in addition to the
92 # regular version.  This one does not contain the manuals.
93 AC_ARG_ENABLE(light-installer,
94     AC_HELP_STRING([--disable-light-installer],
95                    [Do not create the light version of the installer]),
96                     build_light_installer=$enableval,
97                     build_light_installer=yes)
98 AC_MSG_RESULT($light_installer)
99 AM_CONDITIONAL(BUILD_LIGHT_INSTALLER, test "$build_light_installer" = yes)
100
101
102 # Required tools.
103 AC_PROG_CC
104 AC_PROG_CPP
105 AC_CHECK_TOOLS(DLLTOOL, dlltool)
106 AC_CHECK_PROGS(MAKE, make)
107 AC_CHECK_PROGS(UNZIP, unzip)
108 AC_CHECK_PROGS(TAR, tar)
109 AC_CHECK_PROGS(MKDIR, mkdir)
110 AC_CHECK_PROGS(CP, cp)
111 AC_CHECK_PROGS(RM, rm)
112 AC_CHECK_PROGS(STOW, stow)
113 AC_CHECK_PROGS(MAKENSIS, makensis)
114 AC_CHECK_PROGS(ZCAT, zcat)
115 AC_CHECK_PROGS(TEXI2DVI, texi2dvi)
116 AC_CHECK_PROGS(DVIPDF, dvipdf)
117 AC_CHECK_PROGS(CONVERT, convert)
118 AC_CHECK_PROGS(SHA1SUM, sha1sum)
119 AC_PROG_INSTALL
120
121 missing_tools=
122 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS ZCAT TEXI2DVI \
123          DVIPDF CONVERT SHA1SUM ; do
124    eval tmp='$'$i
125    if test -z "$tmp"; then 
126       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
127    fi
128 done
129
130
131 # Optional tools.
132
133 AC_CHECK_PROGS(WGET, wget)
134
135
136 # Packages.
137
138 GPG4WIN_BPKG_GNU([libiconv])
139 GPG4WIN_BPKG_GNU([gettext], [libiconv])
140
141 GPG4WIN_BPKG_GNUWIN32([zlib])
142 GPG4WIN_BPKG_GNUWIN32_LIB([crypt])
143 GPG4WIN_BPKG_GNUWIN32_LIB([regex])
144 GPG4WIN_BPKG_GNUWIN32([libpng], [pkgconfig])
145 GPG4WIN_BPKG_GNUWIN32([jpeg])
146
147 GPG4WIN_BPKG_GTK([pkgconfig])
148 # We build our own version of glib, because we need to patch giowin32.c.
149 # GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
150 GPG4WIN_SPKG([glib], [libiconv gettext pkgconfig])
151 GPG4WIN_BPKG_GTK_DEV([gtk+], [atk pango glib libiconv gettext pkgconfig])
152 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
153 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
154 GPG4WIN_BPKG_BINSRC([GPGee], [gnupg])
155
156 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
157 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg glib])
158 GPG4WIN_SPKG([gnupg], [libiconv])
159 GPG4WIN_SPKG([pthreads-w32])
160 GPG4WIN_SPKG([gpgol], [gpgme])
161 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
162 GPG4WIN_SPKG([winpt], [gpgme gnupg])
163 GPG4WIN_SPKG([sylpheed-claws], [libiconv gettext zlib gtk+ libpng jpeg glib dnl
164                                 gpgme pthreads-w32 crypt regex])
165 # The Eudora license (the one for thye EMS API) is still not acceptable.
166 #GPG4WIN_SPKG([eudoragpg])
167 GPG4WIN_IPKG([man_novice_de])
168 GPG4WIN_IPKG([man_advanced_de])
169
170 GPG4WIN_FINALIZE
171
172 # Throw an error if required tools are missing
173 if test -n "$missing_tools"; then
174     for i in $missing_tools; do 
175       AC_MSG_NOTICE([$i is missing])
176     done
177     AC_MSG_ERROR([[
178 ***
179 *** Required tools not found. Please consult the above messages
180 *** and install them before running configure again.
181 ***]])
182 fi
183
184
185 # Finalize.
186
187 AC_CONFIG_FILES(Makefile packages/Makefile include/Makefile src/Makefile)
188 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
189 AC_CONFIG_FILES(doc/Makefile)
190 AC_CONFIG_FILES(doc/logo/Makefile)
191 AC_CONFIG_FILES(doc/manual-de/Makefile doc/manual-de/version.tex)
192 AC_CONFIG_FILES(doc/website/Makefile)
193 AC_OUTPUT