Qt / Cpp: Fix make dist
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=6
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=0
67
68 LIBQGPGME_LT_CURRENT=6
69 LIBQGPGME_LT_AGE=0
70 LIBQGPGME_LT_REVISION=0
71
72 # If the API is changed in an incompatible way: increment the next counter.
73 GPGME_CONFIG_API_VERSION=1
74 ##############################################
75
76 NEED_GPG_ERROR_VERSION=1.11
77 NEED_LIBASSUAN_API=2
78 NEED_LIBASSUAN_VERSION=2.0.2
79
80
81 PACKAGE=$PACKAGE_NAME
82 VERSION=$PACKAGE_VERSION
83
84 AC_CONFIG_AUX_DIR([build-aux])
85 AC_CONFIG_MACRO_DIR([m4])
86 AC_CONFIG_SRCDIR(src/gpgme.h.in)
87 AC_CONFIG_HEADER(config.h)
88 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
89 AM_MAINTAINER_MODE
90 AC_CANONICAL_HOST
91 AM_SILENT_RULES
92 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
93
94 # Enable GNU extensions on systems that have them.
95 AC_GNU_SOURCE
96
97 AH_VERBATIM([_REENTRANT],
98 [/* To allow the use of GPGME in multithreaded programs we have to use
99   special features from the library.
100   IMPORTANT: gpgme is not yet fully reentrant and you should use it
101   only from one thread.  */
102 #ifndef _REENTRANT
103 # define _REENTRANT 1
104 #endif])
105
106 AC_PROG_CC
107 AC_PROG_CXX
108
109 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
110 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
111
112 AC_SUBST(LIBGPGME_LT_CURRENT)
113 AC_SUBST(LIBGPGME_LT_AGE)
114 AC_SUBST(LIBGPGME_LT_REVISION)
115 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
116 AC_SUBST(LIBGPGMEPP_LT_AGE)
117 AC_SUBST(LIBGPGMEPP_LT_REVISION)
118 AC_SUBST(LIBQGPGME_LT_CURRENT)
119 AC_SUBST(LIBQGPGME_LT_AGE)
120 AC_SUBST(LIBQGPGME_LT_REVISION)
121
122 AC_SUBST(PACKAGE)
123 AC_SUBST(VERSION)
124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
125 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
126 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
127                           mym4_version_minor mym4_version_micro)
128 AC_SUBST(VERSION_NUMBER)
129
130 # Don't default to build static libs.
131 LT_PREREQ([2.2.6])
132 LT_INIT([win32-dll disable-static])
133 LT_LANG([Windows Resource])
134
135 # For now we hardcode the use of version scripts.  It would be better
136 # to write a test for this or even implement this within libtool.
137 have_ld_version_script=no
138 case "${host}" in
139     *-*-linux*)
140         have_ld_version_script=yes
141         ;;
142     *-*-gnu*)
143         have_ld_version_script=yes
144         ;;
145     *-apple-darwin*)
146         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
147         ;;
148 esac
149
150 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
151
152 GPG_DEFAULT=no
153 GPGSM_DEFAULT=no
154 GPGCONF_DEFAULT=no
155 G13_DEFAULT=no
156 component_system=None
157 have_dosish_system=no
158 have_android_system=no
159 have_w32_system=no
160 have_w64_system=no
161 build_w32_glib=no
162 build_w32_qt=no
163 available_languages="cpp cl qt"
164 default_languages="cpp cl qt"
165 case "${host}" in
166     x86_64-*mingw32*)
167         have_w64_system=yes
168         ;;
169     *-mingw32ce*)
170         have_w32ce_system=yes
171         ;;
172     *-linux-androideabi)
173         have_android_system=yes
174         ;;
175 esac
176 case "${host}" in
177     *-mingw32ce*|*-mingw32*)
178         have_dosish_system=yes
179         have_w32_system=yes
180         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
181         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
182         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
183         G13_DEFAULT='c:\\gnupg\\g13.exe'
184         #component_system='COM+'
185
186         AM_PATH_GLIB_2_0
187         AC_ARG_ENABLE(w32-glib,
188             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
189                            build_w32_glib=$enableval)
190        ;;
191     *)
192
193         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
194         if test "$have_pthread" = yes; then
195           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
196         fi
197
198         # XXX: Probably use exec-prefix here?
199 #       GPG_DEFAULT='/usr/bin/gpg'
200 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
201 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
202 #       G13_DEFAULT='/usr/bin/g13'
203         ;;
204 esac
205
206 if test "$have_dosish_system" = yes; then
207    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
208              [Defined if we run on some of the PCDOS like systems
209               (DOS, Windoze. OS/2) with special properties like
210               no file modes])
211 fi
212 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
213
214 if test "$have_w32_system" = yes; then
215    AC_DEFINE(HAVE_W32_SYSTEM,1,
216              [Defined if we run on any kind of W32 API based system])
217 fi
218 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
219
220 if test "$have_w64_system" = yes; then
221    AC_DEFINE(HAVE_W64_SYSTEM,1,
222              [Defined if we run on a 64 bit W32 API based system])
223 fi
224 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
225
226 if test "$have_w32ce_system" = yes; then
227    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
228              [Defined if we run on a W32 CE API based system])
229 fi
230 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
231
232 if test "$have_android_system" = yes; then
233    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
234 fi
235 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
236
237 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
238
239 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
240
241
242 AC_ARG_ENABLE([fixed-path],
243               AC_HELP_STRING([--enable-fixed-path=PATH],
244                              [locate binaries only via this PATH]),
245               [fixed_search_path="$enableval"],
246               [fixed_search_path=""])
247 if test x$fixed_search_path != x ; then
248   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
249                     [Locate binaries only via this PATH])
250 fi
251
252 AC_ARG_ENABLE([languages],
253               AC_HELP_STRING([--enable-languages=languages],
254                              [enable only specific language bindings]),
255                              [enabled_languages=`echo $enableval | \
256                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
257                              sed 's/c++/cpp/'`],
258                              [enabled_languages="maybe"])
259 if test "x$enabled_languages" = "x" \
260    -o "$enabled_languages" = "no"; then
261    enabled_languages=
262 fi
263
264 # If languages are explicitly set missing requirements
265 # for the languages are treated as errors otherwise
266 # there will be a warning.
267 explicit_languages=1
268 if test "x$enabled_languages" = "xmaybe"; then
269     explicit_languages=0
270     enabled_languages="$default_languages"
271 fi
272
273 for language in $enabled_languages; do
274     LIST_MEMBER($language, $available_languages)
275     if test "$found" = "0"; then
276        AC_MSG_ERROR([unsupported language binding specified])
277     fi
278 done
279
280
281
282 # Enable C++ 11 if cpp language is requested
283 LIST_MEMBER("cpp", $enabled_languages)
284 if test "$found" = "1"; then
285     AX_CXX_COMPILE_STDCXX(11, noext, optional)
286     if test "$HAVE_CXX11" != "1"; then
287         if test "$explicit_languages" = "1"; then
288             AC_MSG_ERROR([[
289 ***
290 *** A compiler with c++11 support is required for the c++ binding.
291 ***]])
292         else
293             enabled_languages=$(echo $enabled_languages | sed 's/cpp//')
294             enabled_languages=$(echo $enabled_languages | sed 's/qt//')
295             AC_MSG_WARN([[
296 ***
297 *** No c++11 support detected. C++ and Qt bindings will be disabled.
298 ***]])
299         fi
300     fi
301 fi
302
303 # Check that if qt is enabled cpp also is enabled
304 LIST_MEMBER("qt", $enabled_languages)
305 if test "$found" = "1"; then
306     # We need to ensure that in the langauge order qt comes after cpp
307     # so we remove qt first and explicitly add it as last list member.
308     enabled_languages=$(echo $enabled_languages | sed 's/qt//')
309     LIST_MEMBER("cpp", $enabled_languages)
310     if test "$found" = "0"; then
311         AC_MSG_ERROR([[
312 ***
313 *** Qt language binding depends on cpp binding.
314 ***]])
315     fi
316     FIND_QT
317     if test "$have_qt5_libs" != "yes"; then
318         if test "$explicit_languages" = "1"; then
319         AC_MSG_ERROR([[
320 ***
321 *** Qt5 (Qt5Core) is required for Qt binding.
322 ***]])
323         else
324            AC_MSG_WARN([[
325 ***
326 *** Qt5 (Qt5Core) not found Qt Binding will be disabled.
327 ***]])
328         fi
329     else
330         enabled_languages=`echo $enabled_languages qt`
331
332         AC_CHECK_PROGS([DOXYGEN], [doxygen])
333         if test -z "$DOXYGEN";
334             # This is not highlighted becase it's not really important.
335             then AC_MSG_WARN([Doxygen not found - Qt binding doc will not be built.])
336         fi
337     fi
338 fi
339 AM_CONDITIONAL([HAVE_DOXYGEN],
340                [test -n "$DOXYGEN"])
341
342 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
343
344 #
345 # Provide information about the build.
346 #
347 BUILD_REVISION="mym4_revision"
348 AC_SUBST(BUILD_REVISION)
349 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
350                    [GIT commit id revision used to build this package])
351
352 changequote(,)dnl
353 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
354 changequote([,])dnl
355 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
356 AC_SUBST(BUILD_FILEVERSION)
357
358 AC_ARG_ENABLE([build-timestamp],
359   AC_HELP_STRING([--enable-build-timestamp],
360                  [set an explicit build timestamp for reproducibility.
361                   (default is the current time in ISO-8601 format)]),
362      [if test "$enableval" = "yes"; then
363         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
364       else
365         BUILD_TIMESTAMP="$enableval"
366       fi],
367      [BUILD_TIMESTAMP="<none>"])
368 AC_SUBST(BUILD_TIMESTAMP)
369 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
370                    [The time this package was configured for a build])
371
372
373 #
374 # Options to disable some regression tests
375 #
376 run_gpgconf_test="yes"
377 AC_ARG_ENABLE(gpgconf-test,
378   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
379          run_gpgconf_test=$enableval)
380 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
381
382 run_gpg_test="yes"
383 AC_ARG_ENABLE(gpg-test,
384   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
385          run_gpg_test=$enableval)
386 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
387
388 run_gpgsm_test="yes"
389 AC_ARG_ENABLE(gpgsm-test,
390   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
391          run_gpgsm_test=$enableval)
392 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
393
394 run_g13_test="yes"
395 AC_ARG_ENABLE(g13-test,
396   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
397          run_g13_test=$enableval)
398 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
399
400
401 # Checks for header files.
402 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
403                        unistd.h sys/time.h sys/types.h sys/stat.h])
404
405
406 # Type checks.
407 AC_C_INLINE
408 AC_CHECK_SIZEOF(unsigned int)
409 AC_SYS_LARGEFILE
410 AC_TYPE_OFF_T
411 AC_TYPE_UINTPTR_T
412
413 # A simple compile time check in gpgme.h for GNU/Linux systems that
414 # prevents a file offset bits mismatch between gpgme and the application.
415 NEED__FILE_OFFSET_BITS=0
416 if test "$have_w32_system" != yes; then
417   case "$ac_cv_sys_file_offset_bits" in
418     "" | no | unknown) ;;
419     *)
420     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
421     ;;
422   esac
423 fi
424 AC_SUBST(NEED__FILE_OFFSET_BITS)
425
426 # Figure out platform dependent typedefs for gpgme.h
427 if test "$have_w32_system" = yes; then
428     INSERT__TYPEDEFS_FOR_GPGME_H="
429 #ifdef _WIN64
430 # include <stdint.h>
431   typedef int64_t gpgme_off_t;
432   typedef int64_t gpgme_ssize_t;
433 #else /* _WIN32 */
434   typedef long gpgme_off_t;
435   typedef long gpgme_ssize_t;
436 #endif /* _WIN32 */"
437     API__OFF_T="gpgme_off_t"
438     API__SSIZE_T="gpgme_ssize_t"
439 else
440     INSERT__TYPEDEFS_FOR_GPGME_H="
441 #include <sys/types.h>
442 typedef off_t   gpgme_off_t;
443 typedef ssize_t gpgme_ssize_t;"
444     API__OFF_T="off_t"
445     API__SSIZE_T="ssize_t"
446 fi
447 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
448 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
449 AC_SUBST(API__OFF_T)
450 AM_SUBST_NOTMAKE(API__OFF_T)
451 AC_SUBST(API__SSIZE_T)
452 AM_SUBST_NOTMAKE(API__SSIZE_T)
453
454 # Checks for compiler features.
455 if test "$GCC" = yes; then
456     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
457     if test "$have_w32_system" = yes; then
458        CFLAGS="$CFLAGS -mms-bitfields"
459     fi
460 fi
461
462 # Only used for debugging, so no serious test needed (for actual
463 # functionality you have to test libc as well, this only tests the
464 # compiler).
465 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
466    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
467                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
468 if test "$gpgme_cv_tls_works" = yes; then
469   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
470 fi
471
472
473 # Checks for library functions.
474 AC_MSG_NOTICE([checking for libraries])
475
476 AC_FUNC_FSEEKO
477
478 AC_REPLACE_FUNCS(vasprintf)
479 if test "$ac_cv_func_vasprintf" != yes; then
480   GNUPG_CHECK_VA_COPY
481 fi
482
483 # Try to find a thread-safe version of ttyname().
484 gnupg_REPLACE_TTYNAME_R
485 if test "$ac_cv_func_ttyname_r" != yes; then
486   AC_MSG_WARN([
487 ***
488 *** ttyname() is not thread-safe and ttyname_r() does not exist
489 ***])
490 fi
491
492 # Try to find a thread-safe version of getenv().
493 have_thread_safe_getenv=no
494 jm_GLIBC21
495 if test $GLIBC21 = yes; then
496   have_thread_safe_getenv=yes
497 fi
498 if test $have_thread_safe_getenv = yes; then
499   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
500 fi
501 have_getenv_r=no
502 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
503 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
504   AC_MSG_WARN([
505 ***
506 *** getenv() is not thread-safe and getenv_r() does not exist
507 ***])
508 fi
509
510 # For converting time strings to seconds since Epoch, we need the timegm
511 # function.
512 AC_CHECK_FUNCS(timegm)
513 if test "$ac_cv_func_timegm" != yes; then
514   AC_MSG_WARN([
515 ***
516 *** timegm() not available - a non-thread-safe kludge will be used
517 *** and the TZ variable might be changed at runtime.
518 ***])
519 fi
520
521 AC_CHECK_FUNCS(setlocale)
522
523 # Checking for libgpg-error.
524 have_gpg_error=no
525 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
526                   have_gpg_error=yes, have_gpg_error=no)
527 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
528           [The default error source for GPGME.])
529
530 # And for libassuan.
531 have_libassuan=no
532 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
533                   have_libassuan=yes, have_libassuan=no)
534 if test "$have_libassuan" = "yes"; then
535   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
536                      [version of the libassuan library])
537 fi
538
539
540 #
541 # Other checks
542 #
543
544 # Check for funopen
545 AC_CHECK_FUNCS(funopen)
546 if test $ac_cv_func_funopen != yes; then
547     # No funopen but we can implement that in terms of fopencookie.
548     AC_CHECK_FUNCS(fopencookie)
549     if test $ac_cv_func_fopencookie = yes; then
550         AC_REPLACE_FUNCS(funopen)
551     else
552         AC_MSG_WARN([
553 ***
554 *** No implementation of fopencookie or funopen available
555 ***])
556     fi
557 fi
558
559 # Check for getgid etc
560 AC_CHECK_FUNCS(getgid getegid)
561
562
563 # Replacement functions.
564 AC_REPLACE_FUNCS(stpcpy)
565 AC_REPLACE_FUNCS(setenv)
566
567 # Assuan check for descriptor passing.
568 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
569                 [supports_descriptor_passing=yes],
570                 [supports_descriptor_passing=no
571                  AC_MSG_WARN([
572 ***
573 *** Data structure for sending ancillary data missing.
574 *** Descriptor passing won't work.
575 ***])],[
576 #include <stdlib.h>
577 #include <stddef.h>
578 #include <stdio.h>
579 #include <sys/types.h>
580 #include <sys/socket.h>
581 #include <sys/un.h>
582 #if HAVE_SYS_UIO_H
583 #include <sys/uio.h>
584 #endif
585 #include <unistd.h>
586        ])
587
588
589 dnl There seems to be a problem with Apple and decriptor passing.
590 dnl Until we found a solution we change the default to no.
591 dnl See bug 1483.
592 case "${host}" in
593     *-apple-darwin*)
594       use_descriptor_passing=no
595       ;;
596     *)
597       use_descriptor_passing=yes
598       ;;
599 esac
600 AC_ARG_ENABLE(fd-passing,
601   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
602   use_descriptor_passing=$enableval)
603
604 if test "$supports_descriptor_passing" != "yes"; then
605   use_descriptor_passing=no
606 fi
607
608 if test "$use_descriptor_passing" = "yes"; then
609 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
610           [Defined if descriptor passing is enabled and supported])
611 fi
612
613 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
614
615
616 uiserver=no
617 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
618   uiserver=yes
619 fi
620 if test "$uiserver" != "no"; then
621   AC_DEFINE(ENABLE_UISERVER, 1,
622             [Defined if we are building with uiserver support.])
623 fi
624 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
625
626
627 # Add a few constants to help porting to W32
628 AH_VERBATIM([SEPCONSTANTS],
629 [
630 /* Separators as used in $PATH and file name.  */
631 #ifdef HAVE_DOSISH_SYSTEM
632 #define PATHSEP_C ';'
633 #define DIRSEP_C '\\'
634 #define DIRSEP_S "\\"
635 #else
636 #define PATHSEP_C ':'
637 #define DIRSEP_C '/'
638 #define DIRSEP_S "/"
639 #endif
640 ])
641
642 AH_BOTTOM([
643 /* Definition of GCC specific attributes.  */
644 #if __GNUC__ > 2
645 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
646 #else
647 # define GPGME_GCC_A_PURE
648 #endif
649
650 /* Under WindowsCE we need gpg-error's strerror macro.  */
651 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
652
653 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
654                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
655 ])
656
657
658 # Substitution used for gpgme-config
659 GPGME_CONFIG_LIBS="-lgpgme"
660 GPGME_CONFIG_CFLAGS=""
661 GPGME_CONFIG_HOST="$host"
662 AC_SUBST(GPGME_CONFIG_API_VERSION)
663 AC_SUBST(GPGME_CONFIG_LIBS)
664 AC_SUBST(GPGME_CONFIG_CFLAGS)
665 AC_SUBST(GPGME_CONFIG_HOST)
666
667 # Frob'da Variables
668 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
669            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
670 AC_SUBST(LTLIBOBJS)
671
672 # Some checks for gpgme-tool
673 # Done at top: AC_CHECK_HEADER([argp.h])
674 AC_CHECK_TYPES([error_t], [],
675    [AC_DEFINE([error_t], [int],
676    [Define to a type to use for `error_t' if it is not otherwise available.])],
677    [#include <errno.h>])
678
679
680 # A substitution to set generated files in a Emacs buffer to read-only.
681 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
682 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
683 AC_SUBST(emacs_local_vars_end, ['End:'])
684
685
686 # Last check.
687 die=no
688 if test "$have_gpg_error" = "no"; then
689    die=yes
690    AC_MSG_NOTICE([[
691 ***
692 *** You need libgpg-error to build this program.
693 **  This library is for example available at
694 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
695 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
696 ***]])
697 fi
698 if test "$have_libassuan" = "no"; then
699    die=yes
700    AC_MSG_NOTICE([[
701 ***
702 *** You need libassuan to build this program.
703 *** This library is for example available at
704 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
705 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
706 ***]])
707 fi
708
709 if test "$die" = "yes"; then
710     AC_MSG_ERROR([[
711 ***
712 *** Required libraries not found. Please consult the above messages
713 *** and install them before running configure again.
714 ***]])
715 fi
716
717
718 #
719 # Create config files
720
721 AC_CONFIG_FILES(Makefile src/Makefile
722                 tests/Makefile
723                 tests/gpg/Makefile
724                 tests/gpgsm/Makefile
725                 tests/opassuan/Makefile
726                 doc/Makefile
727                 src/versioninfo.rc
728                 src/gpgme.h)
729 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
730 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
731 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
732 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
733 AC_CONFIG_FILES(lang/qt/Makefile lang/qt/src/Makefile)
734 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfig.cmake.in)
735 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfigVersion.cmake)
736 AC_CONFIG_FILES(lang/qt/tests/Makefile)
737 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
738 AM_COND_IF([HAVE_DOXYGEN], [AC_CONFIG_FILES([lang/qt/doc/Doxyfile])])
739 AC_CONFIG_FILES(lang/qt/doc/Makefile)
740 AC_OUTPUT
741
742 echo "
743         GPGME v${VERSION} has been configured as follows:
744
745         Revision:          mym4_revision  (mym4_revision_dec)
746         Platform:          $host
747
748         UI Server:         $uiserver
749         FD Passing:        $use_descriptor_passing
750         GPGME Pthread:     $have_pthread
751
752         Language bindings: $enabled_languages
753 "
754 if test "x${gpg_config_script_warn}" != x; then
755 cat <<G10EOF
756         Mismatches between the target platform and the to
757         be used libraries have been been detected for:
758          ${gpg_config_script_warn}
759         Please check above for warning messages.
760
761 G10EOF
762 fi