2007-09-26 Marcus Brinkmann <marcus@g10code.de>
[gpg4win.git] / src / inst-gnupg2.nsi
1 # inst-gnupg2.nsi - Installer snippet for gnupg2.     -*- coding: latin-1; -*-
2 # Copyright (C) 2007 g10 Code GmbH
3
4 # This file is part of Gpg4win.
5
6 # Gpg4win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # Gpg4win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
19 # MA 02110-1301, USA.
20
21
22 !ifdef prefix
23 !undef prefix
24 !endif
25 !define prefix ${ipdir}/gnupg2-${gpg4win_pkg_gnupg2_version}
26
27
28 Section "GnuPG2" SEC_gnupg2
29   SectionIn RO
30
31   SetOutPath "$INSTDIR"
32 !ifdef SOURCES
33   File "${gpg4win_pkg_gnupg2}"
34 !else
35   File "${prefix}/bin/gpg2.exe"
36   File "${prefix}/bin/gpgsm.exe"
37
38   ClearErrors
39   SetOverwrite try
40   File "${prefix}/bin/gpg-agent.exe"
41   SetOverwrite lastused
42   ifErrors 0 +3
43       File /oname=gpg-agent.exe.tmp "${prefix}/bin/gpg-agent.exe"
44       Rename /REBOOTOK gpg-agent.exe.tmp gpg-agent.exe
45
46   File "${prefix}/bin/scdaemon.exe"
47   File "${prefix}/bin/gpgconf.exe"
48   File "${prefix}/bin/gpg-connect-agent.exe"
49
50
51   # As a special exception, these programs are not kept in
52   # libexec/gnupg, where they belong.  Please see the comment in
53   # gnupg/g10/keyserver.c::keyserver_spawn() for an explanation.
54   File "${prefix}/libexec/gpg2keys_finger.exe"
55   File "${prefix}/libexec/gpg2keys_hkp.exe"
56   File "${prefix}/libexec/gpg2keys_curl.exe"
57   File "${prefix}/libexec/gpg2keys_ldap.exe"
58   File "${prefix}/libexec/gpg-protect-tool.exe"
59   File "${prefix}/libexec/gpg-preset-passphrase.exe"
60
61   SetOutPath "$INSTDIR\pub"
62   File /oname=gpg2.exe      "${BUILD_DIR}/gpgwrap.exe"
63   File /oname=gpgsm.exe     "${BUILD_DIR}/gpgwrap.exe"
64   File /oname=gpg-connect-agent.exe  "${BUILD_DIR}/gpgwrap.exe"
65
66   SetOutPath "$INSTDIR\share\gnupg"
67   File "${prefix}/share/gnupg/qualified.txt"
68   File "${prefix}/share/gnupg/com-certs.pem"
69   File "${prefix}/share/gnupg/gpg-conf.skel"
70
71   # Install the language files for gpg.  Note that the PO files are
72   # required to be UTF-8 encoded and that the post-install macro in
73   # Makefile.am needs to build them.
74 #  SetOutPath "$INSTDIR\gnupg2.nls"
75 #  File "${prefix}/share/gnupg2/de.mo"
76
77   # If requested, install the configuration files.
78   ReadRegStr $0 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" AppData
79   StrCmp $0 "" no_config_gpg_conf_files
80   CreateDirectory "$0\gnupg"
81
82   g4wihelp::config_fetch "gpg.conf"
83   StrCmp $R0 "" no_config_gpg2_conf
84     CopyFiles $R0 "$0\gnupg\gpg.conf"
85   no_config_gpg2_conf:
86
87   g4wihelp::config_fetch "gpg-agent.conf"
88   StrCmp $R0 "" no_config_gpg_agent_conf
89     CopyFiles $R0 "$0\gnupg\gpg-agent.conf"
90   no_config_gpg_agent_conf:
91
92   g4wihelp::config_fetch "scdaemon.conf"
93   StrCmp $R0 "" no_config_scdaemon_conf
94     CopyFiles $R0 "$0\gnupg\scdaemon.conf"
95   no_config_scdaemon_conf:
96
97   g4wihelp::config_fetch "trustlist.txt"
98   StrCmp $R0 "" no_config_trustlist_txt
99     CopyFiles $R0 "$0\gnupg\trustlist.txt"
100   no_config_trustlist_txt:
101
102   no_config_gpg_conf_files:
103 !endif
104 SectionEnd
105
106 LangString DESC_SEC_gnupg2 ${LANG_ENGLISH} \
107    "GNU Privacy Guard with S/MIME support"