2005-09-30 Marcus Brinkmann <marcus@g10code.de>
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU Lesser General Public License as
9 # published by the Free Software Foundation; either version 2.1 of the
10 # License, or (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful, but WITHOUT
13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
15 # Public License for more details.
16
17 # You should have received a copy of the GNU Lesser General Public
18 # License along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22
23 AC_PREREQ(2.59)
24 min_automake_version="1.9.3"
25
26 # Version number: Remember to change it immediately *after* a release.
27 AC_INIT(gpgme, 1.1.0-cvs, [bug-gpgme@gnupg.org])
28 # LT Version numbers, remember to change them just *before* a release.
29 #   (Code changed:                      REVISION++)
30 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
31 #   (Interfaces added:                  AGE++)
32 #   (Interfaces removed/changed:        AGE=0)
33 #
34 LIBGPGME_LT_CURRENT=14
35 # Subtract 2 from this value if you want to make the LFS transition an
36 # ABI break.  [Note to self: Remove this comment with the next regular break.]
37 LIBGPGME_LT_AGE=3
38 LIBGPGME_LT_REVISION=3
39
40 # If the API is changed in an incompatible way: increment the next counter.
41 GPGME_CONFIG_API_VERSION=1
42
43 NEED_GPG_VERSION=1.2.2
44 NEED_GPGSM_VERSION=1.9.6
45 ##############################################
46
47
48 PACKAGE=$PACKAGE_NAME
49 VERSION=$PACKAGE_VERSION
50
51 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
52 dnl FIXME: Enable this with autoconf 2.59.
53 dnl AC_CONFIG_MACRO_DIR(m4)
54 AM_CONFIG_HEADER(config.h)
55 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
56 AM_MAINTAINER_MODE
57 AC_CANONICAL_HOST
58
59 # Enable GNU extensions on systems that have them.
60 AC_GNU_SOURCE
61
62 AH_VERBATIM([_REENTRANT],
63 [/* To allow the use of GPGME in multithreaded programs we have to use
64   special features from the library.
65   IMPORTANT: gpgme is not yet fully reentrant and you should use it
66   only from one thread.  */
67 #ifndef _REENTRANT
68 # define _REENTRANT 1
69 #endif])
70
71 AC_PROG_CC
72 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
73 AC_CHECK_TOOL(WINDRES, windres, :)
74
75
76 AC_SUBST(LIBGPGME_LT_CURRENT)
77 AC_SUBST(LIBGPGME_LT_AGE)
78 AC_SUBST(LIBGPGME_LT_REVISION)
79 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
80                                      [Min. needed GnuPG version.])
81 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
82                                        [Min. needed GPGSM version.])
83
84 AC_SUBST(PACKAGE)
85 AC_SUBST(VERSION)
86 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
87 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
88
89 # Don't default to build static libs.
90 AC_DISABLE_STATIC
91 AC_PROG_LIBTOOL
92
93 # For now we hardcode the use of version scripts.  It would be better
94 # to write a test for this or even implement this within libtool.
95 have_ld_version_script=no
96 case "${host}" in
97     *-*-linux*)
98         have_ld_version_script=yes
99         ;;
100     *-*-gnu*)
101         have_ld_version_script=yes
102         ;;
103 esac
104 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
105
106 GPG_DEFAULT=no
107 GPGSM_DEFAULT=no
108 component_system=None
109 have_dosish_system=no
110 have_w32_system=no
111 case "${host}" in
112     *-mingw32*)
113         # special stuff for Windoze NT
114         have_dosish_system=yes
115         have_w32_system=yes
116         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
117         # XXX Assuan is not supported in this configuration.
118         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
119         #component_system='COM+'
120         ;;
121     *)
122         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
123         if test "$have_pth" = yes; then
124           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
125         fi
126         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
127         if test "$have_pthread" = yes; then
128           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
129         fi
130
131         # XXX: Probably use exec-prefix here?
132 #       GPG_DEFAULT='/usr/bin/gpg'
133 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
134         ;;
135 esac
136
137 if test "$have_dosish_system" = yes; then
138    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
139              [Defined if we run on some of the PCDOS like systems 
140               (DOS, Windoze. OS/2) with special properties like
141               no file modes])
142 fi
143 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
144
145 if test "$have_w32_system" = yes; then
146    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
147 fi
148 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
149
150
151 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
152 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
153
154
155 # Checks for header files.
156 AC_CHECK_HEADERS(sys/select.h)
157
158
159 # Type checks.
160 AC_CHECK_SIZEOF(unsigned int)
161 AC_SYS_LARGEFILE
162 AC_TYPE_OFF_T
163
164 # Checks for compiler features.
165 if test "$GCC" = yes; then
166     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
167 fi
168
169
170 # Checks for library functions.
171 AC_FUNC_FSEEKO
172
173 AC_CHECK_FUNCS(stpcpy)
174
175 AC_REPLACE_FUNCS(vasprintf)
176 if test "$ac_cv_func_vasprintf" != yes; then
177   GNUPG_CHECK_VA_COPY
178 fi
179
180 # Try to find a thread-safe version of ttyname().
181 AC_REPLACE_FUNCS(ttyname_r)
182 if test "$ac_cv_func_ttyname_r" != yes; then
183   AC_MSG_WARN([
184 ***
185 *** ttyname() is not thread-safe and ttyname_r() does not exist
186 ***])
187 fi
188
189 # Try to find a thread-safe version of getenv().
190 have_thread_safe_getenv=no
191 jm_GLIBC21
192 if test $GLIBC21 = yes; then
193   have_thread_safe_getenv=yes
194 fi
195 if test $have_thread_safe_getenv = yes; then
196   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
197 fi
198 have_getenv_r=no
199 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
200 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
201   AC_MSG_WARN([
202 ***
203 *** getenv() is not thread-safe and getenv_r() does not exist
204 ***])
205 fi
206
207 # For converting time strings to seconds since Epoch, we need the timegm
208 # function.
209 AC_CHECK_FUNCS(timegm)
210 if test "$ac_cv_func_timegm" != yes; then
211   AC_MSG_WARN([
212 ***
213 *** timegm() not available - a non-thread-safe kludge will be used
214 *** and the TZ variable might be changed at runtime.
215 ***])
216 fi
217
218 # Checking for libgpg-error.
219 AM_PATH_GPG_ERROR(0.5,, AC_MSG_ERROR([libgpg-error was not found]))
220 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
221           [The default error source for GPGME.])
222
223
224
225 # Checks for system services
226 NO_OVERRIDE=no
227 AC_ARG_WITH(gpg,
228             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
229             GPG=$withval, NO_OVERRIDE=yes)
230 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
231   GPG=
232   NO_OVERRIDE=yes
233   if test "$cross_compiling" != "yes"; then
234     AC_PATH_PROG(GPG, gpg)
235   fi
236   if test -z "$GPG"; then
237     GPG="$GPG_DEFAULT"
238   fi
239 fi
240 if test "$GPG" = no; then
241   if test "$NO_OVERRIDE" = "yes"; then
242     if test "$cross_compiling" != "yes"; then
243       AC_MSG_WARN([
244 ***
245 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
246 ***])
247     else
248       AC_MSG_ERROR([
249 ***
250 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
251 ***])
252     fi
253   fi
254 else
255   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
256   AC_SUBST(GPG)
257 fi
258 dnl Check for GnuPG version requirement.
259 GPG_VERSION=unknown
260 ok=maybe
261 if test -z "$GPG" -o "x$GPG" = "xno"; then
262   ok=no
263 else
264   if test "$cross_compiling" = "yes"; then
265     AC_MSG_WARN([GnuPG version can not be checked when cross compiling])
266     ok=no
267   else
268     if test ! -x "$GPG"; then
269       AC_MSG_WARN([GnuPG not executable, version check disabled])
270       ok=no
271     fi
272   fi
273 fi
274 if test "$ok" = "maybe"; then
275   AC_MSG_CHECKING(for GnuPG >= $NEED_GPG_VERSION)
276   req_major=`echo $NEED_GPG_VERSION | \
277              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
278   req_minor=`echo $NEED_GPG_VERSION | \
279              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
280   req_micro=`echo $NEED_GPG_VERSION | \
281              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
282   gpg_version=`$GPG --version | grep ^gpg`
283   major=`echo $gpg_version | \
284          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
285   minor=`echo $gpg_version | \
286          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
287   micro=`echo $gpg_version | \
288          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
289   GPG_VERSION=`echo $gpg_version | sed 's/^gpg (GnuPG) //'`
290
291   if test "$major" -gt "$req_major"; then
292     ok=yes
293   else
294     if test "$major" -eq "$req_major"; then
295       if test "$minor" -gt "$req_minor"; then
296         ok=yes
297       else
298         if test "$minor" -eq "$req_minor"; then
299           if test "$micro" -ge "$req_micro"; then
300             ok=yes
301           fi
302         fi
303       fi
304     fi
305   fi
306   if test "$ok" = "yes"; then
307     AC_MSG_RESULT(yes)
308   else
309     AC_MSG_RESULT(no)
310     AC_MSG_WARN([GnuPG must be at least version $NEED_GPG_VERSION])
311   fi
312 fi
313 AM_CONDITIONAL(RUN_GPG_TESTS, test "$ok" = "yes")
314 AC_SUBST(GPG_PATH)
315
316 NO_OVERRIDE=no
317 AC_ARG_WITH(gpgsm,
318             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
319             GPGSM=$withval, NO_OVERRIDE=yes)
320 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
321   GPGSM=
322   NO_OVERRIDE=yes
323   if test "$cross_compiling" != "yes"; then
324     AC_PATH_PROG(GPGSM, gpgsm)
325   fi
326   if test -z "$GPGSM"; then
327     GPGSM="$GPGSM_DEFAULT"
328   fi
329 fi
330 if test "$GPGSM" = no; then
331   if test "$NO_OVERRIDE" = "yes"; then
332     if test "$cross_compiling" != "yes"; then
333       AC_MSG_WARN([
334 ***
335 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
336 ***])
337     else
338       AC_MSG_ERROR([
339 ***
340 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
341 ***])
342     fi
343   fi
344 else
345   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
346   AC_DEFINE(ENABLE_GPGSM,1,[Whether GPGSM support is enabled])
347 fi
348 AM_CONDITIONAL(HAVE_GPGSM, test "$GPGSM" != "no")
349
350
351 dnl Check for GPGSM version requirement.
352 GPGSM_VERSION=unknown
353 ok=maybe
354 if test -z "$GPGSM" -o "x$GPGSM" = "xno"; then
355   ok=no
356 else
357   if test "$cross_compiling" = "yes"; then
358     AC_MSG_WARN([GPGSM version can not be checked when cross compiling])
359     ok=no
360   else
361     if test ! -x "$GPGSM"; then
362       AC_MSG_WARN([GPGSM not executable, version check disabled])
363       ok=no
364     fi
365   fi
366 fi
367 if test "$ok" = "maybe"; then
368   AC_MSG_CHECKING(for GPGSM >= $NEED_GPGSM_VERSION)
369   req_major=`echo $NEED_GPGSM_VERSION | \
370              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
371   req_minor=`echo $NEED_GPGSM_VERSION | \
372              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
373   req_micro=`echo $NEED_GPGSM_VERSION | \
374              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
375   gpgsm_version=`$GPGSM --version | grep ^gpgsm`
376   major=`echo $gpgsm_version | \
377          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
378   minor=`echo $gpgsm_version | \
379          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
380   micro=`echo $gpgsm_version | \
381          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
382   GPGSM_VERSION=`echo $gpgsm_version | sed 's/^gpgsm (GnuPG) //'`
383
384   if test "$major" -gt "$req_major"; then
385     ok=yes
386   else
387     if test "$major" -eq "$req_major"; then
388       if test "$minor" -gt "$req_minor"; then
389         ok=yes
390       else
391         if test "$minor" -eq "$req_minor"; then
392           if test "$micro" -ge "$req_micro"; then
393             ok=yes
394           fi
395         fi
396       fi
397     fi
398   fi
399   if test "$ok" = "yes"; then
400     AC_MSG_RESULT(yes)
401   else
402     AC_MSG_RESULT(no)
403     AC_MSG_WARN([GPGSM must be at least version $NEED_GPGSM_VERSION])
404   fi
405 fi
406 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$ok" = "yes")
407
408 # FIXME: Only build if supported.
409 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
410
411
412 # The assuan code uses funopen but it will also build without it.  So
413 # test for it.  Frankly, this is not required in gpgme, but thats the
414 # way we handle it in libassuan.
415 AC_CHECK_FUNCS(funopen)
416 if test $ac_cv_func_funopen != yes; then
417     # No funopen but we can implement that in terms of fopencookie.
418     AC_CHECK_FUNCS(fopencookie)
419     if test $ac_cv_func_fopencookie = yes; then
420         AC_LIBOBJ([funopen])
421     else
422         AC_MSG_WARN([
423 ***
424 *** No implementation of fopencookie or funopen available
425 ***])
426     fi
427 fi
428
429 # More assuan replacement functions.
430 AC_REPLACE_FUNCS(isascii)
431 AC_REPLACE_FUNCS(putc_unlocked)
432 AC_REPLACE_FUNCS(memrchr)
433
434 # More assuan checks.
435 AC_CHECK_HEADERS([sys/uio.h])
436
437 # End of assuan checks.
438
439 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
440
441 # Make the version number in gpgme/gpgme.h the same as the one here.
442 # (this is easier than to have a *.in file just for one substitution)
443 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
444
445 # Generate values for the DLL version info
446 if test "$have_w32_system" = yes; then
447     BUILD_TIMESTAMP=`date --iso-8601=minutes`
448     changequote(,)dnl 
449     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
450     changequote([,])dnl
451     case "$VERSION" in
452       *-cvs) BUILD_FILEVERSION="${BUILD_FILEVERSION}0" ;;
453       *-rc*) BUILD_FILEVERSION="${BUILD_FILEVERSION}1" ;;
454       *)     BUILD_FILEVERSION="${BUILD_FILEVERSION}2" ;;
455     esac
456 fi
457 AC_SUBST(BUILD_TIMESTAMP)
458 AC_SUBST(BUILD_FILEVERSION)
459
460 # Add a few constants to help porting to W32
461 AH_VERBATIM([SEPCONSTANTS],
462 [
463 /* Separators as used in file names and $PATH. Please note that the
464    string version must not contain more than one character because
465    the using code assumes strlen()==1 */
466 #ifdef HAVE_DOSISH_SYSTEM
467 #define DIRSEP_C '\\\\'
468 #define EXTSEP_C '.'
469 #define DIRSEP_S "\\\\"
470 #define EXTSEP_S "."
471 #define PATHSEP_C ';'
472 #define PATHSEP_S ";"
473 #else
474 #define DIRSEP_C '/'
475 #define EXTSEP_C '.'
476 #define DIRSEP_S "/"
477 #define EXTSEP_S "."
478 #define PATHSEP_C ':'
479 #define PATHSEP_S ":"
480 #endif
481 ])
482
483
484 # Substitution used for gpgme-config 
485 GPGME_CONFIG_LIBS="-lgpgme"
486 GPGME_CONFIG_CFLAGS=""
487 AC_SUBST(GPGME_CONFIG_API_VERSION)
488 AC_SUBST(GPGME_CONFIG_LIBS)
489 AC_SUBST(GPGME_CONFIG_CFLAGS)
490
491 # Frob'da Variables
492 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
493            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
494 AC_SUBST(LTLIBOBJS)
495
496 #
497 # Create config files 
498
499 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
500                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
501                 doc/Makefile complus/Makefile
502                 gpgme/versioninfo.rc)
503 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
504 AC_OUTPUT
505
506 echo "
507         GPGME v${VERSION} has been configured as follows:
508
509         GnuPG path:    $GPG
510         GnuPG version: $GPG_VERSION, min. $NEED_GPG_VERSION
511
512         GpgSM path:    $GPGSM
513         GpgSM version: $GPGSM_VERSION, min. $NEED_GPGSM_VERSION
514
515         GPGME Pthread: $have_pthread
516         GPGME Pth:     $have_pth
517 "