* ath.c: Include sys/time.h if sys/select.h is not available.
[gpgme.git] / configure.ac
1 # configure.in  for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22
23 # Version number: Remember to change it immediately *after* a release.
24 AC_INIT(gpgme, 0.3.11, [bug-gpgme@gnupg.org])
25 # LT Version numbers, remember to change them just *before* a release.
26 #   (Code changed:                      REVISION++)
27 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
28 #   (Interfaces added:                  AGE++)
29 #   (Interfaces removed:                AGE=0)
30 #
31 LIBGPGME_LT_CURRENT=9
32 LIBGPGME_LT_AGE=3
33 LIBGPGME_LT_REVISION=1
34 NEED_GPG_VERSION=1.0.7
35 NEED_GPGSM_VERSION=0.3.8
36 ##############################################
37 AC_PREREQ(2.52)
38 AC_REVISION($Revision$)
39
40 PACKAGE=$PACKAGE_NAME
41 VERSION=$PACKAGE_VERSION
42
43 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
44 AM_CONFIG_HEADER(config.h)
45 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
46 AM_MAINTAINER_MODE
47
48 AH_VERBATIM([_GNU_SOURCE],
49 [/* Enable GNU extensions on systems that have them.  */
50 #ifndef _GNU_SOURCE
51 # define _GNU_SOURCE
52 #endif])
53
54 AH_VERBATIM([_REENTRANT],
55 [/* To allow the use of GPGME in multithreaded programs we have to use
56   special features from the library.
57   IMPORTANT: gpgme is not yet fully reentrant and you should use it
58   only from one thread.  */
59 #ifndef _REENTRANT
60 # define _REENTRANT 1
61 #endif])
62
63
64 AC_PROG_CC
65
66
67 AC_SUBST(LIBGPGME_LT_CURRENT)
68 AC_SUBST(LIBGPGME_LT_AGE)
69 AC_SUBST(LIBGPGME_LT_REVISION)
70 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
71                                      [Min. needed GnuPG version.])
72 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
73                                        [Min. needed GPGSM version.])
74
75 AC_SUBST(PACKAGE)
76 AC_SUBST(VERSION)
77 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
78 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
79
80 dnl Don't default to build static libs.
81 dnl AC_DISABLE_STATIC
82 AC_PROG_LIBTOOL
83
84 GPG_DEFAULT=no
85 GPGSM_DEFAULT=no
86 component_system=None
87 case "${target}" in
88     *-*-mingw32* | i?86-emx-os2 | i?86-*-os2*emx | i?86-*-msdosdjgpp* )
89         # special stuff for Windoze NT
90         # OS/2 with the EMX environment
91         # DOS with the DJGPP environment
92         AC_DEFINE(HAVE_DRIVE_LETTERS, ,
93                   [Defined if we run on some of the PCDOS like systems (DOS,
94                    Windoze, OS/2) with special properties like no file modes.])
95         AC_DEFINE(HAVE_DOSISH_SYSTEM, ,
96                   [Defined if the filesystem uses driver letters.])
97         have_dosish_system=yes
98         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
99         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
100         #component_system='COM+'
101         ;;
102     *)
103         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
104         if test "$have_pth" = yes; then
105           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
106           CFLAGS="$CFLAGS $PTH_CFLAGS"
107         fi
108         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
109         if test "$have_pthread" = yes; then
110           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
111         fi
112
113 dnl     # XXX: Probably use exec-prefix here?
114 dnl     GPG_DEFAULT='/usr/bin/gpg'
115 dnl     GPGSM_DEFAULT='/usr/bin/gpgsm'
116         ;;
117 esac
118 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = "yes")
119 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
120 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
121
122 dnl
123 dnl Checks for libraries.
124 dnl
125
126 dnl FIXME: check whether Bonobo is installed
127
128 dnl
129 dnl Checks for header files.
130 dnl
131 AC_CHECK_HEADERS(sys/select.h)
132
133
134
135 dnl
136 dnl Checks for typedefs and structures.
137 dnl
138 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
139 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
140 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
141 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
142 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
143
144 AC_CHECK_SIZEOF(unsigned int)
145
146 dnl
147 dnl Checks for compiler features.
148 dnl
149
150 if test "$GCC" = yes; then
151     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
152 fi
153
154 dnl
155 dnl Checks for library functions.
156 dnl
157
158 AC_REPLACE_FUNCS(stpcpy)
159
160 AC_REPLACE_FUNCS(vasprintf)
161 if test "$ac_cv_func_vasprintf" != yes; then
162   GNUPG_CHECK_VA_COPY
163 fi
164
165
166
167 # Note: fopencokie is only a dummy stub and not used.  
168 #       However some code in assuan/ links against it.
169 AC_REPLACE_FUNCS(fopencookie)
170
171
172
173 dnl
174 dnl Checks for system services
175 dnl
176
177 NO_OVERRIDE=no
178 AC_ARG_WITH(gpg,
179             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
180             GPG=$withval, NO_OVERRIDE=yes)
181 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
182   GPG=
183   NO_OVERRIDE=yes
184   if test "$cross_compiling" != "yes"; then
185     AC_PATH_PROG(GPG, gpg)
186   fi
187   if test -z "$GPG"; then
188     GPG="$GPG_DEFAULT"
189   fi
190 fi
191 if test "$GPG" = no; then
192   if test "$NO_OVERRIDE" = "yes"; then
193     if test "$cross_compiling" != "yes"; then
194       AC_MSG_WARN([Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it])
195     else
196       AC_MSG_ERROR([Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH])
197     fi
198   fi
199 else
200   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
201   AC_SUBST(GPG)
202 fi
203 AM_CONDITIONAL(RUN_GPG_TESTS,
204   [test "$cross_compiling" != "yes" && test -n "$GPG" && test -r "$GPG"])
205 AC_SUBST(GPG_PATH)
206
207 NO_OVERRIDE=no
208 AC_ARG_WITH(gpgsm,
209             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
210             GPGSM=$withval, NO_OVERRIDE=yes)
211 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
212   GPGSM=
213   NO_OVERRIDE=yes
214   if test "$cross_compiling" != "yes"; then
215     AC_PATH_PROG(GPGSM, gpgsm)
216   fi
217   if test -z "$GPGSM"; then
218     GPGSM="$GPGSM_DEFAULT"
219   fi
220 fi
221 if test "$GPGSM" = no; then
222   if test "$NO_OVERRIDE" = "yes"; then
223     if test "$cross_compiling" != "yes"; then
224       AC_MSG_WARN([Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it])
225     else
226       AC_MSG_ERROR([Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH])
227     fi
228   fi
229 else
230   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
231   AC_SUBST(GPGSM)
232 fi
233 AM_CONDITIONAL(RUN_GPGSM_TESTS,
234   [test "$cross_compiling" != "yes" && test -n "$GPGSM" && test -r "$GPGSM"])
235
236 dnl FIXME: Only build if supported.
237 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
238
239 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
240 AM_CONDITIONAL(BUILD_BONOBO,  test "$component_system" = "Bonobo")
241
242 GPGMEPLUG=no
243 AC_ARG_ENABLE(gpgmeplug,
244             AC_HELP_STRING([--enable-gpgmeplug], [build GPGME Crypt Plug-In]),
245             GPGMEPLUG=$enableval)
246 AM_CONDITIONAL(BUILD_GPGMEPLUG, test "$GPGMEPLUG" = "yes")
247
248 dnl Make the version number in gpgme/gpgme.h the same as the one here.
249 dnl (this is easier than to have a *.in file just for one substitution)
250 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
251
252 dnl Substitution used for gpgme-config 
253 GPGME_CONFIG_LIBS="-lgpgme"
254 GPGME_CONFIG_CFLAGS=""
255 AC_SUBST(GPGME_CONFIG_LIBS)
256 AC_SUBST(GPGME_CONFIG_CFLAGS)
257
258 dnl Frob'da Variables
259 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
260            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
261 AC_SUBST(LTLIBOBJS)
262
263 dnl
264 dnl Create config files 
265 dnl
266
267 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
268                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
269                 doc/Makefile
270                 bonobo/Makefile complus/Makefile gpgmeplug/Makefile)
271 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
272 AC_OUTPUT
273
274 echo "
275         GPGME v${VERSION} has been configured as follows:
276
277         GnuPG version: min. $NEED_GPG_VERSION
278         GnuPG path:    $GPG
279
280         GpgSM version: min. $NEED_GPGSM_VERSION
281         GpgSM path:    $GPGSM
282
283         GPGME CryptPlug: $GPGMEPLUG
284 "