Remove Kleowrap and Gpgwrap
[gpg4win.git] / src / inst-gpgex.nsi
1 # inst-gpgex.nsi - Installer snippet for gpgex.      -*- coding: latin-1; -*-
2 # Copyright (C) 2005, 2007, 2008 g10 Code GmbH
3 #
4 # This file is part of GPG4Win.
5 #
6 # GPG4Win is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10 #
11 # GPG4Win is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19
20 !ifdef prefix
21 !undef prefix
22 !endif
23 !ifdef exprefix
24 !undef exprefix
25 !endif
26 !define prefix ${ipdir}/gpgex-${gpg4win_pkg_gpgex_version}
27 !define exprefix ${exipdir}/gpgex-${gpg4win_pkg_gpgex_version}
28
29
30 Section "-removegpgee"
31 !ifndef SOURCES
32 # Uninstall a previous gpgee version, if it exists.
33   ifFileExists "$INSTDIR\GPGee.dll" 0 gpgex_no_gpgee
34     UnRegDLL "$INSTDIR\GPGee.dll"
35     Delete /REBOOTOK "$INSTDIR\bin\GPGee.dll"
36     Delete /REBOOTOK "$INSTDIR\GPGee.DEU"
37     Delete "$INSTDIR\GPGee.hlp"
38     Delete "$INSTDIR\share\gpgee\gpl.txt"
39     RMDir "$INSTDIR\share\gpgee"
40     RMDir "$INSTDIR\share"
41     RMDir "$INSTDIR"
42   gpgex_no_gpgee:
43 !endif
44 SectionEnd
45
46
47 ${MementoSection} "GpgEX" SEC_gpgex
48   SetOutPath "$INSTDIR"
49 !ifdef SOURCES
50   File "${gpg4win_pkg_gpgex}"
51 !else
52   SetOutPath "$INSTDIR\bin"
53
54   ClearErrors
55   SetOverwrite try
56   File ${prefix}/bin/gpgex.dll
57   SetOverwrite lastused
58   ifErrors 0 do_reg
59       File /oname=gpgex.dll.tmp ${prefix}/bin/gpgex.dll
60       Rename /REBOOTOK gpgex.dll.tmp gpgex.dll
61
62  do_reg:
63   # Register the DLL.
64   ClearErrors
65   RegDLL "$INSTDIR\bin\gpgex.dll"
66   ifErrors 0 +2
67      MessageBox MB_OK "$(T_GpgEX_RegFailed)"
68
69   SetOutPath "$INSTDIR\share\locale\de\LC_MESSAGES"
70   File ${prefix}/share/locale/de/LC_MESSAGES/gpgex.mo
71   SetOutPath "$INSTDIR\share\locale\ar\LC_MESSAGES"
72   File ${prefix}/share/locale/ar/LC_MESSAGES/gpgex.mo
73   SetOutPath "$INSTDIR\share\locale\es\LC_MESSAGES"
74   File ${prefix}/share/locale/es/LC_MESSAGES/gpgex.mo
75   SetOutPath "$INSTDIR\share\locale\ru\LC_MESSAGES"
76   File ${prefix}/share/locale/ru/LC_MESSAGES/gpgex.mo
77   SetOutPath "$INSTDIR\share\locale\pt\LC_MESSAGES"
78   File ${prefix}/share/locale/pt/LC_MESSAGES/gpgex.mo
79   SetOutPath "$INSTDIR\share\locale\pl\LC_MESSAGES"
80   File ${prefix}/share/locale/pl/LC_MESSAGES/gpgex.mo
81   SetOutPath "$INSTDIR\share\locale\zh_CN\LC_MESSAGES"
82   File ${prefix}/share/locale/zh_CN/LC_MESSAGES/gpgex.mo
83   SetOutPath "$INSTDIR\share\locale\zh_TW\LC_MESSAGES"
84   File ${prefix}/share/locale/zh_TW/LC_MESSAGES/gpgex.mo
85   SetOutPath "$INSTDIR\share\locale\fr\LC_MESSAGES"
86   File ${prefix}/share/locale/fr/LC_MESSAGES/gpgex.mo
87
88   SetOutPath "$INSTDIR\share\doc\gpgex"
89   File ${prefix}/share/doc/gpgex/gpgex-en.html
90   File ${prefix}/share/doc/gpgex/gpgex-de.html
91
92
93 ${If} ${RunningX64}
94
95   # Install the 64 bit version of the dll.
96   SetOutPath "$INSTDIR\bin_64"
97   ClearErrors
98   SetOverwrite try
99   File ${exprefix}/bin/gpgex.dll
100   SetOverwrite lastused
101   ifErrors 0 do_reg64
102       File /oname=gpgex.dll.tmp ${exprefix}/bin/gpgex.dll
103       Rename /REBOOTOK gpgex.dll.tmp gpgex.dll
104
105  do_reg64:
106   # Register the DLL. We need to register both versions.  However
107   # RegDLL can't be used for 64 bit and InstallLib seems to be a
108   # registry hack.
109   ClearErrors
110   ExecWait '"$SYSDIR\regsvr32" /s "$INSTDIR\bin_64\gpgex.dll"'
111   ifErrors 0 +2
112      MessageBox MB_OK "$(T_GpgEX_RegFailed) (64 bit)"
113
114   # Note: There is no need to install the help an mo files because
115   # they are identical to those installed by the 32 bit version.
116 ${EndIf}
117
118 !endif
119 ${MementoSectionEnd}
120
121
122 LangString T_GpgEX_RegFailed ${LANG_ENGLISH} \
123    "Warning: Registration of the GpgEX plugin failed."
124
125 LangString DESC_SEC_gpgex ${LANG_ENGLISH} \
126    "GnuPG Shell Extension"