Add CFI unwind assembly directives for 64-bit ARM assembly
[libgcrypt.git] / mpi / aarch64 / mpih-mul1.S
1 /* ARM64 mul_1 -- Multiply a limb vector with a limb and store the result in
2  *                a second limb vector.
3  *
4  *      Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
5  *
6  * This file is part of Libgcrypt.
7  *
8  * Libgcrypt is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU Lesser General Public License as
10  * published by the Free Software Foundation; either version 2.1 of
11  * the License, or (at your option) any later version.
12  *
13  * Libgcrypt is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU Lesser General Public License for more details.
17  *
18  * You should have received a copy of the GNU Lesser General Public
19  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
20  *
21  */
22
23 #include "sysdep.h"
24 #include "asm-syntax.h"
25 #include "asm-common-aarch64.h"
26
27 /*******************
28  * mpi_limb_t
29  * _gcry_mpih_mul_1( mpi_ptr_t res_ptr,         x0
30  *                mpi_ptr_t s1_ptr,             x1
31  *                mpi_size_t s1_size,           w2
32  *                mpi_limb_t s2_limb)           x3
33  */
34
35 .text
36
37 .globl _gcry_mpih_mul_1
38 ELF(.type  _gcry_mpih_mul_1,%function)
39 _gcry_mpih_mul_1:
40         CFI_STARTPROC()
41         and     w5, w2, #3;
42         mov     x4, xzr;
43
44         cbz     w5, .Large_loop;
45
46 .Loop:
47         ldr     x5, [x1], #8;
48         sub     w2, w2, #1;
49         mul     x9, x5, x3;
50         umulh   x10, x5, x3;
51         and     w5, w2, #3;
52         adds    x4, x4, x9;
53         str     x4, [x0], #8;
54         adc     x4, x10, xzr;
55
56         cbz     w2, .Lend;
57         cbnz    w5, .Loop;
58
59 .Large_loop:
60         ldp     x5, x6, [x1];
61         sub     w2, w2, #4;
62
63         mul     x9, x5, x3;
64         ldp     x7, x8, [x1, #16];
65         umulh   x10, x5, x3;
66         add     x1, x1, #32;
67
68         adds    x4, x4, x9;
69         str     x4, [x0], #8;
70         mul     x11, x6, x3;
71         adc     x4, x10, xzr;
72
73         umulh   x12, x6, x3;
74
75         adds    x4, x4, x11;
76         str     x4, [x0], #8;
77         mul     x13, x7, x3;
78         adc     x4, x12, xzr;
79
80         umulh   x14, x7, x3;
81
82         adds    x4, x4, x13;
83         str     x4, [x0], #8;
84         mul     x15, x8, x3;
85         adc     x4, x14, xzr;
86
87         umulh   x16, x8, x3;
88
89         adds    x4, x4, x15;
90         str     x4, [x0], #8;
91         adc     x4, x16, xzr;
92
93         cbnz    w2, .Large_loop;
94
95 .Lend:
96         mov     x0, x4;
97         ret;
98         CFI_ENDPROC()
99 ELF(.size _gcry_mpih_mul_1,.-_gcry_mpih_mul_1;)