Post release updates. Website needs to be updated from this as soon
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005, 2006 g10 Code GmbH
3
4 # This file is part of GPG4Win
5
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19  
20 # (Process this file with autoconf to produce a configure script.)
21
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 # Remember to change the version number immediately *after* a release.
26 # Set my_issvn to "yes" for non-released code.  Remember to run an
27 # "svn up" and "autogen.sh" right before creating a distribution.
28 # Right after a release the make target "copy-news" is to be called!
29 m4_define([my_version], [1.1.3])
30 m4_define([my_issvn], [yes])
31
32 m4_define([svn_revision], m4_esyscmd([echo -n $( (svn info 2>/dev/null \
33           ||echo 'Revision: 0')|sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
34 AC_INIT([gpg4win], my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision]),
35         [gpg4win-devel@wald.intevation.org])
36
37 # Remember to update these version numbers also in the NEWS file.
38 MANUALVERSION_EINSTEIGER="2.0.2"
39 MANUALDATE_EINSTEIGER="30. Mai 2006"
40 MANUALVERSION_DURCHBLICKER="2.0.2"
41 MANUALDATE_DURCHBLICKER="30. Mai 2006"
42 MANUALVERSION_NOVICES="1.0.0"
43 MANUALDATE_NOVICES="Nov. 30, 2006"
44 MANUALVERSION_ADVANCED="0.0.0"
45 MANUALDATE_ADVANCED="Nov. 30, 2006"
46
47
48 MANUALINPROGRESS_DE=m4_if(my_issvn,[yes],["~und evtl. seitdem weiter bearbeitet"])
49 MANUALINPROGRESS_EN=m4_if(my_issvn,[yes],["~and may have been further edited"])
50 SVN_REVISION=svn_revision
51 PACKAGE=$PACKAGE_NAME
52 VERSION=$PACKAGE_VERSION
53
54
55 AC_CONFIG_SRCDIR(include/config.nsi.in)
56 AC_CONFIG_MACRO_DIR(m4)
57
58 AM_INIT_AUTOMAKE
59 AM_MAINTAINER_MODE
60 AC_CANONICAL_HOST
61 AM_CONFIG_HEADER(config.h)
62
63 # Language support
64 AM_PO_SUBDIRS
65
66
67 AC_SUBST(PACKAGE)
68 AC_SUBST(VERSION)
69 AC_SUBST(MANUALVERSION_EINSTEIGER)
70 AC_SUBST(MANUALDATE_EINSTEIGER)
71 AC_SUBST(MANUALVERSION_DURCHBLICKER)
72 AC_SUBST(MANUALDATE_DURCHBLICKER)
73 AC_SUBST(MANUALINPROGRESS_DE)
74 AC_SUBST(MANUALVERSION_NOVICES)
75 AC_SUBST(MANUALDATE_NOVICES)
76 AC_SUBST(MANUALVERSION_ADVANCED)
77 AC_SUBST(MANUALDATE_ADVANCED)
78 AC_SUBST(MANUALINPROGRESS_EN)
79
80
81 # Generate extended version information.  Note, that for NSIS use we
82 # must not translate the dots to commas in the BUILD_FILEVERSION.
83 BUILD_TIMESTAMP=`date --iso-8601=minutes`
84 BUILD_ISODATE=`date --iso-8601`
85 changequote(,)dnl
86 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./'`
87 changequote([,])dnl
88 BUILD_FILEVERSION="${BUILD_FILEVERSION}${SVN_REVISION}"
89 AC_SUBST(BUILD_TIMESTAMP)
90 AC_SUBST(BUILD_ISODATE)
91 AC_SUBST(BUILD_FILEVERSION)
92
93
94 # To test tye manuals using an actual web server, the preview target
95 # may be used in doc/manuals.  The default is my (wk) test environment
96 # but may be overriden using another preview variable.  PREVIEWHOST is
97 # expected to be the target for an rsync command.
98 if test -z "$PREVIEWHOST" ; then
99    PREVIEWHOST="vigenere:/var/www/all/preview.gpg4win.org/htdocs/"
100 fi
101 AC_SUBST(PREVIEWHOST)
102
103
104 # For development of this package it is useful to build without
105 # creating the source installer (takes a long time).  This option may
106 # be used to suppress creation of the source installer.
107 AC_ARG_ENABLE(source-installer,
108     AC_HELP_STRING([--disable-source-installer],
109                    [Do not create the Source installer]),
110                     build_source_installer=$enableval,
111                     build_source_installer=yes)
112 AC_MSG_RESULT($source_installer)
113 AM_CONDITIONAL(BUILD_SOURCE_INSTALLER, test "$build_source_installer" = yes)
114
115
116 # You can build a light version of the installer in addition to the
117 # regular version.  This one does not contain the manuals.
118 AC_ARG_ENABLE(light-installer,
119     AC_HELP_STRING([--disable-light-installer],
120                    [Do not create the light version of the installer]),
121                     build_light_installer=$enableval,
122                     build_light_installer=yes)
123 AC_MSG_RESULT($light_installer)
124 AM_CONDITIONAL(BUILD_LIGHT_INSTALLER, test "$build_light_installer" = yes)
125
126
127 # Required tools.
128 AC_PROG_CC
129 AC_PROG_CPP
130 AC_CHECK_TOOLS(STRIP, strip)
131 AC_CHECK_TOOLS(DLLTOOL, dlltool)
132 AC_CHECK_PROGS(MAKE, make)
133 AC_CHECK_PROGS(UNZIP, unzip)
134 AC_CHECK_PROGS(TAR, tar)
135 AC_CHECK_PROGS(MKDIR, mkdir)
136 AC_CHECK_PROGS(CP, cp)
137 AC_CHECK_PROGS(RM, rm)
138 AC_CHECK_PROGS(STOW, stow)
139 AC_CHECK_PROGS(MAKENSIS, makensis)
140 AC_CHECK_PROGS(ZCAT, zcat)
141 AC_CHECK_PROGS(TEXI2DVI, texi2dvi)
142 AC_CHECK_PROGS(DVIPDF, dvipdf)
143 AC_CHECK_PROGS(CONVERT, convert)
144 AC_CHECK_PROGS(SHA1SUM, sha1sum)
145 AC_CHECK_PROGS(MSGFMT, msgfmt)
146 AC_PROG_INSTALL
147
148 missing_tools=
149 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS ZCAT TEXI2DVI \
150          DVIPDF CONVERT SHA1SUM MSGFMT ; do
151    eval tmp='$'$i
152    if test -z "$tmp"; then 
153       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
154    fi
155 done
156
157
158 # Optional tools.
159
160 AC_CHECK_PROGS(WGET, wget)
161
162
163 # Packages.
164
165 GPG4WIN_BPKG_GNU([libiconv])
166 GPG4WIN_BPKG_GNU([gettext], [libiconv])
167
168 GPG4WIN_BPKG_GNUWIN32([zlib])
169 GPG4WIN_BPKG_GNUWIN32_LIB([crypt])
170 GPG4WIN_BPKG_GNUWIN32_LIB([regex])
171 GPG4WIN_BPKG_GNUWIN32([libpng], [pkgconfig])
172 GPG4WIN_BPKG_GNUWIN32([jpeg])
173
174 GPG4WIN_BPKG_GTK([pkgconfig])
175 # We build our own version of glib, because we need to apply a few patches.
176 # GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
177 GPG4WIN_SPKG([glib], [libiconv gettext pkgconfig])
178 GPG4WIN_BPKG_GTK_DEV([gtk+], [atk pango glib libiconv gettext pkgconfig cairo])
179 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
180 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
181 GPG4WIN_BPKG_GTK_DEV([cairo], [glib pkgconfig])
182
183 GPG4WIN_BPKG_BINSRC([GPGee], [gnupg])
184
185 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
186 GPG4WIN_SPKG([libgcrypt], [libgpg-error])
187 GPG4WIN_SPKG([libksba], [libgpg-error])
188 GPG4WIN_SPKG([libassuan], [w32pth])
189 GPG4WIN_SPKG([dirmngr], [libgpg-error libgcrypt libassuan libksba])
190 GPG4WIN_SPKG([w32pth])
191 GPG4WIN_SPKG([pinentry], [libiconv])
192 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg glib])
193 GPG4WIN_SPKG([gnupg], [libiconv])
194 GPG4WIN_SPKG([gnupg2], [libiconv libgcrypt libksba libassuan libgpg-error dnl
195                         w32pth zlib])
196 GPG4WIN_SPKG([pthreads-w32])
197 GPG4WIN_SPKG([pinentry])
198 GPG4WIN_SPKG([gpgol], [gpgme])
199 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
200 GPG4WIN_SPKG([winpt], [gpgme gnupg])
201 GPG4WIN_SPKG([sylpheed-claws], [libiconv gettext zlib gtk+ libpng jpeg glib dnl
202                                 gpgme pthreads-w32 crypt regex])
203 GPG4WIN_SPKG([claws-mail], [libiconv gettext zlib gtk+ libpng jpeg glib dnl
204                             gpgme pthreads-w32 crypt regex])
205 # The Eudora license (the one for the EMS API) is still not acceptable.
206 #GPG4WIN_SPKG([eudoragpg])
207 GPG4WIN_IPKG([man_novice_de])
208 GPG4WIN_IPKG([man_advanced_de])
209 GPG4WIN_IPKG([man_novice_en])
210 #GPG4WIN_IPKG([man_advanced_en])
211
212 GPG4WIN_FINALIZE
213
214 # Throw an error if required tools are missing
215 if test -n "$missing_tools"; then
216     for i in $missing_tools; do 
217       AC_MSG_NOTICE([$i is missing])
218     done
219     AC_MSG_ERROR([[
220 ***
221 *** Required tools not found. Please consult the above messages
222 *** and install them before running configure again.
223 ***]])
224 fi
225
226
227 # Finalize.
228
229 AC_CONFIG_FILES(Makefile)
230 AC_CONFIG_FILES(packages/Makefile include/Makefile src/Makefile po/Makefile.in)
231 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
232 AC_CONFIG_FILES(doc/Makefile)
233 AC_CONFIG_FILES(doc/logo/Makefile)
234 AC_CONFIG_FILES(doc/manual/Makefile doc/manual/version.tex)
235 AC_CONFIG_FILES(doc/website/Makefile)
236 AC_OUTPUT