* jnlib/: Removed.
[libgcrypt.git] / configure.ac
1 dnl Configure.ac script for Libgcrypt
2 dnl Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
3 dnl
4 dnl This file is part of Libgcrypt.
5 dnl
6 dnl Libgcrypt is free software; you can redistribute it and/or modify
7 dnl it under the terms of the GNU General Public License as published by
8 dnl the Free Software Foundation; either version 2 of the License, or
9 dnl (at your option) any later version.
10 dnl 
11 dnl Libgcrypt is distributed in the hope that it will be useful,
12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 dnl GNU General Public License for more details.
15 dnl 
16 dnl You should have received a copy of the GNU General Public License
17 dnl along with this program; if not, write to the Free Software
18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19 dnl
20 dnl (Process this file with autoconf to produce a configure script.)
21 AC_REVISION($Revision$)dnl
22
23 AC_PREREQ(2.52)
24 # Version numbers (Remember to change them just before a release)
25 #   (Interfaces removed:    CURRENT++, AGE=0, REVISION=0)
26 #   (Interfaces added:      CURRENT++, AGE++, REVISION=0)
27 #   (No interfaces changed:                   REVISION++)
28 AC_INIT(libgcrypt,1.1.7-cvs)
29 LIBGCRYPT_LT_CURRENT=3
30 LIBGCRYPT_LT_AGE=2
31 LIBGCRYPT_LT_REVISION=1
32 #-----------------------
33
34 PACKAGE=$PACKAGE_NAME
35 VERSION=$PACKAGE_VERSION
36
37 AC_CONFIG_SRCDIR([src/gcrypt.h])
38 AC_CONFIG_AUX_DIR(scripts)
39 AC_CANONICAL_TARGET()
40 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
41 AM_CONFIG_HEADER(config.h)
42
43 AH_TOP([
44 /* need this, because some autoconf tests rely on this (e.g. stpcpy)
45  * and it should be used for new programs  */
46 #define _GNU_SOURCE  1
47 ])
48
49
50 AH_BOTTOM([
51 #include "gcrypt-defs.h"
52 #define _GCRYPT_IN_LIBGCRYPT 1
53 ])
54
55 AH_VERBATIM([_REENTRANT],
56 [/* To allow the use of Libgcrypt in multithreaded programs we have to use
57     special features from the library. */
58 #ifndef _REENTRANT
59 # define _REENTRANT 1
60 #endif])
61
62
63
64 AC_SUBST(LIBGCRYPT_LT_CURRENT)
65 AC_SUBST(LIBGCRYPT_LT_AGE)
66 AC_SUBST(LIBGCRYPT_LT_REVISION)
67 AC_SUBST(PACKAGE)
68 AC_SUBST(VERSION)
69 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
70 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
71
72 static_modules="sha1 md5 rmd160"
73 static_random_module=""
74
75 AC_PROG_AWK
76
77 MODULES_IN_CIPHER=`$AWK '/^EXTRA_PROGRAMS/ { for(i=3;i<=NF;i++) print $i}' \
78                                               $srcdir/cipher/Makefile.am`
79
80 dnl
81 dnl  Check for random module options
82 dnl
83 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
84 dnl         and check against this list
85
86 AC_MSG_CHECKING([which static random module to use])
87 AC_ARG_ENABLE(static-rnd,
88     [  --enable-static-rnd=[egd|unix|linux|none]  ],
89 [use_static_rnd=$enableval], [use_static_rnd=default] )
90
91 if test "$use_static_rnd" = no; then
92     use_static_rnd=default
93 fi
94
95 case "$use_static_rnd" in
96     egd | linux | unix | none | default )
97       AC_MSG_RESULT($use_static_rnd)
98       ;;
99     * )
100       AC_MSG_RESULT(invalid argument)
101       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
102       ;;
103 esac
104
105 AC_ARG_WITH(egd-socket,
106     [  --with-egd-socket=NAME  Use NAME for the EGD socket)],
107             egd_socket_name="$withval", egd_socket_name="" )
108 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
109                    [Define if you don't want the default EGD socket name.
110                     For details see cipher/rndegd.c])
111
112
113
114 dnl
115 dnl See whether the user wants to disable checking for /dev/random
116
117 AC_MSG_CHECKING([whether use of /dev/random is requested])
118 AC_ARG_ENABLE(dev-random,
119 [  --disable-dev-random    disable the use of dev random],
120     try_dev_random=$enableval, try_dev_random=yes)
121 AC_MSG_RESULT($try_dev_random)
122
123
124 dnl
125 dnl  Check other options
126 dnl
127
128 AC_MSG_CHECKING([whether use of extensions is requested])
129 AC_ARG_ENABLE(dynload,
130 [  --disable-dynload       disable use of extensions],
131     try_dynload=$enableval, try_dynload=yes)
132 AC_MSG_RESULT($try_dynload)
133
134 AC_MSG_CHECKING([whether assembler modules are requested])
135 AC_ARG_ENABLE(asm,
136 [  --disable-asm           do not use assembler modules],
137      try_asm_modules=$enableval, try_asm_modules=yes)
138 AC_MSG_RESULT($try_asm_modules)
139
140 AC_MSG_CHECKING([whether memory guard is requested])
141 AC_ARG_ENABLE(m-guard,
142     [  --enable-m-guard        enable memory guard facility],
143     use_m_guard=$enableval, use_m_guard=no)
144     AC_MSG_RESULT($use_m_guard)
145 if test "$use_m_guard" = yes ; then
146     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
147 fi
148
149 dnl
150 dnl Check whether we want to use Linux capabilities
151 dnl
152 AC_MSG_CHECKING([whether use of capabilities is requested])
153 AC_ARG_WITH(capabilities,
154     [  --with-capabilities     use linux capabilities [default=no]],
155 [use_capabilities="$withval"],[use_capabilities=no])
156 AC_MSG_RESULT($use_capabilities)
157
158
159 AM_MAINTAINER_MODE
160
161 dnl Checks for programs.
162
163 dnl
164 dnl Setup some stuff depending on host/target.
165 dnl
166 case "${target}" in
167     *-*-mingw32*)
168         # special stuff for Windoze NT
169         disallowed_modules="rndunix rndlinux rndegd"
170         ;;
171     *)
172         disallowed_modules="rndw32"
173        ;;
174 esac
175
176 AC_PROG_MAKE_SET
177 AM_SANITY_CHECK
178 missing_dir=`cd $ac_aux_dir && pwd`
179 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
180 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
181 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
182 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
183 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
184 AC_PROG_CC
185 AC_PROG_CPP
186 AC_ISC_POSIX
187 AC_PROG_INSTALL
188 AC_PROG_AWK
189 GPH_PROG_DB2ANY
190
191 AM_PROG_LIBTOOL
192
193
194 MPI_OPT_FLAGS=""
195
196
197 try_gettext=no
198 case "${target}" in
199     *-*-mingw32*)
200         # special stuff for Windoze NT
201         ac_cv_have_dev_random=no
202         AC_DEFINE(USE_ONLY_8DOT3,1,
203                   [set this to limit filenames to the 8.3 format])
204         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
205                   [defined if we must run on a stupid file system])
206         AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
207                   [defined if we run on some of the PCDOS like systems 
208                    (DOS, Windoze. OS/2) with special properties like
209                     no file modes])
210         try_gettext="no"
211         ;;
212     i?86-emx-os2 | i?86-*-os2*emx )
213         # OS/2 with the EMX environment
214         ac_cv_have_dev_random=no
215         AC_DEFINE(HAVE_DRIVE_LETTERS)
216         AC_DEFINE(HAVE_DOSISH_SYSTEM)
217         try_gettext="no"
218         ;;
219
220     i?86-*-msdosdjgpp*)
221         # DOS with the DJGPP environment
222         ac_cv_have_dev_random=no
223         AC_DEFINE(HAVE_DRIVE_LETTERS)
224         AC_DEFINE(HAVE_DOSISH_SYSTEM)
225         try_gettext="no"
226         ;;
227
228     *-*-freebsd*)
229        # FreeBSD
230        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
231        LDFLAGS="$LDFLAGS -L/usr/local/lib"
232        ;;
233
234     *-*-hpux*)
235         if test -z "$GCC" ; then
236             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
237         fi
238         ;;
239     *-dec-osf4*)
240         if test -z "$GCC" ; then
241             # Suppress all warnings
242             # to get rid of the unsigned/signed char mismatch warnings.
243             CFLAGS="$CFLAGS -w"
244         fi
245         ;;
246     m68k-atari-mint)
247         ;;
248     *)
249        ;;
250 esac
251
252 AC_SUBST(MPI_OPT_FLAGS)
253 GNUPG_SYS_SYMBOL_UNDERSCORE
254 GNUPG_CHECK_PIC
255 GNUPG_CHECK_EXPORTDYNAMIC
256 if test "$NO_PIC" = yes; then
257     try_dynload=no
258 fi
259
260
261 case "${target}" in
262     *-*-mingw32*)
263         PRINTABLE_OS_NAME="MingW32"
264         ;;
265     i?86-emx-os2 | i?86-*-os2*emx )
266         PRINTABLE_OS_NAME="OS/2"
267         ;;
268     i?86-*-msdosdjgpp*)
269         PRINTABLE_OS_NAME="MSDOS/DJGPP"
270         try_dynload=no
271         ;;
272     *-linux*)
273         PRINTABLE_OS_NAME="GNU/Linux"
274         ;;
275 dnl let that after linux to avoid gnu-linux problems
276     *-gnu*)
277         PRINTABLE_OS_NAME="GNU/Hurd"
278         ;;
279     *)
280         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
281         ;;
282 esac
283 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
284                    [A human readable text with the name of the OS])
285
286 dnl  Fixme: Are these the best flags for OpenBSD????
287 case "${target}" in
288     *-openbsd* | *-netbsd*)
289         NAME_OF_DEV_RANDOM="/dev/srandom"
290         NAME_OF_DEV_URANDOM="/dev/urandom"
291         DYNLINK_MOD_CFLAGS="-shared -rdynamic $CFLAGS_PIC -Wl,-Bshareable -Wl,-x"
292         ;;
293
294     *-solaris* | *-irix* | *-dec-osf* )
295         NAME_OF_DEV_RANDOM="/dev/random"
296         NAME_OF_DEV_URANDOM="/dev/random"
297         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"
298         ;;
299
300     *)
301         NAME_OF_DEV_RANDOM="/dev/random"
302         NAME_OF_DEV_URANDOM="/dev/urandom"
303         # -shared is a gcc-ism.  Find pic flags from GNUPG_CHECK_PIC.
304         if test -n "$GCC" ; then
305            DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"                            
306         else
307            DYNLINK_MOD_CFLAGS="$CFLAGS_PIC"
308         fi
309         ;;
310 esac
311 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM",
312                    [defined to the name of the strong random device])
313 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM",
314                    [defined to the name of the weaker random device])
315 AC_SUBST(MPI_OPT_FLAGS)
316
317
318 dnl Checks for libraries.
319
320 USE_NLS=no
321 USE_INCLUDED_LIBINTL=no
322 AC_SUBST(USE_NLS)
323 AC_SUBST(USE_INCLUDED_LIBINTL)
324
325
326 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
327 dnl gethostbyname in libsocket but needs libnsl for socket.
328 AC_CHECK_LIB(nsl, gethostbyname)
329 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
330 if test x$ac_need_libsocket = x1; then
331     LIBS="$LIBS -lsocket"
332 fi
333 if test x$ac_try_nsl = x1; then
334     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
335     if test x$ac_need_libnsl = x1
336     then
337         LIBS="$LIBS -lnsl"
338     fi
339 fi
340
341
342 if test "$try_dynload" = yes ; then
343   AC_CHECK_LIB(dl,dlopen)
344   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
345     AC_DEFINE(USE_DYNAMIC_LINKING,1,
346               [define to enable the use of extensions])
347     AC_DEFINE(HAVE_DL_DLOPEN,1,
348               [Defined when the dlopen function family is available])
349     DYNLINK_LDFLAGS="$CFLAGS_EXPORTDYNAMIC"
350     use_gnupg_extensions=yes
351   else
352     AC_CHECK_FUNCS(dlopen)
353     if test "$ac_cv_func_dlopen" = "yes"; then
354       AC_DEFINE(USE_DYNAMIC_LINKING)
355       AC_DEFINE(HAVE_DL_DLOPEN)
356       DYNLINK_LDFLAGS="$CFLAGS_EXPORTDYNAMIC"
357       use_gnupg_extensions=yes
358     else
359       AC_CHECK_LIB(dld,shl_load)
360       if test "$ac_cv_lib_dld_shl_load" = "yes"; then
361         AC_DEFINE(USE_DYNAMIC_LINKING)
362         AC_DEFINE(HAVE_DL_SHL_LOAD,1,
363                   [Defined if the shl_load function family is available])
364         DYNLINK_LDFLAGS="$CFLAGS_EXPORTDYNAMIC"
365         use_gnupg_extensions=yes
366 dnl -----------------
367 dnl  DLD is not ready for use. So I better disable this test
368 dnl
369 dnl    AC_CHECK_LIB(dld,dld_link)
370 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
371 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
372 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
373 dnl      DYNLINK_LDFLAGS="$CFLAGS_EXPORTDYNAMIC"
374 dnl      use_gnupg_extensions=yes
375 dnl ---------------
376       fi
377     fi
378   fi
379 else
380   AC_MSG_CHECKING(for dynamic loading)
381   DYNLINK_LDFLAGS=
382   DYNLINK_MOD_CFLAGS=
383   use_gnupg_extensions=no
384   AC_MSG_RESULT(has been disabled)
385 fi
386
387 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
388 AC_SUBST(DYNLINK_LDFLAGS)
389 AC_SUBST(DYNLINK_MOD_CFLAGS)
390
391
392 dnl Checks for header files.
393 AC_HEADER_STDC
394 AC_CHECK_HEADERS(unistd.h langinfo.h termio.h)
395
396
397 dnl Checks for typedefs, structures, and compiler characteristics.
398 AC_C_CONST
399 AC_C_INLINE
400 AC_TYPE_SIZE_T
401 AC_TYPE_SIGNAL
402 AC_DECL_SYS_SIGLIST
403
404 GNUPG_CHECK_ENDIAN
405
406
407 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
408 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
409 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
410 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
411 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
412
413 AC_CHECK_SIZEOF(unsigned short, 2)
414 AC_CHECK_SIZEOF(unsigned int, 4)
415 AC_CHECK_SIZEOF(unsigned long, 4)
416 AC_CHECK_SIZEOF(unsigned long long, 0)
417
418 if test "$ac_cv_sizeof_unsigned_short" = "0" \
419    || test "$ac_cv_sizeof_unsigned_int" = "0" \
420    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
421     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
422 fi
423
424
425
426 dnl Checks for library functions.
427 AC_FUNC_VPRINTF
428 AC_CHECK_FUNCS(strerror stpcpy strlwr stricmp tcgetattr rand strtoul mmap)
429 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit clock_gettime)
430 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
431 AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask fopen64 fstat64)
432
433 GNUPG_CHECK_MLOCK
434 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
435
436 dnl
437 dnl Check whether we can use Linux capabilities as requested
438 dnl
439 if test "$use_capabilities" = "yes" ; then
440 use_capabilities=no
441 AC_CHECK_HEADERS(sys/capability.h)
442 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
443   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
444   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
445      AC_DEFINE(USE_CAPABILITIES,1,
446                [define if capabilities should be used])
447      LIBS="$LIBS -lcap"
448      use_capabilities=yes
449   fi
450 fi
451 if test "$use_capabilities" = "no" ; then
452     AC_MSG_WARN([[
453 ***
454 *** The use of capabilities on this system is not possible.
455 *** You need a recent Linux kernel and some patches:
456 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
457 ***   fcap-module-990613.tar.gz     (kernel module)
458 ***   libcap-1.92.tar.gz            (user mode library and utilities)
459 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
460 *** set (filesystems menu). Be warned: This code is *really* ALPHA.
461 ***]])
462 fi
463 fi
464
465
466 GNUPG_CHECK_IPC
467 if test "$ac_cv_header_sys_shm_h" = "yes"; then
468   AC_DEFINE(USE_SHM_COPROCESSING,1,
469             [define if the shared memory interface should be made available])
470 fi
471
472 dnl
473 dnl check whether we have a random device
474 dnl
475 if test "$try_dev_random" = yes ; then
476     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
477     [if test -r "$NAME_OF_DEV_RANDOM" && test -r "$NAME_OF_DEV_URANDOM" ; then
478       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
479     if test "$ac_cv_have_dev_random" = yes; then
480         AC_DEFINE(HAVE_DEV_RANDOM,1,
481                  [defined if the system supports a random device] )
482     fi
483 else
484     AC_MSG_CHECKING(for random device)
485     ac_cv_have_dev_random=no
486     AC_MSG_RESULT(has been disabled)
487 fi
488
489 dnl
490 dnl and whether this device supports ioctl
491 dnl (Note, that we should do a real test here)
492 dnl
493 if test "$ac_cv_have_dev_random" = yes ; then
494     AC_CHECK_HEADERS(linux/random.h)
495     AC_CACHE_CHECK(for random device ioctl, ac_cv_have_dev_random_ioctl,
496       [ if test "$ac_cv_header_linux_random_h" = yes ; then
497           ac_cv_have_dev_random_ioctl=yes;
498         else
499           ac_cv_have_dev_random_ioctl=no;
500         fi
501       ])
502     if test "$ac_cv_have_dev_random_ioctl" = yes; then
503         AC_DEFINE(HAVE_DEV_RANDOM_IOCTL,1,
504                   [defined if the random device supports some IOCTLs])
505     fi
506 fi
507
508
509 dnl
510 dnl Figure out the default linkage mode for cipher modules
511 dnl
512 print_egd_notice=no
513 if test "$use_static_rnd" = default; then
514   if test "$ac_cv_have_dev_random" = yes; then
515       static_random_module="rndlinux"
516   else
517       case "${target}" in
518           *-*-mingw32*)
519               static_random_module="rndw32"
520               AC_DEFINE(USE_STATIC_RNDW32,1,
521                        [At a certain point in the code we need to know that
522                         we use the Windows random module.])
523               ;;
524           i?86-emx-os2|i?86-*-os2*emx)
525               static_random_module="rndos2"
526               ;;
527           m68k-atari-mint)
528               static_random_module="rndatari"
529               ;;
530           i?86-*-msdosdjgpp*)
531               :
532               ;;
533           *)
534               static_random_module="rndunix"
535               print_egd_notice=yes
536              ;;
537       esac
538   fi
539 else
540   if test "$use_static_rnd" = none; then
541     :
542   else
543     static_random_module="rnd$use_static_rnd"
544     if test "$use_static_rnd" = "unix"; then
545         print_egd_notice=yes
546     fi
547   fi
548 fi
549
550
551 if test "$print_egd_notice" = "yes"; then
552     AC_MSG_WARN([[
553 ***
554 *** The performance of the UNIX random gatherer module is not very good
555 *** and it does not keep the entropy pool over multiple invocations of
556 *** GnuPG.  The suggested way to overcome this problem is to use the
557 ***
558 ***               Entropy Gathering Daemon (EGD)
559 ***
560 *** which provides a entropy source for the whole system.  It is written
561 *** in Perl and available at the GnuPG FTP servers.  For more information
562 *** consult the GnuPG webpages:
563 ***
564 ***           http://www.gnupg.org/download.html#egd
565 ***
566 *** You may want to run ./configure with --enable-static-rnd=none to be
567 *** able to load the EGD client code dynamically; this way you can choose
568 *** between RNDUNIX and RNDEGD without recompilation.
569 ***]])
570 fi
571
572 dnl
573 dnl Parse the modules list and build the list
574 dnl of static and dymically linked modules
575 dnl
576 dnl (We always need a static rmd160)
577 static_modules="$static_modules rmd160 $static_random_module"
578 STATIC_CIPHER_NAMES=""
579 STATIC_CIPHER_OBJS=""
580 DYNAMIC_CIPHER_MODS=""
581 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
582 for name in $MODULES_IN_CIPHER; do
583     x="yes"
584     for i in $disallowed_modules; do
585         if test "$name" = "$i" ; then x="no" ; fi
586     done;
587     if test $x = yes; then
588         x="no"
589         for i in $static_modules; do
590             if test "$name" = "$i" ; then
591                 x="yes"
592             fi
593         done;
594         if test $x = yes; then
595             STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
596             STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.lo"
597         else
598             DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
599             GNUPG_MSG_PRINT([$name])
600         fi
601
602 dnl        dnl Very ugly way to do this, but I don't knwo how to
603 dnl        dnl cope with AC_SUBST otherwise
604 dnl        case "$name" in
605 dnl          tiger)
606 dnl            AM_CONDITIONAL(BUILD_MODULE_TIGER,   [test $x = no])
607 dnl            ;;                                   
608 dnl          twofish)                               
609 dnl            AM_CONDITIONAL(BUILD_MODULE_TWOFISH, [test $x = no])
610 dnl            ;;                                   
611 dnl          rndunix)                               
612 dnl            AM_CONDITIONAL(BUILD_MODULE_RNDUNIX, [test $x = no])
613 dnl            ;;                                   
614 dnl          rndlinux)                              
615 dnl            AM_CONDITIONAL(BUILD_MODULE_RNDLINUX,[test $x = no])
616 dnl            ;;                                   
617 dnl          rndegd)                                
618 dnl            AM_CONDITIONAL(BUILD_MODULE_RNDEGD,  [test $x = no])
619 dnl            ;;
620 dnl          *)
621 dnl            ;;
622 dnl        esac
623     fi
624 done
625 AC_MSG_RESULT()
626 AC_SUBST(STATIC_CIPHER_OBJS)
627 AC_SUBST(STATIC_CIPHER_NAMES)
628 AC_SUBST(DYNAMIC_CIPHER_MODS)
629
630
631 dnl
632 dnl And build the constructor file
633 dnl
634
635 test -d cipher || mkdir cipher
636 cat <<G10EOF >cipher/construct.c
637 /* automatically generated by configure - do not edit */
638
639 G10EOF
640 GNUPG_MSG_PRINT([statically linked cipher modules:])
641 for name in $STATIC_CIPHER_NAMES; do
642     echo "void _gcry_${name}_constructor(void);" >>cipher/construct.c
643     GNUPG_MSG_PRINT([$name])
644 done
645 AC_MSG_RESULT()
646 cat <<G10EOF >>cipher/construct.c
647
648 void
649 _gcry_cipher_modules_constructor(void)
650 {
651     static int done = 0;
652     if( done )
653         return;
654     done = 1;
655
656 G10EOF
657 for name in $STATIC_CIPHER_NAMES; do
658     echo "   _gcry_${name}_constructor();" >>cipher/construct.c
659 done
660 echo '}' >>cipher/construct.c
661
662
663
664
665 dnl
666 dnl Figure how to link the cipher modules
667 dnl
668 AC_SUBST(STATIC_CIPHER_OBJS)
669 AC_SUBST(DYNAMIC_CIPHER_MODS)
670
671 #
672 # setup assembler stuff
673 #
674 AC_MSG_CHECKING(for mpi assembler functions)
675 if test -f $srcdir/mpi/config.links ; then
676     . $srcdir/mpi/config.links
677     AC_CONFIG_LINKS("$mpi_ln_list")
678     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
679     ac_cv_mpi_sflags="$mpi_sflags"
680     ac_cv_mpi_config_done="yes"
681     AC_MSG_RESULT(done)
682 else
683     AC_MSG_RESULT(failed)
684     AC_MSG_ERROR([mpi/config.links missing!])
685 fi
686 MPI_EXTRA_ASM_OBJS=""
687 show_extraasm=""
688 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
689 for i in $ac_cv_mpi_extra_asm_modules; do
690     show_extraasm="$show_extraasm $i"
691     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.lo"
692 done
693 fi
694 AC_SUBST(MPI_EXTRA_ASM_OBJS)
695 MPI_SFLAGS="$ac_cv_mpi_sflags"
696 AC_SUBST(MPI_SFLAGS)
697
698
699 # Allow users to append something to the version string without
700 # flagging it as development version.  The user version part is
701 # considered everything after a dash.
702 changequote(,)dnl
703 tmp_pat='[a-zA-Z]'
704 changequote([,])dnl
705 if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
706     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
707               [Defined if this is not a regular release])
708 fi
709
710 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
711
712 GNUPG_CHECK_GNUMAKE
713
714 if test "$GCC" = yes; then
715     if test "$MAINTAINER_MODE" = "yes"; then
716         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
717     else
718         CFLAGS="$CFLAGS -Wall"
719     fi
720 fi
721
722 dnl
723 dnl Make the version number in src/gcrypt.h the same as the one here.
724 dnl (this is easier than to have a *.in file just for one substitution)
725 dnl
726 GNUPG_FIX_HDR_VERSION([src/gcrypt.h], GCRYPT_VERSION)
727
728 LIBGCRYPT_LIBS="-L${libdir} -lgcrypt"
729 LIBGCRYPT_CFLAGS=""
730 AC_SUBST(LIBGCRYPT_LIBS)
731 AC_SUBST(LIBGCRYPT_CFLAGS)
732
733 AC_CONFIG_COMMANDS([gcrypt-defs],[[
734 chmod +x src/libgcrypt-config
735 cat >gcrypt-defs.tmp <<G10EOF
736 /* Generated automatically by configure */
737 #ifdef HAVE_DRIVE_LETTERS
738   #define GNUPG_LOCALEDIR "c:/lib/gnupg/locale"
739   #define GNUPG_LIBDIR  "c:/lib/gnupg"
740   #define GNUPG_DATADIR "c:/lib/gnupg"
741   #define GNUPG_HOMEDIR "c:/gnupg-test"
742 #else
743   #define GNUPG_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
744   #define GNUPG_LIBDIR  "${libdir}/gnupg"
745   #define GNUPG_DATADIR "${datadir}/gnupg"
746   #ifdef __VMS
747     #define GNUPG_HOMEDIR "/SYS\$LOGIN/gnupg" 
748   #else
749     #define GNUPG_HOMEDIR "~/.gnupg-test" 
750   #endif
751 #endif
752 G10EOF
753 if cmp -s gcrypt-defs.h gcrypt-defs.tmp 2>/dev/null; then
754     echo "gcrypt-defs.h is unchanged"
755     rm -f gcrypt-defs.tmp
756 else
757     rm -f gcrypt-defs.h
758     mv gcrypt-defs.tmp gcrypt-defs.h
759     echo "gcrypt-defs.h created"
760 fi
761 ]],[[
762 prefix=$prefix
763 exec_prefix=$exec_prefix
764 libdir=$libdir
765 datadir=$datadir
766 DATADIRNAME=$DATADIRNAME
767 ]])
768
769
770 AC_CONFIG_FILES([
771 Makefile
772 mpi/Makefile
773 cipher/Makefile
774 doc/Makefile
775 doc/version.sgml
776 src/Makefile
777 src/libgcrypt-config
778 tests/Makefile
779 ])
780 AC_OUTPUT
781