Fix type inconsistency between gpgme.h and gpgme.c.
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.11"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [5])
32 m4_define(mym4_version_micro, [0])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=22
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=11
62 LIBGPGME_LT_REVISION=0
63
64 # If the API is changed in an incompatible way: increment the next counter.
65 GPGME_CONFIG_API_VERSION=1
66 ##############################################
67
68 NEED_GPG_ERROR_VERSION=1.11
69 NEED_LIBASSUAN_API=2
70 NEED_LIBASSUAN_VERSION=2.0.2
71
72
73 PACKAGE=$PACKAGE_NAME
74 VERSION=$PACKAGE_VERSION
75
76 AC_CONFIG_AUX_DIR([build-aux])
77 AC_CONFIG_MACRO_DIR([m4])
78 AC_CONFIG_SRCDIR(src/gpgme.h.in)
79 AC_CONFIG_HEADER(config.h)
80 # Note: For automake 1.13 add the option
81 #          serial-tests
82 AM_INIT_AUTOMAKE
83 AM_MAINTAINER_MODE
84 AC_CANONICAL_HOST
85 AM_SILENT_RULES
86
87 # Enable GNU extensions on systems that have them.
88 AC_GNU_SOURCE
89
90 AH_VERBATIM([_REENTRANT],
91 [/* To allow the use of GPGME in multithreaded programs we have to use
92   special features from the library.
93   IMPORTANT: gpgme is not yet fully reentrant and you should use it
94   only from one thread.  */
95 #ifndef _REENTRANT
96 # define _REENTRANT 1
97 #endif])
98
99 AC_PROG_CC
100 AC_PROG_CXX
101
102 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
103 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
104
105 AC_SUBST(LIBGPGME_LT_CURRENT)
106 AC_SUBST(LIBGPGME_LT_AGE)
107 AC_SUBST(LIBGPGME_LT_REVISION)
108
109 AC_SUBST(PACKAGE)
110 AC_SUBST(VERSION)
111 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
112 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
113 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
114                           mym4_version_minor mym4_version_micro)
115 AC_SUBST(VERSION_NUMBER)
116
117 # Don't default to build static libs.
118 LT_PREREQ([2.2.6])
119 LT_INIT([win32-dll disable-static])
120 LT_LANG([Windows Resource])
121
122 # For now we hardcode the use of version scripts.  It would be better
123 # to write a test for this or even implement this within libtool.
124 have_ld_version_script=no
125 case "${host}" in
126     *-*-linux*)
127         have_ld_version_script=yes
128         ;;
129     *-*-gnu*)
130         have_ld_version_script=yes
131         ;;
132     *-apple-darwin*)
133         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
134         ;;
135 esac
136
137 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
138
139 GPG_DEFAULT=no
140 GPGSM_DEFAULT=no
141 GPGCONF_DEFAULT=no
142 G13_DEFAULT=no
143 component_system=None
144 have_dosish_system=no
145 have_android_system=no
146 have_w32_system=no
147 have_w64_system=no
148 build_w32_glib=no
149 build_w32_qt=no
150 case "${host}" in
151     x86_64-*mingw32*)
152         have_w64_system=yes
153         ;;
154     *-mingw32ce*)
155         have_w32ce_system=yes
156         ;;
157     *-linux-androideabi)
158         have_android_system=yes
159         ;;
160 esac
161 case "${host}" in
162     *-mingw32ce*|*-mingw32*)
163         have_dosish_system=yes
164         have_w32_system=yes
165         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
166         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
167         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
168         G13_DEFAULT='c:\\gnupg\\g13.exe'
169         #component_system='COM+'
170
171         AM_PATH_GLIB_2_0
172         AC_ARG_ENABLE(w32-glib,
173             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
174                            build_w32_glib=$enableval)
175
176         # Check disabled, because the qt-dev packages in gpg4win do
177         # not provide any support for cross compilation.
178         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
179
180         # Use it like this:
181         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
182         AC_SUBST(QT4_CORE_CFLAGS)
183         AC_SUBST(QT4_CORE_LIBS)
184         AC_ARG_ENABLE(w32-qt,
185             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
186                            build_w32_qt=$enableval)
187         ;;
188     *)
189         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
190         if test "$have_pthread" = yes; then
191           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
192         fi
193
194         # XXX: Probably use exec-prefix here?
195 #       GPG_DEFAULT='/usr/bin/gpg'
196 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
197 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
198 #       G13_DEFAULT='/usr/bin/g13'
199         ;;
200 esac
201
202 if test "$have_dosish_system" = yes; then
203    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
204              [Defined if we run on some of the PCDOS like systems
205               (DOS, Windoze. OS/2) with special properties like
206               no file modes])
207 fi
208 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
209
210 if test "$have_w32_system" = yes; then
211    AC_DEFINE(HAVE_W32_SYSTEM,1,
212              [Defined if we run on any kind of W32 API based system])
213 fi
214 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
215
216 if test "$have_w64_system" = yes; then
217    AC_DEFINE(HAVE_W64_SYSTEM,1,
218              [Defined if we run on a 64 bit W32 API based system])
219 fi
220 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
221
222 if test "$have_w32ce_system" = yes; then
223    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
224              [Defined if we run on a W32 CE API based system])
225 fi
226 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
227
228 if test "$have_android_system" = yes; then
229    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
230 fi
231 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
232
233 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
234 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
235
236 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
237
238
239 #
240 # Provide information about the build.
241 #
242 BUILD_REVISION="mym4_revision"
243 AC_SUBST(BUILD_REVISION)
244 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
245                    [GIT commit id revision used to build this package])
246
247 changequote(,)dnl
248 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
249 changequote([,])dnl
250 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
251 AC_SUBST(BUILD_FILEVERSION)
252
253 BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
254 AC_SUBST(BUILD_TIMESTAMP)
255 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
256                    [The time this package was configured for a build])
257
258 #
259 # Options to disable some regression tests
260 #
261 run_gpgconf_test="yes"
262 AC_ARG_ENABLE(gpgconf-test,
263   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
264          run_gpgconf_test=$enableval)
265 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
266
267 run_gpg_test="yes"
268 AC_ARG_ENABLE(gpg-test,
269   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
270          run_gpg_test=$enableval)
271 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
272
273 run_gpgsm_test="yes"
274 AC_ARG_ENABLE(gpgsm-test,
275   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
276          run_gpgsm_test=$enableval)
277 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
278
279 run_g13_test="yes"
280 AC_ARG_ENABLE(g13-test,
281   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
282          run_g13_test=$enableval)
283 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
284
285
286 # Checks for header files.
287 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
288                        unistd.h sys/time.h sys/types.h sys/stat.h])
289
290
291 # Type checks.
292 AC_C_INLINE
293 AC_CHECK_SIZEOF(unsigned int)
294 AC_SYS_LARGEFILE
295 AC_TYPE_OFF_T
296 AC_TYPE_UINTPTR_T
297
298 # A simple compile time check in gpgme.h for GNU/Linux systems that
299 # prevents a file offset bits mismatch between gpgme and the application.
300 NEED__FILE_OFFSET_BITS=0
301 if test "$have_w32_system" != yes; then
302   case "$ac_cv_sys_file_offset_bits" in
303     "" | no | unknown) ;;
304     *)
305     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
306     ;;
307   esac
308 fi
309 AC_SUBST(NEED__FILE_OFFSET_BITS)
310
311 # Figure out platform dependent typedefs for gpgme.h
312 if test "$have_w32_system" = yes; then
313     INSERT__TYPEDEFS_FOR_GPGME_H="
314 #ifdef _WIN64
315 # include <stdint.h>
316   typedef int64_t gpgme_off_t;
317   typedef int64_t gpgme_ssize_t;
318 #else /* _WIN32 */
319   typedef long gpgme_off_t;
320   typedef long gpgme_ssize_t;
321 #endif /* _WIN32 */"
322     API__OFF_T="gpgme_off_t"
323     API__SSIZE_T="gpgme_ssize_t"
324 else
325     INSERT__TYPEDEFS_FOR_GPGME_H="
326 #include <sys/types.h>
327 typedef off_t   gpgme_off_t;
328 typedef ssize_t gpgme_ssize_t;"
329     API__OFF_T="off_t"
330     API__SSIZE_T="ssize_t"
331 fi
332 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
333 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
334 AC_SUBST(API__OFF_T)
335 AM_SUBST_NOTMAKE(API__OFF_T)
336 AC_SUBST(API__SSIZE_T)
337 AM_SUBST_NOTMAKE(API__SSIZE_T)
338
339 # Checks for compiler features.
340 if test "$GCC" = yes; then
341     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
342     if test "$have_w32_system" = yes; then
343        CFLAGS="$CFLAGS -mms-bitfields"
344     fi
345 fi
346
347 # Only used for debugging, so no serious test needed (for actual
348 # functionality you have to test libc as well, this only tests the
349 # compiler).
350 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
351    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
352                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
353 if test "$gpgme_cv_tls_works" = yes; then
354   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
355 fi
356
357
358 # Checks for library functions.
359 AC_MSG_NOTICE([checking for libraries])
360
361 AC_FUNC_FSEEKO
362
363 AC_REPLACE_FUNCS(vasprintf)
364 if test "$ac_cv_func_vasprintf" != yes; then
365   GNUPG_CHECK_VA_COPY
366 fi
367
368 # Try to find a thread-safe version of ttyname().
369 gnupg_REPLACE_TTYNAME_R
370 if test "$ac_cv_func_ttyname_r" != yes; then
371   AC_MSG_WARN([
372 ***
373 *** ttyname() is not thread-safe and ttyname_r() does not exist
374 ***])
375 fi
376
377 # Try to find a thread-safe version of getenv().
378 have_thread_safe_getenv=no
379 jm_GLIBC21
380 if test $GLIBC21 = yes; then
381   have_thread_safe_getenv=yes
382 fi
383 if test $have_thread_safe_getenv = yes; then
384   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
385 fi
386 have_getenv_r=no
387 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
388 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
389   AC_MSG_WARN([
390 ***
391 *** getenv() is not thread-safe and getenv_r() does not exist
392 ***])
393 fi
394
395 # For converting time strings to seconds since Epoch, we need the timegm
396 # function.
397 AC_CHECK_FUNCS(timegm)
398 if test "$ac_cv_func_timegm" != yes; then
399   AC_MSG_WARN([
400 ***
401 *** timegm() not available - a non-thread-safe kludge will be used
402 *** and the TZ variable might be changed at runtime.
403 ***])
404 fi
405
406 AC_CHECK_FUNCS(setlocale)
407
408 # Checking for libgpg-error.
409 have_gpg_error=no
410 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
411                   have_gpg_error=yes, have_gpg_error=no)
412 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
413           [The default error source for GPGME.])
414
415 # And for libassuan.
416 have_libassuan=no
417 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
418                   have_libassuan=yes, have_libassuan=no)
419 if test "$have_libassuan" = "yes"; then
420   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
421                      [version of the libassuan library])
422 fi
423
424
425 #
426 # Other checks
427 #
428
429 # Check for funopen
430 AC_CHECK_FUNCS(funopen)
431 if test $ac_cv_func_funopen != yes; then
432     # No funopen but we can implement that in terms of fopencookie.
433     AC_CHECK_FUNCS(fopencookie)
434     if test $ac_cv_func_fopencookie = yes; then
435         AC_REPLACE_FUNCS(funopen)
436     else
437         AC_MSG_WARN([
438 ***
439 *** No implementation of fopencookie or funopen available
440 ***])
441     fi
442 fi
443
444 # Check for getgid etc
445 AC_CHECK_FUNCS(getgid getegid)
446
447
448 # Replacement functions.
449 AC_REPLACE_FUNCS(stpcpy)
450 AC_REPLACE_FUNCS(setenv)
451
452 # Assuan check for descriptor passing.
453 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
454                 [supports_descriptor_passing=yes],
455                 [supports_descriptor_passing=no
456                  AC_MSG_WARN([
457 ***
458 *** Data structure for sending ancillary data missing.
459 *** Descriptor passing won't work.
460 ***])],[
461 #include <stdlib.h>
462 #include <stddef.h>
463 #include <stdio.h>
464 #include <sys/types.h>
465 #include <sys/socket.h>
466 #include <sys/un.h>
467 #if HAVE_SYS_UIO_H
468 #include <sys/uio.h>
469 #endif
470 #include <unistd.h>
471        ])
472
473
474 dnl There seems to be a problem with Apple and decriptor passing.
475 dnl Until we found a solution we change the default to no.
476 dnl See bug 1483.
477 case "${host}" in
478     *-apple-darwin*)
479       use_descriptor_passing=no
480       ;;
481     *)
482       use_descriptor_passing=yes
483       ;;
484 esac
485 AC_ARG_ENABLE(fd-passing,
486   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
487   use_descriptor_passing=$enableval)
488
489 if test "$supports_descriptor_passing" != "yes"; then
490   use_descriptor_passing=no
491 fi
492
493 if test "$use_descriptor_passing" = "yes"; then
494 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
495           [Defined if descriptor passing is enabled and supported])
496 fi
497
498 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
499
500
501 uiserver=no
502 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
503   uiserver=yes
504 fi
505 if test "$uiserver" != "no"; then
506   AC_DEFINE(ENABLE_UISERVER, 1,
507             [Defined if we are building with uiserver support.])
508 fi
509 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
510
511
512 # Add a few constants to help porting to W32
513 AH_VERBATIM([SEPCONSTANTS],
514 [
515 /* Separators as used in $PATH and file name.  */
516 #ifdef HAVE_DOSISH_SYSTEM
517 #define PATHSEP_C ';'
518 #define DIRSEP_C '\\'
519 #define DIRSEP_S "\\"
520 #else
521 #define PATHSEP_C ':'
522 #define DIRSEP_C '/'
523 #define DIRSEP_S "/"
524 #endif
525 ])
526
527 AH_BOTTOM([
528 /* Definition of GCC specific attributes.  */
529 #if __GNUC__ > 2
530 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
531 #else
532 # define GPGME_GCC_A_PURE
533 #endif
534
535 /* Under WindowsCE we need gpg-error's strerror macro.  */
536 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
537
538 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
539                     "Copyright (C) 2001--2013 g10 Code GmbH\n"
540 ])
541
542
543 # Substitution used for gpgme-config
544 GPGME_CONFIG_LIBS="-lgpgme"
545 GPGME_CONFIG_CFLAGS=""
546 GPGME_CONFIG_HOST="$host"
547 AC_SUBST(GPGME_CONFIG_API_VERSION)
548 AC_SUBST(GPGME_CONFIG_LIBS)
549 AC_SUBST(GPGME_CONFIG_CFLAGS)
550 AC_SUBST(GPGME_CONFIG_HOST)
551
552 # Frob'da Variables
553 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
554            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
555 AC_SUBST(LTLIBOBJS)
556
557 # Some checks for gpgme-tool
558 # Done at top: AC_CHECK_HEADER([argp.h])
559 AC_CHECK_TYPES([error_t], [],
560    [AC_DEFINE([error_t], [int],
561    [Define to a type to use for `error_t' if it is not otherwise available.])],
562    [#include <errno.h>])
563
564
565 # A substitution to set generated files in a Emacs buffer to read-only.
566 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
567 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
568 AC_SUBST(emacs_local_vars_end, ['End:'])
569
570
571 # Last check.
572 die=no
573 if test "$have_gpg_error" = "no"; then
574    die=yes
575    AC_MSG_NOTICE([[
576 ***
577 *** You need libgpg-error to build this program.
578 **  This library is for example available at
579 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
580 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
581 ***]])
582 fi
583 if test "$have_libassuan" = "no"; then
584    die=yes
585    AC_MSG_NOTICE([[
586 ***
587 *** You need libassuan to build this program.
588 *** This library is for example available at
589 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
590 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
591 ***]])
592 fi
593
594 if test "$die" = "yes"; then
595     AC_MSG_ERROR([[
596 ***
597 *** Required libraries not found. Please consult the above messages
598 *** and install them before running configure again.
599 ***]])
600 fi
601
602
603 #
604 # Create config files
605
606 AC_CONFIG_FILES(Makefile src/Makefile
607                 tests/Makefile
608                 tests/gpg/Makefile
609                 tests/gpgsm/Makefile
610                 tests/opassuan/Makefile
611                 doc/Makefile
612                 src/versioninfo.rc
613                 src/gpgme.h)
614 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
615 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
616 AC_OUTPUT
617
618 echo "
619         GPGME v${VERSION} has been configured as follows:
620
621         Revision:        mym4_revision  (mym4_revision_dec)
622         Platform:        $host
623
624         UI Server:       $uiserver
625         FD Passing:      $use_descriptor_passing
626         GPGME Pthread:   $have_pthread
627 "