Mark called uninstallers rebootok
[gpg4win.git] / src / inst-gpg4win.nsi
1 # inst-gpg4win.nsi - Hidden section for common files. -*- coding: latin-1; -*-
2 # Copyright (C) 2006 g10 Code GmbH
3 #
4 # This file is part of GPG4Win.
5 #
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10 #
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20
21 # This is the very first section installed.
22 Section "-gpg4win" SEC_gpg4win
23 !ifdef SOURCES
24   SetOutPath "$INSTDIR"
25   File "${BUILD_DIR}/../gpg4win-${VERSION}.tar.bz2"
26 !else
27
28 # Uninstall an old version if found.
29   ClearErrors
30   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "DisplayVersion"
31   IfErrors skip_uninst 0
32   StrCmp $0 "" skip_uninst
33   DetailPrint  "$(T_UninstallingOldVersion)$0"
34   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "UninstallString"
35   IfErrors skip_uninst 0
36   ReadRegStr $1 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GPG4Win" "InstallLocation"
37   IfErrors skip_uninst 0
38
39   ExecWait '$0 /S _?=$1'
40 # Deleting here does not work?
41   Delete /REBOOTOK "$1\gpg4win-uninstall.exe"
42   RmDir "$1"
43
44 skip_uninst:
45   SetOutPath "$INSTDIR\share\gpg4win"
46
47   File "${BUILD_DIR}/README.en.txt"
48   File "${BUILD_DIR}/README.de.txt"
49   File /oname=README.ar.txt "${BUILD_DIR}/README.en.txt"
50   File /oname=README.cz.txt "${BUILD_DIR}/README.en.txt"
51   File /oname=README.es.txt "${BUILD_DIR}/README.en.txt"
52   File /oname=README.fr.txt "${BUILD_DIR}/README.en.txt"
53   File /oname=README.it.txt "${BUILD_DIR}/README.en.txt"
54   File /oname=README.pt.txt "${BUILD_DIR}/README.en.txt"
55   File /oname=README.ru.txt "${BUILD_DIR}/README.en.txt"
56   File "${BUILD_DIR}/HOWTO-SMIME.en.txt"
57   File "${BUILD_DIR}/HOWTO-SMIME.de.txt"
58
59   File "${BUILD_DIR}/versioninfo.txt"
60
61   # Write a version file.
62   DetailPrint "Opening VERSION file for writing"
63   FileOpen $0 "$INSTDIR\VERSION" w
64   FileWrite $0 "${PACKAGE}$\r$\n"
65   FileWrite $0 "${VERSION}$\r$\n"
66   FileClose $0
67   DetailPrint "VERSION closed"
68
69   # Register the install directory for Gpg4win suite.
70   WriteRegStr HKLM "Software\${PRETTY_PACKAGE_SHORT}" "Install Directory" $INSTDIR
71   DetailPrint "Saved install directory in the registry"
72
73   # We used to determine the language using a Registry entry.
74   # Although we don't want to delete the user's Lang Registry Setting
75   # because he might have have selected a different language than his
76   # default.  We delete the global Lang of the installation.
77   DeleteRegValue HKLM "Software\GNU\GnuPG" "Lang"
78   DetailPrint "Deleted obsolete Lang entry"
79
80   # This old key is required for GPGee.  Please do not use in new
81   # applications.
82   # Note: We don't use it anymore so that gpgme decides what gpg to use
83   #       For the new gpg4win we actually use gpg2.exe.
84   #       To cope with old installations we actually remove this value.
85   #       However we can only remove the HKLM version not those set by
86   #       the user under HKCU.
87   #WriteRegStr HKLM "Software\GNU\GnuPG" "gpgProgram" "$INSTDIR\gpg.exe"
88   DeleteRegValue HKLM "Software\GNU\GnuPG" "gpgProgram"
89   DetailPrint "Deleted obsolete gpgProgram value"
90
91   # Install gpg4win included tools
92   SetOutPath "$INSTDIR"
93   File "${BUILD_DIR}/sha1sum.exe"
94   File "${BUILD_DIR}/sha256sum.exe"
95   File "${BUILD_DIR}/md5sum.exe"
96   File "${BUILD_DIR}/mkportable.exe"
97
98   # Install the mingw32 runtime libraries.  They are stored in the
99   # build directory with a different suffix, so that makensis does not
100   # list symbol names.
101   File /oname=libstdc++-6.dll     "${BUILD_DIR}/libstdc++-6.dll-x"
102   File /oname=libgcc_s_sjlj-1.dll "${BUILD_DIR}/libgcc_s_sjlj-1.dll-x"
103   File /oname=libwinpthread-1.dll "${BUILD_DIR}/libwinpthread-1.dll-x"
104
105 !endif
106
107 SectionEnd
108
109 LangString DESC_Menu_gpg4win_readme ${LANG_ENGLISH} \
110    "General information on Gpg4win"
111
112 LangString DESC_Menu_gpg4win_howtosmime ${LANG_ENGLISH} \
113    "Instruction to configure S/MIME"
114
115 LangString DESC_Menu_gnupg_faq ${LANG_ENGLISH} \
116    "Show the Frequently Asked Questions document for GnuPG"