Cpp: Handle PINENTRY_LAUNCHED status line
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=6
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=0
67
68 LIBQGPGME_LT_CURRENT=6
69 LIBQGPGME_LT_AGE=0
70 LIBQGPGME_LT_REVISION=0
71
72 # If the API is changed in an incompatible way: increment the next counter.
73 GPGME_CONFIG_API_VERSION=1
74 ##############################################
75
76 NEED_GPG_ERROR_VERSION=1.11
77 NEED_LIBASSUAN_API=2
78 NEED_LIBASSUAN_VERSION=2.0.2
79
80
81 PACKAGE=$PACKAGE_NAME
82 VERSION=$PACKAGE_VERSION
83
84 AC_CONFIG_AUX_DIR([build-aux])
85 AC_CONFIG_MACRO_DIR([m4])
86 AC_CONFIG_SRCDIR(src/gpgme.h.in)
87 AC_CONFIG_HEADER(config.h)
88 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
89 AM_MAINTAINER_MODE
90 AC_CANONICAL_HOST
91 AM_SILENT_RULES
92 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
93
94 # Enable GNU extensions on systems that have them.
95 AC_GNU_SOURCE
96
97 AH_VERBATIM([_REENTRANT],
98 [/* To allow the use of GPGME in multithreaded programs we have to use
99   special features from the library.
100   IMPORTANT: gpgme is not yet fully reentrant and you should use it
101   only from one thread.  */
102 #ifndef _REENTRANT
103 # define _REENTRANT 1
104 #endif])
105
106 AC_PROG_CC
107 AC_PROG_CXX
108
109 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
110 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
111
112 AC_SUBST(LIBGPGME_LT_CURRENT)
113 AC_SUBST(LIBGPGME_LT_AGE)
114 AC_SUBST(LIBGPGME_LT_REVISION)
115 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
116 AC_SUBST(LIBGPGMEPP_LT_AGE)
117 AC_SUBST(LIBGPGMEPP_LT_REVISION)
118 AC_SUBST(LIBQGPGME_LT_CURRENT)
119 AC_SUBST(LIBQGPGME_LT_AGE)
120 AC_SUBST(LIBQGPGME_LT_REVISION)
121
122 AC_SUBST(PACKAGE)
123 AC_SUBST(VERSION)
124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
125 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
126 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
127                           mym4_version_minor mym4_version_micro)
128 AC_SUBST(VERSION_NUMBER)
129
130 # Don't default to build static libs.
131 LT_PREREQ([2.2.6])
132 LT_INIT([win32-dll disable-static])
133 LT_LANG([Windows Resource])
134
135 # For now we hardcode the use of version scripts.  It would be better
136 # to write a test for this or even implement this within libtool.
137 have_ld_version_script=no
138 case "${host}" in
139     *-*-linux*)
140         have_ld_version_script=yes
141         ;;
142     *-*-gnu*)
143         have_ld_version_script=yes
144         ;;
145     *-apple-darwin*)
146         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
147         ;;
148 esac
149
150 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
151
152 GPG_DEFAULT=no
153 GPGSM_DEFAULT=no
154 GPGCONF_DEFAULT=no
155 G13_DEFAULT=no
156 component_system=None
157 have_dosish_system=no
158 have_android_system=no
159 have_w32_system=no
160 have_w64_system=no
161 build_w32_glib=no
162 build_w32_qt=no
163 available_languages="cpp cl qt"
164 default_languages="cpp cl qt"
165 case "${host}" in
166     x86_64-*mingw32*)
167         have_w64_system=yes
168         ;;
169     *-mingw32ce*)
170         have_w32ce_system=yes
171         ;;
172     *-linux-androideabi)
173         have_android_system=yes
174         ;;
175 esac
176 case "${host}" in
177     *-mingw32ce*|*-mingw32*)
178         have_dosish_system=yes
179         have_w32_system=yes
180         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
181         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
182         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
183         G13_DEFAULT='c:\\gnupg\\g13.exe'
184         #component_system='COM+'
185
186         AM_PATH_GLIB_2_0
187         AC_ARG_ENABLE(w32-glib,
188             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
189                            build_w32_glib=$enableval)
190        ;;
191     *)
192
193         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
194         if test "$have_pthread" = yes; then
195           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
196         fi
197
198         # XXX: Probably use exec-prefix here?
199 #       GPG_DEFAULT='/usr/bin/gpg'
200 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
201 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
202 #       G13_DEFAULT='/usr/bin/g13'
203         ;;
204 esac
205
206 if test "$have_dosish_system" = yes; then
207    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
208              [Defined if we run on some of the PCDOS like systems
209               (DOS, Windoze. OS/2) with special properties like
210               no file modes])
211 fi
212 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
213
214 if test "$have_w32_system" = yes; then
215    AC_DEFINE(HAVE_W32_SYSTEM,1,
216              [Defined if we run on any kind of W32 API based system])
217 fi
218 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
219
220 if test "$have_w64_system" = yes; then
221    AC_DEFINE(HAVE_W64_SYSTEM,1,
222              [Defined if we run on a 64 bit W32 API based system])
223 fi
224 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
225
226 if test "$have_w32ce_system" = yes; then
227    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
228              [Defined if we run on a W32 CE API based system])
229 fi
230 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
231
232 if test "$have_android_system" = yes; then
233    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
234 fi
235 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
236
237 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
238
239 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
240
241
242 AC_ARG_ENABLE([fixed-path],
243               AC_HELP_STRING([--enable-fixed-path=PATH],
244                              [locate binaries only via this PATH]),
245               [fixed_search_path="$enableval"],
246               [fixed_search_path=""])
247 if test x$fixed_search_path != x ; then
248   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
249                     [Locate binaries only via this PATH])
250 fi
251
252 AC_ARG_ENABLE([languages],
253               AC_HELP_STRING([--enable-languages=languages],
254                              [enable only specific language bindings]),
255                              [enabled_languages=`echo $enableval | \
256                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
257                              sed 's/c++/cpp/'`],
258                              [enabled_languages="$default_languages"])
259 if test "x$enabled_languages" = "x" \
260    -o "$enabled_languages" = "no"; then
261    enabled_languages=
262 fi
263 for language in $enabled_languages; do
264     LIST_MEMBER($language, $available_languages)
265     if test "$found" = "0"; then
266        AC_MSG_ERROR([unsupported language binding specified])
267     fi
268 done
269 # Enable C++ 11 if cpp language is requested
270 LIST_MEMBER("cpp", $enabled_languages)
271 if test "$found" = "1"; then
272     AX_CXX_COMPILE_STDCXX(11, noext, optional)
273 fi
274
275 # Check that if qt is enabled cpp also is enabled
276 LIST_MEMBER("qt", $enabled_languages)
277 if test "$found" = "1"; then
278    LIST_MEMBER("cpp", $enabled_languages)
279    if test "$found" = "0"; then
280       AC_MSG_ERROR([qt binding depends on cpp language binding])
281    fi
282    FIND_QT
283    if test "$have_qt5_libs" != "yes"; then
284        AC_MSG_ERROR([[
285    ***
286    *** Qt5 (Qt5Core) is required for qt binding.
287    ***]])
288    fi
289
290    AC_CHECK_PROGS([DOXYGEN], [doxygen])
291    if test -z "$DOXYGEN";
292        then AC_MSG_WARN([Doxygen not found - Qt binding doc will not be built.])
293    fi
294    # Make sure that qt comes after cpp
295    enabled_languages=`echo $enabled_languages | sed 's/qt//'`
296    enabled_languages=`echo $enabled_languages qt`
297 fi
298 AM_CONDITIONAL([HAVE_DOXYGEN],
299                [test -n "$DOXYGEN"])
300
301 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
302
303 #
304 # Provide information about the build.
305 #
306 BUILD_REVISION="mym4_revision"
307 AC_SUBST(BUILD_REVISION)
308 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
309                    [GIT commit id revision used to build this package])
310
311 changequote(,)dnl
312 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
313 changequote([,])dnl
314 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
315 AC_SUBST(BUILD_FILEVERSION)
316
317 AC_ARG_ENABLE([build-timestamp],
318   AC_HELP_STRING([--enable-build-timestamp],
319                  [set an explicit build timestamp for reproducibility.
320                   (default is the current time in ISO-8601 format)]),
321      [if test "$enableval" = "yes"; then
322         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
323       else
324         BUILD_TIMESTAMP="$enableval"
325       fi],
326      [BUILD_TIMESTAMP="<none>"])
327 AC_SUBST(BUILD_TIMESTAMP)
328 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
329                    [The time this package was configured for a build])
330
331
332 #
333 # Options to disable some regression tests
334 #
335 run_gpgconf_test="yes"
336 AC_ARG_ENABLE(gpgconf-test,
337   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
338          run_gpgconf_test=$enableval)
339 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
340
341 run_gpg_test="yes"
342 AC_ARG_ENABLE(gpg-test,
343   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
344          run_gpg_test=$enableval)
345 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
346
347 run_gpgsm_test="yes"
348 AC_ARG_ENABLE(gpgsm-test,
349   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
350          run_gpgsm_test=$enableval)
351 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
352
353 run_g13_test="yes"
354 AC_ARG_ENABLE(g13-test,
355   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
356          run_g13_test=$enableval)
357 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
358
359
360 # Checks for header files.
361 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
362                        unistd.h sys/time.h sys/types.h sys/stat.h])
363
364
365 # Type checks.
366 AC_C_INLINE
367 AC_CHECK_SIZEOF(unsigned int)
368 AC_SYS_LARGEFILE
369 AC_TYPE_OFF_T
370 AC_TYPE_UINTPTR_T
371
372 # A simple compile time check in gpgme.h for GNU/Linux systems that
373 # prevents a file offset bits mismatch between gpgme and the application.
374 NEED__FILE_OFFSET_BITS=0
375 if test "$have_w32_system" != yes; then
376   case "$ac_cv_sys_file_offset_bits" in
377     "" | no | unknown) ;;
378     *)
379     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
380     ;;
381   esac
382 fi
383 AC_SUBST(NEED__FILE_OFFSET_BITS)
384
385 # Figure out platform dependent typedefs for gpgme.h
386 if test "$have_w32_system" = yes; then
387     INSERT__TYPEDEFS_FOR_GPGME_H="
388 #ifdef _WIN64
389 # include <stdint.h>
390   typedef int64_t gpgme_off_t;
391   typedef int64_t gpgme_ssize_t;
392 #else /* _WIN32 */
393   typedef long gpgme_off_t;
394   typedef long gpgme_ssize_t;
395 #endif /* _WIN32 */"
396     API__OFF_T="gpgme_off_t"
397     API__SSIZE_T="gpgme_ssize_t"
398 else
399     INSERT__TYPEDEFS_FOR_GPGME_H="
400 #include <sys/types.h>
401 typedef off_t   gpgme_off_t;
402 typedef ssize_t gpgme_ssize_t;"
403     API__OFF_T="off_t"
404     API__SSIZE_T="ssize_t"
405 fi
406 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
407 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
408 AC_SUBST(API__OFF_T)
409 AM_SUBST_NOTMAKE(API__OFF_T)
410 AC_SUBST(API__SSIZE_T)
411 AM_SUBST_NOTMAKE(API__SSIZE_T)
412
413 # Checks for compiler features.
414 if test "$GCC" = yes; then
415     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
416     if test "$have_w32_system" = yes; then
417        CFLAGS="$CFLAGS -mms-bitfields"
418     fi
419 fi
420
421 # Only used for debugging, so no serious test needed (for actual
422 # functionality you have to test libc as well, this only tests the
423 # compiler).
424 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
425    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
426                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
427 if test "$gpgme_cv_tls_works" = yes; then
428   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
429 fi
430
431
432 # Checks for library functions.
433 AC_MSG_NOTICE([checking for libraries])
434
435 AC_FUNC_FSEEKO
436
437 AC_REPLACE_FUNCS(vasprintf)
438 if test "$ac_cv_func_vasprintf" != yes; then
439   GNUPG_CHECK_VA_COPY
440 fi
441
442 # Try to find a thread-safe version of ttyname().
443 gnupg_REPLACE_TTYNAME_R
444 if test "$ac_cv_func_ttyname_r" != yes; then
445   AC_MSG_WARN([
446 ***
447 *** ttyname() is not thread-safe and ttyname_r() does not exist
448 ***])
449 fi
450
451 # Try to find a thread-safe version of getenv().
452 have_thread_safe_getenv=no
453 jm_GLIBC21
454 if test $GLIBC21 = yes; then
455   have_thread_safe_getenv=yes
456 fi
457 if test $have_thread_safe_getenv = yes; then
458   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
459 fi
460 have_getenv_r=no
461 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
462 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
463   AC_MSG_WARN([
464 ***
465 *** getenv() is not thread-safe and getenv_r() does not exist
466 ***])
467 fi
468
469 # For converting time strings to seconds since Epoch, we need the timegm
470 # function.
471 AC_CHECK_FUNCS(timegm)
472 if test "$ac_cv_func_timegm" != yes; then
473   AC_MSG_WARN([
474 ***
475 *** timegm() not available - a non-thread-safe kludge will be used
476 *** and the TZ variable might be changed at runtime.
477 ***])
478 fi
479
480 AC_CHECK_FUNCS(setlocale)
481
482 # Checking for libgpg-error.
483 have_gpg_error=no
484 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
485                   have_gpg_error=yes, have_gpg_error=no)
486 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
487           [The default error source for GPGME.])
488
489 # And for libassuan.
490 have_libassuan=no
491 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
492                   have_libassuan=yes, have_libassuan=no)
493 if test "$have_libassuan" = "yes"; then
494   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
495                      [version of the libassuan library])
496 fi
497
498
499 #
500 # Other checks
501 #
502
503 # Check for funopen
504 AC_CHECK_FUNCS(funopen)
505 if test $ac_cv_func_funopen != yes; then
506     # No funopen but we can implement that in terms of fopencookie.
507     AC_CHECK_FUNCS(fopencookie)
508     if test $ac_cv_func_fopencookie = yes; then
509         AC_REPLACE_FUNCS(funopen)
510     else
511         AC_MSG_WARN([
512 ***
513 *** No implementation of fopencookie or funopen available
514 ***])
515     fi
516 fi
517
518 # Check for getgid etc
519 AC_CHECK_FUNCS(getgid getegid)
520
521
522 # Replacement functions.
523 AC_REPLACE_FUNCS(stpcpy)
524 AC_REPLACE_FUNCS(setenv)
525
526 # Assuan check for descriptor passing.
527 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
528                 [supports_descriptor_passing=yes],
529                 [supports_descriptor_passing=no
530                  AC_MSG_WARN([
531 ***
532 *** Data structure for sending ancillary data missing.
533 *** Descriptor passing won't work.
534 ***])],[
535 #include <stdlib.h>
536 #include <stddef.h>
537 #include <stdio.h>
538 #include <sys/types.h>
539 #include <sys/socket.h>
540 #include <sys/un.h>
541 #if HAVE_SYS_UIO_H
542 #include <sys/uio.h>
543 #endif
544 #include <unistd.h>
545        ])
546
547
548 dnl There seems to be a problem with Apple and decriptor passing.
549 dnl Until we found a solution we change the default to no.
550 dnl See bug 1483.
551 case "${host}" in
552     *-apple-darwin*)
553       use_descriptor_passing=no
554       ;;
555     *)
556       use_descriptor_passing=yes
557       ;;
558 esac
559 AC_ARG_ENABLE(fd-passing,
560   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
561   use_descriptor_passing=$enableval)
562
563 if test "$supports_descriptor_passing" != "yes"; then
564   use_descriptor_passing=no
565 fi
566
567 if test "$use_descriptor_passing" = "yes"; then
568 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
569           [Defined if descriptor passing is enabled and supported])
570 fi
571
572 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
573
574
575 uiserver=no
576 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
577   uiserver=yes
578 fi
579 if test "$uiserver" != "no"; then
580   AC_DEFINE(ENABLE_UISERVER, 1,
581             [Defined if we are building with uiserver support.])
582 fi
583 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
584
585
586 # Add a few constants to help porting to W32
587 AH_VERBATIM([SEPCONSTANTS],
588 [
589 /* Separators as used in $PATH and file name.  */
590 #ifdef HAVE_DOSISH_SYSTEM
591 #define PATHSEP_C ';'
592 #define DIRSEP_C '\\'
593 #define DIRSEP_S "\\"
594 #else
595 #define PATHSEP_C ':'
596 #define DIRSEP_C '/'
597 #define DIRSEP_S "/"
598 #endif
599 ])
600
601 AH_BOTTOM([
602 /* Definition of GCC specific attributes.  */
603 #if __GNUC__ > 2
604 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
605 #else
606 # define GPGME_GCC_A_PURE
607 #endif
608
609 /* Under WindowsCE we need gpg-error's strerror macro.  */
610 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
611
612 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
613                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
614 ])
615
616
617 # Substitution used for gpgme-config
618 GPGME_CONFIG_LIBS="-lgpgme"
619 GPGME_CONFIG_CFLAGS=""
620 GPGME_CONFIG_HOST="$host"
621 AC_SUBST(GPGME_CONFIG_API_VERSION)
622 AC_SUBST(GPGME_CONFIG_LIBS)
623 AC_SUBST(GPGME_CONFIG_CFLAGS)
624 AC_SUBST(GPGME_CONFIG_HOST)
625
626 # Frob'da Variables
627 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
628            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
629 AC_SUBST(LTLIBOBJS)
630
631 # Some checks for gpgme-tool
632 # Done at top: AC_CHECK_HEADER([argp.h])
633 AC_CHECK_TYPES([error_t], [],
634    [AC_DEFINE([error_t], [int],
635    [Define to a type to use for `error_t' if it is not otherwise available.])],
636    [#include <errno.h>])
637
638
639 # A substitution to set generated files in a Emacs buffer to read-only.
640 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
641 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
642 AC_SUBST(emacs_local_vars_end, ['End:'])
643
644
645 # Last check.
646 die=no
647 if test "$have_gpg_error" = "no"; then
648    die=yes
649    AC_MSG_NOTICE([[
650 ***
651 *** You need libgpg-error to build this program.
652 **  This library is for example available at
653 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
654 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
655 ***]])
656 fi
657 if test "$have_libassuan" = "no"; then
658    die=yes
659    AC_MSG_NOTICE([[
660 ***
661 *** You need libassuan to build this program.
662 *** This library is for example available at
663 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
664 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
665 ***]])
666 fi
667
668 if test "$die" = "yes"; then
669     AC_MSG_ERROR([[
670 ***
671 *** Required libraries not found. Please consult the above messages
672 *** and install them before running configure again.
673 ***]])
674 fi
675
676
677 #
678 # Create config files
679
680 AC_CONFIG_FILES(Makefile src/Makefile
681                 tests/Makefile
682                 tests/gpg/Makefile
683                 tests/gpgsm/Makefile
684                 tests/opassuan/Makefile
685                 doc/Makefile
686                 src/versioninfo.rc
687                 src/gpgme.h)
688 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
689 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
690 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
691 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
692 AC_CONFIG_FILES(lang/qt/Makefile lang/qt/src/Makefile)
693 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfig.cmake.in)
694 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfigVersion.cmake)
695 AC_CONFIG_FILES(lang/qt/tests/Makefile)
696 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
697 AM_COND_IF([HAVE_DOXYGEN], [AC_CONFIG_FILES([lang/qt/doc/Doxyfile])])
698 AC_CONFIG_FILES(lang/qt/doc/Makefile)
699 AC_OUTPUT
700
701 echo "
702         GPGME v${VERSION} has been configured as follows:
703
704         Revision:          mym4_revision  (mym4_revision_dec)
705         Platform:          $host
706
707         UI Server:         $uiserver
708         FD Passing:        $use_descriptor_passing
709         GPGME Pthread:     $have_pthread
710
711         Language bindings: $enabled_languages
712 "
713 if test "x${gpg_config_script_warn}" != x; then
714 cat <<G10EOF
715         Mismatches between the target platform and the to
716         be used libraries have been been detected for:
717          ${gpg_config_script_warn}
718         Please check above for warning messages.
719
720 G10EOF
721 fi