Add crypto hash SM3.
[libgcrypt.git] / cipher / sha512-avx-amd64.S
1 /*
2 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3 ; Copyright (c) 2012, Intel Corporation
4 ;
5 ; All rights reserved.
6 ;
7 ; Redistribution and use in source and binary forms, with or without
8 ; modification, are permitted provided that the following conditions are
9 ; met:
10 ;
11 ; * Redistributions of source code must retain the above copyright
12 ;   notice, this list of conditions and the following disclaimer.
13 ;
14 ; * Redistributions in binary form must reproduce the above copyright
15 ;   notice, this list of conditions and the following disclaimer in the
16 ;   documentation and/or other materials provided with the
17 ;   distribution.
18 ;
19 ; * Neither the name of the Intel Corporation nor the names of its
20 ;   contributors may be used to endorse or promote products derived from
21 ;   this software without specific prior written permission.
22 ;
23 ;
24 ; THIS SOFTWARE IS PROVIDED BY INTEL CORPORATION "AS IS" AND ANY
25 ; EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
26 ; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
27 ; PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL CORPORATION OR
28 ; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 ; EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 ; PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 ; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
32 ; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
33 ; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 ; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
36 */
37 /*
38  * Conversion to GAS assembly and integration to libgcrypt
39  *  by Jussi Kivilinna <jussi.kivilinna@iki.fi>
40  */
41
42 #ifdef __x86_64
43 #include <config.h>
44 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
45      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
46     defined(HAVE_INTEL_SYNTAX_PLATFORM_AS) && \
47     defined(HAVE_GCC_INLINE_ASM_AVX) && defined(USE_SHA512)
48
49 #ifdef __PIC__
50 #  define ADD_RIP +rip
51 #else
52 #  define ADD_RIP
53 #endif
54
55 #ifdef HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS
56 # define ELF(...) __VA_ARGS__
57 #else
58 # define ELF(...) /*_*/
59 #endif
60
61 .intel_syntax noprefix
62
63 .text
64
65 /* Virtual Registers */
66 msg = rdi /* ARG1 */
67 digest = rsi /* ARG2 */
68 msglen = rdx /* ARG3 */
69 T1 = rcx
70 T2 = r8
71 a_64 = r9
72 b_64 = r10
73 c_64 = r11
74 d_64 = r12
75 e_64 = r13
76 f_64 = r14
77 g_64 = r15
78 h_64 = rbx
79 tmp0 = rax
80
81 /*
82 ; Local variables (stack frame)
83 ; Note: frame_size must be an odd multiple of 8 bytes to XMM align RSP
84 */
85 frame_W      = 0 /* Message Schedule */
86 frame_W_size = (80 * 8)
87 frame_WK      = ((frame_W) + (frame_W_size)) /* W[t] + K[t] | W[t+1] + K[t+1] */
88 frame_WK_size = (2 * 8)
89 frame_GPRSAVE      = ((frame_WK) + (frame_WK_size))
90 frame_GPRSAVE_size = (5 * 8)
91 frame_size = ((frame_GPRSAVE) + (frame_GPRSAVE_size))
92
93
94 /* Useful QWORD "arrays" for simpler memory references */
95 #define MSG(i)    msg    + 8*(i)               /* Input message (arg1) */
96 #define DIGEST(i) digest + 8*(i)               /* Output Digest (arg2) */
97 #define K_t(i)    .LK512   + 8*(i) ADD_RIP     /* SHA Constants (static mem) */
98 #define W_t(i)    rsp + frame_W  + 8*(i)       /* Message Schedule (stack frame) */
99 #define WK_2(i)   rsp + frame_WK + 8*((i) % 2) /* W[t]+K[t] (stack frame) */
100 /* MSG, DIGEST, K_t, W_t are arrays */
101 /* WK_2(t) points to 1 of 2 qwords at frame.WK depdending on t being odd/even */
102
103 .macro RotateState
104         /* Rotate symbles a..h right */
105         __TMP = h_64
106         h_64 =  g_64
107         g_64 =  f_64
108         f_64 =  e_64
109         e_64 =  d_64
110         d_64 =  c_64
111         c_64 =  b_64
112         b_64 =  a_64
113         a_64 =  __TMP
114 .endm
115
116 .macro RORQ p1 p2
117         /* shld is faster than ror on Intel Sandybridge */
118         shld    \p1, \p1, (64 - \p2)
119 .endm
120
121 .macro SHA512_Round t
122         /* Compute Round %%t */
123         mov     T1,   f_64        /* T1 = f */
124         mov     tmp0, e_64        /* tmp = e */
125         xor     T1,   g_64        /* T1 = f ^ g */
126         RORQ    tmp0, 23 /* 41     ; tmp = e ror 23 */
127         and     T1,   e_64        /* T1 = (f ^ g) & e */
128         xor     tmp0, e_64        /* tmp = (e ror 23) ^ e */
129         xor     T1,   g_64        /* T1 = ((f ^ g) & e) ^ g = CH(e,f,g) */
130         add     T1,   [WK_2(\t)] /* W[t] + K[t] from message scheduler */
131         RORQ    tmp0, 4 /* 18      ; tmp = ((e ror 23) ^ e) ror 4 */
132         xor     tmp0, e_64        /* tmp = (((e ror 23) ^ e) ror 4) ^ e */
133         mov     T2,   a_64        /* T2 = a */
134         add     T1,   h_64        /* T1 = CH(e,f,g) + W[t] + K[t] + h */
135         RORQ    tmp0, 14 /* 14     ; tmp = ((((e ror23)^e)ror4)^e)ror14 = S1(e) */
136         add     T1,   tmp0        /* T1 = CH(e,f,g) + W[t] + K[t] + S1(e) */
137         mov     tmp0, a_64        /* tmp = a */
138         xor     T2,   c_64        /* T2 = a ^ c */
139         and     tmp0, c_64        /* tmp = a & c */
140         and     T2,   b_64        /* T2 = (a ^ c) & b */
141         xor     T2,   tmp0        /* T2 = ((a ^ c) & b) ^ (a & c) = Maj(a,b,c) */
142         mov     tmp0, a_64        /* tmp = a */
143         RORQ    tmp0, 5 /* 39      ; tmp = a ror 5 */
144         xor     tmp0, a_64        /* tmp = (a ror 5) ^ a */
145         add     d_64, T1          /* e(next_state) = d + T1  */
146         RORQ    tmp0, 6 /* 34      ; tmp = ((a ror 5) ^ a) ror 6 */
147         xor     tmp0, a_64        /* tmp = (((a ror 5) ^ a) ror 6) ^ a */
148         lea     h_64, [T1 + T2]   /* a(next_state) = T1 + Maj(a,b,c) */
149         RORQ    tmp0, 28 /* 28     ; tmp = ((((a ror5)^a)ror6)^a)ror28 = S0(a) */
150         add     h_64, tmp0        /* a(next_state) = T1 + Maj(a,b,c) S0(a) */
151         RotateState
152 .endm
153
154 .macro SHA512_2Sched_2Round_avx t
155 /*      ; Compute rounds %%t-2 and %%t-1
156         ; Compute message schedule QWORDS %%t and %%t+1
157
158         ;   Two rounds are computed based on the values for K[t-2]+W[t-2] and
159         ; K[t-1]+W[t-1] which were previously stored at WK_2 by the message
160         ; scheduler.
161         ;   The two new schedule QWORDS are stored at [W_t(%%t)] and [W_t(%%t+1)].
162         ; They are then added to their respective SHA512 constants at
163         ; [K_t(%%t)] and [K_t(%%t+1)] and stored at dqword [WK_2(%%t)]
164         ;   For brievity, the comments following vectored instructions only refer to
165         ; the first of a pair of QWORDS.
166         ; Eg. XMM4=W[t-2] really means XMM4={W[t-2]|W[t-1]}
167         ;   The computation of the message schedule and the rounds are tightly
168         ; stitched to take advantage of instruction-level parallelism.
169         ; For clarity, integer instructions (for the rounds calculation) are indented
170         ; by one tab. Vectored instructions (for the message scheduler) are indented
171         ; by two tabs. */
172
173                 vmovdqa xmm4, [W_t(\t-2)]   /* XMM4 = W[t-2] */
174                 vmovdqu xmm5, [W_t(\t-15)]  /* XMM5 = W[t-15] */
175         mov     T1,   f_64
176                 vpsrlq  xmm0, xmm4, 61       /* XMM0 = W[t-2]>>61 */
177         mov     tmp0, e_64
178                 vpsrlq  xmm6, xmm5, 1        /* XMM6 = W[t-15]>>1 */
179         xor     T1,   g_64
180         RORQ    tmp0, 23 /* 41 */
181                 vpsrlq  xmm1, xmm4, 19       /* XMM1 = W[t-2]>>19 */
182         and     T1,   e_64
183         xor     tmp0, e_64
184                 vpxor   xmm0, xmm0, xmm1           /* XMM0 = W[t-2]>>61 ^ W[t-2]>>19 */
185         xor     T1,   g_64
186         add     T1,   [WK_2(\t)];
187                 vpsrlq  xmm7, xmm5, 8        /* XMM7 = W[t-15]>>8 */
188         RORQ    tmp0, 4 /* 18 */
189                 vpsrlq  xmm2, xmm4, 6        /* XMM2 = W[t-2]>>6 */
190         xor     tmp0, e_64
191         mov     T2,   a_64
192         add     T1,   h_64
193                 vpxor   xmm6, xmm6, xmm7           /* XMM6 = W[t-15]>>1 ^ W[t-15]>>8 */
194         RORQ    tmp0, 14 /* 14 */
195         add     T1,   tmp0
196                 vpsrlq  xmm8, xmm5, 7        /* XMM8 = W[t-15]>>7 */
197         mov     tmp0, a_64
198         xor     T2,   c_64
199                 vpsllq  xmm3, xmm4, (64-61)  /* XMM3 = W[t-2]<<3 */
200         and     tmp0, c_64
201         and     T2,   b_64
202                 vpxor   xmm2, xmm2, xmm3           /* XMM2 = W[t-2]>>6 ^ W[t-2]<<3 */
203         xor     T2,   tmp0
204         mov     tmp0, a_64
205                 vpsllq  xmm9, xmm5, (64-1)   /* XMM9 = W[t-15]<<63 */
206         RORQ    tmp0, 5 /* 39 */
207                 vpxor   xmm8, xmm8, xmm9           /* XMM8 = W[t-15]>>7 ^ W[t-15]<<63 */
208         xor     tmp0, a_64
209         add     d_64, T1
210         RORQ    tmp0, 6 /* 34 */
211         xor     tmp0, a_64
212                 vpxor   xmm6, xmm6, xmm8           /* XMM6 = W[t-15]>>1 ^ W[t-15]>>8 ^ W[t-15]>>7 ^ W[t-15]<<63 */
213         lea     h_64, [T1 + T2]
214         RORQ    tmp0, 28 /* 28 */
215                 vpsllq  xmm4, xmm4, (64-19)        /* XMM4 = W[t-2]<<25 */
216         add     h_64, tmp0
217         RotateState
218                 vpxor   xmm0, xmm0, xmm4           /* XMM0 = W[t-2]>>61 ^ W[t-2]>>19 ^ W[t-2]<<25 */
219         mov     T1, f_64
220                 vpxor   xmm0, xmm0, xmm2           /* XMM0 = s1(W[t-2]) */
221         mov     tmp0, e_64
222         xor     T1,   g_64
223                 vpaddq  xmm0, xmm0, [W_t(\t-16)]  /* XMM0 = s1(W[t-2]) + W[t-16] */
224                 vmovdqu xmm1, [W_t(\t- 7)]  /* XMM1 = W[t-7] */
225         RORQ    tmp0, 23 /* 41 */
226         and     T1,   e_64
227         xor     tmp0, e_64
228         xor     T1,   g_64
229                 vpsllq  xmm5, xmm5, (64-8)         /* XMM5 = W[t-15]<<56 */
230         add     T1,   [WK_2(\t+1)]
231                 vpxor   xmm6, xmm6, xmm5           /* XMM6 = s0(W[t-15]) */
232         RORQ    tmp0, 4 /* 18 */
233                 vpaddq  xmm0, xmm0, xmm6           /* XMM0 = s1(W[t-2]) + W[t-16] + s0(W[t-15]) */
234         xor     tmp0, e_64
235                 vpaddq  xmm0, xmm0, xmm1           /* XMM0 = W[t] = s1(W[t-2]) + W[t-7] + s0(W[t-15]) + W[t-16] */
236         mov     T2,   a_64
237         add     T1,   h_64
238         RORQ    tmp0, 14 /* 14 */
239         add     T1,   tmp0
240                 vmovdqa [W_t(\t)], xmm0      /* Store W[t] */
241                 vpaddq  xmm0, xmm0, [K_t(t)]        /* Compute W[t]+K[t] */
242                 vmovdqa [WK_2(t)], xmm0       /* Store W[t]+K[t] for next rounds */
243         mov     tmp0, a_64
244         xor     T2,   c_64
245         and     tmp0, c_64
246         and     T2,   b_64
247         xor     T2,   tmp0
248         mov     tmp0, a_64
249         RORQ    tmp0, 5 /* 39 */
250         xor     tmp0, a_64
251         add     d_64, T1
252         RORQ    tmp0, 6 /* 34 */
253         xor     tmp0, a_64
254         lea     h_64, [T1 + T2]
255         RORQ    tmp0, 28 /* 28 */
256         add     h_64, tmp0
257         RotateState
258 .endm
259
260 /*
261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
262 ; void sha512_avx(const void* M, void* D, uint64_t L);
263 ; Purpose: Updates the SHA512 digest stored at D with the message stored in M.
264 ; The size of the message pointed to by M must be an integer multiple of SHA512
265 ;   message blocks.
266 ; L is the message length in SHA512 blocks
267 */
268 .globl _gcry_sha512_transform_amd64_avx
269 ELF(.type _gcry_sha512_transform_amd64_avx,@function;)
270 .align 16
271 _gcry_sha512_transform_amd64_avx:
272         xor eax, eax
273
274         cmp     msglen, 0
275         je      .Lnowork
276
277         vzeroupper
278
279         /* Allocate Stack Space */
280         sub     rsp, frame_size
281
282         /* Save GPRs */
283         mov     [rsp + frame_GPRSAVE + 8 * 0], rbx
284         mov     [rsp + frame_GPRSAVE + 8 * 1], r12
285         mov     [rsp + frame_GPRSAVE + 8 * 2], r13
286         mov     [rsp + frame_GPRSAVE + 8 * 3], r14
287         mov     [rsp + frame_GPRSAVE + 8 * 4], r15
288
289 .Lupdateblock:
290
291         /* Load state variables */
292         mov     a_64, [DIGEST(0)]
293         mov     b_64, [DIGEST(1)]
294         mov     c_64, [DIGEST(2)]
295         mov     d_64, [DIGEST(3)]
296         mov     e_64, [DIGEST(4)]
297         mov     f_64, [DIGEST(5)]
298         mov     g_64, [DIGEST(6)]
299         mov     h_64, [DIGEST(7)]
300
301         t = 0
302         .rept 80/2 + 1
303         /* (80 rounds) / (2 rounds/iteration) + (1 iteration) */
304         /* +1 iteration because the scheduler leads hashing by 1 iteration */
305                 .if t < 2
306                         /* BSWAP 2 QWORDS */
307                         vmovdqa xmm1, [.LXMM_QWORD_BSWAP ADD_RIP]
308                         vmovdqu xmm0, [MSG(t)]
309                         vpshufb xmm0, xmm0, xmm1     /* BSWAP */
310                         vmovdqa [W_t(t)], xmm0       /* Store Scheduled Pair */
311                         vpaddq  xmm0, xmm0, [K_t(t)] /* Compute W[t]+K[t] */
312                         vmovdqa [WK_2(t)], xmm0      /* Store into WK for rounds */
313                 .elseif t < 16
314                         /* BSWAP 2 QWORDS, Compute 2 Rounds */
315                         vmovdqu xmm0, [MSG(t)]
316                         vpshufb xmm0, xmm0, xmm1     /* BSWAP */
317                         SHA512_Round (t - 2)         /* Round t-2 */
318                         vmovdqa [W_t(t)], xmm0       /* Store Scheduled Pair */
319                         vpaddq  xmm0, xmm0, [K_t(t)] /* Compute W[t]+K[t] */
320                         SHA512_Round (t - 1)         /* Round t-1 */
321                         vmovdqa [WK_2(t)], xmm0      /* W[t]+K[t] into WK */
322                 .elseif t < 79
323                         /* Schedule 2 QWORDS; Compute 2 Rounds */
324                         SHA512_2Sched_2Round_avx t
325                 .else
326                         /* Compute 2 Rounds */
327                         SHA512_Round (t - 2)
328                         SHA512_Round (t - 1)
329                 .endif
330                 t = ((t)+2)
331         .endr
332
333         /* Update digest */
334         add     [DIGEST(0)], a_64
335         add     [DIGEST(1)], b_64
336         add     [DIGEST(2)], c_64
337         add     [DIGEST(3)], d_64
338         add     [DIGEST(4)], e_64
339         add     [DIGEST(5)], f_64
340         add     [DIGEST(6)], g_64
341         add     [DIGEST(7)], h_64
342
343         /* Advance to next message block */
344         add     msg, 16*8
345         dec     msglen
346         jnz     .Lupdateblock
347
348         /* Restore GPRs */
349         mov     rbx, [rsp + frame_GPRSAVE + 8 * 0]
350         mov     r12, [rsp + frame_GPRSAVE + 8 * 1]
351         mov     r13, [rsp + frame_GPRSAVE + 8 * 2]
352         mov     r14, [rsp + frame_GPRSAVE + 8 * 3]
353         mov     r15, [rsp + frame_GPRSAVE + 8 * 4]
354
355         /* Restore Stack Pointer */
356         add     rsp, frame_size
357
358         vzeroall
359
360         /* Return stack burn depth */
361         mov     rax, frame_size
362
363 .Lnowork:
364         ret
365
366 /*
367 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
368 ;;; Binary Data
369 */
370
371 .align 16
372
373 /* Mask for byte-swapping a couple of qwords in an XMM register using (v)pshufb. */
374 .LXMM_QWORD_BSWAP:
375         .octa 0x08090a0b0c0d0e0f0001020304050607
376
377 /* K[t] used in SHA512 hashing */
378 .LK512:
379         .quad 0x428a2f98d728ae22,0x7137449123ef65cd
380         .quad 0xb5c0fbcfec4d3b2f,0xe9b5dba58189dbbc
381         .quad 0x3956c25bf348b538,0x59f111f1b605d019
382         .quad 0x923f82a4af194f9b,0xab1c5ed5da6d8118
383         .quad 0xd807aa98a3030242,0x12835b0145706fbe
384         .quad 0x243185be4ee4b28c,0x550c7dc3d5ffb4e2
385         .quad 0x72be5d74f27b896f,0x80deb1fe3b1696b1
386         .quad 0x9bdc06a725c71235,0xc19bf174cf692694
387         .quad 0xe49b69c19ef14ad2,0xefbe4786384f25e3
388         .quad 0x0fc19dc68b8cd5b5,0x240ca1cc77ac9c65
389         .quad 0x2de92c6f592b0275,0x4a7484aa6ea6e483
390         .quad 0x5cb0a9dcbd41fbd4,0x76f988da831153b5
391         .quad 0x983e5152ee66dfab,0xa831c66d2db43210
392         .quad 0xb00327c898fb213f,0xbf597fc7beef0ee4
393         .quad 0xc6e00bf33da88fc2,0xd5a79147930aa725
394         .quad 0x06ca6351e003826f,0x142929670a0e6e70
395         .quad 0x27b70a8546d22ffc,0x2e1b21385c26c926
396         .quad 0x4d2c6dfc5ac42aed,0x53380d139d95b3df
397         .quad 0x650a73548baf63de,0x766a0abb3c77b2a8
398         .quad 0x81c2c92e47edaee6,0x92722c851482353b
399         .quad 0xa2bfe8a14cf10364,0xa81a664bbc423001
400         .quad 0xc24b8b70d0f89791,0xc76c51a30654be30
401         .quad 0xd192e819d6ef5218,0xd69906245565a910
402         .quad 0xf40e35855771202a,0x106aa07032bbd1b8
403         .quad 0x19a4c116b8d2d0c8,0x1e376c085141ab53
404         .quad 0x2748774cdf8eeb99,0x34b0bcb5e19b48a8
405         .quad 0x391c0cb3c5c95a63,0x4ed8aa4ae3418acb
406         .quad 0x5b9cca4f7763e373,0x682e6ff3d6b2b8a3
407         .quad 0x748f82ee5defb2fc,0x78a5636f43172f60
408         .quad 0x84c87814a1f0ab72,0x8cc702081a6439ec
409         .quad 0x90befffa23631e28,0xa4506cebde82bde9
410         .quad 0xbef9a3f7b2c67915,0xc67178f2e372532b
411         .quad 0xca273eceea26619c,0xd186b8c721c0c207
412         .quad 0xeada7dd6cde0eb1e,0xf57d4f7fee6ed178
413         .quad 0x06f067aa72176fba,0x0a637dc5a2c898a6
414         .quad 0x113f9804bef90dae,0x1b710b35131c471b
415         .quad 0x28db77f523047d84,0x32caab7b40c72493
416         .quad 0x3c9ebe0a15c9bebc,0x431d67c49c100d4c
417         .quad 0x4cc5d4becb3e42b6,0x597f299cfc657e2a
418         .quad 0x5fcb6fab3ad6faec,0x6c44198c4a475817
419
420 #endif
421 #endif