Add dummy manual packages and a very stupid splash screen
[gpg4win.git] / configure.ac
1 # configure.ac for GPG4Win
2 # Copyright (C) 2005 g10 Code GmbH
3
4 # This file is part of GPG4Win
5
6 # GPG4Win is free software; you can redistribute it and/or modify it
7 # under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # GPG4Win is distributed in the hope that it will be useful, but
12 # WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 # General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19  
20 # (Process this file with autoconf to produce a configure script.)
21
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 AC_INIT([gpg4win],[0.0.1],[gpg4win-devel@wald.intevation.org])
26
27 PACKAGE=$PACKAGE_NAME
28 VERSION=$PACKAGE_VERSION
29
30 AC_CONFIG_SRCDIR(include/config.nsi.in)
31 AC_CONFIG_MACRO_DIR(m4)
32
33 AM_INIT_AUTOMAKE
34 AM_MAINTAINER_MODE
35 AC_CANONICAL_HOST
36
37 AC_SUBST(PACKAGE)
38 AC_SUBST(VERSION)
39
40
41 # Required tools.
42
43 AC_CHECK_TOOLS(DLLTOOL, dlltool)
44 AC_CHECK_PROGS(MAKE, make)
45 AC_CHECK_PROGS(UNZIP, unzip)
46 AC_CHECK_PROGS(TAR, tar)
47 AC_CHECK_PROGS(MKDIR, mkdir)
48 AC_CHECK_PROGS(CP, cp)
49 AC_CHECK_PROGS(RM, rm)
50 AC_CHECK_PROGS(STOW, stow)
51 AC_CHECK_PROGS(MAKENSIS, makensis)
52 AC_PROG_INSTALL
53
54 missing_tools=
55 for i in DLLTOOL MAKE UNZIP TAR MKDIR CP RM STOW MAKENSIS; do
56    eval tmp='$'$i
57    if test -z "$tmp"; then 
58       missing_tools="$missing_tools `echo $i | tr 'A-Z' 'a-z'`"
59    fi
60 done
61
62
63 # Optional tools.
64
65 AC_CHECK_PROGS(WGET, wget)
66
67
68 # Packages.
69
70 GPG4WIN_BPKG_GNU([libiconv])
71 GPG4WIN_BPKG_GNU([gettext], [libiconv])
72
73 GPG4WIN_BPKG_GNUWIN32([zlib])
74 GPG4WIN_BPKG_GNUWIN32([libpng], [pkgconfig])
75
76 GPG4WIN_BPKG_GTK([pkgconfig])
77 GPG4WIN_BPKG_GTK_DEV([glib], [pkgconfig])
78 GPG4WIN_BPKG_GTK_DEV([gtk+], [atk pango glib libiconv gettext pkgconfig])
79 GPG4WIN_BPKG_GTK_DEV([atk], [glib pkgconfig])
80 GPG4WIN_BPKG_GTK_DEV([pango], [glib pkgconfig])
81 #fixme: These are intermediate package.
82 GPG4WIN_BPKG_BINSRC([gpgee], [gnupg])
83
84
85 GPG4WIN_SPKG([libgpg-error], [libiconv gettext])
86 GPG4WIN_SPKG([gpgme], [libgpg-error gnupg])
87 GPG4WIN_SPKG([gnupg])
88 GPG4WIN_SPKG([gpgol], [gpgme])
89 GPG4WIN_SPKG([gpa], [libiconv gettext zlib gtk+ libpng glib gpgme])
90 GPG4WIN_SPKG([winpt], [gpgme gnupg])
91 GPG4WIN_SPKG([man_novice_de])
92 GPG4WIN_SPKG([man_advanced_de])
93
94 GPG4WIN_FINALIZE
95
96 # Throw an error if required tools are missing
97 if test -n "$missing_tools"; then
98     for i in $missing_tools; do 
99       AC_MSG_NOTICE([$i is missing])
100     done
101     AC_MSG_ERROR([[
102 ***
103 *** Required tools not found. Please consult the above messages
104 *** and install them before running configure again.
105 ***]])
106 fi
107
108
109 # Finalize.
110
111 AC_CONFIG_FILES(Makefile packages/Makefile include/Makefile src/Makefile)
112 AC_CONFIG_FILES(include/config.nsi src/gpg4win.mk)
113 AC_OUTPUT