camellia-aesni-avx-amd64: Move register clearing to assembly functions
[libgcrypt.git] / cipher / camellia-aesni-avx-amd64.S
1 /* camellia-avx-aesni-amd64.S  -  AES-NI/AVX implementation of Camellia cipher
2  *
3  * Copyright © 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
4  *
5  * This file is part of Libgcrypt.
6  *
7  * Libgcrypt is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU Lesser General Public License as
9  * published by the Free Software Foundation; either version 2.1 of
10  * the License, or (at your option) any later version.
11  *
12  * Libgcrypt is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU Lesser General Public License for more details.
16  *
17  * You should have received a copy of the GNU Lesser General Public
18  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
19  */
20
21 #ifdef __x86_64
22 #include <config.h>
23 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
24     defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX_SUPPORT)
25
26 #ifdef __PIC__
27 #  define RIP (%rip)
28 #else
29 #  define RIP
30 #endif
31
32 #define CAMELLIA_TABLE_BYTE_LEN 272
33
34 /* struct CAMELLIA_context: */
35 #define key_bitlength 0
36 #define key_table 4
37
38 /* register macros */
39 #define CTX %rdi
40 #define RIO %r8
41
42 /**********************************************************************
43   helper macros
44  **********************************************************************/
45 #define filter_8bit(x, lo_t, hi_t, mask4bit, tmp0) \
46         vpand x, mask4bit, tmp0; \
47         vpandn x, mask4bit, x; \
48         vpsrld $4, x, x; \
49         \
50         vpshufb tmp0, lo_t, tmp0; \
51         vpshufb x, hi_t, x; \
52         vpxor tmp0, x, x;
53
54 /**********************************************************************
55   16-way camellia
56  **********************************************************************/
57
58 /*
59  * IN:
60  *   x0..x7: byte-sliced AB state
61  *   mem_cd: register pointer storing CD state
62  *   key: index for key material
63  * OUT:
64  *   x0..x7: new byte-sliced CD state
65  */
66 #define roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, t0, t1, t2, t3, t4, t5, t6, \
67                   t7, mem_cd, key) \
68         /* \
69          * S-function with AES subbytes \
70          */ \
71         vmovdqa .Linv_shift_row RIP, t4; \
72         vbroadcastss .L0f0f0f0f RIP, t7; \
73         vmovdqa .Lpre_tf_lo_s1 RIP, t0; \
74         vmovdqa .Lpre_tf_hi_s1 RIP, t1; \
75         \
76         /* AES inverse shift rows */ \
77         vpshufb t4, x0, x0; \
78         vpshufb t4, x7, x7; \
79         vpshufb t4, x1, x1; \
80         vpshufb t4, x4, x4; \
81         vpshufb t4, x2, x2; \
82         vpshufb t4, x5, x5; \
83         vpshufb t4, x3, x3; \
84         vpshufb t4, x6, x6; \
85         \
86         /* prefilter sboxes 1, 2 and 3 */ \
87         vmovdqa .Lpre_tf_lo_s4 RIP, t2; \
88         vmovdqa .Lpre_tf_hi_s4 RIP, t3; \
89         filter_8bit(x0, t0, t1, t7, t6); \
90         filter_8bit(x7, t0, t1, t7, t6); \
91         filter_8bit(x1, t0, t1, t7, t6); \
92         filter_8bit(x4, t0, t1, t7, t6); \
93         filter_8bit(x2, t0, t1, t7, t6); \
94         filter_8bit(x5, t0, t1, t7, t6); \
95         \
96         /* prefilter sbox 4 */ \
97         vpxor t4, t4, t4; \
98         filter_8bit(x3, t2, t3, t7, t6); \
99         filter_8bit(x6, t2, t3, t7, t6); \
100         \
101         /* AES subbytes + AES shift rows */ \
102         vmovdqa .Lpost_tf_lo_s1 RIP, t0; \
103         vmovdqa .Lpost_tf_hi_s1 RIP, t1; \
104         vaesenclast t4, x0, x0; \
105         vaesenclast t4, x7, x7; \
106         vaesenclast t4, x1, x1; \
107         vaesenclast t4, x4, x4; \
108         vaesenclast t4, x2, x2; \
109         vaesenclast t4, x5, x5; \
110         vaesenclast t4, x3, x3; \
111         vaesenclast t4, x6, x6; \
112         \
113         /* postfilter sboxes 1 and 4 */ \
114         vmovdqa .Lpost_tf_lo_s3 RIP, t2; \
115         vmovdqa .Lpost_tf_hi_s3 RIP, t3; \
116         filter_8bit(x0, t0, t1, t7, t6); \
117         filter_8bit(x7, t0, t1, t7, t6); \
118         filter_8bit(x3, t0, t1, t7, t6); \
119         filter_8bit(x6, t0, t1, t7, t6); \
120         \
121         /* postfilter sbox 3 */ \
122         vmovdqa .Lpost_tf_lo_s2 RIP, t4; \
123         vmovdqa .Lpost_tf_hi_s2 RIP, t5; \
124         filter_8bit(x2, t2, t3, t7, t6); \
125         filter_8bit(x5, t2, t3, t7, t6); \
126         \
127         vpxor t6, t6, t6; \
128         vmovq key, t0; \
129         \
130         /* postfilter sbox 2 */ \
131         filter_8bit(x1, t4, t5, t7, t2); \
132         filter_8bit(x4, t4, t5, t7, t2); \
133         \
134         vpsrldq $5, t0, t5; \
135         vpsrldq $1, t0, t1; \
136         vpsrldq $2, t0, t2; \
137         vpsrldq $3, t0, t3; \
138         vpsrldq $4, t0, t4; \
139         vpshufb t6, t0, t0; \
140         vpshufb t6, t1, t1; \
141         vpshufb t6, t2, t2; \
142         vpshufb t6, t3, t3; \
143         vpshufb t6, t4, t4; \
144         vpsrldq $2, t5, t7; \
145         vpshufb t6, t7, t7; \
146         \
147         /* P-function */ \
148         vpxor x5, x0, x0; \
149         vpxor x6, x1, x1; \
150         vpxor x7, x2, x2; \
151         vpxor x4, x3, x3; \
152         \
153         vpxor x2, x4, x4; \
154         vpxor x3, x5, x5; \
155         vpxor x0, x6, x6; \
156         vpxor x1, x7, x7; \
157         \
158         vpxor x7, x0, x0; \
159         vpxor x4, x1, x1; \
160         vpxor x5, x2, x2; \
161         vpxor x6, x3, x3; \
162         \
163         vpxor x3, x4, x4; \
164         vpxor x0, x5, x5; \
165         vpxor x1, x6, x6; \
166         vpxor x2, x7, x7; /* note: high and low parts swapped */ \
167         \
168         /* Add key material and result to CD (x becomes new CD) */ \
169         \
170         vpxor t3, x4, x4; \
171         vpxor 0 * 16(mem_cd), x4, x4; \
172         \
173         vpxor t2, x5, x5; \
174         vpxor 1 * 16(mem_cd), x5, x5; \
175         \
176         vpsrldq $1, t5, t3; \
177         vpshufb t6, t5, t5; \
178         vpshufb t6, t3, t6; \
179         \
180         vpxor t1, x6, x6; \
181         vpxor 2 * 16(mem_cd), x6, x6; \
182         \
183         vpxor t0, x7, x7; \
184         vpxor 3 * 16(mem_cd), x7, x7; \
185         \
186         vpxor t7, x0, x0; \
187         vpxor 4 * 16(mem_cd), x0, x0; \
188         \
189         vpxor t6, x1, x1; \
190         vpxor 5 * 16(mem_cd), x1, x1; \
191         \
192         vpxor t5, x2, x2; \
193         vpxor 6 * 16(mem_cd), x2, x2; \
194         \
195         vpxor t4, x3, x3; \
196         vpxor 7 * 16(mem_cd), x3, x3;
197
198 /*
199  * IN/OUT:
200  *  x0..x7: byte-sliced AB state preloaded
201  *  mem_ab: byte-sliced AB state in memory
202  *  mem_cb: byte-sliced CD state in memory
203  */
204 #define two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
205                       y6, y7, mem_ab, mem_cd, i, dir, store_ab) \
206         roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
207                   y6, y7, mem_cd, (key_table + (i) * 8)(CTX)); \
208         \
209         vmovdqu x4, 0 * 16(mem_cd); \
210         vmovdqu x5, 1 * 16(mem_cd); \
211         vmovdqu x6, 2 * 16(mem_cd); \
212         vmovdqu x7, 3 * 16(mem_cd); \
213         vmovdqu x0, 4 * 16(mem_cd); \
214         vmovdqu x1, 5 * 16(mem_cd); \
215         vmovdqu x2, 6 * 16(mem_cd); \
216         vmovdqu x3, 7 * 16(mem_cd); \
217         \
218         roundsm16(x4, x5, x6, x7, x0, x1, x2, x3, y0, y1, y2, y3, y4, y5, \
219                   y6, y7, mem_ab, (key_table + ((i) + (dir)) * 8)(CTX)); \
220         \
221         store_ab(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab);
222
223 #define dummy_store(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) /* do nothing */
224
225 #define store_ab_state(x0, x1, x2, x3, x4, x5, x6, x7, mem_ab) \
226         /* Store new AB state */ \
227         vmovdqu x0, 0 * 16(mem_ab); \
228         vmovdqu x1, 1 * 16(mem_ab); \
229         vmovdqu x2, 2 * 16(mem_ab); \
230         vmovdqu x3, 3 * 16(mem_ab); \
231         vmovdqu x4, 4 * 16(mem_ab); \
232         vmovdqu x5, 5 * 16(mem_ab); \
233         vmovdqu x6, 6 * 16(mem_ab); \
234         vmovdqu x7, 7 * 16(mem_ab);
235
236 #define enc_rounds16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
237                       y6, y7, mem_ab, mem_cd, i) \
238         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
239                       y6, y7, mem_ab, mem_cd, (i) + 2, 1, store_ab_state); \
240         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
241                       y6, y7, mem_ab, mem_cd, (i) + 4, 1, store_ab_state); \
242         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
243                       y6, y7, mem_ab, mem_cd, (i) + 6, 1, dummy_store);
244
245 #define dec_rounds16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
246                       y6, y7, mem_ab, mem_cd, i) \
247         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
248                       y6, y7, mem_ab, mem_cd, (i) + 7, -1, store_ab_state); \
249         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
250                       y6, y7, mem_ab, mem_cd, (i) + 5, -1, store_ab_state); \
251         two_roundsm16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
252                       y6, y7, mem_ab, mem_cd, (i) + 3, -1, dummy_store);
253
254 /*
255  * IN:
256  *  v0..3: byte-sliced 32-bit integers
257  * OUT:
258  *  v0..3: (IN <<< 1)
259  */
260 #define rol32_1_16(v0, v1, v2, v3, t0, t1, t2, zero) \
261         vpcmpgtb v0, zero, t0; \
262         vpaddb v0, v0, v0; \
263         vpabsb t0, t0; \
264         \
265         vpcmpgtb v1, zero, t1; \
266         vpaddb v1, v1, v1; \
267         vpabsb t1, t1; \
268         \
269         vpcmpgtb v2, zero, t2; \
270         vpaddb v2, v2, v2; \
271         vpabsb t2, t2; \
272         \
273         vpor t0, v1, v1; \
274         \
275         vpcmpgtb v3, zero, t0; \
276         vpaddb v3, v3, v3; \
277         vpabsb t0, t0; \
278         \
279         vpor t1, v2, v2; \
280         vpor t2, v3, v3; \
281         vpor t0, v0, v0;
282
283 /*
284  * IN:
285  *   r: byte-sliced AB state in memory
286  *   l: byte-sliced CD state in memory
287  * OUT:
288  *   x0..x7: new byte-sliced CD state
289  */
290 #define fls16(l, l0, l1, l2, l3, l4, l5, l6, l7, r, t0, t1, t2, t3, tt0, \
291               tt1, tt2, tt3, kll, klr, krl, krr) \
292         /* \
293          * t0 = kll; \
294          * t0 &= ll; \
295          * lr ^= rol32(t0, 1); \
296          */ \
297         vpxor tt0, tt0, tt0; \
298         vmovd kll, t0; \
299         vpshufb tt0, t0, t3; \
300         vpsrldq $1, t0, t0; \
301         vpshufb tt0, t0, t2; \
302         vpsrldq $1, t0, t0; \
303         vpshufb tt0, t0, t1; \
304         vpsrldq $1, t0, t0; \
305         vpshufb tt0, t0, t0; \
306         \
307         vpand l0, t0, t0; \
308         vpand l1, t1, t1; \
309         vpand l2, t2, t2; \
310         vpand l3, t3, t3; \
311         \
312         rol32_1_16(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
313         \
314         vpxor l4, t0, l4; \
315         vmovdqu l4, 4 * 16(l); \
316         vpxor l5, t1, l5; \
317         vmovdqu l5, 5 * 16(l); \
318         vpxor l6, t2, l6; \
319         vmovdqu l6, 6 * 16(l); \
320         vpxor l7, t3, l7; \
321         vmovdqu l7, 7 * 16(l); \
322         \
323         /* \
324          * t2 = krr; \
325          * t2 |= rr; \
326          * rl ^= t2; \
327          */ \
328         \
329         vmovd krr, t0; \
330         vpshufb tt0, t0, t3; \
331         vpsrldq $1, t0, t0; \
332         vpshufb tt0, t0, t2; \
333         vpsrldq $1, t0, t0; \
334         vpshufb tt0, t0, t1; \
335         vpsrldq $1, t0, t0; \
336         vpshufb tt0, t0, t0; \
337         \
338         vpor 4 * 16(r), t0, t0; \
339         vpor 5 * 16(r), t1, t1; \
340         vpor 6 * 16(r), t2, t2; \
341         vpor 7 * 16(r), t3, t3; \
342         \
343         vpxor 0 * 16(r), t0, t0; \
344         vpxor 1 * 16(r), t1, t1; \
345         vpxor 2 * 16(r), t2, t2; \
346         vpxor 3 * 16(r), t3, t3; \
347         vmovdqu t0, 0 * 16(r); \
348         vmovdqu t1, 1 * 16(r); \
349         vmovdqu t2, 2 * 16(r); \
350         vmovdqu t3, 3 * 16(r); \
351         \
352         /* \
353          * t2 = krl; \
354          * t2 &= rl; \
355          * rr ^= rol32(t2, 1); \
356          */ \
357         vmovd krl, t0; \
358         vpshufb tt0, t0, t3; \
359         vpsrldq $1, t0, t0; \
360         vpshufb tt0, t0, t2; \
361         vpsrldq $1, t0, t0; \
362         vpshufb tt0, t0, t1; \
363         vpsrldq $1, t0, t0; \
364         vpshufb tt0, t0, t0; \
365         \
366         vpand 0 * 16(r), t0, t0; \
367         vpand 1 * 16(r), t1, t1; \
368         vpand 2 * 16(r), t2, t2; \
369         vpand 3 * 16(r), t3, t3; \
370         \
371         rol32_1_16(t3, t2, t1, t0, tt1, tt2, tt3, tt0); \
372         \
373         vpxor 4 * 16(r), t0, t0; \
374         vpxor 5 * 16(r), t1, t1; \
375         vpxor 6 * 16(r), t2, t2; \
376         vpxor 7 * 16(r), t3, t3; \
377         vmovdqu t0, 4 * 16(r); \
378         vmovdqu t1, 5 * 16(r); \
379         vmovdqu t2, 6 * 16(r); \
380         vmovdqu t3, 7 * 16(r); \
381         \
382         /* \
383          * t0 = klr; \
384          * t0 |= lr; \
385          * ll ^= t0; \
386          */ \
387         \
388         vmovd klr, t0; \
389         vpshufb tt0, t0, t3; \
390         vpsrldq $1, t0, t0; \
391         vpshufb tt0, t0, t2; \
392         vpsrldq $1, t0, t0; \
393         vpshufb tt0, t0, t1; \
394         vpsrldq $1, t0, t0; \
395         vpshufb tt0, t0, t0; \
396         \
397         vpor l4, t0, t0; \
398         vpor l5, t1, t1; \
399         vpor l6, t2, t2; \
400         vpor l7, t3, t3; \
401         \
402         vpxor l0, t0, l0; \
403         vmovdqu l0, 0 * 16(l); \
404         vpxor l1, t1, l1; \
405         vmovdqu l1, 1 * 16(l); \
406         vpxor l2, t2, l2; \
407         vmovdqu l2, 2 * 16(l); \
408         vpxor l3, t3, l3; \
409         vmovdqu l3, 3 * 16(l);
410
411 #define transpose_4x4(x0, x1, x2, x3, t1, t2) \
412         vpunpckhdq x1, x0, t2; \
413         vpunpckldq x1, x0, x0; \
414         \
415         vpunpckldq x3, x2, t1; \
416         vpunpckhdq x3, x2, x2; \
417         \
418         vpunpckhqdq t1, x0, x1; \
419         vpunpcklqdq t1, x0, x0; \
420         \
421         vpunpckhqdq x2, t2, x3; \
422         vpunpcklqdq x2, t2, x2;
423
424 #define byteslice_16x16b_fast(a0, b0, c0, d0, a1, b1, c1, d1, a2, b2, c2, d2, \
425                               a3, b3, c3, d3, st0, st1) \
426         vmovdqu d2, st0; \
427         vmovdqu d3, st1; \
428         transpose_4x4(a0, a1, a2, a3, d2, d3); \
429         transpose_4x4(b0, b1, b2, b3, d2, d3); \
430         vmovdqu st0, d2; \
431         vmovdqu st1, d3; \
432         \
433         vmovdqu a0, st0; \
434         vmovdqu a1, st1; \
435         transpose_4x4(c0, c1, c2, c3, a0, a1); \
436         transpose_4x4(d0, d1, d2, d3, a0, a1); \
437         \
438         vmovdqu .Lshufb_16x16b RIP, a0; \
439         vmovdqu st1, a1; \
440         vpshufb a0, a2, a2; \
441         vpshufb a0, a3, a3; \
442         vpshufb a0, b0, b0; \
443         vpshufb a0, b1, b1; \
444         vpshufb a0, b2, b2; \
445         vpshufb a0, b3, b3; \
446         vpshufb a0, a1, a1; \
447         vpshufb a0, c0, c0; \
448         vpshufb a0, c1, c1; \
449         vpshufb a0, c2, c2; \
450         vpshufb a0, c3, c3; \
451         vpshufb a0, d0, d0; \
452         vpshufb a0, d1, d1; \
453         vpshufb a0, d2, d2; \
454         vpshufb a0, d3, d3; \
455         vmovdqu d3, st1; \
456         vmovdqu st0, d3; \
457         vpshufb a0, d3, a0; \
458         vmovdqu d2, st0; \
459         \
460         transpose_4x4(a0, b0, c0, d0, d2, d3); \
461         transpose_4x4(a1, b1, c1, d1, d2, d3); \
462         vmovdqu st0, d2; \
463         vmovdqu st1, d3; \
464         \
465         vmovdqu b0, st0; \
466         vmovdqu b1, st1; \
467         transpose_4x4(a2, b2, c2, d2, b0, b1); \
468         transpose_4x4(a3, b3, c3, d3, b0, b1); \
469         vmovdqu st0, b0; \
470         vmovdqu st1, b1; \
471         /* does not adjust output bytes inside vectors */
472
473 #define transpose_8x8b(a, b, c, d, e, f, g, h, t0, t1, t2, t3, t4) \
474         vpunpcklbw a, b, t0; \
475         vpunpckhbw a, b, b; \
476         \
477         vpunpcklbw c, d, t1; \
478         vpunpckhbw c, d, d; \
479         \
480         vpunpcklbw e, f, t2; \
481         vpunpckhbw e, f, f; \
482         \
483         vpunpcklbw g, h, t3; \
484         vpunpckhbw g, h, h; \
485         \
486         vpunpcklwd t0, t1, g; \
487         vpunpckhwd t0, t1, t0; \
488         \
489         vpunpcklwd b, d, t1; \
490         vpunpckhwd b, d, e; \
491         \
492         vpunpcklwd t2, t3, c; \
493         vpunpckhwd t2, t3, t2; \
494         \
495         vpunpcklwd f, h, t3; \
496         vpunpckhwd f, h, b; \
497         \
498         vpunpcklwd e, b, t4; \
499         vpunpckhwd e, b, b; \
500         \
501         vpunpcklwd t1, t3, e; \
502         vpunpckhwd t1, t3, f; \
503         \
504         vmovdqa .Ltranspose_8x8_shuf RIP, t3; \
505         \
506         vpunpcklwd g, c, d; \
507         vpunpckhwd g, c, c; \
508         \
509         vpunpcklwd t0, t2, t1; \
510         vpunpckhwd t0, t2, h; \
511         \
512         vpunpckhqdq b, h, a; \
513         vpshufb t3, a, a; \
514         vpunpcklqdq b, h, b; \
515         vpshufb t3, b, b; \
516         \
517         vpunpckhqdq e, d, g; \
518         vpshufb t3, g, g; \
519         vpunpcklqdq e, d, h; \
520         vpshufb t3, h, h; \
521         \
522         vpunpckhqdq f, c, e; \
523         vpshufb t3, e, e; \
524         vpunpcklqdq f, c, f; \
525         vpshufb t3, f, f; \
526         \
527         vpunpckhqdq t4, t1, c; \
528         vpshufb t3, c, c; \
529         vpunpcklqdq t4, t1, d; \
530         vpshufb t3, d, d;
531
532 /* load blocks to registers and apply pre-whitening */
533 #define inpack16_pre(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
534                      y6, y7, rio, key) \
535         vmovq key, x0; \
536         vpshufb .Lpack_bswap RIP, x0, x0; \
537         \
538         vpxor 0 * 16(rio), x0, y7; \
539         vpxor 1 * 16(rio), x0, y6; \
540         vpxor 2 * 16(rio), x0, y5; \
541         vpxor 3 * 16(rio), x0, y4; \
542         vpxor 4 * 16(rio), x0, y3; \
543         vpxor 5 * 16(rio), x0, y2; \
544         vpxor 6 * 16(rio), x0, y1; \
545         vpxor 7 * 16(rio), x0, y0; \
546         vpxor 8 * 16(rio), x0, x7; \
547         vpxor 9 * 16(rio), x0, x6; \
548         vpxor 10 * 16(rio), x0, x5; \
549         vpxor 11 * 16(rio), x0, x4; \
550         vpxor 12 * 16(rio), x0, x3; \
551         vpxor 13 * 16(rio), x0, x2; \
552         vpxor 14 * 16(rio), x0, x1; \
553         vpxor 15 * 16(rio), x0, x0;
554
555 /* byteslice pre-whitened blocks and store to temporary memory */
556 #define inpack16_post(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
557                       y6, y7, mem_ab, mem_cd) \
558         byteslice_16x16b_fast(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, \
559                               y4, y5, y6, y7, (mem_ab), (mem_cd)); \
560         \
561         vmovdqu x0, 0 * 16(mem_ab); \
562         vmovdqu x1, 1 * 16(mem_ab); \
563         vmovdqu x2, 2 * 16(mem_ab); \
564         vmovdqu x3, 3 * 16(mem_ab); \
565         vmovdqu x4, 4 * 16(mem_ab); \
566         vmovdqu x5, 5 * 16(mem_ab); \
567         vmovdqu x6, 6 * 16(mem_ab); \
568         vmovdqu x7, 7 * 16(mem_ab); \
569         vmovdqu y0, 0 * 16(mem_cd); \
570         vmovdqu y1, 1 * 16(mem_cd); \
571         vmovdqu y2, 2 * 16(mem_cd); \
572         vmovdqu y3, 3 * 16(mem_cd); \
573         vmovdqu y4, 4 * 16(mem_cd); \
574         vmovdqu y5, 5 * 16(mem_cd); \
575         vmovdqu y6, 6 * 16(mem_cd); \
576         vmovdqu y7, 7 * 16(mem_cd);
577
578 /* de-byteslice, apply post-whitening and store blocks */
579 #define outunpack16(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, \
580                     y5, y6, y7, key, stack_tmp0, stack_tmp1) \
581         byteslice_16x16b_fast(y0, y4, x0, x4, y1, y5, x1, x5, y2, y6, x2, x6, \
582                               y3, y7, x3, x7, stack_tmp0, stack_tmp1); \
583         \
584         vmovdqu x0, stack_tmp0; \
585         \
586         vmovq key, x0; \
587         vpshufb .Lpack_bswap RIP, x0, x0; \
588         \
589         vpxor x0, y7, y7; \
590         vpxor x0, y6, y6; \
591         vpxor x0, y5, y5; \
592         vpxor x0, y4, y4; \
593         vpxor x0, y3, y3; \
594         vpxor x0, y2, y2; \
595         vpxor x0, y1, y1; \
596         vpxor x0, y0, y0; \
597         vpxor x0, x7, x7; \
598         vpxor x0, x6, x6; \
599         vpxor x0, x5, x5; \
600         vpxor x0, x4, x4; \
601         vpxor x0, x3, x3; \
602         vpxor x0, x2, x2; \
603         vpxor x0, x1, x1; \
604         vpxor stack_tmp0, x0, x0;
605
606 #define write_output(x0, x1, x2, x3, x4, x5, x6, x7, y0, y1, y2, y3, y4, y5, \
607                      y6, y7, rio) \
608         vmovdqu x0, 0 * 16(rio); \
609         vmovdqu x1, 1 * 16(rio); \
610         vmovdqu x2, 2 * 16(rio); \
611         vmovdqu x3, 3 * 16(rio); \
612         vmovdqu x4, 4 * 16(rio); \
613         vmovdqu x5, 5 * 16(rio); \
614         vmovdqu x6, 6 * 16(rio); \
615         vmovdqu x7, 7 * 16(rio); \
616         vmovdqu y0, 8 * 16(rio); \
617         vmovdqu y1, 9 * 16(rio); \
618         vmovdqu y2, 10 * 16(rio); \
619         vmovdqu y3, 11 * 16(rio); \
620         vmovdqu y4, 12 * 16(rio); \
621         vmovdqu y5, 13 * 16(rio); \
622         vmovdqu y6, 14 * 16(rio); \
623         vmovdqu y7, 15 * 16(rio);
624
625 .data
626 .align 16
627
628 #define SHUFB_BYTES(idx) \
629         0 + (idx), 4 + (idx), 8 + (idx), 12 + (idx)
630
631 .Lshufb_16x16b:
632         .byte SHUFB_BYTES(0), SHUFB_BYTES(1), SHUFB_BYTES(2), SHUFB_BYTES(3);
633
634 .Lpack_bswap:
635         .long 0x00010203
636         .long 0x04050607
637         .long 0x80808080
638         .long 0x80808080
639
640 /* For CTR-mode IV byteswap */
641 .Lbswap128_mask:
642         .byte 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0
643
644 /*
645  * pre-SubByte transform
646  *
647  * pre-lookup for sbox1, sbox2, sbox3:
648  *   swap_bitendianness(
649  *       isom_map_camellia_to_aes(
650  *           camellia_f(
651  *               swap_bitendianess(in)
652  *           )
653  *       )
654  *   )
655  *
656  * (note: '⊕ 0xc5' inside camellia_f())
657  */
658 .Lpre_tf_lo_s1:
659         .byte 0x45, 0xe8, 0x40, 0xed, 0x2e, 0x83, 0x2b, 0x86
660         .byte 0x4b, 0xe6, 0x4e, 0xe3, 0x20, 0x8d, 0x25, 0x88
661 .Lpre_tf_hi_s1:
662         .byte 0x00, 0x51, 0xf1, 0xa0, 0x8a, 0xdb, 0x7b, 0x2a
663         .byte 0x09, 0x58, 0xf8, 0xa9, 0x83, 0xd2, 0x72, 0x23
664
665 /*
666  * pre-SubByte transform
667  *
668  * pre-lookup for sbox4:
669  *   swap_bitendianness(
670  *       isom_map_camellia_to_aes(
671  *           camellia_f(
672  *               swap_bitendianess(in <<< 1)
673  *           )
674  *       )
675  *   )
676  *
677  * (note: '⊕ 0xc5' inside camellia_f())
678  */
679 .Lpre_tf_lo_s4:
680         .byte 0x45, 0x40, 0x2e, 0x2b, 0x4b, 0x4e, 0x20, 0x25
681         .byte 0x14, 0x11, 0x7f, 0x7a, 0x1a, 0x1f, 0x71, 0x74
682 .Lpre_tf_hi_s4:
683         .byte 0x00, 0xf1, 0x8a, 0x7b, 0x09, 0xf8, 0x83, 0x72
684         .byte 0xad, 0x5c, 0x27, 0xd6, 0xa4, 0x55, 0x2e, 0xdf
685
686 /*
687  * post-SubByte transform
688  *
689  * post-lookup for sbox1, sbox4:
690  *  swap_bitendianness(
691  *      camellia_h(
692  *          isom_map_aes_to_camellia(
693  *              swap_bitendianness(
694  *                  aes_inverse_affine_transform(in)
695  *              )
696  *          )
697  *      )
698  *  )
699  *
700  * (note: '⊕ 0x6e' inside camellia_h())
701  */
702 .Lpost_tf_lo_s1:
703         .byte 0x3c, 0xcc, 0xcf, 0x3f, 0x32, 0xc2, 0xc1, 0x31
704         .byte 0xdc, 0x2c, 0x2f, 0xdf, 0xd2, 0x22, 0x21, 0xd1
705 .Lpost_tf_hi_s1:
706         .byte 0x00, 0xf9, 0x86, 0x7f, 0xd7, 0x2e, 0x51, 0xa8
707         .byte 0xa4, 0x5d, 0x22, 0xdb, 0x73, 0x8a, 0xf5, 0x0c
708
709 /*
710  * post-SubByte transform
711  *
712  * post-lookup for sbox2:
713  *  swap_bitendianness(
714  *      camellia_h(
715  *          isom_map_aes_to_camellia(
716  *              swap_bitendianness(
717  *                  aes_inverse_affine_transform(in)
718  *              )
719  *          )
720  *      )
721  *  ) <<< 1
722  *
723  * (note: '⊕ 0x6e' inside camellia_h())
724  */
725 .Lpost_tf_lo_s2:
726         .byte 0x78, 0x99, 0x9f, 0x7e, 0x64, 0x85, 0x83, 0x62
727         .byte 0xb9, 0x58, 0x5e, 0xbf, 0xa5, 0x44, 0x42, 0xa3
728 .Lpost_tf_hi_s2:
729         .byte 0x00, 0xf3, 0x0d, 0xfe, 0xaf, 0x5c, 0xa2, 0x51
730         .byte 0x49, 0xba, 0x44, 0xb7, 0xe6, 0x15, 0xeb, 0x18
731
732 /*
733  * post-SubByte transform
734  *
735  * post-lookup for sbox3:
736  *  swap_bitendianness(
737  *      camellia_h(
738  *          isom_map_aes_to_camellia(
739  *              swap_bitendianness(
740  *                  aes_inverse_affine_transform(in)
741  *              )
742  *          )
743  *      )
744  *  ) >>> 1
745  *
746  * (note: '⊕ 0x6e' inside camellia_h())
747  */
748 .Lpost_tf_lo_s3:
749         .byte 0x1e, 0x66, 0xe7, 0x9f, 0x19, 0x61, 0xe0, 0x98
750         .byte 0x6e, 0x16, 0x97, 0xef, 0x69, 0x11, 0x90, 0xe8
751 .Lpost_tf_hi_s3:
752         .byte 0x00, 0xfc, 0x43, 0xbf, 0xeb, 0x17, 0xa8, 0x54
753         .byte 0x52, 0xae, 0x11, 0xed, 0xb9, 0x45, 0xfa, 0x06
754
755 /* For isolating SubBytes from AESENCLAST, inverse shift row */
756 .Linv_shift_row:
757         .byte 0x00, 0x0d, 0x0a, 0x07, 0x04, 0x01, 0x0e, 0x0b
758         .byte 0x08, 0x05, 0x02, 0x0f, 0x0c, 0x09, 0x06, 0x03
759
760 /* shuffle mask for 8x8 byte transpose */
761 .Ltranspose_8x8_shuf:
762         .byte 0, 1, 4, 5, 2, 3, 6, 7, 8+0, 8+1, 8+4, 8+5, 8+2, 8+3, 8+6, 8+7
763
764 .align 4
765 /* 4-bit mask */
766 .L0f0f0f0f:
767         .long 0x0f0f0f0f
768
769 .text
770
771 .align 8
772 .type   __camellia_enc_blk16,@function;
773
774 __camellia_enc_blk16:
775         /* input:
776          *      %rdi: ctx, CTX
777          *      %rax: temporary storage, 256 bytes
778          *      %xmm0..%xmm15: 16 plaintext blocks
779          * output:
780          *      %xmm0..%xmm15: 16 encrypted blocks, order swapped:
781          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
782          */
783
784         leaq 8 * 16(%rax), %rcx;
785
786         inpack16_post(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
787                       %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
788                       %xmm15, %rax, %rcx);
789
790         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
791                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
792                      %xmm15, %rax, %rcx, 0);
793
794         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
795               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
796               %xmm15,
797               ((key_table + (8) * 8) + 0)(CTX),
798               ((key_table + (8) * 8) + 4)(CTX),
799               ((key_table + (8) * 8) + 8)(CTX),
800               ((key_table + (8) * 8) + 12)(CTX));
801
802         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
803                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
804                      %xmm15, %rax, %rcx, 8);
805
806         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
807               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
808               %xmm15,
809               ((key_table + (16) * 8) + 0)(CTX),
810               ((key_table + (16) * 8) + 4)(CTX),
811               ((key_table + (16) * 8) + 8)(CTX),
812               ((key_table + (16) * 8) + 12)(CTX));
813
814         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
815                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
816                      %xmm15, %rax, %rcx, 16);
817
818         movl $24, %r8d;
819         cmpl $128, key_bitlength(CTX);
820         jne .Lenc_max32;
821
822 .Lenc_done:
823         /* load CD for output */
824         vmovdqu 0 * 16(%rcx), %xmm8;
825         vmovdqu 1 * 16(%rcx), %xmm9;
826         vmovdqu 2 * 16(%rcx), %xmm10;
827         vmovdqu 3 * 16(%rcx), %xmm11;
828         vmovdqu 4 * 16(%rcx), %xmm12;
829         vmovdqu 5 * 16(%rcx), %xmm13;
830         vmovdqu 6 * 16(%rcx), %xmm14;
831         vmovdqu 7 * 16(%rcx), %xmm15;
832
833         outunpack16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
834                     %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
835                     %xmm15, (key_table)(CTX, %r8, 8), (%rax), 1 * 16(%rax));
836
837         ret;
838
839 .align 8
840 .Lenc_max32:
841         movl $32, %r8d;
842
843         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
844               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
845               %xmm15,
846               ((key_table + (24) * 8) + 0)(CTX),
847               ((key_table + (24) * 8) + 4)(CTX),
848               ((key_table + (24) * 8) + 8)(CTX),
849               ((key_table + (24) * 8) + 12)(CTX));
850
851         enc_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
852                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
853                      %xmm15, %rax, %rcx, 24);
854
855         jmp .Lenc_done;
856 .size __camellia_enc_blk16,.-__camellia_enc_blk16;
857
858 .align 8
859 .type   __camellia_dec_blk16,@function;
860
861 __camellia_dec_blk16:
862         /* input:
863          *      %rdi: ctx, CTX
864          *      %rax: temporary storage, 256 bytes
865          *      %r8d: 24 for 16 byte key, 32 for larger
866          *      %xmm0..%xmm15: 16 encrypted blocks
867          * output:
868          *      %xmm0..%xmm15: 16 plaintext blocks, order swapped:
869          *       7, 8, 6, 5, 4, 3, 2, 1, 0, 15, 14, 13, 12, 11, 10, 9, 8
870          */
871
872         leaq 8 * 16(%rax), %rcx;
873
874         inpack16_post(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
875                       %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
876                       %xmm15, %rax, %rcx);
877
878         cmpl $32, %r8d;
879         je .Ldec_max32;
880
881 .Ldec_max24:
882         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
883                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
884                      %xmm15, %rax, %rcx, 16);
885
886         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
887               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
888               %xmm15,
889               ((key_table + (16) * 8) + 8)(CTX),
890               ((key_table + (16) * 8) + 12)(CTX),
891               ((key_table + (16) * 8) + 0)(CTX),
892               ((key_table + (16) * 8) + 4)(CTX));
893
894         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
895                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
896                      %xmm15, %rax, %rcx, 8);
897
898         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
899               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
900               %xmm15,
901               ((key_table + (8) * 8) + 8)(CTX),
902               ((key_table + (8) * 8) + 12)(CTX),
903               ((key_table + (8) * 8) + 0)(CTX),
904               ((key_table + (8) * 8) + 4)(CTX));
905
906         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
907                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
908                      %xmm15, %rax, %rcx, 0);
909
910         /* load CD for output */
911         vmovdqu 0 * 16(%rcx), %xmm8;
912         vmovdqu 1 * 16(%rcx), %xmm9;
913         vmovdqu 2 * 16(%rcx), %xmm10;
914         vmovdqu 3 * 16(%rcx), %xmm11;
915         vmovdqu 4 * 16(%rcx), %xmm12;
916         vmovdqu 5 * 16(%rcx), %xmm13;
917         vmovdqu 6 * 16(%rcx), %xmm14;
918         vmovdqu 7 * 16(%rcx), %xmm15;
919
920         outunpack16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
921                     %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
922                     %xmm15, (key_table)(CTX), (%rax), 1 * 16(%rax));
923
924         ret;
925
926 .align 8
927 .Ldec_max32:
928         dec_rounds16(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
929                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
930                      %xmm15, %rax, %rcx, 24);
931
932         fls16(%rax, %xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
933               %rcx, %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
934               %xmm15,
935               ((key_table + (24) * 8) + 8)(CTX),
936               ((key_table + (24) * 8) + 12)(CTX),
937               ((key_table + (24) * 8) + 0)(CTX),
938               ((key_table + (24) * 8) + 4)(CTX));
939
940         jmp .Ldec_max24;
941 .size __camellia_dec_blk16,.-__camellia_dec_blk16;
942
943 #define inc_le128(x, minus_one, tmp) \
944         vpcmpeqq minus_one, x, tmp; \
945         vpsubq minus_one, x, x; \
946         vpslldq $8, tmp, tmp; \
947         vpsubq tmp, x, x;
948
949 .align 8
950 .global _gcry_camellia_aesni_avx_ctr_enc
951 .type   _gcry_camellia_aesni_avx_ctr_enc,@function;
952
953 _gcry_camellia_aesni_avx_ctr_enc:
954         /* input:
955          *      %rdi: ctx, CTX
956          *      %rsi: dst (16 blocks)
957          *      %rdx: src (16 blocks)
958          *      %rcx: iv (big endian, 128bit)
959          */
960
961         vzeroupper;
962
963         subq $(16 * 16), %rsp;
964         movq %rsp, %rax;
965
966         vmovdqa .Lbswap128_mask RIP, %xmm14;
967
968         /* load IV and byteswap */
969         vmovdqu (%rcx), %xmm15;
970         vmovdqu %xmm15, 15 * 16(%rax);
971         vpshufb %xmm14, %xmm15, %xmm0; /* be => le */
972
973         vpcmpeqd %xmm15, %xmm15, %xmm15;
974         vpsrldq $8, %xmm15, %xmm15; /* low: -1, high: 0 */
975
976         /* construct IVs */
977         inc_le128(%xmm0, %xmm15, %xmm13);
978         vpshufb %xmm14, %xmm0, %xmm13;
979         vmovdqu %xmm13, 14 * 16(%rax);
980         inc_le128(%xmm0, %xmm15, %xmm13);
981         vpshufb %xmm14, %xmm0, %xmm13;
982         vmovdqu %xmm13, 13 * 16(%rax);
983         inc_le128(%xmm0, %xmm15, %xmm13);
984         vpshufb %xmm14, %xmm0, %xmm12;
985         inc_le128(%xmm0, %xmm15, %xmm13);
986         vpshufb %xmm14, %xmm0, %xmm11;
987         inc_le128(%xmm0, %xmm15, %xmm13);
988         vpshufb %xmm14, %xmm0, %xmm10;
989         inc_le128(%xmm0, %xmm15, %xmm13);
990         vpshufb %xmm14, %xmm0, %xmm9;
991         inc_le128(%xmm0, %xmm15, %xmm13);
992         vpshufb %xmm14, %xmm0, %xmm8;
993         inc_le128(%xmm0, %xmm15, %xmm13);
994         vpshufb %xmm14, %xmm0, %xmm7;
995         inc_le128(%xmm0, %xmm15, %xmm13);
996         vpshufb %xmm14, %xmm0, %xmm6;
997         inc_le128(%xmm0, %xmm15, %xmm13);
998         vpshufb %xmm14, %xmm0, %xmm5;
999         inc_le128(%xmm0, %xmm15, %xmm13);
1000         vpshufb %xmm14, %xmm0, %xmm4;
1001         inc_le128(%xmm0, %xmm15, %xmm13);
1002         vpshufb %xmm14, %xmm0, %xmm3;
1003         inc_le128(%xmm0, %xmm15, %xmm13);
1004         vpshufb %xmm14, %xmm0, %xmm2;
1005         inc_le128(%xmm0, %xmm15, %xmm13);
1006         vpshufb %xmm14, %xmm0, %xmm1;
1007         inc_le128(%xmm0, %xmm15, %xmm13);
1008         vmovdqa %xmm0, %xmm13;
1009         vpshufb %xmm14, %xmm0, %xmm0;
1010         inc_le128(%xmm13, %xmm15, %xmm14);
1011         vpshufb .Lbswap128_mask RIP, %xmm13, %xmm13; /* le => be */
1012         vmovdqu %xmm13, (%rcx);
1013
1014         /* inpack16_pre: */
1015         vmovq (key_table)(CTX), %xmm15;
1016         vpshufb .Lpack_bswap RIP, %xmm15, %xmm15;
1017         vpxor %xmm0, %xmm15, %xmm0;
1018         vpxor %xmm1, %xmm15, %xmm1;
1019         vpxor %xmm2, %xmm15, %xmm2;
1020         vpxor %xmm3, %xmm15, %xmm3;
1021         vpxor %xmm4, %xmm15, %xmm4;
1022         vpxor %xmm5, %xmm15, %xmm5;
1023         vpxor %xmm6, %xmm15, %xmm6;
1024         vpxor %xmm7, %xmm15, %xmm7;
1025         vpxor %xmm8, %xmm15, %xmm8;
1026         vpxor %xmm9, %xmm15, %xmm9;
1027         vpxor %xmm10, %xmm15, %xmm10;
1028         vpxor %xmm11, %xmm15, %xmm11;
1029         vpxor %xmm12, %xmm15, %xmm12;
1030         vpxor 13 * 16(%rax), %xmm15, %xmm13;
1031         vpxor 14 * 16(%rax), %xmm15, %xmm14;
1032         vpxor 15 * 16(%rax), %xmm15, %xmm15;
1033
1034         call __camellia_enc_blk16;
1035
1036         addq $(16 * 16), %rsp;
1037
1038         vpxor 0 * 16(%rdx), %xmm7, %xmm7;
1039         vpxor 1 * 16(%rdx), %xmm6, %xmm6;
1040         vpxor 2 * 16(%rdx), %xmm5, %xmm5;
1041         vpxor 3 * 16(%rdx), %xmm4, %xmm4;
1042         vpxor 4 * 16(%rdx), %xmm3, %xmm3;
1043         vpxor 5 * 16(%rdx), %xmm2, %xmm2;
1044         vpxor 6 * 16(%rdx), %xmm1, %xmm1;
1045         vpxor 7 * 16(%rdx), %xmm0, %xmm0;
1046         vpxor 8 * 16(%rdx), %xmm15, %xmm15;
1047         vpxor 9 * 16(%rdx), %xmm14, %xmm14;
1048         vpxor 10 * 16(%rdx), %xmm13, %xmm13;
1049         vpxor 11 * 16(%rdx), %xmm12, %xmm12;
1050         vpxor 12 * 16(%rdx), %xmm11, %xmm11;
1051         vpxor 13 * 16(%rdx), %xmm10, %xmm10;
1052         vpxor 14 * 16(%rdx), %xmm9, %xmm9;
1053         vpxor 15 * 16(%rdx), %xmm8, %xmm8;
1054
1055         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1056                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1057                      %xmm8, %rsi);
1058
1059         vzeroall;
1060
1061         ret;
1062 .size _gcry_camellia_aesni_avx_ctr_enc,.-_gcry_camellia_aesni_avx_ctr_enc;
1063
1064 .align 8
1065 .global _gcry_camellia_aesni_avx_cbc_dec
1066 .type   _gcry_camellia_aesni_avx_cbc_dec,@function;
1067
1068 _gcry_camellia_aesni_avx_cbc_dec:
1069         /* input:
1070          *      %rdi: ctx, CTX
1071          *      %rsi: dst (16 blocks)
1072          *      %rdx: src (16 blocks)
1073          *      %rcx: iv
1074          */
1075
1076         vzeroupper;
1077
1078         movq %rcx, %r9;
1079
1080         cmpl $128, key_bitlength(CTX);
1081         movl $32, %r8d;
1082         movl $24, %eax;
1083         cmovel %eax, %r8d; /* max */
1084
1085         inpack16_pre(%xmm0, %xmm1, %xmm2, %xmm3, %xmm4, %xmm5, %xmm6, %xmm7,
1086                      %xmm8, %xmm9, %xmm10, %xmm11, %xmm12, %xmm13, %xmm14,
1087                      %xmm15, %rdx, (key_table)(CTX, %r8, 8));
1088
1089         subq $(16 * 16), %rsp;
1090         movq %rsp, %rax;
1091
1092         call __camellia_dec_blk16;
1093
1094         addq $(16 * 16), %rsp;
1095
1096         /* XOR output with IV */
1097         vpxor (%r9), %xmm7, %xmm7;
1098         vpxor (0 * 16)(%rdx), %xmm6, %xmm6;
1099         vpxor (1 * 16)(%rdx), %xmm5, %xmm5;
1100         vpxor (2 * 16)(%rdx), %xmm4, %xmm4;
1101         vpxor (3 * 16)(%rdx), %xmm3, %xmm3;
1102         vpxor (4 * 16)(%rdx), %xmm2, %xmm2;
1103         vpxor (5 * 16)(%rdx), %xmm1, %xmm1;
1104         vpxor (6 * 16)(%rdx), %xmm0, %xmm0;
1105         vpxor (7 * 16)(%rdx), %xmm15, %xmm15;
1106         vpxor (8 * 16)(%rdx), %xmm14, %xmm14;
1107         vpxor (9 * 16)(%rdx), %xmm13, %xmm13;
1108         vpxor (10 * 16)(%rdx), %xmm12, %xmm12;
1109         vpxor (11 * 16)(%rdx), %xmm11, %xmm11;
1110         vpxor (12 * 16)(%rdx), %xmm10, %xmm10;
1111         vpxor (13 * 16)(%rdx), %xmm9, %xmm9;
1112         vpxor (14 * 16)(%rdx), %xmm8, %xmm8;
1113         movq (15 * 16 + 0)(%rdx), %r10;
1114         movq (15 * 16 + 8)(%rdx), %r11;
1115         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1116                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1117                      %xmm8, %rsi);
1118
1119         /* store new IV */
1120         movq %r10, (0)(%r9);
1121         movq %r11, (8)(%r9);
1122
1123         vzeroall;
1124
1125         ret;
1126 .size _gcry_camellia_aesni_avx_cbc_dec,.-_gcry_camellia_aesni_avx_cbc_dec;
1127
1128 .align 8
1129 .global _gcry_camellia_aesni_avx_cfb_dec
1130 .type   _gcry_camellia_aesni_avx_cfb_dec,@function;
1131
1132 _gcry_camellia_aesni_avx_cfb_dec:
1133         /* input:
1134          *      %rdi: ctx, CTX
1135          *      %rsi: dst (16 blocks)
1136          *      %rdx: src (16 blocks)
1137          *      %rcx: iv
1138          */
1139
1140         vzeroupper;
1141
1142         subq $(16 * 16), %rsp;
1143         movq %rsp, %rax;
1144
1145         /* inpack16_pre: */
1146         vmovq (key_table)(CTX), %xmm0;
1147         vpshufb .Lpack_bswap RIP, %xmm0, %xmm0;
1148         vpxor (%rcx), %xmm0, %xmm15;
1149         vmovdqu 15 * 16(%rdx), %xmm1;
1150         vmovdqu %xmm1, (%rcx); /* store new IV */
1151         vpxor 0 * 16(%rdx), %xmm0, %xmm14;
1152         vpxor 1 * 16(%rdx), %xmm0, %xmm13;
1153         vpxor 2 * 16(%rdx), %xmm0, %xmm12;
1154         vpxor 3 * 16(%rdx), %xmm0, %xmm11;
1155         vpxor 4 * 16(%rdx), %xmm0, %xmm10;
1156         vpxor 5 * 16(%rdx), %xmm0, %xmm9;
1157         vpxor 6 * 16(%rdx), %xmm0, %xmm8;
1158         vpxor 7 * 16(%rdx), %xmm0, %xmm7;
1159         vpxor 8 * 16(%rdx), %xmm0, %xmm6;
1160         vpxor 9 * 16(%rdx), %xmm0, %xmm5;
1161         vpxor 10 * 16(%rdx), %xmm0, %xmm4;
1162         vpxor 11 * 16(%rdx), %xmm0, %xmm3;
1163         vpxor 12 * 16(%rdx), %xmm0, %xmm2;
1164         vpxor 13 * 16(%rdx), %xmm0, %xmm1;
1165         vpxor 14 * 16(%rdx), %xmm0, %xmm0;
1166
1167         call __camellia_enc_blk16;
1168
1169         addq $(16 * 16), %rsp;
1170
1171         vpxor 0 * 16(%rdx), %xmm7, %xmm7;
1172         vpxor 1 * 16(%rdx), %xmm6, %xmm6;
1173         vpxor 2 * 16(%rdx), %xmm5, %xmm5;
1174         vpxor 3 * 16(%rdx), %xmm4, %xmm4;
1175         vpxor 4 * 16(%rdx), %xmm3, %xmm3;
1176         vpxor 5 * 16(%rdx), %xmm2, %xmm2;
1177         vpxor 6 * 16(%rdx), %xmm1, %xmm1;
1178         vpxor 7 * 16(%rdx), %xmm0, %xmm0;
1179         vpxor 8 * 16(%rdx), %xmm15, %xmm15;
1180         vpxor 9 * 16(%rdx), %xmm14, %xmm14;
1181         vpxor 10 * 16(%rdx), %xmm13, %xmm13;
1182         vpxor 11 * 16(%rdx), %xmm12, %xmm12;
1183         vpxor 12 * 16(%rdx), %xmm11, %xmm11;
1184         vpxor 13 * 16(%rdx), %xmm10, %xmm10;
1185         vpxor 14 * 16(%rdx), %xmm9, %xmm9;
1186         vpxor 15 * 16(%rdx), %xmm8, %xmm8;
1187
1188         write_output(%xmm7, %xmm6, %xmm5, %xmm4, %xmm3, %xmm2, %xmm1, %xmm0,
1189                      %xmm15, %xmm14, %xmm13, %xmm12, %xmm11, %xmm10, %xmm9,
1190                      %xmm8, %rsi);
1191
1192         vzeroall;
1193
1194         ret;
1195 .size _gcry_camellia_aesni_avx_cfb_dec,.-_gcry_camellia_aesni_avx_cfb_dec;
1196
1197 #endif /*defined(ENABLE_AESNI_SUPPORT) && defined(ENABLE_AVX_SUPPORT)*/
1198 #endif /*__x86_64*/