2b1df17a6ed8bb71b19e34c280e7f6644d83f057
[libgcrypt.git] / cipher / camellia-aesni-avx-amd64.S
1 /* camellia-avx-aesni-amd64.S  -  AES-NI/AVX implementation of Camellia cipher
2  *
3  * Copyright © 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
4  *
5  * This file is part of Libgcrypt.
6  *
7  * Libgcrypt is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU Lesser General Public License as
9  * published by the Free Software Foundation; either version 2.1 of
10  * the License, or (at your option) any later version.
11  *
12  * Libgcrypt is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU Lesser General Public License for more details.
16  *
17  * You should have received a copy of the GNU Lesser General Public
18  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
19  */
20
21 #ifdef __x86_64
22 #include <config.h>
23 #if defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX_SUPPORT)
24
25 #ifdef __PIC__
26 #  define RIP (%rip)
27 #else
28 #  define RIP
29 #endif
30
31 #define CAMELLIA_TABLE_BYTE_LEN 272
32
33 /* struct CAMELLIA_context: */
34 #define key_bitlength 0
35 #define key_table 4
36
37 /* register macros */
38 #define CTX %rdi
39 #define RIO %r8
40
41 /**********************************************************************
42   helper macros
43  **********************************************************************/
44 #define filter_8bit(x, lo_t, hi_t, mask4bit, tmp0) \
45         vpand x, mask4bit, tmp0; \
46         vpandn x, mask4bit, x; \
47         vpsrld $4, x, x; \
48         \
49         vpshufb tmp0, lo_t, tmp0; \
50         vpshufb x, hi_t, x; \
51         vpxor tmp0, x, x;
52
53 /**********************************************************************
54   16-way camellia
55  **********************************************************************/
56
57 /*
58  * IN:
59  *   x0..x7: byte-sliced AB state
60  *   mem_cd: register pointer storing CD state
61  *   key: index for key material
62  * OUT:
63  *   x0..x7: new byte-sliced CD state
64  */
65 #define roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, t0, t1, t2, t3, t4, t5, t6, \
66                   t7, mem_cd, key) \
67         /* \
68          * S-function with AES subbytes \
69          */ \
70         vmovdqa .Linv_shift_row RIP, t4; \
71         vbroadcastss .L0f0f0f0f RIP, t7; \
72         vmovdqa .Lpre_tf_lo_s1 RIP, t0; \
73         vmovdqa .Lpre_tf_hi_s1 RIP, t1; \
74         \
75         /* AES inverse shift rows */ \
76         vpshufb t4, x0, x0; \
77         vpshufb t4, x7, x7; \
78         vpshufb t4, x1, x1; \
79         vpshufb t4, x4, x4; \
80         vpshufb t4, x2, x2; \
81         vpshufb t4, x5, x5; \
82         vpshufb t4, x3, x3; \
83         vpshufb t4, x6, x6; \
84         \
85         /* prefilter sboxes 1, 2 and 3 */ \
86         vmovdqa .Lpre_tf_lo_s4 RIP, t2; \
87         vmovdqa .Lpre_tf_hi_s4 RIP, t3; \
88         filter_8bit(x0, t0, t1, t7, t6); \
89         filter_8bit(x7, t0, t1, t7, t6); \
90         filter_8bit(x1, t0, t1, t7, t6); \
91         filter_8bit(x4, t0, t1, t7, t6); \
92         filter_8bit(x2, t0, t1, t7, t6); \
93         filter_8bit(x5, t0, t1, t7, t6); \
94         \
95         /* prefilter sbox 4 */ \
96         vpxor t4, t4, t4; \
97         filter_8bit(x3, t2, t3, t7, t6); \
98         filter_8bit(x6, t2, t3, t7, t6); \
99         \
100         /* AES subbytes + AES shift rows */ \
101         vmovdqa .Lpost_tf_lo_s1 RIP, t0; \
102         vmovdqa .Lpost_tf_hi_s1 RIP, t1; \
103         vaesenclast t4, x0, x0; \
104         vaesenclast t4, x7, x7; \
105         vaesenclast t4, x1, x1; \
106         vaesenclast t4, x4, x4; \
107         vaesenclast t4, x2, x2; \
108         vaesenclast t4, x5, x5; \
109         vaesenclast t4, x3, x3; \
110         vaesenclast t4, x6, x6; \
111         \
112         /* postfilter sboxes 1 and 4 */ \
113         vmovdqa .Lpost_tf_lo_s3 RIP, t2; \
114         vmovdqa .Lpost_tf_hi_s3 RIP, t3; \
115         filter_8bit(x0, t0, t1, t7, t6); \
116         filter_8bit(x7, t0, t1, t7, t6); \
117         filter_8bit(x3, t0, t1, t7, t6); \
118         filter_8bit(x6, t0, t1, t7, t6); \
119         \
120         /* postfilter sbox 3 */ \
121         vmovdqa .Lpost_tf_lo_s2 RIP, t4; \
122         vmovdqa .Lpost_tf_hi_s2 RIP, t5; \
123         filter_8bit(x2, t2, t3, t7, t6); \
124         filter_8bit(x5, t2, t3, t7, t6); \
125         \
126         vpxor t6, t6, t6; \
127         vmovq key, t0; \
128         \
129         /* postfilter sbox 2 */ \
130         filter_8bit(x1, t4, t5, t7, t2); \
131         filter_8bit(x4, t4, t5, t7, t2); \
132         \
133         vpsrldq $5, t0, t5; \
134         vpsrldq $1, t0, t1; \
135         vpsrldq $2, t0, t2; \
136         vpsrldq $3, t0, t3; \
137         vpsrldq $4, t0, t4; \
138         vpshufb t6, t0, t0; \
139         vpshufb t6, t1, t1; \
140         vpshufb t6, t2, t2; \
141         vpshufb t6, t3, t3; \
142         vpshufb t6, t4, t4; \
143         vpsrldq $2, t5, t7; \
144         vpshufb t6, t7, t7; \
145         \
146         /* P-function */ \
147         vpxor x5, x0, x0; \
148         vpxor x6, x1, x1; \
149         vpxor x7, x2, x2; \
150         vpxor x4, x3, x3; \
151         \
152         vpxor x2, x4, x4; \
153         vpxor x3, x5, x5; \
154         vpxor x0, x6, x6; \
155         vpxor x1, x7, x7; \
156         \
157         vpxor x7, x0, x0; \
158         vpxor x4, x1, x1; \
159         vpxor x5, x2, x2; \
160         vpxor x6, x3, x3; \
161         \
162         vpxor x3, x4, x4; \
163         vpxor x0, x5, x5; \
164         vpxor x1, x6, x6; \
165         vpxor x2, x7, x7; /* note: high and low parts swapped */ \
166         \
167         /* Add key material and result to CD (x becomes new CD) */ \
168         \
169         vpxor t3, x4, x4; \
170         vpxor 0 * 16(mem_cd), x4, x4; \
171         \
172         vpxor t2, x5, x5; \
173         vpxor 1 * 16(mem_cd), x5, x5; \
174         \
175         vpsrldq $1, t5, t3; \
176         vpshufb t6, t5, t5; \
177         vpshufb t6, t3, t6; \
178         \
179         vpxor t1, x6, x6; \
180         vpxor 2 * 16(mem_cd), x6, x6; \
181         \
182         vpxor t0, x7, x7; \
183         vpxor 3 * 16(mem_cd), x7, x7; \
184         \
185         vpxor t7, x0, x0; \
186         vpxor 4 * 16(mem_cd), x0, x0; \
187         \
188         vpxor t6, x1, x1; \
189         vpxor 5 * 16(mem_cd), x1, x1; \
190         \
191         vpxor t5, x2, x2; \
192         vpxor 6 * 16(mem_cd), x2, x2; \
193         \
194         vpxor t4, x3, x3; \
195         vpxor 7 * 16(mem_cd), x3, x3;
196
197 /*
198  * IN/OUT:
199  *  x0..x7: byte-sliced AB state preloaded
200  *  mem_ab: byte-sliced AB state in memory
201  *  mem_cb: byte-sliced CD state in memory
202  */
203 #define two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
204                       y6, y7, mem_ab, mem_cd, i, dir, store_ab) \
205         roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
206                   y6, y7, mem_cd, (key_table + (i) * 8)(CTX)); \
207         \
208         vmovdqu x4, 0 * 16(mem_cd); \
209         vmovdqu x5, 1 * 16(mem_cd); \
210         vmovdqu x6, 2 * 16(mem_cd); \
211         vmovdqu x7, 3 * 16(mem_cd); \
212         vmovdqu x0, 4 * 16(mem_cd); \
213         vmovdqu x1, 5 * 16(mem_cd); \
214         vmovdqu x2, 6 * 16(mem_cd); \
215         vmovdqu x3, 7 * 16(mem_cd); \
216         \
217         roundsm16(x4, x5, x6, x7, x0, x1, x2, x3, y0, y1, y2, y3, y4, y5, \
218                   y6, y7, mem_ab, (key_table + ((i) + (dir)) * 8)(CTX)); \
219         \
220         store_ab(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab);
221
222 #define dummy_store(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) /* do nothing */
223
224 #define store_ab_state(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) \
225         /* Store new AB state */ \
226         vmovdqu x0, 0 * 16(mem_ab); \
227         vmovdqu x1, 1 * 16(mem_ab); \
228         vmovdqu x2, 2 * 16(mem_ab); \
229         vmovdqu x3, 3 * 16(mem_ab); \
230         vmovdqu x4, 4 * 16(mem_ab); \
231         vmovdqu x5, 5 * 16(mem_ab); \
232         vmovdqu x6, 6 * 16(mem_ab); \
233         vmovdqu x7, 7 * 16(mem_ab);
234
235 #define enc_rounds16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
236                       y6, y7, mem_ab, mem_cd, i) \
237         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
238                       y6, y7, mem_ab, mem_cd, (i) + 2, 1, store_ab_state); \
239         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
240                       y6, y7, mem_ab, mem_cd, (i) + 4, 1, store_ab_state); \
241         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
242                       y6, y7, mem_ab, mem_cd, (i) + 6, 1, dummy_store);
243
244 #define dec_rounds16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
245                       y6, y7, mem_ab, mem_cd, i) \
246         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
247                       y6, y7, mem_ab, mem_cd, (i) + 7, -1, store_ab_state); \
248         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
249                       y6, y7, mem_ab, mem_cd, (i) + 5, -1, store_ab_state); \
250         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
251                       y6, y7, mem_ab, mem_cd, (i) + 3, -1, dummy_store);
252
253 /*
254  * IN:
255  *  v0..3: byte-sliced 32-bit integers
256  * OUT:
257  *  v0..3: (IN <<< 1)
258  */
259 #define rol32_1_16(v0, v1, v2, v3, t0, t1, t2, zero) \
260         vpcmpgtb v0, zero, t0; \
261         vpaddb v0, v0, v0; \
262         vpabsb t0, t0; \
263         \
264         vpcmpgtb v1, zero, t1; \
265         vpaddb v1, v1, v1; \
266         vpabsb t1, t1; \
267         \
268         vpcmpgtb v2, zero, t2; \
269         vpaddb v2, v2, v2; \
270         vpabsb t2, t2; \
271         \
272         vpor t0, v1, v1; \
273         \
274         vpcmpgtb v3, zero, t0; \
275         vpaddb v3, v3, v3; \
276         vpabsb t0, t0; \
277         \
278         vpor t1, v2, v2; \
279         vpor t2, v3, v3; \
280         vpor t0, v0, v0;
281
282 /*
283  * IN:
284  *   r: byte-sliced AB state in memory
285  *   l: byte-sliced CD state in memory
286  * OUT:
287  *   x0..x7: new byte-sliced CD state
288  */
289 #define fls16(l, l0, l1, l2, l3, l4, l5, l6, l7, r, t0, t1, t2, t3, tt0, \
290               tt1, tt2, tt3, kll, klr, krl, krr) \
291         /* \
292          * t0 = kll; \
293          * t0 &= ll; \
294          * lr ^= rol32(t0, 1); \
295          */ \
296         vpxor tt0, tt0, tt0; \
297         vmovd kll, t0; \
298         vpshufb tt0, t0, t3; \
299         vpsrldq $1, t0, t0; \
300         vpshufb tt0, t0, t2; \
301         vpsrldq $1, t0, t0; \
302         vpshufb tt0, t0, t1; \
303         vpsrldq $1, t0, t0; \
304         vpshufb tt0, t0, t0; \
305         \
306         vpand l0, t0, t0; \
307         vpand l1, t1, t1; \
308         vpand l2, t2, t2; \
309         vpand l3, t3, t3; \
310         \
311         rol32_1_16(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
312         \
313         vpxor l4, t0, l4; \
314         vmovdqu l4, 4 * 16(l); \
315         vpxor l5, t1, l5; \
316         vmovdqu l5, 5 * 16(l); \
317         vpxor l6, t2, l6; \
318         vmovdqu l6, 6 * 16(l); \
319         vpxor l7, t3, l7; \
320         vmovdqu l7, 7 * 16(l); \
321         \
322         /* \
323          * t2 = krr; \
324          * t2 |= rr; \
325          * rl ^= t2; \
326          */ \
327         \
328         vmovd krr, t0; \
329         vpshufb tt0, t0, t3; \
330         vpsrldq $1, t0, t0; \
331         vpshufb tt0, t0, t2; \
332         vpsrldq $1, t0, t0; \
333         vpshufb tt0, t0, t1; \
334         vpsrldq $1, t0, t0; \
335         vpshufb tt0, t0, t0; \
336         \
337         vpor 4 * 16(r), t0, t0; \
338         vpor 5 * 16(r), t1, t1; \
339         vpor 6 * 16(r), t2, t2; \
340         vpor 7 * 16(r), t3, t3; \
341         \
342         vpxor 0 * 16(r), t0, t0; \
343         vpxor 1 * 16(r), t1, t1; \
344         vpxor 2 * 16(r), t2, t2; \
345         vpxor 3 * 16(r), t3, t3; \
346         vmovdqu t0, 0 * 16(r); \
347         vmovdqu t1, 1 * 16(r); \
348         vmovdqu t2, 2 * 16(r); \
349         vmovdqu t3, 3 * 16(r); \
350         \
351         /* \
352          * t2 = krl; \
353          * t2 &= rl; \
354          * rr ^= rol32(t2, 1); \
355          */ \
356         vmovd krl, t0; \
357         vpshufb tt0, t0, t3; \
358         vpsrldq $1, t0, t0; \
359         vpshufb tt0, t0, t2; \
360         vpsrldq $1, t0, t0; \
361         vpshufb tt0, t0, t1; \
362         vpsrldq $1, t0, t0; \
363         vpshufb tt0, t0, t0; \
364         \
365         vpand 0 * 16(r), t0, t0; \
366         vpand 1 * 16(r), t1, t1; \
367         vpand 2 * 16(r), t2, t2; \
368         vpand 3 * 16(r), t3, t3; \
369         \
370         rol32_1_16(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
371         \
372         vpxor 4 * 16(r), t0, t0; \
373         vpxor 5 * 16(r), t1, t1; \
374         vpxor 6 * 16(r), t2, t2; \
375         vpxor 7 * 16(r), t3, t3; \
376         vmovdqu t0, 4 * 16(r); \
377         vmovdqu t1, 5 * 16(r); \
378         vmovdqu t2, 6 * 16(r); \
379         vmovdqu t3, 7 * 16(r); \
380         \
381         /* \
382          * t0 = klr; \
383          * t0 |= lr; \
384          * ll ^= t0; \
385          */ \
386         \
387         vmovd klr, t0; \
388         vpshufb tt0, t0, t3; \
389         vpsrldq $1, t0, t0; \
390         vpshufb tt0, t0, t2; \
391         vpsrldq $1, t0, t0; \
392         vpshufb tt0, t0, t1; \
393         vpsrldq $1, t0, t0; \
394         vpshufb tt0, t0, t0; \
395         \
396         vpor l4, t0, t0; \
397         vpor l5, t1, t1; \
398         vpor l6, t2, t2; \
399         vpor l7, t3, t3; \
400         \
401         vpxor l0, t0, l0; \
402         vmovdqu l0, 0 * 16(l); \
403         vpxor l1, t1, l1; \
404         vmovdqu l1, 1 * 16(l); \
405         vpxor l2, t2, l2; \
406         vmovdqu l2, 2 * 16(l); \
407         vpxor l3, t3, l3; \
408         vmovdqu l3, 3 * 16(l);
409
410 #define transpose_4x4(x0, x1, x2, x3, t1, t2) \
411         vpunpckhdq x1, x0, t2; \
412         vpunpckldq x1, x0, x0; \
413         \
414         vpunpckldq x3, x2, t1; \
415         vpunpckhdq x3, x2, x2; \
416         \
417         vpunpckhqdq t1, x0, x1; \
418         vpunpcklqdq t1, x0, x0; \
419         \
420         vpunpckhqdq x2, t2, x3; \
421         vpunpcklqdq x2, t2, x2;
422
423 #define byteslice_16x16b_fast(a0, b0, c0, d0, a1, b1, c1, d1, a2, b2, c2, d2, \
424                               a3, b3, c3, d3, st0, st1) \
425         vmovdqu d2, st0; \
426         vmovdqu d3, st1; \
427         transpose_4x4(a0, a1, a2, a3, d2, d3); \
428         transpose_4x4(b0, b1, b2, b3, d2, d3); \
429         vmovdqu st0, d2; \
430         vmovdqu st1, d3; \
431         \
432         vmovdqu a0, st0; \
433         vmovdqu a1, st1; \
434         transpose_4x4(c0, c1, c2, c3, a0, a1); \
435         transpose_4x4(d0, d1, d2, d3, a0, a1); \
436         \
437         vmovdqu .Lshufb_16x16b RIP, a0; \
438         vmovdqu st1, a1; \
439         vpshufb a0, a2, a2; \
440         vpshufb a0, a3, a3; \
441         vpshufb a0, b0, b0; \
442         vpshufb a0, b1, b1; \
443         vpshufb a0, b2, b2; \
444         vpshufb a0, b3, b3; \
445         vpshufb a0, a1, a1; \
446         vpshufb a0, c0, c0; \
447         vpshufb a0, c1, c1; \
448         vpshufb a0, c2, c2; \
449         vpshufb a0, c3, c3; \
450         vpshufb a0, d0, d0; \
451         vpshufb a0, d1, d1; \
452         vpshufb a0, d2, d2; \
453         vpshufb a0, d3, d3; \
454         vmovdqu d3, st1; \
455         vmovdqu st0, d3; \
456         vpshufb a0, d3, a0; \
457         vmovdqu d2, st0; \
458         \
459         transpose_4x4(a0, b0, c0, d0, d2, d3); \
460         transpose_4x4(a1, b1, c1, d1, d2, d3); \
461         vmovdqu st0, d2; \
462         vmovdqu st1, d3; \
463         \
464         vmovdqu b0, st0; \
465         vmovdqu b1, st1; \
466         transpose_4x4(a2, b2, c2, d2, b0, b1); \
467         transpose_4x4(a3, b3, c3, d3, b0, b1); \
468         vmovdqu st0, b0; \
469         vmovdqu st1, b1; \
470         /* does not adjust output bytes inside vectors */
471
472 #define transpose_8x8b(a, b, c, d, e, f, g, h, t0, t1, t2, t3, t4) \
473         vpunpcklbw a, b, t0; \
474         vpunpckhbw a, b, b; \
475         \
476         vpunpcklbw c, d, t1; \
477         vpunpckhbw c, d, d; \
478         \
479         vpunpcklbw e, f, t2; \
480         vpunpckhbw e, f, f; \
481         \
482         vpunpcklbw g, h, t3; \
483         vpunpckhbw g, h, h; \
484         \
485         vpunpcklwd t0, t1, g; \
486         vpunpckhwd t0, t1, t0; \
487         \
488         vpunpcklwd b, d, t1; \
489         vpunpckhwd b, d, e; \
490         \
491         vpunpcklwd t2, t3, c; \
492         vpunpckhwd t2, t3, t2; \
493         \
494         vpunpcklwd f, h, t3; \
495         vpunpckhwd f, h, b; \
496         \
497         vpunpcklwd e, b, t4; \
498         vpunpckhwd e, b, b; \
499         \
500         vpunpcklwd t1, t3, e; \
501         vpunpckhwd t1, t3, f; \
502         \
503         vmovdqa .Ltranspose_8x8_shuf RIP, t3; \
504         \
505         vpunpcklwd g, c, d; \
506         vpunpckhwd g, c, c; \
507         \
508         vpunpcklwd t0, t2, t1; \
509         vpunpckhwd t0, t2, h; \
510         \
511         vpunpckhqdq b, h, a; \
512         vpshufb t3, a, a; \
513         vpunpcklqdq b, h, b; \
514         vpshufb t3, b, b; \
515         \
516         vpunpckhqdq e, d, g; \
517         vpshufb t3, g, g; \
518         vpunpcklqdq e, d, h; \
519         vpshufb t3, h, h; \
520         \
521         vpunpckhqdq f, c, e; \
522         vpshufb t3, e, e; \
523         vpunpcklqdq f, c, f; \
524         vpshufb t3, f, f; \
525         \
526         vpunpckhqdq t4, t1, c; \
527         vpshufb t3, c, c; \
528         vpunpcklqdq t4, t1, d; \
529         vpshufb t3, d, d;
530
531 /* load blocks to registers and apply pre-whitening */
532 #define inpack16_pre(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
533                      y6, y7, rio, key) \
534         vmovq key, x0; \
535         vpshufb .Lpack_bswap RIP, x0, x0; \
536         \
537         vpxor 0 * 16(rio), x0, y7; \
538         vpxor 1 * 16(rio), x0, y6; \
539         vpxor 2 * 16(rio), x0, y5; \
540         vpxor 3 * 16(rio), x0, y4; \
541         vpxor 4 * 16(rio), x0, y3; \
542         vpxor 5 * 16(rio), x0, y2; \
543         vpxor 6 * 16(rio), x0, y1; \
544         vpxor 7 * 16(rio), x0, y0; \
545         vpxor 8 * 16(rio), x0, x7; \
546         vpxor 9 * 16(rio), x0, x6; \
547         vpxor 10 * 16(rio), x0, x5; \
548         vpxor 11 * 16(rio), x0, x4; \
549         vpxor 12 * 16(rio), x0, x3; \
550         vpxor 13 * 16(rio), x0, x2; \
551         vpxor 14 * 16(rio), x0, x1; \
552         vpxor 15 * 16(rio), x0, x0;
553
554 /* byteslice pre-whitened blocks and store to temporary memory */
555 #define inpack16_post(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
556                       y6, y7, mem_ab, mem_cd) \
557         byteslice_16x16b_fast(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, \
558                               y4, y5, y6, y7, (mem_ab), (mem_cd)); \
559         \
560         vmovdqu x0, 0 * 16(mem_ab); \
561         vmovdqu x1, 1 * 16(mem_ab); \
562         vmovdqu x2, 2 * 16(mem_ab); \
563         vmovdqu x3, 3 * 16(mem_ab); \
564         vmovdqu x4, 4 * 16(mem_ab); \
565         vmovdqu x5, 5 * 16(mem_ab); \
566         vmovdqu x6, 6 * 16(mem_ab); \
567         vmovdqu x7, 7 * 16(mem_ab); \
568         vmovdqu y0, 0 * 16(mem_cd); \
569         vmovdqu y1, 1 * 16(mem_cd); \
570         vmovdqu y2, 2 * 16(mem_cd); \
571         vmovdqu y3, 3 * 16(mem_cd); \
572         vmovdqu y4, 4 * 16(mem_cd); \
573         vmovdqu y5, 5 * 16(mem_cd); \
574         vmovdqu y6, 6 * 16(mem_cd); \
575         vmovdqu y7, 7 * 16(mem_cd);
576
577 /* de-byteslice, apply post-whitening and store blocks */
578 #define outunpack16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, \
579                     y5, y6, y7, key, stack_tmp0, stack_tmp1) \
580         byteslice_16x16b_fast(y0, y4, x0, x4, y1, y5, x1, x5, y2, y6, x2, x6, \
581                               y3, y7, x3, x7, stack_tmp0, stack_tmp1); \
582         \
583         vmovdqu x0, stack_tmp0; \
584         \
585         vmovq key, x0; \
586         vpshufb .Lpack_bswap RIP, x0, x0; \
587         \
588         vpxor x0, y7, y7; \
589         vpxor x0, y6, y6; \
590         vpxor x0, y5, y5; \
591         vpxor x0, y4, y4; \
592         vpxor x0, y3, y3; \
593         vpxor x0, y2, y2; \
594         vpxor x0, y1, y1; \
595         vpxor x0, y0, y0; \
596         vpxor x0, x7, x7; \
597         vpxor x0, x6, x6; \
598         vpxor x0, x5, x5; \
599         vpxor x0, x4, x4; \
600         vpxor x0, x3, x3; \
601         vpxor x0, x2, x2; \
602         vpxor x0, x1, x1; \
603         vpxor stack_tmp0, x0, x0;
604
605 #define write_output(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
606                      y6, y7, rio) \
607         vmovdqu x0, 0 * 16(rio); \
608         vmovdqu x1, 1 * 16(rio); \
609         vmovdqu x2, 2 * 16(rio); \
610         vmovdqu x3, 3 * 16(rio); \
611         vmovdqu x4, 4 * 16(rio); \
612         vmovdqu x5, 5 * 16(rio); \
613         vmovdqu x6, 6 * 16(rio); \
614         vmovdqu x7, 7 * 16(rio); \
615         vmovdqu y0, 8 * 16(rio); \
616         vmovdqu y1, 9 * 16(rio); \
617         vmovdqu y2, 10 * 16(rio); \
618         vmovdqu y3, 11 * 16(rio); \
619         vmovdqu y4, 12 * 16(rio); \
620         vmovdqu y5, 13 * 16(rio); \
621         vmovdqu y6, 14 * 16(rio); \
622         vmovdqu y7, 15 * 16(rio);
623
624 .data
625 .align 16
626
627 #define SHUFB_BYTES(idx) \
628         0 + (idx), 4 + (idx), 8 + (idx), 12 + (idx)
629
630 .Lshufb_16x16b:
631         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3);
632
633 .Lpack_bswap:
634         .long 0x00010203
635         .long 0x04050607
636         .long 0x80808080
637         .long 0x80808080
638
639 /* For CTR-mode IV byteswap */
640 .Lbswap128_mask:
641         .byte 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0
642
643 /*
644  * pre-SubByte transform
645  *
646  * pre-lookup for sbox1, sbox2, sbox3:
647  *   swap_bitendianness(
648  *       isom_map_camellia_to_aes(
649  *           camellia_f(
650  *               swap_bitendianess(in)
651  *           )
652  *       )
653  *   )
654  *
655  * (note: '⊕ 0xc5' inside camellia_f())
656  */
657 .Lpre_tf_lo_s1:
658         .byte 0x45, 0xe8, 0x40, 0xed, 0x2e, 0x83, 0x2b, 0x86
659         .byte 0x4b, 0xe6, 0x4e, 0xe3, 0x20, 0x8d, 0x25, 0x88
660 .Lpre_tf_hi_s1:
661         .byte 0x00, 0x51, 0xf1, 0xa0, 0x8a, 0xdb, 0x7b, 0x2a
662         .byte 0x09, 0x58, 0xf8, 0xa9, 0x83, 0xd2, 0x72, 0x23
663
664 /*
665  * pre-SubByte transform
666  *
667  * pre-lookup for sbox4:
668  *   swap_bitendianness(
669  *       isom_map_camellia_to_aes(
670  *           camellia_f(
671  *               swap_bitendianess(in <<< 1)
672  *           )
673  *       )
674  *   )
675  *
676  * (note: '⊕ 0xc5' inside camellia_f())
677  */
678 .Lpre_tf_lo_s4:
679         .byte 0x45, 0x40, 0x2e, 0x2b, 0x4b, 0x4e, 0x20, 0x25
680         .byte 0x14, 0x11, 0x7f, 0x7a, 0x1a, 0x1f, 0x71, 0x74
681 .Lpre_tf_hi_s4:
682         .byte 0x00, 0xf1, 0x8a, 0x7b, 0x09, 0xf8, 0x83, 0x72
683         .byte 0xad, 0x5c, 0x27, 0xd6, 0xa4, 0x55, 0x2e, 0xdf
684
685 /*
686  * post-SubByte transform
687  *
688  * post-lookup for sbox1, sbox4:
689  *  swap_bitendianness(
690  *      camellia_h(
691  *          isom_map_aes_to_camellia(
692  *              swap_bitendianness(
693  *                  aes_inverse_affine_transform(in)
694  *              )
695  *          )
696  *      )
697  *  )
698  *
699  * (note: '⊕ 0x6e' inside camellia_h())
700  */
701 .Lpost_tf_lo_s1:
702         .byte 0x3c, 0xcc, 0xcf, 0x3f, 0x32, 0xc2, 0xc1, 0x31
703         .byte 0xdc, 0x2c, 0x2f, 0xdf, 0xd2, 0x22, 0x21, 0xd1
704 .Lpost_tf_hi_s1:
705         .byte 0x00, 0xf9, 0x86, 0x7f, 0xd7, 0x2e, 0x51, 0xa8
706         .byte 0xa4, 0x5d, 0x22, 0xdb, 0x73, 0x8a, 0xf5, 0x0c
707
708 /*
709  * post-SubByte transform
710  *
711  * post-lookup for sbox2:
712  *  swap_bitendianness(
713  *      camellia_h(
714  *          isom_map_aes_to_camellia(
715  *              swap_bitendianness(
716  *                  aes_inverse_affine_transform(in)
717  *              )
718  *          )
719  *      )
720  *  ) <<< 1
721  *
722  * (note: '⊕ 0x6e' inside camellia_h())
723  */
724 .Lpost_tf_lo_s2:
725         .byte 0x78, 0x99, 0x9f, 0x7e, 0x64, 0x85, 0x83, 0x62
726         .byte 0xb9, 0x58, 0x5e, 0xbf, 0xa5, 0x44, 0x42, 0xa3
727 .Lpost_tf_hi_s2:
728         .byte 0x00, 0xf3, 0x0d, 0xfe, 0xaf, 0x5c, 0xa2, 0x51
729         .byte 0x49, 0xba, 0x44, 0xb7, 0xe6, 0x15, 0xeb, 0x18
730
731 /*
732  * post-SubByte transform
733  *
734  * post-lookup for sbox3:
735  *  swap_bitendianness(
736  *      camellia_h(
737  *          isom_map_aes_to_camellia(
738  *              swap_bitendianness(
739  *                  aes_inverse_affine_transform(in)
740  *              )
741  *          )
742  *      )
743  *  ) >>> 1
744  *
745  * (note: '⊕ 0x6e' inside camellia_h())
746  */
747 .Lpost_tf_lo_s3:
748         .byte 0x1e, 0x66, 0xe7, 0x9f, 0x19, 0x61, 0xe0, 0x98
749         .byte 0x6e, 0x16, 0x97, 0xef, 0x69, 0x11, 0x90, 0xe8
750 .Lpost_tf_hi_s3:
751         .byte 0x00, 0xfc, 0x43, 0xbf, 0xeb, 0x17, 0xa8, 0x54
752         .byte 0x52, 0xae, 0x11, 0xed, 0xb9, 0x45, 0xfa, 0x06
753
754 /* For isolating SubBytes from AESENCLAST, inverse shift row */
755 .Linv_shift_row:
756         .byte 0x00, 0x0d, 0x0a, 0x07, 0x04, 0x01, 0x0e, 0x0b
757         .byte 0x08, 0x05, 0x02, 0x0f, 0x0c, 0x09, 0x06, 0x03
758
759 /* shuffle mask for 8x8 byte transpose */
760 .Ltranspose_8x8_shuf:
761         .byte 0, 1, 4, 5, 2, 3, 6, 7, 8+0, 8+1, 8+4, 8+5, 8+2, 8+3, 8+6, 8+7
762
763 .align 4
764 /* 4-bit mask */
765 .L0f0f0f0f:
766         .long 0x0f0f0f0f
767
768 .text
769
770 .align 8
771 .type   __camellia_enc_blk16,@function;
772
773 __camellia_enc_blk16:
774         /* input:
775          *      %rdi: ctx, CTX
776          *      %rax: temporary storage, 256 bytes
777          *      %xmm0..%xmm15: 16 plaintext blocks
778          * output:
779          *      %xmm0..%xmm15: 16 encrypted blocks, order swapped:
780          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
781          */
782
783         leaq 8 * 16(%rax), %rcx;
784
785         inpack16_post(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
786                       %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
787                       %xmm15, %rax, %rcx);
788
789         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
790                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
791                      %xmm15, %rax, %rcx, 0);
792
793         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
794               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
795               %xmm15,
796               ((key_table + (8) * 8) + 0)(CTX),
797               ((key_table + (8) * 8) + 4)(CTX),
798               ((key_table + (8) * 8) + 8)(CTX),
799               ((key_table + (8) * 8) + 12)(CTX));
800
801         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
802                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
803                      %xmm15, %rax, %rcx, 8);
804
805         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
806               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
807               %xmm15,
808               ((key_table + (16) * 8) + 0)(CTX),
809               ((key_table + (16) * 8) + 4)(CTX),
810               ((key_table + (16) * 8) + 8)(CTX),
811               ((key_table + (16) * 8) + 12)(CTX));
812
813         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
814                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
815                      %xmm15, %rax, %rcx, 16);
816
817         movl $24, %r8d;
818         cmpl $128, key_bitlength(CTX);
819         jne .Lenc_max32;
820
821 .Lenc_done:
822         /* load CD for output */
823         vmovdqu 0 * 16(%rcx), %xmm8;
824         vmovdqu 1 * 16(%rcx), %xmm9;
825         vmovdqu 2 * 16(%rcx), %xmm10;
826         vmovdqu 3 * 16(%rcx), %xmm11;
827         vmovdqu 4 * 16(%rcx), %xmm12;
828         vmovdqu 5 * 16(%rcx), %xmm13;
829         vmovdqu 6 * 16(%rcx), %xmm14;
830         vmovdqu 7 * 16(%rcx), %xmm15;
831
832         outunpack16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
833                     %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
834                     %xmm15, (key_table)(CTX, %r8, 8), (%rax), 1 * 16(%rax));
835
836         ret;
837
838 .align 8
839 .Lenc_max32:
840         movl $32, %r8d;
841
842         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
843               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
844               %xmm15,
845               ((key_table + (24) * 8) + 0)(CTX),
846               ((key_table + (24) * 8) + 4)(CTX),
847               ((key_table + (24) * 8) + 8)(CTX),
848               ((key_table + (24) * 8) + 12)(CTX));
849
850         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
851                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
852                      %xmm15, %rax, %rcx, 24);
853
854         jmp .Lenc_done;
855 .size __camellia_enc_blk16,.-__camellia_enc_blk16;
856
857 .align 8
858 .type   __camellia_dec_blk16,@function;
859
860 __camellia_dec_blk16:
861         /* input:
862          *      %rdi: ctx, CTX
863          *      %rax: temporary storage, 256 bytes
864          *      %r8d: 24 for 16 byte key, 32 for larger
865          *      %xmm0..%xmm15: 16 encrypted blocks
866          * output:
867          *      %xmm0..%xmm15: 16 plaintext blocks, order swapped:
868          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
869          */
870
871         leaq 8 * 16(%rax), %rcx;
872
873         inpack16_post(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
874                       %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
875                       %xmm15, %rax, %rcx);
876
877         cmpl $32, %r8d;
878         je .Ldec_max32;
879
880 .Ldec_max24:
881         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
882                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
883                      %xmm15, %rax, %rcx, 16);
884
885         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
886               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
887               %xmm15,
888               ((key_table + (16) * 8) + 8)(CTX),
889               ((key_table + (16) * 8) + 12)(CTX),
890               ((key_table + (16) * 8) + 0)(CTX),
891               ((key_table + (16) * 8) + 4)(CTX));
892
893         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
894                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
895                      %xmm15, %rax, %rcx, 8);
896
897         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
898               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
899               %xmm15,
900               ((key_table + (8) * 8) + 8)(CTX),
901               ((key_table + (8) * 8) + 12)(CTX),
902               ((key_table + (8) * 8) + 0)(CTX),
903               ((key_table + (8) * 8) + 4)(CTX));
904
905         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
906                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
907                      %xmm15, %rax, %rcx, 0);
908
909         /* load CD for output */
910         vmovdqu 0 * 16(%rcx), %xmm8;
911         vmovdqu 1 * 16(%rcx), %xmm9;
912         vmovdqu 2 * 16(%rcx), %xmm10;
913         vmovdqu 3 * 16(%rcx), %xmm11;
914         vmovdqu 4 * 16(%rcx), %xmm12;
915         vmovdqu 5 * 16(%rcx), %xmm13;
916         vmovdqu 6 * 16(%rcx), %xmm14;
917         vmovdqu 7 * 16(%rcx), %xmm15;
918
919         outunpack16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
920                     %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
921                     %xmm15, (key_table)(CTX), (%rax), 1 * 16(%rax));
922
923         ret;
924
925 .align 8
926 .Ldec_max32:
927         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
928                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
929                      %xmm15, %rax, %rcx, 24);
930
931         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
932               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
933               %xmm15,
934               ((key_table + (24) * 8) + 8)(CTX),
935               ((key_table + (24) * 8) + 12)(CTX),
936               ((key_table + (24) * 8) + 0)(CTX),
937               ((key_table + (24) * 8) + 4)(CTX));
938
939         jmp .Ldec_max24;
940 .size __camellia_dec_blk16,.-__camellia_dec_blk16;
941
942 #define inc_le128(x, minus_one, tmp) \
943         vpcmpeqq minus_one, x, tmp; \
944         vpsubq minus_one, x, x; \
945         vpslldq $8, tmp, tmp; \
946         vpsubq tmp, x, x;
947
948 .align 8
949 .global _gcry_camellia_aesni_avx_ctr_enc
950 .type   _gcry_camellia_aesni_avx_ctr_enc,@function;
951
952 _gcry_camellia_aesni_avx_ctr_enc:
953         /* input:
954          *      %rdi: ctx, CTX
955          *      %rsi: dst (16 blocks)
956          *      %rdx: src (16 blocks)
957          *      %rcx: iv (big endian, 128bit)
958          */
959
960         subq $(16 * 16), %rsp;
961         movq %rsp, %rax;
962
963         vmovdqa .Lbswap128_mask RIP, %xmm14;
964
965         /* load IV and byteswap */
966         vmovdqu (%rcx), %xmm15;
967         vmovdqu %xmm15, 15 * 16(%rax);
968         vpshufb %xmm14, %xmm15, %xmm0; /* be => le */
969
970         vpcmpeqd %xmm15, %xmm15, %xmm15;
971         vpsrldq $8, %xmm15, %xmm15; /* low: -1, high: 0 */
972
973         /* construct IVs */
974         inc_le128(%xmm0, %xmm15, %xmm13);
975         vpshufb %xmm14, %xmm0, %xmm13;
976         vmovdqu %xmm13, 14 * 16(%rax);
977         inc_le128(%xmm0, %xmm15, %xmm13);
978         vpshufb %xmm14, %xmm0, %xmm13;
979         vmovdqu %xmm13, 13 * 16(%rax);
980         inc_le128(%xmm0, %xmm15, %xmm13);
981         vpshufb %xmm14, %xmm0, %xmm12;
982         inc_le128(%xmm0, %xmm15, %xmm13);
983         vpshufb %xmm14, %xmm0, %xmm11;
984         inc_le128(%xmm0, %xmm15, %xmm13);
985         vpshufb %xmm14, %xmm0, %xmm10;
986         inc_le128(%xmm0, %xmm15, %xmm13);
987         vpshufb %xmm14, %xmm0, %xmm9;
988         inc_le128(%xmm0, %xmm15, %xmm13);
989         vpshufb %xmm14, %xmm0, %xmm8;
990         inc_le128(%xmm0, %xmm15, %xmm13);
991         vpshufb %xmm14, %xmm0, %xmm7;
992         inc_le128(%xmm0, %xmm15, %xmm13);
993         vpshufb %xmm14, %xmm0, %xmm6;
994         inc_le128(%xmm0, %xmm15, %xmm13);
995         vpshufb %xmm14, %xmm0, %xmm5;
996         inc_le128(%xmm0, %xmm15, %xmm13);
997         vpshufb %xmm14, %xmm0, %xmm4;
998         inc_le128(%xmm0, %xmm15, %xmm13);
999         vpshufb %xmm14, %xmm0, %xmm3;
1000         inc_le128(%xmm0, %xmm15, %xmm13);
1001         vpshufb %xmm14, %xmm0, %xmm2;
1002         inc_le128(%xmm0, %xmm15, %xmm13);
1003         vpshufb %xmm14, %xmm0, %xmm1;
1004         inc_le128(%xmm0, %xmm15, %xmm13);
1005         vmovdqa %xmm0, %xmm13;
1006         vpshufb %xmm14, %xmm0, %xmm0;
1007         inc_le128(%xmm13, %xmm15, %xmm14);
1008         vpshufb .Lbswap128_mask RIP, %xmm13, %xmm13; /* le => be */
1009         vmovdqu %xmm13, (%rcx);
1010
1011         /* inpack16_pre: */
1012         vmovq (key_table)(CTX), %xmm15;
1013         vpshufb .Lpack_bswap RIP, %xmm15, %xmm15;
1014         vpxor %xmm0, %xmm15, %xmm0;
1015         vpxor %xmm1, %xmm15, %xmm1;
1016         vpxor %xmm2, %xmm15, %xmm2;
1017         vpxor %xmm3, %xmm15, %xmm3;
1018         vpxor %xmm4, %xmm15, %xmm4;
1019         vpxor %xmm5, %xmm15, %xmm5;
1020         vpxor %xmm6, %xmm15, %xmm6;
1021         vpxor %xmm7, %xmm15, %xmm7;
1022         vpxor %xmm8, %xmm15, %xmm8;
1023         vpxor %xmm9, %xmm15, %xmm9;
1024         vpxor %xmm10, %xmm15, %xmm10;
1025         vpxor %xmm11, %xmm15, %xmm11;
1026         vpxor %xmm12, %xmm15, %xmm12;
1027         vpxor 13 * 16(%rax), %xmm15, %xmm13;
1028         vpxor 14 * 16(%rax), %xmm15, %xmm14;
1029         vpxor 15 * 16(%rax), %xmm15, %xmm15;
1030
1031         call __camellia_enc_blk16;
1032
1033         addq $(16 * 16), %rsp;
1034
1035         vpxor 0 * 16(%rdx), %xmm7, %xmm7;
1036         vpxor 1 * 16(%rdx), %xmm6, %xmm6;
1037         vpxor 2 * 16(%rdx), %xmm5, %xmm5;
1038         vpxor 3 * 16(%rdx), %xmm4, %xmm4;
1039         vpxor 4 * 16(%rdx), %xmm3, %xmm3;
1040         vpxor 5 * 16(%rdx), %xmm2, %xmm2;
1041         vpxor 6 * 16(%rdx), %xmm1, %xmm1;
1042         vpxor 7 * 16(%rdx), %xmm0, %xmm0;
1043         vpxor 8 * 16(%rdx), %xmm15, %xmm15;
1044         vpxor 9 * 16(%rdx), %xmm14, %xmm14;
1045         vpxor 10 * 16(%rdx), %xmm13, %xmm13;
1046         vpxor 11 * 16(%rdx), %xmm12, %xmm12;
1047         vpxor 12 * 16(%rdx), %xmm11, %xmm11;
1048         vpxor 13 * 16(%rdx), %xmm10, %xmm10;
1049         vpxor 14 * 16(%rdx), %xmm9, %xmm9;
1050         vpxor 15 * 16(%rdx), %xmm8, %xmm8;
1051
1052         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1053                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1054                      %xmm8, %rsi);
1055
1056         ret;
1057 .size _gcry_camellia_aesni_avx_ctr_enc,.-_gcry_camellia_aesni_avx_ctr_enc;
1058
1059 .align 8
1060 .global _gcry_camellia_aesni_avx_cbc_dec
1061 .type   _gcry_camellia_aesni_avx_cbc_dec,@function;
1062
1063 _gcry_camellia_aesni_avx_cbc_dec:
1064         /* input:
1065          *      %rdi: ctx, CTX
1066          *      %rsi: dst (16 blocks)
1067          *      %rdx: src (16 blocks)
1068          *      %rcx: iv
1069          */
1070
1071         movq %rcx, %r9;
1072
1073         cmpl $128, key_bitlength(CTX);
1074         movl $32, %r8d;
1075         movl $24, %eax;
1076         cmovel %eax, %r8d; /* max */
1077
1078         inpack16_pre(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
1079                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
1080                      %xmm15, %rdx, (key_table)(CTX, %r8, 8));
1081
1082         subq $(16 * 16), %rsp;
1083         movq %rsp, %rax;
1084
1085         call __camellia_dec_blk16;
1086
1087         addq $(16 * 16), %rsp;
1088
1089         /* XOR output with IV */
1090         vpxor (%r9), %xmm7, %xmm7;
1091         vpxor (0 * 16)(%rdx), %xmm6, %xmm6;
1092         vpxor (1 * 16)(%rdx), %xmm5, %xmm5;
1093         vpxor (2 * 16)(%rdx), %xmm4, %xmm4;
1094         vpxor (3 * 16)(%rdx), %xmm3, %xmm3;
1095         vpxor (4 * 16)(%rdx), %xmm2, %xmm2;
1096         vpxor (5 * 16)(%rdx), %xmm1, %xmm1;
1097         vpxor (6 * 16)(%rdx), %xmm0, %xmm0;
1098         vpxor (7 * 16)(%rdx), %xmm15, %xmm15;
1099         vpxor (8 * 16)(%rdx), %xmm14, %xmm14;
1100         vpxor (9 * 16)(%rdx), %xmm13, %xmm13;
1101         vpxor (10 * 16)(%rdx), %xmm12, %xmm12;
1102         vpxor (11 * 16)(%rdx), %xmm11, %xmm11;
1103         vpxor (12 * 16)(%rdx), %xmm10, %xmm10;
1104         vpxor (13 * 16)(%rdx), %xmm9, %xmm9;
1105         vpxor (14 * 16)(%rdx), %xmm8, %xmm8;
1106         movq (15 * 16 + 0)(%rdx), %r10;
1107         movq (15 * 16 + 8)(%rdx), %r11;
1108         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1109                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1110                      %xmm8, %rsi);
1111
1112         /* store new IV */
1113         movq %r10, (0)(%r9);
1114         movq %r11, (8)(%r9);
1115
1116         ret;
1117 .size _gcry_camellia_aesni_avx_cbc_dec,.-_gcry_camellia_aesni_avx_cbc_dec;
1118
1119 #endif /*defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX_SUPPORT)*/
1120 #endif /*__x86_64*/