rndhw: add missing "memory" clobbers
[libgcrypt.git] / configure.ac
1 # Configure.ac script for Libgcrypt
2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2006,
3 #               2007, 2008, 2009, 2011 Free Software Foundation, Inc.
4 # Copyright (C) 2012, 2013, 2014, 2015, 2016  g10 Code GmbH
5 #
6 # This file is part of Libgcrypt.
7 #
8 # Libgcrypt is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of
11 # the License, or (at your option) any later version.
12 #
13 # Libgcrypt is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU Lesser General Public License for more details.
17 #
18 # You should have received a copy of the GNU Lesser General Public
19 # License along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_REVISION($Revision$)
23 AC_PREREQ(2.60)
24 min_automake_version="1.14"
25
26 # To build a release you need to create a tag with the version number
27 # (git tag -s libgcrypt-n.m.k) and run "./autogen.sh --force".  Please
28 # bump the version number immediately after the release and do another
29 # commit and push so that the git magic is able to work.  See below
30 # for the LT versions.
31 m4_define(mym4_version_major, [1])
32 m4_define(mym4_version_minor, [8])
33 m4_define(mym4_version_micro, [0])
34
35 # Below is m4 magic to extract and compute the revision number, the
36 # decimalized short revision number, a beta version string, and a flag
37 # indicating a development version (mym4_isgit). Note that the m4
38 # processing is done by autoconf and not during the configure run.
39 m4_define(mym4_version,
40           [mym4_version_major.mym4_version_minor.mym4_version_micro])
41 m4_define([mym4_revision],
42           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
43 m4_define([mym4_revision_dec],
44           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
45 m4_define([mym4_betastring],
46           m4_esyscmd_s([git describe --match 'libgcrypt-[0-9].*[0-9]' --long|\
47                         awk -F- '$3!=0{print"-beta"$3}']))
48 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
49 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
50
51 AC_INIT([libgcrypt],[mym4_full_version],[http://bugs.gnupg.org])
52
53 # LT Version numbers, remember to change them just *before* a release.
54 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
55 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
56 #   (No interfaces changed:                   REVISION++)
57 LIBGCRYPT_LT_CURRENT=21
58 LIBGCRYPT_LT_AGE=1
59 LIBGCRYPT_LT_REVISION=3
60
61
62 # If the API is changed in an incompatible way: increment the next counter.
63 #
64 # 1.6: ABI and API change but the change is to most users irrelevant
65 #      and thus the API version number has not been incremented.
66 LIBGCRYPT_CONFIG_API_VERSION=1
67
68 # If you change the required gpg-error version, please remove
69 # unnecessary error code defines in src/gcrypt-int.h.
70 NEED_GPG_ERROR_VERSION=1.25
71
72 PACKAGE=$PACKAGE_NAME
73 VERSION=$PACKAGE_VERSION
74
75 AC_CONFIG_AUX_DIR([build-aux])
76 AC_CONFIG_SRCDIR([src/libgcrypt.vers])
77 AM_INIT_AUTOMAKE([serial-tests dist-bzip2])
78 AC_CONFIG_HEADER(config.h)
79 AC_CONFIG_MACRO_DIR([m4])
80 AC_CONFIG_LIBOBJ_DIR([compat])
81 AC_CANONICAL_HOST
82 AM_MAINTAINER_MODE
83 AM_SILENT_RULES
84
85 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
86
87 AH_TOP([
88 #ifndef _GCRYPT_CONFIG_H_INCLUDED
89 #define _GCRYPT_CONFIG_H_INCLUDED
90
91 /* Enable gpg-error's strerror macro for W32CE.  */
92 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
93 ])
94
95 AH_BOTTOM([
96 #define _GCRYPT_IN_LIBGCRYPT 1
97
98 /* If the configure check for endianness has been disabled, get it from
99    OS macros.  This is intended for making fat binary builds on OS X.  */
100 #ifdef DISABLED_ENDIAN_CHECK
101 # if defined(__BIG_ENDIAN__)
102 #  define WORDS_BIGENDIAN 1
103 # elif defined(__LITTLE_ENDIAN__)
104 #  undef WORDS_BIGENDIAN
105 # else
106 #  error "No endianness found"
107 # endif
108 #endif /*DISABLED_ENDIAN_CHECK*/
109
110 /* We basically use the original Camellia source.  Make sure the symbols
111    properly prefixed.  */
112 #define CAMELLIA_EXT_SYM_PREFIX _gcry_
113
114 #endif /*_GCRYPT_CONFIG_H_INCLUDED*/
115 ])
116
117 AH_VERBATIM([_REENTRANT],
118 [/* To allow the use of Libgcrypt in multithreaded programs we have to use
119     special features from the library. */
120 #ifndef _REENTRANT
121 # define _REENTRANT 1
122 #endif
123 ])
124
125
126 AC_SUBST(LIBGCRYPT_LT_CURRENT)
127 AC_SUBST(LIBGCRYPT_LT_AGE)
128 AC_SUBST(LIBGCRYPT_LT_REVISION)
129 AC_SUBST(PACKAGE)
130 AC_SUBST(VERSION)
131 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
132 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
133 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
134                           mym4_version_minor mym4_version_micro)
135 AC_SUBST(VERSION_NUMBER)
136
137
138 ######################
139 ##  Basic checks.  ### (we need some results later on (e.g. $GCC)
140 ######################
141
142 AC_PROG_MAKE_SET
143 missing_dir=`cd $ac_aux_dir && pwd`
144 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
145 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
146 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
147 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
148 # AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
149 AC_PROG_CC
150 AC_PROG_CPP
151 AM_PROG_CC_C_O
152 AM_PROG_AS
153 AC_ISC_POSIX
154 AC_PROG_INSTALL
155 AC_PROG_AWK
156
157 AC_GNU_SOURCE
158
159 # We need to compile and run a program on the build machine.  A
160 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
161 # the AC archive is broken for autoconf 2.57.  Given that there is no
162 # newer version of that macro, we assume that it is also broken for
163 # autoconf 2.61 and thus we use a simple but usually sufficient
164 # approach.
165 AC_MSG_CHECKING(for cc for build)
166 if test "$cross_compiling" = "yes"; then
167   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
168 else
169   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
170 fi
171 AC_MSG_RESULT($CC_FOR_BUILD)
172 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
173
174
175 LT_PREREQ([2.2.6])
176 LT_INIT([win32-dll disable-static])
177 LT_LANG([Windows Resource])
178
179
180 ##########################
181 ## General definitions. ##
182 ##########################
183
184 # Used by libgcrypt-config
185 LIBGCRYPT_CONFIG_LIBS="-lgcrypt"
186 LIBGCRYPT_CONFIG_CFLAGS=""
187 LIBGCRYPT_CONFIG_HOST="$host"
188
189 # Definitions for symmetric ciphers.
190 available_ciphers="arcfour blowfish cast5 des aes twofish serpent rfc2268 seed"
191 available_ciphers="$available_ciphers camellia idea salsa20 gost28147 chacha20"
192 enabled_ciphers=""
193
194 # Definitions for public-key ciphers.
195 available_pubkey_ciphers="dsa elgamal rsa ecc"
196 enabled_pubkey_ciphers=""
197
198 # Definitions for message digests.
199 available_digests="crc gostr3411-94 md2 md4 md5 rmd160 sha1 sha256"
200 available_digests="$available_digests sha512 sha3 tiger whirlpool stribog"
201 enabled_digests=""
202
203 # Definitions for kdfs (optional ones)
204 available_kdfs="s2k pkdf2 scrypt"
205 enabled_kdfs=""
206
207 # Definitions for random modules.
208 available_random_modules="linux egd unix"
209 auto_random_modules="$available_random_modules"
210
211 # Supported thread backends.
212 LIBGCRYPT_THREAD_MODULES=""
213
214 # Other definitions.
215 print_egd_notice=no
216 have_w32_system=no
217 have_w32ce_system=no
218 have_pthread=no
219
220
221 # Setup some stuff depending on host.
222 case "${host}" in
223     *-*-mingw32*)
224       ac_cv_have_dev_random=no
225       have_w32_system=yes
226       case "${host}" in
227         *-mingw32ce*)
228             have_w32ce_system=yes
229             available_random_modules="w32ce"
230             ;;
231         *)
232             available_random_modules="w32"
233             ;;
234       esac
235       AC_DEFINE(USE_ONLY_8DOT3,1,
236                 [set this to limit filenames to the 8.3 format])
237       AC_DEFINE(HAVE_DRIVE_LETTERS,1,
238                 [defined if we must run on a stupid file system])
239       AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
240                 [defined if we run on some of the PCDOS like systems
241                  (DOS, Windoze. OS/2) with special properties like
242                   no file modes])
243       ;;
244
245     i?86-emx-os2 | i?86-*-os2*emx)
246         # OS/2 with the EMX environment
247         ac_cv_have_dev_random=no
248         AC_DEFINE(HAVE_DRIVE_LETTERS)
249         AC_DEFINE(HAVE_DOSISH_SYSTEM)
250         ;;
251
252     i?86-*-msdosdjgpp*)
253         # DOS with the DJGPP environment
254         ac_cv_have_dev_random=no
255         AC_DEFINE(HAVE_DRIVE_LETTERS)
256         AC_DEFINE(HAVE_DOSISH_SYSTEM)
257         ;;
258
259     *-*-hpux*)
260         if test -z "$GCC" ; then
261             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
262         fi
263         ;;
264     *-dec-osf4*)
265         if test -z "$GCC" ; then
266             # Suppress all warnings
267             # to get rid of the unsigned/signed char mismatch warnings.
268             CFLAGS="$CFLAGS -w"
269         fi
270         ;;
271     m68k-atari-mint)
272         ;;
273     *)
274       ;;
275 esac
276
277 if test "$have_w32_system" = yes; then
278    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
279    if test "$have_w32ce_system" = yes; then
280      AC_DEFINE(HAVE_W32CE_SYSTEM,1,[Defined if we run on WindowsCE])
281    fi
282 fi
283 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
284 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
285
286
287
288 # A printable OS Name is sometimes useful.
289 case "${host}" in
290     *-*-mingw32ce*)
291         PRINTABLE_OS_NAME="W32CE"
292         ;;
293
294     *-*-mingw32*)
295         PRINTABLE_OS_NAME="W32"
296         ;;
297
298     i?86-emx-os2 | i?86-*-os2*emx )
299         PRINTABLE_OS_NAME="OS/2"
300         ;;
301
302     i?86-*-msdosdjgpp*)
303         PRINTABLE_OS_NAME="MSDOS/DJGPP"
304         ;;
305
306     *-linux*)
307         PRINTABLE_OS_NAME="GNU/Linux"
308         ;;
309
310     *)
311         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
312         ;;
313 esac
314
315 #
316 # Figure out the name of the random device
317 #
318 case "${host}" in
319     *-openbsd*)
320         NAME_OF_DEV_RANDOM="/dev/srandom"
321         NAME_OF_DEV_URANDOM="/dev/urandom"
322         ;;
323
324     *)
325         NAME_OF_DEV_RANDOM="/dev/random"
326         NAME_OF_DEV_URANDOM="/dev/urandom"
327         ;;
328 esac
329
330
331 AC_ARG_ENABLE(endian-check,
332               AC_HELP_STRING([--disable-endian-check],
333               [disable the endian check and trust the OS provided macros]),
334               endiancheck=$enableval,endiancheck=yes)
335 if test x"$endiancheck" = xyes ; then
336   AC_C_BIGENDIAN
337 else
338   AC_DEFINE(DISABLED_ENDIAN_CHECK,1,[configure did not test for endianess])
339 fi
340
341 AC_CHECK_SIZEOF(unsigned short, 2)
342 AC_CHECK_SIZEOF(unsigned int, 4)
343 AC_CHECK_SIZEOF(unsigned long, 4)
344 AC_CHECK_SIZEOF(unsigned long long, 0)
345 AC_CHECK_SIZEOF(void *, 0)
346
347 AC_TYPE_UINTPTR_T
348
349 if test "$ac_cv_sizeof_unsigned_short" = "0" \
350    || test "$ac_cv_sizeof_unsigned_int" = "0" \
351    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
352     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
353 fi
354
355 # Ensure that we have UINT64_C before we bother to check for uint64_t
356 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
357    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <inttypes.h>]],
358        [[uint64_t foo=UINT64_C(42);]])],
359      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
360 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
361    AC_CHECK_SIZEOF(uint64_t)
362 fi
363
364 # Do we have any 64-bit data types?
365 if test "$ac_cv_sizeof_unsigned_int" != "8" \
366    && test "$ac_cv_sizeof_unsigned_long" != "8" \
367    && test "$ac_cv_sizeof_unsigned_long_long" != "8" \
368    && test "$ac_cv_sizeof_uint64_t" != "8"; then
369     AC_MSG_ERROR([[
370 ***
371 *** No 64-bit integer type available.
372 *** It is not possible to build Libgcrypt on this platform.
373 ***]])
374 fi
375
376
377 # If not specified otherwise, all available algorithms will be
378 # included.
379 default_ciphers="$available_ciphers"
380 default_pubkey_ciphers="$available_pubkey_ciphers"
381 default_digests="$available_digests"
382 default_kdfs="$available_kdfs"
383 # Blacklist MD2 by default
384 default_digests=`echo $default_digests | sed -e 's/md2//g'`
385
386 # Substitutions to set generated files in a Emacs buffer to read-only.
387 AC_SUBST(emacs_local_vars_begin, ['Local Variables:'])
388 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
389 AC_SUBST(emacs_local_vars_end, ['End:'])
390
391 ############################
392 ## Command line switches. ##
393 ############################
394
395 # Implementation of the --enable-ciphers switch.
396 AC_ARG_ENABLE(ciphers,
397               AC_HELP_STRING([--enable-ciphers=ciphers],
398                              [select the symmetric ciphers to include]),
399               [enabled_ciphers=`echo $enableval | tr ',:' '  ' | tr '[A-Z]' '[a-z]'`],
400               [enabled_ciphers=""])
401 if test "x$enabled_ciphers" = "x" \
402    -o "$enabled_ciphers" = "yes"  \
403    -o "$enabled_ciphers" = "no"; then
404    enabled_ciphers=$default_ciphers
405 fi
406 AC_MSG_CHECKING([which symmetric ciphers to include])
407 for cipher in $enabled_ciphers; do
408     LIST_MEMBER($cipher, $available_ciphers)
409     if test "$found" = "0"; then
410        AC_MSG_ERROR([unsupported cipher "$cipher" specified])
411     fi
412 done
413 AC_MSG_RESULT([$enabled_ciphers])
414
415 # Implementation of the --enable-pubkey-ciphers switch.
416 AC_ARG_ENABLE(pubkey-ciphers,
417               AC_HELP_STRING([--enable-pubkey-ciphers=ciphers],
418                              [select the public-key ciphers to include]),
419               [enabled_pubkey_ciphers=`echo $enableval | tr ',:' '  ' | tr '[A-Z]' '[a-z]'`],
420               [enabled_pubkey_ciphers=""])
421 if test "x$enabled_pubkey_ciphers" = "x" \
422    -o "$enabled_pubkey_ciphers" = "yes"  \
423    -o "$enabled_pubkey_ciphers" = "no"; then
424    enabled_pubkey_ciphers=$default_pubkey_ciphers
425 fi
426 AC_MSG_CHECKING([which public-key ciphers to include])
427 for cipher in $enabled_pubkey_ciphers; do
428     LIST_MEMBER($cipher, $available_pubkey_ciphers)
429     if test "$found" = "0"; then
430        AC_MSG_ERROR([unsupported public-key cipher specified])
431     fi
432 done
433 AC_MSG_RESULT([$enabled_pubkey_ciphers])
434
435 # Implementation of the --enable-digests switch.
436 AC_ARG_ENABLE(digests,
437               AC_HELP_STRING([--enable-digests=digests],
438                              [select the message digests to include]),
439               [enabled_digests=`echo $enableval | tr ',:' '  ' | tr '[A-Z]' '[a-z]'`],
440               [enabled_digests=""])
441 if test "x$enabled_digests" = "x" \
442    -o "$enabled_digests" = "yes"  \
443    -o "$enabled_digests" = "no"; then
444    enabled_digests=$default_digests
445 fi
446 AC_MSG_CHECKING([which message digests to include])
447 for digest in $enabled_digests; do
448     LIST_MEMBER($digest, $available_digests)
449     if test "$found" = "0"; then
450        AC_MSG_ERROR([unsupported message digest specified])
451     fi
452 done
453 AC_MSG_RESULT([$enabled_digests])
454
455 # Implementation of the --enable-kdfs switch.
456 AC_ARG_ENABLE(kdfs,
457       AC_HELP_STRING([--enable-kfds=kdfs],
458                      [select the KDFs to include]),
459       [enabled_kdfs=`echo $enableval | tr ',:' '  ' | tr '[A-Z]' '[a-z]'`],
460       [enabled_kdfs=""])
461 if test "x$enabled_kdfs" = "x" \
462    -o "$enabled_kdfs" = "yes"  \
463    -o "$enabled_kdfs" = "no"; then
464    enabled_kdfs=$default_kdfs
465 fi
466 AC_MSG_CHECKING([which key derivation functions to include])
467 for kdf in $enabled_kdfs; do
468     LIST_MEMBER($kdf, $available_kdfs)
469     if test "$found" = "0"; then
470        AC_MSG_ERROR([unsupported key derivation function specified])
471     fi
472 done
473 AC_MSG_RESULT([$enabled_kdfs])
474
475 # Implementation of the --enable-random switch.
476 AC_ARG_ENABLE(random,
477               AC_HELP_STRING([--enable-random=name],
478                              [select which random number generator to use]),
479               [random=`echo $enableval | tr '[A-Z]' '[a-z]'`],
480               [])
481 if test "x$random" = "x" -o "$random" = "yes" -o "$random" = "no"; then
482     random=default
483 fi
484 AC_MSG_CHECKING([which random module to use])
485 if test "$random" != "default" -a "$random" != "auto"; then
486     LIST_MEMBER($random, $available_random_modules)
487     if test "$found" = "0"; then
488        AC_MSG_ERROR([unsupported random module specified])
489     fi
490 fi
491 AC_MSG_RESULT($random)
492
493 # Implementation of the --disable-dev-random switch.
494 AC_MSG_CHECKING([whether use of /dev/random is requested])
495 AC_ARG_ENABLE(dev-random,
496 [  --disable-dev-random    disable the use of dev random],
497     try_dev_random=$enableval, try_dev_random=yes)
498 AC_MSG_RESULT($try_dev_random)
499
500 # Implementation of the --with-egd-socket switch.
501 AC_ARG_WITH(egd-socket,
502     [  --with-egd-socket=NAME  Use NAME for the EGD socket)],
503             egd_socket_name="$withval", egd_socket_name="" )
504 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
505                    [Define if you don't want the default EGD socket name.
506                     For details see cipher/rndegd.c])
507
508 # Implementation of the --enable-random-daemon
509 AC_MSG_CHECKING([whether the experimental random daemon is requested])
510 AC_ARG_ENABLE([random-daemon],
511               AC_HELP_STRING([--enable-random-daemon],
512                              [Build and support the experimental gcryptrnd]),
513               [use_random_daemon=$enableval],
514               [use_random_daemon=no])
515 AC_MSG_RESULT($use_random_daemon)
516 if test x$use_random_daemon = xyes ; then
517     AC_DEFINE(USE_RANDOM_DAEMON,1,
518               [Define to support the experimental random daemon])
519 fi
520 AM_CONDITIONAL(USE_RANDOM_DAEMON, test x$use_random_daemon = xyes)
521
522
523 # Implementation of --disable-asm.
524 AC_MSG_CHECKING([whether MPI assembler modules are requested])
525 AC_ARG_ENABLE([asm],
526               AC_HELP_STRING([--disable-asm],
527                              [Disable MPI assembler modules]),
528               [try_asm_modules=$enableval],
529               [try_asm_modules=yes])
530 AC_MSG_RESULT($try_asm_modules)
531
532 # Implementation of the --enable-m-guard switch.
533 AC_MSG_CHECKING([whether memory guard is requested])
534 AC_ARG_ENABLE(m-guard,
535               AC_HELP_STRING([--enable-m-guard],
536                              [Enable memory guard facility]),
537               [use_m_guard=$enableval], [use_m_guard=no])
538 AC_MSG_RESULT($use_m_guard)
539 if test "$use_m_guard" = yes ; then
540     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
541 fi
542
543 # Implementation of the --enable-large-data-tests switch.
544 AC_MSG_CHECKING([whether to run large data tests])
545 AC_ARG_ENABLE(large-data-tests,
546               AC_HELP_STRING([--enable-large-data-tests],
547                  [Enable the real long ruinning large data tests]),
548               large_data_tests=$enableval,large_data_tests=no)
549 AC_MSG_RESULT($large_data_tests)
550 AC_SUBST(RUN_LARGE_DATA_TESTS, $large_data_tests)
551
552
553 # Implementation of the --with-capabilities switch.
554 # Check whether we want to use Linux capabilities
555 AC_MSG_CHECKING([whether use of capabilities is requested])
556 AC_ARG_WITH(capabilities,
557             AC_HELP_STRING([--with-capabilities],
558                            [Use linux capabilities [default=no]]),
559             [use_capabilities="$withval"],[use_capabilities=no])
560 AC_MSG_RESULT($use_capabilities)
561
562 # Implementation of the --enable-hmac-binary-check.
563 AC_MSG_CHECKING([whether a HMAC binary check is requested])
564 AC_ARG_ENABLE(hmac-binary-check,
565               AC_HELP_STRING([--enable-hmac-binary-check],
566                              [Enable library integrity check]),
567               [use_hmac_binary_check=$enableval],
568               [use_hmac_binary_check=no])
569 AC_MSG_RESULT($use_hmac_binary_check)
570 if test "$use_hmac_binary_check" = yes ; then
571     AC_DEFINE(ENABLE_HMAC_BINARY_CHECK,1,
572               [Define to support an HMAC based integrity check])
573 fi
574
575
576 # Implementation of the --disable-padlock-support switch.
577 AC_MSG_CHECKING([whether padlock support is requested])
578 AC_ARG_ENABLE(padlock-support,
579               AC_HELP_STRING([--disable-padlock-support],
580                  [Disable support for the PadLock Engine of VIA processors]),
581               padlocksupport=$enableval,padlocksupport=yes)
582 AC_MSG_RESULT($padlocksupport)
583
584 # Implementation of the --disable-aesni-support switch.
585 AC_MSG_CHECKING([whether AESNI support is requested])
586 AC_ARG_ENABLE(aesni-support,
587               AC_HELP_STRING([--disable-aesni-support],
588                  [Disable support for the Intel AES-NI instructions]),
589               aesnisupport=$enableval,aesnisupport=yes)
590 AC_MSG_RESULT($aesnisupport)
591
592 # Implementation of the --disable-pclmul-support switch.
593 AC_MSG_CHECKING([whether PCLMUL support is requested])
594 AC_ARG_ENABLE(pclmul-support,
595               AC_HELP_STRING([--disable-pclmul-support],
596                  [Disable support for the Intel PCLMUL instructions]),
597               pclmulsupport=$enableval,pclmulsupport=yes)
598 AC_MSG_RESULT($pclmulsupport)
599
600 # Implementation of the --disable-sse41-support switch.
601 AC_MSG_CHECKING([whether SSE4.1 support is requested])
602 AC_ARG_ENABLE(sse41-support,
603               AC_HELP_STRING([--disable-sse41-support],
604                  [Disable support for the Intel SSE4.1 instructions]),
605               sse41support=$enableval,sse41support=yes)
606 AC_MSG_RESULT($sse41support)
607
608 # Implementation of the --disable-drng-support switch.
609 AC_MSG_CHECKING([whether DRNG support is requested])
610 AC_ARG_ENABLE(drng-support,
611               AC_HELP_STRING([--disable-drng-support],
612                  [Disable support for the Intel DRNG (RDRAND instruction)]),
613               drngsupport=$enableval,drngsupport=yes)
614 AC_MSG_RESULT($drngsupport)
615
616 # Implementation of the --disable-avx-support switch.
617 AC_MSG_CHECKING([whether AVX support is requested])
618 AC_ARG_ENABLE(avx-support,
619               AC_HELP_STRING([--disable-avx-support],
620                  [Disable support for the Intel AVX instructions]),
621               avxsupport=$enableval,avxsupport=yes)
622 AC_MSG_RESULT($avxsupport)
623
624 # Implementation of the --disable-avx2-support switch.
625 AC_MSG_CHECKING([whether AVX2 support is requested])
626 AC_ARG_ENABLE(avx2-support,
627               AC_HELP_STRING([--disable-avx2-support],
628                  [Disable support for the Intel AVX2 instructions]),
629               avx2support=$enableval,avx2support=yes)
630 AC_MSG_RESULT($avx2support)
631
632 # Implementation of the --disable-neon-support switch.
633 AC_MSG_CHECKING([whether NEON support is requested])
634 AC_ARG_ENABLE(neon-support,
635               AC_HELP_STRING([--disable-neon-support],
636                  [Disable support for the ARM NEON instructions]),
637               neonsupport=$enableval,neonsupport=yes)
638 AC_MSG_RESULT($neonsupport)
639
640 # Implementation of the --disable-arm-crypto-support switch.
641 AC_MSG_CHECKING([whether ARMv8 Crypto Extension support is requested])
642 AC_ARG_ENABLE(arm-crypto-support,
643               AC_HELP_STRING([--disable-arm-crypto-support],
644                  [Disable support for the ARMv8 Crypto Extension instructions]),
645               armcryptosupport=$enableval,armcryptosupport=yes)
646 AC_MSG_RESULT($armcryptosupport)
647
648 # Implementation of the --disable-O-flag-munging switch.
649 AC_MSG_CHECKING([whether a -O flag munging is requested])
650 AC_ARG_ENABLE([O-flag-munging],
651               AC_HELP_STRING([--disable-O-flag-munging],
652                  [Disable modification of the cc -O flag]),
653               [enable_o_flag_munging=$enableval],
654               [enable_o_flag_munging=yes])
655 AC_MSG_RESULT($enable_o_flag_munging)
656 AM_CONDITIONAL(ENABLE_O_FLAG_MUNGING, test "$enable_o_flag_munging" = "yes")
657
658 # Implementation of the --disable-amd64-as-feature-detection switch.
659 AC_MSG_CHECKING([whether to enable AMD64 as(1) feature detection])
660 AC_ARG_ENABLE(amd64-as-feature-detection,
661               AC_HELP_STRING([--disable-amd64-as-feature-detection],
662                  [Disable the auto-detection of AMD64 as(1) features]),
663               amd64_as_feature_detection=$enableval,
664               amd64_as_feature_detection=yes)
665 AC_MSG_RESULT($amd64_as_feature_detection)
666
667
668 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
669                    [A human readable text with the name of the OS])
670
671 # For some systems we know that we have ld_version scripts.
672 # Use it then as default.
673 have_ld_version_script=no
674 case "${host}" in
675     *-*-linux*)
676         have_ld_version_script=yes
677         ;;
678     *-*-gnu*)
679         have_ld_version_script=yes
680         ;;
681 esac
682 AC_ARG_ENABLE([ld-version-script],
683               AC_HELP_STRING([--enable-ld-version-script],
684                              [enable/disable use of linker version script.
685                               (default is system dependent)]),
686               [have_ld_version_script=$enableval],
687               [ : ] )
688 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
689
690 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
691                    [defined to the name of the strong random device])
692 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
693                    [defined to the name of the weaker random device])
694
695
696 ###############################
697 #### Checks for libraries. ####
698 ###############################
699
700 #
701 # gpg-error is required.
702 #
703 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION")
704 if test "x$GPG_ERROR_LIBS" = "x"; then
705   AC_MSG_ERROR([libgpg-error is needed.
706                 See ftp://ftp.gnupg.org/gcrypt/libgpg-error/ .])
707 fi
708
709 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GCRYPT,
710           [The default error source for libgcrypt.])
711
712 #
713 # Check whether the GNU Pth library is available.  We require this
714 # to build the optional gcryptrnd program.
715 #
716 AC_ARG_WITH(pth-prefix,
717             AC_HELP_STRING([--with-pth-prefix=PFX],
718                            [prefix where GNU Pth is installed (optional)]),
719      pth_config_prefix="$withval", pth_config_prefix="")
720 if test x$pth_config_prefix != x ; then
721    PTH_CONFIG="$pth_config_prefix/bin/pth-config"
722 fi
723 if test "$use_random_daemon" = "yes"; then
724   AC_PATH_PROG(PTH_CONFIG, pth-config, no)
725   if test "$PTH_CONFIG" = "no"; then
726     AC_MSG_WARN([[
727 ***
728 *** To build the Libgcrypt's random number daemon
729 *** we need the support of the GNU Portable Threads Library.
730 *** Download it from ftp://ftp.gnu.org/gnu/pth/
731 *** On a Debian GNU/Linux system you might want to try
732 ***   apt-get install libpth-dev
733 ***]])
734   else
735     GNUPG_PTH_VERSION_CHECK([1.3.7])
736     if test $have_pth = yes; then
737        PTH_CFLAGS=`$PTH_CONFIG --cflags`
738        PTH_LIBS=`$PTH_CONFIG --ldflags`
739        PTH_LIBS="$PTH_LIBS `$PTH_CONFIG --libs --all`"
740        AC_DEFINE(USE_GNU_PTH, 1,
741                 [Defined if the GNU Portable Thread Library should be used])
742        AC_DEFINE(HAVE_PTH, 1,
743                 [Defined if the GNU Pth is available])
744     fi
745   fi
746 fi
747 AC_SUBST(PTH_CFLAGS)
748 AC_SUBST(PTH_LIBS)
749
750 #
751 # Check whether pthreads is available
752 #
753 if test "$have_w32_system" != yes; then
754   AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
755   if test "$have_pthread" = yes; then
756     AC_DEFINE(HAVE_PTHREAD, 1 ,[Define if we have pthread.])
757   fi
758 fi
759
760
761 # Solaris needs -lsocket and -lnsl. Unisys system includes
762 # gethostbyname in libsocket but needs libnsl for socket.
763 AC_SEARCH_LIBS(setsockopt, [socket], ,
764         [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
765 AC_SEARCH_LIBS(setsockopt, [nsl])
766
767 ##################################
768 #### Checks for header files. ####
769 ##################################
770
771 AC_HEADER_STDC
772 AC_CHECK_HEADERS(unistd.h sys/select.h sys/msg.h)
773 INSERT_SYS_SELECT_H=
774 if test x"$ac_cv_header_sys_select_h" = xyes; then
775   INSERT_SYS_SELECT_H=" include <sys/select.h>"
776 fi
777 AC_SUBST(INSERT_SYS_SELECT_H)
778
779
780 ##########################################
781 #### Checks for typedefs, structures, ####
782 ####  and compiler characteristics.   ####
783 ##########################################
784
785 AC_C_CONST
786 AC_C_INLINE
787 AC_TYPE_SIZE_T
788 AC_TYPE_SIGNAL
789 AC_DECL_SYS_SIGLIST
790 AC_TYPE_PID_T
791
792 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
793 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
794 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
795 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
796 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
797
798 gl_TYPE_SOCKLEN_T
799 case "${host}" in
800   *-*-mingw32*)
801     # socklen_t may or may not be defined depending on what headers
802     # are included.  To be safe we use int as this is the actual type.
803     FALLBACK_SOCKLEN_T="typedef int gcry_socklen_t;"
804     ;;
805   *)
806     if test ".$gl_cv_socklen_t_equiv" = "."; then
807       FALLBACK_SOCKLEN_T="typedef socklen_t gcry_socklen_t;"
808     else
809       FALLBACK_SOCKLEN_T="typedef ${gl_cv_socklen_t_equiv} gcry_socklen_t;"
810     fi
811 esac
812 AC_SUBST(FALLBACK_SOCKLEN_T)
813
814
815 #
816 # Check for __builtin_bswap32 intrinsic.
817 #
818 AC_CACHE_CHECK(for __builtin_bswap32,
819        [gcry_cv_have_builtin_bswap32],
820        [gcry_cv_have_builtin_bswap32=no
821         AC_LINK_IFELSE([AC_LANG_PROGRAM([],
822           [int x = 0; int y = __builtin_bswap32(x); return y;])],
823           [gcry_cv_have_builtin_bswap32=yes])])
824 if test "$gcry_cv_have_builtin_bswap32" = "yes" ; then
825    AC_DEFINE(HAVE_BUILTIN_BSWAP32,1,
826              [Defined if compiler has '__builtin_bswap32' intrinsic])
827 fi
828
829
830 #
831 # Check for __builtin_bswap64 intrinsic.
832 #
833 AC_CACHE_CHECK(for __builtin_bswap64,
834        [gcry_cv_have_builtin_bswap64],
835        [gcry_cv_have_builtin_bswap64=no
836         AC_LINK_IFELSE([AC_LANG_PROGRAM([],
837           [long long x = 0; long long y = __builtin_bswap64(x); return y;])],
838           [gcry_cv_have_builtin_bswap64=yes])])
839 if test "$gcry_cv_have_builtin_bswap64" = "yes" ; then
840    AC_DEFINE(HAVE_BUILTIN_BSWAP64,1,
841              [Defined if compiler has '__builtin_bswap64' intrinsic])
842 fi
843
844
845 #
846 # Check for __builtin_ctz intrinsic.
847 #
848 AC_CACHE_CHECK(for __builtin_ctz,
849        [gcry_cv_have_builtin_ctz],
850        [gcry_cv_have_builtin_ctz=no
851         AC_LINK_IFELSE([AC_LANG_PROGRAM([],
852           [unsigned int x = 0; int y = __builtin_ctz(x); return y;])],
853           [gcry_cv_have_builtin_ctz=yes])])
854 if test "$gcry_cv_have_builtin_ctz" = "yes" ; then
855    AC_DEFINE(HAVE_BUILTIN_CTZ, 1,
856              [Defined if compiler has '__builtin_ctz' intrinsic])
857 fi
858
859
860 #
861 # Check for VLA support (variable length arrays).
862 #
863 AC_CACHE_CHECK(whether the variable length arrays are supported,
864        [gcry_cv_have_vla],
865        [gcry_cv_have_vla=no
866         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
867           [[void f1(char *, int);
868             char foo(int i) {
869               char b[(i < 0 ? 0 : i) + 1];
870               f1(b, sizeof b); return b[0];}]])],
871           [gcry_cv_have_vla=yes])])
872 if test "$gcry_cv_have_vla" = "yes" ; then
873    AC_DEFINE(HAVE_VLA,1, [Defined if variable length arrays are supported])
874 fi
875
876
877 #
878 # Check for ELF visibility support.
879 #
880 AC_CACHE_CHECK(whether the visibility attribute is supported,
881        gcry_cv_visibility_attribute,
882        [gcry_cv_visibility_attribute=no
883         AC_LANG_CONFTEST([AC_LANG_SOURCE(
884           [[int foo __attribute__ ((visibility ("hidden"))) = 1;
885             int bar __attribute__ ((visibility ("protected"))) = 1;
886           ]])])
887
888         if ${CC-cc} -Werror -S conftest.c -o conftest.s \
889                   1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
890             if grep '\.hidden.*foo' conftest.s >/dev/null 2>&1 ; then
891                 if grep '\.protected.*bar' conftest.s >/dev/null 2>&1; then
892                     gcry_cv_visibility_attribute=yes
893                 fi
894             fi
895         fi
896        ])
897 if test "$gcry_cv_visibility_attribute" = "yes"; then
898     AC_CACHE_CHECK(for broken visibility attribute,
899        gcry_cv_broken_visibility_attribute,
900        [gcry_cv_broken_visibility_attribute=yes
901         AC_LANG_CONFTEST([AC_LANG_SOURCE(
902           [[int foo (int x);
903             int bar (int x) __asm__ ("foo")
904                             __attribute__ ((visibility ("hidden")));
905             int bar (int x) { return x; }
906           ]])])
907
908         if ${CC-cc} -Werror -S conftest.c -o conftest.s \
909                   1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
910            if grep '\.hidden@<:@        _@:>@foo' conftest.s >/dev/null 2>&1;
911             then
912                gcry_cv_broken_visibility_attribute=no
913            fi
914         fi
915        ])
916 fi
917 if test "$gcry_cv_visibility_attribute" = "yes"; then
918     AC_CACHE_CHECK(for broken alias attribute,
919        gcry_cv_broken_alias_attribute,
920        [gcry_cv_broken_alias_attribute=yes
921         AC_LANG_CONFTEST([AC_LANG_SOURCE(
922           [[extern int foo (int x) __asm ("xyzzy");
923             int bar (int x) { return x; }
924             extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
925             extern int dfoo;
926             extern __typeof (dfoo) dfoo __asm ("abccb");
927             int dfoo = 1;
928           ]])])
929
930         if ${CC-cc} -Werror -S conftest.c -o conftest.s \
931                   1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
932            if grep 'xyzzy' conftest.s >/dev/null 2>&1 && \
933               grep 'abccb' conftest.s >/dev/null 2>&1; then
934               gcry_cv_broken_alias_attribute=no
935            fi
936         fi
937         ])
938 fi
939 if test "$gcry_cv_visibility_attribute" = "yes"; then
940     AC_CACHE_CHECK(if gcc supports -fvisibility=hidden,
941        gcry_cv_gcc_has_f_visibility,
942        [gcry_cv_gcc_has_f_visibility=no
943         _gcc_cflags_save=$CFLAGS
944         CFLAGS="-fvisibility=hidden"
945         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],
946                           gcry_cv_gcc_has_f_visibility=yes)
947         CFLAGS=$_gcc_cflags_save;
948        ])
949 fi
950 if test "$gcry_cv_visibility_attribute" = "yes" \
951    && test "$gcry_cv_broken_visibility_attribute" != "yes" \
952    && test "$gcry_cv_broken_alias_attribute" != "yes" \
953    && test "$gcry_cv_gcc_has_f_visibility" = "yes"
954  then
955    AC_DEFINE(GCRY_USE_VISIBILITY, 1,
956                [Define to use the GNU C visibility attribute.])
957    CFLAGS="$CFLAGS -fvisibility=hidden"
958 fi
959
960
961 # Following attribute tests depend on warnings to cause compile to fail,
962 # so set -Werror temporarily.
963 _gcc_cflags_save=$CFLAGS
964 CFLAGS="$CFLAGS -Werror"
965
966
967 #
968 # Check whether the compiler supports the GCC style aligned attribute
969 #
970 AC_CACHE_CHECK([whether the GCC style aligned attribute is supported],
971        [gcry_cv_gcc_attribute_aligned],
972        [gcry_cv_gcc_attribute_aligned=no
973         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
974           [[struct { int a; } foo __attribute__ ((aligned (16)));]])],
975           [gcry_cv_gcc_attribute_aligned=yes])])
976 if test "$gcry_cv_gcc_attribute_aligned" = "yes" ; then
977    AC_DEFINE(HAVE_GCC_ATTRIBUTE_ALIGNED,1,
978      [Defined if a GCC style "__attribute__ ((aligned (n))" is supported])
979 fi
980
981
982 #
983 # Check whether the compiler supports the GCC style packed attribute
984 #
985 AC_CACHE_CHECK([whether the GCC style packed attribute is supported],
986        [gcry_cv_gcc_attribute_packed],
987        [gcry_cv_gcc_attribute_packed=no
988         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
989           [[struct foolong_s { long b; } __attribute__ ((packed));
990             struct foo_s { char a; struct foolong_s b; }
991               __attribute__ ((packed));
992             enum bar {
993               FOO = 1 / (sizeof(struct foo_s) == (sizeof(char) + sizeof(long))),
994             };]])],
995           [gcry_cv_gcc_attribute_packed=yes])])
996 if test "$gcry_cv_gcc_attribute_packed" = "yes" ; then
997    AC_DEFINE(HAVE_GCC_ATTRIBUTE_PACKED,1,
998      [Defined if a GCC style "__attribute__ ((packed))" is supported])
999 fi
1000
1001
1002 #
1003 # Check whether the compiler supports the GCC style may_alias attribute
1004 #
1005 AC_CACHE_CHECK([whether the GCC style may_alias attribute is supported],
1006        [gcry_cv_gcc_attribute_may_alias],
1007        [gcry_cv_gcc_attribute_may_alias=no
1008         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1009           [[typedef struct foo_s { int a; }
1010             __attribute__ ((may_alias)) foo_t;]])],
1011           [gcry_cv_gcc_attribute_may_alias=yes])])
1012 if test "$gcry_cv_gcc_attribute_may_alias" = "yes" ; then
1013    AC_DEFINE(HAVE_GCC_ATTRIBUTE_MAY_ALIAS,1,
1014      [Defined if a GCC style "__attribute__ ((may_alias))" is supported])
1015 fi
1016
1017
1018 # Restore flags.
1019 CFLAGS=$_gcc_cflags_save;
1020
1021
1022 #
1023 # Check whether the compiler supports 'asm' or '__asm__' keyword for
1024 # assembler blocks.
1025 #
1026 AC_CACHE_CHECK([whether 'asm' assembler keyword is supported],
1027        [gcry_cv_have_asm],
1028        [gcry_cv_have_asm=no
1029         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1030           [[void a(void) { asm("":::"memory"); }]])],
1031           [gcry_cv_have_asm=yes])])
1032 AC_CACHE_CHECK([whether '__asm__' assembler keyword is supported],
1033        [gcry_cv_have___asm__],
1034        [gcry_cv_have___asm__=no
1035         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1036           [[void a(void) { __asm__("":::"memory"); }]])],
1037           [gcry_cv_have___asm__=yes])])
1038 if test "$gcry_cv_have_asm" = "no" ; then
1039    if test "$gcry_cv_have___asm__" = "yes" ; then
1040       AC_DEFINE(asm,__asm__,
1041         [Define to supported assembler block keyword, if plain 'asm' was not
1042          supported])
1043    fi
1044 fi
1045
1046
1047 #
1048 # Check whether the compiler supports inline assembly memory barrier.
1049 #
1050 if test "$gcry_cv_have_asm" = "no" ; then
1051    if test "$gcry_cv_have___asm__" = "yes" ; then
1052       AC_CACHE_CHECK([whether inline assembly memory barrier is supported],
1053           [gcry_cv_have_asm_volatile_memory],
1054           [gcry_cv_have_asm_volatile_memory=no
1055            AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1056              [[void a(void) { __asm__ volatile("":::"memory"); }]])],
1057              [gcry_cv_have_asm_volatile_memory=yes])])
1058    fi
1059 else
1060    AC_CACHE_CHECK([whether inline assembly memory barrier is supported],
1061        [gcry_cv_have_asm_volatile_memory],
1062        [gcry_cv_have_asm_volatile_memory=no
1063         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1064           [[void a(void) { asm volatile("":::"memory"); }]])],
1065           [gcry_cv_have_asm_volatile_memory=yes])])
1066 fi
1067 if test "$gcry_cv_have_asm_volatile_memory" = "yes" ; then
1068    AC_DEFINE(HAVE_GCC_ASM_VOLATILE_MEMORY,1,
1069      [Define if inline asm memory barrier is supported])
1070 fi
1071
1072
1073 #
1074 # Check whether GCC assembler supports features needed for our ARM
1075 # implementations.  This needs to be done before setting up the
1076 # assembler stuff.
1077 #
1078 AC_CACHE_CHECK([whether GCC assembler is compatible for ARM assembly implementations],
1079        [gcry_cv_gcc_arm_platform_as_ok],
1080        [gcry_cv_gcc_arm_platform_as_ok=no
1081         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1082           [[__asm__(
1083                 /* Test if assembler supports UAL syntax.  */
1084                 ".syntax unified\n\t"
1085                 ".arm\n\t" /* our assembly code is in ARM mode  */
1086                 /* Following causes error if assembler ignored '.syntax unified'.  */
1087                 "asmfunc:\n\t"
1088                 "add %r0, %r0, %r4, ror #12;\n\t"
1089
1090                 /* Test if '.type' and '.size' are supported.  */
1091                 ".size asmfunc,.-asmfunc;\n\t"
1092                 ".type asmfunc,%function;\n\t"
1093             );]])],
1094           [gcry_cv_gcc_arm_platform_as_ok=yes])])
1095 if test "$gcry_cv_gcc_arm_platform_as_ok" = "yes" ; then
1096    AC_DEFINE(HAVE_COMPATIBLE_GCC_ARM_PLATFORM_AS,1,
1097      [Defined if underlying assembler is compatible with ARM assembly implementations])
1098 fi
1099
1100
1101 #
1102 # Check whether GCC assembler supports features needed for our ARMv8/Aarch64
1103 # implementations.  This needs to be done before setting up the
1104 # assembler stuff.
1105 #
1106 AC_CACHE_CHECK([whether GCC assembler is compatible for ARMv8/Aarch64 assembly implementations],
1107        [gcry_cv_gcc_aarch64_platform_as_ok],
1108        [gcry_cv_gcc_aarch64_platform_as_ok=no
1109         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1110           [[__asm__(
1111                 "asmfunc:\n\t"
1112                 "eor x0, x0, x30, ror #12;\n\t"
1113                 "add x0, x0, x30, asr #12;\n\t"
1114                 "eor v0.16b, v0.16b, v31.16b;\n\t"
1115
1116                 /* Test if '.type' and '.size' are supported.  */
1117                 ".size asmfunc,.-asmfunc;\n\t"
1118                 ".type asmfunc,@function;\n\t"
1119             );]])],
1120           [gcry_cv_gcc_aarch64_platform_as_ok=yes])])
1121 if test "$gcry_cv_gcc_aarch64_platform_as_ok" = "yes" ; then
1122    AC_DEFINE(HAVE_COMPATIBLE_GCC_AARCH64_PLATFORM_AS,1,
1123      [Defined if underlying assembler is compatible with ARMv8/Aarch64 assembly implementations])
1124 fi
1125
1126
1127 #
1128 # Check whether underscores in symbols are required.  This needs to be
1129 # done before setting up the assembler stuff.
1130 #
1131 GNUPG_SYS_SYMBOL_UNDERSCORE()
1132
1133
1134 #################################
1135 ####                         ####
1136 #### Setup assembler stuff.  ####
1137 #### Define mpi_cpu_arch.    ####
1138 ####                         ####
1139 #################################
1140 AC_ARG_ENABLE(mpi-path,
1141               AC_HELP_STRING([--enable-mpi-path=EXTRA_PATH],
1142               [prepend EXTRA_PATH to list of CPU specific optimizations]),
1143               mpi_extra_path="$enableval",mpi_extra_path="")
1144 AC_MSG_CHECKING(architecture and mpi assembler functions)
1145 if test -f $srcdir/mpi/config.links ; then
1146     . $srcdir/mpi/config.links
1147     AC_CONFIG_LINKS("$mpi_ln_list")
1148     ac_cv_mpi_sflags="$mpi_sflags"
1149     AC_MSG_RESULT($mpi_cpu_arch)
1150 else
1151     AC_MSG_RESULT(failed)
1152     AC_MSG_ERROR([mpi/config.links missing!])
1153 fi
1154 MPI_SFLAGS="$ac_cv_mpi_sflags"
1155 AC_SUBST(MPI_SFLAGS)
1156
1157 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_ADD1, test "$mpi_mod_asm_mpih_add1" = yes)
1158 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_SUB1, test "$mpi_mod_asm_mpih_sub1" = yes)
1159 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_MUL1, test "$mpi_mod_asm_mpih_mul1" = yes)
1160 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_MUL2, test "$mpi_mod_asm_mpih_mul2" = yes)
1161 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_MUL3, test "$mpi_mod_asm_mpih_mul3" = yes)
1162 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_LSHIFT, test "$mpi_mod_asm_mpih_lshift" = yes)
1163 AM_CONDITIONAL(MPI_MOD_ASM_MPIH_RSHIFT, test "$mpi_mod_asm_mpih_rshift" = yes)
1164 AM_CONDITIONAL(MPI_MOD_ASM_UDIV, test "$mpi_mod_asm_udiv" = yes)
1165 AM_CONDITIONAL(MPI_MOD_ASM_UDIV_QRNND, test "$mpi_mod_asm_udiv_qrnnd" = yes)
1166 AM_CONDITIONAL(MPI_MOD_C_MPIH_ADD1, test "$mpi_mod_c_mpih_add1" = yes)
1167 AM_CONDITIONAL(MPI_MOD_C_MPIH_SUB1, test "$mpi_mod_c_mpih_sub1" = yes)
1168 AM_CONDITIONAL(MPI_MOD_C_MPIH_MUL1, test "$mpi_mod_c_mpih_mul1" = yes)
1169 AM_CONDITIONAL(MPI_MOD_C_MPIH_MUL2, test "$mpi_mod_c_mpih_mul2" = yes)
1170 AM_CONDITIONAL(MPI_MOD_C_MPIH_MUL3, test "$mpi_mod_c_mpih_mul3" = yes)
1171 AM_CONDITIONAL(MPI_MOD_C_MPIH_LSHIFT, test "$mpi_mod_c_mpih_lshift" = yes)
1172 AM_CONDITIONAL(MPI_MOD_C_MPIH_RSHIFT, test "$mpi_mod_c_mpih_rshift" = yes)
1173 AM_CONDITIONAL(MPI_MOD_C_UDIV, test "$mpi_mod_c_udiv" = yes)
1174 AM_CONDITIONAL(MPI_MOD_C_UDIV_QRNND, test "$mpi_mod_c_udiv_qrnnd" = yes)
1175
1176 # Reset non applicable feature flags.
1177 if test "$mpi_cpu_arch" != "x86" ; then
1178    aesnisupport="n/a"
1179    pclmulsupport="n/a"
1180    sse41support="n/a"
1181    avxsupport="n/a"
1182    avx2support="n/a"
1183    padlocksupport="n/a"
1184    drngsupport="n/a"
1185 fi
1186
1187 if test "$mpi_cpu_arch" != "arm" ; then
1188    if test "$mpi_cpu_arch" != "aarch64" ; then
1189      neonsupport="n/a"
1190      armcryptosupport="n/a"
1191    fi
1192 fi
1193
1194
1195 #############################################
1196 ####                                     ####
1197 #### Platform specific compiler checks.  ####
1198 ####                                     ####
1199 #############################################
1200
1201
1202 # Following tests depend on warnings to cause compile to fail, so set -Werror
1203 # temporarily.
1204 _gcc_cflags_save=$CFLAGS
1205 CFLAGS="$CFLAGS -Werror"
1206
1207
1208 #
1209 # Check whether compiler supports 'ms_abi' function attribute.
1210 #
1211 AC_CACHE_CHECK([whether compiler supports 'ms_abi' function attribute],
1212        [gcry_cv_gcc_attribute_ms_abi],
1213        [gcry_cv_gcc_attribute_ms_abi=no
1214         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1215           [[int __attribute__ ((ms_abi)) proto(int);]])],
1216           [gcry_cv_gcc_attribute_ms_abi=yes])])
1217 if test "$gcry_cv_gcc_attribute_ms_abi" = "yes" ; then
1218    AC_DEFINE(HAVE_GCC_ATTRIBUTE_MS_ABI,1,
1219      [Defined if compiler supports "__attribute__ ((ms_abi))" function attribute])
1220 fi
1221
1222
1223 #
1224 # Check whether compiler supports 'sysv_abi' function attribute.
1225 #
1226 AC_CACHE_CHECK([whether compiler supports 'sysv_abi' function attribute],
1227        [gcry_cv_gcc_attribute_sysv_abi],
1228        [gcry_cv_gcc_attribute_sysv_abi=no
1229         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1230           [[int __attribute__ ((sysv_abi)) proto(int);]])],
1231           [gcry_cv_gcc_attribute_sysv_abi=yes])])
1232 if test "$gcry_cv_gcc_attribute_sysv_abi" = "yes" ; then
1233    AC_DEFINE(HAVE_GCC_ATTRIBUTE_SYSV_ABI,1,
1234      [Defined if compiler supports "__attribute__ ((sysv_abi))" function attribute])
1235 fi
1236
1237
1238 #
1239 # Check whether default calling convention is 'ms_abi'.
1240 #
1241 if test "$gcry_cv_gcc_attribute_ms_abi" = "yes" ; then
1242    AC_CACHE_CHECK([whether default calling convention is 'ms_abi'],
1243           [gcry_cv_gcc_default_abi_is_ms_abi],
1244           [gcry_cv_gcc_default_abi_is_ms_abi=no
1245            AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1246              [[void *test(void) {
1247                  void *(*def_func)(void) = test;
1248                  void *__attribute__((ms_abi))(*msabi_func)(void);
1249                  /* warning on SysV abi targets, passes on Windows based targets */
1250                  msabi_func = def_func;
1251                  return msabi_func;
1252              }]])],
1253              [gcry_cv_gcc_default_abi_is_ms_abi=yes])])
1254    if test "$gcry_cv_gcc_default_abi_is_ms_abi" = "yes" ; then
1255       AC_DEFINE(HAVE_GCC_DEFAULT_ABI_IS_MS_ABI,1,
1256         [Defined if default calling convention is 'ms_abi'])
1257    fi
1258 fi
1259
1260
1261 #
1262 # Check whether default calling convention is 'sysv_abi'.
1263 #
1264 if test "$gcry_cv_gcc_attribute_sysv_abi" = "yes" ; then
1265    AC_CACHE_CHECK([whether default calling convention is 'sysv_abi'],
1266           [gcry_cv_gcc_default_abi_is_sysv_abi],
1267           [gcry_cv_gcc_default_abi_is_sysv_abi=no
1268            AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1269              [[void *test(void) {
1270                  void *(*def_func)(void) = test;
1271                  void *__attribute__((sysv_abi))(*sysvabi_func)(void);
1272                  /* warning on MS ABI targets, passes on SysV ABI targets */
1273                  sysvabi_func = def_func;
1274                  return sysvabi_func;
1275              }]])],
1276              [gcry_cv_gcc_default_abi_is_sysv_abi=yes])])
1277    if test "$gcry_cv_gcc_default_abi_is_sysv_abi" = "yes" ; then
1278       AC_DEFINE(HAVE_GCC_DEFAULT_ABI_IS_SYSV_ABI,1,
1279         [Defined if default calling convention is 'sysv_abi'])
1280    fi
1281 fi
1282
1283
1284 # Restore flags.
1285 CFLAGS=$_gcc_cflags_save;
1286
1287
1288 #
1289 # Check whether GCC inline assembler supports SSSE3 instructions
1290 # This is required for the AES-NI instructions.
1291 #
1292 AC_CACHE_CHECK([whether GCC inline assembler supports SSSE3 instructions],
1293        [gcry_cv_gcc_inline_asm_ssse3],
1294        [if test "$mpi_cpu_arch" != "x86" ; then
1295           gcry_cv_gcc_inline_asm_ssse3="n/a"
1296         else
1297           gcry_cv_gcc_inline_asm_ssse3=no
1298           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1299           [[static unsigned char be_mask[16] __attribute__ ((aligned (16))) =
1300               { 15, 14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0 };
1301             void a(void) {
1302               __asm__("pshufb %[mask], %%xmm2\n\t"::[mask]"m"(*be_mask):);
1303             }]])],
1304           [gcry_cv_gcc_inline_asm_ssse3=yes])
1305         fi])
1306 if test "$gcry_cv_gcc_inline_asm_ssse3" = "yes" ; then
1307    AC_DEFINE(HAVE_GCC_INLINE_ASM_SSSE3,1,
1308      [Defined if inline assembler supports SSSE3 instructions])
1309 fi
1310
1311
1312 #
1313 # Check whether GCC inline assembler supports PCLMUL instructions.
1314 #
1315 AC_CACHE_CHECK([whether GCC inline assembler supports PCLMUL instructions],
1316        [gcry_cv_gcc_inline_asm_pclmul],
1317        [if test "$mpi_cpu_arch" != "x86" ; then
1318           gcry_cv_gcc_inline_asm_pclmul="n/a"
1319         else
1320           gcry_cv_gcc_inline_asm_pclmul=no
1321           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1322           [[void a(void) {
1323               __asm__("pclmulqdq \$0, %%xmm1, %%xmm3\n\t":::"cc");
1324             }]])],
1325           [gcry_cv_gcc_inline_asm_pclmul=yes])
1326         fi])
1327 if test "$gcry_cv_gcc_inline_asm_pclmul" = "yes" ; then
1328    AC_DEFINE(HAVE_GCC_INLINE_ASM_PCLMUL,1,
1329      [Defined if inline assembler supports PCLMUL instructions])
1330 fi
1331
1332 #
1333 # Check whether GCC inline assembler supports SSE4.1 instructions.
1334 #
1335 AC_CACHE_CHECK([whether GCC inline assembler supports SSE4.1 instructions],
1336        [gcry_cv_gcc_inline_asm_sse41],
1337        [if test "$mpi_cpu_arch" != "x86" ; then
1338           gcry_cv_gcc_inline_asm_sse41="n/a"
1339         else
1340           gcry_cv_gcc_inline_asm_sse41=no
1341           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1342           [[void a(void) {
1343               int i;
1344               __asm__("pextrd \$2, %%xmm0, %[out]\n\t" : [out] "=m" (i));
1345             }]])],
1346           [gcry_cv_gcc_inline_asm_sse41=yes])
1347         fi])
1348 if test "$gcry_cv_gcc_inline_asm_sse41" = "yes" ; then
1349    AC_DEFINE(HAVE_GCC_INLINE_ASM_SSE41,1,
1350      [Defined if inline assembler supports SSE4.1 instructions])
1351 fi
1352
1353
1354 #
1355 # Check whether GCC inline assembler supports AVX instructions
1356 #
1357 AC_CACHE_CHECK([whether GCC inline assembler supports AVX instructions],
1358        [gcry_cv_gcc_inline_asm_avx],
1359        [if test "$mpi_cpu_arch" != "x86" ; then
1360           gcry_cv_gcc_inline_asm_avx="n/a"
1361         else
1362           gcry_cv_gcc_inline_asm_avx=no
1363           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1364           [[void a(void) {
1365               __asm__("xgetbv; vaesdeclast (%[mem]),%%xmm0,%%xmm7\n\t"::[mem]"r"(0):);
1366             }]])],
1367           [gcry_cv_gcc_inline_asm_avx=yes])
1368         fi])
1369 if test "$gcry_cv_gcc_inline_asm_avx" = "yes" ; then
1370    AC_DEFINE(HAVE_GCC_INLINE_ASM_AVX,1,
1371      [Defined if inline assembler supports AVX instructions])
1372 fi
1373
1374
1375 #
1376 # Check whether GCC inline assembler supports AVX2 instructions
1377 #
1378 AC_CACHE_CHECK([whether GCC inline assembler supports AVX2 instructions],
1379        [gcry_cv_gcc_inline_asm_avx2],
1380        [if test "$mpi_cpu_arch" != "x86" ; then
1381           gcry_cv_gcc_inline_asm_avx2="n/a"
1382         else
1383           gcry_cv_gcc_inline_asm_avx2=no
1384           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1385           [[void a(void) {
1386               __asm__("xgetbv; vpbroadcastb %%xmm7,%%ymm1\n\t":::"cc");
1387             }]])],
1388           [gcry_cv_gcc_inline_asm_avx2=yes])
1389         fi])
1390 if test "$gcry_cv_gcc_inline_asm_avx2" = "yes" ; then
1391    AC_DEFINE(HAVE_GCC_INLINE_ASM_AVX2,1,
1392      [Defined if inline assembler supports AVX2 instructions])
1393 fi
1394
1395
1396 #
1397 # Check whether GCC inline assembler supports BMI2 instructions
1398 #
1399 AC_CACHE_CHECK([whether GCC inline assembler supports BMI2 instructions],
1400        [gcry_cv_gcc_inline_asm_bmi2],
1401        [if test "$mpi_cpu_arch" != "x86" ; then
1402           gcry_cv_gcc_inline_asm_bmi2="n/a"
1403         else
1404           gcry_cv_gcc_inline_asm_bmi2=no
1405           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1406           [[void a(void) {
1407               __asm__("rorxl \$23, %%eax, %%edx\\n\\t":::"memory");
1408             }]])],
1409           [gcry_cv_gcc_inline_asm_bmi2=yes])
1410         fi])
1411 if test "$gcry_cv_gcc_inline_asm_bmi2" = "yes" ; then
1412    AC_DEFINE(HAVE_GCC_INLINE_ASM_BMI2,1,
1413      [Defined if inline assembler supports BMI2 instructions])
1414 fi
1415
1416
1417 #
1418 # Check whether GCC assembler needs "-Wa,--divide" to correctly handle
1419 # constant division
1420 #
1421 if test $amd64_as_feature_detection = yes; then
1422   AC_CACHE_CHECK([whether GCC assembler handles division correctly],
1423        [gcry_cv_gcc_as_const_division_ok],
1424        [gcry_cv_gcc_as_const_division_ok=no
1425         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1426           [[__asm__("xorl \$(123456789/12345678), %ebp;\n\t");]])],
1427           [gcry_cv_gcc_as_const_division_ok=yes])])
1428   if test "$gcry_cv_gcc_as_const_division_ok" = "no" ; then
1429     #
1430     # Add '-Wa,--divide' to CPPFLAGS and try check again.
1431     #
1432     _gcc_cppflags_save="$CPPFLAGS"
1433     CPPFLAGS="$CPPFLAGS -Wa,--divide"
1434     AC_CACHE_CHECK([whether GCC assembler handles division correctly with "-Wa,--divide"],
1435          [gcry_cv_gcc_as_const_division_with_wadivide_ok],
1436          [gcry_cv_gcc_as_const_division_with_wadivide_ok=no
1437           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1438             [[__asm__("xorl \$(123456789/12345678), %ebp;\n\t");]])],
1439             [gcry_cv_gcc_as_const_division_with_wadivide_ok=yes])])
1440     if test "$gcry_cv_gcc_as_const_division_with_wadivide_ok" = "no" ; then
1441       # '-Wa,--divide' did not work, restore old flags.
1442       CPPFLAGS="$_gcc_cppflags_save"
1443     fi
1444   fi
1445 fi
1446
1447
1448 #
1449 # Check whether GCC assembler supports features needed for our amd64
1450 # implementations
1451 #
1452 if test $amd64_as_feature_detection = yes; then
1453   AC_CACHE_CHECK([whether GCC assembler is compatible for amd64 assembly implementations],
1454        [gcry_cv_gcc_amd64_platform_as_ok],
1455        [if test "$mpi_cpu_arch" != "x86" ; then
1456           gcry_cv_gcc_amd64_platform_as_ok="n/a"
1457         else
1458           gcry_cv_gcc_amd64_platform_as_ok=no
1459           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1460           [[__asm__(
1461                 /* Test if '.type' and '.size' are supported.  */
1462                 /* These work only on ELF targets. */
1463                 "asmfunc:\n\t"
1464                 ".size asmfunc,.-asmfunc;\n\t"
1465                 ".type asmfunc,@function;\n\t"
1466                 /* Test if assembler allows use of '/' for constant division
1467                  * (Solaris/x86 issue). If previous constant division check
1468                  * and "-Wa,--divide" workaround failed, this causes assembly
1469                  * to be disable on this machine. */
1470                 "xorl \$(123456789/12345678), %ebp;\n\t"
1471             );]])],
1472           [gcry_cv_gcc_amd64_platform_as_ok=yes])
1473         fi])
1474   if test "$gcry_cv_gcc_amd64_platform_as_ok" = "yes" ; then
1475      AC_DEFINE(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS,1,
1476               [Defined if underlying assembler is compatible with amd64 assembly implementations])
1477   fi
1478   if test "$gcry_cv_gcc_amd64_platform_as_ok" = "no" &&
1479      test "$gcry_cv_gcc_attribute_sysv_abi" = "yes" &&
1480      test "$gcry_cv_gcc_default_abi_is_ms_abi" = "yes"; then
1481     AC_CACHE_CHECK([whether GCC assembler is compatible for WIN64 assembly implementations],
1482       [gcry_cv_gcc_win64_platform_as_ok],
1483       [gcry_cv_gcc_win64_platform_as_ok=no
1484       AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1485         [[__asm__(
1486               ".globl asmfunc\n\t"
1487               "asmfunc:\n\t"
1488               "xorq \$(1234), %rbp;\n\t"
1489           );]])],
1490         [gcry_cv_gcc_win64_platform_as_ok=yes])])
1491     if test "$gcry_cv_gcc_win64_platform_as_ok" = "yes" ; then
1492       AC_DEFINE(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS,1,
1493                 [Defined if underlying assembler is compatible with WIN64 assembly implementations])
1494     fi
1495   fi
1496 fi
1497
1498
1499 #
1500 # Check whether GCC assembler supports features needed for assembly
1501 # implementations that use Intel syntax
1502 #
1503 AC_CACHE_CHECK([whether GCC assembler is compatible for Intel syntax assembly implementations],
1504        [gcry_cv_gcc_platform_as_ok_for_intel_syntax],
1505        [if test "$mpi_cpu_arch" != "x86" ; then
1506           gcry_cv_gcc_platform_as_ok_for_intel_syntax="n/a"
1507         else
1508           gcry_cv_gcc_platform_as_ok_for_intel_syntax=no
1509           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1510           [[__asm__(
1511                 ".intel_syntax noprefix\n\t"
1512                 "pxor xmm1, xmm7;\n\t"
1513                 /* Intel syntax implementation also use GAS macros, so check
1514                  * for them here. */
1515                 "VAL_A = xmm4\n\t"
1516                 "VAL_B = xmm2\n\t"
1517                 ".macro SET_VAL_A p1\n\t"
1518                 "  VAL_A = \\\\p1 \n\t"
1519                 ".endm\n\t"
1520                 ".macro SET_VAL_B p1\n\t"
1521                 "  VAL_B = \\\\p1 \n\t"
1522                 ".endm\n\t"
1523                 "vmovdqa VAL_A, VAL_B;\n\t"
1524                 "SET_VAL_A eax\n\t"
1525                 "SET_VAL_B ebp\n\t"
1526                 "add VAL_A, VAL_B;\n\t"
1527                 "add VAL_B, 0b10101;\n\t"
1528             );]])],
1529           [gcry_cv_gcc_platform_as_ok_for_intel_syntax=yes])
1530         fi])
1531 if test "$gcry_cv_gcc_platform_as_ok_for_intel_syntax" = "yes" ; then
1532   AC_DEFINE(HAVE_INTEL_SYNTAX_PLATFORM_AS,1,
1533             [Defined if underlying assembler is compatible with Intel syntax assembly implementations])
1534 fi
1535
1536
1537 #
1538 # Check whether compiler is configured for ARMv6 or newer architecture
1539 #
1540 AC_CACHE_CHECK([whether compiler is configured for ARMv6 or newer architecture],
1541        [gcry_cv_cc_arm_arch_is_v6],
1542        [if test "$mpi_cpu_arch" != "arm" ; then
1543           gcry_cv_cc_arm_arch_is_v6="n/a"
1544         else
1545           gcry_cv_cc_arm_arch_is_v6=no
1546           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1547           [[
1548            #if defined(__arm__) && \
1549              ((defined(__ARM_ARCH) && __ARM_ARCH >= 6) \
1550              || defined(__ARM_ARCH_6__) || defined(__ARM_ARCH_6J__) \
1551              || defined(__ARM_ARCH_6Z__) || defined(__ARM_ARCH_6ZK__) \
1552              || defined(__ARM_ARCH_6K__) || defined(__ARM_ARCH_6T2__) \
1553              || defined(__ARM_ARCH_7__) || defined(__ARM_ARCH_7A__) \
1554              || defined(__ARM_ARCH_7R__) || defined(__ARM_ARCH_7M__) \
1555              || defined(__ARM_ARCH_7EM__))
1556              /* empty */
1557            #else
1558              /* fail compile if not ARMv6. */
1559              not_armv6 not_armv6 = (not_armv6)not_armv6;
1560            #endif
1561           ]])],
1562           [gcry_cv_cc_arm_arch_is_v6=yes])
1563         fi])
1564 if test "$gcry_cv_cc_arm_arch_is_v6" = "yes" ; then
1565    AC_DEFINE(HAVE_ARM_ARCH_V6,1,
1566      [Defined if ARM architecture is v6 or newer])
1567 fi
1568
1569
1570 #
1571 # Check whether GCC inline assembler supports NEON instructions
1572 #
1573 AC_CACHE_CHECK([whether GCC inline assembler supports NEON instructions],
1574        [gcry_cv_gcc_inline_asm_neon],
1575        [if test "$mpi_cpu_arch" != "arm" ; then
1576           gcry_cv_gcc_inline_asm_neon="n/a"
1577         else
1578           gcry_cv_gcc_inline_asm_neon=no
1579           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1580           [[__asm__(
1581                 ".syntax unified\n\t"
1582                 ".arm\n\t"
1583                 ".fpu neon\n\t"
1584                 "vld1.64 {%q0-%q1}, [%r0]!;\n\t"
1585                 "vrev64.8 %q0, %q3;\n\t"
1586                 "vadd.u64 %q0, %q1;\n\t"
1587                 "vadd.s64 %d3, %d2, %d3;\n\t"
1588                 );
1589             ]])],
1590           [gcry_cv_gcc_inline_asm_neon=yes])
1591         fi])
1592 if test "$gcry_cv_gcc_inline_asm_neon" = "yes" ; then
1593    AC_DEFINE(HAVE_GCC_INLINE_ASM_NEON,1,
1594      [Defined if inline assembler supports NEON instructions])
1595 fi
1596
1597
1598 #
1599 # Check whether GCC inline assembler supports AArch32 Crypto Extension instructions
1600 #
1601 AC_CACHE_CHECK([whether GCC inline assembler supports AArch32 Crypto Extension instructions],
1602        [gcry_cv_gcc_inline_asm_aarch32_crypto],
1603        [if test "$mpi_cpu_arch" != "arm" ; then
1604           gcry_cv_gcc_inline_asm_aarch32_crypto="n/a"
1605         else
1606           gcry_cv_gcc_inline_asm_aarch32_crypto=no
1607           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1608           [[__asm__(
1609                 ".syntax unified\n\t"
1610                 ".arm\n\t"
1611                 ".fpu crypto-neon-fp-armv8\n\t"
1612
1613                 "sha1h.32 q0, q0;\n\t"
1614                 "sha1c.32 q0, q0, q0;\n\t"
1615                 "sha1p.32 q0, q0, q0;\n\t"
1616                 "sha1su0.32 q0, q0, q0;\n\t"
1617                 "sha1su1.32 q0, q0;\n\t"
1618
1619                 "sha256h.32 q0, q0, q0;\n\t"
1620                 "sha256h2.32 q0, q0, q0;\n\t"
1621                 "sha1p.32 q0, q0, q0;\n\t"
1622                 "sha256su0.32 q0, q0;\n\t"
1623                 "sha256su1.32 q0, q0, q15;\n\t"
1624
1625                 "aese.8 q0, q0;\n\t"
1626                 "aesd.8 q0, q0;\n\t"
1627                 "aesmc.8 q0, q0;\n\t"
1628                 "aesimc.8 q0, q0;\n\t"
1629
1630                 "vmull.p64 q0, d0, d0;\n\t"
1631                 );
1632             ]])],
1633           [gcry_cv_gcc_inline_asm_aarch32_crypto=yes])
1634         fi])
1635 if test "$gcry_cv_gcc_inline_asm_aarch32_crypto" = "yes" ; then
1636    AC_DEFINE(HAVE_GCC_INLINE_ASM_AARCH32_CRYPTO,1,
1637      [Defined if inline assembler supports AArch32 Crypto Extension instructions])
1638 fi
1639
1640
1641 #
1642 # Check whether GCC inline assembler supports AArch64 NEON instructions
1643 #
1644 AC_CACHE_CHECK([whether GCC inline assembler supports AArch64 NEON instructions],
1645        [gcry_cv_gcc_inline_asm_aarch64_neon],
1646        [if test "$mpi_cpu_arch" != "aarch64" ; then
1647           gcry_cv_gcc_inline_asm_aarch64_neon="n/a"
1648         else
1649           gcry_cv_gcc_inline_asm_aarch64_neon=no
1650           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1651           [[__asm__(
1652                 ".arch armv8-a\n\t"
1653                 "mov w0, \#42;\n\t"
1654                 "dup v0.8b, w0;\n\t"
1655                 "ld4 {v0.8b,v1.8b,v2.8b,v3.8b},[x0],\#32;\n\t"
1656                 );
1657             ]])],
1658           [gcry_cv_gcc_inline_asm_aarch64_neon=yes])
1659         fi])
1660 if test "$gcry_cv_gcc_inline_asm_aarch64_neon" = "yes" ; then
1661    AC_DEFINE(HAVE_GCC_INLINE_ASM_AARCH64_NEON,1,
1662      [Defined if inline assembler supports AArch64 NEON instructions])
1663 fi
1664
1665
1666 #
1667 # Check whether GCC inline assembler supports AArch64 Crypto Extension instructions
1668 #
1669 AC_CACHE_CHECK([whether GCC inline assembler supports AArch64 Crypto Extension instructions],
1670        [gcry_cv_gcc_inline_asm_aarch64_crypto],
1671        [if test "$mpi_cpu_arch" != "aarch64" ; then
1672           gcry_cv_gcc_inline_asm_aarch64_crypto="n/a"
1673         else
1674           gcry_cv_gcc_inline_asm_aarch64_crypto=no
1675           AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1676           [[__asm__(
1677                 ".arch armv8-a+crypto\n\t"
1678
1679                 "sha1h s0, s0;\n\t"
1680                 "sha1c q0, s0, v0.4s;\n\t"
1681                 "sha1p q0, s0, v0.4s;\n\t"
1682                 "sha1su0 v0.4s, v0.4s, v0.4s;\n\t"
1683                 "sha1su1 v0.4s, v0.4s;\n\t"
1684
1685                 "sha256h q0, q0, v0.4s;\n\t"
1686                 "sha256h2 q0, q0, v0.4s;\n\t"
1687                 "sha1p q0, s0, v0.4s;\n\t"
1688                 "sha256su0 v0.4s, v0.4s;\n\t"
1689                 "sha256su1 v0.4s, v0.4s, v31.4s;\n\t"
1690
1691                 "aese v0.16b, v0.16b;\n\t"
1692                 "aesd v0.16b, v0.16b;\n\t"
1693                 "aesmc v0.16b, v0.16b;\n\t"
1694                 "aesimc v0.16b, v0.16b;\n\t"
1695
1696                 "pmull v0.1q, v0.1d, v31.1d;\n\t"
1697                 "pmull2 v0.1q, v0.2d, v31.2d;\n\t"
1698                 );
1699             ]])],
1700           [gcry_cv_gcc_inline_asm_aarch64_crypto=yes])
1701         fi])
1702 if test "$gcry_cv_gcc_inline_asm_aarch64_crypto" = "yes" ; then
1703    AC_DEFINE(HAVE_GCC_INLINE_ASM_AARCH64_CRYPTO,1,
1704      [Defined if inline assembler supports AArch64 Crypto Extension instructions])
1705 fi
1706
1707
1708 #######################################
1709 #### Checks for library functions. ####
1710 #######################################
1711
1712 AC_FUNC_VPRINTF
1713 # We have replacements for these in src/missing-string.c
1714 AC_CHECK_FUNCS(stpcpy strcasecmp)
1715 # We have replacements for these in src/g10lib.h
1716 AC_CHECK_FUNCS(strtoul memmove stricmp atexit raise)
1717 # Other checks
1718 AC_CHECK_FUNCS(strerror rand mmap getpagesize sysconf waitpid wait4)
1719 AC_CHECK_FUNCS(gettimeofday getrusage gethrtime clock_gettime syslog)
1720 AC_CHECK_FUNCS(syscall fcntl ftruncate flockfile)
1721
1722 GNUPG_CHECK_MLOCK
1723
1724 #
1725 # Replacement functions.
1726 #
1727 AC_REPLACE_FUNCS([getpid clock])
1728
1729
1730 #
1731 # Check wether it is necessary to link against libdl.
1732 #
1733 DL_LIBS=""
1734 if test "$use_hmac_binary_check" = yes ; then
1735   _gcry_save_libs="$LIBS"
1736   LIBS=""
1737   AC_SEARCH_LIBS(dlopen, c dl,,,)
1738   DL_LIBS=$LIBS
1739   LIBS="$_gcry_save_libs"
1740   LIBGCRYPT_CONFIG_LIBS="${LIBGCRYPT_CONFIG_LIBS} ${DL_LIBS}"
1741 fi
1742 AC_SUBST(DL_LIBS)
1743
1744
1745 #
1746 # Check whether we can use Linux capabilities as requested.
1747 #
1748 if test "$use_capabilities" = "yes" ; then
1749 use_capabilities=no
1750 AC_CHECK_HEADERS(sys/capability.h)
1751 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
1752   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
1753   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
1754      AC_DEFINE(USE_CAPABILITIES,1,
1755                [define if capabilities should be used])
1756      LIBS="$LIBS -lcap"
1757      use_capabilities=yes
1758   fi
1759 fi
1760 if test "$use_capabilities" = "no" ; then
1761     AC_MSG_WARN([[
1762 ***
1763 *** The use of capabilities on this system is not possible.
1764 *** You need a recent Linux kernel and some patches:
1765 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
1766 ***   fcap-module-990613.tar.gz     (kernel module)
1767 ***   libcap-1.92.tar.gz            (user mode library and utilities)
1768 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
1769 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
1770 ***]])
1771 fi
1772 fi
1773
1774 # Check whether a random device is available.
1775 if test "$try_dev_random" = yes ; then
1776     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1777     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
1778       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1779     if test "$ac_cv_have_dev_random" = yes; then
1780         AC_DEFINE(HAVE_DEV_RANDOM,1,
1781                  [defined if the system supports a random device] )
1782     fi
1783 else
1784     AC_MSG_CHECKING(for random device)
1785     ac_cv_have_dev_random=no
1786     AC_MSG_RESULT(has been disabled)
1787 fi
1788
1789 # Figure out the random modules for this configuration.
1790 if test "$random" = "default"; then
1791
1792     # Select default value.
1793     if test "$ac_cv_have_dev_random" = yes; then
1794         # Try Linuxish random device.
1795         random_modules="linux"
1796     else
1797         case "${host}" in
1798         *-*-mingw32ce*)
1799           # WindowsCE random device.
1800           random_modules="w32ce"
1801           ;;
1802         *-*-mingw32*|*-*-cygwin*)
1803           # Windows random device.
1804           random_modules="w32"
1805           ;;
1806         *)
1807           # Build everything, allow to select at runtime.
1808           random_modules="$auto_random_modules"
1809           ;;
1810         esac
1811     fi
1812 else
1813     if test "$random" = "auto"; then
1814         # Build everything, allow to select at runtime.
1815         random_modules="$auto_random_modules"
1816     else
1817         random_modules="$random"
1818     fi
1819 fi
1820
1821
1822 #
1823 # Other defines
1824 #
1825 if test mym4_isgit = "yes"; then
1826     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1827               [Defined if this is not a regular release])
1828 fi
1829
1830
1831 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1832
1833
1834 # This is handy for debugging so the compiler doesn't rearrange
1835 # things and eliminate variables.
1836 AC_ARG_ENABLE(optimization,
1837        AC_HELP_STRING([--disable-optimization],
1838                       [disable compiler optimization]),
1839                       [if test $enableval = no ; then
1840                          CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1841                        fi])
1842
1843 # CFLAGS mangling when using gcc.
1844 if test "$GCC" = yes; then
1845     CFLAGS="$CFLAGS -Wall"
1846     if test "$USE_MAINTAINER_MODE" = "yes"; then
1847         CFLAGS="$CFLAGS -Wcast-align -Wshadow -Wstrict-prototypes"
1848         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1849
1850         # If -Wno-missing-field-initializers is supported we can enable a
1851         # a bunch of really useful warnings.
1852         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1853         _gcc_cflags_save=$CFLAGS
1854         CFLAGS="-Wno-missing-field-initializers"
1855         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1856         AC_MSG_RESULT($_gcc_wopt)
1857         CFLAGS=$_gcc_cflags_save;
1858         if test x"$_gcc_wopt" = xyes ; then
1859           CFLAGS="$CFLAGS -W -Wextra -Wbad-function-cast"
1860           CFLAGS="$CFLAGS -Wwrite-strings"
1861           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1862           CFLAGS="$CFLAGS -Wno-missing-field-initializers"
1863           CFLAGS="$CFLAGS -Wno-sign-compare"
1864         fi
1865
1866         AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1867         _gcc_cflags_save=$CFLAGS
1868         CFLAGS="-Wpointer-arith"
1869         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])],_gcc_wopt=yes,_gcc_wopt=no)
1870         AC_MSG_RESULT($_gcc_wopt)
1871         CFLAGS=$_gcc_cflags_save;
1872         if test x"$_gcc_wopt" = xyes ; then
1873           CFLAGS="$CFLAGS -Wpointer-arith"
1874         fi
1875     fi
1876
1877 fi
1878
1879 # Check whether as(1) supports a noeexecstack feature.  This test
1880 # includes an override option.
1881 CL_AS_NOEXECSTACK
1882
1883
1884 AC_SUBST(LIBGCRYPT_CONFIG_API_VERSION)
1885 AC_SUBST(LIBGCRYPT_CONFIG_LIBS)
1886 AC_SUBST(LIBGCRYPT_CONFIG_CFLAGS)
1887 AC_SUBST(LIBGCRYPT_CONFIG_HOST)
1888 AC_SUBST(LIBGCRYPT_THREAD_MODULES)
1889
1890 AC_CONFIG_COMMANDS([gcrypt-conf],[[
1891 chmod +x src/libgcrypt-config
1892 ]],[[
1893 prefix=$prefix
1894 exec_prefix=$exec_prefix
1895 libdir=$libdir
1896 datadir=$datadir
1897 DATADIRNAME=$DATADIRNAME
1898 ]])
1899
1900 #####################
1901 #### Conclusion. ####
1902 #####################
1903
1904 # Check that requested feature can actually be used and define
1905 # ENABLE_foo_SUPPORT macros.
1906
1907 if test x"$aesnisupport" = xyes ; then
1908   if test "$gcry_cv_gcc_inline_asm_ssse3" != "yes" ; then
1909     aesnisupport="no (unsupported by compiler)"
1910   fi
1911 fi
1912 if test x"$pclmulsupport" = xyes ; then
1913   if test "$gcry_cv_gcc_inline_asm_pclmul" != "yes" ; then
1914     pclmulsupport="no (unsupported by compiler)"
1915   fi
1916 fi
1917 if test x"$sse41support" = xyes ; then
1918   if test "$gcry_cv_gcc_inline_asm_sse41" != "yes" ; then
1919     sse41support="no (unsupported by compiler)"
1920   fi
1921 fi
1922 if test x"$avxsupport" = xyes ; then
1923   if test "$gcry_cv_gcc_inline_asm_avx" != "yes" ; then
1924     avxsupport="no (unsupported by compiler)"
1925   fi
1926 fi
1927 if test x"$avx2support" = xyes ; then
1928   if test "$gcry_cv_gcc_inline_asm_avx2" != "yes" ; then
1929     avx2support="no (unsupported by compiler)"
1930   fi
1931 fi
1932 if test x"$neonsupport" = xyes ; then
1933   if test "$gcry_cv_gcc_inline_asm_neon" != "yes" ; then
1934     if test "$gcry_cv_gcc_inline_asm_aarch64_neon" != "yes" ; then
1935       neonsupport="no (unsupported by compiler)"
1936     fi
1937   fi
1938 fi
1939 if test x"$armcryptosupport" = xyes ; then
1940   if test "$gcry_cv_gcc_inline_asm_aarch32_crypto" != "yes" ; then
1941     if test "$gcry_cv_gcc_inline_asm_aarch64_crypto" != "yes" ; then
1942       neonsupport="no (unsupported by compiler)"
1943     fi
1944   fi
1945 fi
1946
1947 if test x"$aesnisupport" = xyes ; then
1948   AC_DEFINE(ENABLE_AESNI_SUPPORT, 1,
1949             [Enable support for Intel AES-NI instructions.])
1950 fi
1951 if test x"$pclmulsupport" = xyes ; then
1952   AC_DEFINE(ENABLE_PCLMUL_SUPPORT, 1,
1953             [Enable support for Intel PCLMUL instructions.])
1954 fi
1955 if test x"$sse41support" = xyes ; then
1956   AC_DEFINE(ENABLE_SSE41_SUPPORT, 1,
1957             [Enable support for Intel SSE4.1 instructions.])
1958 fi
1959 if test x"$avxsupport" = xyes ; then
1960   AC_DEFINE(ENABLE_AVX_SUPPORT,1,
1961             [Enable support for Intel AVX instructions.])
1962 fi
1963 if test x"$avx2support" = xyes ; then
1964   AC_DEFINE(ENABLE_AVX2_SUPPORT,1,
1965             [Enable support for Intel AVX2 instructions.])
1966 fi
1967 if test x"$neonsupport" = xyes ; then
1968   AC_DEFINE(ENABLE_NEON_SUPPORT,1,
1969             [Enable support for ARM NEON instructions.])
1970 fi
1971 if test x"$armcryptosupport" = xyes ; then
1972   AC_DEFINE(ENABLE_ARM_CRYPTO_SUPPORT,1,
1973             [Enable support for ARMv8 Crypto Extension instructions.])
1974 fi
1975 if test x"$padlocksupport" = xyes ; then
1976   AC_DEFINE(ENABLE_PADLOCK_SUPPORT, 1,
1977             [Enable support for the PadLock engine.])
1978 fi
1979 if test x"$drngsupport" = xyes ; then
1980   AC_DEFINE(ENABLE_DRNG_SUPPORT, 1,
1981             [Enable support for Intel DRNG (RDRAND instruction).])
1982 fi
1983
1984
1985 # Define conditional sources and config.h symbols depending on the
1986 # selected ciphers, pubkey-ciphers, digests, kdfs, and random modules.
1987
1988 LIST_MEMBER(arcfour, $enabled_ciphers)
1989 if test "$found" = "1"; then
1990    GCRYPT_CIPHERS="$GCRYPT_CIPHERS arcfour.lo"
1991    AC_DEFINE(USE_ARCFOUR, 1, [Defined if this module should be included])
1992
1993    case "${host}" in
1994       x86_64-*-*)
1995          # Build with the assembly implementation
1996          GCRYPT_CIPHERS="$GCRYPT_CIPHERS arcfour-amd64.lo"
1997       ;;
1998    esac
1999 fi
2000
2001 LIST_MEMBER(blowfish, $enabled_ciphers)
2002 if test "$found" = "1" ; then
2003    GCRYPT_CIPHERS="$GCRYPT_CIPHERS blowfish.lo"
2004    AC_DEFINE(USE_BLOWFISH, 1, [Defined if this module should be included])
2005
2006    case "${host}" in
2007       x86_64-*-*)
2008          # Build with the assembly implementation
2009          GCRYPT_CIPHERS="$GCRYPT_CIPHERS blowfish-amd64.lo"
2010       ;;
2011       arm*-*-*)
2012          # Build with the assembly implementation
2013          GCRYPT_CIPHERS="$GCRYPT_CIPHERS blowfish-arm.lo"
2014       ;;
2015    esac
2016 fi
2017
2018 LIST_MEMBER(cast5, $enabled_ciphers)
2019 if test "$found" = "1" ; then
2020    GCRYPT_CIPHERS="$GCRYPT_CIPHERS cast5.lo"
2021    AC_DEFINE(USE_CAST5, 1, [Defined if this module should be included])
2022
2023    case "${host}" in
2024       x86_64-*-*)
2025          # Build with the assembly implementation
2026          GCRYPT_CIPHERS="$GCRYPT_CIPHERS cast5-amd64.lo"
2027       ;;
2028       arm*-*-*)
2029          # Build with the assembly implementation
2030          GCRYPT_CIPHERS="$GCRYPT_CIPHERS cast5-arm.lo"
2031       ;;
2032    esac
2033 fi
2034
2035 LIST_MEMBER(des, $enabled_ciphers)
2036 if test "$found" = "1" ; then
2037    GCRYPT_CIPHERS="$GCRYPT_CIPHERS des.lo"
2038    AC_DEFINE(USE_DES, 1, [Defined if this module should be included])
2039
2040    case "${host}" in
2041       x86_64-*-*)
2042          # Build with the assembly implementation
2043          GCRYPT_CIPHERS="$GCRYPT_CIPHERS des-amd64.lo"
2044       ;;
2045    esac
2046 fi
2047
2048 LIST_MEMBER(aes, $enabled_ciphers)
2049 if test "$found" = "1" ; then
2050    GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael.lo"
2051    AC_DEFINE(USE_AES, 1, [Defined if this module should be included])
2052
2053    case "${host}" in
2054       x86_64-*-*)
2055          # Build with the assembly implementation
2056          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-amd64.lo"
2057
2058          # Build with the SSSE3 implementation
2059          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-ssse3-amd64.lo"
2060          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-ssse3-amd64-asm.lo"
2061       ;;
2062       arm*-*-*)
2063          # Build with the assembly implementation
2064          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-arm.lo"
2065
2066          # Build with the ARMv8/AArch32 CE implementation
2067          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-armv8-ce.lo"
2068          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-armv8-aarch32-ce.lo"
2069       ;;
2070       aarch64-*-*)
2071          # Build with the assembly implementation
2072          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-aarch64.lo"
2073
2074          # Build with the ARMv8/AArch64 CE implementation
2075          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-armv8-ce.lo"
2076          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-armv8-aarch64-ce.lo"
2077       ;;
2078    esac
2079
2080    case "$mpi_cpu_arch" in
2081      x86)
2082          # Build with the AES-NI implementation
2083          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-aesni.lo"
2084
2085          # Build with the Padlock implementation
2086          GCRYPT_CIPHERS="$GCRYPT_CIPHERS rijndael-padlock.lo"
2087       ;;
2088    esac
2089 fi
2090
2091 LIST_MEMBER(twofish, $enabled_ciphers)
2092 if test "$found" = "1" ; then
2093    GCRYPT_CIPHERS="$GCRYPT_CIPHERS twofish.lo"
2094    AC_DEFINE(USE_TWOFISH, 1, [Defined if this module should be included])
2095
2096    case "${host}" in
2097       x86_64-*-*)
2098          # Build with the assembly implementation
2099          GCRYPT_CIPHERS="$GCRYPT_CIPHERS twofish-amd64.lo"
2100
2101          if test x"$avx2support" = xyes ; then
2102             # Build with the AVX2 implementation
2103             GCRYPT_CIPHERS="$GCRYPT_CIPHERS twofish-avx2-amd64.lo"
2104          fi
2105       ;;
2106       arm*-*-*)
2107          # Build with the assembly implementation
2108          GCRYPT_CIPHERS="$GCRYPT_CIPHERS twofish-arm.lo"
2109       ;;
2110       aarch64-*-*)
2111          # Build with the assembly implementation
2112          GCRYPT_CIPHERS="$GCRYPT_CIPHERS twofish-aarch64.lo"
2113       ;;
2114    esac
2115 fi
2116
2117 LIST_MEMBER(serpent, $enabled_ciphers)
2118 if test "$found" = "1" ; then
2119    GCRYPT_CIPHERS="$GCRYPT_CIPHERS serpent.lo"
2120    AC_DEFINE(USE_SERPENT, 1, [Defined if this module should be included])
2121
2122    case "${host}" in
2123       x86_64-*-*)
2124          # Build with the SSE2 implementation
2125          GCRYPT_CIPHERS="$GCRYPT_CIPHERS serpent-sse2-amd64.lo"
2126       ;;
2127    esac
2128
2129    if test x"$avx2support" = xyes ; then
2130       # Build with the AVX2 implementation
2131       GCRYPT_CIPHERS="$GCRYPT_CIPHERS serpent-avx2-amd64.lo"
2132    fi
2133
2134    if test x"$neonsupport" = xyes ; then
2135       # Build with the NEON implementation
2136       GCRYPT_CIPHERS="$GCRYPT_CIPHERS serpent-armv7-neon.lo"
2137    fi
2138 fi
2139
2140 LIST_MEMBER(rfc2268, $enabled_ciphers)
2141 if test "$found" = "1" ; then
2142    GCRYPT_CIPHERS="$GCRYPT_CIPHERS rfc2268.lo"
2143    AC_DEFINE(USE_RFC2268, 1, [Defined if this module should be included])
2144 fi
2145
2146 LIST_MEMBER(seed, $enabled_ciphers)
2147 if test "$found" = "1" ; then
2148    GCRYPT_CIPHERS="$GCRYPT_CIPHERS seed.lo"
2149    AC_DEFINE(USE_SEED, 1, [Defined if this module should be included])
2150 fi
2151
2152 LIST_MEMBER(camellia, $enabled_ciphers)
2153 if test "$found" = "1" ; then
2154    GCRYPT_CIPHERS="$GCRYPT_CIPHERS camellia.lo camellia-glue.lo"
2155    AC_DEFINE(USE_CAMELLIA, 1, [Defined if this module should be included])
2156
2157    case "${host}" in
2158       arm*-*-*)
2159          # Build with the assembly implementation
2160          GCRYPT_CIPHERS="$GCRYPT_CIPHERS camellia-arm.lo"
2161       ;;
2162       aarch64-*-*)
2163          # Build with the assembly implementation
2164          GCRYPT_CIPHERS="$GCRYPT_CIPHERS camellia-aarch64.lo"
2165       ;;
2166    esac
2167
2168    if test x"$avxsupport" = xyes ; then
2169       if test x"$aesnisupport" = xyes ; then
2170         # Build with the AES-NI/AVX implementation
2171         GCRYPT_CIPHERS="$GCRYPT_CIPHERS camellia-aesni-avx-amd64.lo"
2172       fi
2173    fi
2174
2175    if test x"$avx2support" = xyes ; then
2176       if test x"$aesnisupport" = xyes ; then
2177         # Build with the AES-NI/AVX2 implementation
2178         GCRYPT_CIPHERS="$GCRYPT_CIPHERS camellia-aesni-avx2-amd64.lo"
2179       fi
2180    fi
2181 fi
2182
2183 LIST_MEMBER(idea, $enabled_ciphers)
2184 if test "$found" = "1" ; then
2185    GCRYPT_CIPHERS="$GCRYPT_CIPHERS idea.lo"
2186    AC_DEFINE(USE_IDEA, 1, [Defined if this module should be included])
2187 fi
2188
2189 LIST_MEMBER(salsa20, $enabled_ciphers)
2190 if test "$found" = "1" ; then
2191    GCRYPT_CIPHERS="$GCRYPT_CIPHERS salsa20.lo"
2192    AC_DEFINE(USE_SALSA20, 1, [Defined if this module should be included])
2193
2194    case "${host}" in
2195       x86_64-*-*)
2196          # Build with the assembly implementation
2197          GCRYPT_CIPHERS="$GCRYPT_CIPHERS salsa20-amd64.lo"
2198       ;;
2199    esac
2200
2201    if test x"$neonsupport" = xyes ; then
2202      # Build with the NEON implementation
2203      GCRYPT_CIPHERS="$GCRYPT_CIPHERS salsa20-armv7-neon.lo"
2204    fi
2205 fi
2206
2207 LIST_MEMBER(gost28147, $enabled_ciphers)
2208 if test "$found" = "1" ; then
2209    GCRYPT_CIPHERS="$GCRYPT_CIPHERS gost28147.lo"
2210    AC_DEFINE(USE_GOST28147, 1, [Defined if this module should be included])
2211 fi
2212
2213 LIST_MEMBER(chacha20, $enabled_ciphers)
2214 if test "$found" = "1" ; then
2215    GCRYPT_CIPHERS="$GCRYPT_CIPHERS chacha20.lo"
2216    AC_DEFINE(USE_CHACHA20, 1, [Defined if this module should be included])
2217
2218    case "${host}" in
2219       x86_64-*-*)
2220          # Build with the assembly implementation
2221          GCRYPT_CIPHERS="$GCRYPT_CIPHERS chacha20-sse2-amd64.lo"
2222          GCRYPT_CIPHERS="$GCRYPT_CIPHERS chacha20-ssse3-amd64.lo"
2223          GCRYPT_CIPHERS="$GCRYPT_CIPHERS chacha20-avx2-amd64.lo"
2224       ;;
2225    esac
2226
2227    if test x"$neonsupport" = xyes ; then
2228      # Build with the NEON implementation
2229      GCRYPT_CIPHERS="$GCRYPT_CIPHERS chacha20-armv7-neon.lo"
2230    fi
2231 fi
2232
2233 case "${host}" in
2234    x86_64-*-*)
2235       # Build with the assembly implementation
2236       GCRYPT_CIPHERS="$GCRYPT_CIPHERS poly1305-sse2-amd64.lo"
2237       GCRYPT_CIPHERS="$GCRYPT_CIPHERS poly1305-avx2-amd64.lo"
2238    ;;
2239 esac
2240
2241 if test x"$neonsupport" = xyes ; then
2242    # Build with the NEON implementation
2243    GCRYPT_CIPHERS="$GCRYPT_CIPHERS poly1305-armv7-neon.lo"
2244 fi
2245
2246 LIST_MEMBER(dsa, $enabled_pubkey_ciphers)
2247 if test "$found" = "1" ; then
2248    GCRYPT_PUBKEY_CIPHERS="$GCRYPT_PUBKEY_CIPHERS dsa.lo"
2249    AC_DEFINE(USE_DSA, 1, [Defined if this module should be included])
2250 fi
2251
2252 LIST_MEMBER(rsa, $enabled_pubkey_ciphers)
2253 if test "$found" = "1" ; then
2254    GCRYPT_PUBKEY_CIPHERS="$GCRYPT_PUBKEY_CIPHERS rsa.lo"
2255    AC_DEFINE(USE_RSA, 1, [Defined if this module should be included])
2256 fi
2257
2258 LIST_MEMBER(elgamal, $enabled_pubkey_ciphers)
2259 if test "$found" = "1" ; then
2260    GCRYPT_PUBKEY_CIPHERS="$GCRYPT_PUBKEY_CIPHERS elgamal.lo"
2261    AC_DEFINE(USE_ELGAMAL, 1, [Defined if this module should be included])
2262 fi
2263
2264 LIST_MEMBER(ecc, $enabled_pubkey_ciphers)
2265 if test "$found" = "1" ; then
2266    GCRYPT_PUBKEY_CIPHERS="$GCRYPT_PUBKEY_CIPHERS \
2267                           ecc.lo ecc-curves.lo ecc-misc.lo \
2268                           ecc-ecdsa.lo ecc-eddsa.lo ecc-gost.lo"
2269    AC_DEFINE(USE_ECC, 1, [Defined if this module should be included])
2270 fi
2271
2272 LIST_MEMBER(crc, $enabled_digests)
2273 if test "$found" = "1" ; then
2274    GCRYPT_DIGESTS="$GCRYPT_DIGESTS crc.lo"
2275    AC_DEFINE(USE_CRC, 1, [Defined if this module should be included])
2276
2277    case "${host}" in
2278       i?86-*-* | x86_64-*-*)
2279          # Build with the assembly implementation
2280          GCRYPT_DIGESTS="$GCRYPT_DIGESTS crc-intel-pclmul.lo"
2281       ;;
2282    esac
2283 fi
2284
2285 LIST_MEMBER(gostr3411-94, $enabled_digests)
2286 if test "$found" = "1" ; then
2287    # GOST R 34.11-94 internally uses GOST 28147-89
2288    LIST_MEMBER(gost28147, $enabled_ciphers)
2289    if test "$found" = "1" ; then
2290       GCRYPT_DIGESTS="$GCRYPT_DIGESTS gostr3411-94.lo"
2291       AC_DEFINE(USE_GOST_R_3411_94, 1, [Defined if this module should be included])
2292    fi
2293 fi
2294
2295 LIST_MEMBER(stribog, $enabled_digests)
2296 if test "$found" = "1" ; then
2297    GCRYPT_DIGESTS="$GCRYPT_DIGESTS stribog.lo"
2298    AC_DEFINE(USE_GOST_R_3411_12, 1, [Defined if this module should be included])
2299 fi
2300
2301 LIST_MEMBER(md2, $enabled_digests)
2302 if test "$found" = "1" ; then
2303    GCRYPT_DIGESTS="$GCRYPT_DIGESTS md2.lo"
2304    AC_DEFINE(USE_MD2, 1, [Defined if this module should be included])
2305 fi
2306
2307 LIST_MEMBER(md4, $enabled_digests)
2308 if test "$found" = "1" ; then
2309    GCRYPT_DIGESTS="$GCRYPT_DIGESTS md4.lo"
2310    AC_DEFINE(USE_MD4, 1, [Defined if this module should be included])
2311 fi
2312
2313 LIST_MEMBER(md5, $enabled_digests)
2314 if test "$found" = "1" ; then
2315    GCRYPT_DIGESTS="$GCRYPT_DIGESTS md5.lo"
2316    AC_DEFINE(USE_MD5, 1, [Defined if this module should be included])
2317 fi
2318
2319 LIST_MEMBER(rmd160, $enabled_digests)
2320 if test "$found" = "1" ; then
2321    GCRYPT_DIGESTS="$GCRYPT_DIGESTS rmd160.lo"
2322    AC_DEFINE(USE_RMD160, 1, [Defined if this module should be included])
2323 fi
2324
2325 LIST_MEMBER(sha256, $enabled_digests)
2326 if test "$found" = "1" ; then
2327    GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha256.lo"
2328    AC_DEFINE(USE_SHA256, 1, [Defined if this module should be included])
2329
2330    case "${host}" in
2331       x86_64-*-*)
2332          # Build with the assembly implementation
2333          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha256-ssse3-amd64.lo"
2334          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha256-avx-amd64.lo"
2335          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha256-avx2-bmi2-amd64.lo"
2336       ;;
2337       arm*-*-*)
2338          # Build with the assembly implementation
2339          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha256-armv8-aarch32-ce.lo"
2340       ;;
2341       aarch64-*-*)
2342          # Build with the assembly implementation
2343          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha256-armv8-aarch64-ce.lo"
2344       ;;
2345    esac
2346 fi
2347
2348 LIST_MEMBER(sha512, $enabled_digests)
2349 if test "$found" = "1" ; then
2350    GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha512.lo"
2351    AC_DEFINE(USE_SHA512, 1, [Defined if this module should be included])
2352
2353    case "${host}" in
2354       x86_64-*-*)
2355          # Build with the assembly implementation
2356          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha512-ssse3-amd64.lo"
2357          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha512-avx-amd64.lo"
2358          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha512-avx2-bmi2-amd64.lo"
2359       ;;
2360       arm*-*-*)
2361          # Build with the assembly implementation
2362          GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha512-arm.lo"
2363       ;;
2364    esac
2365
2366    if test x"$neonsupport" = xyes ; then
2367      # Build with the NEON implementation
2368      GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha512-armv7-neon.lo"
2369    fi
2370 fi
2371
2372 LIST_MEMBER(sha3, $enabled_digests)
2373 if test "$found" = "1" ; then
2374    GCRYPT_DIGESTS="$GCRYPT_DIGESTS keccak.lo"
2375    AC_DEFINE(USE_SHA3, 1, [Defined if this module should be included])
2376
2377    case "${host}" in
2378       x86_64-*-*)
2379          # Build with the assembly implementation
2380          :
2381       ;;
2382    esac
2383
2384    if test x"$neonsupport" = xyes ; then
2385      # Build with the NEON implementation
2386      GCRYPT_DIGESTS="$GCRYPT_DIGESTS keccak-armv7-neon.lo"
2387    fi
2388 fi
2389
2390 LIST_MEMBER(tiger, $enabled_digests)
2391 if test "$found" = "1" ; then
2392    GCRYPT_DIGESTS="$GCRYPT_DIGESTS tiger.lo"
2393    AC_DEFINE(USE_TIGER, 1, [Defined if this module should be included])
2394 fi
2395
2396 LIST_MEMBER(whirlpool, $enabled_digests)
2397 if test "$found" = "1" ; then
2398    GCRYPT_DIGESTS="$GCRYPT_DIGESTS whirlpool.lo"
2399    AC_DEFINE(USE_WHIRLPOOL, 1, [Defined if this module should be included])
2400
2401    case "${host}" in
2402       x86_64-*-*)
2403          # Build with the assembly implementation
2404          GCRYPT_DIGESTS="$GCRYPT_DIGESTS whirlpool-sse2-amd64.lo"
2405       ;;
2406    esac
2407 fi
2408
2409 # SHA-1 needs to be included always for example because it is used by
2410 # random-csprng.c.
2411 GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1.lo"
2412 AC_DEFINE(USE_SHA1, 1,   [Defined if this module should be included])
2413
2414 case "${host}" in
2415   x86_64-*-*)
2416     # Build with the assembly implementation
2417     GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1-ssse3-amd64.lo"
2418     GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1-avx-amd64.lo"
2419     GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1-avx-bmi2-amd64.lo"
2420   ;;
2421   arm*-*-*)
2422     # Build with the assembly implementation
2423     GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1-armv7-neon.lo"
2424     GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1-armv8-aarch32-ce.lo"
2425   ;;
2426   aarch64-*-*)
2427     # Build with the assembly implementation
2428     GCRYPT_DIGESTS="$GCRYPT_DIGESTS sha1-armv8-aarch64-ce.lo"
2429   ;;
2430 esac
2431
2432 LIST_MEMBER(scrypt, $enabled_kdfs)
2433 if test "$found" = "1" ; then
2434    GCRYPT_KDFS="$GCRYPT_KDFS scrypt.lo"
2435    AC_DEFINE(USE_SCRYPT, 1, [Defined if this module should be included])
2436 fi
2437
2438 LIST_MEMBER(linux, $random_modules)
2439 if test "$found" = "1" ; then
2440    GCRYPT_RANDOM="$GCRYPT_RANDOM rndlinux.lo"
2441    AC_DEFINE(USE_RNDLINUX, 1, [Defined if the /dev/random RNG should be used.])
2442 fi
2443
2444 LIST_MEMBER(unix, $random_modules)
2445 if test "$found" = "1" ; then
2446    GCRYPT_RANDOM="$GCRYPT_RANDOM rndunix.lo"
2447    AC_DEFINE(USE_RNDUNIX, 1, [Defined if the default Unix RNG should be used.])
2448    print_egd_notice=yes
2449 fi
2450
2451 LIST_MEMBER(egd, $random_modules)
2452 if test "$found" = "1" ; then
2453    GCRYPT_RANDOM="$GCRYPT_RANDOM rndegd.lo"
2454    AC_DEFINE(USE_RNDEGD, 1, [Defined if the EGD based RNG should be used.])
2455 fi
2456
2457 LIST_MEMBER(w32, $random_modules)
2458 if test "$found" = "1" ; then
2459    GCRYPT_RANDOM="$GCRYPT_RANDOM rndw32.lo"
2460    AC_DEFINE(USE_RNDW32, 1,
2461              [Defined if the Windows specific RNG should be used.])
2462 fi
2463
2464 LIST_MEMBER(w32ce, $random_modules)
2465 if test "$found" = "1" ; then
2466    GCRYPT_RANDOM="$GCRYPT_RANDOM rndw32ce.lo"
2467    AC_DEFINE(USE_RNDW32CE, 1,
2468              [Defined if the WindowsCE specific RNG should be used.])
2469 fi
2470
2471 AC_SUBST([GCRYPT_CIPHERS])
2472 AC_SUBST([GCRYPT_PUBKEY_CIPHERS])
2473 AC_SUBST([GCRYPT_DIGESTS])
2474 AC_SUBST([GCRYPT_KDFS])
2475 AC_SUBST([GCRYPT_RANDOM])
2476
2477 AC_SUBST(LIBGCRYPT_CIPHERS, $enabled_ciphers)
2478 AC_SUBST(LIBGCRYPT_PUBKEY_CIPHERS, $enabled_pubkey_ciphers)
2479 AC_SUBST(LIBGCRYPT_DIGESTS, $enabled_digests)
2480
2481 # For printing the configuration we need a colon separated list of
2482 # algorithm names.
2483 tmp=`echo "$enabled_ciphers" | tr ' ' : `
2484 AC_DEFINE_UNQUOTED(LIBGCRYPT_CIPHERS, "$tmp",
2485                    [List of available cipher algorithms])
2486 tmp=`echo "$enabled_pubkey_ciphers" | tr ' ' : `
2487 AC_DEFINE_UNQUOTED(LIBGCRYPT_PUBKEY_CIPHERS, "$tmp",
2488                    [List of available public key cipher algorithms])
2489 tmp=`echo "$enabled_digests" | tr ' ' : `
2490 AC_DEFINE_UNQUOTED(LIBGCRYPT_DIGESTS, "$tmp",
2491                    [List of available digest algorithms])
2492 tmp=`echo "$enabled_kdfs" | tr ' ' : `
2493 AC_DEFINE_UNQUOTED(LIBGCRYPT_KDFS, "$tmp",
2494                    [List of available KDF algorithms])
2495
2496
2497 #
2498 # Define conditional sources depending on the used hardware platform.
2499 # Note that all possible modules must also be listed in
2500 # src/Makefile.am (EXTRA_libgcrypt_la_SOURCES).
2501 #
2502 GCRYPT_HWF_MODULES=
2503 case "$mpi_cpu_arch" in
2504      x86)
2505         AC_DEFINE(HAVE_CPU_ARCH_X86, 1,   [Defined for the x86 platforms])
2506         GCRYPT_HWF_MODULES="hwf-x86.lo"
2507         ;;
2508      alpha)
2509         AC_DEFINE(HAVE_CPU_ARCH_ALPHA, 1, [Defined for Alpha platforms])
2510         ;;
2511      sparc)
2512         AC_DEFINE(HAVE_CPU_ARCH_SPARC, 1, [Defined for SPARC platforms])
2513         ;;
2514      mips)
2515         AC_DEFINE(HAVE_CPU_ARCH_MIPS, 1,  [Defined for MIPS platforms])
2516         ;;
2517      m68k)
2518         AC_DEFINE(HAVE_CPU_ARCH_M68K, 1,  [Defined for M68k platforms])
2519         ;;
2520      ppc)
2521         AC_DEFINE(HAVE_CPU_ARCH_PPC, 1,   [Defined for PPC platforms])
2522         ;;
2523      arm)
2524         AC_DEFINE(HAVE_CPU_ARCH_ARM, 1,   [Defined for ARM platforms])
2525         GCRYPT_HWF_MODULES="hwf-arm.lo"
2526         ;;
2527      aarch64)
2528         AC_DEFINE(HAVE_CPU_ARCH_ARM, 1,   [Defined for ARM AArch64 platforms])
2529         GCRYPT_HWF_MODULES="hwf-arm.lo"
2530         ;;
2531 esac
2532 AC_SUBST([GCRYPT_HWF_MODULES])
2533
2534
2535 #
2536 # Option to disable building of doc file
2537 #
2538 build_doc=yes
2539 AC_ARG_ENABLE([doc], AC_HELP_STRING([--disable-doc],
2540                                     [do not build the documentation]),
2541                      build_doc=$enableval, build_doc=yes)
2542 AM_CONDITIONAL([BUILD_DOC], [test "x$build_doc" != xno])
2543
2544
2545 #
2546 # Provide information about the build.
2547 #
2548 BUILD_REVISION="mym4_revision"
2549 AC_SUBST(BUILD_REVISION)
2550 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
2551                    [GIT commit id revision used to build this package])
2552
2553 changequote(,)dnl
2554 BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
2555 changequote([,])dnl
2556 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
2557 AC_SUBST(BUILD_FILEVERSION)
2558
2559 AC_ARG_ENABLE([build-timestamp],
2560   AC_HELP_STRING([--enable-build-timestamp],
2561                  [set an explicit build timestamp for reproducibility.
2562                   (default is the current time in ISO-8601 format)]),
2563      [if test "$enableval" = "yes"; then
2564         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
2565       else
2566         BUILD_TIMESTAMP="$enableval"
2567       fi],
2568      [BUILD_TIMESTAMP="<none>"])
2569 AC_SUBST(BUILD_TIMESTAMP)
2570 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
2571                    [The time this package was configured for a build])
2572
2573
2574 # And create the files.
2575 AC_CONFIG_FILES([
2576 Makefile
2577 m4/Makefile
2578 compat/Makefile
2579 mpi/Makefile
2580 cipher/Makefile
2581 random/Makefile
2582 doc/Makefile
2583 src/Makefile
2584 src/gcrypt.h
2585 src/libgcrypt-config
2586 src/versioninfo.rc
2587 tests/Makefile
2588 ])
2589 AC_CONFIG_FILES([tests/hashtest-256g], [chmod +x tests/hashtest-256g])
2590 AC_CONFIG_FILES([tests/basic-disable-all-hwf], [chmod +x tests/basic-disable-all-hwf])
2591 AC_OUTPUT
2592
2593
2594 detection_module="${GCRYPT_HWF_MODULES%.lo}"
2595 test -n "$detection_module" || detection_module="none"
2596
2597 # Give some feedback
2598 GCRY_MSG_SHOW([],[])
2599 GCRY_MSG_SHOW([Libgcrypt],[v${VERSION} has been configured as follows:])
2600 GCRY_MSG_SHOW([],[])
2601 GCRY_MSG_SHOW([Platform:                 ],[$PRINTABLE_OS_NAME ($host)])
2602 GCRY_MSG_SHOW([Hardware detection module:],[$detection_module])
2603 GCRY_MSG_WRAP([Enabled cipher algorithms:],[$enabled_ciphers])
2604 GCRY_MSG_WRAP([Enabled digest algorithms:],[$enabled_digests])
2605 GCRY_MSG_WRAP([Enabled kdf algorithms:   ],[$enabled_kdfs])
2606 GCRY_MSG_WRAP([Enabled pubkey algorithms:],[$enabled_pubkey_ciphers])
2607 GCRY_MSG_SHOW([Random number generator:  ],[$random])
2608 GCRY_MSG_SHOW([Using linux capabilities: ],[$use_capabilities])
2609 GCRY_MSG_SHOW([Try using Padlock crypto: ],[$padlocksupport])
2610 GCRY_MSG_SHOW([Try using AES-NI crypto:  ],[$aesnisupport])
2611 GCRY_MSG_SHOW([Try using Intel PCLMUL:   ],[$pclmulsupport])
2612 GCRY_MSG_SHOW([Try using Intel SSE4.1:   ],[$sse41support])
2613 GCRY_MSG_SHOW([Try using DRNG (RDRAND):  ],[$drngsupport])
2614 GCRY_MSG_SHOW([Try using Intel AVX:      ],[$avxsupport])
2615 GCRY_MSG_SHOW([Try using Intel AVX2:     ],[$avx2support])
2616 GCRY_MSG_SHOW([Try using ARM NEON:       ],[$neonsupport])
2617 GCRY_MSG_SHOW([Try using ARMv8 crypto:   ],[$armcryptosupport])
2618 GCRY_MSG_SHOW([],[])
2619
2620 if test "x${gpg_config_script_warn}" != x; then
2621 cat <<G10EOF
2622         Mismatches between the target platform and the to
2623         be used libraries have been been detected for:
2624          ${gpg_config_script_warn}
2625         Please check above for warning messages.
2626
2627 G10EOF
2628 fi
2629 if test "$print_egd_notice" = "yes"; then
2630 cat <<G10EOF
2631    The performance of the Unix random gatherer module (rndunix) is not
2632    very good and it does not keep the entropy pool over multiple
2633    invocations of Libgcrypt base applications.  The suggested way to
2634    overcome this problem is to use the
2635
2636                  Entropy Gathering Daemon (EGD)
2637
2638    which provides a entropy source for the whole system.  It is written
2639    in Perl and available at the GnuPG FTP servers.  For more information
2640    consult the GnuPG site:
2641
2642           https://gnupg.org/related_software/swlist.html#egd
2643
2644 G10EOF
2645 fi
2646
2647 if test "$gcry_cv_gcc_attribute_aligned" != "yes" ; then
2648 cat <<G10EOF
2649    Please not that your compiler does not support the GCC style
2650    aligned attribute. Using this software may evoke bus errors.
2651
2652 G10EOF
2653 fi
2654
2655 if test -n "$gpl"; then
2656   echo "Please note that you are building a version of Libgcrypt with"
2657   echo "  $gpl"
2658   echo "included.  These parts are licensed under the GPL and thus the"
2659   echo "use of this library has to comply with the conditions of the GPL."
2660   echo ""
2661 fi