9d20616345c70eadf6bfba50ef4a5bd9709af8af
[gpg4win.git] / src / inst-gpg4win.nsi
1 # inst-gpg4win.nsi - Hidden section for common files. -*- coding: latin-1; -*-
2 # Copyright (C) 2006 g10 Code GmbH
3 #
4 # This file is part of GPG4Win.
5 #
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10 #
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20
21 # This is the very first section installed.
22 Section "-gpg4win" SEC_gpg4win
23 !ifdef SOURCES
24   SetOutPath "$INSTDIR"
25   File "${BUILD_DIR}/../gpg4win-${VERSION}.tar.bz2"
26 !else
27 # Start the slideshow.
28   SetDetailsPrint none
29
30   SetOutPath "$PLUGINSDIR\Slides"
31   File "${BUILD_DIR}/slideshow/slide1-gpgol.png"
32   File "${BUILD_DIR}/slideshow/slide2-gpgex.png"
33   #File "${BUILD_DIR}/slideshow/slide3-kleopatra.png"
34   File "${BUILD_DIR}/slideshow/slide4-summary.png"
35   File "${BUILD_DIR}/slideshow/slides.dat"
36   g4wihelp::slide_show /NOUNLOAD /CCOLOR=0x000000 "/auto=$PLUGINSDIR\Slides\slides.dat" /FIT=WIDTH
37   SetDetailsPrint both
38   SetOutPath "$INSTDIR"
39
40 # Uninstall an old version if found.
41   ClearErrors
42   ReadRegStr $0 SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "DisplayVersion"
43   IfErrors skip_uninst 0
44   StrCmp $0 "" skip_uninst
45   DetailPrint  "$(T_UninstallingOldVersion)$0"
46   ReadRegStr $0 SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "UninstallString"
47   IfErrors skip_uninst 0
48   ReadRegStr $1 SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "InstallLocation"
49   IfErrors skip_uninst 0
50
51   ExecWait '$0 /S _?=$1'
52 # Deleting here does not work?
53   Delete /REBOOTOK "$1\gpg4win-uninstall.exe"
54   RmDir "$1"
55
56 skip_uninst:
57   SetOutPath "$INSTDIR\share\gpg4win"
58
59   File "${BUILD_DIR}/README.en.txt"
60   File "${BUILD_DIR}/README.de.txt"
61   File /oname=README.ar.txt "${BUILD_DIR}/README.en.txt"
62   File /oname=README.cz.txt "${BUILD_DIR}/README.en.txt"
63   File /oname=README.es.txt "${BUILD_DIR}/README.en.txt"
64   File /oname=README.fr.txt "${BUILD_DIR}/README.en.txt"
65   File /oname=README.it.txt "${BUILD_DIR}/README.en.txt"
66   File /oname=README.pt.txt "${BUILD_DIR}/README.en.txt"
67   File /oname=README.ru.txt "${BUILD_DIR}/README.en.txt"
68   File "${BUILD_DIR}/HOWTO-SMIME.en.txt"
69   File "${BUILD_DIR}/HOWTO-SMIME.de.txt"
70
71   File "${BUILD_DIR}/versioninfo.txt"
72
73   # Write a version file.
74   DetailPrint "Opening VERSION file for writing"
75   FileOpen $0 "$INSTDIR\VERSION" w
76   FileWrite $0 "${PACKAGE}$\r$\n"
77   FileWrite $0 "${VERSION}$\r$\n"
78   FileClose $0
79   DetailPrint "VERSION closed"
80
81   # Register the install directory for Gpg4win suite.
82   WriteRegStr SHCTX "Software\${PRETTY_PACKAGE_SHORT}" "Install Directory" $INSTDIR
83   DetailPrint "Saved install directory in the registry"
84
85   # We used to determine the language using a Registry entry.
86   # Although we don't want to delete the user's Lang Registry Setting
87   # because he might have have selected a different language than his
88   # default.  We delete the global Lang of the installation.
89   DeleteRegValue SHCTX "Software\GNU\GnuPG" "Lang"
90   DetailPrint "Deleted obsolete Lang entry"
91
92   # This old key is required for GPGee.  Please do not use in new
93   # applications.
94   # Note: We don't use it anymore so that gpgme decides what gpg to use
95   #       For the new gpg4win we actually use gpg2.exe.
96   #       To cope with old installations we actually remove this value.
97   #       However we can only remove the SHCTX version not those set by
98   #       the user under HKCU.
99   #WriteRegStr SHCTX "Software\GNU\GnuPG" "gpgProgram" "$INSTDIR\gpg.exe"
100   DeleteRegValue SHCTX "Software\GNU\GnuPG" "gpgProgram"
101   DetailPrint "Deleted obsolete gpgProgram value"
102
103   # Install gpg4win included tools
104   SetOutPath "$INSTDIR\bin"
105   File "${BUILD_DIR}/sha1sum.exe"
106   File "${BUILD_DIR}/sha256sum.exe"
107   File "${BUILD_DIR}/md5sum.exe"
108   File "${BUILD_DIR}/mkportable.exe"
109
110   # Install the mingw32 runtime libraries.  They are stored in the
111   # build directory with a different suffix, so that makensis does not
112   # list symbol names.
113   File /oname=libstdc++-6.dll     "${BUILD_DIR}/libstdc++-6.dll-x"
114   File /oname=libgcc_s_sjlj-1.dll "${BUILD_DIR}/libgcc_s_sjlj-1.dll-x"
115   File /oname=libwinpthread-1.dll "${BUILD_DIR}/libwinpthread-1.dll-x"
116
117 !endif
118
119 SectionEnd
120
121 LangString DESC_Menu_gpg4win_readme ${LANG_ENGLISH} \
122    "General information on Gpg4win"
123
124 LangString DESC_Menu_gpg4win_howtosmime ${LANG_ENGLISH} \
125    "Instruction to configure S/MIME"
126
127 LangString DESC_Menu_gnupg_faq ${LANG_ENGLISH} \
128    "Show the Frequently Asked Questions document for GnuPG"