Update gpgol
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005, 2006, 2007, 2008, 2010 g10 Code GmbH
3
4 # This file is part of GPG4Win
5
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, see <http://www.gnu.org/licenses/>.
18  
19 # (Process this file with autoconf to produce a configure script.)
20
21 AC_PREREQ(2.59)
22 min_automake_version="1.9.3"
23
24 # Remember to change the version number immediately *after* a release.
25 # Set my_issvn to "yes" for non-released code.  Remember to run an
26 # "svn up" and "autogen.sh" right before creating a distribution.
27 # Right after a release the make target "copy-news" is to be called!
28 m4_define([my_version], [2.1.0])
29 m4_define([my_issvn], [yes])
30
31 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
32           ||echo 'Revision: 0')|sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
33 AC_INIT([gpg4win], 
34         [my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision])],
35         [gpg4win-devel@wald.intevation.org])
36
37 # Remember to update these version numbers also in the NEWS file.
38 MANUALVERSION_EINSTEIGER="2.0.2"
39 MANUALDATE_EINSTEIGER="30. Mai 2006"
40 MANUALVERSION_DURCHBLICKER="2.0.2"
41 MANUALDATE_DURCHBLICKER="30. Mai 2006"
42 MANUALVERSION_NOVICES="1.0.0"
43 MANUALDATE_NOVICES="Nov. 30, 2006"
44 MANUALVERSION_ADVANCED="0.0.0"
45 MANUALDATE_ADVANCED="Nov. 30, 2006"
46 COMPENDIUM_VERSION_DE="3.0.0"
47 COMPENDIUM_DATE_DE="21. Mai 2010"
48
49
50 MANUALINPROGRESS_DE=m4_if(my_issvn,[yes],["~und evtl. seitdem weiter bearbeitet"])
51 MANUALINPROGRESS_EN=m4_if(my_issvn,[yes],["~and may have been further edited"])
52 SVN_REVISION=svn_revision
53 PACKAGE=$PACKAGE_NAME
54 VERSION=$PACKAGE_VERSION
55
56
57 AC_CONFIG_SRCDIR(include/config.nsi.in)
58 AC_CONFIG_MACRO_DIR(m4)
59
60 AM_INIT_AUTOMAKE
61 AM_MAINTAINER_MODE
62 AC_CANONICAL_HOST
63 AM_CONFIG_HEADER(config.h)
64
65 # Language support
66 AM_PO_SUBDIRS
67
68
69 AC_SUBST(PACKAGE)
70 AC_SUBST(VERSION)
71 AC_SUBST(MANUALVERSION_EINSTEIGER)
72 AC_SUBST(MANUALDATE_EINSTEIGER)
73 AC_SUBST(MANUALVERSION_DURCHBLICKER)
74 AC_SUBST(MANUALDATE_DURCHBLICKER)
75 AC_SUBST(MANUALINPROGRESS_DE)
76 AC_SUBST(MANUALVERSION_NOVICES)
77 AC_SUBST(MANUALDATE_NOVICES)
78 AC_SUBST(MANUALVERSION_ADVANCED)
79 AC_SUBST(MANUALDATE_ADVANCED)
80 AC_SUBST(MANUALINPROGRESS_EN)
81 AC_SUBST(COMPENDIUM_VERSION_DE)
82 AC_SUBST(COMPENDIUM_DATE_DE)
83
84 if echo "${PACKAGE_VERSION}" | egrep 'svn|rc|beta|git' >/dev/null ; then 
85   IS_BETA_BUILD=yes
86 else
87   IS_BETA_BUILD=no
88 fi
89 AC_SUBST(IS_BETA_BUILD)
90
91 # Generate extended version information.  Note, that for NSIS use we
92 # must not translate the dots to commas in the BUILD_FILEVERSION.
93 BUILD_TIMESTAMP=`date --iso-8601=minutes`
94 BUILD_ISODATE=`date --iso-8601`
95 changequote(,)dnl
96 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
97 changequote([,])dnl
98 BUILD_FILEVERSION="${BUILD_FILEVERSION}${SVN_REVISION}"
99 AC_SUBST(BUILD_TIMESTAMP)
100 AC_SUBST(BUILD_ISODATE)
101 AC_SUBST(BUILD_FILEVERSION)
102
103 # To test the manuals using an actual web server, the preview target
104 # may be used in doc/manuals.  The default is my (wk) test environment
105 # but may be overriden using another preview variable.  PREVIEWHOST is
106 # expected to be the target for an rsync command.
107 if test -z "$PREVIEWHOST" ; then
108    PREVIEWHOST="vigenere:/var/www/all/preview.gpg4win.org/htdocs/"
109 fi
110 AC_SUBST(PREVIEWHOST)
111
112 # The final release is copied to an archive server.  The default
113 # location may be changed by setting the RELEASEHOST envvar.
114 if test -z "$RELEASEHOST" ; then
115    RELEASEHOST="vigenere:tarballs/gpg4win"
116    if test "${IS_BETA_BUILD}" = yes ; then
117       RELEASEHOST="${RELEASEHOST}/Beta"
118    fi
119 fi
120 AC_SUBST(RELEASEHOST)
121
122 # For development of this package it is useful to build without
123 # creating the source installer (takes a long time).  This option may
124 # be used to suppress creation of the source installer.
125 AC_ARG_ENABLE(source-installer,
126     AC_HELP_STRING([--disable-source-installer],
127                    [Do not create the Source installer]),
128                     build_source_installer=$enableval,
129                     build_source_installer=yes)
130 AM_CONDITIONAL(BUILD_SOURCE_INSTALLER, test "$build_source_installer" = yes)
131
132
133 # You can build a light version of the installer in addition to the
134 # regular version.  This one does not contain the manuals.
135 AC_ARG_ENABLE(light-installer,
136     AC_HELP_STRING([--disable-light-installer],
137                    [Do not create the light version of the installer]),
138                     build_light_installer=$enableval,
139                     build_light_installer=yes)
140 AM_CONDITIONAL(BUILD_LIGHT_INSTALLER, test "$build_light_installer" = yes)
141
142 AC_ARG_ENABLE(fast-makensis,
143     AC_HELP_STRING([--enable-fast-makensis],
144                    [Use a less efficient compressor to speed up building]),
145                     use_fast_makensis=$enableval,
146                     use_fast_makensis=no)
147 if test "$use_fast_makensis" = yes; then
148   EXTRA_MAKENSIS_FLAGS="${EXTRA_MAKENSIS_FLAGS} -DDISABLE_LZMA=1"
149 fi
150 AC_SUBST(EXTRA_MAKENSIS_FLAGS)
151
152
153 # Required tools.
154 AC_PROG_CC
155 AC_PROG_CPP
156 AC_PROG_RANLIB
157 AC_CHECK_TOOL(AR, ar, :)
158 AC_CHECK_TOOLS(STRIP, strip)
159 AC_CHECK_TOOLS(DLLTOOL, dlltool)
160 AC_CHECK_PROGS(MAKE, make)
161 AC_CHECK_PROGS(UNZIP, unzip)
162 AC_CHECK_PROGS(TAR, tar)
163 AC_CHECK_PROGS(MKDIR, mkdir)
164 AC_CHECK_PROGS(CP, cp)
165 AC_CHECK_PROGS(RM, rm)
166 AC_CHECK_PROGS(STOW, stow)
167 AC_CHECK_PROGS(MAKENSIS, makensis)
168 AC_CHECK_PROGS(ZCAT, zcat)
169 AC_CHECK_PROGS(TEXI2DVI, texi2dvi)
170 AC_CHECK_PROGS(DVIPDF, dvipdf)
171 AC_CHECK_PROGS(CONVERT, convert)
172 AC_CHECK_PROGS(SHA1SUM, sha1sum)
173 AC_CHECK_PROGS(MSGFMT, msgfmt)
174 AC_PROG_INSTALL
175
176 missing_tools=
177 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS ZCAT TEXI2DVI \
178          DVIPDF CONVERT SHA1SUM MSGFMT ; do
179    eval tmp='$'$i
180    if test -z "$tmp"; then 
181       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
182    fi
183 done
184
185
186
187 # Optional tools.
188
189 AC_CHECK_PROGS(WGET, wget)
190
191
192 # Packages.
193 gpg4win_dup_sources=""
194
195 GPG4WIN_BPKG_GNU([libiconv])
196 GPG4WIN_BPKG_GNU([gettext], [libiconv])
197
198 GPG4WIN_SPKG([zlib])
199 GPG4WIN_BPKG_GNUWIN32([bsfilter])
200
201 GPG4WIN_BPKG_GTK([pkgconfig])
202 # We build our own version of glib, because we need to apply a few patches.
203 # GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
204 GPG4WIN_SPKG([glib], [libiconv gettext pkgconfig])
205 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
206 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
207 GPG4WIN_BPKG_GTK_DEV([cairo], [glib pkgconfig])
208 GPG4WIN_BPKG_GTK_DEV([expat])
209 GPG4WIN_BPKG_GTK_DEV([freetype], [pkgconfig zlib])
210 GPG4WIN_BPKG_GTK_DEV([fontconfig], [pkgconfig zlib expat])
211 GPG4WIN_BPKG_GTK_DEV([gtk+], [libiconv gettext pkgconfig atk pango glib cairo])
212 GPG4WIN_SPKG([libpng], [pkgconfig])
213
214 GPG4WIN_SPKG([bzip2])
215 GPG4WIN_SPKG([adns])
216 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
217 GPG4WIN_SPKG([libgcrypt], [libgpg-error])
218 GPG4WIN_SPKG([libksba], [libgpg-error])
219 GPG4WIN_SPKG([w32pth])
220 GPG4WIN_SPKG([libassuan], [libgpg-error w32pth])
221 GPG4WIN_SPKG([dirmngr], [libgpg-error libgcrypt libassuan libksba w32pth])
222 GPG4WIN_SPKG([pinentry], [libiconv gtk+])
223 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg2 glib])
224 GPG4WIN_SPKG([curl], [zlib gnutls])
225 GPG4WIN_SPKG([gnupg2], [libiconv libgcrypt libksba libassuan libgpg-error dnl
226                         w32pth zlib bzip2 adns pinentry])
227 GPG4WIN_SPKG([pthreads-w32])
228 GPG4WIN_SPKG([gpgol], [gpgme libassuan])
229 GPG4WIN_SPKG([gpgex], [libassuan])
230 GPG4WIN_SPKG([scute], [libgpg-error libassuan])
231 GPG4WIN_SPKG([paperkey])
232 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
233 GPG4WIN_SPKG([libgsasl])
234 GPG4WIN_SPKG([libtasn1])
235 GPG4WIN_SPKG([gnutls], [libgsasl libtasn1 libgcrypt])
236 GPG4WIN_SPKG([libetpan], [pthreads-w32 gnutls])
237 GPG4WIN_SPKG([libxml2], [zlib])
238 GPG4WIN_SPKG([regex])
239 GPG4WIN_SPKG([crypt])
240 GPG4WIN_SPKG([claws-mail], [libiconv gettext zlib gtk+ libpng glib dnl
241                             gpgme pthreads-w32 crypt regex libetpan gnutls])
242 GPG4WIN_SPKG([notification_plugin], [claws-mail])
243 GPG4WIN_SPKG([gtkhtml2_viewer], [curl claws-mail libxml2])
244 GPG4WIN_SPKG([vcalendar], [curl claws-mail])
245 GPG4WIN_SPKG([rssyl], [curl claws-mail])
246 GPG4WIN_SPKG([tnef_parse], [claws-mail])
247 GPG4WIN_SPKG([attachwarner], [claws-mail])
248 GPG4WIN_SPKG([bsfilter_plugin], [claws-mail])
249 GPG4WIN_IPKG([compendium_de])
250 GPG4WIN_IPKG([man_novice_en])
251 #GPG4WIN_IPKG([man_advanced_en])
252
253 # Qt related stuff.
254 GPG4WIN_BPKG_GNUWIN32([kdesupport])
255 GPG4WIN_BPKG_BINSRC([oxygen-icons])
256 GPG4WIN_BPKG_GNUWIN32([qt], [kdesupport])
257 GPG4WIN_BPKG_GNUWIN32([kdelibs], [qt oxygen-icons])
258 GPG4WIN_BPKG_BINSRC([kleopatra], [gpgme gnupg2 kdelibs])
259 #GPG4WIN_BPKG_GNUWIN32([kleopatra], [gpgme gnupg2 kdelibs])
260
261 GPG4WIN_FINALIZE
262
263 # Qt is compiled with -mthreads, and thus requires the mingwm10.dll.
264 mingwm_dll=no
265 AC_ARG_WITH([mingwm-dll],
266             AC_HELP_STRING([--with-mingwm-dll=FILE], [use the mingwm DLL]),
267             [mingwm_dll=$withval])
268 if test "$mingwm_dll" = "no"; then
269   file="/usr/share/doc/mingw32-runtime/mingwm10.dll.gz"
270   if test -r "$file"; then
271     mingwm_dll="$file"
272   fi
273 fi
274 if test "$mingwm_dll" = "no"; then
275   missing_tools="mingwm10.dll $missing_tools"
276 fi
277 # To make things simple, we just install a copy of the file in the
278 # source directory.  No need to make this ugly hack any uglier by
279 # messing around with the build system.
280 case "$mingwm_dll" in
281     *.gz)
282       $ZCAT $mingwm_dll > src/mingwm10.dll
283       ;;
284     *)
285       cp $mingwm_dll src/mingwm10.dll
286       ;;
287 esac
288
289
290 # Throw an error if required tools are missing
291 if test -n "$missing_tools"; then
292     for i in $missing_tools; do 
293       AC_MSG_NOTICE([$i is missing])
294     done
295     AC_MSG_ERROR([[
296 ***
297 *** Required tools not found. Please consult the above messages
298 *** and install them before running configure again.
299 ***]])
300 fi
301
302 # Throw an error if any duplicate source packages have been found
303 if test -n "$gpg4win_dup_sources"; then
304     tmp=
305     for i in $gpg4win_dup_sources; do 
306       tmp="$tmp
307 $i"
308     done
309     AC_MSG_ERROR([Packages with more that one source version:$tmp])
310 fi
311
312
313 # Finalize.
314
315 AC_CONFIG_COMMANDS([gpg4win-conf],[[
316 chmod +x patches/gnupg2/01-version.patch
317 ]])
318
319 AC_CONFIG_FILES(Makefile)
320 AC_CONFIG_FILES(packages/Makefile include/Makefile src/Makefile po/Makefile.in)
321 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
322 AC_CONFIG_FILES(doc/Makefile)
323 AC_CONFIG_FILES(doc/logo/Makefile)
324 AC_CONFIG_FILES(doc/manual/Makefile doc/manual/version.tex)
325 AC_CONFIG_FILES(doc/website/Makefile)
326 AC_CONFIG_FILES(patches/gnupg2/01-version.patch)
327 AC_OUTPUT