More optimized CRC implementations
[libgcrypt.git] / cipher / sha1-avx-amd64.S
1 /* sha1-avx-amd64.S - Intel AVX accelerated SHA-1 transform function
2  * Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * Based on sha1.c:
5  *  Copyright (C) 1998, 2001, 2002, 2003, 2008 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
21  */
22
23 /*
24  * Intel SSSE3 accelerated SHA-1 implementation based on white paper:
25  *  "Improving the Performance of the Secure Hash Algorithm (SHA-1)"
26  *  http://software.intel.com/en-us/articles/improving-the-performance-of-the-secure-hash-algorithm-1
27  */
28
29 #ifdef __x86_64__
30 #include <config.h>
31
32 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
33      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
34     defined(HAVE_GCC_INLINE_ASM_BMI2) && \
35     defined(HAVE_GCC_INLINE_ASM_AVX2) && defined(USE_SHA1)
36
37 #ifdef __PIC__
38 #  define RIP (%rip)
39 #else
40 #  define RIP
41 #endif
42
43
44 #ifdef HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS
45 # define ELF(...) __VA_ARGS__
46 #else
47 # define ELF(...) /*_*/
48 #endif
49
50
51 /* Context structure */
52
53 #define state_h0 0
54 #define state_h1 4
55 #define state_h2 8
56 #define state_h3 12
57 #define state_h4 16
58
59
60 /* Constants */
61
62 .data
63 #define K1  0x5A827999
64 #define K2  0x6ED9EBA1
65 #define K3  0x8F1BBCDC
66 #define K4  0xCA62C1D6
67 .align 16
68 .LK_XMM:
69 .LK1:   .long K1, K1, K1, K1
70 .LK2:   .long K2, K2, K2, K2
71 .LK3:   .long K3, K3, K3, K3
72 .LK4:   .long K4, K4, K4, K4
73
74 .Lbswap_shufb_ctl:
75         .long 0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
76
77
78 /* Register macros */
79
80 #define RSTATE %r8
81 #define RDATA %r9
82 #define ROLDSTACK %r10
83 #define RNBLKS %r11
84
85 #define a %eax
86 #define b %ebx
87 #define c %ecx
88 #define d %edx
89 #define e %edi
90
91 #define RT0 %esi
92 #define RT1 %ebp
93
94 #define Wtmp0 %xmm0
95 #define Wtmp1 %xmm1
96
97 #define W0 %xmm2
98 #define W1 %xmm3
99 #define W2 %xmm4
100 #define W3 %xmm5
101 #define W4 %xmm6
102 #define W5 %xmm7
103 #define W6 %xmm8
104 #define W7 %xmm9
105
106 #define BSWAP_REG %xmm10
107
108
109 /* Round function macros. */
110
111 #define WK(i) (((i) & 15) * 4)(%rsp)
112
113 #define R_F1(a,b,c,d,e,i) \
114         movl c, RT0; \
115         addl WK(i), e; \
116         xorl d, RT0; \
117         movl a, RT1; \
118         andl b, RT0; \
119         shldl $30, b, b; \
120         xorl d, RT0; \
121         leal (RT0,e), e; \
122         shldl $5, RT1, RT1; \
123         addl RT1, e;
124
125 #define R_F2(a,b,c,d,e,i) \
126         movl c, RT0; \
127         addl WK(i), e; \
128         xorl b, RT0; \
129         shldl $30, b, b; \
130         xorl d, RT0; \
131         movl a, RT1; \
132         leal (RT0,e), e; \
133         shldl $5, RT1, RT1; \
134         addl RT1, e;
135
136 #define R_F3(a,b,c,d,e,i) \
137         movl c, RT0; \
138         movl b, RT1; \
139         xorl b, RT0; \
140         andl c, RT1; \
141         andl d, RT0; \
142         addl RT1, e; \
143         addl WK(i), e; \
144         shldl $30, b, b; \
145         movl a, RT1; \
146         leal (RT0,e), e; \
147         shldl $5, RT1, RT1; \
148         addl RT1, e;
149
150 #define R_F4(a,b,c,d,e,i) R_F2(a,b,c,d,e,i)
151
152 #define R(a,b,c,d,e,f,i) \
153         R_##f(a,b,c,d,e,i)
154
155
156 /* Input expansion macros. */
157
158 #define W_PRECALC_00_15_0(i, W, tmp0) \
159         vmovdqu (4*(i))(RDATA), tmp0;
160
161 #define W_PRECALC_00_15_1(i, W, tmp0) \
162         vpshufb BSWAP_REG, tmp0, W;
163
164 #define W_PRECALC_00_15_2(i, W, tmp0) \
165         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0;
166
167 #define W_PRECALC_00_15_3(i, W, tmp0) \
168         vmovdqa tmp0, WK(i&~3);
169
170 #define W_PRECALC_16_31_0(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
171         vpalignr $8, W_m16, W_m12, W; \
172         vpsrldq $4, W_m04, tmp0; \
173         vpxor W_m08, W, W;
174
175 #define W_PRECALC_16_31_1(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
176         vpxor W_m16, tmp0, tmp0; \
177         vpxor tmp0, W, W; \
178         vpslld $1, W, tmp0; \
179         vpslldq $12, W, tmp1; \
180         vpsrld $31, W, W;
181
182 #define W_PRECALC_16_31_2(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
183         vpor W, tmp0, tmp0; \
184         vpsrld $30, tmp1, W; \
185         vpslld $2, tmp1, tmp1;
186
187 #define W_PRECALC_16_31_3(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
188         vpxor W, tmp0, tmp0; \
189         vpxor tmp1, tmp0, W; \
190         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
191         vmovdqa tmp0, WK((i)&~3);
192
193 #define W_PRECALC_32_79_0(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
194         vpxor W_m28, W, W; \
195         vpalignr $8, W_m08, W_m04, tmp0;
196
197 #define W_PRECALC_32_79_1(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
198         vpxor W_m16, W, W; \
199         vpxor tmp0, W, W;
200
201 #define W_PRECALC_32_79_2(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
202         vpsrld $30, W, tmp0; \
203         vpslld $2, W, W;
204
205 #define W_PRECALC_32_79_3(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
206         vpor W, tmp0, W; \
207         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
208         vmovdqa tmp0, WK((i)&~3);
209
210
211 /*
212  * Transform nblks*64 bytes (nblks*16 32-bit words) at DATA.
213  *
214  * unsigned int
215  * _gcry_sha1_transform_amd64_avx (void *ctx, const unsigned char *data,
216  *                                  size_t nblks)
217  */
218 .text
219 .globl _gcry_sha1_transform_amd64_avx
220 ELF(.type _gcry_sha1_transform_amd64_avx,@function)
221 .align 16
222 _gcry_sha1_transform_amd64_avx:
223   /* input:
224    *    %rdi: ctx, CTX
225    *    %rsi: data (64*nblks bytes)
226    *    %rdx: nblks
227    */
228
229   xorl %eax, %eax;
230   cmpq $0, %rdx;
231   jz .Lret;
232
233   vzeroupper;
234
235   movq %rdx, RNBLKS;
236   movq %rdi, RSTATE;
237   movq %rsi, RDATA;
238   pushq %rbx;
239   pushq %rbp;
240
241   movq %rsp, ROLDSTACK;
242
243   subq $(16*4), %rsp;
244   andq $(~31), %rsp;
245
246   /* Get the values of the chaining variables. */
247   movl state_h0(RSTATE), a;
248   movl state_h1(RSTATE), b;
249   movl state_h2(RSTATE), c;
250   movl state_h3(RSTATE), d;
251   movl state_h4(RSTATE), e;
252
253   movdqa .Lbswap_shufb_ctl RIP, BSWAP_REG;
254
255   /* Precalc 0-15. */
256   W_PRECALC_00_15_0(0, W0, Wtmp0);
257   W_PRECALC_00_15_1(1, W0, Wtmp0);
258   W_PRECALC_00_15_2(2, W0, Wtmp0);
259   W_PRECALC_00_15_3(3, W0, Wtmp0);
260   W_PRECALC_00_15_0(4, W7, Wtmp0);
261   W_PRECALC_00_15_1(5, W7, Wtmp0);
262   W_PRECALC_00_15_2(6, W7, Wtmp0);
263   W_PRECALC_00_15_3(7, W7, Wtmp0);
264   W_PRECALC_00_15_0(8, W6, Wtmp0);
265   W_PRECALC_00_15_1(9, W6, Wtmp0);
266   W_PRECALC_00_15_2(10, W6, Wtmp0);
267   W_PRECALC_00_15_3(11, W6, Wtmp0);
268   W_PRECALC_00_15_0(12, W5, Wtmp0);
269   W_PRECALC_00_15_1(13, W5, Wtmp0);
270   W_PRECALC_00_15_2(14, W5, Wtmp0);
271   W_PRECALC_00_15_3(15, W5, Wtmp0);
272
273 .align 8
274 .Loop:
275   addq $64, RDATA;
276
277   /* Transform 0-15 + Precalc 16-31. */
278   R( a, b, c, d, e, F1,  0 ); W_PRECALC_16_31_0(16, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
279   R( e, a, b, c, d, F1,  1 ); W_PRECALC_16_31_1(17, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
280   R( d, e, a, b, c, F1,  2 ); W_PRECALC_16_31_2(18, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
281   R( c, d, e, a, b, F1,  3 ); W_PRECALC_16_31_3(19, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
282   R( b, c, d, e, a, F1,  4 ); W_PRECALC_16_31_0(20, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
283   R( a, b, c, d, e, F1,  5 ); W_PRECALC_16_31_1(21, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
284   R( e, a, b, c, d, F1,  6 ); W_PRECALC_16_31_2(22, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
285   R( d, e, a, b, c, F1,  7 ); W_PRECALC_16_31_3(23, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
286   R( c, d, e, a, b, F1,  8 ); W_PRECALC_16_31_0(24, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
287   R( b, c, d, e, a, F1,  9 ); W_PRECALC_16_31_1(25, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
288   R( a, b, c, d, e, F1, 10 ); W_PRECALC_16_31_2(26, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
289   R( e, a, b, c, d, F1, 11 ); W_PRECALC_16_31_3(27, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
290   R( d, e, a, b, c, F1, 12 ); W_PRECALC_16_31_0(28, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
291   R( c, d, e, a, b, F1, 13 ); W_PRECALC_16_31_1(29, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
292   R( b, c, d, e, a, F1, 14 ); W_PRECALC_16_31_2(30, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
293   R( a, b, c, d, e, F1, 15 ); W_PRECALC_16_31_3(31, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
294
295   /* Transform 16-63 + Precalc 32-79. */
296   R( e, a, b, c, d, F1, 16 ); W_PRECALC_32_79_0(32, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
297   R( d, e, a, b, c, F1, 17 ); W_PRECALC_32_79_1(33, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
298   R( c, d, e, a, b, F1, 18 ); W_PRECALC_32_79_2(34, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
299   R( b, c, d, e, a, F1, 19 ); W_PRECALC_32_79_3(35, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
300   R( a, b, c, d, e, F2, 20 ); W_PRECALC_32_79_0(36, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
301   R( e, a, b, c, d, F2, 21 ); W_PRECALC_32_79_1(37, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
302   R( d, e, a, b, c, F2, 22 ); W_PRECALC_32_79_2(38, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
303   R( c, d, e, a, b, F2, 23 ); W_PRECALC_32_79_3(39, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
304   R( b, c, d, e, a, F2, 24 ); W_PRECALC_32_79_0(40, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
305   R( a, b, c, d, e, F2, 25 ); W_PRECALC_32_79_1(41, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
306   R( e, a, b, c, d, F2, 26 ); W_PRECALC_32_79_2(42, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
307   R( d, e, a, b, c, F2, 27 ); W_PRECALC_32_79_3(43, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
308   R( c, d, e, a, b, F2, 28 ); W_PRECALC_32_79_0(44, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
309   R( b, c, d, e, a, F2, 29 ); W_PRECALC_32_79_1(45, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
310   R( a, b, c, d, e, F2, 30 ); W_PRECALC_32_79_2(46, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
311   R( e, a, b, c, d, F2, 31 ); W_PRECALC_32_79_3(47, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
312   R( d, e, a, b, c, F2, 32 ); W_PRECALC_32_79_0(48, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
313   R( c, d, e, a, b, F2, 33 ); W_PRECALC_32_79_1(49, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
314   R( b, c, d, e, a, F2, 34 ); W_PRECALC_32_79_2(50, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
315   R( a, b, c, d, e, F2, 35 ); W_PRECALC_32_79_3(51, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
316   R( e, a, b, c, d, F2, 36 ); W_PRECALC_32_79_0(52, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
317   R( d, e, a, b, c, F2, 37 ); W_PRECALC_32_79_1(53, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
318   R( c, d, e, a, b, F2, 38 ); W_PRECALC_32_79_2(54, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
319   R( b, c, d, e, a, F2, 39 ); W_PRECALC_32_79_3(55, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
320   R( a, b, c, d, e, F3, 40 ); W_PRECALC_32_79_0(56, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
321   R( e, a, b, c, d, F3, 41 ); W_PRECALC_32_79_1(57, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
322   R( d, e, a, b, c, F3, 42 ); W_PRECALC_32_79_2(58, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
323   R( c, d, e, a, b, F3, 43 ); W_PRECALC_32_79_3(59, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
324   R( b, c, d, e, a, F3, 44 ); W_PRECALC_32_79_0(60, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
325   R( a, b, c, d, e, F3, 45 ); W_PRECALC_32_79_1(61, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
326   R( e, a, b, c, d, F3, 46 ); W_PRECALC_32_79_2(62, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
327   R( d, e, a, b, c, F3, 47 ); W_PRECALC_32_79_3(63, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
328   R( c, d, e, a, b, F3, 48 ); W_PRECALC_32_79_0(64, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
329   R( b, c, d, e, a, F3, 49 ); W_PRECALC_32_79_1(65, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
330   R( a, b, c, d, e, F3, 50 ); W_PRECALC_32_79_2(66, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
331   R( e, a, b, c, d, F3, 51 ); W_PRECALC_32_79_3(67, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
332   R( d, e, a, b, c, F3, 52 ); W_PRECALC_32_79_0(68, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
333   R( c, d, e, a, b, F3, 53 ); W_PRECALC_32_79_1(69, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
334   R( b, c, d, e, a, F3, 54 ); W_PRECALC_32_79_2(70, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
335   R( a, b, c, d, e, F3, 55 ); W_PRECALC_32_79_3(71, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
336   R( e, a, b, c, d, F3, 56 ); W_PRECALC_32_79_0(72, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
337   R( d, e, a, b, c, F3, 57 ); W_PRECALC_32_79_1(73, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
338   R( c, d, e, a, b, F3, 58 ); W_PRECALC_32_79_2(74, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
339   R( b, c, d, e, a, F3, 59 ); W_PRECALC_32_79_3(75, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
340   R( a, b, c, d, e, F4, 60 ); W_PRECALC_32_79_0(76, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
341   R( e, a, b, c, d, F4, 61 ); W_PRECALC_32_79_1(77, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
342   R( d, e, a, b, c, F4, 62 ); W_PRECALC_32_79_2(78, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
343   R( c, d, e, a, b, F4, 63 ); W_PRECALC_32_79_3(79, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
344
345   decq RNBLKS;
346   jz .Lend;
347
348   /* Transform 64-79 + Precalc 0-15 of next block. */
349   R( b, c, d, e, a, F4, 64 ); W_PRECALC_00_15_0(0, W0, Wtmp0);
350   R( a, b, c, d, e, F4, 65 ); W_PRECALC_00_15_1(1, W0, Wtmp0);
351   R( e, a, b, c, d, F4, 66 ); W_PRECALC_00_15_2(2, W0, Wtmp0);
352   R( d, e, a, b, c, F4, 67 ); W_PRECALC_00_15_3(3, W0, Wtmp0);
353   R( c, d, e, a, b, F4, 68 ); W_PRECALC_00_15_0(4, W7, Wtmp0);
354   R( b, c, d, e, a, F4, 69 ); W_PRECALC_00_15_1(5, W7, Wtmp0);
355   R( a, b, c, d, e, F4, 70 ); W_PRECALC_00_15_2(6, W7, Wtmp0);
356   R( e, a, b, c, d, F4, 71 ); W_PRECALC_00_15_3(7, W7, Wtmp0);
357   R( d, e, a, b, c, F4, 72 ); W_PRECALC_00_15_0(8, W6, Wtmp0);
358   R( c, d, e, a, b, F4, 73 ); W_PRECALC_00_15_1(9, W6, Wtmp0);
359   R( b, c, d, e, a, F4, 74 ); W_PRECALC_00_15_2(10, W6, Wtmp0);
360   R( a, b, c, d, e, F4, 75 ); W_PRECALC_00_15_3(11, W6, Wtmp0);
361   R( e, a, b, c, d, F4, 76 ); W_PRECALC_00_15_0(12, W5, Wtmp0);
362   R( d, e, a, b, c, F4, 77 ); W_PRECALC_00_15_1(13, W5, Wtmp0);
363   R( c, d, e, a, b, F4, 78 );
364   addl state_h0(RSTATE), a;   W_PRECALC_00_15_2(14, W5, Wtmp0);
365   R( b, c, d, e, a, F4, 79 ); W_PRECALC_00_15_3(15, W5, Wtmp0);
366
367   /* Update the chaining variables. */
368   addl state_h3(RSTATE), d;
369   addl state_h2(RSTATE), c;
370   addl state_h1(RSTATE), b;
371   addl state_h4(RSTATE), e;
372
373   movl d, state_h3(RSTATE);
374   movl c, state_h2(RSTATE);
375   movl b, state_h1(RSTATE);
376   movl a, state_h0(RSTATE);
377   movl e, state_h4(RSTATE);
378
379   jmp .Loop;
380
381 .align 16
382 .Lend:
383   vzeroall;
384
385   /* Transform 64-79. */
386   R( b, c, d, e, a, F4, 64 );
387   R( a, b, c, d, e, F4, 65 );
388   R( e, a, b, c, d, F4, 66 );
389   R( d, e, a, b, c, F4, 67 );
390   R( c, d, e, a, b, F4, 68 );
391   R( b, c, d, e, a, F4, 69 );
392   R( a, b, c, d, e, F4, 70 );
393   R( e, a, b, c, d, F4, 71 );
394   R( d, e, a, b, c, F4, 72 );
395   R( c, d, e, a, b, F4, 73 );
396   R( b, c, d, e, a, F4, 74 );
397   R( a, b, c, d, e, F4, 75 );
398   R( e, a, b, c, d, F4, 76 );
399   R( d, e, a, b, c, F4, 77 );
400   R( c, d, e, a, b, F4, 78 );
401   addl state_h0(RSTATE), a;
402   R( b, c, d, e, a, F4, 79 );
403
404   /* Update the chaining variables. */
405   addl state_h3(RSTATE), d;
406   addl state_h2(RSTATE), c;
407   addl state_h1(RSTATE), b;
408   addl state_h4(RSTATE), e;
409
410   movl d, state_h3(RSTATE);
411   movl c, state_h2(RSTATE);
412   movl b, state_h1(RSTATE);
413   movl a, state_h0(RSTATE);
414   movl e, state_h4(RSTATE);
415
416   movq ROLDSTACK, %rsp;
417
418   popq %rbp;
419   popq %rbx;
420
421   /* burn_stack */
422   movl $(16*4 + 2*8 + 31), %eax;
423
424 .Lret:
425   ret;
426
427 #endif
428 #endif