cf92f6a280c2c9b0a59033eb2240c83c8c29bf7e
[gpg4win.git] / src / inst-gpg4win.nsi
1 # inst-gpg4win.nsi - Hidden section for common files. -*- coding: latin-1; -*-
2 # Copyright (C) 2006 g10 Code GmbH
3 #
4 # This file is part of GPG4Win.
5 #
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10 #
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20
21 # This is the very first section installed.
22 Section "-gpg4win" SEC_gpg4win
23 !ifdef SOURCES
24   SetOutPath "$INSTDIR"
25   File "${BUILD_DIR}/../gpg4win-${VERSION}.tar.bz2"
26 !else
27   SetOutPath "$INSTDIR\share\gpg4win"
28
29   File "${BUILD_DIR}/README.en.txt"
30   File "${BUILD_DIR}/README.de.txt"
31   File /oname=README.ar.txt "${BUILD_DIR}/README.en.txt"
32   File /oname=README.cz.txt "${BUILD_DIR}/README.en.txt"
33   File /oname=README.es.txt "${BUILD_DIR}/README.en.txt"
34   File /oname=README.fr.txt "${BUILD_DIR}/README.en.txt"
35   File /oname=README.it.txt "${BUILD_DIR}/README.en.txt"
36   File /oname=README.pt.txt "${BUILD_DIR}/README.en.txt"
37   File /oname=README.ru.txt "${BUILD_DIR}/README.en.txt"
38   File "${BUILD_DIR}/HOWTO-SMIME.en.txt"
39   File "${BUILD_DIR}/HOWTO-SMIME.de.txt"
40
41   File "${BUILD_DIR}/versioninfo.txt"
42
43   # Write a version file.
44   FileOpen $0 "$INSTDIR\VERSION" w
45   FileWrite $0 "${PACKAGE}$\r$\n"
46   FileWrite $0 "${VERSION}$\r$\n"
47   FileClose $0
48
49   # Register the install directory for the GnuPG suite.
50   WriteRegStr HKLM "Software\GNU\GnuPG" "Install Directory" $INSTDIR
51
52   # Also write it to be recalled on new installation.  Currently
53   # disabled.
54   # WriteRegStr HKLM "Software\GNU\${PRETTY_PACKAGE_SHORT}" "Install Directory" $INSTDIR
55
56   # We used to determine the language using a Registry entry.
57   # Although we don't want to delete the user's Lang Registry Setting
58   # because he might have have selected a different language than his
59   # default.  We delete the global Lang of the installation.
60   DeleteRegValue HKLM "Software\GNU\GnuPG" "Lang"
61
62   # This old key is required for GPGee.  Please do not use in new
63   # applications.
64   # Note: We don't use it anymore so that gpgme decides what gpg to use
65   #       For the new gpg4win we actually use gpg2.exe.
66   #       To cope with old installations we actually remove this value.
67   #       However we can only remove the HKLM version not those set by
68   #       the user under HKCU.
69   #WriteRegStr HKLM "Software\GNU\GnuPG" "gpgProgram" "$INSTDIR\gpg.exe"
70   DeleteRegValue HKLM "Software\GNU\GnuPG" "gpgProgram"
71
72   # Add the public directory to the PATH
73   Push "$INSTDIR\pub"
74   Call AddToPath
75
76   # Install gpg4win included tools
77   SetOutPath "$INSTDIR"
78   File "${BUILD_DIR}/sha1sum.exe"
79   File "${BUILD_DIR}/sha256sum.exe"
80   File "${BUILD_DIR}/md5sum.exe"
81
82 !endif
83
84 SectionEnd
85
86 LangString DESC_Menu_gpg4win_readme ${LANG_ENGLISH} \
87    "General information on Gpg4win"
88
89 LangString DESC_Menu_gpg4win_howtosmime ${LANG_ENGLISH} \
90    "Instruction to configure S/MIME"
91
92 LangString DESC_Menu_gnupg_faq ${LANG_ENGLISH} \
93    "Show the Frequently Asked Questions document for GnuPG"