bufhelp: use one-byte aligned type for unaligned memory accesses
[libgcrypt.git] / cipher / sha1-avx-amd64.S
1 /* sha1-avx-amd64.S - Intel AVX accelerated SHA-1 transform function
2  * Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * Based on sha1.c:
5  *  Copyright (C) 1998, 2001, 2002, 2003, 2008 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
21  */
22
23 /*
24  * Intel SSSE3 accelerated SHA-1 implementation based on white paper:
25  *  "Improving the Performance of the Secure Hash Algorithm (SHA-1)"
26  *  http://software.intel.com/en-us/articles/improving-the-performance-of-the-secure-hash-algorithm-1
27  */
28
29 #ifdef __x86_64__
30 #include <config.h>
31
32 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
33     defined(HAVE_GCC_INLINE_ASM_BMI2) && \
34     defined(HAVE_GCC_INLINE_ASM_AVX2) && defined(USE_SHA1)
35
36 #ifdef __PIC__
37 #  define RIP (%rip)
38 #else
39 #  define RIP
40 #endif
41
42
43 /* Context structure */
44
45 #define state_h0 0
46 #define state_h1 4
47 #define state_h2 8
48 #define state_h3 12
49 #define state_h4 16
50
51
52 /* Constants */
53
54 .data
55 #define K1  0x5A827999
56 #define K2  0x6ED9EBA1
57 #define K3  0x8F1BBCDC
58 #define K4  0xCA62C1D6
59 .align 16
60 .LK_XMM:
61 .LK1:   .long K1, K1, K1, K1
62 .LK2:   .long K2, K2, K2, K2
63 .LK3:   .long K3, K3, K3, K3
64 .LK4:   .long K4, K4, K4, K4
65
66 .Lbswap_shufb_ctl:
67         .long 0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
68
69
70 /* Register macros */
71
72 #define RSTATE %r8
73 #define RDATA %r9
74 #define ROLDSTACK %r10
75 #define RNBLKS %r11
76
77 #define a %eax
78 #define b %ebx
79 #define c %ecx
80 #define d %edx
81 #define e %edi
82
83 #define RT0 %esi
84 #define RT1 %ebp
85
86 #define Wtmp0 %xmm0
87 #define Wtmp1 %xmm1
88
89 #define W0 %xmm2
90 #define W1 %xmm3
91 #define W2 %xmm4
92 #define W3 %xmm5
93 #define W4 %xmm6
94 #define W5 %xmm7
95 #define W6 %xmm8
96 #define W7 %xmm9
97
98 #define BSWAP_REG %xmm10
99
100
101 /* Round function macros. */
102
103 #define WK(i) (((i) & 15) * 4)(%rsp)
104
105 #define R_F1(a,b,c,d,e,i) \
106         movl c, RT0; \
107         addl WK(i), e; \
108         xorl d, RT0; \
109         movl a, RT1; \
110         andl b, RT0; \
111         shldl $30, b, b; \
112         xorl d, RT0; \
113         leal (RT0,e), e; \
114         shldl $5, RT1, RT1; \
115         addl RT1, e;
116
117 #define R_F2(a,b,c,d,e,i) \
118         movl c, RT0; \
119         addl WK(i), e; \
120         xorl b, RT0; \
121         shldl $30, b, b; \
122         xorl d, RT0; \
123         movl a, RT1; \
124         leal (RT0,e), e; \
125         shldl $5, RT1, RT1; \
126         addl RT1, e;
127
128 #define R_F3(a,b,c,d,e,i) \
129         movl c, RT0; \
130         movl b, RT1; \
131         xorl b, RT0; \
132         andl c, RT1; \
133         andl d, RT0; \
134         addl RT1, e; \
135         addl WK(i), e; \
136         shldl $30, b, b; \
137         movl a, RT1; \
138         leal (RT0,e), e; \
139         shldl $5, RT1, RT1; \
140         addl RT1, e;
141
142 #define R_F4(a,b,c,d,e,i) R_F2(a,b,c,d,e,i)
143
144 #define R(a,b,c,d,e,f,i) \
145         R_##f(a,b,c,d,e,i)
146
147
148 /* Input expansion macros. */
149
150 #define W_PRECALC_00_15_0(i, W, tmp0) \
151         vmovdqu (4*(i))(RDATA), tmp0;
152
153 #define W_PRECALC_00_15_1(i, W, tmp0) \
154         vpshufb BSWAP_REG, tmp0, W;
155
156 #define W_PRECALC_00_15_2(i, W, tmp0) \
157         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0;
158
159 #define W_PRECALC_00_15_3(i, W, tmp0) \
160         vmovdqa tmp0, WK(i&~3);
161
162 #define W_PRECALC_16_31_0(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
163         vpalignr $8, W_m16, W_m12, W; \
164         vpsrldq $4, W_m04, tmp0; \
165         vpxor W_m08, W, W;
166
167 #define W_PRECALC_16_31_1(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
168         vpxor W_m16, tmp0, tmp0; \
169         vpxor tmp0, W, W; \
170         vpslld $1, W, tmp0; \
171         vpslldq $12, W, tmp1; \
172         vpsrld $31, W, W;
173
174 #define W_PRECALC_16_31_2(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
175         vpor W, tmp0, tmp0; \
176         vpsrld $30, tmp1, W; \
177         vpslld $2, tmp1, tmp1;
178
179 #define W_PRECALC_16_31_3(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
180         vpxor W, tmp0, tmp0; \
181         vpxor tmp1, tmp0, W; \
182         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
183         vmovdqa tmp0, WK((i)&~3);
184
185 #define W_PRECALC_32_79_0(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
186         vpxor W_m28, W, W; \
187         vpalignr $8, W_m08, W_m04, tmp0;
188
189 #define W_PRECALC_32_79_1(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
190         vpxor W_m16, W, W; \
191         vpxor tmp0, W, W;
192
193 #define W_PRECALC_32_79_2(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
194         vpsrld $30, W, tmp0; \
195         vpslld $2, W, W;
196
197 #define W_PRECALC_32_79_3(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
198         vpor W, tmp0, W; \
199         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
200         vmovdqa tmp0, WK((i)&~3);
201
202
203 /*
204  * Transform nblks*64 bytes (nblks*16 32-bit words) at DATA.
205  *
206  * unsigned int
207  * _gcry_sha1_transform_amd64_avx (void *ctx, const unsigned char *data,
208  *                                  size_t nblks)
209  */
210 .text
211 .globl _gcry_sha1_transform_amd64_avx
212 .type _gcry_sha1_transform_amd64_avx,@function
213 .align 16
214 _gcry_sha1_transform_amd64_avx:
215   /* input:
216    *    %rdi: ctx, CTX
217    *    %rsi: data (64*nblks bytes)
218    *    %rdx: nblks
219    */
220
221   xorl %eax, %eax;
222   cmpq $0, %rdx;
223   jz .Lret;
224
225   vzeroupper;
226
227   movq %rdx, RNBLKS;
228   movq %rdi, RSTATE;
229   movq %rsi, RDATA;
230   pushq %rbx;
231   pushq %rbp;
232
233   movq %rsp, ROLDSTACK;
234
235   subq $(16*4), %rsp;
236   andq $(~31), %rsp;
237
238   /* Get the values of the chaining variables. */
239   movl state_h0(RSTATE), a;
240   movl state_h1(RSTATE), b;
241   movl state_h2(RSTATE), c;
242   movl state_h3(RSTATE), d;
243   movl state_h4(RSTATE), e;
244
245   movdqa .Lbswap_shufb_ctl RIP, BSWAP_REG;
246
247   /* Precalc 0-15. */
248   W_PRECALC_00_15_0(0, W0, Wtmp0);
249   W_PRECALC_00_15_1(1, W0, Wtmp0);
250   W_PRECALC_00_15_2(2, W0, Wtmp0);
251   W_PRECALC_00_15_3(3, W0, Wtmp0);
252   W_PRECALC_00_15_0(4, W7, Wtmp0);
253   W_PRECALC_00_15_1(5, W7, Wtmp0);
254   W_PRECALC_00_15_2(6, W7, Wtmp0);
255   W_PRECALC_00_15_3(7, W7, Wtmp0);
256   W_PRECALC_00_15_0(8, W6, Wtmp0);
257   W_PRECALC_00_15_1(9, W6, Wtmp0);
258   W_PRECALC_00_15_2(10, W6, Wtmp0);
259   W_PRECALC_00_15_3(11, W6, Wtmp0);
260   W_PRECALC_00_15_0(12, W5, Wtmp0);
261   W_PRECALC_00_15_1(13, W5, Wtmp0);
262   W_PRECALC_00_15_2(14, W5, Wtmp0);
263   W_PRECALC_00_15_3(15, W5, Wtmp0);
264
265 .align 8
266 .Loop:
267   addq $64, RDATA;
268
269   /* Transform 0-15 + Precalc 16-31. */
270   R( a, b, c, d, e, F1,  0 ); W_PRECALC_16_31_0(16, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
271   R( e, a, b, c, d, F1,  1 ); W_PRECALC_16_31_1(17, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
272   R( d, e, a, b, c, F1,  2 ); W_PRECALC_16_31_2(18, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
273   R( c, d, e, a, b, F1,  3 ); W_PRECALC_16_31_3(19, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
274   R( b, c, d, e, a, F1,  4 ); W_PRECALC_16_31_0(20, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
275   R( a, b, c, d, e, F1,  5 ); W_PRECALC_16_31_1(21, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
276   R( e, a, b, c, d, F1,  6 ); W_PRECALC_16_31_2(22, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
277   R( d, e, a, b, c, F1,  7 ); W_PRECALC_16_31_3(23, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
278   R( c, d, e, a, b, F1,  8 ); W_PRECALC_16_31_0(24, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
279   R( b, c, d, e, a, F1,  9 ); W_PRECALC_16_31_1(25, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
280   R( a, b, c, d, e, F1, 10 ); W_PRECALC_16_31_2(26, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
281   R( e, a, b, c, d, F1, 11 ); W_PRECALC_16_31_3(27, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
282   R( d, e, a, b, c, F1, 12 ); W_PRECALC_16_31_0(28, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
283   R( c, d, e, a, b, F1, 13 ); W_PRECALC_16_31_1(29, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
284   R( b, c, d, e, a, F1, 14 ); W_PRECALC_16_31_2(30, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
285   R( a, b, c, d, e, F1, 15 ); W_PRECALC_16_31_3(31, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
286
287   /* Transform 16-63 + Precalc 32-79. */
288   R( e, a, b, c, d, F1, 16 ); W_PRECALC_32_79_0(32, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
289   R( d, e, a, b, c, F1, 17 ); W_PRECALC_32_79_1(33, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
290   R( c, d, e, a, b, F1, 18 ); W_PRECALC_32_79_2(34, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
291   R( b, c, d, e, a, F1, 19 ); W_PRECALC_32_79_3(35, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
292   R( a, b, c, d, e, F2, 20 ); W_PRECALC_32_79_0(36, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
293   R( e, a, b, c, d, F2, 21 ); W_PRECALC_32_79_1(37, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
294   R( d, e, a, b, c, F2, 22 ); W_PRECALC_32_79_2(38, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
295   R( c, d, e, a, b, F2, 23 ); W_PRECALC_32_79_3(39, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
296   R( b, c, d, e, a, F2, 24 ); W_PRECALC_32_79_0(40, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
297   R( a, b, c, d, e, F2, 25 ); W_PRECALC_32_79_1(41, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
298   R( e, a, b, c, d, F2, 26 ); W_PRECALC_32_79_2(42, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
299   R( d, e, a, b, c, F2, 27 ); W_PRECALC_32_79_3(43, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
300   R( c, d, e, a, b, F2, 28 ); W_PRECALC_32_79_0(44, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
301   R( b, c, d, e, a, F2, 29 ); W_PRECALC_32_79_1(45, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
302   R( a, b, c, d, e, F2, 30 ); W_PRECALC_32_79_2(46, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
303   R( e, a, b, c, d, F2, 31 ); W_PRECALC_32_79_3(47, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
304   R( d, e, a, b, c, F2, 32 ); W_PRECALC_32_79_0(48, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
305   R( c, d, e, a, b, F2, 33 ); W_PRECALC_32_79_1(49, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
306   R( b, c, d, e, a, F2, 34 ); W_PRECALC_32_79_2(50, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
307   R( a, b, c, d, e, F2, 35 ); W_PRECALC_32_79_3(51, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
308   R( e, a, b, c, d, F2, 36 ); W_PRECALC_32_79_0(52, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
309   R( d, e, a, b, c, F2, 37 ); W_PRECALC_32_79_1(53, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
310   R( c, d, e, a, b, F2, 38 ); W_PRECALC_32_79_2(54, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
311   R( b, c, d, e, a, F2, 39 ); W_PRECALC_32_79_3(55, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
312   R( a, b, c, d, e, F3, 40 ); W_PRECALC_32_79_0(56, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
313   R( e, a, b, c, d, F3, 41 ); W_PRECALC_32_79_1(57, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
314   R( d, e, a, b, c, F3, 42 ); W_PRECALC_32_79_2(58, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
315   R( c, d, e, a, b, F3, 43 ); W_PRECALC_32_79_3(59, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
316   R( b, c, d, e, a, F3, 44 ); W_PRECALC_32_79_0(60, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
317   R( a, b, c, d, e, F3, 45 ); W_PRECALC_32_79_1(61, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
318   R( e, a, b, c, d, F3, 46 ); W_PRECALC_32_79_2(62, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
319   R( d, e, a, b, c, F3, 47 ); W_PRECALC_32_79_3(63, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
320   R( c, d, e, a, b, F3, 48 ); W_PRECALC_32_79_0(64, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
321   R( b, c, d, e, a, F3, 49 ); W_PRECALC_32_79_1(65, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
322   R( a, b, c, d, e, F3, 50 ); W_PRECALC_32_79_2(66, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
323   R( e, a, b, c, d, F3, 51 ); W_PRECALC_32_79_3(67, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
324   R( d, e, a, b, c, F3, 52 ); W_PRECALC_32_79_0(68, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
325   R( c, d, e, a, b, F3, 53 ); W_PRECALC_32_79_1(69, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
326   R( b, c, d, e, a, F3, 54 ); W_PRECALC_32_79_2(70, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
327   R( a, b, c, d, e, F3, 55 ); W_PRECALC_32_79_3(71, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
328   R( e, a, b, c, d, F3, 56 ); W_PRECALC_32_79_0(72, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
329   R( d, e, a, b, c, F3, 57 ); W_PRECALC_32_79_1(73, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
330   R( c, d, e, a, b, F3, 58 ); W_PRECALC_32_79_2(74, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
331   R( b, c, d, e, a, F3, 59 ); W_PRECALC_32_79_3(75, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
332   R( a, b, c, d, e, F4, 60 ); W_PRECALC_32_79_0(76, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
333   R( e, a, b, c, d, F4, 61 ); W_PRECALC_32_79_1(77, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
334   R( d, e, a, b, c, F4, 62 ); W_PRECALC_32_79_2(78, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
335   R( c, d, e, a, b, F4, 63 ); W_PRECALC_32_79_3(79, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
336
337   decq RNBLKS;
338   jz .Lend;
339
340   /* Transform 64-79 + Precalc 0-15 of next block. */
341   R( b, c, d, e, a, F4, 64 ); W_PRECALC_00_15_0(0, W0, Wtmp0);
342   R( a, b, c, d, e, F4, 65 ); W_PRECALC_00_15_1(1, W0, Wtmp0);
343   R( e, a, b, c, d, F4, 66 ); W_PRECALC_00_15_2(2, W0, Wtmp0);
344   R( d, e, a, b, c, F4, 67 ); W_PRECALC_00_15_3(3, W0, Wtmp0);
345   R( c, d, e, a, b, F4, 68 ); W_PRECALC_00_15_0(4, W7, Wtmp0);
346   R( b, c, d, e, a, F4, 69 ); W_PRECALC_00_15_1(5, W7, Wtmp0);
347   R( a, b, c, d, e, F4, 70 ); W_PRECALC_00_15_2(6, W7, Wtmp0);
348   R( e, a, b, c, d, F4, 71 ); W_PRECALC_00_15_3(7, W7, Wtmp0);
349   R( d, e, a, b, c, F4, 72 ); W_PRECALC_00_15_0(8, W6, Wtmp0);
350   R( c, d, e, a, b, F4, 73 ); W_PRECALC_00_15_1(9, W6, Wtmp0);
351   R( b, c, d, e, a, F4, 74 ); W_PRECALC_00_15_2(10, W6, Wtmp0);
352   R( a, b, c, d, e, F4, 75 ); W_PRECALC_00_15_3(11, W6, Wtmp0);
353   R( e, a, b, c, d, F4, 76 ); W_PRECALC_00_15_0(12, W5, Wtmp0);
354   R( d, e, a, b, c, F4, 77 ); W_PRECALC_00_15_1(13, W5, Wtmp0);
355   R( c, d, e, a, b, F4, 78 );
356   addl state_h0(RSTATE), a;   W_PRECALC_00_15_2(14, W5, Wtmp0);
357   R( b, c, d, e, a, F4, 79 ); W_PRECALC_00_15_3(15, W5, Wtmp0);
358
359   /* Update the chaining variables. */
360   addl state_h3(RSTATE), d;
361   addl state_h2(RSTATE), c;
362   addl state_h1(RSTATE), b;
363   addl state_h4(RSTATE), e;
364
365   movl d, state_h3(RSTATE);
366   movl c, state_h2(RSTATE);
367   movl b, state_h1(RSTATE);
368   movl a, state_h0(RSTATE);
369   movl e, state_h4(RSTATE);
370
371   jmp .Loop;
372
373 .align 16
374 .Lend:
375   vzeroall;
376
377   /* Transform 64-79. */
378   R( b, c, d, e, a, F4, 64 );
379   R( a, b, c, d, e, F4, 65 );
380   R( e, a, b, c, d, F4, 66 );
381   R( d, e, a, b, c, F4, 67 );
382   R( c, d, e, a, b, F4, 68 );
383   R( b, c, d, e, a, F4, 69 );
384   R( a, b, c, d, e, F4, 70 );
385   R( e, a, b, c, d, F4, 71 );
386   R( d, e, a, b, c, F4, 72 );
387   R( c, d, e, a, b, F4, 73 );
388   R( b, c, d, e, a, F4, 74 );
389   R( a, b, c, d, e, F4, 75 );
390   R( e, a, b, c, d, F4, 76 );
391   R( d, e, a, b, c, F4, 77 );
392   R( c, d, e, a, b, F4, 78 );
393   addl state_h0(RSTATE), a;
394   R( b, c, d, e, a, F4, 79 );
395
396   /* Update the chaining variables. */
397   addl state_h3(RSTATE), d;
398   addl state_h2(RSTATE), c;
399   addl state_h1(RSTATE), b;
400   addl state_h4(RSTATE), e;
401
402   movl d, state_h3(RSTATE);
403   movl c, state_h2(RSTATE);
404   movl b, state_h1(RSTATE);
405   movl a, state_h0(RSTATE);
406   movl e, state_h4(RSTATE);
407
408   movq ROLDSTACK, %rsp;
409
410   popq %rbp;
411   popq %rbx;
412
413   /* burn_stack */
414   movl $(16*4 + 2*8 + 31), %eax;
415
416 .Lret:
417   ret;
418
419 #endif
420 #endif