095d3758ac247070e5eb9bcf7c9b8a28b981a886
[npth.git] / npth.m4
1 # npth.m4 - autoconf macro to detect NPTH.
2 # Copyright (C) 2002, 2003, 2004, 2011, 2018 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 AC_DEFUN([_AM_PATH_NPTH_CONFIG],
13 [ AC_ARG_WITH(npth-prefix,
14             AC_HELP_STRING([--with-npth-prefix=PFX],
15                            [prefix where NPTH is installed (optional)]),
16      npth_config_prefix="$withval", npth_config_prefix="")
17   if test "x$npth_config_prefix" != x ; then
18       NPTH_CONFIG="$npth_config_prefix/bin/npth-config"
19   fi
20   if test x"$GPGRT_CONFIG" != x -a "$GPGRT_CONFIG" != "no"; then
21     if CC=$CC $GPGRT_CONFIG npth >/dev/null 2>&1; then
22       NPTH_CONFIG="$GPGRT_CONFIG npth"
23     else
24       NPTH_CONFIG=no
25     fi
26   else
27     AC_PATH_PROG(NPTH_CONFIG, npth-config, no)
28   fi
29
30   if test "$NPTH_CONFIG" != "no" ; then
31     npth_version=`CC=$CC $NPTH_CONFIG --modversion`
32   fi
33   npth_version_major=`echo $npth_version | \
34                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
35   npth_version_minor=`echo $npth_version | \
36                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
37 ])
38
39 dnl AM_PATH_NPTH([MINIMUM-VERSION,
40 dnl               [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
41 dnl Test for libnpth and define NPTH_CFLAGS and NPTH_LIBS.
42 dnl
43 AC_DEFUN([AM_PATH_NPTH],
44 [ AC_REQUIRE([_AM_PATH_NPTH_CONFIG])dnl
45   tmp=ifelse([$1], ,1:0.91,$1)
46   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
47      req_npth_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
48      min_npth_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
49   else
50      req_npth_api=1
51      min_npth_version="$tmp"
52   fi
53
54   AC_MSG_CHECKING(for NPTH - version >= $min_npth_version)
55   ok=no
56   if test "$NPTH_CONFIG" != "no" ; then
57     req_major=`echo $min_npth_version | \
58                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
59     req_minor=`echo $min_npth_version | \
60                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
61     if test "$npth_version_major" -gt "$req_major"; then
62         ok=yes
63     else
64         if test "$npth_version_major" -eq "$req_major"; then
65             if test "$npth_version_minor" -gt "$req_minor"; then
66                ok=yes
67             else
68                if test "$npth_version_minor" -eq "$req_minor"; then
69                   ok=yes
70                fi
71             fi
72         fi
73     fi
74   fi
75   if test $ok = yes; then
76     AC_MSG_RESULT([yes ($npth_version)])
77   else
78     AC_MSG_RESULT(no)
79   fi
80   if test $ok = yes; then
81      # If we have a recent NPTH, we should also check that the
82      # API is compatible.
83      if test "$req_npth_api" -gt 0 ; then
84         tmp=`CC=$CC $NPTH_CONFIG --variable=api_version 2>/dev/null || echo 0`
85         if test "$tmp" -gt 0 ; then
86            AC_MSG_CHECKING([NPTH API version])
87            if test "$req_npth_api" -eq "$tmp" ; then
88              AC_MSG_RESULT([okay])
89            else
90              ok=no
91              AC_MSG_RESULT([does not match. want=$req_npth_api got=$tmp])
92            fi
93         fi
94      fi
95   fi
96   if test $ok = yes; then
97     NPTH_CFLAGS=`CC=$CC $NPTH_CONFIG --cflags`
98     NPTH_LIBS=`CC=$CC $NPTH_CONFIG --libs`
99     ifelse([$2], , :, [$2])
100     npth_config_host=`CC=$CC $NPTH_CONFIG --variable=host 2>/dev/null || echo none`
101     if test x"$npth_config_host" != xnone ; then
102       if test x"$npth_config_host" != x"$host" ; then
103         AC_MSG_WARN([[
104 ***
105 *** The config script "$NPTH_CONFIG" was
106 *** built for $npth_config_host and thus may not match the
107 *** used host $host.
108 *** You may want to use the configure option --with-npth-prefix
109 *** to specify a matching config script.
110 ***]])
111       fi
112     fi
113   else
114     NPTH_CFLAGS=""
115     NPTH_LIBS=""
116     ifelse([$3], , :, [$3])
117   fi
118   AC_SUBST(NPTH_CFLAGS)
119   AC_SUBST(NPTH_LIBS)
120 ])