Qt: Add a unit test for qgpgme
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=3
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=0
67
68 LIBQGPGME_LT_CURRENT=1
69 LIBQGPGME_LT_AGE=0
70 LIBQGPGME_LT_REVISION=0
71
72 # If the API is changed in an incompatible way: increment the next counter.
73 GPGME_CONFIG_API_VERSION=1
74 ##############################################
75
76 NEED_GPG_ERROR_VERSION=1.11
77 NEED_LIBASSUAN_API=2
78 NEED_LIBASSUAN_VERSION=2.0.2
79
80
81 PACKAGE=$PACKAGE_NAME
82 VERSION=$PACKAGE_VERSION
83
84 AC_CONFIG_AUX_DIR([build-aux])
85 AC_CONFIG_MACRO_DIR([m4])
86 AC_CONFIG_SRCDIR(src/gpgme.h.in)
87 AC_CONFIG_HEADER(config.h)
88 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
89 AM_MAINTAINER_MODE
90 AC_CANONICAL_HOST
91 AM_SILENT_RULES
92 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
93
94 # Enable GNU extensions on systems that have them.
95 AC_GNU_SOURCE
96
97 AH_VERBATIM([_REENTRANT],
98 [/* To allow the use of GPGME in multithreaded programs we have to use
99   special features from the library.
100   IMPORTANT: gpgme is not yet fully reentrant and you should use it
101   only from one thread.  */
102 #ifndef _REENTRANT
103 # define _REENTRANT 1
104 #endif])
105
106 AC_PROG_CC
107 AC_PROG_CXX
108
109 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
110 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
111
112 AC_SUBST(LIBGPGME_LT_CURRENT)
113 AC_SUBST(LIBGPGME_LT_AGE)
114 AC_SUBST(LIBGPGME_LT_REVISION)
115 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
116 AC_SUBST(LIBGPGMEPP_LT_AGE)
117 AC_SUBST(LIBGPGMEPP_LT_REVISION)
118 AC_SUBST(LIBQGPGME_LT_CURRENT)
119 AC_SUBST(LIBQGPGME_LT_AGE)
120 AC_SUBST(LIBQGPGME_LT_REVISION)
121
122 AC_SUBST(PACKAGE)
123 AC_SUBST(VERSION)
124 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
125 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
126 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
127                           mym4_version_minor mym4_version_micro)
128 AC_SUBST(VERSION_NUMBER)
129
130 # Don't default to build static libs.
131 LT_PREREQ([2.2.6])
132 LT_INIT([win32-dll disable-static])
133 LT_LANG([Windows Resource])
134
135 # For now we hardcode the use of version scripts.  It would be better
136 # to write a test for this or even implement this within libtool.
137 have_ld_version_script=no
138 case "${host}" in
139     *-*-linux*)
140         have_ld_version_script=yes
141         ;;
142     *-*-gnu*)
143         have_ld_version_script=yes
144         ;;
145     *-apple-darwin*)
146         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
147         ;;
148 esac
149
150 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
151
152 GPG_DEFAULT=no
153 GPGSM_DEFAULT=no
154 GPGCONF_DEFAULT=no
155 G13_DEFAULT=no
156 component_system=None
157 have_dosish_system=no
158 have_android_system=no
159 have_w32_system=no
160 have_w64_system=no
161 build_w32_glib=no
162 build_w32_qt=no
163 available_languages="cpp cl qt"
164 default_languages="cpp cl qt"
165 case "${host}" in
166     x86_64-*mingw32*)
167         have_w64_system=yes
168         ;;
169     *-mingw32ce*)
170         have_w32ce_system=yes
171         ;;
172     *-linux-androideabi)
173         have_android_system=yes
174         ;;
175 esac
176 case "${host}" in
177     *-mingw32ce*|*-mingw32*)
178         have_dosish_system=yes
179         have_w32_system=yes
180         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
181         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
182         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
183         G13_DEFAULT='c:\\gnupg\\g13.exe'
184         #component_system='COM+'
185
186         AM_PATH_GLIB_2_0
187         AC_ARG_ENABLE(w32-glib,
188             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
189                            build_w32_glib=$enableval)
190        ;;
191     *)
192
193         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
194         if test "$have_pthread" = yes; then
195           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
196         fi
197
198         # XXX: Probably use exec-prefix here?
199 #       GPG_DEFAULT='/usr/bin/gpg'
200 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
201 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
202 #       G13_DEFAULT='/usr/bin/g13'
203         ;;
204 esac
205
206 if test "$have_dosish_system" = yes; then
207    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
208              [Defined if we run on some of the PCDOS like systems
209               (DOS, Windoze. OS/2) with special properties like
210               no file modes])
211 fi
212 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
213
214 if test "$have_w32_system" = yes; then
215    AC_DEFINE(HAVE_W32_SYSTEM,1,
216              [Defined if we run on any kind of W32 API based system])
217 fi
218 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
219
220 if test "$have_w64_system" = yes; then
221    AC_DEFINE(HAVE_W64_SYSTEM,1,
222              [Defined if we run on a 64 bit W32 API based system])
223 fi
224 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
225
226 if test "$have_w32ce_system" = yes; then
227    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
228              [Defined if we run on a W32 CE API based system])
229 fi
230 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
231
232 if test "$have_android_system" = yes; then
233    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
234 fi
235 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
236
237 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
238
239 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
240
241
242 AC_ARG_ENABLE([fixed-path],
243               AC_HELP_STRING([--enable-fixed-path=PATH],
244                              [locate binaries only via this PATH]),
245               [fixed_search_path="$enableval"],
246               [fixed_search_path=""])
247 if test x$fixed_search_path != x ; then
248   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
249                     [Locate binaries only via this PATH])
250 fi
251
252 AC_ARG_ENABLE([languages],
253               AC_HELP_STRING([--enable-languages=languages],
254                              [enable only specific language bindings]),
255                              [enabled_languages=`echo $enableval | \
256                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
257                              sed 's/c++/cpp/'`],
258                              [enabled_languages="$default_languages"])
259 if test "x$enabled_languages" = "x" \
260    -o "$enabled_languages" = "no"; then
261    enabled_languages=
262 fi
263 for language in $enabled_languages; do
264     LIST_MEMBER($language, $available_languages)
265     if test "$found" = "0"; then
266        AC_MSG_ERROR([unsupported language binding specified])
267     fi
268 done
269 # Check that if qt is enabled cpp also is enabled
270 LIST_MEMBER("qt", $enabled_languages)
271 if test "$found" = "1"; then
272    LIST_MEMBER("cpp", $enabled_languages)
273    if test "$found" = "0"; then
274       AC_MSG_ERROR([qt binding depends on cpp language binding])
275    fi
276    FIND_QT
277    if test "$have_qt5_libs" != "yes"; then
278        AC_MSG_ERROR([[
279    ***
280    *** Qt5 (Qt5Core) is required for qt binding.
281    ***]])
282    fi
283    # Make sure that qt comes after cpp
284    enabled_languages=`echo $enabled_languages | sed 's/qt//'`
285    enabled_languages=`echo $enabled_languages qt`
286 fi
287 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
288
289 #
290 # Provide information about the build.
291 #
292 BUILD_REVISION="mym4_revision"
293 AC_SUBST(BUILD_REVISION)
294 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
295                    [GIT commit id revision used to build this package])
296
297 changequote(,)dnl
298 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
299 changequote([,])dnl
300 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
301 AC_SUBST(BUILD_FILEVERSION)
302
303 AC_ARG_ENABLE([build-timestamp],
304   AC_HELP_STRING([--enable-build-timestamp],
305                  [set an explicit build timestamp for reproducibility.
306                   (default is the current time in ISO-8601 format)]),
307      [if test "$enableval" = "yes"; then
308         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
309       else
310         BUILD_TIMESTAMP="$enableval"
311       fi],
312      [BUILD_TIMESTAMP="<none>"])
313 AC_SUBST(BUILD_TIMESTAMP)
314 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
315                    [The time this package was configured for a build])
316
317
318 #
319 # Options to disable some regression tests
320 #
321 run_gpgconf_test="yes"
322 AC_ARG_ENABLE(gpgconf-test,
323   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
324          run_gpgconf_test=$enableval)
325 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
326
327 run_gpg_test="yes"
328 AC_ARG_ENABLE(gpg-test,
329   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
330          run_gpg_test=$enableval)
331 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
332
333 run_gpgsm_test="yes"
334 AC_ARG_ENABLE(gpgsm-test,
335   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
336          run_gpgsm_test=$enableval)
337 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
338
339 run_g13_test="yes"
340 AC_ARG_ENABLE(g13-test,
341   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
342          run_g13_test=$enableval)
343 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
344
345
346 # Checks for header files.
347 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
348                        unistd.h sys/time.h sys/types.h sys/stat.h])
349
350
351 # Type checks.
352 AC_C_INLINE
353 AC_CHECK_SIZEOF(unsigned int)
354 AC_SYS_LARGEFILE
355 AC_TYPE_OFF_T
356 AC_TYPE_UINTPTR_T
357
358 # A simple compile time check in gpgme.h for GNU/Linux systems that
359 # prevents a file offset bits mismatch between gpgme and the application.
360 NEED__FILE_OFFSET_BITS=0
361 if test "$have_w32_system" != yes; then
362   case "$ac_cv_sys_file_offset_bits" in
363     "" | no | unknown) ;;
364     *)
365     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
366     ;;
367   esac
368 fi
369 AC_SUBST(NEED__FILE_OFFSET_BITS)
370
371 # Figure out platform dependent typedefs for gpgme.h
372 if test "$have_w32_system" = yes; then
373     INSERT__TYPEDEFS_FOR_GPGME_H="
374 #ifdef _WIN64
375 # include <stdint.h>
376   typedef int64_t gpgme_off_t;
377   typedef int64_t gpgme_ssize_t;
378 #else /* _WIN32 */
379   typedef long gpgme_off_t;
380   typedef long gpgme_ssize_t;
381 #endif /* _WIN32 */"
382     API__OFF_T="gpgme_off_t"
383     API__SSIZE_T="gpgme_ssize_t"
384 else
385     INSERT__TYPEDEFS_FOR_GPGME_H="
386 #include <sys/types.h>
387 typedef off_t   gpgme_off_t;
388 typedef ssize_t gpgme_ssize_t;"
389     API__OFF_T="off_t"
390     API__SSIZE_T="ssize_t"
391 fi
392 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
393 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
394 AC_SUBST(API__OFF_T)
395 AM_SUBST_NOTMAKE(API__OFF_T)
396 AC_SUBST(API__SSIZE_T)
397 AM_SUBST_NOTMAKE(API__SSIZE_T)
398
399 # Checks for compiler features.
400 if test "$GCC" = yes; then
401     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
402     if test "$have_w32_system" = yes; then
403        CFLAGS="$CFLAGS -mms-bitfields"
404     fi
405 fi
406
407 # Only used for debugging, so no serious test needed (for actual
408 # functionality you have to test libc as well, this only tests the
409 # compiler).
410 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
411    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
412                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
413 if test "$gpgme_cv_tls_works" = yes; then
414   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
415 fi
416
417
418 # Checks for library functions.
419 AC_MSG_NOTICE([checking for libraries])
420
421 AC_FUNC_FSEEKO
422
423 AC_REPLACE_FUNCS(vasprintf)
424 if test "$ac_cv_func_vasprintf" != yes; then
425   GNUPG_CHECK_VA_COPY
426 fi
427
428 # Try to find a thread-safe version of ttyname().
429 gnupg_REPLACE_TTYNAME_R
430 if test "$ac_cv_func_ttyname_r" != yes; then
431   AC_MSG_WARN([
432 ***
433 *** ttyname() is not thread-safe and ttyname_r() does not exist
434 ***])
435 fi
436
437 # Try to find a thread-safe version of getenv().
438 have_thread_safe_getenv=no
439 jm_GLIBC21
440 if test $GLIBC21 = yes; then
441   have_thread_safe_getenv=yes
442 fi
443 if test $have_thread_safe_getenv = yes; then
444   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
445 fi
446 have_getenv_r=no
447 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
448 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
449   AC_MSG_WARN([
450 ***
451 *** getenv() is not thread-safe and getenv_r() does not exist
452 ***])
453 fi
454
455 # For converting time strings to seconds since Epoch, we need the timegm
456 # function.
457 AC_CHECK_FUNCS(timegm)
458 if test "$ac_cv_func_timegm" != yes; then
459   AC_MSG_WARN([
460 ***
461 *** timegm() not available - a non-thread-safe kludge will be used
462 *** and the TZ variable might be changed at runtime.
463 ***])
464 fi
465
466 AC_CHECK_FUNCS(setlocale)
467
468 # Checking for libgpg-error.
469 have_gpg_error=no
470 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
471                   have_gpg_error=yes, have_gpg_error=no)
472 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
473           [The default error source for GPGME.])
474
475 # And for libassuan.
476 have_libassuan=no
477 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
478                   have_libassuan=yes, have_libassuan=no)
479 if test "$have_libassuan" = "yes"; then
480   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
481                      [version of the libassuan library])
482 fi
483
484
485 #
486 # Other checks
487 #
488
489 # Check for funopen
490 AC_CHECK_FUNCS(funopen)
491 if test $ac_cv_func_funopen != yes; then
492     # No funopen but we can implement that in terms of fopencookie.
493     AC_CHECK_FUNCS(fopencookie)
494     if test $ac_cv_func_fopencookie = yes; then
495         AC_REPLACE_FUNCS(funopen)
496     else
497         AC_MSG_WARN([
498 ***
499 *** No implementation of fopencookie or funopen available
500 ***])
501     fi
502 fi
503
504 # Check for getgid etc
505 AC_CHECK_FUNCS(getgid getegid)
506
507
508 # Replacement functions.
509 AC_REPLACE_FUNCS(stpcpy)
510 AC_REPLACE_FUNCS(setenv)
511
512 # Assuan check for descriptor passing.
513 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
514                 [supports_descriptor_passing=yes],
515                 [supports_descriptor_passing=no
516                  AC_MSG_WARN([
517 ***
518 *** Data structure for sending ancillary data missing.
519 *** Descriptor passing won't work.
520 ***])],[
521 #include <stdlib.h>
522 #include <stddef.h>
523 #include <stdio.h>
524 #include <sys/types.h>
525 #include <sys/socket.h>
526 #include <sys/un.h>
527 #if HAVE_SYS_UIO_H
528 #include <sys/uio.h>
529 #endif
530 #include <unistd.h>
531        ])
532
533
534 dnl There seems to be a problem with Apple and decriptor passing.
535 dnl Until we found a solution we change the default to no.
536 dnl See bug 1483.
537 case "${host}" in
538     *-apple-darwin*)
539       use_descriptor_passing=no
540       ;;
541     *)
542       use_descriptor_passing=yes
543       ;;
544 esac
545 AC_ARG_ENABLE(fd-passing,
546   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
547   use_descriptor_passing=$enableval)
548
549 if test "$supports_descriptor_passing" != "yes"; then
550   use_descriptor_passing=no
551 fi
552
553 if test "$use_descriptor_passing" = "yes"; then
554 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
555           [Defined if descriptor passing is enabled and supported])
556 fi
557
558 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
559
560
561 uiserver=no
562 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
563   uiserver=yes
564 fi
565 if test "$uiserver" != "no"; then
566   AC_DEFINE(ENABLE_UISERVER, 1,
567             [Defined if we are building with uiserver support.])
568 fi
569 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
570
571
572 # Add a few constants to help porting to W32
573 AH_VERBATIM([SEPCONSTANTS],
574 [
575 /* Separators as used in $PATH and file name.  */
576 #ifdef HAVE_DOSISH_SYSTEM
577 #define PATHSEP_C ';'
578 #define DIRSEP_C '\\'
579 #define DIRSEP_S "\\"
580 #else
581 #define PATHSEP_C ':'
582 #define DIRSEP_C '/'
583 #define DIRSEP_S "/"
584 #endif
585 ])
586
587 AH_BOTTOM([
588 /* Definition of GCC specific attributes.  */
589 #if __GNUC__ > 2
590 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
591 #else
592 # define GPGME_GCC_A_PURE
593 #endif
594
595 /* Under WindowsCE we need gpg-error's strerror macro.  */
596 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
597
598 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
599                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
600 ])
601
602
603 # Substitution used for gpgme-config
604 GPGME_CONFIG_LIBS="-lgpgme"
605 GPGME_CONFIG_CFLAGS=""
606 GPGME_CONFIG_HOST="$host"
607 AC_SUBST(GPGME_CONFIG_API_VERSION)
608 AC_SUBST(GPGME_CONFIG_LIBS)
609 AC_SUBST(GPGME_CONFIG_CFLAGS)
610 AC_SUBST(GPGME_CONFIG_HOST)
611
612 # Frob'da Variables
613 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
614            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
615 AC_SUBST(LTLIBOBJS)
616
617 # Some checks for gpgme-tool
618 # Done at top: AC_CHECK_HEADER([argp.h])
619 AC_CHECK_TYPES([error_t], [],
620    [AC_DEFINE([error_t], [int],
621    [Define to a type to use for `error_t' if it is not otherwise available.])],
622    [#include <errno.h>])
623
624
625 # A substitution to set generated files in a Emacs buffer to read-only.
626 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
627 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
628 AC_SUBST(emacs_local_vars_end, ['End:'])
629
630
631 # Last check.
632 die=no
633 if test "$have_gpg_error" = "no"; then
634    die=yes
635    AC_MSG_NOTICE([[
636 ***
637 *** You need libgpg-error to build this program.
638 **  This library is for example available at
639 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
640 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
641 ***]])
642 fi
643 if test "$have_libassuan" = "no"; then
644    die=yes
645    AC_MSG_NOTICE([[
646 ***
647 *** You need libassuan to build this program.
648 *** This library is for example available at
649 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
650 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
651 ***]])
652 fi
653
654 if test "$die" = "yes"; then
655     AC_MSG_ERROR([[
656 ***
657 *** Required libraries not found. Please consult the above messages
658 *** and install them before running configure again.
659 ***]])
660 fi
661
662
663 #
664 # Create config files
665
666 AC_CONFIG_FILES(Makefile src/Makefile
667                 tests/Makefile
668                 tests/gpg/Makefile
669                 tests/gpgsm/Makefile
670                 tests/opassuan/Makefile
671                 doc/Makefile
672                 src/versioninfo.rc
673                 src/gpgme.h)
674 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
675 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
676 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
677 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
678 AC_CONFIG_FILES(lang/qt/Makefile lang/qt/src/Makefile)
679 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfig.cmake.in)
680 AC_CONFIG_FILES(lang/qt/src/QGpgmeConfigVersion.cmake)
681 AC_CONFIG_FILES(lang/qt/tests/Makefile)
682 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
683 AC_OUTPUT
684
685 echo "
686         GPGME v${VERSION} has been configured as follows:
687
688         Revision:          mym4_revision  (mym4_revision_dec)
689         Platform:          $host
690
691         UI Server:         $uiserver
692         FD Passing:        $use_descriptor_passing
693         GPGME Pthread:     $have_pthread
694
695         Language bindings: $enabled_languages
696 "
697 if test "x${gpg_config_script_warn}" != x; then
698 cat <<G10EOF
699         Mismatches between the target platform and the to
700         be used libraries have been been detected for:
701          ${gpg_config_script_warn}
702         Please check above for warning messages.
703
704 G10EOF
705 fi